lisp/scroll-bar.el

   1 ;;; scroll-bar.el --- window system-independent scroll bar support
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: hardware
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Window-system-independent bindings of mouse clicks on the scroll bar.
  27 ;; Presently emulates the scroll-bar behavior of xterm.
  28
  29 ;;; Code:
  30
  31 (require 'mouse)
  32
  33 \f
  34 ;;;; Utilities.
  35
  36 (defun scroll-bar-event-ratio (event)
  37   "Given a scroll bar event EVENT, return the scroll bar position as a ratio.
  38 The value is a cons cell (PORTION . WHOLE) containing two integers
  39 whose ratio gives the event's vertical position in the scroll bar, with 0
  40 referring to the top and 1 to the bottom."
  41   (nth 2 event))
  42
  43 (defun scroll-bar-scale (num-denom whole)
  44   "Given a pair (NUM . DENOM) and WHOLE, return (/ (* NUM WHOLE) DENOM).
  45 This is handy for scaling a position on a scroll bar into real units,
  46 like buffer positions.  If SCROLL-BAR-POS is the (PORTION . WHOLE) pair
  47 from a scroll bar event, then (scroll-bar-scale SCROLL-BAR-POS
  48 \(buffer-size)) is the position in the current buffer corresponding to
  49 that scroll bar position."
  50   ;; We multiply before we divide to maintain precision.
  51   ;; We use floating point because the product of a large buffer size
  52   ;; with a large scroll bar portion can easily overflow a lisp int.
  53   (truncate (/ (* (float (car num-denom)) whole) (cdr num-denom))))
  54
  55 (defun scroll-bar-columns (side)
  56   "Return the width, measured in columns, of the vertical scrollbar on SIDE.
  57 SIDE must be the symbol `left' or `right'."
  58   (let* ((wsb   (window-scroll-bars))
  59          (vtype (nth 2 wsb))
  60          (cols  (nth 1 wsb)))
  61     (cond
  62      ((not (memq side '(left right)))
  63       (error "`left' or `right' expected instead of %S" side))
  64      ((and (eq vtype side) cols))
  65      ((eq (frame-parameter nil 'vertical-scroll-bars) side)
  66       ;; nil means it's a non-toolkit scroll bar, and its width in
  67       ;; columns is 14 pixels rounded up.
  68       (ceiling (or (frame-parameter nil 'scroll-bar-width) 14)
  69                (frame-char-width)))
  70      (0))))
  71
  72 \f
  73 ;;;; Helpful functions for enabling and disabling scroll bars.
  74
  75 (defvar scroll-bar-mode)
  76 (defvar previous-scroll-bar-mode nil)
  77
  78 (defvar scroll-bar-mode-explicit nil
  79   "Non-nil means `set-scroll-bar-mode' should really do something.
  80 This is nil while loading `scroll-bar.el', and t afterward.")
  81
  82 (defun set-scroll-bar-mode-1 (ignore value)
  83   (set-scroll-bar-mode value))
  84
  85 (defun set-scroll-bar-mode (value)
  86   "Set `scroll-bar-mode' to VALUE and put the new value into effect."
  87   (if scroll-bar-mode
  88       (setq previous-scroll-bar-mode scroll-bar-mode))
  89
  90   (setq scroll-bar-mode value)
  91
  92   (when scroll-bar-mode-explicit
  93     (modify-all-frames-parameters (list (cons 'vertical-scroll-bars
  94                                               scroll-bar-mode)))))
  95
  96 (defcustom scroll-bar-mode default-frame-scroll-bars
  97   "Specify whether to have vertical scroll bars, and on which side.
  98 Possible values are nil (no scroll bars), `left' (scroll bars on left)
  99 and `right' (scroll bars on right).
 100 To set this variable in a Lisp program, use `set-scroll-bar-mode'
 101 to make it take real effect.
 102 Setting the variable with a customization buffer also takes effect."
 103   :type '(choice (const :tag "none (nil)" nil)
 104                  (const left)
 105                  (const right))
 106   :group 'frames
 107   ;; The default value for :initialize would try to use :set
 108   ;; when processing the file in cus-dep.el.
 109   :initialize 'custom-initialize-default
 110   :set 'set-scroll-bar-mode-1)
 111
 112 ;; We just set scroll-bar-mode, but that was the default.
 113 ;; If it is set again, that is for real.
 114 (setq scroll-bar-mode-explicit t)
 115
 116 (defun scroll-bar-mode (&optional flag)
 117   "Toggle display of vertical scroll bars on all frames.
 118 This command applies to all frames that exist and frames to be
 119 created in the future.
 120 With a numeric argument, if the argument is positive
 121 turn on scroll bars; otherwise turn off scroll bars."
 122   (interactive "P")
 123
 124   ;; Tweedle the variable according to the argument.
 125   (set-scroll-bar-mode (if (if (null flag)
 126                                (not scroll-bar-mode)
 127                              (setq flag (prefix-numeric-value flag))
 128                              (or (not (numberp flag)) (> flag 0)))
 129                            (or previous-scroll-bar-mode
 130                                default-frame-scroll-bars))))
 131
 132 (defun toggle-scroll-bar (arg)
 133   "Toggle whether or not the selected frame has vertical scroll bars.
 134 With arg, turn vertical scroll bars on if and only if arg is positive.
 135 The variable `scroll-bar-mode' controls which side the scroll bars are on
 136 when they are turned on; if it is nil, they go on the left."
 137   (interactive "P")
 138   (if (null arg)
 139       (setq arg
 140             (if (cdr (assq 'vertical-scroll-bars
 141                            (frame-parameters (selected-frame))))
 142                 -1 1))
 143     (setq arg (prefix-numeric-value arg)))
 144   (modify-frame-parameters
 145    (selected-frame)
 146    (list (cons 'vertical-scroll-bars
 147                (if (> arg 0)
 148                    (or scroll-bar-mode default-frame-scroll-bars))))))
 149
 150 (defun toggle-horizontal-scroll-bar (arg)
 151   "Toggle whether or not the selected frame has horizontal scroll bars.
 152 With arg, turn horizontal scroll bars on if and only if arg is positive.
 153 Horizontal scroll bars aren't implemented yet."
 154   (interactive "P")
 155   (error "Horizontal scroll bars aren't implemented yet"))
 156 \f
 157 ;;;; Buffer navigation using the scroll bar.
 158
 159 ;;; This was used for up-events on button 2, but no longer.
 160 (defun scroll-bar-set-window-start (event)
 161   "Set the window start according to where the scroll bar is dragged.
 162 EVENT should be a scroll bar click or drag event."
 163   (interactive "e")
 164   (let* ((end-position (event-end event))
 165          (window (nth 0 end-position))
 166          (portion-whole (nth 2 end-position)))
 167     (save-excursion
 168       (set-buffer (window-buffer window))
 169       (save-excursion
 170         (goto-char (+ (point-min)
 171                       (scroll-bar-scale portion-whole
 172                                         (- (point-max) (point-min)))))
 173         (beginning-of-line)
 174         (set-window-start window (point))))))
 175
 176 (defun scroll-bar-drag-position (portion-whole)
 177   "Calculate new window start for drag event."
 178   (save-excursion
 179     (goto-char (+ (point-min)
 180                   (scroll-bar-scale portion-whole
 181                                     (- (point-max) (point-min)))))
 182     (beginning-of-line)
 183     (point)))
 184
 185 (defun scroll-bar-maybe-set-window-start (event)
 186   "Set the window start according to where the scroll bar is dragged.
 187 Only change window start if the new start is substantially different.
 188 EVENT should be a scroll bar click or drag event."
 189   (interactive "e")
 190   (let* ((end-position (event-end event))
 191          (window (nth 0 end-position))
 192          (portion-whole (nth 2 end-position))
 193          (next-portion-whole (cons (1+ (car portion-whole))
 194                                    (cdr portion-whole)))
 195          portion-start
 196          next-portion-start
 197          (current-start (window-start window)))
 198     (save-excursion
 199       (set-buffer (window-buffer window))
 200       (setq portion-start (scroll-bar-drag-position portion-whole))
 201       (setq next-portion-start (max
 202                                 (scroll-bar-drag-position next-portion-whole)
 203                                 (1+ portion-start)))
 204       (if (or (>= current-start next-portion-start)
 205               (< current-start portion-start))
 206           (set-window-start window portion-start)
 207         ;; Always set window start, to ensure scroll bar position is updated.
 208         (set-window-start window current-start)))))
 209
 210 ;; Scroll the window to the proper position for EVENT.
 211 (defun scroll-bar-drag-1 (event)
 212   (let* ((start-position (event-start event))
 213          (window (nth 0 start-position))
 214          (portion-whole (nth 2 start-position)))
 215     (save-excursion
 216       (set-buffer (window-buffer window))
 217       ;; Calculate position relative to the accessible part of the buffer.
 218       (goto-char (+ (point-min)
 219                     (scroll-bar-scale portion-whole
 220                                       (- (point-max) (point-min)))))
 221       (vertical-motion 0 window)
 222       (set-window-start window (point)))))
 223
 224 (defun scroll-bar-drag (event)
 225   "Scroll the window by dragging the scroll bar slider.
 226 If you click outside the slider, the window scrolls to bring the slider there."
 227   (interactive "e")
 228   (let* (done
 229          (echo-keystrokes 0)
 230          (end-position (event-end event))
 231          (window (nth 0 end-position))
 232          (before-scroll))
 233     (with-current-buffer (window-buffer window)
 234       (setq before-scroll point-before-scroll))
 235     (save-selected-window
 236       (select-window window)
 237       (setq before-scroll
 238             (or before-scroll (point))))
 239     (scroll-bar-drag-1 event)
 240     (track-mouse
 241       (while (not done)
 242         (setq event (read-event))
 243         (if (eq (car-safe event) 'mouse-movement)
 244             (setq event (read-event)))
 245         (cond ((eq (car-safe event) 'scroll-bar-movement)
 246                (scroll-bar-drag-1 event))
 247               (t
 248                ;; Exit when we get the drag event; ignore that event.
 249                (setq done t)))))
 250     (sit-for 0)
 251     (with-current-buffer (window-buffer window)
 252       (setq point-before-scroll before-scroll))))
 253
 254 (defun scroll-bar-scroll-down (event)
 255   "Scroll the window's top line down to the location of the scroll bar click.
 256 EVENT should be a scroll bar click."
 257   (interactive "e")
 258   (let* ((end-position (event-end event))
 259          (window (nth 0 end-position))
 260          (before-scroll))
 261     (with-current-buffer (window-buffer window)
 262       (setq before-scroll point-before-scroll))
 263     (unwind-protect
 264         (save-selected-window
 265           (let ((portion-whole (nth 2 end-position)))
 266             (select-window window)
 267             (setq before-scroll
 268                   (or before-scroll (point)))
 269             (scroll-down
 270              (scroll-bar-scale portion-whole (1- (window-height)))))
 271           (sit-for 0))
 272       (with-current-buffer (window-buffer window)
 273         (setq point-before-scroll before-scroll)))))
 274
 275 (defun scroll-bar-scroll-up (event)
 276   "Scroll the line next to the scroll bar click to the top of the window.
 277 EVENT should be a scroll bar click."
 278   (interactive "e")
 279   (let* ((end-position (event-end event))
 280          (window (nth 0 end-position))
 281          (before-scroll))
 282     (with-current-buffer (window-buffer window)
 283       (setq before-scroll point-before-scroll))
 284     (unwind-protect
 285         (save-selected-window
 286           (let ((portion-whole (nth 2 end-position)))
 287             (select-window window)
 288             (setq before-scroll
 289                   (or before-scroll (point)))
 290             (scroll-up
 291              (scroll-bar-scale portion-whole (1- (window-height)))))
 292           (sit-for 0))
 293       (with-current-buffer (window-buffer window)
 294         (setq point-before-scroll before-scroll)))))
 295
 296 \f
 297 ;;; Tookit scroll bars.
 298
 299 (defun scroll-bar-toolkit-scroll (event)
 300   (interactive "e")
 301   (let* ((end-position (event-end event))
 302          (window (nth 0 end-position))
 303          (part (nth 4 end-position))
 304          before-scroll)
 305     (cond ((eq part 'end-scroll))
 306           (t
 307            (with-current-buffer (window-buffer window)
 308              (setq before-scroll point-before-scroll))
 309            (save-selected-window
 310              (select-window window)
 311              (setq before-scroll (or before-scroll (point)))
 312              (cond ((eq part 'above-handle)
 313                     (scroll-up '-))
 314                    ((eq part 'below-handle)
 315                     (scroll-up nil))
 316                    ((eq part 'ratio)
 317                     (let* ((portion-whole (nth 2 end-position))
 318                            (lines (scroll-bar-scale portion-whole
 319                                                     (1- (window-height)))))
 320                       (scroll-up (cond ((not (zerop lines)) lines)
 321                                        ((< (car portion-whole) 0) -1)
 322                                        (t 1)))))
 323                    ((eq part 'up)
 324                     (scroll-up -1))
 325                    ((eq part 'down)
 326                     (scroll-up 1))
 327                    ((eq part 'top)
 328                     (set-window-start window (point-min)))
 329                    ((eq part 'bottom)
 330                     (goto-char (point-max))
 331                     (recenter))
 332                    ((eq part 'handle)
 333                     (scroll-bar-drag-1 event))))
 334            (sit-for 0)
 335            (with-current-buffer (window-buffer window)
 336              (setq point-before-scroll before-scroll))))))
 337
 338
 339 \f
 340 ;;;; Bindings.
 341
 342 ;;; For now, we'll set things up to work like xterm.
 343 (cond ((and (boundp 'x-toolkit-scroll-bars) x-toolkit-scroll-bars)
 344        (global-set-key [vertical-scroll-bar mouse-1]
 345                        'scroll-bar-toolkit-scroll))
 346       (t
 347        (global-set-key [vertical-scroll-bar mouse-1]
 348                        'scroll-bar-scroll-up)
 349        (global-set-key [vertical-scroll-bar drag-mouse-1]
 350                        'scroll-bar-scroll-up)
 351        (global-set-key [vertical-scroll-bar down-mouse-2]
 352                        'scroll-bar-drag)
 353        (global-set-key [vertical-scroll-bar mouse-3]
 354                        'scroll-bar-scroll-down)
 355        (global-set-key [vertical-scroll-bar drag-mouse-3]
 356                        'scroll-bar-scroll-down)))
 357
 358 \f
 359 (provide 'scroll-bar)
 360
 361 ;; arch-tag: 6f1d01d0-0b1e-4bf8-86db-d491e0f399f3
 362 ;;; scroll-bar.el ends here