configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 143 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 dnl _ON results in a '--without' option in the --help output, so
 150 dnl the help text should refer to "don't compile", etc.
 151 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 152 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 153 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 154 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 155 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 156 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171
 172 ## For the times when you want to build Emacs but don't have
 173 ## a suitable makeinfo, and can live without the manuals.
 174 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 175 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 176
 177 ## This is an option because I do not know if all info/man support
 178 ## compressed files, nor how to test if they do so.
 179 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 180 if test $with_compress_info = yes; then
 181    GZIP_INFO=yes
 182 else
 183    GZIP_INFO=
 184 fi
 185 AC_SUBST(GZIP_INFO)
 186
 187 AC_ARG_WITH([pkg-config-prog],dnl
 188 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 189                   [path to pkg-config for finding GTK and librsvg])])
 190 if test "X${with_pkg_config_prog}" != X; then
 191    if test "${with_pkg_config_prog}" != yes; then
 192       PKG_CONFIG="${with_pkg_config_prog}"
 193    fi
 194 fi
 195
 196 CRT_DIR=
 197 AC_ARG_WITH([crt-dir],dnl
 198 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 199 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 200 CRT_DIR="${with_crt_dir}"
 201
 202 AC_ARG_WITH([gnustep-conf],dnl
 203 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 204 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 205   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 206 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 207      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 208
 209 AC_ARG_ENABLE(ns-self-contained,
 210 [AS_HELP_STRING([--disable-ns-self-contained],
 211                 [disable self contained build under NeXTstep])],
 212    EN_NS_SELF_CONTAINED=$enableval,
 213    EN_NS_SELF_CONTAINED=yes)
 214
 215 AC_ARG_ENABLE(asserts,
 216 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 217       USE_XASSERTS=$enableval,
 218       USE_XASSERTS=no)
 219
 220 AC_ARG_ENABLE(maintainer-mode,
 221 [AS_HELP_STRING([--enable-maintainer-mode],
 222                 [enable make rules and dependencies not useful (and sometimes
 223                  confusing) to the casual installer])],
 224       USE_MAINTAINER_MODE=$enableval,
 225       USE_MAINTAINER_MODE=no)
 226 if test $USE_MAINTAINER_MODE = yes; then
 227   MAINT=
 228 else
 229   MAINT=#
 230 fi
 231 AC_SUBST(MAINT)
 232
 233 AC_ARG_ENABLE(locallisppath,
 234 [AS_HELP_STRING([--enable-locallisppath=PATH],
 235                 [directories Emacs should search for lisp files specific
 236                  to this site])],
 237 if test "${enableval}" = "no"; then
 238   locallisppath=
 239 elif test "${enableval}" != "yes"; then
 240   locallisppath=${enableval}
 241 fi)
 242
 243 AC_ARG_ENABLE(checking,
 244 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 245                 [enable expensive run-time checks.  With LIST,
 246                  enable only specific categories of checks.
 247                  Categories are: all,yes,no.
 248                  Flags are: stringbytes, stringoverrun, stringfreelist,
 249                  xmallocoverrun, conslist])],
 250 [ac_checking_flags="${enableval}"],[])
 251 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 252 for check in $ac_checking_flags
 253 do
 254         case $check in
 255         # these set all the flags to specific states
 256         yes)            ac_enable_checking=1 ;;
 257         no)             ac_enable_checking= ;
 258                         ac_gc_check_stringbytes= ;
 259                         ac_gc_check_string_overrun= ;
 260                         ac_gc_check_string_free_list= ;
 261                         ac_xmalloc_overrun= ;
 262                         ac_gc_check_cons_list= ;;
 263         all)            ac_enable_checking=1 ;
 264                         ac_gc_check_stringbytes=1 ;
 265                         ac_gc_check_string_overrun=1 ;
 266                         ac_gc_check_string_free_list=1 ;
 267                         ac_xmalloc_overrun=1 ;
 268                         ac_gc_check_cons_list=1 ;;
 269         # these enable particular checks
 270         stringbytes)    ac_gc_check_stringbytes=1 ;;
 271         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 272         stringfreelist) ac_gc_check_string_free_list=1 ;;
 273         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 274         conslist)       ac_gc_check_cons_list=1 ;;
 275         *)      AC_MSG_ERROR(unknown check category $check) ;;
 276         esac
 277 done
 278 IFS="$ac_save_IFS"
 279
 280 if test x$ac_enable_checking != x ; then
 281   AC_DEFINE(ENABLE_CHECKING, 1,
 282 [Enable expensive run-time checking of data types?])
 283 fi
 284 if test x$ac_gc_check_stringbytes != x ; then
 285   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 286 [Define this temporarily to hunt a bug.  If defined, the size of
 287    strings is redundantly recorded in sdata structures so that it can
 288    be compared to the sizes recorded in Lisp strings.])
 289 fi
 290 if test x$ac_gc_check_stringoverrun != x ; then
 291   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 292 [Define this to check for short string overrun.])
 293 fi
 294 if test x$ac_gc_check_string_free_list != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 296 [Define this to check the string free list.])
 297 fi
 298 if test x$ac_xmalloc_overrun != x ; then
 299   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 300 [Define this to check for malloc buffer overrun.])
 301 fi
 302 if test x$ac_gc_check_cons_list != x ; then
 303   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 304 [Define this to check for errors in cons list.])
 305 fi
 306
 307 AC_ARG_ENABLE(profiling,
 308 [AS_HELP_STRING([--enable-profiling],
 309                 [build emacs with profiling support.
 310                  This might not work on all platforms])],
 311 [ac_enable_profiling="${enableval}"],[])
 312 if test x$ac_enable_profiling != x ; then
 313    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 314    PROFILING_LDFLAGS="-pg"
 315 else
 316    PROFILING_CFLAGS=
 317    PROFILING_LDFLAGS=
 318 fi
 319
 320 AC_ARG_ENABLE(autodepend,
 321 [AS_HELP_STRING([--enable-autodepend],
 322                 [automatically generate dependencies to .h-files.
 323                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 324                  found])],
 325 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 326
 327 #### Make srcdir absolute, if it isn't already.  It's important to
 328 #### avoid running the path through pwd unnecessarily, since pwd can
 329 #### give you automounter prefixes, which can go away.  We do all this
 330 #### so Emacs can find its files when run uninstalled.
 331 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 332 unset CDPATH
 333 case "${srcdir}" in
 334   /* ) ;;
 335   . )
 336     ## We may be able to use the $PWD environment variable to make this
 337     ## absolute.  But sometimes PWD is inaccurate.
 338     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 339     ## but that tested only for a well-formed and valid PWD,
 340     ## it did not object when PWD was well-formed and valid but just wrong.
 341     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 342     then
 343       srcdir="$PWD"
 344     else
 345       srcdir="`(cd ${srcdir}; pwd)`"
 346     fi
 347   ;;
 348   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 349 esac
 350
 351 #### Check if the source directory already has a configured system in it.
 352 if test `pwd` != `(cd ${srcdir} && pwd)` \
 353    && test -f "${srcdir}/src/config.h" ; then
 354   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 355    as a build directory right now; it has been configured in its own
 356    right.  To configure in another directory as well, you MUST
 357    use GNU make.  If you do not have GNU make, then you must
 358    now do `make distclean' in ${srcdir},
 359    and then run $0 again.]])
 360 fi
 361
 362 #### Given the configuration name, set machfile and opsysfile to the
 363 #### names of the m/*.h and s/*.h files we should use.
 364
 365 ### Canonicalize the configuration name.
 366
 367 AC_CANONICAL_HOST
 368 canonical=$host
 369 configuration=${host_alias-${build_alias-$host}}
 370
 371 dnl This used to use changequote, but, apart from `changequote is evil'
 372 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 373 dnl the great gob of text.  Thus it's not processed for possible expansion.
 374 dnl Just make sure the brackets remain balanced.
 375 dnl
 376 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 377 dnl indicated by comments.
 378 dnl quotation begins
 379 [
 380
 381 ### If you add support for a new configuration, add code to this
 382 ### switch statement to recognize your configuration name and select
 383 ### the appropriate operating system and machine description files.
 384
 385 ### You would hope that you could choose an m/*.h file pretty much
 386 ### based on the machine portion of the configuration name, and an s/*.h
 387 ### file based on the operating system portion.  However, it turns out
 388 ### that each m/*.h file is pretty manufacturer-specific - for
 389 ### example mips.h is MIPS
 390 ### So we basically have to have a special case for each
 391 ### configuration name.
 392 ###
 393 ### As far as handling version numbers on operating systems is
 394 ### concerned, make sure things will fail in a fixable way.  If
 395 ### /etc/MACHINES doesn't say anything about version numbers, be
 396 ### prepared to handle anything reasonably.  If version numbers
 397 ### matter, be sure /etc/MACHINES says something about it.
 398
 399 machine='' opsys='' unported=no
 400 case "${canonical}" in
 401
 402   ## FreeBSD ports
 403   *-*-freebsd* )
 404     opsys=freebsd
 405     case "${canonical}" in
 406       alpha*)           machine=alpha ;;
 407       amd64-*|x86_64-*) machine=amdx86-64 ;;
 408       arm*)             machine=arm ;;
 409       ia64-*)           machine=ia64 ;;
 410       i[3456]86-*)      machine=intel386 ;;
 411       powerpc-*)        machine=macppc ;;
 412       sparc-*)          machine=sparc ;;
 413       sparc64-*)        machine=sparc ;;
 414     esac
 415   ;;
 416
 417   ## FreeBSD kernel + glibc based userland
 418   *-*-kfreebsd*gnu* )
 419     opsys=gnu-kfreebsd
 420     case "${canonical}" in
 421       alpha*)           machine=alpha ;;
 422       amd64-*|x86_64-*) machine=amdx86-64 ;;
 423       ia64-*)           machine=ia64 ;;
 424       i[3456]86-*)      machine=intel386 ;;
 425       powerpc-*)        machine=macppc ;;
 426       sparc-*)          machine=sparc ;;
 427       sparc64-*)        machine=sparc ;;
 428     esac
 429   ;;
 430
 431   ## NetBSD ports
 432   *-*-netbsd* )
 433     opsys=netbsd
 434     case "${canonical}" in
 435       alpha*)      machine=alpha ;;
 436       x86_64-*)    machine=amdx86-64 ;;
 437       arm-*)       machine=arm ;;
 438       hppa-*)      machine=hp800 ;;
 439       i[3456]86-*) machine=intel386 ;;
 440       m68k-*)      machine=m68k ;;
 441       powerpc-*)   machine=macppc ;;
 442       mips-*)      machine=mips ;;
 443       mipse[bl]-*) machine=mips ;;
 444       sparc*-)     machine=sparc ;;
 445       vax-*)       machine=vax ;;
 446     esac
 447   ;;
 448
 449   ## OpenBSD ports
 450   *-*-openbsd* )
 451     opsys=openbsd
 452     case "${canonical}" in
 453       alpha*)    machine=alpha ;;
 454       x86_64-*)  machine=amdx86-64 ;;
 455       arm-*)     machine=arm ;;
 456       hppa-*)    machine=hp800 ;;
 457       i386-*)    machine=intel386 ;;
 458       powerpc-*) machine=macppc ;;
 459       sparc*)    machine=sparc ;;
 460       vax-*)     machine=vax ;;
 461     esac
 462   ;;
 463
 464   alpha*-*-linux-gnu* )
 465     machine=alpha opsys=gnu-linux
 466   ;;
 467
 468   arm*-*-linux-gnu* )
 469     machine=arm opsys=gnu-linux
 470   ;;
 471
 472   ## Apple Darwin / Mac OS X
 473   *-apple-darwin* )
 474     case "${canonical}" in
 475       i[3456]86-* )  machine=intel386 ;;
 476       powerpc-* )    machine=macppc ;;
 477       x86_64-* )     machine=amdx86-64 ;;
 478       * )            unported=yes ;;
 479     esac
 480     opsys=darwin
 481     # Define CPP as follows to make autoconf work correctly.
 482     CPP="${CC-cc} -E -no-cpp-precomp"
 483     # Use fink packages if available.
 484     if test -d /sw/include && test -d /sw/lib; then
 485       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 486       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 487       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 488     fi
 489   ;;
 490
 491   ## HP 9000 series 700 and 800, running HP/UX
 492   hppa*-hp-hpux10.2* )
 493     machine=hp800 opsys=hpux10-20
 494   ;;
 495   hppa*-hp-hpux1[1-9]* )
 496     machine=hp800 opsys=hpux11
 497     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 498   ;;
 499
 500   hppa*-*-linux-gnu* )
 501     machine=hp800 opsys=gnu-linux
 502   ;;
 503
 504   ## IBM machines
 505   s390-*-linux-gnu* )
 506     machine=ibms390 opsys=gnu-linux
 507   ;;
 508   s390x-*-linux-gnu* )
 509     machine=ibms390x opsys=gnu-linux
 510   ;;
 511   rs6000-ibm-aix4.[23]* )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   powerpc-ibm-aix4.[23]*  )
 515     machine=ibmrs6000 opsys=aix4-2
 516   ;;
 517   rs6000-ibm-aix[56]* )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520   powerpc-ibm-aix[56]*  )
 521     machine=ibmrs6000 opsys=aix4-2
 522   ;;
 523
 524   ## Macintosh PowerPC
 525   powerpc*-*-linux-gnu* )
 526     machine=macppc opsys=gnu-linux
 527   ;;
 528
 529   ## Silicon Graphics machines
 530   ## Iris 4D
 531   mips-sgi-irix6.5 )
 532     machine=iris4d opsys=irix6-5
 533     # Without defining _LANGUAGE_C, things get masked out in the headers
 534     # so that, for instance, grepping for `free' in stdlib.h fails and
 535     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 536     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 537     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 538   ;;
 539
 540   ## Suns
 541   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 542     machine=sparc opsys=gnu-linux
 543   ;;
 544
 545   *-sun-solaris* \
 546     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 547     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 548     case "${canonical}" in
 549       i[3456]86-*-* )     machine=intel386 ;;
 550       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 551       sparc* )          machine=sparc ;;
 552       * )               unported=yes ;;
 553     esac
 554     case "${canonical}" in
 555       *-sunos5.6* | *-solaris2.6* )
 556                 opsys=sol2-6
 557                 NON_GNU_CPP=/usr/ccs/lib/cpp
 558                 RANLIB="ar -ts"
 559                 ;;
 560       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 561                 opsys=sol2-6
 562                 emacs_check_sunpro_c=yes
 563                 NON_GNU_CPP=/usr/ccs/lib/cpp
 564                 ;;
 565       *-sunos5* | *-solaris* )
 566                 opsys=sol2-10
 567                 emacs_check_sunpro_c=yes
 568                 NON_GNU_CPP=/usr/ccs/lib/cpp
 569                 ;;
 570     esac
 571     ## Watch out for a compiler that we know will not work.
 572     case "${canonical}" in
 573      *-solaris* | *-sunos5* )
 574                 if [ "x$CC" = x/usr/ucb/cc ]; then
 575                   ## /usr/ucb/cc doesn't work;
 576                   ## we should find some other compiler that does work.
 577                   unset CC
 578                 fi
 579                 ;;
 580       *) ;;
 581     esac
 582   ;;
 583
 584   ## IA-64
 585   ia64*-*-linux* )
 586     machine=ia64 opsys=gnu-linux
 587   ;;
 588
 589   ## Intel 386 machines where we don't care about the manufacturer.
 590   i[3456]86-*-* )
 591     machine=intel386
 592     case "${canonical}" in
 593       *-cygwin )                opsys=cygwin ;;
 594       *-darwin* )               opsys=darwin
 595                                 CPP="${CC-cc} -E -no-cpp-precomp"
 596                                 ;;
 597       *-linux-gnu* )            opsys=gnu-linux ;;
 598       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 600       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 602     esac
 603   ;;
 604
 605   ## m68k Linux-based GNU system
 606   m68k-*-linux-gnu* )
 607     machine=m68k opsys=gnu-linux
 608   ;;
 609
 610   ## Mips Linux-based GNU system
 611   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 612     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 613     machine=mips opsys=gnu-linux
 614   ;;
 615
 616   ## AMD x86-64 Linux-based GNU system
 617   x86_64-*-linux-gnu* )
 618     machine=amdx86-64 opsys=gnu-linux
 619   ;;
 620
 621   ## Tensilica Xtensa Linux-based GNU system
 622   xtensa*-*-linux-gnu* )
 623     machine=xtensa opsys=gnu-linux
 624     ;;
 625
 626   ## SuperH Linux-based GNU system
 627   sh[34]*-*-linux-gnu* )
 628     machine=sh3 opsys=gnu-linux
 629   ;;
 630
 631   * )
 632     unported=yes
 633   ;;
 634 esac
 635
 636 ### If the code above didn't choose an operating system, just choose
 637 ### an operating system based on the configuration name.  You really
 638 ### only want to use this when you have no idea what the right
 639 ### operating system is; if you know what operating systems a machine
 640 ### runs, it's cleaner to make it explicit in the case statement
 641 ### above.
 642 if test x"${opsys}" = x; then
 643   case "${canonical}" in
 644     *-gnu* )                            opsys=gnu ;;
 645     * )
 646       unported=yes
 647     ;;
 648   esac
 649 fi
 650
 651 ]
 652 dnl quotation ends
 653
 654 if test $unported = yes; then
 655   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 656 Check `etc/MACHINES' for recognized configuration names.])
 657 fi
 658
 659 machfile="m/${machine}.h"
 660 opsysfile="s/${opsys}.h"
 661
 662
 663 #### Choose a compiler.
 664 test -n "$CC" && cc_specified=yes
 665
 666 # Save the value of CFLAGS that the user specified.
 667 SPECIFIED_CFLAGS="$CFLAGS"
 668
 669 dnl Sets GCC=yes if using gcc.
 670 AC_PROG_CC
 671
 672 # On Suns, sometimes $CPP names a directory.
 673 if test -n "$CPP" && test -d "$CPP"; then
 674   CPP=
 675 fi
 676
 677 ## If not using gcc, and on Solaris, and no CPP specified, see if
 678 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 679 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 680  test x"$CPP" = x; then
 681   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 682   AC_CACHE_VAL(emacs_cv_sunpro_c,
 683   [AC_TRY_LINK([],
 684 [#ifndef __SUNPRO_C
 685 fail;
 686 #endif
 687 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 688   AC_MSG_RESULT($emacs_cv_sunpro_c)
 689
 690   if test x"$emacs_cv_sunpro_c" = xyes; then
 691     NON_GNU_CPP="$CC -E -Xs"
 692   fi
 693 fi
 694
 695 #### Some systems specify a CPP to use unless we are using GCC.
 696 #### Now that we know whether we are using GCC, we can decide whether
 697 #### to use that one.
 698 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 699 then
 700   CPP="$NON_GNU_CPP"
 701 fi
 702
 703 #### Some systems specify a CC to use unless we are using GCC.
 704 #### Now that we know whether we are using GCC, we can decide whether
 705 #### to use that one.
 706 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 707   test x$cc_specified != xyes
 708 then
 709   CC="$NON_GNU_CC"
 710 fi
 711
 712 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 713 then
 714   CC="$CC $GCC_TEST_OPTIONS"
 715 fi
 716
 717 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 718 then
 719   CC="$CC $NON_GCC_TEST_OPTIONS"
 720 fi
 721
 722 dnl checks for Unix variants
 723 AC_USE_SYSTEM_EXTENSIONS
 724
 725 ### Use -Wno-pointer-sign if the compiler supports it
 726 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 727 SAVE_CFLAGS="$CFLAGS"
 728 CFLAGS="$CFLAGS -Wno-pointer-sign"
 729 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 730 if test $has_option = yes; then
 731    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 732 fi
 733 AC_MSG_RESULT($has_option)
 734 CFLAGS="$SAVE_CFLAGS"
 735 unset has_option
 736 unset SAVE_CFLAGS
 737
 738 ### Use -Wdeclaration-after-statement if the compiler supports it
 739 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 740 SAVE_CFLAGS="$CFLAGS"
 741 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 742 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 743 if test $has_option = yes; then
 744    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 745 fi
 746 AC_MSG_RESULT($has_option)
 747 CFLAGS="$SAVE_CFLAGS"
 748 unset has_option
 749 unset SAVE_CFLAGS
 750
 751 #### Some other nice autoconf tests.
 752
 753 dnl checks for programs
 754 AC_PROG_CPP
 755 AC_PROG_INSTALL
 756 if test "x$RANLIB" = x; then
 757   AC_PROG_RANLIB
 758 fi
 759
 760 ## Although we're running on an amd64 kernel, we're actually compiling for
 761 ## the x86 architecture.  The user should probably have provided an
 762 ## explicit --build to `configure', but if everything else than the kernel
 763 ## is running in i386 mode, we can help them out.
 764 if test "$machine" = "amdx86-64"; then
 765   AC_CHECK_DECL([i386])
 766   if test "$ac_cv_have_decl_i386" = "yes"; then
 767     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 768     machine=intel386
 769     machfile="m/${machine}.h"
 770   fi
 771 fi
 772
 773 AC_PATH_PROG(INSTALL_INFO, install-info)
 774 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 775 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 776 dnl Don't use GZIP, which is used by gzip for additional parameters.
 777 AC_PATH_PROG(GZIP_PROG, gzip)
 778
 779
 780 ## Need makeinfo >= 4.6 (?) to build the manuals.
 781 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 782 dnl By this stage, configure has already checked for egrep and set EGREP,
 783 dnl or exited with an error if no egrep was found.
 784 if test "$MAKEINFO" != "no" && \
 785   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 786    MAKEINFO=no
 787 fi
 788
 789 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 790 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 791 ## therefore in the category of "special tools" not normally required, which
 792 ## configure does not have to check for (eg autoconf itself).
 793 ## In a Bazaar checkout on the other hand, the manuals are not included.
 794 ## So makeinfo is a requirement to build from Bazaar, and configure
 795 ## should test for it as it does for any other build requirement.
 796 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 797 ## with pre-built manuals, from a Bazaar checkout.
 798 if test "$MAKEINFO" = "no"; then
 799   if test "x${with_makeinfo}" = "xno"; then
 800     MAKEINFO=off
 801   elif test ! -e $srcdir/info/emacs; then
 802     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 803 source tree does not seem to have pre-built manuals in the `info' directory.
 804 Either install a suitable version of makeinfo, or re-run configure
 805 with the `--without-makeinfo' option to build without the manuals.] )
 806   fi
 807 fi
 808
 809 dnl Add our options to ac_link now, after it is set up.
 810
 811 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 812 then
 813   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 814 fi
 815
 816 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 817 then
 818   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 819 fi
 820
 821 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 822 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 823 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 824 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 825 dnl if not built to support GNU ld.
 826
 827 late_LDFLAGS=$LDFLAGS
 828 if test "$GCC" = yes; then
 829   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 830 else
 831   LDFLAGS="$LDFLAGS -znocombreloc"
 832 fi
 833
 834 AC_MSG_CHECKING([for -znocombreloc])
 835 AC_LINK_IFELSE([main(){return 0;}],
 836   [AC_MSG_RESULT(yes)],
 837   LDFLAGS=$late_LDFLAGS
 838   [AC_MSG_RESULT(no)])
 839
 840 #### Extract some information from the operating system and machine files.
 841
 842 AC_CHECKING([the machine- and system-dependent files to find out
 843  - which libraries the lib-src programs will want, and
 844  - whether the GNU malloc routines are usable])
 845
 846 ### First figure out CFLAGS (which we use for running the compiler here)
 847 ### and REAL_CFLAGS (which we use for real compilation).
 848 ### The two are the same except on a few systems, where they are made
 849 ### different to work around various lossages.  For example,
 850 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 851 ### as implying static linking.
 852
 853 ### If the CFLAGS env var is specified, we use that value
 854 ### instead of the default.
 855
 856 ### It's not important that this name contain the PID; you can't run
 857 ### two configures in the same directory and have anything work
 858 ### anyway.
 859 tempcname="conftest.c"
 860
 861 echo '
 862 #include "'${srcdir}'/src/'${opsysfile}'"
 863 #include "'${srcdir}'/src/'${machfile}'"
 864
 865 configure___ LIBX=-lX11
 866
 867 #ifdef CANNOT_DUMP
 868 configure___ cannot_dump=yes
 869 #else
 870 configure___ cannot_dump=no
 871 #endif
 872
 873 #ifdef SYSTEM_MALLOC
 874 configure___ system_malloc=yes
 875 #else
 876 configure___ system_malloc=no
 877 #endif
 878
 879 #ifdef USE_MMAP_FOR_BUFFERS
 880 configure___ use_mmap_for_buffers=yes
 881 #else
 882 configure___ use_mmap_for_buffers=no
 883 #endif
 884
 885 #ifndef C_OPTIMIZE_SWITCH
 886 #ifdef __GNUC__
 887 #define C_OPTIMIZE_SWITCH -O2
 888 #else
 889 #define C_OPTIMIZE_SWITCH -O
 890 #endif
 891 #endif
 892
 893 #ifndef C_WARNINGS_SWITCH
 894 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 895 #endif
 896
 897 #ifdef THIS_IS_CONFIGURE
 898
 899 /* Get the CFLAGS for tests in configure.  */
 900 #ifdef __GNUC__
 901 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 902 #else
 903 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 904 #endif
 905
 906 #else /* not THIS_IS_CONFIGURE */
 907
 908 /* Get the CFLAGS for real compilation.  */
 909 #ifdef __GNUC__
 910 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 911 #else
 912 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 913 #endif
 914
 915 #endif /* not THIS_IS_CONFIGURE */
 916 ' > ${tempcname}
 917
 918 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 919
 920 # The value of CPP is a quoted variable reference, so we need to do this
 921 # to get its actual value...
 922 CPP=`eval "echo $CPP"`
 923 [eval `${CPP} -Isrc ${tempcname} \
 924        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 925 if test "x$SPECIFIED_CFLAGS" = x; then
 926   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 927          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 928 else
 929   REAL_CFLAGS="$CFLAGS"
 930 fi]
 931 rm ${tempcname}
 932
 933
 934 AC_SUBST(cannot_dump)
 935
 936 UNEXEC_OBJ=unexelf.o
 937 case "$opsys" in
 938   aix4-2)
 939    UNEXEC_OBJ=unexaix.o
 940    ;;
 941   cygwin)
 942    UNEXEC_OBJ=unexcw.o
 943    ;;
 944   darwin)
 945    UNEXEC_OBJ=unexmacosx.o
 946    ;;
 947   hpux10-20 | hpux11)
 948    UNEXEC_OBJ=unexhp9k800.o
 949    ;;
 950   sol2-10)
 951    # Use the Solaris dldump() function, called from unexsol.c, to dump
 952    # emacs, instead of the generic ELF dump code found in unexelf.c.
 953    # The resulting binary has a complete symbol table, and is better
 954    # for debugging and other observability tools (debuggers, pstack, etc).
 955    #
 956    # If you encounter a problem using dldump(), please consider sending
 957    # a message to the OpenSolaris tools-linking mailing list:
 958    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 959    #
 960    # It is likely that dldump() works with older Solaris too, but this has
 961    # not been tested, so for now this change is for Solaris 10 or newer.
 962    UNEXEC_OBJ=unexsol.o
 963    ;;
 964 esac
 965
 966 LD_SWITCH_SYSTEM=
 967 case "$opsys" in
 968   freebsd)
 969    ## Let `ld' find image libs and similar things in /usr/local/lib.
 970    ## The system compiler, GCC, has apparently been modified to not
 971    ## look there, contrary to what a stock GCC would do.
 972    LD_SWITCH_SYSTEM=-L/usr/local/lib
 973    ;;
 974
 975   gnu-linux)
 976    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 977    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 978    ;;
 979
 980   netbsd)
 981    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 982    ;;
 983
 984   openbsd)
 985    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 986    ## otherwise Emacs dumps core on elf systems.
 987    LD_SWITCH_SYSTEM="-Z"
 988    ;;
 989 esac
 990 AC_SUBST(LD_SWITCH_SYSTEM)
 991
 992 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 993
 994 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 995 ## which has not been defined yet.  When this was handled with cpp,
 996 ## it was expanded to null when configure sourced the s/*.h file.
 997 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 998 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 999 ## (or somesuch), but because it is supposed to go at the _front_
1000 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1001 ## Compare with the gnu-linux case below, which added to the end
1002 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1003 ## LD_SWITCH_SYSTEM_TEMACS.
1004 case "$opsys" in
1005   netbsd|openbsd)
1006    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
1007    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
1008 esac
1009
1010
1011 C_SWITCH_MACHINE=
1012 if test "$machine" = "alpha"; then
1013   AC_CHECK_DECL([__ELF__])
1014   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1015     ## With ELF, make sure that all common symbols get allocated to in the
1016     ## data section.  Otherwise, the dump of temacs may miss variables in
1017     ## the shared library that have been initialized.  For example, with
1018     ## GNU libc, __malloc_initialized would normally be resolved to the
1019     ## shared library's .bss section, which is fatal.
1020     if test "x$GCC" = "xyes"; then
1021       C_SWITCH_MACHINE="-fno-common"
1022     else
1023       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1024     fi
1025   else
1026     UNEXEC_OBJ=unexalpha.o
1027   fi
1028 fi
1029 AC_SUBST(C_SWITCH_MACHINE)
1030
1031 AC_SUBST(UNEXEC_OBJ)
1032
1033 C_SWITCH_SYSTEM=
1034 ## Some programs in src produce warnings saying certain subprograms
1035 ## are too complex and need a MAXMEM value greater than 2000 for
1036 ## additional optimization.  --nils@exp-math.uni-essen.de
1037 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1038   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1039 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1040 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1041 AC_SUBST(C_SWITCH_SYSTEM)
1042
1043
1044 LIBS_SYSTEM=
1045 case "$opsys" in
1046   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1047   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1048
1049   freebsd) LIBS_SYSTEM="-lutil" ;;
1050
1051   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1052
1053   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1054
1055   ## Motif needs -lgen.
1056   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1057 esac
1058 AC_SUBST(LIBS_SYSTEM)
1059
1060
1061 ### Make sure subsequent tests use flags consistent with the build flags.
1062
1063 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1064   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1065 else
1066   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1067 fi
1068
1069 dnl For AC_FUNC_GETLOADAVG, at least:
1070 AC_CONFIG_LIBOBJ_DIR(src)
1071
1072 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1073 AC_SYS_LARGEFILE
1074
1075
1076 ## If user specified a crt-dir, use that unconditionally.
1077 if test "X$CRT_DIR" = "X"; then
1078
1079   case "$canonical" in
1080     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1081     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1082     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1083     ## For anything else (eg /usr/lib32), it is up the user to specify
1084     ## the location (bug#5655).
1085     ## Test for crtn.o, not just the directory, because sometimes the
1086     ## directory exists but does not have the relevant files (bug#1287).
1087     ## FIXME better to test for binary compatibility somehow.
1088     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1089     ;;
1090
1091     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1092   esac
1093
1094   case "$opsys" in
1095     hpux10-20) CRT_DIR=/lib ;;
1096   esac
1097
1098   ## Default is /usr/lib.
1099   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1100
1101 else
1102
1103   ## Some platforms don't use any of these files, so it is not
1104   ## appropriate to put this test outside the if block.
1105   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1106     AC_MSG_ERROR([crt*.o not found in specified location.])
1107
1108 fi
1109
1110 AC_SUBST(CRT_DIR)
1111
1112 LIB_MATH=-lm
1113 LIB_STANDARD=
1114 START_FILES=
1115
1116 case $opsys in
1117   cygwin )
1118     LIB_MATH=
1119     START_FILES='ecrt0.o'
1120     ;;
1121   darwin )
1122     ## Adding -lm confuses the dynamic linker, so omit it.
1123     LIB_MATH=
1124     START_FILES='pre-crt0.o'
1125     ;;
1126   freebsd )
1127     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1128     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1129     ;;
1130   gnu-linux | gnu-kfreebsd )
1131     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1132     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1133     ;;
1134   hpux10-20 | hpux11 )
1135     LIB_STANDARD=-lc
1136     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1137     ;;
1138   netbsd | openbsd )
1139     if test -f $CRT_DIR/crti.o; then
1140         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1141         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1142     else
1143         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1144         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1145     fi
1146     ;;
1147 esac
1148
1149 AC_SUBST(LIB_MATH)
1150 AC_SUBST(START_FILES)
1151
1152 dnl This function definition taken from Gnome 2.0
1153 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1154 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1155 dnl also defines GSTUFF_PKG_ERRORS on error
1156 AC_DEFUN([PKG_CHECK_MODULES], [
1157   succeeded=no
1158
1159   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1160
1161   if test "$PKG_CONFIG" = "no" ; then
1162      ifelse([$4], , [AC_MSG_ERROR([
1163       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1164   else
1165      PKG_CONFIG_MIN_VERSION=0.9.0
1166      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1167         AC_MSG_CHECKING(for $2)
1168
1169         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1170             AC_MSG_RESULT(yes)
1171             succeeded=yes
1172
1173             AC_MSG_CHECKING($1_CFLAGS)
1174             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1175             AC_MSG_RESULT($$1_CFLAGS)
1176
1177             AC_MSG_CHECKING($1_LIBS)
1178             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1179             AC_MSG_RESULT($$1_LIBS)
1180         else
1181             AC_MSG_RESULT(no)
1182             $1_CFLAGS=""
1183             $1_LIBS=""
1184             ## If we have a custom action on failure, don't print errors, but
1185             ## do set a variable so people can do so.
1186             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1187             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1188         fi
1189
1190         AC_SUBST($1_CFLAGS)
1191         AC_SUBST($1_LIBS)
1192      else
1193         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1194         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1195      fi
1196   fi
1197
1198   if test $succeeded = yes; then
1199      ifelse([$3], , :, [$3])
1200   else
1201      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1202   fi
1203 ])
1204
1205
1206 if test "${with_sound}" != "no"; then
1207   # Sound support for GNU/Linux and the free BSDs.
1208   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1209   # Emulation library used on NetBSD.
1210   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1211   AC_SUBST(LIBSOUND)
1212
1213   ALSA_REQUIRED=1.0.0
1214   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1215   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1216   if test $HAVE_ALSA = yes; then
1217     SAVE_CFLAGS="$CFLAGS"
1218     SAVE_LDFLAGS="$LDFLAGS"
1219     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1220     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1221     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1222                     emacs_alsa_normal=yes,
1223                     emacs_alsa_normal=no)
1224     if test "$emacs_alsa_normal" != yes; then
1225       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1226                      [snd_lib_error_set_handler (0);],
1227                      emacs_alsa_subdir=yes,
1228                      emacs_alsa_subdir=no)
1229       if test "$emacs_alsa_subdir" != yes; then
1230         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1231       fi
1232       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1233     fi
1234
1235     CFLAGS="$SAVE_CFLAGS"
1236     LDFLAGS="$SAVE_LDFLAGS"
1237     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1238     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1239     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1240   fi
1241   AC_SUBST(CFLAGS_SOUND)
1242 fi
1243
1244 dnl checks for header files
1245 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1246   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1247   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1248   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1249   sys/utsname.h pwd.h utmp.h)
1250
1251 AC_MSG_CHECKING(if personality LINUX32 can be set)
1252 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1253                emacs_cv_personality_linux32=yes,
1254                emacs_cv_personality_linux32=no)
1255 AC_MSG_RESULT($emacs_cv_personality_linux32)
1256
1257 if test $emacs_cv_personality_linux32 = yes; then
1258   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1259             [Define to 1 if personality LINUX32 can be set.])
1260 fi
1261
1262 dnl On Solaris 8 there's a compilation warning for term.h because
1263 dnl it doesn't define `bool'.
1264 AC_CHECK_HEADERS(term.h, , , -)
1265 AC_HEADER_STDC
1266 AC_HEADER_TIME
1267 AC_CHECK_DECLS([sys_siglist])
1268 if test $ac_cv_have_decl_sys_siglist != yes; then
1269   # For Tru64, at least:
1270   AC_CHECK_DECLS([__sys_siglist])
1271   if test $ac_cv_have_decl___sys_siglist = yes; then
1272     AC_DEFINE(sys_siglist, __sys_siglist,
1273               [Define to any substitute for sys_siglist.])
1274   fi
1275 fi
1276 AC_HEADER_SYS_WAIT
1277
1278 dnl Some systems have utime.h but don't declare the struct anyplace.
1279 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1280 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1281 #include <sys/time.h>
1282 #include <time.h>
1283 #else
1284 #ifdef HAVE_SYS_TIME_H
1285 #include <sys/time.h>
1286 #else
1287 #include <time.h>
1288 #endif
1289 #endif
1290 #ifdef HAVE_UTIME_H
1291 #include <utime.h>
1292 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1293   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1294 if test $emacs_cv_struct_utimbuf = yes; then
1295   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1296 fi
1297
1298 dnl checks for typedefs
1299 AC_TYPE_SIGNAL
1300
1301 dnl Check for speed_t typedef.
1302 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1303   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1304     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1305 if test $emacs_cv_speed_t = yes; then
1306   AC_DEFINE(HAVE_SPEED_T, 1,
1307            [Define to 1 if `speed_t' is declared by <termios.h>.])
1308 fi
1309
1310 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1311 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1312 #include <sys/time.h>
1313 #include <time.h>
1314 #else
1315 #ifdef HAVE_SYS_TIME_H
1316 #include <sys/time.h>
1317 #else
1318 #include <time.h>
1319 #endif
1320 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1321   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1322 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1323 if test $emacs_cv_struct_timeval = yes; then
1324   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1325 fi
1326
1327 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1328 AC_TRY_COMPILE([#include <math.h>],
1329 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1330   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1331 HAVE_EXCEPTION=$emacs_cv_struct_exception
1332 if test $emacs_cv_struct_exception != yes; then
1333   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1334 fi
1335
1336 AC_CHECK_HEADERS(sys/socket.h)
1337 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1338 #if HAVE_SYS_SOCKET_H
1339 #include <sys/socket.h>
1340 #endif])
1341
1342 dnl checks for structure members
1343 AC_STRUCT_TM
1344 AC_STRUCT_TIMEZONE
1345 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1346                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1347                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1348                 [#include <time.h>])
1349 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1350                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1351                   struct ifreq.ifr_addr], , ,
1352                  [AC_INCLUDES_DEFAULT
1353 #if HAVE_SYS_SOCKET_H
1354 #include <sys/socket.h>
1355 #endif
1356 #if HAVE_NET_IF_H
1357 #include <net/if.h>
1358 #endif])
1359
1360 dnl checks for compiler characteristics
1361
1362 dnl Testing __STDC__ to determine prototype support isn't good enough.
1363 dnl DEC C, for instance, doesn't define it with default options, and
1364 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1365 dnl and void *.
1366 AC_C_PROTOTYPES
1367 AC_C_VOLATILE
1368 AC_C_CONST
1369 dnl This isn't useful because we can't turn on use of `inline' unless
1370 dnl the compiler groks `extern inline'.
1371 dnl AC_C_INLINE
1372 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1373   [AC_TRY_COMPILE(, [void * foo;],
1374                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1375 if test $emacs_cv_void_star = yes; then
1376   AC_DEFINE(POINTER_TYPE, void)
1377 else
1378   AC_DEFINE(POINTER_TYPE, char)
1379 fi
1380 AH_TEMPLATE(POINTER_TYPE,
1381             [Define as `void' if your compiler accepts `void *'; otherwise
1382              define as `char'.])dnl
1383
1384
1385
1386 dnl This could be used for targets which can have both byte sexes.
1387 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1388 dnl AC_C_BIGENDIAN
1389
1390 dnl check for Make feature
1391 AC_PROG_MAKE_SET
1392
1393 DEPFLAGS=
1394 MKDEPDIR=":"
1395 deps_frag=deps.mk
1396 dnl check for GNU Make if we have GCC and autodepend is on.
1397 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1398    AC_MSG_CHECKING([whether we are using GNU Make])
1399    HAVE_GNU_MAKE=no
1400    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1401    if test "x$testval" != x; then
1402       HAVE_GNU_MAKE=yes
1403    else
1404       ac_enable_autodepend=no
1405    fi
1406    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1407    if test $HAVE_GNU_MAKE = yes; then
1408       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1409       SAVE_CFLAGS="$CFLAGS"
1410       CFLAGS="$CFLAGS -MMD -MF deps.d"
1411       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1412       CFLAGS="$SAVE_CFLAGS"
1413       test -f deps.d || ac_enable_autodepend=no
1414       rm -rf deps.d
1415       AC_MSG_RESULT([$ac_enable_autodepend])
1416    fi
1417    if test $ac_enable_autodepend = yes; then
1418       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1419       ## In parallel builds, another make might create depdir between
1420       ## the first test and mkdir, so stick another test on the end.
1421       ## Or use mkinstalldirs?  mkdir -p is not portable.
1422       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1423       deps_frag=autodeps.mk
1424    fi
1425 fi
1426 deps_frag=$srcdir/src/$deps_frag
1427 AC_SUBST(MKDEPDIR)
1428 AC_SUBST(DEPFLAGS)
1429 AC_SUBST_FILE(deps_frag)
1430
1431
1432 dnl checks for operating system services
1433 AC_SYS_LONG_FILE_NAMES
1434
1435 #### Choose a window system.
1436
1437 AC_PATH_X
1438 if test "$no_x" = yes; then
1439   window_system=none
1440 else
1441   window_system=x11
1442 fi
1443
1444 ## Workaround for bug in autoconf <= 2.62.
1445 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1446 ## No need to do anything special for these standard directories.
1447 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1448
1449    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1450
1451 fi
1452
1453 LD_SWITCH_X_SITE_AUX=
1454 LD_SWITCH_X_SITE_AUX_RPATH=
1455 if test "${x_libraries}" != NONE; then
1456   if test -n "${x_libraries}"; then
1457     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1458     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1459     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1460   fi
1461   x_default_search_path=""
1462   x_search_path=${x_libraries}
1463   if test -z "${x_search_path}"; then
1464     x_search_path=/usr/lib
1465   fi
1466   for x_library in `echo ${x_search_path}: | \
1467                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1468     x_search_path="\
1469 ${x_library}/X11/%L/%T/%N%C%S:\
1470 ${x_library}/X11/%l/%T/%N%C%S:\
1471 ${x_library}/X11/%T/%N%C%S:\
1472 ${x_library}/X11/%L/%T/%N%S:\
1473 ${x_library}/X11/%l/%T/%N%S:\
1474 ${x_library}/X11/%T/%N%S"
1475     if test x"${x_default_search_path}" = x; then
1476       x_default_search_path=${x_search_path}
1477     else
1478       x_default_search_path="${x_search_path}:${x_default_search_path}"
1479     fi
1480   done
1481 fi
1482 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1483 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1484
1485 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1486   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1487 fi
1488
1489 if test x"${x_includes}" = x; then
1490   bitmapdir=/usr/include/X11/bitmaps
1491 else
1492   # accumulate include directories that have X11 bitmap subdirectories
1493   bmd_acc="dummyval"
1494   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1495     if test -d "${bmd}/X11/bitmaps"; then
1496       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1497     fi
1498     if test -d "${bmd}/bitmaps"; then
1499       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1500     fi
1501   done
1502   if test ${bmd_acc} != "dummyval"; then
1503     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1504   fi
1505 fi
1506
1507 HAVE_NS=no
1508 NS_IMPL_COCOA=no
1509 NS_IMPL_GNUSTEP=no
1510 tmp_CPPFLAGS="$CPPFLAGS"
1511 tmp_CFLAGS="$CFLAGS"
1512 CPPFLAGS="$CPPFLAGS -x objective-c"
1513 CFLAGS="$CFLAGS -x objective-c"
1514 TEMACS_LDFLAGS2="\${LDFLAGS}"
1515 dnl I don't think it's especially important, but src/Makefile.in
1516 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1517 dnl trailing "/" to it, so now we do it here.
1518 if test "${with_ns}" != no; then
1519   if test "${opsys}" = darwin; then
1520      NS_IMPL_COCOA=yes
1521      ns_appdir=`pwd`/nextstep/Emacs.app/
1522      ns_appbindir=${ns_appdir}Contents/MacOS/
1523      ns_appresdir=${ns_appdir}Contents/Resources
1524      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1525   elif test -f $GNUSTEP_CONFIG_FILE; then
1526      NS_IMPL_GNUSTEP=yes
1527      ns_appdir=`pwd`/nextstep/Emacs.app/
1528      ns_appbindir=${ns_appdir}
1529      ns_appresdir=${ns_appdir}Resources
1530      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1531      dnl FIXME sourcing this several times in subshells seems inefficient.
1532      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1533      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1534      dnl I seemed to need these as well with GNUstep-startup 0.25.
1535      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1536      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1537      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1538        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1539      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1540        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1541      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1542      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1543      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1544      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1545      LIB_STANDARD=
1546      START_FILES=
1547      TEMACS_LDFLAGS2=
1548   fi
1549   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1550                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1551   files are missing or cannot be compiled.])])
1552   NS_HAVE_NSINTEGER=yes
1553   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1554                                      [NSInteger i;])],
1555                     ns_have_nsinteger=yes,
1556                     ns_have_nsinteger=no)
1557   if test $ns_have_nsinteger = no; then
1558     NS_HAVE_NSINTEGER=no
1559   fi
1560 fi
1561 AC_SUBST(TEMACS_LDFLAGS2)
1562
1563 ns_frag=/dev/null
1564 NS_OBJ=
1565 NS_SUPPORT=
1566 if test "${HAVE_NS}" = yes; then
1567   window_system=nextstep
1568   with_xft=no
1569   # set up packaging dirs
1570   exec_prefix=${ns_appbindir}
1571   libexecdir=${ns_appbindir}/libexec
1572   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1573      prefix=${ns_appresdir}
1574   fi
1575   ns_frag=$srcdir/src/ns.mk
1576   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1577   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1578 fi
1579 CFLAGS="$tmp_CFLAGS"
1580 CPPFLAGS="$tmp_CPPFLAGS"
1581 AC_SUBST(NS_OBJ)
1582 AC_SUBST(NS_SUPPORT)
1583 AC_SUBST(LIB_STANDARD)
1584 AC_SUBST_FILE(ns_frag)
1585
1586 case "${window_system}" in
1587   x11 )
1588     HAVE_X_WINDOWS=yes
1589     HAVE_X11=yes
1590     case "${with_x_toolkit}" in
1591       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1592       motif ) USE_X_TOOLKIT=MOTIF ;;
1593       gtk ) with_gtk=yes
1594 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1595 dnl USE_X_TOOLKIT is set.
1596             USE_X_TOOLKIT=none ;;
1597       no ) USE_X_TOOLKIT=none ;;
1598 dnl If user did not say whether to use a toolkit, make this decision later:
1599 dnl use the toolkit if we have gtk, or X11R5 or newer.
1600       * ) USE_X_TOOLKIT=maybe ;;
1601     esac
1602   ;;
1603   nextstep | none )
1604     HAVE_X_WINDOWS=no
1605     HAVE_X11=no
1606     USE_X_TOOLKIT=none
1607   ;;
1608 esac
1609
1610 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1611    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1612    if test "$HAVE_XSERVER" = true ||
1613       test -n "$DISPLAY" ||
1614       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1615         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1616 were found.  You should install the relevant development files for X
1617 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1618 sure you have development files for image handling, i.e.
1619 tiff, gif, jpeg, png and xpm.
1620 If you are sure you want Emacs compiled without X window support, pass
1621   --without-x
1622 to configure.])
1623    fi
1624 fi
1625
1626 ### If we're using X11, we should use the X menu package.
1627 HAVE_MENUS=no
1628 case ${HAVE_X11} in
1629   yes ) HAVE_MENUS=yes ;;
1630 esac
1631
1632 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1633 # Assume not, until told otherwise.
1634 GNU_MALLOC=yes
1635 doug_lea_malloc=yes
1636 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1637 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1638 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1639                emacs_cv_var___after_morecore_hook,
1640 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1641   emacs_cv_var___after_morecore_hook=yes,
1642   emacs_cv_var___after_morecore_hook=no)])
1643 if test $emacs_cv_var___after_morecore_hook = no; then
1644   doug_lea_malloc=no
1645 fi
1646
1647 if test "${system_malloc}" = "yes"; then
1648   GNU_MALLOC=no
1649   GNU_MALLOC_reason="
1650     (The GNU allocators don't work with this system configuration.)"
1651   GMALLOC_OBJ=
1652   VMLIMIT_OBJ=
1653 else
1654   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1655   VMLIMIT_OBJ=vm-limit.o
1656 fi
1657 AC_SUBST(GMALLOC_OBJ)
1658 AC_SUBST(VMLIMIT_OBJ)
1659
1660 if test "$doug_lea_malloc" = "yes" ; then
1661   if test "$GNU_MALLOC" = yes ; then
1662     GNU_MALLOC_reason="
1663       (Using Doug Lea's new malloc from the GNU C Library.)"
1664   fi
1665   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1666             [Define to 1 if you are using the GNU C Library.])
1667
1668   ## Use mmap directly for allocating larger buffers.
1669   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1670   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1671   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1672   case "$opsys" in
1673     gnu*) REL_ALLOC=no ;;
1674   esac
1675 fi
1676
1677 if test x"${REL_ALLOC}" = x; then
1678   REL_ALLOC=${GNU_MALLOC}
1679 fi
1680
1681 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1682 dnl the system configuration file (s/*.h) to turn the use of mmap
1683 dnl in the relocating allocator on.
1684
1685 AC_FUNC_MMAP
1686 if test $use_mmap_for_buffers = yes; then
1687   REL_ALLOC=no
1688 fi
1689
1690 LIBS="$LIBS_SYSTEM $LIBS"
1691
1692 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1693 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1694 AC_CHECK_LIB(dnet, dnet_ntoa)
1695 dnl This causes -lresolv to get used in subsequent tests,
1696 dnl which causes failures on some systems such as HPUX 9.
1697 dnl AC_CHECK_LIB(resolv, gethostbyname)
1698
1699 dnl FIXME replace main with a function we actually want from this library.
1700 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1701
1702 AC_CHECK_LIB(pthreads, cma_open)
1703
1704 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1705 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1706 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1707 ## added to LIBS in configure would never contain the pthreads part,
1708 ## but the value used in Makefiles might.  FIXME?
1709 ##
1710 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1711 ## be harmless on older versions of X where it happens to exist.
1712 test "$opsys" = "aix4-2" && \
1713   test $ac_cv_lib_pthreads_cma_open = yes && \
1714   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1715
1716 dnl Check for need for bigtoc support on IBM AIX
1717
1718 case ${host_os} in
1719 aix*)
1720   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1721     case $GCC in
1722     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1723     *) gdb_cv_bigtoc=-bbigtoc ;;
1724     esac
1725
1726     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1727     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1728   ])
1729   ;;
1730 esac
1731
1732 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1733 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1734 # REAL_CPPFLAGS later on.
1735
1736 REAL_CPPFLAGS="$CPPFLAGS"
1737
1738 if test "${HAVE_X11}" = "yes"; then
1739   DEFS="$C_SWITCH_X_SITE $DEFS"
1740   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1741   LIBS="$LIBX $LIBS"
1742   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1743   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1744
1745   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1746   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1747   # but it's more convenient here to set LD_RUN_PATH
1748   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1749   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1750     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1751     export LD_RUN_PATH
1752   fi
1753
1754   if test "${opsys}" = "gnu-linux"; then
1755     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1756     AC_TRY_LINK([],
1757      [XOpenDisplay ("foo");],
1758      [xlinux_first_failure=no],
1759      [xlinux_first_failure=yes])
1760     if test "${xlinux_first_failure}" = "yes"; then
1761       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1762       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1763       OLD_CPPFLAGS="$CPPFLAGS"
1764       OLD_LIBS="$LIBS"
1765       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1766       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1767       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1768       LIBS="$LIBS -b i486-linuxaout"
1769       AC_TRY_LINK([],
1770        [XOpenDisplay ("foo");],
1771        [xlinux_second_failure=no],
1772        [xlinux_second_failure=yes])
1773       if test "${xlinux_second_failure}" = "yes"; then
1774         # If we get the same failure with -b, there is no use adding -b.
1775         # So take it out.  This plays safe.
1776         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1777         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1778         CPPFLAGS="$OLD_CPPFLAGS"
1779         LIBS="$OLD_LIBS"
1780         AC_MSG_RESULT(no)
1781       else
1782         AC_MSG_RESULT(yes)
1783       fi
1784     else
1785       AC_MSG_RESULT(no)
1786     fi
1787   fi
1788
1789   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1790   # header files included from there.
1791   AC_MSG_CHECKING(for Xkb)
1792   AC_TRY_LINK([#include <X11/Xlib.h>
1793 #include <X11/XKBlib.h>],
1794         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1795         emacs_xkb=yes, emacs_xkb=no)
1796   AC_MSG_RESULT($emacs_xkb)
1797   if test $emacs_xkb = yes; then
1798     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1799   fi
1800
1801   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1802 XScreenNumberOfScreen XSetWMProtocols)
1803 fi
1804
1805 if test "${window_system}" = "x11"; then
1806   AC_MSG_CHECKING(X11 version 6)
1807   AC_CACHE_VAL(emacs_cv_x11_version_6,
1808   [AC_TRY_LINK([#include <X11/Xlib.h>],
1809 [#if XlibSpecificationRelease < 6
1810 fail;
1811 #endif
1812 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1813   if test $emacs_cv_x11_version_6 = yes; then
1814     AC_MSG_RESULT(6 or newer)
1815     AC_DEFINE(HAVE_X11R6, 1,
1816               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1817   else
1818     AC_MSG_RESULT(before 6)
1819   fi
1820 fi
1821
1822
1823 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1824 HAVE_RSVG=no
1825 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1826   if test "${with_rsvg}" != "no"; then
1827     RSVG_REQUIRED=2.11.0
1828     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1829
1830     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1831     AC_SUBST(RSVG_CFLAGS)
1832     AC_SUBST(RSVG_LIBS)
1833
1834     if test ".${RSVG_CFLAGS}" != "."; then
1835       HAVE_RSVG=yes
1836       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1837       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1838       LIBS="$RSVG_LIBS $LIBS"
1839     fi
1840   fi
1841 fi
1842
1843
1844 HAVE_GTK=no
1845 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1846   GLIB_REQUIRED=2.6
1847   GTK_REQUIRED=2.6
1848   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1849
1850   dnl Checks for libraries.
1851   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1852   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1853      AC_MSG_ERROR($GTK_PKG_ERRORS)
1854   fi
1855 fi
1856
1857
1858 GTK_OBJ=
1859 if test x"$pkg_check_gtk" = xyes; then
1860
1861   AC_SUBST(GTK_CFLAGS)
1862   AC_SUBST(GTK_LIBS)
1863   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1864   CFLAGS="$CFLAGS $GTK_CFLAGS"
1865   LIBS="$GTK_LIBS $LIBS"
1866   dnl Try to compile a simple GTK program.
1867   GTK_COMPILES=no
1868   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1869   if test "${GTK_COMPILES}" != "yes"; then
1870     if test "$USE_X_TOOLKIT" != "maybe"; then
1871       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1872     fi
1873   else
1874     HAVE_GTK=yes
1875     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1876     GTK_OBJ=gtkutil.o
1877     USE_X_TOOLKIT=none
1878     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1879       :
1880     else
1881       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1882        closing open displays.  This is no problem if you just use
1883        one display, but if you use more than one and close one of them
1884        Emacs may crash.]])
1885       sleep 3
1886     fi
1887   fi
1888
1889 fi
1890 AC_SUBST(GTK_OBJ)
1891
1892
1893 if test "${HAVE_GTK}" = "yes"; then
1894
1895   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1896   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1897   if test "$with_toolkit_scroll_bars" != no; then
1898     with_toolkit_scroll_bars=yes
1899   fi
1900
1901   dnl  Check if we can use multiple displays with this GTK version.
1902   dnl  If gdk_display_open exists, assume all others are there also.
1903   HAVE_GTK_MULTIDISPLAY=no
1904   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1905   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1906     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1907               [Define to 1 if GTK can handle more than one display.])
1908   fi
1909
1910   dnl  Check if we have the old file selection dialog declared and
1911   dnl  in the link library.  In 2.x it may be in the library,
1912   dnl  but not declared if deprecated featured has been selected out.
1913   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1914   HAVE_GTK_FILE_SELECTION=no
1915   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1916                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1917 #include <gtk/gtk.h>])
1918   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1919     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1920                    HAVE_GTK_FILE_SELECTION=no)
1921   fi
1922
1923   dnl  Check if we have the new file chooser dialog
1924   HAVE_GTK_FILE_CHOOSER=no
1925   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1926                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1927 #include <gtk/gtk.h>])
1928   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1929     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1930                    HAVE_GTK_FILE_CHOOSER=no)
1931   fi
1932
1933   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1934      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1935     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1936               [Define to 1 if GTK has both file selection and chooser dialog.])
1937   fi
1938
1939   dnl Check if pthreads are available.  Emacs only needs this when using
1940   dnl gtk_file_chooser under Gnome.
1941   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1942     HAVE_GTK_AND_PTHREAD=no
1943     AC_CHECK_HEADERS(pthread.h)
1944     if test "$ac_cv_header_pthread_h"; then
1945       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1946     fi
1947     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1948       case "${canonical}" in
1949         *-hpux*) ;;
1950         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1951       esac
1952       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1953                [Define to 1 if you have GTK and pthread (-lpthread).])
1954     fi
1955   fi
1956 fi
1957
1958 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1959 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1960 dnl also not configured.
1961 HAVE_DBUS=no
1962 DBUS_OBJ=
1963 if test "${with_dbus}" = "yes"; then
1964    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1965    if test "$HAVE_DBUS" = yes; then
1966      LIBS="$LIBS $DBUS_LIBS"
1967      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1968      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1969      DBUS_OBJ=dbusbind.o
1970    fi
1971 fi
1972 AC_SUBST(DBUS_OBJ)
1973
1974 dnl GConf has been tested under GNU/Linux only.
1975 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1976 HAVE_GCONF=no
1977 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1978    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1979    if test "$HAVE_GCONF" = yes; then
1980       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1981    fi
1982 fi
1983
1984 dnl SELinux is available for GNU/Linux only.
1985 HAVE_LIBSELINUX=no
1986 LIBSELINUX_LIBS=
1987 if test "${with_selinux}" = "yes"; then
1988    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1989    if test "$HAVE_LIBSELINUX" = yes; then
1990       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1991       LIBSELINUX_LIBS=-lselinux
1992    fi
1993 fi
1994 AC_SUBST(LIBSELINUX_LIBS)
1995
1996 dnl Do not put whitespace before the #include statements below.
1997 dnl Older compilers (eg sunos4 cc) choke on it.
1998 HAVE_XAW3D=no
1999 LUCID_LIBW=
2000 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2001   if test "$with_xaw3d" != no; then
2002     AC_MSG_CHECKING(for xaw3d)
2003     AC_CACHE_VAL(emacs_cv_xaw3d,
2004     [AC_TRY_LINK([
2005 #include <X11/Intrinsic.h>
2006 #include <X11/Xaw3d/Simple.h>],
2007       [],
2008       emacs_cv_xaw3d=yes,
2009       emacs_cv_xaw3d=no)])
2010   else
2011     emacs_cv_xaw3d=no
2012   fi
2013   if test $emacs_cv_xaw3d = yes; then
2014     AC_MSG_RESULT([yes; using Lucid toolkit])
2015     USE_X_TOOLKIT=LUCID
2016     HAVE_XAW3D=yes
2017     LUCID_LIBW=-lXaw3d
2018     AC_DEFINE(HAVE_XAW3D, 1,
2019               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2020   else
2021     AC_MSG_RESULT(no)
2022     AC_MSG_CHECKING(for libXaw)
2023     AC_CACHE_VAL(emacs_cv_xaw,
2024     [AC_TRY_LINK([
2025 #include <X11/Intrinsic.h>
2026 #include <X11/Xaw/Simple.h>],
2027       [],
2028       emacs_cv_xaw=yes,
2029       emacs_cv_xaw=no)])
2030     if test $emacs_cv_xaw = yes; then
2031       AC_MSG_RESULT([yes; using Lucid toolkit])
2032       USE_X_TOOLKIT=LUCID
2033       LUCID_LIBW=-lXaw
2034     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2035       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2036     else
2037       AC_MSG_RESULT([no; do not use toolkit by default])
2038       USE_X_TOOLKIT=none
2039     fi
2040   fi
2041 fi
2042
2043 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2044
2045 LIBXTR6=
2046 if test "${USE_X_TOOLKIT}" != "none"; then
2047   AC_MSG_CHECKING(X11 toolkit version)
2048   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2049   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2050 [#if XtSpecificationRelease < 6
2051 fail;
2052 #endif
2053 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2054   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2055   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2056     AC_MSG_RESULT(6 or newer)
2057     AC_DEFINE(HAVE_X11XTR6, 1,
2058               [Define to 1 if you have the X11R6 or newer version of Xt.])
2059     LIBXTR6="-lSM -lICE"
2060     case "$opsys" in
2061       ## Use libw.a along with X11R6 Xt.
2062       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2063     esac
2064   else
2065     AC_MSG_RESULT(before 6)
2066   fi
2067
2068 dnl If using toolkit, check whether libXmu.a exists.
2069 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2070   OLDLIBS="$LIBS"
2071   if test x$HAVE_X11XTR6 = xyes; then
2072     LIBS="-lXt -lSM -lICE $LIBS"
2073   else
2074     LIBS="-lXt $LIBS"
2075   fi
2076   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2077   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2078 fi
2079 AC_SUBST(LIBXTR6)
2080
2081 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2082 dnl Why not just test for libxmu in the normal way?
2083 LIBXMU=-lXmu
2084 case "$machine" in
2085   ## These machines don't supply Xmu.
2086   hpux* | aix4-2 )
2087     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2088     ;;
2089 esac
2090 AC_SUBST(LIBXMU)
2091
2092 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2093 if test "${HAVE_X11}" = "yes"; then
2094   if test "${USE_X_TOOLKIT}" != "none"; then
2095     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2096   fi
2097 fi
2098
2099 LIBXP=
2100 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2101   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2102   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2103     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2104 int x = 5;
2105 #else
2106 Motif version prior to 2.1.
2107 #endif],
2108     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2109   if test $emacs_cv_motif_version_2_1 = yes; then
2110     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2111   else
2112     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2113     # We put this in CFLAGS temporarily to precede other -I options
2114     # that might be in CFLAGS temporarily.
2115     # We put this in CPPFLAGS where it precedes the other -I options.
2116     OLD_CPPFLAGS=$CPPFLAGS
2117     OLD_CFLAGS=$CFLAGS
2118     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2119     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2120     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2121       [int x = 5;],
2122       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2123     if test $emacs_cv_lesstif = yes; then
2124       # Make sure this -I option remains in CPPFLAGS after it is set
2125       # back to REAL_CPPFLAGS.
2126       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2127       # have those other -I options anyway.  Ultimately, having this
2128       # directory ultimately in CPPFLAGS will be enough.
2129       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2130       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2131     else
2132       CFLAGS=$OLD_CFLAGS
2133       CPPFLAGS=$OLD_CPPFLAGS
2134     fi
2135   fi
2136 fi
2137
2138 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2139 dnl using Motif or Xaw3d is available, and unless
2140 dnl --with-toolkit-scroll-bars=no was specified.
2141
2142 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2143             [Define to 1 if we should use toolkit scroll bars.])dnl
2144 USE_TOOLKIT_SCROLL_BARS=no
2145 if test "${with_toolkit_scroll_bars}" != "no"; then
2146   if test "${USE_X_TOOLKIT}" != "none"; then
2147     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2148       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2149       HAVE_XAW3D=no
2150       USE_TOOLKIT_SCROLL_BARS=yes
2151     elif test "${HAVE_XAW3D}" = "yes"; then
2152       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2153       USE_TOOLKIT_SCROLL_BARS=yes
2154     fi
2155   elif test "${HAVE_GTK}" = "yes"; then
2156     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2157     USE_TOOLKIT_SCROLL_BARS=yes
2158   elif test "${HAVE_NS}" = "yes"; then
2159     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2160     USE_TOOLKIT_SCROLL_BARS=yes
2161   fi
2162 fi
2163
2164 dnl See if XIM is available.
2165 AC_TRY_COMPILE([
2166           #include <X11/Xlib.h>
2167           #include <X11/Xresource.h>],
2168          [XIMProc  callback;],
2169          [HAVE_XIM=yes
2170          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2171          HAVE_XIM=no)
2172
2173 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2174
2175 if test "${with_xim}" != "no"; then
2176   AC_DEFINE(USE_XIM, 1,
2177             [Define to 1 if we should use XIM, if it is available.])
2178 fi
2179
2180
2181 if test "${HAVE_XIM}" != "no"; then
2182   late_CFLAGS=$CFLAGS
2183   if test "$GCC" = yes; then
2184     CFLAGS="$CFLAGS --pedantic-errors"
2185   fi
2186   AC_TRY_COMPILE([
2187 #include <X11/Xlib.h>
2188 #include <X11/Xresource.h>],
2189 [Display *display;
2190 XrmDatabase db;
2191 char *res_name;
2192 char *res_class;
2193 XIMProc  callback;
2194 XPointer *client_data;
2195 #ifndef __GNUC__
2196 /* If we're not using GCC, it's probably not XFree86, and this is
2197    probably right, but we can't use something like --pedantic-errors.  */
2198 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2199                                            char*, XIMProc, XPointer*);
2200 #endif
2201 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2202    client_data);],
2203     [emacs_cv_arg6_star=yes])
2204   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2205          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2206 either XPointer or XPointer*.])dnl
2207   if test "$emacs_cv_arg6_star" = yes; then
2208     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2209   else
2210     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2211   fi
2212   CFLAGS=$late_CFLAGS
2213 fi
2214
2215 ### Start of font-backend (under any platform) section.
2216 # (nothing here yet -- this is a placeholder)
2217 ### End of font-backend (under any platform) section.
2218
2219 ### Start of font-backend (under X11) section.
2220 if test "${HAVE_X11}" = "yes"; then
2221    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2222
2223    ## Use -lXft if available, unless `--with-xft=no'.
2224    HAVE_XFT=maybe
2225     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2226       with_xft="no";
2227     fi
2228     if test "x${with_xft}" != "xno"; then
2229
2230       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2231       ## Because xftfont.c uses XRenderQueryExtension, we also
2232       ## need to link to -lXrender.
2233       HAVE_XRENDER=no
2234       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2235       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2236         OLD_CPPFLAGS="$CPPFLAGS"
2237         OLD_CFLAGS="$CFLAGS"
2238         OLD_LIBS="$LIBS"
2239         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2240         CFLAGS="$CFLAGS $XFT_CFLAGS"
2241         XFT_LIBS="-lXrender $XFT_LIBS"
2242         LIBS="$XFT_LIBS $LIBS"
2243         AC_CHECK_HEADER(X11/Xft/Xft.h,
2244           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2245
2246         if test "${HAVE_XFT}" = "yes"; then
2247           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2248             AC_SUBST(XFT_LIBS)
2249           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2250         else
2251           CPPFLAGS="$OLD_CPPFLAGS"
2252           CFLAGS="$OLD_CFLAGS"
2253           LIBS="$OLD_LIBS"
2254         fi                        # "${HAVE_XFT}" = "yes"
2255       fi                          # "$HAVE_XFT" != no
2256     fi                            # "x${with_xft}" != "xno"
2257
2258     dnl For the "Does Emacs use" message at the end.
2259     if test "$HAVE_XFT" != "yes"; then
2260        HAVE_XFT=no
2261     fi
2262
2263
2264     HAVE_FREETYPE=no
2265     ## We used to allow building with FreeType and without Xft.
2266     ## However, the ftx font backend driver is not in good shape.
2267     if test "${HAVE_XFT}" = "yes"; then
2268       dnl As we use Xft, we anyway use freetype.
2269       dnl There's no need for additional CFLAGS and LIBS.
2270       HAVE_FREETYPE=yes
2271       FONTCONFIG_CFLAGS=
2272       FONTCONFIG_LIBS=
2273     fi
2274
2275     HAVE_LIBOTF=no
2276     if test "${HAVE_FREETYPE}" = "yes"; then
2277       AC_DEFINE(HAVE_FREETYPE, 1,
2278                 [Define to 1 if using the freetype and fontconfig libraries.])
2279       if test "${with_libotf}" != "no"; then
2280         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2281                           HAVE_LIBOTF=no)
2282         if test "$HAVE_LIBOTF" = "yes"; then
2283           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2284           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2285                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2286                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2287           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2288             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2289                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2290           fi
2291         fi
2292       fi
2293     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2294     dnl Does the new font backend require it, or can it work without it?
2295     fi
2296
2297     HAVE_M17N_FLT=no
2298     if test "${HAVE_LIBOTF}" = yes; then
2299       if test "${with_m17n_flt}" != "no"; then
2300         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2301         if test "$HAVE_M17N_FLT" = "yes"; then
2302           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2303         fi
2304       fi
2305     fi
2306 else
2307     HAVE_XFT=no
2308     HAVE_FREETYPE=no
2309     HAVE_LIBOTF=no
2310     HAVE_M17N_FLT=no
2311 fi
2312
2313 ### End of font-backend (under X11) section.
2314
2315 AC_SUBST(FREETYPE_CFLAGS)
2316 AC_SUBST(FREETYPE_LIBS)
2317 AC_SUBST(FONTCONFIG_CFLAGS)
2318 AC_SUBST(FONTCONFIG_LIBS)
2319 AC_SUBST(LIBOTF_CFLAGS)
2320 AC_SUBST(LIBOTF_LIBS)
2321 AC_SUBST(M17N_FLT_CFLAGS)
2322 AC_SUBST(M17N_FLT_LIBS)
2323
2324 ### Use -lXpm if available, unless `--with-xpm=no'.
2325 HAVE_XPM=no
2326 LIBXPM=
2327 if test "${HAVE_X11}" = "yes"; then
2328   if test "${with_xpm}" != "no"; then
2329     AC_CHECK_HEADER(X11/xpm.h,
2330       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2331     if test "${HAVE_XPM}" = "yes"; then
2332       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2333       AC_EGREP_CPP(no_return_alloc_pixels,
2334       [#include "X11/xpm.h"
2335 #ifndef XpmReturnAllocPixels
2336 no_return_alloc_pixels
2337 #endif
2338       ], HAVE_XPM=no, HAVE_XPM=yes)
2339
2340       if test "${HAVE_XPM}" = "yes"; then
2341         AC_MSG_RESULT(yes)
2342       else
2343         AC_MSG_RESULT(no)
2344       fi
2345     fi
2346   fi
2347
2348   if test "${HAVE_XPM}" = "yes"; then
2349     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2350     LIBXPM=-lXpm
2351   fi
2352 fi
2353 AC_SUBST(LIBXPM)
2354
2355 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2356 HAVE_JPEG=no
2357 LIBJPEG=
2358 if test "${HAVE_X11}" = "yes"; then
2359   if test "${with_jpeg}" != "no"; then
2360     dnl Checking for jpeglib.h can lose because of a redefinition of
2361     dnl  HAVE_STDLIB_H.
2362     AC_CHECK_HEADER(jerror.h,
2363       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2364   fi
2365
2366   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2367   if test "${HAVE_JPEG}" = "yes"; then
2368     AC_DEFINE(HAVE_JPEG)
2369     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2370         [#include <jpeglib.h>
2371          version=JPEG_LIB_VERSION
2372 ],
2373         [AC_DEFINE(HAVE_JPEG)],
2374         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2375         HAVE_JPEG=no])
2376   fi
2377   if test "${HAVE_JPEG}" = "yes"; then
2378     LIBJPEG=-ljpeg
2379   fi
2380 fi
2381 AC_SUBST(LIBJPEG)
2382
2383 ### Use -lpng if available, unless `--with-png=no'.
2384 HAVE_PNG=no
2385 LIBPNG=
2386 if test "${HAVE_X11}" = "yes"; then
2387   if test "${with_png}" != "no"; then
2388     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2389     # in /usr/include/libpng.
2390     AC_CHECK_HEADERS(png.h libpng/png.h)
2391     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2392       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2393     fi
2394   fi
2395
2396   if test "${HAVE_PNG}" = "yes"; then
2397     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2398     LIBPNG="-lpng -lz -lm"
2399   fi
2400 fi
2401 AC_SUBST(LIBPNG)
2402
2403 ### Use -ltiff if available, unless `--with-tiff=no'.
2404 HAVE_TIFF=no
2405 LIBTIFF=
2406 if test "${HAVE_X11}" = "yes"; then
2407   if test "${with_tiff}" != "no"; then
2408     AC_CHECK_HEADER(tiffio.h,
2409       [tifflibs="-lz -lm"
2410       # At least one tiff package requires the jpeg library.
2411       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2412       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2413   fi
2414
2415   if test "${HAVE_TIFF}" = "yes"; then
2416     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2417     dnl FIXME -lz -lm, as per libpng?
2418     LIBTIFF=-ltiff
2419   fi
2420 fi
2421 AC_SUBST(LIBTIFF)
2422
2423 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2424 HAVE_GIF=no
2425 LIBGIF=
2426 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2427   AC_CHECK_HEADER(gif_lib.h,
2428 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2429 # Earlier versions can crash Emacs.
2430     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2431
2432   if test "$HAVE_GIF" = yes; then
2433     LIBGIF=-lgif
2434   elif test "$HAVE_GIF" = maybe; then
2435 # If gif_lib.h but no libgif, try libungif.
2436     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2437     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2438   fi
2439
2440   if test "${HAVE_GIF}" = "yes"; then
2441     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2442   fi
2443 fi
2444 AC_SUBST(LIBGIF)
2445
2446 dnl Check for required libraries.
2447 if test "${HAVE_X11}" = "yes"; then
2448   MISSING=""
2449   WITH_NO=""
2450   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2451     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2452   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2453     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2454   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2455     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2456   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2457     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2458   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2459     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2460
2461   if test "X${MISSING}" != X; then
2462     AC_MSG_ERROR([The following required libraries were not found:
2463     $MISSING
2464 Maybe some development libraries/packages are missing?
2465 If you don't want to link with them give
2466     $WITH_NO
2467 as options to configure])
2468   fi
2469 fi
2470
2471 ### Use -lgpm if available, unless `--with-gpm=no'.
2472 HAVE_GPM=no
2473 LIBGPM=
2474 MOUSE_SUPPORT=
2475 if test "${with_gpm}" != "no"; then
2476   AC_CHECK_HEADER(gpm.h,
2477     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2478
2479   if test "${HAVE_GPM}" = "yes"; then
2480     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2481     LIBGPM=-lgpm
2482     ## May be reset below.
2483     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2484   fi
2485 fi
2486 AC_SUBST(LIBGPM)
2487
2488 dnl Check for malloc/malloc.h on darwin
2489 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2490
2491 C_SWITCH_X_SYSTEM=
2492 ### Use NeXTstep API to implement GUI.
2493 if test "${HAVE_NS}" = "yes"; then
2494   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2495   if test "${NS_IMPL_COCOA}" = "yes"; then
2496     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2497     GNU_OBJC_CFLAGS=
2498   fi
2499   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2500     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2501     # See also .m.o rule in Makefile.in */
2502     # FIXME: are all these flags really needed?  Document here why.  */
2503     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2504     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2505   fi
2506   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2507     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2508   fi
2509   # We also have mouse menus.
2510   HAVE_MENUS=yes
2511   OTHER_FILES=ns-app
2512 fi
2513
2514
2515 ### Use session management (-lSM -lICE) if available
2516 HAVE_X_SM=no
2517 LIBXSM=
2518 if test "${HAVE_X11}" = "yes"; then
2519   AC_CHECK_HEADER(X11/SM/SMlib.h,
2520     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2521
2522   if test "${HAVE_X_SM}" = "yes"; then
2523     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2524     LIBXSM="-lSM -lICE"
2525     case "$LIBS" in
2526       *-lSM*) ;;
2527       *)      LIBS="$LIBXSM $LIBS" ;;
2528     esac
2529   fi
2530 fi
2531 AC_SUBST(LIBXSM)
2532
2533 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2534 AC_CACHE_CHECK(whether netdb declares h_errno,
2535                emacs_cv_netdb_declares_h_errno,
2536 [AC_TRY_LINK([#include <netdb.h>],
2537   [return h_errno;],
2538   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2539 if test $emacs_cv_netdb_declares_h_errno = yes; then
2540   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2541 fi
2542
2543 AC_FUNC_ALLOCA
2544
2545 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2546 dnl FIXME is there an autoconf test that does the right thing, without
2547 dnl needing to call A_M_E afterwards?
2548 if test x"$ac_cv_func_alloca_works" != xyes; then
2549    AC_MSG_ERROR( [a system implementation of alloca is required] )
2550 fi
2551
2552 # fmod, logb, and frexp are found in -lm on most systems.
2553 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2554 AC_CHECK_LIB(m, sqrt)
2555
2556 # Check for mail-locking functions in a "mail" library.  Probably this should
2557 # have the same check as for liblockfile below.
2558 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2559 if test $have_mail = yes; then
2560   LIBS_MAIL=-lmail
2561   LIBS="$LIBS_MAIL $LIBS"
2562   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2563 else
2564   LIBS_MAIL=
2565 fi
2566 dnl Debian, at least:
2567 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2568 if test $have_lockfile = yes; then
2569    LIBS_MAIL=-llockfile
2570    LIBS="$LIBS_MAIL $LIBS"
2571    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2572 else
2573 # If we have the shared liblockfile, assume we must use it for mail
2574 # locking (e.g. Debian).  If we couldn't link against liblockfile
2575 # (no liblockfile.a installed), ensure that we don't need to.
2576   dnl This works for files generally, not just executables.
2577   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2578   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2579                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2580   if test $ac_cv_prog_liblockfile = yes; then
2581     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2582 This probably means that movemail could lose mail.
2583 There may be a `development' package to install containing liblockfile.])
2584   fi
2585 fi
2586 AC_CHECK_FUNCS(touchlock)
2587 AC_CHECK_HEADERS(maillock.h)
2588 AC_SUBST(LIBS_MAIL)
2589
2590 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2591 ## interlock access to the mail spool.  The alternative is a lock file named
2592 ## /usr/spool/mail/$USER.lock.
2593 mail_lock=no
2594 case "$opsys" in
2595   aix4-2) mail_lock="lockf" ;;
2596
2597   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2598
2599   ## On GNU/Linux systems, both methods are used by various mail programs.
2600   ## I assume most people are using newer mailers that have heard of flock.
2601   ## Change this if you need to.
2602   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2603   ## configure gets the right answers, and that means *NOT* using flock.
2604   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2605   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2606   ## Debian maintainer hasn't provided a clean fix for Emacs.
2607   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2608   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2609   ## correct logic.  -- fx
2610   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2611   ## liblockfile is a Free Software replacement for libmail, used on
2612   ## Debian systems and elsewhere. -rfr.
2613   gnu-*)
2614     mail_lock="flock"
2615     if test $have_mail = yes || test $have_lockfile = yes; then
2616       test $ac_cv_header_maillock_h = yes && mail_lock=no
2617     fi
2618     ;;
2619 esac
2620
2621 BLESSMAIL_TARGET=
2622 case "$mail_lock" in
2623   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2624
2625   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2626
2627   *) BLESSMAIL_TARGET="need-blessmail" ;;
2628 esac
2629 AC_SUBST(BLESSMAIL_TARGET)
2630
2631
2632 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2633 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2634 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2635 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2636 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2637 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2638 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2639 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2640 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2641 cfmakeraw cfsetspeed isnan copysign)
2642
2643 AC_CHECK_HEADERS(sys/un.h)
2644
2645 AC_FUNC_MKTIME
2646 if test "$ac_cv_func_working_mktime" = no; then
2647   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2648 fi
2649
2650 AC_FUNC_GETLOADAVG
2651
2652 AC_FUNC_FSEEKO
2653
2654 # Configure getopt.
2655 m4_include([m4/getopt.m4])
2656 gl_GETOPT_IFELSE([
2657   gl_GETOPT_SUBSTITUTE_HEADER
2658   gl_PREREQ_GETOPT
2659   GETOPTOBJS='getopt.o getopt1.o'
2660 ])
2661 AC_SUBST(GETOPTOBJS)
2662
2663 AC_FUNC_GETPGRP
2664
2665 AC_FUNC_STRFTIME
2666
2667 # UNIX98 PTYs.
2668 AC_CHECK_FUNCS(grantpt)
2669
2670 # PTY-related GNU extensions.
2671 AC_CHECK_FUNCS(getpt)
2672
2673 # Check this now, so that we will NOT find the above functions in ncurses.
2674 # That is because we have not set up to link ncurses in lib-src.
2675 # It's better to believe a function is not available
2676 # than to expect to find it in ncurses.
2677 # Also we need tputs and friends to be able to build at all.
2678 have_tputs_et_al=true
2679 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2680 if test "$have_tputs_et_al" != true; then
2681   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2682 Maybe some development libraries/packages are missing?  Try installing
2683 libncurses-dev(el), libterminfo-dev(el) or similar.])
2684 fi
2685 # Must define this when any termcap library is found.
2686 AC_DEFINE(HAVE_LIBNCURSES, 1,
2687           [Define to 1 if you have the `ncurses' library (-lncurses).])
2688 ## FIXME This was the cpp logic, but I am not sure it is right.
2689 ## The above test has not necessarily found libncurses.
2690 HAVE_LIBNCURSES=yes
2691
2692 ## Use terminfo instead of termcap?
2693 ## Note only system files NOT using terminfo are:
2694 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2695 ## darwin|gnu without ncurses.
2696 TERMINFO=no
2697 LIBS_TERMCAP=
2698 case "$opsys" in
2699   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2700   ## hpux10-20: Use the system provided termcap(3) library.
2701   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2702   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2703   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2704
2705   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2706   ##  The ncurses library has been moved out of the System framework in
2707   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2708   ##  option to use it.
2709   darwin|gnu*)
2710     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2711     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2712       TERMINFO=yes
2713       LIBS_TERMCAP="-lncurses"
2714     fi
2715     ;;
2716
2717   freebsd)
2718     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2719     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2720     [AC_TRY_LINK([#include <osreldate.h>],
2721 [#if __FreeBSD_version < 400000
2722 fail;
2723 #endif
2724 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2725
2726     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2727
2728     if test $emacs_cv_freebsd_terminfo = yes; then
2729       TERMINFO=yes
2730       LIBS_TERMCAP="-lncurses"
2731     else
2732       LIBS_TERMCAP="-ltermcap"
2733     fi
2734     ;;
2735
2736   netbsd)
2737     if test $ac_cv_search_tputs = -lterminfo; then
2738       TERMINFO=yes
2739       LIBS_TERMCAP="-lterminfo"
2740     else
2741       LIBS_TERMCAP="-ltermcap"
2742     fi
2743     ;;
2744
2745 esac
2746
2747 case "$opsys" in
2748   ## hpux: Make sure we get select from libc rather than from libcurses
2749   ##  because libcurses on HPUX 10.10 has a broken version of select.
2750   ##  We used to use -lc -lcurses, but this may be cleaner.
2751   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2752
2753   openbsd) LIBS_TERMCAP="-lncurses" ;;
2754
2755   ## Must use system termcap, if we use any termcap.  It does special things.
2756   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2757 esac
2758
2759 TERMCAP_OBJ=tparam.o
2760 if test $TERMINFO = yes; then
2761   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2762
2763   ## Default used to be -ltermcap.  Add a case above if need something else.
2764   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2765
2766   TERMCAP_OBJ=terminfo.o
2767 fi
2768 AC_SUBST(LIBS_TERMCAP)
2769 AC_SUBST(TERMCAP_OBJ)
2770
2771
2772 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2773 resolv=no
2774 AC_TRY_LINK([#include <netinet/in.h>
2775 #include <arpa/nameser.h>
2776 #include <resolv.h>],
2777     [return res_init();],
2778     have_res_init=yes, have_res_init=no)
2779 if test "$have_res_init" = no; then
2780   OLIBS="$LIBS"
2781   LIBS="$LIBS -lresolv"
2782   AC_MSG_CHECKING(for res_init with -lresolv)
2783   AC_TRY_LINK([#include <netinet/in.h>
2784 #include <arpa/nameser.h>
2785 #include <resolv.h>],
2786     [return res_init();],
2787     have_res_init=yes, have_res_init=no)
2788   AC_MSG_RESULT($have_res_init)
2789   if test "$have_res_init" = yes ; then
2790     resolv=yes
2791   fi
2792   LIBS="$OLIBS"
2793 fi
2794
2795 if test "$have_res_init" = yes; then
2796   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2797 fi
2798
2799 # Do we need the Hesiod library to provide the support routines?
2800 LIBHESIOD=
2801 if test "$with_hesiod" != no ; then
2802   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2803   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2804      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2805                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2806   if test "$resolv" = yes ; then
2807     RESOLVLIB=-lresolv
2808   else
2809     RESOLVLIB=
2810   fi
2811   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2812         hesiod=yes, :, $RESOLVLIB)])
2813
2814   if test x"$hesiod" = xyes; then
2815     AC_DEFINE(HAVE_LIBHESIOD, 1,
2816               [Define to 1 if you have the hesiod library (-lhesiod).])
2817     LIBHESIOD=-lhesiod
2818   fi
2819 fi
2820 AC_SUBST(LIBHESIOD)
2821
2822 # Do we need libresolv (due to res_init or Hesiod)?
2823 if test "$resolv" = yes ; then
2824   AC_DEFINE(HAVE_LIBRESOLV, 1,
2825             [Define to 1 if you have the resolv library (-lresolv).])
2826   LIBRESOLV=-lresolv
2827 else
2828   LIBRESOLV=
2829 fi
2830 AC_SUBST(LIBRESOLV)
2831
2832 # These tell us which Kerberos-related libraries to use.
2833 COM_ERRLIB=
2834 CRYPTOLIB=
2835 KRB5LIB=
2836 DESLIB=
2837 KRB4LIB=
2838
2839 if test "${with_kerberos}" != no; then
2840   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2841   if test $have_com_err = yes; then
2842     COM_ERRLIB=-lcom_err
2843     LIBS="$COM_ERRLIB $LIBS"
2844     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2845   fi
2846   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2847   if test $have_crypto = yes; then
2848     CRYPTOLIB=-lcrypto
2849     LIBS="$CRYPTOLIB $LIBS"
2850     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2851   fi
2852   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2853   if test $have_k5crypto = yes; then
2854     CRYPTOLIB=-lk5crypto
2855     LIBS="$CRYPTOLIB $LIBS"
2856     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2857   fi
2858   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2859   if test $have_krb5=yes; then
2860     KRB5LIB=-lkrb5
2861     LIBS="$KRB5LIB $LIBS"
2862     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2863   fi
2864   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2865   if test "${with_kerberos5}" = no; then
2866     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2867     if test $have_des425 = yes; then
2868       DESLIB=-ldes425
2869       LIBS="$DESLIB $LIBS"
2870       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2871     else
2872       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2873       if test $have_des = yes; then
2874         DESLIB=-ldes
2875         LIBS="$DESLIB $LIBS"
2876         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2877       fi
2878     fi
2879     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2880     if test $have_krb4 = yes; then
2881       KRB4LIB=-lkrb4
2882       LIBS="$KRB4LIB $LIBS"
2883       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2884     else
2885       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2886       if test $have_krb = yes; then
2887         KRB4LIB=-lkrb
2888         LIBS="$KRB4LIB $LIBS"
2889         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2890       fi
2891     fi
2892   fi
2893
2894   if test "${with_kerberos5}" != no; then
2895     AC_CHECK_HEADERS(krb5.h,
2896       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2897                         [#include <krb5.h>])])
2898   else
2899     AC_CHECK_HEADERS(des.h,,
2900                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2901                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2902     AC_CHECK_HEADERS(krb.h,,
2903                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2904                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2905   fi
2906   AC_CHECK_HEADERS(com_err.h)
2907 fi
2908
2909 AC_SUBST(COM_ERRLIB)
2910 AC_SUBST(CRYPTOLIB)
2911 AC_SUBST(KRB5LIB)
2912 AC_SUBST(DESLIB)
2913 AC_SUBST(KRB4LIB)
2914
2915 # Solaris requires -lintl if you want strerror (which calls dgettext)
2916 # to return localized messages.
2917 AC_CHECK_LIB(intl, dgettext)
2918
2919 AC_MSG_CHECKING(whether localtime caches TZ)
2920 AC_CACHE_VAL(emacs_cv_localtime_cache,
2921 [if test x$ac_cv_func_tzset = xyes; then
2922 AC_TRY_RUN([#include <time.h>
2923 extern char **environ;
2924 unset_TZ ()
2925 {
2926   char **from, **to;
2927   for (to = from = environ; (*to = *from); from++)
2928     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2929       to++;
2930 }
2931 char TZ_GMT0[] = "TZ=GMT0";
2932 char TZ_PST8[] = "TZ=PST8";
2933 main()
2934 {
2935   time_t now = time ((time_t *) 0);
2936   int hour_GMT0, hour_unset;
2937   if (putenv (TZ_GMT0) != 0)
2938     exit (1);
2939   hour_GMT0 = localtime (&now)->tm_hour;
2940   unset_TZ ();
2941   hour_unset = localtime (&now)->tm_hour;
2942   if (putenv (TZ_PST8) != 0)
2943     exit (1);
2944   if (localtime (&now)->tm_hour == hour_GMT0)
2945     exit (1);
2946   unset_TZ ();
2947   if (localtime (&now)->tm_hour != hour_unset)
2948     exit (1);
2949   exit (0);
2950 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2951 [# If we have tzset, assume the worst when cross-compiling.
2952 emacs_cv_localtime_cache=yes])
2953 else
2954         # If we lack tzset, report that localtime does not cache TZ,
2955         # since we can't invalidate the cache if we don't have tzset.
2956         emacs_cv_localtime_cache=no
2957 fi])dnl
2958 AC_MSG_RESULT($emacs_cv_localtime_cache)
2959 if test $emacs_cv_localtime_cache = yes; then
2960   AC_DEFINE(LOCALTIME_CACHE, 1,
2961             [Define to 1 if localtime caches TZ.])
2962 fi
2963
2964 if test "x$HAVE_TIMEVAL" = xyes; then
2965   AC_CHECK_FUNCS(gettimeofday)
2966   if test $ac_cv_func_gettimeofday = yes; then
2967     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2968                    emacs_cv_gettimeofday_two_arguments,
2969     [AC_TRY_COMPILE([
2970 #ifdef TIME_WITH_SYS_TIME
2971 #include <sys/time.h>
2972 #include <time.h>
2973 #else
2974 #ifdef HAVE_SYS_TIME_H
2975 #include <sys/time.h>
2976 #else
2977 #include <time.h>
2978 #endif
2979 #endif],
2980       [struct timeval time;
2981        gettimeofday (&time, 0);],
2982       emacs_cv_gettimeofday_two_arguments=yes,
2983       emacs_cv_gettimeofday_two_arguments=no)])
2984     if test $emacs_cv_gettimeofday_two_arguments = no; then
2985       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2986                 [Define to 1 if gettimeofday accepts only one argument.])
2987     fi
2988   fi
2989 fi
2990
2991 ok_so_far=yes
2992 AC_CHECK_FUNC(socket, , ok_so_far=no)
2993 if test $ok_so_far = yes; then
2994   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2995 fi
2996 if test $ok_so_far = yes; then
2997   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2998 fi
2999 if test $ok_so_far = yes; then
3000 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3001   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3002             [Define to 1 if you have inet sockets.])
3003 fi
3004
3005 AC_CHECK_HEADERS(sys/ioctl.h)
3006
3007 if test -f /usr/lpp/X11/bin/smt.exp; then
3008   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3009             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3010 fi
3011
3012 AC_MSG_CHECKING(whether system supports dynamic ptys)
3013 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3014   AC_MSG_RESULT(yes)
3015   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3016 else
3017   AC_MSG_RESULT(no)
3018 fi
3019
3020 AC_FUNC_FORK
3021
3022 dnl Adapted from Haible's version.
3023 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3024   [AC_TRY_LINK([#include <langinfo.h>],
3025     [char* cs = nl_langinfo(CODESET);],
3026     emacs_cv_langinfo_codeset=yes,
3027     emacs_cv_langinfo_codeset=no)
3028   ])
3029 if test $emacs_cv_langinfo_codeset = yes; then
3030   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3031     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3032 fi
3033
3034 AC_CHECK_TYPES(size_t)
3035
3036 AC_TYPE_MBSTATE_T
3037
3038 dnl Restrict could probably be used effectively other than in regex.c.
3039 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3040   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3041                   emacs_cv_c_restrict=yes,
3042                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3043                                   emacs_cv_c_restrict=__restrict,
3044                                   emacs_cv_c_restrict=no)])])
3045 case "$emacs_cv_c_restrict" in
3046   yes) emacs_restrict=restrict;;
3047   no) emacs_restrict="";;
3048   *) emacs_restrict="$emacs_cv_c_restrict";;
3049 esac
3050 if test "$emacs_restrict" != __restrict; then
3051   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3052     [Define to compiler's equivalent of C99 restrict keyword.
3053      Don't define if equivalent is `__restrict'.])
3054 fi
3055
3056 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3057   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3058                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3059 if test "$emacs_cv_c_restrict_arr" = yes; then
3060   AC_DEFINE(__restrict_arr, __restrict,
3061     [Define to compiler's equivalent of C99 restrict keyword in array
3062      declarations.  Define as empty for no equivalent.])
3063 fi
3064
3065 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3066 dnl how the tty code is related to POSIX and/or other versions of termios.
3067 dnl The following looks like a useful start.
3068 dnl
3069 dnl AC_SYS_POSIX_TERMIOS
3070 dnl if test $ac_cv_sys_posix_termios = yes; then
3071 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3072 dnl                                and macros for terminal control.])
3073 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3074 dnl fi
3075
3076 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3077
3078 # Set up the CFLAGS for real compilation, so we can substitute it.
3079 CFLAGS="$REAL_CFLAGS"
3080 CPPFLAGS="$REAL_CPPFLAGS"
3081
3082 ## Hack to detect a buggy GCC version.
3083 if test "x$GCC" = xyes \
3084    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3085    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3086    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3087    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3088 fi
3089
3090 #### Find out which version of Emacs this is.
3091 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3092          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3093 if test x"${version}" = x; then
3094   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3095 fi
3096 if test x"${version}" != x"$PACKAGE_VERSION"; then
3097   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3098 fi
3099
3100 ### Specify what sort of things we'll be editing into Makefile and config.h.
3101 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3102 AC_SUBST(version)
3103 AC_SUBST(configuration)
3104 ## Unused?
3105 AC_SUBST(canonical)
3106 AC_SUBST(srcdir)
3107 AC_SUBST(prefix)
3108 AC_SUBST(exec_prefix)
3109 AC_SUBST(bindir)
3110 AC_SUBST(datadir)
3111 AC_SUBST(sharedstatedir)
3112 AC_SUBST(libexecdir)
3113 AC_SUBST(mandir)
3114 AC_SUBST(infodir)
3115 AC_SUBST(lispdir)
3116 AC_SUBST(locallisppath)
3117 AC_SUBST(lisppath)
3118 AC_SUBST(x_default_search_path)
3119 AC_SUBST(etcdir)
3120 AC_SUBST(archlibdir)
3121 AC_SUBST(docdir)
3122 AC_SUBST(bitmapdir)
3123 AC_SUBST(gamedir)
3124 AC_SUBST(gameuser)
3125 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3126 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3127 ## end of LIBX_BASE, but nothing ever set it.
3128 AC_SUBST(LD_SWITCH_X_SITE)
3129 AC_SUBST(C_SWITCH_X_SITE)
3130 AC_SUBST(C_SWITCH_X_SYSTEM)
3131 AC_SUBST(CFLAGS)
3132 ## Used in lwlib/Makefile.in.
3133 AC_SUBST(X_TOOLKIT_TYPE)
3134 AC_SUBST(machfile)
3135 AC_SUBST(opsysfile)
3136 AC_SUBST(GETLOADAVG_LIBS)
3137 AC_SUBST(ns_appdir)
3138 AC_SUBST(ns_appbindir)
3139 AC_SUBST(ns_appresdir)
3140 AC_SUBST(ns_appsrc)
3141 AC_SUBST(GNU_OBJC_CFLAGS)
3142 AC_SUBST(OTHER_FILES)
3143
3144 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3145                    [Define to the canonical Emacs configuration name.])
3146 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3147                    [Define to the options passed to configure.])
3148 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3149                    [Define to the used machine dependent file.])
3150 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3151                    [Define to the used os dependent file.])
3152
3153 XMENU_OBJ=
3154 XOBJ=
3155 FONT_OBJ=
3156 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3157   AC_DEFINE(HAVE_X_WINDOWS, 1,
3158             [Define to 1 if you want to use the X window system.])
3159   XMENU_OBJ=xmenu.o
3160   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3161   FONT_OBJ=xfont.o
3162   if test "$HAVE_XFT" = "yes"; then
3163     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3164   elif test "$HAVE_FREETYPE" = "yes"; then
3165     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3166   fi
3167   AC_SUBST(FONT_OBJ)
3168 fi
3169 AC_SUBST(XMENU_OBJ)
3170 AC_SUBST(XOBJ)
3171 AC_SUBST(FONT_OBJ)
3172
3173 WIDGET_OBJ=
3174 MOTIF_LIBW=
3175 if test "${USE_X_TOOLKIT}" != "none" ; then
3176   WIDGET_OBJ=widget.o
3177   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3178   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3179     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3180   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3181     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3182     MOTIF_LIBW=-lXm
3183     case "$opsys" in
3184       gnu-linux)
3185         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3186         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3187         ;;
3188
3189       unixware)
3190         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3191         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3192         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3193         ;;
3194
3195       aix4-2)
3196         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3197         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3198         ;;
3199     esac
3200     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3201   fi
3202 fi
3203 AC_SUBST(WIDGET_OBJ)
3204
3205 TOOLKIT_LIBW=
3206 case "$USE_X_TOOLKIT" in
3207   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3208   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3209   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3210 esac
3211 AC_SUBST(TOOLKIT_LIBW)
3212
3213 if test "$USE_X_TOOLKIT" = "none"; then
3214   LIBXT_OTHER="\$(LIBXSM)"
3215   OLDXMENU_TARGET="really-oldXMenu"
3216 else
3217   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3218   OLDXMENU_TARGET="really-lwlib"
3219 fi
3220 AC_SUBST(LIBXT_OTHER)
3221
3222 ## The X Menu stuff is present in the X10 distribution, but missing
3223 ## from X11.  If we have X10, just use the installed library;
3224 ## otherwise, use our own copy.
3225 if test "${HAVE_X11}" = "yes" ; then
3226   AC_DEFINE(HAVE_X11, 1,
3227             [Define to 1 if you want to use version 11 of X windows.
3228              Otherwise, Emacs expects to use version 10.])
3229
3230   if test "$USE_X_TOOLKIT" = "none"; then
3231     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3232   else
3233     OLDXMENU="\${lwlibdir}liblw.a"
3234   fi
3235   LIBXMENU="\$(OLDXMENU)"
3236   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3237   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3238 else
3239   ## For a syntactically valid Makefile; not actually used for anything.
3240   ## See comments in src/Makefile.in.
3241   OLDXMENU=nothing
3242   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3243   if test "${HAVE_X_WINDOWS}" = "yes"; then
3244     LIBXMENU="-lXMenu"
3245   else
3246     LIBXMENU=
3247   fi
3248   LIBX_OTHER=
3249   OLDXMENU_DEPS=
3250 fi
3251
3252 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3253   OLDXMENU_TARGET=
3254   OLDXMENU=nothing
3255   LIBXMENU=
3256   OLDXMENU_DEPS=
3257 fi
3258
3259 AC_SUBST(OLDXMENU_TARGET)
3260 AC_SUBST(OLDXMENU)
3261 AC_SUBST(LIBXMENU)
3262 AC_SUBST(LIBX_OTHER)
3263 AC_SUBST(OLDXMENU_DEPS)
3264
3265 if test "${HAVE_MENUS}" = "yes" ; then
3266   AC_DEFINE(HAVE_MENUS, 1,
3267             [Define to 1 if you have mouse menus.
3268              (This is automatic if you use X, but the option to specify it remains.)
3269              It is also defined with other window systems that support xmenu.c.])
3270 fi
3271
3272 if test "${GNU_MALLOC}" = "yes" ; then
3273   AC_DEFINE(GNU_MALLOC, 1,
3274             [Define to 1 if you want to use the GNU memory allocator.])
3275 fi
3276
3277 RALLOC_OBJ=
3278 if test "${REL_ALLOC}" = "yes" ; then
3279   AC_DEFINE(REL_ALLOC, 1,
3280             [Define REL_ALLOC if you want to use the relocating allocator for
3281              buffer space.])
3282
3283   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3284 fi
3285 AC_SUBST(RALLOC_OBJ)
3286
3287 if test "$opsys" = "cygwin"; then
3288   CYGWIN_OBJ="sheap.o"
3289   ## Cygwin differs because of its unexec().
3290   PRE_ALLOC_OBJ=
3291   POST_ALLOC_OBJ=lastfile.o
3292 else
3293   CYGWIN_OBJ=
3294   PRE_ALLOC_OBJ=lastfile.o
3295   POST_ALLOC_OBJ=
3296 fi
3297 AC_SUBST(CYGWIN_OBJ)
3298 AC_SUBST(PRE_ALLOC_OBJ)
3299 AC_SUBST(POST_ALLOC_OBJ)
3300
3301
3302 case "$opsys" in
3303   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3304
3305   darwin)
3306    ## The -headerpad option tells ld (see man page) to leave room at the
3307    ## end of the header for adding load commands.  Needed for dumping.
3308    ## 0x690 is the total size of 30 segment load commands (at 56
3309    ## each); under Cocoa 31 commands are required.
3310    if test "$HAVE_NS" = "yes"; then
3311      libs_nsgui="-framework AppKit"
3312      headerpad_extra=6C8
3313    else
3314      libs_nsgui=
3315      headerpad_extra=690
3316    fi
3317    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3318
3319    ## This is here because src/Makefile.in did some extra fiddling around
3320    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3321    ##   #ifndef LD_SWITCH_SYSTEM
3322    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3323    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3324    ## not using gcc, darwin system not on an alpha (ie darwin, since
3325    ## darwin + alpha does not occur).
3326    ## Because this was done in src/Makefile.in, the resulting part of
3327    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3328    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3329    ## rather than LD_SWITCH_SYSTEM.
3330    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3331      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3332    ;;
3333
3334   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3335   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3336   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3337   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3338   ## had different values in configure (in ac_link) and src/Makefile.in.
3339   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3340   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3341
3342   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3343 esac
3344
3345 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3346   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3347 fi
3348
3349 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3350
3351
3352 LINKER=
3353 ORDINARY_LINK=
3354 case "$opsys" in
3355   ## gnu: GNU needs its own crt0.
3356   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3357
3358   cygwin) LINKER="\$(CC)" ;;
3359
3360   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3361   ## library search parth, i.e. it won't search /usr/lib for libc and
3362   ## friends.  Using -nostartfiles instead avoids this problem, and
3363   ## will also work on earlier NetBSD releases.
3364   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3365
3366   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3367   ##   MkLinux/LinuxPPC needs this.
3368   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3369   gnu-*)
3370     case "$machine" in
3371       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3372     esac
3373     ;;
3374 esac
3375
3376
3377 PRE_EDIT_LDFLAGS=
3378 POST_EDIT_LDFLAGS=
3379 if test "x$ORDINARY_LINK" = "xyes"; then
3380
3381   LINKER="\$(CC)"
3382   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3383
3384 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3385 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3386 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3387
3388   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3389   ## places that are difficult to figure out at make time.  Fortunately,
3390   ## these same versions allow you to pass arbitrary flags on to the
3391   ## linker, so there is no reason not to use it as a linker.
3392   ##
3393   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3394   ## searching for libraries in its internal directories, so we have to
3395   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3396   LINKER="\$(CC) -nostdlib"
3397   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3398   ## See prefix-args.c for an explanation of why we do not do this with the
3399   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3400   ## their paths, so we must use ./prefix-args.
3401   ## TODO either make prefix-args check ORDINARY_LINK internally,
3402   ## or remove it altogether (bug#6184), removing the need for this hack.
3403   PRE_EDIT_LDFLAGS='`./prefix-args -Xlinker'
3404   POST_EDIT_LDFLAGS='`'
3405 fi
3406 AC_SUBST(PRE_EDIT_LDFLAGS)
3407 AC_SUBST(POST_EDIT_LDFLAGS)
3408
3409 test "x$LINKER" = "x" && LINKER=ld
3410 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3411 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3412
3413 AC_SUBST(LINKER)
3414
3415
3416 ## FIXME? The logic here is not precisely the same as that above.
3417 ## There is no check here for a pre-defined LINKER.
3418 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3419 LIB_GCC=
3420 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3421
3422   case "$opsys" in
3423     ## cygwin: don't link against static libgcc.
3424     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3425
3426     gnu-*)
3427       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3428       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3429       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3430       if test "$machine" = "arm"; then
3431         LIB_GCC="-lgcc_s"
3432       else
3433         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3434         ## immediately undefine it again and redefine it to empty.
3435         ## Was the C_SWITCH_X_SITE part really necessary?
3436 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3437         LIB_GCC=
3438       fi
3439       ;;
3440
3441     ## Ask GCC where to find libgcc.a.
3442     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3443   esac
3444 fi                              dnl if $GCC
3445 AC_SUBST(LIB_GCC)
3446
3447
3448 TOOLTIP_SUPPORT=
3449 WINDOW_SUPPORT=
3450 ## If we're using X11/GNUstep, define some consequences.
3451 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3452   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3453   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3454   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3455   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3456
3457   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3458   test "$HAVE_X_WINDOWS" = "yes" && \
3459     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3460
3461 fi
3462 AC_SUBST(MOUSE_SUPPORT)
3463 AC_SUBST(TOOLTIP_SUPPORT)
3464 AC_SUBST(WINDOW_SUPPORT)
3465
3466
3467 AH_TOP([/* GNU Emacs site configuration template file.
3468    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3469      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3470
3471 This file is part of GNU Emacs.
3472
3473 GNU Emacs is free software: you can redistribute it and/or modify
3474 it under the terms of the GNU General Public License as published by
3475 the Free Software Foundation, either version 3 of the License, or
3476 (at your option) any later version.
3477
3478 GNU Emacs is distributed in the hope that it will be useful,
3479 but WITHOUT ANY WARRANTY; without even the implied warranty of
3480 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3481 GNU General Public License for more details.
3482
3483 You should have received a copy of the GNU General Public License
3484 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3485
3486
3487 /* No code in Emacs #includes config.h twice, but some bits of code
3488    intended to work with other packages as well (like gmalloc.c)
3489    think they can include it as many times as they like.  */
3490 #ifndef EMACS_CONFIG_H
3491 #define EMACS_CONFIG_H
3492 ])dnl
3493
3494 AH_BOTTOM([
3495 /* Define AMPERSAND_FULL_NAME if you use the convention
3496    that & in the full name stands for the login id.  */
3497 /* Turned on June 1996 supposing nobody will mind it.  */
3498 #define AMPERSAND_FULL_NAME
3499
3500 /* Define HAVE_SOUND if we have sound support.  We know it works
3501    and compiles only on the specified platforms.   For others,
3502    it probably doesn't make sense to try.  */
3503
3504 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3505 #ifdef HAVE_MACHINE_SOUNDCARD_H
3506 #define HAVE_SOUND 1
3507 #endif
3508 #ifdef HAVE_SYS_SOUNDCARD_H
3509 #define HAVE_SOUND 1
3510 #endif
3511 #ifdef HAVE_SOUNDCARD_H
3512 #define HAVE_SOUND 1
3513 #endif
3514 #ifdef HAVE_ALSA
3515 #define HAVE_SOUND 1
3516 #endif
3517 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3518
3519 /* If using GNU, then support inline function declarations.  */
3520 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3521    generally, because even if non-gcc compilers accept `inline', they
3522    may reject `extern inline'.  */
3523 #if defined (__GNUC__) && defined (OPTIMIZE)
3524 #define INLINE __inline__
3525 #else
3526 #define INLINE
3527 #endif
3528
3529 /* `subprocesses' should be defined if you want to
3530    have code for asynchronous subprocesses
3531    (as used in M-x compile and M-x shell).
3532    Only MSDOS does not support this (it overrides
3533    this in its config_opsysfile below).  */
3534
3535 #define subprocesses
3536
3537 /* Include the os and machine dependent files.  */
3538 #include config_opsysfile
3539 #include config_machfile
3540
3541 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3542   (There is probably a better place to do this, but right now the Cocoa
3543    side does this in s/darwin.h and we cannot
3544    parallel this exactly since GNUstep is multi-OS.  */
3545 #ifdef HAVE_NS
3546 # ifdef NS_IMPL_GNUSTEP
3547 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3548 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3549 #  define SYSTEM_PURESIZE_EXTRA 30000
3550 # endif /* NS_IMPL_GNUSTEP */
3551 #endif /* HAVE_NS */
3552
3553 /* SIGTYPE is the macro we actually use.  */
3554 #ifndef SIGTYPE
3555 #define SIGTYPE RETSIGTYPE
3556 #endif
3557
3558 #ifdef emacs /* Don't do this for lib-src.  */
3559 /* Tell regex.c to use a type compatible with Emacs.  */
3560 #define RE_TRANSLATE_TYPE Lisp_Object
3561 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3562 #ifdef make_number
3563 /* If make_number is a macro, use it.  */
3564 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3565 #else
3566 /* If make_number is a function, avoid it.  */
3567 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3568 #endif
3569 #endif
3570
3571 /* Avoid link-time collision with system mktime if we will use our own.  */
3572 #if ! HAVE_MKTIME || BROKEN_MKTIME
3573 #define mktime emacs_mktime
3574 #endif
3575
3576 #define my_strftime nstrftime   /* for strftime.c */
3577
3578 /* Some of the files of Emacs which are intended for use with other
3579    programs assume that if you have a config.h file, you must declare
3580    the type of getenv.  */
3581 extern char *getenv ();
3582
3583 /* These default definitions are good for almost all machines.
3584    The exceptions override them in m/MACHINE.h.  */
3585
3586 #ifndef BITS_PER_CHAR
3587 #define BITS_PER_CHAR 8
3588 #endif
3589
3590 #ifndef BITS_PER_SHORT
3591 #define BITS_PER_SHORT 16
3592 #endif
3593
3594 /* Note that lisp.h uses this in a preprocessor conditional, so it
3595    would not work to use sizeof.  That being so, we do all of them
3596    without sizeof, for uniformity's sake.  */
3597 #ifndef BITS_PER_INT
3598 #define BITS_PER_INT 32
3599 #endif
3600
3601 #ifndef BITS_PER_LONG
3602 #ifdef _LP64
3603 #define BITS_PER_LONG 64
3604 #else
3605 #define BITS_PER_LONG 32
3606 #endif
3607 #endif
3608
3609 /* Define if the compiler supports function prototypes.  It may do so
3610    but not define __STDC__ (e.g. DEC C by default) or may define it as
3611    zero.  */
3612 #undef PROTOTYPES
3613 /* For mktime.c:  */
3614 #ifndef __P
3615 # if defined PROTOTYPES
3616 #  define __P(args) args
3617 # else
3618 #  define __P(args) ()
3619 # endif  /* GCC.  */
3620 #endif /* __P */
3621
3622 #ifdef HAVE_STRING_H
3623 #include <string.h>
3624 #endif
3625
3626 #ifdef HAVE_STRINGS_H
3627 #include <strings.h>  /* May be needed for bcopy & al.  */
3628 #endif
3629
3630 #ifdef HAVE_STDLIB_H
3631 #include <stdlib.h>
3632 #endif
3633
3634 #ifdef HAVE_ALLOCA_H
3635 # include <alloca.h>
3636 #elif defined __GNUC__
3637 # define alloca __builtin_alloca
3638 #elif defined _AIX
3639 # define alloca __alloca
3640 #else
3641 # include <stddef.h>
3642 # ifdef  __cplusplus
3643 extern "C"
3644 # endif
3645 void *alloca (size_t);
3646 #endif
3647
3648 #ifndef HAVE_SIZE_T
3649 typedef unsigned size_t;
3650 #endif
3651
3652 /* Define HAVE_X_I18N if we have usable i18n support.  */
3653
3654 #ifdef HAVE_X11R6
3655 #define HAVE_X_I18N
3656 #endif
3657
3658 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3659
3660 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3661 #define HAVE_X11R6_XIM
3662 #endif
3663
3664 #if defined __GNUC__ && (__GNUC__ > 2 \
3665                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3666 #define NO_RETURN       __attribute__ ((__noreturn__))
3667 #else
3668 #define NO_RETURN       /* nothing */
3669 #endif
3670
3671 /* These won't be used automatically yet.  We also need to know, at least,
3672    that the stack is continuous.  */
3673 #ifdef __GNUC__
3674 #  ifndef GC_SETJMP_WORKS
3675   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3676 #    define GC_SETJMP_WORKS 1
3677 #  endif
3678 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3679 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3680 #  endif
3681 #endif
3682
3683 #ifndef HAVE_BCOPY
3684 #define bcopy(a,b,s) memcpy (b,a,s)
3685 #endif
3686 #ifndef HAVE_BZERO
3687 #define bzero(a,s) memset (a,0,s)
3688 #endif
3689 #ifndef HAVE_BCMP
3690 #define BCMP memcmp
3691 #endif
3692
3693 #endif /* EMACS_CONFIG_H */
3694
3695 /*
3696 Local Variables:
3697 mode: c
3698 End:
3699 */
3700 ])dnl
3701
3702 #### Report on what we decided to do.
3703 #### Report GTK as a toolkit, even if it doesn't use Xt.
3704 #### It makes printing result more understandable as using GTK sets
3705 #### toolkit_scroll_bars to yes by default.
3706 if test "${HAVE_GTK}" = "yes"; then
3707   USE_X_TOOLKIT=GTK
3708 fi
3709
3710 echo "
3711 Configured for \`${canonical}'.
3712
3713   Where should the build process find the source code?    ${srcdir}
3714   What operating system and machine description files should Emacs use?
3715         \`${opsysfile}' and \`${machfile}'
3716   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3717   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3718   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3719   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3720   What window system should Emacs use?                    ${window_system}
3721   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3722
3723 if test -n "${x_includes}"; then
3724 echo "  Where do we find X Windows header files?                ${x_includes}"
3725 else
3726 echo "  Where do we find X Windows header files?                Standard dirs"
3727 fi
3728 if test -n "${x_libraries}"; then
3729 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3730 else
3731 echo "  Where do we find X Windows libraries?                   Standard dirs"
3732 fi
3733
3734 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3735 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3736 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3737 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3738 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3739 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3740 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3741 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3742 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3743 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3744 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3745
3746 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3747 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3748 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3749 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3750
3751 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3752 echo
3753
3754 if test $USE_XASSERTS = yes; then
3755    echo "  Compiling with asserts turned on."
3756    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3757 fi
3758
3759 echo
3760
3761 if test "$HAVE_NS" = "yes"; then
3762    echo
3763    echo "You must run \"make install\" in order to test the built application.
3764 The installed application will go to nextstep/Emacs.app and can be
3765 run or moved from there."
3766    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3767       echo "The application will be fully self-contained."
3768     else
3769       echo "The lisp resources for the application will be installed under ${prefix}.
3770 You may need to run \"make install\" with sudo.  The application will fail
3771 to run if these resources are not installed."
3772    fi
3773    echo
3774 fi
3775
3776 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3777   echo "D-Bus integration has been tested for GNU/Linux only."
3778   echo
3779 fi
3780
3781
3782 # Remove any trailing slashes in these variables.
3783 [test "${prefix}" != NONE &&
3784   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3785 test "${exec_prefix}" != NONE &&
3786   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3787
3788 dnl You might wonder (I did) why epaths.h is generated by running make,
3789 dnl rather than just letting configure generate it from epaths.in.
3790 dnl One reason is that the various paths are not fully expanded (see above);
3791 dnl eg gamedir=${prefix}/var/games/emacs.
3792 dnl Secondly, the GNU Coding standards require that one should be able
3793 dnl to run `make prefix=/some/where/else' and override the values set
3794 dnl by configure.  This also explains the `move-if-change' test and
3795 dnl the use of force in the `epaths-force' rule in Makefile.in.
3796 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3797         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3798         doc/lispref/Makefile src/Makefile \
3799         lwlib/Makefile lisp/Makefile leim/Makefile, [
3800
3801 ### Make the necessary directories, if they don't exist.
3802 for dir in etc lisp ; do
3803   test -d ${dir} || mkdir ${dir}
3804 done
3805
3806 echo creating src/epaths.h
3807 ${MAKE-make} epaths-force
3808
3809 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3810   echo creating src/.gdbinit
3811   echo source $srcdir/src/.gdbinit > src/.gdbinit
3812 fi
3813
3814 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3815
3816 m4_if(dnl       Do not change this comment
3817    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3818 )dnl