lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2015 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  30 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  31
  32 ;; USAGE: In your ~/.emacs,
  33 ;;
  34 ;; (add-hook 'dired-load-hook
  35 ;;           (lambda ()
  36 ;;                       (load "dired-x")
  37 ;;                       ;; Set global variables here.  For example:
  38 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  39 ;;                       ))
  40 ;; (add-hook 'dired-mode-hook
  41 ;;           (lambda ()
  42 ;;                       ;; Set buffer-local variables here.  For example:
  43 ;;                       ;; (dired-omit-mode 1)
  44 ;;                       ))
  45 ;;
  46 ;; At load time dired-x.el will install itself and bind some dired keys.
  47 ;; Some dired.el and dired-aux.el functions have extra features if
  48 ;; dired-x is loaded.
  49
  50 ;; User customization: M-x customize-group RET dired-x RET.
  51
  52 ;; *Please* see the `dired-x' info pages for more details.
  53
  54 \f
  55 ;;; Code:
  56
  57 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  58 ;; but maybe not if a dired-x function is being autoloaded.
  59 (require 'dired)
  60
  61 ;;; User-defined variables.
  62
  63 (defgroup dired-x nil
  64   "Extended directory editing (dired-x)."
  65   :group 'dired)
  66
  67 (defgroup dired-keys nil
  68   "Dired keys customizations."
  69   :prefix "dired-"
  70   :group 'dired-x)
  71
  72 (defcustom dired-bind-vm nil
  73   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  74 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  75 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  76 will run `rmail' on these files.  New RMAIL files use the standard
  77 mbox format, and so cannot be distinguished in this way."
  78   :type 'boolean
  79   :group 'dired-keys)
  80
  81 (defcustom dired-bind-jump t
  82   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  83 Setting this variable directly after dired-x is loaded has no effect -
  84 use \\[customize]."
  85   :type 'boolean
  86   :set (lambda (sym val)
  87          (if (set sym val)
  88              (progn
  89                (define-key ctl-x-map "\C-j" 'dired-jump)
  90                (define-key ctl-x-4-map "\C-j" 'dired-jump-other-window))
  91            (if (eq 'dired-jump (lookup-key ctl-x-map "\C-j"))
  92                (define-key ctl-x-map "\C-j" nil))
  93            (if (eq 'dired-jump-other-window (lookup-key ctl-x-4-map "\C-j"))
  94                (define-key ctl-x-4-map "\C-j" nil))))
  95   :group 'dired-keys)
  96
  97 (defcustom dired-bind-man t
  98   "Non-nil means bind `dired-man' to \"N\" in Dired, otherwise do not.
  99 Setting this variable directly after dired-x is loaded has no effect -
 100 use \\[customize]."
 101   :type 'boolean
 102   :set (lambda (sym val)
 103          (if (set sym val)
 104              (define-key dired-mode-map "N" 'dired-man)
 105            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
 106                (define-key dired-mode-map "N" nil))))
 107   :group 'dired-keys)
 108
 109 (defcustom dired-bind-info t
 110   "Non-nil means bind `dired-info' to \"I\" in Dired, otherwise do not.
 111 Setting this variable directly after dired-x is loaded has no effect -
 112 use \\[customize]."
 113   :type 'boolean
 114   :set (lambda (sym val)
 115          (if (set sym val)
 116              (define-key dired-mode-map "I" 'dired-info)
 117            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 118                (define-key dired-mode-map "I" nil))))
 119   :group 'dired-keys)
 120
 121 (defcustom dired-vm-read-only-folders nil
 122   "If non-nil, \\[dired-vm] will visit all folders read-only.
 123 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 124 files not writable by you are visited read-only."
 125   :type '(choice (const :tag "off" nil)
 126                  (const :tag "on" t)
 127                  (other :tag "non-writable only" if-file-read-only))
 128   :group 'dired-x)
 129
 130 (defcustom dired-omit-size-limit 30000
 131   "Maximum size for the \"omitting\" feature.
 132 If nil, there is no maximum size."
 133   :type '(choice (const :tag "no maximum" nil) integer)
 134   :group 'dired-x)
 135
 136 ;; For backward compatibility
 137 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 138 (define-minor-mode dired-omit-mode
 139   "Toggle omission of uninteresting files in Dired (Dired-Omit mode).
 140 With a prefix argument ARG, enable Dired-Omit mode if ARG is
 141 positive, and disable it otherwise.  If called from Lisp, enable
 142 the mode if ARG is omitted or nil.
 143
 144 Dired-Omit mode is a buffer-local minor mode.  When enabled in a
 145 Dired buffer, Dired does not list files whose filenames match
 146 regexp `dired-omit-files', nor files ending with extensions in
 147 `dired-omit-extensions'.
 148
 149 To enable omitting in every Dired buffer, you can put this in
 150 your init file:
 151
 152   (add-hook 'dired-mode-hook (lambda () (dired-omit-mode)))
 153
 154 See Info node `(dired-x) Omitting Variables' for more information."
 155   :group 'dired-x
 156   (if dired-omit-mode
 157       ;; This will mention how many lines were omitted:
 158       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 159     (revert-buffer)))
 160
 161 (put 'dired-omit-mode 'safe-local-variable 'booleanp)
 162
 163 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 164   "Filenames matching this regexp will not be displayed.
 165 This only has effect when `dired-omit-mode' is t.  See interactive function
 166 `dired-omit-mode' (\\[dired-omit-mode]) and variable
 167 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 168 files and lock files."
 169   :type 'regexp
 170   :group 'dired-x)
 171
 172 (defcustom dired-omit-verbose t
 173   "When non-nil, show messages when omitting files.
 174 When nil, don't show messages."
 175   :version "24.1"
 176   :type 'boolean
 177   :group 'dired-x)
 178
 179 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 180   "If non-nil, Dired always finds a directory in a buffer of its own.
 181 If nil, Dired finds the directory as a subdirectory in some other buffer
 182 if it is present as one.
 183
 184 If there are several Dired buffers for a directory, the most recently
 185 used is chosen.
 186
 187 Dired avoids switching to the current buffer, so that if you have
 188 a normal and a wildcard buffer for the same directory, \\[dired] will
 189 toggle between those two."
 190   :type 'boolean
 191   :group 'dired-x)
 192
 193 (defcustom dired-enable-local-variables t
 194   "Control use of local-variables lists in Dired.
 195 This temporarily overrides the value of `enable-local-variables' when
 196 listing a directory.  See also `dired-local-variables-file'."
 197   :risky t
 198   :type '(choice (const :tag "Query Unsafe" t)
 199                  (const :tag "Safe Only" :safe)
 200                  (const :tag "Do all" :all)
 201                  (const :tag "Ignore" nil)
 202                  (other :tag "Query" other))
 203   :group 'dired-x)
 204
 205 (make-obsolete-variable 'dired-enable-local-variables
 206                         "use a standard `dir-locals-file' instead." "24.1")
 207
 208 (defcustom dired-guess-shell-gnutar
 209   (catch 'found
 210     (dolist (exe '("tar" "gtar"))
 211       (if (with-temp-buffer
 212             (ignore-errors (call-process exe nil t nil "--version"))
 213             (and (re-search-backward "GNU tar" nil t) t))
 214           (throw 'found exe))))
 215   "If non-nil, name of GNU tar executable.
 216 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 217 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 218 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 219   ;; Changed from system-type test to testing --version output.
 220   ;; Maybe test --help for -z instead?
 221   :version "24.1"
 222   :type '(choice (const :tag "Not GNU tar" nil)
 223                  (string :tag "Command name"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-gzip-quiet t
 227   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 (defcustom dired-guess-shell-znew-switches nil
 232   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 233   :type '(choice (const :tag "None" nil)
 234                  (string :tag "Switches"))
 235   :group 'dired-x)
 236
 237 (defcustom dired-clean-up-buffers-too t
 238   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 239   :type 'boolean
 240   :group 'dired-x)
 241
 242 ;;; KEY BINDINGS.
 243
 244 (define-key dired-mode-map "\C-x\M-o" 'dired-omit-mode)
 245 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 246 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 248 (define-key dired-mode-map "*." 'dired-mark-extension)
 249 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 250 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 251 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 252 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 253 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 254 (define-key dired-mode-map "V" 'dired-do-run-mail)
 255
 256 ;;; MENU BINDINGS
 257
 258 (require 'easymenu)
 259
 260 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 261   (easy-menu-add-item menu '("Operate")
 262                       ["Find Files" dired-do-find-marked-files
 263                        :help "Find current or marked files"]
 264                       "Shell Command...")
 265   (easy-menu-add-item menu '("Operate")
 266                       ["Relative Symlink to..." dired-do-relsymlink
 267                        :visible (fboundp 'make-symbolic-link)
 268                        :help "Make relative symbolic links for current or \
 269 marked files"]
 270                       "Hardlink to...")
 271   (easy-menu-add-item menu '("Mark")
 272                       ["Flag Extension..." dired-flag-extension
 273                        :help "Flag files with a certain extension for deletion"]
 274                       "Mark Executables")
 275   (easy-menu-add-item menu '("Mark")
 276                       ["Mark Extension..." dired-mark-extension
 277                        :help "Mark files with a certain extension"]
 278                       "Unmark All")
 279   (easy-menu-add-item menu '("Mark")
 280                       ["Mark Omitted" dired-mark-omitted
 281                        :help "Mark files matching `dired-omit-files' \
 282 and `dired-omit-extensions'"]
 283                       "Unmark All")
 284   (easy-menu-add-item menu '("Regexp")
 285                       ["Relative Symlink..." dired-do-relsymlink-regexp
 286                        :visible (fboundp 'make-symbolic-link)
 287                        :help "Make relative symbolic links for files \
 288 matching regexp"]
 289                       "Hardlink...")
 290   (easy-menu-add-item menu '("Immediate")
 291                       ["Omit Mode" dired-omit-mode
 292                        :style toggle :selected dired-omit-mode
 293                        :help "Enable or disable omitting \"uninteresting\" \
 294 files"]
 295                       "Refresh"))
 296
 297 \f
 298 ;; Install into appropriate hooks.
 299
 300 (add-hook 'dired-mode-hook 'dired-extra-startup)
 301 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 302
 303 (defun dired-extra-startup ()
 304   "Automatically put on `dired-mode-hook' to get extra Dired features:
 305 \\<dired-mode-map>
 306   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 307   \\[dired-info]\t-- run info on file
 308   \\[dired-man]\t-- run man on file
 309   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 310   \\[dired-omit-mode]\t-- toggle omitting of files
 311   \\[dired-mark-sexp]\t-- mark by Lisp expression
 312
 313 To see the options you can set, use M-x customize-group RET dired-x RET.
 314 See also the functions:
 315   `dired-flag-extension'
 316   `dired-virtual'
 317   `dired-jump'
 318   `dired-man'
 319   `dired-vm'
 320   `dired-rmail'
 321   `dired-info'
 322   `dired-do-find-marked-files'"
 323   (interactive)
 324   ;; These must be done in each new dired buffer.
 325   (dired-hack-local-variables)
 326   (dired-omit-startup))
 327
 328 \f
 329 ;;; EXTENSION MARKING FUNCTIONS.
 330
 331 ;; Mark files with some extension.
 332 (defun dired-mark-extension (extension &optional marker-char)
 333   "Mark all files with a certain EXTENSION for use in later commands.
 334 A `.' is *not* automatically prepended to the string entered.
 335 EXTENSION may also be a list of extensions instead of a single one.
 336 Optional MARKER-CHAR is marker to use."
 337   (interactive "sMarking extension: \nP")
 338   (or (listp extension)
 339       (setq extension (list extension)))
 340   (dired-mark-files-regexp
 341    (concat ".";; don't match names with nothing but an extension
 342            "\\("
 343            (mapconcat 'regexp-quote extension "\\|")
 344            "\\)$")
 345    marker-char))
 346
 347 (defun dired-flag-extension (extension)
 348   "In Dired, flag all files with a certain EXTENSION for deletion.
 349 A `.' is *not* automatically prepended to the string entered."
 350   (interactive "sFlagging extension: ")
 351   (dired-mark-extension extension dired-del-marker))
 352
 353 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 354
 355 (defvar dired-patch-unclean-extensions
 356   '(".rej" ".orig")
 357   "List of extensions of dispensable files created by the `patch' program.")
 358
 359 (defvar dired-tex-unclean-extensions
 360   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 361   "List of extensions of dispensable files created by TeX.")
 362
 363 (defvar dired-latex-unclean-extensions
 364   '(".idx" ".lof" ".lot" ".glo")
 365   "List of extensions of dispensable files created by LaTeX.")
 366
 367 (defvar dired-bibtex-unclean-extensions
 368   '(".blg" ".bbl")
 369   "List of extensions of dispensable files created by BibTeX.")
 370
 371 (defvar dired-texinfo-unclean-extensions
 372   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 373     ".tp" ".tps" ".vr" ".vrs")
 374   "List of extensions of dispensable files created by texinfo.")
 375
 376 (defun dired-clean-patch ()
 377   "Flag dispensable files created by patch for deletion.
 378 See variable `dired-patch-unclean-extensions'."
 379   (interactive)
 380   (dired-flag-extension dired-patch-unclean-extensions))
 381
 382 (defun dired-clean-tex ()
 383   "Flag dispensable files created by [La]TeX etc. for deletion.
 384 See variables `dired-tex-unclean-extensions',
 385 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 386 `dired-texinfo-unclean-extensions'."
 387   (interactive)
 388   (dired-flag-extension (append dired-texinfo-unclean-extensions
 389                                 dired-latex-unclean-extensions
 390                                 dired-bibtex-unclean-extensions
 391                                 dired-tex-unclean-extensions)))
 392
 393 (defun dired-very-clean-tex ()
 394   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 395 See variables `dired-texinfo-unclean-extensions',
 396 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 397 `dired-texinfo-unclean-extensions'."
 398   (interactive)
 399   (dired-flag-extension (append dired-texinfo-unclean-extensions
 400                                 dired-latex-unclean-extensions
 401                                 dired-bibtex-unclean-extensions
 402                                 dired-tex-unclean-extensions
 403                                 (list ".dvi"))))
 404 \f
 405 ;;; JUMP.
 406
 407 ;;;###autoload
 408 (defun dired-jump (&optional other-window file-name)
 409   "Jump to Dired buffer corresponding to current buffer.
 410 If in a file, Dired the current directory and move to file's line.
 411 If in Dired already, pop up a level and goto old directory's line.
 412 In case the proper Dired file line cannot be found, refresh the dired
 413 buffer and try again.
 414 When OTHER-WINDOW is non-nil, jump to Dired buffer in other window.
 415 Interactively with prefix argument, read FILE-NAME and
 416 move to its line in dired."
 417   (interactive
 418    (list nil (and current-prefix-arg
 419                   (read-file-name "Jump to Dired file: "))))
 420   (let* ((file (or file-name buffer-file-name))
 421          (dir (if file (file-name-directory file) default-directory)))
 422     (if (and (eq major-mode 'dired-mode) (null file-name))
 423         (progn
 424           (setq dir (dired-current-directory))
 425           (dired-up-directory other-window)
 426           (unless (dired-goto-file dir)
 427               ;; refresh and try again
 428             (dired-insert-subdir (file-name-directory dir))
 429             (dired-goto-file dir)))
 430       (if other-window
 431           (dired-other-window dir)
 432         (dired dir))
 433       (if file
 434           (or (dired-goto-file file)
 435               ;; refresh and try again
 436               (progn
 437                 (dired-insert-subdir (file-name-directory file))
 438                 (dired-goto-file file))
 439               ;; Toggle omitting, if it is on, and try again.
 440               (when dired-omit-mode
 441                 (dired-omit-mode)
 442                 (dired-goto-file file)))))))
 443
 444 ;;;###autoload
 445 (defun dired-jump-other-window (&optional file-name)
 446   "Like \\[dired-jump] (`dired-jump') but in other window."
 447   (interactive
 448    (list (and current-prefix-arg
 449               (read-file-name "Jump to Dired file: "))))
 450   (dired-jump t file-name))
 451 \f
 452 ;;; OMITTING.
 453
 454 ;; Enhanced omitting of lines from directory listings.
 455 ;; Marked files are never omitted.
 456
 457 ;; should probably get rid of this and always use 'no-dir.
 458 ;; sk 28-Aug-1991 09:37
 459 (defvar dired-omit-localp 'no-dir
 460   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 461 If it is `no-dir', omitting is much faster, but you can only match
 462 against the non-directory part of the file name.  Set it to nil if you
 463 need to match the entire file name.")
 464
 465 ;; \017=^O for Omit - other packages can chose other control characters.
 466 (defvar dired-omit-marker-char ?\017
 467   "Temporary marker used by Dired-Omit.
 468 Should never be used as marker by the user or other packages.")
 469
 470 (defun dired-omit-startup ()
 471   (or (assq 'dired-omit-mode minor-mode-alist)
 472       (setq minor-mode-alist
 473             (append '((dired-omit-mode
 474                        (:eval (if (eq major-mode 'dired-mode)
 475                                   " Omit" ""))))
 476                     minor-mode-alist))))
 477
 478 (defun dired-mark-omitted ()
 479   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 480   (interactive)
 481   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 482   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 483
 484 (defcustom dired-omit-extensions
 485   (append completion-ignored-extensions
 486           dired-latex-unclean-extensions
 487           dired-bibtex-unclean-extensions
 488           dired-texinfo-unclean-extensions)
 489   "If non-nil, a list of extensions (strings) to omit from Dired listings.
 490 Defaults to elements of `completion-ignored-extensions',
 491 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 492 `dired-texinfo-unclean-extensions'.
 493
 494 See interactive function `dired-omit-mode' (\\[dired-omit-mode]) and
 495 variables `dired-omit-mode' and `dired-omit-files'."
 496   :type '(repeat string)
 497   :group 'dired-x)
 498
 499 (defun dired-omit-expunge (&optional regexp)
 500   "Erases all unmarked files matching REGEXP.
 501 Does nothing if global variable `dired-omit-mode' is nil, or if called
 502   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 503 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 504   filenames ending in `dired-omit-extensions'.
 505 If REGEXP is the empty string, this function is a no-op.
 506
 507 This functions works by temporarily binding `dired-marker-char' to
 508 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 509   (interactive "sOmit files (regexp): ")
 510   (if (and dired-omit-mode
 511            (or (called-interactively-p 'interactive)
 512                (not dired-omit-size-limit)
 513                (< (buffer-size) dired-omit-size-limit)
 514                (progn
 515                  (when dired-omit-verbose
 516                    (message "Not omitting: directory larger than %d characters."
 517                             dired-omit-size-limit))
 518                  (setq dired-omit-mode nil)
 519                  nil)))
 520       (let ((omit-re (or regexp (dired-omit-regexp)))
 521             (old-modified-p (buffer-modified-p))
 522             count)
 523         (or (string= omit-re "")
 524             (let ((dired-marker-char dired-omit-marker-char))
 525               (when dired-omit-verbose (message "Omitting..."))
 526               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 527                   (progn
 528                     (setq count (dired-do-kill-lines
 529                                  nil
 530                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 531                     (force-mode-line-update))
 532                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 533         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 534         ;; in mode-line of omitted buffers.
 535         (set-buffer-modified-p (and old-modified-p
 536                                     (save-excursion
 537                                       (goto-char (point-min))
 538                                       (re-search-forward dired-re-mark nil t))))
 539         count)))
 540
 541 (defun dired-omit-regexp ()
 542   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 543           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 544           (if dired-omit-extensions
 545               (concat ".";; a non-extension part should exist
 546                       "\\("
 547                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 548                       "\\)$")
 549             "")))
 550
 551 ;; Returns t if any work was done, nil otherwise.
 552 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 553   "Mark unmarked files matching REGEXP, displaying MSG.
 554 REGEXP is matched against the entire file name.  When called
 555 interactively, prompt for REGEXP.
 556 With prefix argument, unflag all those files.
 557 Optional fourth argument LOCALP is as in `dired-get-filename'."
 558   (interactive
 559    (list (read-regexp
 560           "Mark unmarked files matching regexp (default all): "
 561           nil 'dired-regexp-history)
 562          nil current-prefix-arg nil))
 563   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 564     (dired-mark-if
 565      (and
 566       ;; not already marked
 567       (looking-at-p " ")
 568       ;; uninteresting
 569       (let ((fn (dired-get-filename localp t)))
 570         (and fn (string-match-p regexp fn))))
 571      msg)))
 572
 573 \f
 574 ;;; VIRTUAL DIRED MODE.
 575
 576 ;; For browsing `ls -lR' listings in a dired-like fashion.
 577
 578 (defalias 'virtual-dired 'dired-virtual)
 579 (defun dired-virtual (dirname &optional switches)
 580   "Put this buffer into Virtual Dired mode.
 581
 582 In Virtual Dired mode, all commands that do not actually consult the
 583 filesystem will work.
 584
 585 This is useful if you want to peruse and move around in an ls -lR
 586 output file, for example one you got from an ftp server.  With
 587 ange-ftp, you can even Dired a directory containing an ls-lR file,
 588 visit that file and turn on Virtual Dired mode.  But don't try to save
 589 this file, as dired-virtual indents the listing and thus changes the
 590 buffer.
 591
 592 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 593 resume it in a later session.
 594
 595 Type \\<dired-mode-map>\\[revert-buffer] \
 596 in the Virtual Dired buffer and answer `y' to convert
 597 the virtual to a real Dired buffer again.  You don't have to do this, though:
 598 you can relist single subdirs using \\[dired-do-redisplay]."
 599
 600   ;; DIRNAME is the top level directory of the buffer.  It will become
 601   ;; its `default-directory'.  If nil, the old value of
 602   ;; default-directory is used.
 603
 604   ;; Optional SWITCHES are the ls switches to use.
 605
 606   ;; Shell wildcards will be used if there already is a `wildcard'
 607   ;; line in the buffer (thus it is a saved Dired buffer), but there
 608   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 609   ;; hand if you want them.
 610
 611   (interactive
 612    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 613   (goto-char (point-min))
 614   (or (looking-at-p "  ")
 615       ;; if not already indented, do it now:
 616       (indent-region (point-min) (point-max) 2))
 617   (or dirname (setq dirname default-directory))
 618   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 619   (setq default-directory dirname)      ; contains no wildcards
 620   (let ((wildcard (save-excursion
 621                     (goto-char (point-min))
 622                     (forward-line 1)
 623                     (and (looking-at "^  wildcard ")
 624                          (buffer-substring (match-end 0)
 625                                            (line-end-position))))))
 626   (if wildcard
 627         (setq dirname (expand-file-name wildcard default-directory))))
 628   ;; If raw ls listing (not a saved old dired buffer), give it a
 629   ;; decent subdir headerline:
 630   (goto-char (point-min))
 631   (or (looking-at-p dired-subdir-regexp)
 632       (insert "  "
 633               (directory-file-name (file-name-directory default-directory))
 634               ":\n"))
 635   (dired-mode dirname (or switches dired-listing-switches))
 636   (setq mode-name "Virtual Dired"
 637         revert-buffer-function 'dired-virtual-revert)
 638   (set (make-local-variable 'dired-subdir-alist) nil)
 639   (dired-build-subdir-alist)
 640   (goto-char (point-min))
 641   (dired-initial-position dirname))
 642
 643 (defun dired-virtual-guess-dir ()
 644   "Guess and return appropriate working directory of this buffer.
 645 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 646 based upon buffer contents.  If nothing could be guessed, returns
 647 nil."
 648
 649   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 650         (subexpr 2))
 651     (goto-char (point-min))
 652     (cond ((looking-at regexp)
 653            ;; If a saved dired buffer, look to which dir and
 654            ;; perhaps wildcard it belongs:
 655            (let ((dir (buffer-substring (match-beginning subexpr)
 656                                         (match-end subexpr))))
 657              (file-name-as-directory dir)))
 658           ;; Else no match for headerline found.  It's a raw ls listing.
 659           ;; In raw ls listings the directory does not have a headerline
 660           ;; try parent of first subdir, if any
 661           ((re-search-forward regexp nil t)
 662            (file-name-directory
 663             (directory-file-name
 664              (file-name-as-directory
 665               (buffer-substring (match-beginning subexpr)
 666                                 (match-end subexpr))))))
 667           (t                            ; if all else fails
 668            nil))))
 669
 670
 671 (defun dired-virtual-revert (&optional _arg _noconfirm)
 672   (if (not
 673        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 674       (error "Cannot revert a Virtual Dired buffer")
 675     (setq mode-name "Dired"
 676           revert-buffer-function 'dired-revert)
 677     (revert-buffer)))
 678
 679 ;; A zero-arg version of dired-virtual.
 680 (defun dired-virtual-mode ()
 681   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 682 Useful on `magic-mode-alist' with the regexp
 683
 684   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 685
 686 to put saved Dired buffers automatically into Virtual Dired mode.
 687
 688 Also useful for `auto-mode-alist' like this:
 689
 690   (add-to-list 'auto-mode-alist
 691                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 692   (interactive)
 693   (dired-virtual (dired-virtual-guess-dir)))
 694
 695 \f
 696 ;;; SMART SHELL.
 697
 698 ;; An Emacs buffer can have but one working directory, stored in the
 699 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 700 ;; several subdirectories inserted, but still has but one working directory:
 701 ;; that of the top level Dired directory in that buffer.  For some commands
 702 ;; it is appropriate that they use the current Dired directory instead of
 703 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 704 ;; mechanism is provided for special handling of the working directory in
 705 ;; special major modes.
 706
 707 (define-obsolete-variable-alias 'default-directory-alist
 708   'dired-default-directory-alist "24.1")
 709
 710 ;; It's easier to add to this alist than redefine function
 711 ;; default-directory while keeping the old information.
 712 (defconst dired-default-directory-alist
 713   '((dired-mode . (if (fboundp 'dired-current-directory)
 714                       (dired-current-directory)
 715                     default-directory)))
 716   "Alist of major modes and their opinion on `default-directory'.
 717 Each element has the form (MAJOR . EXPRESSION).
 718 The function `dired-default-directory' evaluates EXPRESSION to
 719 determine a default directory.")
 720
 721 (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd
 722 (make-obsolete-variable 'dired-default-directory-alist
 723                         "this feature is due to be removed." "24.1")
 724
 725 (defun dired-default-directory ()
 726   "Return the `dired-default-directory-alist' entry for the current major-mode.
 727 If none, return `default-directory'."
 728   ;; It looks like this was intended to be something of a "general"
 729   ;; feature, but it only ever seems to have been used in
 730   ;; dired-smart-shell-command, and doesn't seem worth keeping around.
 731   (declare (obsolete nil "24.1"))
 732   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 733       default-directory))
 734
 735 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 736   "Like function `shell-command', but in the current Virtual Dired directory."
 737   (interactive
 738    (list
 739     (read-shell-command "Shell command: " nil nil
 740                         (cond
 741                          (buffer-file-name (file-relative-name buffer-file-name))
 742                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 743     current-prefix-arg
 744     shell-command-default-error-buffer))
 745   (let ((default-directory (or (and (eq major-mode 'dired-mode)
 746                                     (dired-current-directory))
 747                                default-directory)))
 748     (shell-command command output-buffer error-buffer)))
 749
 750 \f
 751 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 752
 753 ;; Brief Description  (This feature is obsolete as of Emacs 24.1)
 754 ;;
 755 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 756 ;;
 757 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 758 ;;
 759 ;; * `dired-hack-local-variables' checks the value of
 760 ;;   `dired-local-variables-file'
 761 ;;
 762 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 763 ;;   filename found in the directory of the Dired Buffer being created.
 764 ;;
 765 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 766 ;;   include it in the Dired Buffer at the bottom.
 767 ;;
 768 ;; * Set `enable-local-variables' temporarily to the user variable
 769 ;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 770 ;;   Dired Buffer.
 771
 772 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 773   "Filename, as string, containing local Dired buffer variables to be hacked.
 774 If this file found in current directory, then it will be inserted into dired
 775 buffer and `hack-local-variables' will be run.  See Info node
 776 `(emacs)File Variables' for more information on local variables.
 777 See also `dired-enable-local-variables'."
 778   :type 'file
 779   :group 'dired)
 780
 781 (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1")
 782
 783 (defun dired-hack-local-variables ()
 784   "Evaluate local variables in `dired-local-variables-file' for Dired buffer."
 785   (declare (obsolete hack-dir-local-variables-non-file-buffer "24.1"))
 786   (and (stringp dired-local-variables-file)
 787        (file-exists-p dired-local-variables-file)
 788        (let ((opoint (point-max))
 789              (inhibit-read-only t)
 790              ;; In case user has `enable-local-variables' set to nil we
 791              ;; override it locally with dired's variable.
 792              (enable-local-variables dired-enable-local-variables))
 793          ;; Insert 'em.
 794          (save-excursion
 795            (goto-char opoint)
 796            (insert "\^L\n")
 797            (insert-file-contents dired-local-variables-file))
 798          ;; Hack 'em.
 799          (unwind-protect
 800              (let ((buffer-file-name dired-local-variables-file))
 801                (hack-local-variables))
 802            ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 803            (delete-region opoint (point-max)))
 804          ;; Make sure that the mode line shows the proper information.
 805          (dired-sort-set-mode-line))))
 806
 807 ;; Does not seem worth a dedicated command.
 808 ;; See the more general features in files-x.el.
 809 (defun dired-omit-here-always ()
 810   "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'.
 811 If in a Dired buffer, reverts it."
 812   (declare (obsolete add-dir-local-variable "24.1"))
 813   (interactive)
 814   (if (file-exists-p dired-local-variables-file)
 815       (error "Old-style dired-local-variables-file `./%s' found;
 816 replace it with a dir-locals-file `./%s'"
 817              dired-local-variables-file
 818              dir-locals-file))
 819   (if (file-exists-p dir-locals-file)
 820       (message "File `./%s' already exists." dir-locals-file)
 821     (with-temp-buffer
 822       (insert "\
 823 \((dired-mode . ((subdirs . nil)
 824                 (dired-omit-mode . t))))\n")
 825       (write-file dir-locals-file))
 826     ;; Run extra-hooks and revert directory.
 827     (when (derived-mode-p 'dired-mode)
 828       (hack-dir-local-variables-non-file-buffer)
 829       (dired-extra-startup)
 830       (dired-revert))))
 831
 832 \f
 833 ;;; GUESS SHELL COMMAND.
 834
 835 ;; Brief Description:
 836 ;;;
 837 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 838 ;;;
 839 ;; * `dired-guess-shell-command' provides smarter defaults for
 840 ;;;    dired-aux.el's `dired-read-shell-command'.
 841 ;;;
 842 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 843 ;;;    marked files.
 844 ;;;
 845 ;; * Parse `dired-guess-shell-alist-user' and
 846 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 847 ;;;   that matches the first file in the file list.
 848 ;;;
 849 ;; * If the REGEXP matches all the entries of the file list then evaluate
 850 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 851 ;;;   string.  COMMAND may be a list of commands.
 852 ;;;
 853 ;; * Return this command to `dired-guess-shell-command' which prompts user
 854 ;;;   with it.  The list of commands is put into the list of default values.
 855 ;;;   If a command is used successfully then it is stored permanently in
 856 ;;;   `dired-shell-command-history'.
 857
 858 ;; Guess what shell command to apply to a file.
 859 (defvar dired-shell-command-history nil
 860   "History list for commands that read dired-shell commands.")
 861
 862 ;; Default list of shell commands.
 863
 864 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 865 ;; install GNU zip's version of zcat.
 866
 867 (autoload 'Man-support-local-filenames "man")
 868
 869 (defvar dired-guess-shell-alist-default
 870   (list
 871    (list "\\.tar\\'"
 872          '(if dired-guess-shell-gnutar
 873               (concat dired-guess-shell-gnutar " xvf")
 874             "tar xvf")
 875          ;; Extract files into a separate subdirectory
 876          '(if dired-guess-shell-gnutar
 877               (concat "mkdir " (file-name-sans-extension file)
 878                       "; " dired-guess-shell-gnutar " -C "
 879                       (file-name-sans-extension file) " -xvf")
 880             (concat "mkdir " (file-name-sans-extension file)
 881                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 882          ;; List archive contents.
 883          '(if dired-guess-shell-gnutar
 884               (concat dired-guess-shell-gnutar " tvf")
 885             "tar tvf"))
 886
 887    ;; REGEXPS for compressed archives must come before the .Z rule to
 888    ;; be recognized:
 889    (list "\\.tar\\.Z\\'"
 890          ;; Untar it.
 891          '(if dired-guess-shell-gnutar
 892               (concat dired-guess-shell-gnutar " zxvf")
 893             (concat "zcat * | tar xvf -"))
 894          ;; Optional conversion to gzip format.
 895          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 896                   " " dired-guess-shell-znew-switches))
 897
 898    ;; gzip'ed archives
 899    (list "\\.t\\(ar\\.\\)?gz\\'"
 900          '(if dired-guess-shell-gnutar
 901               (concat dired-guess-shell-gnutar " zxvf")
 902             (concat "gunzip -qc * | tar xvf -"))
 903          ;; Extract files into a separate subdirectory
 904          '(if dired-guess-shell-gnutar
 905               (concat "mkdir " (file-name-sans-extension file)
 906                       "; " dired-guess-shell-gnutar " -C "
 907                       (file-name-sans-extension file) " -zxvf")
 908             (concat "mkdir " (file-name-sans-extension file)
 909                     "; gunzip -qc * | tar -C "
 910                     (file-name-sans-extension file) " -xvf -"))
 911          ;; Optional decompression.
 912          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 913          ;; List archive contents.
 914          '(if dired-guess-shell-gnutar
 915               (concat dired-guess-shell-gnutar " ztvf")
 916             (concat "gunzip -qc * | tar tvf -")))
 917
 918    ;; bzip2'ed archives
 919    (list "\\.t\\(ar\\.bz2\\|bz\\)\\'"
 920          "bunzip2 -c * | tar xvf -"
 921          ;; Extract files into a separate subdirectory
 922          '(concat "mkdir " (file-name-sans-extension file)
 923                   "; bunzip2 -c * | tar -C "
 924                   (file-name-sans-extension file) " -xvf -")
 925          ;; Optional decompression.
 926          "bunzip2")
 927
 928    ;; xz'ed archives
 929    (list "\\.t\\(ar\\.\\)?xz\\'"
 930          "unxz -c * | tar xvf -"
 931          ;; Extract files into a separate subdirectory
 932          '(concat "mkdir " (file-name-sans-extension file)
 933                   "; unxz -c * | tar -C "
 934                   (file-name-sans-extension file) " -xvf -")
 935          ;; Optional decompression.
 936          "unxz")
 937
 938    '("\\.shar\\.Z\\'" "zcat * | unshar")
 939    '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar")
 940
 941    '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr")
 942    (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -"
 943          ;; Optional decompression.
 944          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 945    (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -"
 946          ;; Optional conversion to gzip format.
 947          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 948                   " " dired-guess-shell-znew-switches))
 949
 950    '("\\.patch\\'" "cat * | patch")
 951    (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch"
 952          ;; Optional decompression.
 953          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 954    (list "\\.patch\\.Z\\'" "zcat * | patch"
 955          ;; Optional conversion to gzip format.
 956          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 957                   " " dired-guess-shell-znew-switches))
 958
 959    ;; The following four extensions are useful with dired-man ("N" key)
 960    ;; FIXME "man ./" does not work with dired-do-shell-command,
 961    ;; because there seems to be no way for us to modify the filename,
 962    ;; only the command.  Hmph.  `dired-man' works though.
 963    (list "\\.\\(?:[0-9]\\|man\\)\\'"
 964          '(let ((loc (Man-support-local-filenames)))
 965             (cond ((eq loc 'man-db) "man -l")
 966                   ((eq loc 'man) "man ./")
 967                   (t
 968                    "cat * | tbl | nroff -man -h | col -b"))))
 969    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'"
 970          '(let ((loc (Man-support-local-filenames)))
 971             (cond ((eq loc 'man-db)
 972                    "man -l")
 973                   ((eq loc 'man)
 974                    "man ./")
 975                   (t "gunzip -qc * | tbl | nroff -man -h | col -b")))
 976          ;; Optional decompression.
 977          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 978    (list "\\.[0-9]\\.Z\\'"
 979          '(let ((loc (Man-support-local-filenames)))
 980             (cond ((eq loc 'man-db) "man -l")
 981                   ((eq loc 'man) "man ./")
 982                   (t "zcat * | tbl | nroff -man -h | col -b")))
 983          ;; Optional conversion to gzip format.
 984          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 985                   " " dired-guess-shell-znew-switches))
 986    '("\\.pod\\'" "perldoc" "pod2man * | nroff -man")
 987
 988    '("\\.dvi\\'" "xdvi" "dvips")        ; preview and printing
 989    '("\\.au\\'" "play")                 ; play Sun audiofiles
 990    '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p")
 991    '("\\.ogg\\'" "ogg123")
 992    '("\\.mp3\\'" "mpg123")
 993    '("\\.wav\\'" "play")
 994    '("\\.uu\\'" "uudecode")             ; for uudecoded files
 995    '("\\.hqx\\'" "mcvert")
 996    '("\\.sh\\'" "sh")                   ; execute shell scripts
 997    '("\\.xbm\\'" "bitmap")              ; view X11 bitmaps
 998    '("\\.gp\\'" "gnuplot")
 999    '("\\.p[bgpn]m\\'" "xloadimage")
1000    '("\\.gif\\'" "xloadimage")          ; view gif pictures
1001    '("\\.tif\\'" "xloadimage")
1002    '("\\.png\\'" "display")             ; xloadimage 4.1 doesn't grok PNG
1003    '("\\.jpe?g\\'" "xloadimage")
1004    '("\\.fig\\'" "xfig")                ; edit fig pictures
1005    '("\\.out\\'" "xgraph")              ; for plotting purposes.
1006    '("\\.tex\\'" "latex" "tex")
1007    '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi")
1008    '("\\.pdf\\'" "xpdf")
1009    '("\\.doc\\'" "antiword" "strings")
1010    '("\\.rpm\\'" "rpm -qilp" "rpm -ivh")
1011    '("\\.dia\\'" "dia")
1012    '("\\.mgp\\'" "mgp")
1013
1014    ;; Some other popular archivers.
1015    (list "\\.zip\\'" "unzip" "unzip -l"
1016          ;; Extract files into a separate subdirectory
1017          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1018                   " -d " (file-name-sans-extension file)))
1019    '("\\.zoo\\'" "zoo x//")
1020    '("\\.lzh\\'" "lharc x")
1021    '("\\.arc\\'" "arc x")
1022    '("\\.shar\\'" "unshar")
1023    '("\\.rar\\'" "unrar x")
1024    '("\\.7z\\'" "7z x")
1025
1026    ;; Compression.
1027    (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1028    (list "\\.dz\\'" "dictunzip")
1029    (list "\\.bz2\\'" "bunzip2")
1030    (list "\\.xz\\'" "unxz")
1031    (list "\\.Z\\'" "uncompress"
1032          ;; Optional conversion to gzip format.
1033          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1034                   " " dired-guess-shell-znew-switches))
1035
1036    '("\\.sign?\\'" "gpg --verify"))
1037
1038   "Default alist used for shell command guessing.
1039 See `dired-guess-shell-alist-user'.")
1040
1041 (defcustom dired-guess-shell-alist-user nil
1042   "User-defined alist of rules for suggested commands.
1043 These rules take precedence over the predefined rules in the variable
1044 `dired-guess-shell-alist-default' (to which they are prepended).
1045
1046 Each element of this list looks like
1047
1048     (REGEXP COMMAND...)
1049
1050 where each COMMAND can either be a string or a Lisp expression that evaluates
1051 to a string.  This expression can access the file name as the variable `file'.
1052 If several COMMANDs are given, the first one will be the default
1053 and the rest will be added temporarily to the history and can be retrieved
1054 with \\[previous-history-element] (M-p) .
1055
1056 The variable `dired-guess-shell-case-fold-search' controls whether
1057 REGEXP is matched case-sensitively.
1058
1059 You can set this variable in your ~/.emacs.  For example, to add rules for
1060 `.foo' and `.bar' files, write
1061
1062  (setq dired-guess-shell-alist-user
1063         '((\"\\\\.foo\\\\'\" \"FOO-COMMAND\")
1064           (\"\\\\.bar\\\\'\"
1065            (if condition
1066               \"BAR-COMMAND-1\"
1067             \"BAR-COMMAND-2\"))))"
1068   :group 'dired-x
1069   :type '(alist :key-type regexp :value-type (repeat sexp)))
1070
1071 (defcustom dired-guess-shell-case-fold-search t
1072   "If non-nil, `dired-guess-shell-alist-default' and
1073 `dired-guess-shell-alist-user' are matched case-insensitively."
1074   :group 'dired-x
1075   :type 'boolean)
1076
1077 (defun dired-guess-default (files)
1078   "Return a shell command, or a list of commands, appropriate for FILES.
1079 See `dired-guess-shell-alist-user'."
1080
1081   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1082          ;; Prepend the user's alist to the default alist.
1083          (alist (append dired-guess-shell-alist-user
1084                         dired-guess-shell-alist-default))
1085          (file (car files))
1086          (flist (cdr files))
1087          elt regexp cmds)
1088
1089     ;; Find the first match in the alist for first file in FILES.
1090     (while alist
1091       (setq elt (car alist)
1092             regexp (car elt)
1093             alist (cdr alist))
1094       (if (string-match-p regexp file)
1095           (setq cmds (cdr elt)
1096                 alist nil)))
1097
1098     ;; If more than one file, see if all of FILES match regular expression.
1099     (while (and flist
1100                 (string-match-p regexp (car flist)))
1101       (setq flist (cdr flist)))
1102
1103     ;; If flist is still non-nil, then do not guess since this means that not
1104     ;; all the files in FILES were matched by the regexp.
1105     (setq cmds (and (not flist) cmds))
1106
1107     ;; Return commands or nil if flist is still non-nil.
1108     ;; Evaluate the commands in order that any logical testing will be done.
1109     (if (cdr cmds)
1110         (delete-dups (mapcar (lambda (cmd) (eval cmd `((file . ,file)))) cmds))
1111       (eval (car cmds) `((file . ,file))))))            ; single command
1112
1113 (defun dired-guess-shell-command (prompt files)
1114   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1115   (let ((default (dired-guess-default files))
1116         default-list val)
1117     (if (null default)
1118         ;; Nothing to guess
1119         (read-shell-command prompt nil 'dired-shell-command-history)
1120       (setq prompt (replace-regexp-in-string ": $" " " prompt))
1121       (if (listp default)
1122           ;; More than one guess
1123           (setq default-list default
1124                 default (car default)
1125                 prompt (concat
1126                         prompt
1127                         (format "{%d guesses} " (length default-list))))
1128         ;; Just one guess
1129         (setq default-list (list default)))
1130       ;; Put the first guess in the prompt but not in the initial value.
1131       (setq prompt (concat prompt (format "[%s]: " default)))
1132       ;; All guesses can be retrieved with M-n
1133       (setq val (read-shell-command prompt nil
1134                                     'dired-shell-command-history
1135                                     default-list))
1136       ;; If we got a return, then return default.
1137       (if (equal val "") default val))))
1138
1139 \f
1140 ;;; RELATIVE SYMBOLIC LINKS.
1141
1142 (declare-function make-symbolic-link "fileio.c")
1143
1144 (defvar dired-keep-marker-relsymlink ?S
1145   "See variable `dired-keep-marker-move'.")
1146
1147 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1148   "Make a symbolic link (pointing to FILE1) in FILE2.
1149 The link is relative (if possible), for example
1150
1151     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1152
1153 results in
1154
1155     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1156   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1157   (let (name1 name2 len1 len2 (index 0) sub)
1158     (setq file1 (expand-file-name file1)
1159           file2 (expand-file-name file2)
1160           len1 (length file1)
1161           len2 (length file2))
1162     ;; Find common initial file name components:
1163     (let (next)
1164       (while (and (setq next (string-match "/" file1 index))
1165                   (< (setq next (1+ next)) (min len1 len2))
1166                   ;; For the comparison, both substrings must end in
1167                   ;; `/', so NEXT is *one plus* the result of the
1168                   ;; string-match.
1169                   ;; E.g., consider the case of linking "/tmp/a/abc"
1170                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1171                   ;; of "/tmp/" as common initial component
1172                   (string-equal (substring file1 0 next)
1173                                 (substring file2 0 next)))
1174         (setq index next))
1175       (setq name2 file2
1176             sub (substring file1 0 index)
1177             name1 (substring file1 index)))
1178     (if (string-equal sub "/")
1179         ;; No common initial file name found
1180         (setq name1 file1)
1181       ;; Else they have a common parent directory
1182       (let ((tem (substring file2 index))
1183             (start 0)
1184             (count 0))
1185         ;; Count number of slashes we must compensate for ...
1186         (while (setq start (string-match "/" tem start))
1187           (setq count (1+ count)
1188                 start (1+ start)))
1189         ;; ... and prepend a "../" for each slash found:
1190         (dotimes (_ count)
1191           (setq name1 (concat "../" name1)))))
1192     (make-symbolic-link
1193      (directory-file-name name1)        ; must not link to foo/
1194                                         ; (trailing slash!)
1195      name2 ok-if-already-exists)))
1196
1197 (autoload 'dired-do-create-files "dired-aux")
1198
1199 ;;;###autoload
1200 (defun dired-do-relsymlink (&optional arg)
1201    "Relative symlink all marked (or next ARG) files into a directory.
1202 Otherwise make a relative symbolic link to the current file.
1203 This creates relative symbolic links like
1204
1205     foo -> ../bar/foo
1206
1207 not absolute ones like
1208
1209     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1210
1211 For absolute symlinks, use \\[dired-do-symlink]."
1212   (interactive "P")
1213   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1214                            "RelSymLink" arg dired-keep-marker-relsymlink))
1215
1216 (autoload 'dired-mark-read-regexp "dired-aux")
1217 (autoload 'dired-do-create-files-regexp "dired-aux")
1218
1219 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1220   "RelSymlink all marked files containing REGEXP to NEWNAME.
1221 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1222 for more info."
1223   (interactive (dired-mark-read-regexp "RelSymLink"))
1224   (dired-do-create-files-regexp
1225    #'dired-make-relative-symlink
1226    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1227
1228 \f
1229 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1230
1231 ;; Brief Description:
1232 ;;;
1233 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1234 ;;;
1235 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1236 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1237 ;;;
1238 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1239 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1240 ;;;
1241 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1242 ;;;   list each time.
1243 ;;;
1244 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1245 ;;;   element of FILE-LIST.
1246 ;;;
1247 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1248 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1249 ;;;   cognizant of the window-configuration.
1250 ;;;
1251 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1252 ;;;   of FILE-LIST giving each a window of height `size'.
1253
1254 (defun dired-do-find-marked-files (&optional noselect)
1255   "Find all marked files displaying all of them simultaneously.
1256 With optional NOSELECT just find files but do not select them.
1257
1258 The current window is split across all files marked, as evenly as possible.
1259 Remaining lines go to bottom-most window.  The number of files that can be
1260 displayed this way is restricted by the height of the current window and
1261 `window-min-height'.
1262
1263 To keep Dired buffer displayed, type \\[split-window-below] first.
1264 To display just marked files, type \\[delete-other-windows] first."
1265   (interactive "P")
1266   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1267
1268 (defun dired-simultaneous-find-file (file-list noselect)
1269   "Visit all files in FILE-LIST and display them simultaneously.
1270 The current window is split across all files in FILE-LIST, as evenly as
1271 possible.  Remaining lines go to the bottom-most window.  The number of
1272 files that can be displayed this way is restricted by the height of the
1273 current window and the variable `window-min-height'.  With non-nil
1274 NOSELECT the files are merely found but not selected."
1275   ;; We don't make this function interactive because it is usually too clumsy
1276   ;; to specify FILE-LIST interactively unless via dired.
1277   (let (size)
1278     (if noselect
1279         ;; Do not select the buffer.
1280         (find-file-noselect (car file-list))
1281       ;; We will have to select the buffer.  Calculate and check window size.
1282       (setq size (/ (window-height) (length file-list)))
1283       (or (<= window-min-height size)
1284           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1285       (find-file (car file-list)))
1286     ;; Decrement.
1287     (dolist (file (cdr file-list))
1288       (if noselect
1289           ;; Do not select the buffer.
1290           (find-file-noselect file)
1291         ;; Vertically split off a window of desired size.  Upper window will
1292         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1293         (select-window (split-window nil size))
1294         (find-file file)))))
1295
1296 \f
1297 ;;; MISCELLANEOUS COMMANDS.
1298
1299 ;; Run man on files.
1300
1301 (declare-function Man-getpage-in-background "man" (topic))
1302
1303 (defvar manual-program) ; from man.el
1304
1305 (defun dired-man ()
1306   "Run `man' on this file."
1307 ;; Used also to say: "Display old buffer if buffer name matches filename."
1308 ;; but I have no idea what that means.
1309   (interactive)
1310   (require 'man)
1311   (let* ((file (dired-get-filename))
1312          (manual-program (replace-regexp-in-string "\\*" "%s"
1313                           (dired-guess-shell-command
1314                            "Man command: " (list file)))))
1315     (Man-getpage-in-background file)))
1316
1317 ;; Run Info on files.
1318
1319 (defun dired-info ()
1320   "Run `info' on this file."
1321   (interactive)
1322   (info (dired-get-filename)))
1323
1324 ;; Run mail on mail folders.
1325
1326 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1327 (defvar vm-folder-directory)
1328
1329 (defun dired-vm (&optional read-only)
1330   "Run VM on this file.
1331 With optional prefix argument, visits the folder read-only.
1332 Otherwise obeys the value of `dired-vm-read-only-folders'."
1333   (interactive "P")
1334   (let ((dir (dired-current-directory))
1335         (fil (dired-get-filename)))
1336     (vm-visit-folder fil (or read-only
1337                              (eq t dired-vm-read-only-folders)
1338                              (and dired-vm-read-only-folders
1339                                   (not (file-writable-p fil)))))
1340     ;; So that pressing `v' inside VM does prompt within current directory:
1341     (set (make-local-variable 'vm-folder-directory) dir)))
1342
1343 (defun dired-rmail ()
1344   "Run RMAIL on this file."
1345   (interactive)
1346   (rmail (dired-get-filename)))
1347
1348 (defun dired-do-run-mail ()
1349   "Visit the current file as a mailbox, using VM or RMAIL.
1350 Prompt for confirmation first; if the user says yes, call
1351 `dired-vm' if `dired-bind-vm' is non-nil, `dired-rmail'
1352 otherwise."
1353   (interactive)
1354   (let ((file (dired-get-filename t)))
1355     (if dired-bind-vm
1356         (if (y-or-n-p (concat "Visit `" file
1357                               "' as a mail folder with VM?"))
1358             (dired-vm))
1359       ;; Read mail folder using rmail.
1360       (if (y-or-n-p (concat "Visit `" file
1361                             "' as a mailbox with RMAIL?"))
1362           (dired-rmail)))))
1363
1364 \f
1365 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1366
1367 ;; This should be a builtin
1368 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1369   "Return t if BUFFER1 is more recently used than BUFFER2.
1370 Considers buffers closer to the car of `buffer-list' to be more recent."
1371   (and (not (equal buffer1 buffer2))
1372        (memq buffer1 (buffer-list))
1373        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1374
1375 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1376 ;; (defun dired-buffers-for-dir-exact (dir)
1377 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1378 ;; ;; at top level, or as subdirectory.
1379 ;; ;; Top level matches must match the wildcard part too, if any.
1380 ;; ;; The list is in reverse order of buffer creation, most recent last.
1381 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1382 ;; ;; dired-buffers.
1383 ;;   (let ((alist dired-buffers) result elt)
1384 ;;     (while alist
1385 ;;       (setq elt (car alist)
1386 ;;             alist (cdr alist))
1387 ;;       (let ((buf (cdr elt)))
1388 ;;         (if (buffer-name buf)
1389 ;;             ;; Top level must match exactly against dired-directory in
1390 ;;             ;; case one of them is a wildcard.
1391 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1392 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1393 ;;                 (setq result (cons buf result)))
1394 ;;           ;; else buffer is killed - clean up:
1395 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1396 ;;     result))
1397
1398 \f
1399 ;; Does anyone use this? - lrd 6/29/93.
1400 ;; Apparently people do use it. - lrd 12/22/97.
1401
1402 (defun dired-mark-sexp (predicate &optional unflag-p)
1403   "Mark files for which PREDICATE returns non-nil.
1404 With a prefix arg, unmark or unflag those files instead.
1405
1406 PREDICATE is a lisp expression that can refer to the following symbols:
1407
1408     inode  [integer] the inode of the file (only for ls -i output)
1409     s      [integer] the size of the file for ls -s output
1410                      (usually in blocks or, with -k, in KByte)
1411     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1412     nlink  [integer] number of links to file
1413     uid    [string]  owner
1414     gid    [string]  group  (If the gid is not displayed by ls,
1415                      this will still be set (to the same as uid))
1416     size   [integer] file size in bytes
1417     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1418     name   [string]  the name of the file
1419     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1420
1421 For example, use
1422
1423         (equal 0 size)
1424
1425 to mark all zero length files."
1426   ;; Using sym="" instead of nil avoids the trap of
1427   ;; (string-match "foo" sym) into which a user would soon fall.
1428   ;; Give `equal' instead of `=' in the example, as this works on
1429   ;; integers and strings.
1430   (interactive "xMark if (lisp expr): \nP")
1431   (message "%s" predicate)
1432   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1433         inode s mode nlink uid gid size time name sym)
1434     (dired-mark-if
1435      (save-excursion
1436        (and
1437         ;; Sets vars
1438         ;;                inode s mode nlink uid gid size time name sym
1439
1440         ;; according to current file line.  Returns t for success, nil if
1441         ;; there is no file line.  Upon success, all variables are set, either
1442         ;; to nil or the appropriate value, so they need not be initialized.
1443         ;; Moves point within the current line.
1444         (dired-move-to-filename)
1445         (let (pos
1446               (mode-len 10) ; length of mode string
1447               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1448               (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1449           (beginning-of-line)
1450           (forward-char 2)
1451           (if (looking-at dired-re-inode-size)
1452               (progn
1453                 (goto-char (match-end 0))
1454                 (setq inode (string-to-number
1455                              (buffer-substring (match-beginning 1)
1456                                                (match-end 1)))
1457                       s (string-to-number
1458                          (buffer-substring (match-beginning 2)
1459                                            (match-end 2)))))
1460             (setq inode nil
1461                   s nil))
1462           (setq mode (buffer-substring (point) (+ mode-len (point))))
1463           (forward-char mode-len)
1464           ;; Skip any extended attributes marker ("." or "+").
1465           (or (looking-at " ")
1466               (forward-char 1))
1467           (setq nlink (read (current-buffer)))
1468           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1469           (setq uid (buffer-substring (1+ (point))
1470                                       (progn (forward-word 1) (point))))
1471           (re-search-forward directory-listing-before-filename-regexp)
1472           (goto-char (match-beginning 1))
1473           (forward-char -1)
1474           (setq size (string-to-number
1475                       (buffer-substring (save-excursion
1476                                           (backward-word 1)
1477                                           (setq pos (point)))
1478                                         (point))))
1479           (goto-char pos)
1480           (backward-word 1)
1481           ;; if no gid is displayed, gid will be set to uid
1482           ;; but user will then not reference it anyway in PREDICATE.
1483           (setq gid (buffer-substring (save-excursion
1484                                         (forward-word 1) (point))
1485                                       (point))
1486                 time (buffer-substring (match-beginning 1)
1487                                        (1- (dired-move-to-filename)))
1488                 name (buffer-substring (point)
1489                                        (or
1490                                         (dired-move-to-end-of-filename t)
1491                                         (point)))
1492                 sym (if (looking-at-p " -> ")
1493                         (buffer-substring (progn (forward-char 4) (point))
1494                                           (line-end-position))
1495                       ""))
1496           t)
1497         (eval predicate
1498               `((inode . ,inode)
1499                 (s . ,s)
1500                 (mode . ,mode)
1501                 (nlink . ,nlink)
1502                 (uid . ,uid)
1503                 (gid . ,gid)
1504                 (size . ,size)
1505                 (time . ,time)
1506                 (name . ,name)
1507                 (sym . ,sym)))))
1508      (format "'%s file" predicate))))
1509
1510 \f
1511 ;;; FIND FILE AT POINT.
1512
1513 (defcustom dired-x-hands-off-my-keys t
1514   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1515 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1516 If you change this variable without using \\[customize] after `dired-x.el'
1517 is loaded then call \\[dired-x-bind-find-file]."
1518   :type 'boolean
1519   :initialize 'custom-initialize-default
1520   :set (lambda (symbol value)
1521          (set symbol value)
1522          (dired-x-bind-find-file))
1523   :group 'dired-x)
1524
1525 (defun dired-x-bind-find-file ()
1526   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1527 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1528 Binding direction based on `dired-x-hands-off-my-keys'."
1529   (interactive)
1530   (if (called-interactively-p 'interactive)
1531       (setq dired-x-hands-off-my-keys
1532             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1533   (define-key (current-global-map) [remap find-file]
1534     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file))
1535   (define-key (current-global-map) [remap find-file-other-window]
1536     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window)))
1537
1538 ;; Now call it so binding is correct.  This could go in the :initialize
1539 ;; slot, but then dired-x-bind-find-file has to be defined before the
1540 ;; defcustom, and we get free variable warnings.
1541 (dired-x-bind-find-file)
1542
1543 (defun dired-x-find-file (filename)
1544   "Edit file FILENAME.
1545 Like `find-file', except that when called interactively with a
1546 prefix argument, it offers the filename near point as a default."
1547   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1548   (find-file filename))
1549
1550 (defun dired-x-find-file-other-window (filename)
1551   "Edit file FILENAME, in another window.
1552 Like `find-file-other-window', except that when called interactively with
1553 a prefix argument, when it offers the filename near point as a default."
1554   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1555   (find-file-other-window filename))
1556
1557 ;;; Internal functions.
1558
1559 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1560 (defun dired-filename-at-point ()
1561   "Return the filename closest to point, expanded.
1562 Point should be in or after a filename."
1563   (save-excursion
1564     ;; First see if just past a filename.
1565     (or (eobp)                             ; why?
1566         (when (looking-at-p "[] \t\n[{}()]") ; whitespace or some parens
1567           (skip-chars-backward " \n\t\r({[]})")
1568           (or (bobp) (backward-char 1))))
1569     (let ((filename-chars "-.[:alnum:]_/:$+@")
1570           start prefix)
1571       (if (looking-at-p (format "[%s]" filename-chars))
1572           (progn
1573             (skip-chars-backward filename-chars)
1574             (setq start (point)
1575                   prefix
1576                   ;; This is something to do with ange-ftp filenames.
1577                   ;; It convert foo@bar to /foo@bar.
1578                   ;; But when does the former occur in dired buffers?
1579                   (and (string-match-p
1580                         "^\\w+@"
1581                         (buffer-substring start (line-end-position)))
1582                        "/"))
1583             (if (string-match-p "[/~]" (char-to-string (preceding-char)))
1584                 (setq start (1- start)))
1585             (skip-chars-forward filename-chars))
1586         (error "No file found around point!"))
1587       ;; Return string.
1588       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1589
1590 (defun dired-x-read-filename-at-point (prompt)
1591   "Return filename prompting with PROMPT with completion.
1592 If `current-prefix-arg' is non-nil, uses name at point as guess."
1593   (if current-prefix-arg
1594       (let ((guess (dired-filename-at-point)))
1595         (read-file-name prompt
1596                         (file-name-directory guess)
1597                         guess
1598                         nil (file-name-nondirectory guess)))
1599     (read-file-name prompt default-directory)))
1600
1601 (define-obsolete-function-alias 'read-filename-at-point
1602   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1603 \f
1604 ;;; BUG REPORTS
1605
1606 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1607
1608 \f
1609 ;; As Barry Warsaw would say: "This might be useful..."
1610 (provide 'dired-x)
1611
1612 ;; Local Variables:
1613 ;; byte-compile-dynamic: t
1614 ;; generated-autoload-file: "dired.el"
1615 ;; End:
1616
1617 ;;; dired-x.el ends here