lisp/window.el

   1 ;;; window.el --- GNU Emacs window commands aside from those written in C
   2
   3 ;; Copyright (C) 1985, 1989, 1992, 1993, 1994, 2000, 2001, 2002
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Window tree functions.
  29
  30 ;;; Code:
  31
  32 (defmacro save-selected-window (&rest body)
  33   "Execute BODY, then select the window that was selected before BODY.
  34 Also restore the selected window of each frame as it was at the start
  35 of this construct.
  36 However, if a window has become dead, don't get an error,
  37 just refrain from reselecting it."
  38   `(let ((save-selected-window-window (selected-window))
  39          (save-selected-window-alist
  40           (mapcar (lambda (frame) (list frame (frame-selected-window frame)))
  41                   (frame-list))))
  42      (unwind-protect
  43          (progn ,@body)
  44        (dolist (elt save-selected-window-alist)
  45          (and (frame-live-p (car elt))
  46               (window-live-p (cadr elt))
  47               (set-frame-selected-window (car elt) (cadr elt))))
  48        (if (window-live-p save-selected-window-window)
  49            (select-window save-selected-window-window)))))
  50
  51 (defun window-body-height (&optional window)
  52   "Return number of lines in window WINDOW for actual buffer text.
  53 This does not include the mode line (if any) or the header line (if any)."
  54   (or window (setq window (selected-window)))
  55   (if (window-minibuffer-p window)
  56       (window-height window)
  57     (with-current-buffer (window-buffer window)
  58       (max 1 (- (window-height window)
  59                 (if mode-line-format 1 0)
  60                 (if header-line-format 1 0))))))
  61
  62 (defun one-window-p (&optional nomini all-frames)
  63   "Return non-nil if the selected window is the only window (in its frame).
  64 Optional arg NOMINI non-nil means don't count the minibuffer
  65 even if it is active.
  66
  67 The optional arg ALL-FRAMES t means count windows on all frames.
  68 If it is `visible', count windows on all visible frames.
  69 ALL-FRAMES nil or omitted means count only the selected frame,
  70 plus the minibuffer it uses (which may be on another frame).
  71 If ALL-FRAMES is neither nil nor t, count only the selected frame."
  72   (let ((base-window (selected-window)))
  73     (if (and nomini (eq base-window (minibuffer-window)))
  74         (setq base-window (next-window base-window)))
  75     (eq base-window
  76         (next-window base-window (if nomini 'arg) all-frames))))
  77
  78 (defun window-current-scroll-bars (&optional window)
  79   "Return the current scroll-bar settings in window WINDOW.
  80 Value is a cons (VERTICAL . HORISONTAL) where VERTICAL specifies the
  81 current location of the vertical scroll-bars (left, right, or nil),
  82 and HORISONTAL specifies the current location of the horisontal scroll
  83 bars (top, bottom, or nil)."
  84   (let ((vert (nth 2 (window-scroll-bars window)))
  85         (hor nil))
  86     (when (or (eq vert t) (eq hor t))
  87       (let ((fcsb (frame-current-scroll-bars
  88                    (window-frame (or window (selected-window))))))
  89         (if (eq vert t)
  90             (setq vert (car fcsb)))
  91         (if (eq hor t)
  92             (setq hor (cdr fcsb)))))
  93     (cons vert hor)))
  94
  95 (defun walk-windows (proc &optional minibuf all-frames)
  96   "Cycle through all visible windows, calling PROC for each one.
  97 PROC is called with a window as argument.
  98
  99 Optional second arg MINIBUF t means count the minibuffer window even
 100 if not active.  MINIBUF nil or omitted means count the minibuffer iff
 101 it is active.  MINIBUF neither t nor nil means not to count the
 102 minibuffer even if it is active.
 103
 104 Several frames may share a single minibuffer; if the minibuffer
 105 counts, all windows on all frames that share that minibuffer count
 106 too.  Therefore, if you are using a separate minibuffer frame
 107 and the minibuffer is active and MINIBUF says it counts,
 108 `walk-windows' includes the windows in the frame from which you
 109 entered the minibuffer, as well as the minibuffer window.
 110
 111 ALL-FRAMES is the optional third argument.
 112 ALL-FRAMES nil or omitted means cycle within the frames as specified above.
 113 ALL-FRAMES = `visible' means include windows on all visible frames.
 114 ALL-FRAMES = 0 means include windows on all visible and iconified frames.
 115 ALL-FRAMES = t means include windows on all frames including invisible frames.
 116 If ALL-FRAMES is a frame, it means include windows on that frame.
 117 Anything else means restrict to the selected frame."
 118   ;; If we start from the minibuffer window, don't fail to come back to it.
 119   (if (window-minibuffer-p (selected-window))
 120       (setq minibuf t))
 121   (save-selected-window
 122     (if (framep all-frames)
 123         (select-window (frame-first-window all-frames)))
 124     (let* (walk-windows-already-seen
 125            (walk-windows-current (selected-window)))
 126       (while (progn
 127                (setq walk-windows-current
 128                      (next-window walk-windows-current minibuf all-frames))
 129                (not (memq walk-windows-current walk-windows-already-seen)))
 130         (setq walk-windows-already-seen
 131               (cons walk-windows-current walk-windows-already-seen))
 132         (funcall proc walk-windows-current)))))
 133
 134 (defun get-window-with-predicate (predicate &optional minibuf
 135                                             all-frames default)
 136   "Return a window satisfying PREDICATE.
 137
 138 This function cycles through all visible windows using `walk-windows',
 139 calling PREDICATE on each one.  PREDICATE is called with a window as
 140 argument.  The first window for which PREDICATE returns a non-nil
 141 value is returned.  If no window satisfies PREDICATE, DEFAULT is
 142 returned.
 143
 144 Optional second arg MINIBUF t means count the minibuffer window even
 145 if not active.  MINIBUF nil or omitted means count the minibuffer iff
 146 it is active.  MINIBUF neither t nor nil means not to count the
 147 minibuffer even if it is active.
 148
 149 Several frames may share a single minibuffer; if the minibuffer
 150 counts, all windows on all frames that share that minibuffer count
 151 too.  Therefore, if you are using a separate minibuffer frame
 152 and the minibuffer is active and MINIBUF says it counts,
 153 `walk-windows' includes the windows in the frame from which you
 154 entered the minibuffer, as well as the minibuffer window.
 155
 156 ALL-FRAMES is the optional third argument.
 157 ALL-FRAMES nil or omitted means cycle within the frames as specified above.
 158 ALL-FRAMES = `visible' means include windows on all visible frames.
 159 ALL-FRAMES = 0 means include windows on all visible and iconified frames.
 160 ALL-FRAMES = t means include windows on all frames including invisible frames.
 161 If ALL-FRAMES is a frame, it means include windows on that frame.
 162 Anything else means restrict to the selected frame."
 163   (catch 'found
 164     (walk-windows #'(lambda (window)
 165                       (when (funcall predicate window)
 166                         (throw 'found window)))
 167                   minibuf all-frames)
 168     default))
 169
 170 (defalias 'some-window 'get-window-with-predicate)
 171
 172 (defun minibuffer-window-active-p (window)
 173   "Return t if WINDOW (a minibuffer window) is now active."
 174   (eq window (active-minibuffer-window)))
 175 \f
 176 (defun count-windows (&optional minibuf)
 177    "Return the number of visible windows.
 178 This counts the windows in the selected frame and (if the minibuffer is
 179 to be counted) its minibuffer frame (if that's not the same frame).
 180 The optional arg MINIBUF non-nil means count the minibuffer
 181 even if it is inactive."
 182    (let ((count 0))
 183      (walk-windows (function (lambda (w)
 184                                (setq count (+ count 1))))
 185                    minibuf)
 186      count))
 187
 188 (defun window-safely-shrinkable-p (&optional window)
 189   "Non-nil if the WINDOW can be shrunk without shrinking other windows.
 190 If WINDOW is nil or omitted, it defaults to the currently selected window."
 191   (save-selected-window
 192     (when window (select-window window))
 193     (or (and (not (eq window (frame-first-window)))
 194              (= (car (window-edges))
 195                 (car (window-edges (previous-window)))))
 196         (= (car (window-edges))
 197            (car (window-edges (next-window)))))))
 198
 199 (defun balance-windows ()
 200   "Make all visible windows the same height (approximately)."
 201   (interactive)
 202   (let ((count -1) levels newsizes level-size
 203         ;; Don't count the lines that are above the uppermost windows.
 204         ;; (These are the menu bar lines, if any.)
 205         (mbl (nth 1 (window-edges (frame-first-window (selected-frame)))))
 206         (last-window (previous-window (frame-first-window (selected-frame))))
 207         ;; Don't count the lines that are past the lowest main window.
 208         total)
 209     ;; Bottom edge of last window determines what size we have to work with.
 210     (setq total
 211           (+ (window-height last-window)
 212              (nth 1 (window-edges last-window))))
 213
 214     ;; Find all the different vpos's at which windows start,
 215     ;; then count them.  But ignore levels that differ by only 1.
 216     (let (tops (prev-top -2))
 217       (walk-windows (function (lambda (w)
 218                                 (setq tops (cons (nth 1 (window-edges w))
 219                                                  tops))))
 220                     'nomini)
 221       (setq tops (sort tops '<))
 222       (while tops
 223         (if (> (car tops) (1+ prev-top))
 224             (setq prev-top (car tops)
 225                   count (1+ count)))
 226         (setq levels (cons (cons (car tops) count) levels))
 227         (setq tops (cdr tops)))
 228       (setq count (1+ count)))
 229     ;; Subdivide the frame into desired number of vertical levels.
 230     (setq level-size (/ (- total mbl) count))
 231     (save-selected-window
 232       ;; Set up NEWSIZES to map windows to their desired sizes.
 233       ;; If a window ends at the bottom level, don't include
 234       ;; it in NEWSIZES.  Those windows get the right sizes
 235       ;; by adjusting the ones above them.
 236       (walk-windows (function
 237                      (lambda (w)
 238                        (let ((newtop (cdr (assq (nth 1 (window-edges w))
 239                                                 levels)))
 240                              (newbot (cdr (assq (+ (window-height w)
 241                                                    (nth 1 (window-edges w)))
 242                                                 levels))))
 243                          (if newbot
 244                              (setq newsizes
 245                                    (cons (cons w (* level-size (- newbot newtop)))
 246                                          newsizes))))))
 247                     'nomini)
 248       ;; Make walk-windows start with the topmost window.
 249       (select-window (previous-window (frame-first-window (selected-frame))))
 250       (let (done (count 0))
 251         ;; Give each window its precomputed size, or at least try.
 252         ;; Keep trying until they all get the intended sizes,
 253         ;; but not more than 3 times (to prevent infinite loop).
 254         (while (and (not done) (< count 3))
 255           (setq done t)
 256           (setq count (1+ count))
 257           (walk-windows (function (lambda (w)
 258                                     (select-window w)
 259                                     (let ((newsize (cdr (assq w newsizes))))
 260                                       (when newsize
 261                                         (enlarge-window (- newsize
 262                                                            (window-height))
 263                                                         nil t)
 264                                         (unless (= (window-height) newsize)
 265                                           (setq done nil))))))
 266                         'nomini))))))
 267 \f
 268 ;; I think this should be the default; I think people will prefer it--rms.
 269 (defcustom split-window-keep-point t
 270   "*If non-nil, split windows keeps the original point in both children.
 271 This is often more convenient for editing.
 272 If nil, adjust point in each of the two windows to minimize redisplay.
 273 This is convenient on slow terminals, but point can move strangely."
 274   :type 'boolean
 275   :group 'windows)
 276
 277 (defun split-window-vertically (&optional arg)
 278   "Split current window into two windows, one above the other.
 279 The uppermost window gets ARG lines and the other gets the rest.
 280 Negative arg means select the size of the lowermost window instead.
 281 With no argument, split equally or close to it.
 282 Both windows display the same buffer now current.
 283
 284 If the variable `split-window-keep-point' is non-nil, both new windows
 285 will get the same value of point as the current window.  This is often
 286 more convenient for editing.
 287
 288 Otherwise, we chose window starts so as to minimize the amount of
 289 redisplay; this is convenient on slow terminals.  The new selected
 290 window is the one that the current value of point appears in.  The
 291 value of point can change if the text around point is hidden by the
 292 new mode line."
 293   (interactive "P")
 294   (let ((old-w (selected-window))
 295         (old-point (point))
 296         (size (and arg (prefix-numeric-value arg)))
 297         (window-full-p nil)
 298         new-w bottom switch moved)
 299     (and size (< size 0) (setq size (+ (window-height) size)))
 300     (setq new-w (split-window nil size))
 301     (or split-window-keep-point
 302         (progn
 303           (save-excursion
 304             (set-buffer (window-buffer))
 305             (goto-char (window-start))
 306             (setq moved (vertical-motion (window-height)))
 307             (set-window-start new-w (point))
 308             (if (> (point) (window-point new-w))
 309                 (set-window-point new-w (point)))
 310             (and (= moved (window-height))
 311                  (progn
 312                    (setq window-full-p t)
 313                    (vertical-motion -1)))
 314             (setq bottom (point)))
 315           (and window-full-p
 316                (<= bottom (point))
 317                (set-window-point old-w (1- bottom)))
 318           (and window-full-p
 319                (<= (window-start new-w) old-point)
 320                (progn
 321                  (set-window-point new-w old-point)
 322                  (select-window new-w)))))
 323     (split-window-save-restore-data new-w old-w)))
 324
 325 ;; This is to avoid compiler warnings.
 326 (defvar view-return-to-alist)
 327
 328 (defun split-window-save-restore-data (new-w old-w)
 329   (with-current-buffer (window-buffer)
 330     (if view-mode
 331         (let ((old-info (assq old-w view-return-to-alist)))
 332           (push (cons new-w (cons (and old-info (car (cdr old-info))) t))
 333                 view-return-to-alist)))
 334     new-w))
 335
 336 (defun split-window-horizontally (&optional arg)
 337   "Split current window into two windows side by side.
 338 This window becomes the leftmost of the two, and gets ARG columns.
 339 Negative arg means select the size of the rightmost window instead.
 340 The argument includes the width of the window's scroll bar; if there
 341 are no scroll bars, it includes the width of the divider column
 342 to the window's right, if any.  No arg means split equally."
 343   (interactive "P")
 344   (let ((old-w (selected-window))
 345         (size (and arg (prefix-numeric-value arg))))
 346     (and size (< size 0)
 347          (setq size (+ (window-width) size)))
 348     (split-window-save-restore-data (split-window nil size t) old-w)))
 349
 350 \f
 351 (defun set-window-text-height (window height)
 352   "Sets the height in lines of the text display area of WINDOW to HEIGHT.
 353 This doesn't include the mode-line (or header-line if any) or any
 354 partial-height lines in the text display area.
 355
 356 If WINDOW is nil, the selected window is used.
 357
 358 Note that the current implementation of this function cannot always set
 359 the height exactly, but attempts to be conservative, by allocating more
 360 lines than are actually needed in the case where some error may be present."
 361   (let ((delta (- height (window-text-height window))))
 362     (unless (zerop delta)
 363       (let ((window-min-height 1))
 364         (if (and window (not (eq window (selected-window))))
 365             (save-selected-window
 366               (select-window window)
 367               (enlarge-window delta))
 368           (enlarge-window delta))))))
 369
 370 \f
 371 (defun enlarge-window-horizontally (arg)
 372   "Make current window ARG columns wider."
 373   (interactive "p")
 374   (enlarge-window arg t))
 375
 376 (defun shrink-window-horizontally (arg)
 377   "Make current window ARG columns narrower."
 378   (interactive "p")
 379   (shrink-window arg t))
 380
 381 (defun window-buffer-height (window)
 382   "Return the height (in screen lines) of the buffer that WINDOW is displaying."
 383   (save-excursion
 384     (set-buffer (window-buffer window))
 385     (goto-char (point-min))
 386     (let ((ignore-final-newline
 387            ;; If buffer ends with a newline, ignore it when counting height
 388            ;; unless point is after it.
 389            (and (not (eobp)) (eq ?\n (char-after (1- (point-max)))))))
 390       (+ 1 (nth 2 (compute-motion (point-min)
 391                                   '(0 . 0)
 392                                   (- (point-max) (if ignore-final-newline 1 0))
 393                                   (cons 0 100000000)
 394                                   (window-width window)
 395                                   nil
 396                                   window))))))
 397
 398 (defun count-screen-lines (&optional beg end count-final-newline window)
 399   "Return the number of screen lines in the region.
 400 The number of screen lines may be different from the number of actual lines,
 401 due to line breaking, display table, etc.
 402
 403 Optional arguments BEG and END default to `point-min' and `point-max'
 404 respectively.
 405
 406 If region ends with a newline, ignore it unless optional third argument
 407 COUNT-FINAL-NEWLINE is non-nil.
 408
 409 The optional fourth argument WINDOW specifies the window used for obtaining
 410 parameters such as width, horizontal scrolling, and so on.  The default is
 411 to use the selected window's parameters.
 412
 413 Like `vertical-motion', `count-screen-lines' always uses the current buffer,
 414 regardless of which buffer is displayed in WINDOW.  This makes possible to use
 415 `count-screen-lines' in any buffer, whether or not it is currently displayed
 416 in some window."
 417   (unless beg
 418     (setq beg (point-min)))
 419   (unless end
 420     (setq end (point-max)))
 421   (if (= beg end)
 422       0
 423     (save-excursion
 424       (save-restriction
 425         (widen)
 426         (narrow-to-region (min beg end)
 427                           (if (and (not count-final-newline)
 428                                    (= ?\n (char-before (max beg end))))
 429                               (1- (max beg end))
 430                             (max beg end)))
 431         (goto-char (point-min))
 432         (1+ (vertical-motion (buffer-size) window))))))
 433
 434 (defun fit-window-to-buffer (&optional window max-height min-height)
 435   "Make WINDOW the right size to display its contents exactly.
 436 If WINDOW is omitted or nil, it defaults to the selected window.
 437 If the optional argument MAX-HEIGHT is supplied, it is the maximum height
 438   the window is allowed to be, defaulting to the frame height.
 439 If the optional argument MIN-HEIGHT is supplied, it is the minimum
 440   height the window is allowed to be, defaulting to `window-min-height'.
 441
 442 The heights in MAX-HEIGHT and MIN-HEIGHT include the mode-line and/or
 443 header-line."
 444   (interactive)
 445
 446   (when (null window)
 447     (setq window (selected-window)))
 448   (when (null max-height)
 449     (setq max-height (frame-height (window-frame window))))
 450
 451   (let* ((buf
 452           ;; Buffer that is displayed in WINDOW
 453           (window-buffer window))
 454          (window-height
 455           ;; The current height of WINDOW
 456           (window-height window))
 457          (desired-height
 458           ;; The height necessary to show the buffer displayed by WINDOW
 459           ;; (`count-screen-lines' always works on the current buffer).
 460           (with-current-buffer buf
 461             (+ (count-screen-lines)
 462                ;; If the buffer is empty, (count-screen-lines) is
 463                ;; zero.  But, even in that case, we need one text line
 464                ;; for cursor.
 465                (if (= (point-min) (point-max))
 466                    1 0)
 467                ;; For non-minibuffers, count the mode-line, if any
 468                (if (and (not (window-minibuffer-p window))
 469                         mode-line-format)
 470                    1 0)
 471                ;; Count the header-line, if any
 472                (if header-line-format 1 0))))
 473          (delta
 474           ;; Calculate how much the window height has to change to show
 475           ;; desired-height lines, constrained by MIN-HEIGHT and MAX-HEIGHT.
 476           (- (max (min desired-height max-height)
 477                   (or min-height window-min-height))
 478              window-height))
 479          ;; We do our own height checking, so avoid any restrictions due to
 480          ;; window-min-height.
 481          (window-min-height 1))
 482
 483     ;; Don't try to redisplay with the cursor at the end
 484     ;; on its own line--that would force a scroll and spoil things.
 485     (when (with-current-buffer buf
 486             (and (eobp) (bolp) (not (bobp))))
 487       (set-window-point window (1- (window-point window))))
 488
 489     (save-selected-window
 490       (select-window window)
 491
 492       ;; Adjust WINDOW to the nominally correct size (which may actually
 493       ;; be slightly off because of variable height text, etc).
 494       (unless (zerop delta)
 495         (enlarge-window delta))
 496
 497       ;; Check if the last line is surely fully visible.  If not,
 498       ;; enlarge the window.
 499       (let ((end (with-current-buffer buf
 500                    (save-excursion
 501                      (goto-char (point-max))
 502                      (when (and (bolp) (not (bobp)))
 503                        ;; Don't include final newline
 504                        (backward-char 1))
 505                      (when truncate-lines
 506                        ;; If line-wrapping is turned off, test the
 507                        ;; beginning of the last line for visibility
 508                        ;; instead of the end, as the end of the line
 509                        ;; could be invisible by virtue of extending past
 510                        ;; the edge of the window.
 511                        (forward-line 0))
 512                      (point)))))
 513         (set-window-vscroll window 0)
 514         (while (and (< desired-height max-height)
 515                     (= desired-height (window-height window))
 516                     (not (pos-visible-in-window-p end window)))
 517           (enlarge-window 1)
 518           (setq desired-height (1+ desired-height)))))))
 519
 520 (defun shrink-window-if-larger-than-buffer (&optional window)
 521   "Shrink the WINDOW to be as small as possible to display its contents.
 522 If WINDOW is omitted or nil, it defaults to the selected window.
 523 Do not shrink to less than `window-min-height' lines.
 524 Do nothing if the buffer contains more lines than the present window height,
 525 or if some of the window's contents are scrolled out of view,
 526 or if shrinking this window would also shrink another window.
 527 or if the window is the only window of its frame.
 528 Return non-nil if the window was shrunk."
 529   (interactive)
 530   (when (null window)
 531     (setq window (selected-window)))
 532   (let* ((frame (window-frame window))
 533          (mini (frame-parameter frame 'minibuffer))
 534          (edges (window-edges window)))
 535     (if (and (not (eq window (frame-root-window frame)))
 536              (window-safely-shrinkable-p)
 537              (pos-visible-in-window-p (point-min) window)
 538              (not (eq mini 'only))
 539              (or (not mini)
 540                  (let ((mini-window (minibuffer-window frame)))
 541                    (or (null mini-window)
 542                        (not (eq frame (window-frame mini-window)))
 543                        (< (nth 3 edges)
 544                           (nth 1 (window-edges mini-window)))
 545                        (> (nth 1 edges)
 546                           (frame-parameter frame 'menu-bar-lines))))))
 547         (fit-window-to-buffer window (window-height window)))))
 548
 549 (defun kill-buffer-and-window ()
 550   "Kill the current buffer and delete the selected window."
 551   (interactive)
 552   (let ((window-to-delete (selected-window))
 553         (delete-window-hook (lambda ()
 554                               (condition-case nil
 555                                   (delete-window)
 556                                 (error nil)))))
 557     (add-hook 'kill-buffer-hook delete-window-hook t t)
 558     (if (kill-buffer (current-buffer))
 559         ;; If `delete-window' failed before, we rerun it to regenerate
 560         ;; the error so it can be seen in the minibuffer.
 561         (when (eq (selected-window) window-to-delete)
 562           (delete-window))
 563       (remove-hook 'kill-buffer-hook delete-window-hook t))))
 564
 565 (defun quit-window (&optional kill window)
 566   "Quit the current buffer.  Bury it, and maybe delete the selected frame.
 567 \(The frame is deleted if it is contains a dedicated window for the buffer.)
 568 With a prefix argument, kill the buffer instead.
 569
 570 Noninteractively, if KILL is non-nil, then kill the current buffer,
 571 otherwise bury it.
 572
 573 If WINDOW is non-nil, it specifies a window; we delete that window,
 574 and the buffer that is killed or buried is the one in that window."
 575   (interactive "P")
 576   (let ((buffer (window-buffer window))
 577         (frame (window-frame (or window (selected-window))))
 578         (window-solitary
 579          (save-selected-window
 580            (if window
 581                (select-window window))
 582            (one-window-p t)))
 583         window-handled)
 584
 585     (save-selected-window
 586       (if window
 587           (select-window window))
 588       (or (window-minibuffer-p)
 589           (window-dedicated-p (selected-window))
 590           (switch-to-buffer (other-buffer))))
 591
 592     ;; Get rid of the frame, if it has just one dedicated window
 593     ;; and other visible frames exist.
 594     (and (or (window-minibuffer-p) (window-dedicated-p window))
 595          (delq frame (visible-frame-list))
 596          window-solitary
 597          (if (and (eq default-minibuffer-frame frame)
 598                   (= 1 (length (minibuffer-frame-list))))
 599              (setq window nil)
 600            (delete-frame frame)
 601            (setq window-handled t)))
 602
 603     ;; Deal with the buffer.
 604     (if kill
 605         (kill-buffer buffer)
 606       (bury-buffer buffer))
 607
 608     ;; Maybe get rid of the window.
 609     (and window (not window-handled) (not window-solitary)
 610          (delete-window window))))
 611
 612 (defun handle-select-window (event)
 613   "Handle select-window events."
 614   (interactive "e")
 615   (let ((window (posn-window (event-start event))))
 616     (if (and (window-live-p window)
 617              (or (not (window-minibuffer-p window))
 618                  (minibuffer-window-active-p window)))
 619         (select-window window))))
 620
 621 (define-key ctl-x-map "2" 'split-window-vertically)
 622 (define-key ctl-x-map "3" 'split-window-horizontally)
 623 (define-key ctl-x-map "}" 'enlarge-window-horizontally)
 624 (define-key ctl-x-map "{" 'shrink-window-horizontally)
 625 (define-key ctl-x-map "-" 'shrink-window-if-larger-than-buffer)
 626 (define-key ctl-x-map "+" 'balance-windows)
 627 (define-key ctl-x-4-map "0" 'kill-buffer-and-window)
 628
 629 ;;; arch-tag: b508dfcc-c353-4c37-89fa-e773fe10cea9
 630 ;;; window.el ends here