lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file contains those help commands which are complicated, and
  27 ;; which may not be used in every session.  For example
  28 ;; `describe-function' will probably be heavily used when doing elisp
  29 ;; programming, but not if just editing C files.  Simpler help commands
  30 ;; are in help.el
  31
  32 ;;; Code:
  33
  34 (require 'help-mode)
  35
  36 ;; Functions
  37
  38 ;;;###autoload
  39 (defun describe-function (function)
  40   "Display the full documentation of FUNCTION (a symbol)."
  41   (interactive
  42    (let ((fn (function-called-at-point))
  43          (enable-recursive-minibuffers t)
  44          val)
  45      (setq val (completing-read (if fn
  46                                     (format "Describe function (default %s): " fn)
  47                                   "Describe function: ")
  48                                 obarray 'fboundp t nil nil
  49                                 (and fn (symbol-name fn))))
  50      (list (if (equal val "")
  51                fn (intern val)))))
  52   (if (null function)
  53       (message "You didn't specify a function")
  54     (help-setup-xref (list #'describe-function function) (interactive-p))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   (cond
 104    ((byte-code-function-p def) (aref def 0))
 105    ((eq (car-safe def) 'lambda) (nth 1 def))
 106    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 107     "[Arg list not available until function definition is loaded.]")
 108    (t t)))
 109
 110 (defun help-make-usage (function arglist)
 111   (cons (if (symbolp function) function 'anonymous)
 112         (mapcar (lambda (arg)
 113                   (if (not (symbolp arg))
 114                       (if (and (consp arg) (symbolp (car arg)))
 115                           ;; CL style default values for optional args.
 116                           (cons (intern (upcase (symbol-name (car arg))))
 117                                 (cdr arg))
 118                         arg)
 119                     (let ((name (symbol-name arg)))
 120                       (if (string-match "\\`&" name) arg
 121                         (intern (upcase name))))))
 122                 arglist)))
 123
 124 ;; Could be this, if we make symbol-file do the work below.
 125 ;; (defun help-C-file-name (subr-or-var kind)
 126 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 127 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 128 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 129 ;;               (subr-name subr-or-var))
 130 ;;             (if (eq kind 'var) 'defvar 'defun)))
 131 ;;;###autoload
 132 (defun help-C-file-name (subr-or-var kind)
 133   "Return the name of the C file where SUBR-OR-VAR is defined.
 134 KIND should be `var' for a variable or `subr' for a subroutine."
 135   (let ((docbuf (get-buffer-create " *DOC*"))
 136         (name (if (eq 'var kind)
 137                   (concat "V" (symbol-name subr-or-var))
 138                 (concat "F" (subr-name subr-or-var)))))
 139     (with-current-buffer docbuf
 140       (goto-char (point-min))
 141       (if (eobp)
 142           (insert-file-contents-literally
 143            (expand-file-name internal-doc-file-name doc-directory)))
 144       (let ((file (catch 'loop
 145                     (while t
 146                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 147                         (re-search-backward "\x1fS\\(.*\\)")
 148                         (let ((file (match-string 1)))
 149                           (if (member file build-files)
 150                               (throw 'loop file)
 151                             (goto-char pnt))))))))
 152         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 153             (setq file (replace-match ".m" t t file 1))
 154           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 155               (setq file (replace-match ".c" t t file))))
 156         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 157             (concat "src/" file)
 158           file)))))
 159
 160 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 161   "Face to highlight argument names in *Help* buffers."
 162   :group 'help)
 163
 164 (defun help-default-arg-highlight (arg)
 165   "Default function to highlight arguments in *Help* buffers.
 166 It returns ARG in face `help-argument-name'; ARG is also
 167 downcased if it displays differently than the default
 168 face (according to `face-differs-from-default-p')."
 169   (propertize (if (face-differs-from-default-p 'help-argument-name)
 170                   (downcase arg)
 171                 arg)
 172               'face 'help-argument-name))
 173
 174 (defun help-do-arg-highlight (doc args)
 175   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 176     (modify-syntax-entry ?\- "w")
 177     (dolist (arg args doc)
 178       (setq doc (replace-regexp-in-string
 179                  ;; This is heuristic, but covers all common cases
 180                  ;; except ARG1-ARG2
 181                  (concat "\\<"                   ; beginning of word
 182                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 183                          "\\("
 184                          (regexp-quote arg)
 185                          "\\)"
 186                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 187                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 188                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 189                          "\\>")                  ; end of word
 190                  (help-default-arg-highlight arg)
 191                  doc t t 1)))))
 192
 193 (defun help-highlight-arguments (usage doc &rest args)
 194   (when usage
 195     (with-temp-buffer
 196       (insert usage)
 197       (goto-char (point-min))
 198       (let ((case-fold-search nil)
 199             (next (not (or args (looking-at "\\["))))
 200             (opt nil))
 201         ;; Make a list of all arguments
 202         (skip-chars-forward "^ ")
 203         (while next
 204           (or opt (not (looking-at " &")) (setq opt t))
 205           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 206               (setq next nil)
 207             (setq args (cons (match-string 2) args))
 208             (when (and opt (string= (match-string 1) "("))
 209               ;; A pesky CL-style optional argument with default value,
 210               ;; so let's skip over it
 211               (search-backward "(")
 212               (goto-char (scan-sexps (point) 1)))))
 213         ;; Highlight aguments in the USAGE string
 214         (setq usage (help-do-arg-highlight (buffer-string) args))
 215         ;; Highlight arguments in the DOC string
 216         (setq doc (and doc (help-do-arg-highlight doc args))))))
 217   ;; Return value is like the one from help-split-fundoc, but highlighted
 218   (cons usage doc))
 219
 220 ;; The following function was compiled from the former functions
 221 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 222 ;; some excerpts from `describe-function-1' and `describe-variable'.
 223 ;; The only additional twists provided are (1) locate the defining file
 224 ;; for autoloaded functions, and (2) give preference to files in the
 225 ;; "install directory" (directories found via `load-path') rather than
 226 ;; to files in the "compile directory" (directories found by searching
 227 ;; the loaddefs.el file).  We autoload it because it's also used by
 228 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 229
 230 ;;;###autoload
 231 (defun find-lisp-object-file-name (object type)
 232   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 233 OBJECT should be a symbol associated with a function, variable, or face;
 234   alternatively, it can be a function definition.
 235 If TYPE is `variable', search for a variable definition.
 236 If TYPE is `face', search for a face definition.
 237 If TYPE is the value returned by `symbol-function' for a function symbol,
 238  search for a function definition.
 239
 240 The return value is the absolute name of a readable file where OBJECT is
 241 defined.  If several such files exist, preference is given to a file
 242 found via `load-path'.  The return value can also be `C-source', which
 243 means that OBJECT is a function or variable defined in C.  If no
 244 suitable file is found, return nil."
 245   (let* ((autoloaded (eq (car-safe type) 'autoload))
 246          (file-name (or (and autoloaded (nth 1 type))
 247                         (symbol-file
 248                          object (if (memq type (list 'defvar 'defface))
 249                                     type
 250                                   'defun)))))
 251     (cond
 252      (autoloaded
 253       ;; An autoloaded function: Locate the file since `symbol-function'
 254       ;; has only returned a bare string here.
 255       (setq file-name
 256             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 257      ((and (stringp file-name)
 258            (string-match "[.]*loaddefs.el\\'" file-name))
 259       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 260       ;; and try to extract the defining file.  The following form is
 261       ;; from `describe-function-1' and `describe-variable'.
 262       (let ((location
 263              (condition-case nil
 264                  (find-function-search-for-symbol object nil file-name)
 265                (error nil))))
 266         (when (cdr location)
 267           (with-current-buffer (car location)
 268             (goto-char (cdr location))
 269             (when (re-search-backward
 270                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 271               (setq file-name
 272                     (locate-file
 273                      (match-string-no-properties 1)
 274                      load-path nil 'readable))))))))
 275
 276     (cond
 277      ((and (not file-name) (subrp type))
 278       ;; A built-in function.  The form is from `describe-function-1'.
 279       (if (get-buffer " *DOC*")
 280           (help-C-file-name type 'subr)
 281         'C-source))
 282      ((and (not file-name) (symbolp object)
 283            (integerp (get object 'variable-documentation)))
 284       ;; A variable defined in C.  The form is from `describe-variable'.
 285       (if (get-buffer " *DOC*")
 286           (help-C-file-name object 'var)
 287         'C-source))
 288      ((not (stringp file-name))
 289       ;; If we don't have a file-name string by now, we lost.
 290       nil)
 291      ((let ((lib-name
 292              (if (string-match "[.]elc\\'" file-name)
 293                  (substring-no-properties file-name 0 -1)
 294                file-name)))
 295         ;; When the Elisp source file can be found in the install
 296         ;; directory return the name of that file - `file-name' should
 297         ;; have become an absolute file name ny now.
 298         (or (and (file-readable-p lib-name) lib-name)
 299             ;; The library might be compressed.
 300             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 301      ((let* ((lib-name (file-name-nondirectory file-name))
 302              ;; The next form is from `describe-simplify-lib-file-name'.
 303              (file-name
 304               ;; Try converting the absolute file name to a library
 305               ;; name, convert that back to a file name and see if we
 306               ;; get the original one.  If so, they are equivalent.
 307               (if (equal file-name (locate-file lib-name load-path '("")))
 308                   (if (string-match "[.]elc\\'" lib-name)
 309                       (substring-no-properties lib-name 0 -1)
 310                     lib-name)
 311                 file-name))
 312              ;; The next three forms are from `find-source-lisp-file'.
 313              (elc-file (locate-file
 314                         (concat file-name
 315                                 (if (string-match "\\.el\\'" file-name)
 316                                     "c"
 317                                   ".elc"))
 318                         load-path nil 'readable))
 319              (str (when elc-file
 320                     (with-temp-buffer
 321                       (insert-file-contents-literally elc-file nil 0 256)
 322                       (buffer-string))))
 323              (src-file (and str
 324                             (string-match ";;; from file \\(.*\\.el\\)" str)
 325                             (match-string 1 str))))
 326         (and src-file (file-readable-p src-file) src-file))))))
 327
 328 (declare-function ad-get-advice-info "advice" (function))
 329
 330 ;;;###autoload
 331 (defun describe-function-1 (function)
 332   (let* ((advised (and (symbolp function) (featurep 'advice)
 333                        (ad-get-advice-info function)))
 334          ;; If the function is advised, use the symbol that has the
 335          ;; real definition, if that symbol is already set up.
 336          (real-function
 337           (or (and advised
 338                    (let ((origname (cdr (assq 'origname advised))))
 339                      (and (fboundp origname) origname)))
 340               function))
 341          ;; Get the real definition.
 342          (def (if (symbolp real-function)
 343                   (symbol-function real-function)
 344                 function))
 345          file-name string
 346          (beg (if (commandp def) "an interactive " "a "))
 347          (pt1 (with-current-buffer (help-buffer) (point)))
 348          errtype)
 349     (setq string
 350           (cond ((or (stringp def)
 351                      (vectorp def))
 352                  "a keyboard macro")
 353                 ((subrp def)
 354                  (if (eq 'unevalled (cdr (subr-arity def)))
 355                      (concat beg "special form")
 356                    (concat beg "built-in function")))
 357                 ((byte-code-function-p def)
 358                  (concat beg "compiled Lisp function"))
 359                 ((symbolp def)
 360                  (while (and (fboundp def)
 361                              (symbolp (symbol-function def)))
 362                    (setq def (symbol-function def)))
 363                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 364                  (or (fboundp def) (setq errtype 'alias))
 365                  (format "an alias for `%s'" def))
 366                 ((eq (car-safe def) 'lambda)
 367                  (concat beg "Lisp function"))
 368                 ((eq (car-safe def) 'macro)
 369                  "a Lisp macro")
 370                 ((eq (car-safe def) 'autoload)
 371                  (format "%s autoloaded %s"
 372                          (if (commandp def) "an interactive" "an")
 373                          (if (eq (nth 4 def) 'keymap) "keymap"
 374                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 375                 ((keymapp def)
 376                  (let ((is-full nil)
 377                        (elts (cdr-safe def)))
 378                    (while elts
 379                      (if (char-table-p (car-safe elts))
 380                          (setq is-full t
 381                                elts nil))
 382                      (setq elts (cdr-safe elts)))
 383                    (if is-full
 384                        "a full keymap"
 385                      "a sparse keymap")))
 386                 (t "")))
 387     (princ string)
 388     (if (eq errtype 'alias)
 389         (princ ",\nwhich is not defined.  Please make a bug report.")
 390       (with-current-buffer standard-output
 391         (save-excursion
 392           (save-match-data
 393             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 394               (help-xref-button 1 'help-function def)))))
 395
 396       (setq file-name (find-lisp-object-file-name function def))
 397       (when file-name
 398         (princ " in `")
 399         ;; We used to add .el to the file name,
 400         ;; but that's completely wrong when the user used load-file.
 401         (princ (if (eq file-name 'C-source)
 402                    "C source code"
 403                  (file-name-nondirectory file-name)))
 404         (princ "'")
 405         ;; Make a hyperlink to the library.
 406         (with-current-buffer standard-output
 407           (save-excursion
 408             (re-search-backward "`\\([^`']+\\)'" nil t)
 409             (help-xref-button 1 'help-function-def real-function file-name))))
 410       (princ ".")
 411       (with-current-buffer (help-buffer)
 412         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 413                                   (point)))
 414       (terpri)(terpri)
 415       (when (commandp function)
 416         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 417               (remapped (command-remapping function)))
 418           (unless (memq remapped '(ignore undefined))
 419             (let ((keys (where-is-internal
 420                          (or remapped function) overriding-local-map nil nil))
 421                   non-modified-keys)
 422               (if (and (eq function 'self-insert-command)
 423                        (vectorp (car-safe keys))
 424                        (consp (aref (car keys) 0)))
 425                   (princ "It is bound to many ordinary text characters.\n")
 426                 ;; Which non-control non-meta keys run this command?
 427                 (dolist (key keys)
 428                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 429                       (push key non-modified-keys)))
 430                 (when remapped
 431                   (princ "It is remapped to `")
 432                   (princ (symbol-name remapped))
 433                   (princ "'"))
 434
 435                 (when keys
 436                   (princ (if remapped ", which is bound to " "It is bound to "))
 437                   ;; If lots of ordinary text characters run this command,
 438                   ;; don't mention them one by one.
 439                   (if (< (length non-modified-keys) 10)
 440                       (princ (mapconcat 'key-description keys ", "))
 441                     (dolist (key non-modified-keys)
 442                       (setq keys (delq key keys)))
 443                     (if keys
 444                         (progn
 445                           (princ (mapconcat 'key-description keys ", "))
 446                           (princ ", and many ordinary text characters"))
 447                       (princ "many ordinary text characters"))))
 448                 (when (or remapped keys non-modified-keys)
 449                   (princ ".")
 450                   (terpri)))))
 451
 452           (with-current-buffer (help-buffer)
 453             (fill-region-as-paragraph pt2 (point))
 454             (unless (looking-back "\n\n")
 455               (terpri)))))
 456       (let* ((arglist (help-function-arglist def))
 457              (doc (documentation function))
 458              (usage (help-split-fundoc doc function)))
 459         (with-current-buffer standard-output
 460           ;; If definition is a keymap, skip arglist note.
 461           (unless (keymapp function)
 462             (let* ((use (cond
 463                          (usage (setq doc (cdr usage)) (car usage))
 464                          ((listp arglist)
 465                           (format "%S" (help-make-usage function arglist)))
 466                          ((stringp arglist) arglist)
 467                          ;; Maybe the arglist is in the docstring of a symbol
 468                          ;; this one is aliased to.
 469                          ((let ((fun real-function))
 470                             (while (and (symbolp fun)
 471                                         (setq fun (symbol-function fun))
 472                                         (not (setq usage (help-split-fundoc
 473                                                           (documentation fun)
 474                                                           function)))))
 475                             usage)
 476                           (car usage))
 477                          ((or (stringp def)
 478                               (vectorp def))
 479                           (format "\nMacro: %s" (format-kbd-macro def)))
 480                          (t "[Missing arglist.  Please make a bug report.]")))
 481                    (high (help-highlight-arguments use doc)))
 482               (let ((fill-begin (point)))
 483                 (insert (car high) "\n")
 484                 (fill-region fill-begin (point)))
 485               (setq doc (cdr high))))
 486           (let* ((obsolete (and
 487                             ;; function might be a lambda construct.
 488                             (symbolp function)
 489                             (get function 'byte-obsolete-info)))
 490                  (use (car obsolete)))
 491             (when obsolete
 492               (princ "\nThis function is obsolete")
 493               (when (nth 2 obsolete)
 494                 (insert (format " since %s" (nth 2 obsolete))))
 495               (insert (cond ((stringp use) (concat ";\n" use))
 496                             (use (format ";\nuse `%s' instead." use))
 497                             (t "."))
 498                       "\n"))
 499             (insert "\n"
 500                     (or doc "Not documented."))))))))
 501
 502 \f
 503 ;; Variables
 504
 505 ;;;###autoload
 506 (defun variable-at-point (&optional any-symbol)
 507   "Return the bound variable symbol found at or before point.
 508 Return 0 if there is no such symbol.
 509 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 510   (with-syntax-table emacs-lisp-mode-syntax-table
 511     (or (condition-case ()
 512             (save-excursion
 513               (or (not (zerop (skip-syntax-backward "_w")))
 514                   (eq (char-syntax (following-char)) ?w)
 515                   (eq (char-syntax (following-char)) ?_)
 516                   (forward-sexp -1))
 517               (skip-chars-forward "'")
 518               (let ((obj (read (current-buffer))))
 519                 (and (symbolp obj) (boundp obj) obj)))
 520           (error nil))
 521         (let* ((str (find-tag-default))
 522                (sym (if str (intern-soft str))))
 523           (if (and sym (or any-symbol (boundp sym)))
 524               sym
 525             (save-match-data
 526               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 527                 (setq sym (intern-soft (match-string 1 str)))
 528                 (and (or any-symbol (boundp sym)) sym)))))
 529         0)))
 530
 531 (defun describe-variable-custom-version-info (variable)
 532   (let ((custom-version (get variable 'custom-version))
 533         (cpv (get variable 'custom-package-version))
 534         (output nil))
 535     (if custom-version
 536         (setq output
 537               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 538                       custom-version))
 539       (when cpv
 540         (let* ((package (car-safe cpv))
 541                (version (if (listp (cdr-safe cpv))
 542                             (car (cdr-safe cpv))
 543                           (cdr-safe cpv)))
 544                (pkg-versions (assq package customize-package-emacs-version-alist))
 545                (emacsv (cdr (assoc version pkg-versions))))
 546           (if (and package version)
 547               (setq output
 548                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 549                                     (if emacsv
 550                                         (format " that is part of Emacs %s" emacsv))
 551                                     ".\n")
 552                             version package))))))
 553     output))
 554
 555 ;;;###autoload
 556 (defun describe-variable (variable &optional buffer frame)
 557   "Display the full documentation of VARIABLE (a symbol).
 558 Returns the documentation as a string, also.
 559 If VARIABLE has a buffer-local value in BUFFER or FRAME
 560 \(default to the current buffer and current frame),
 561 it is displayed along with the global value."
 562   (interactive
 563    (let ((v (variable-at-point))
 564          (enable-recursive-minibuffers t)
 565          val)
 566      (setq val (completing-read (if (symbolp v)
 567                                     (format
 568                                      "Describe variable (default %s): " v)
 569                                   "Describe variable: ")
 570                                 obarray
 571                                 '(lambda (vv)
 572                                    (or (boundp vv)
 573                                        (get vv 'variable-documentation)))
 574                                 t nil nil
 575                                 (if (symbolp v) (symbol-name v))))
 576      (list (if (equal val "")
 577                v (intern val)))))
 578   (let (file-name)
 579     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 580     (unless (frame-live-p frame) (setq frame (selected-frame)))
 581     (if (not (symbolp variable))
 582         (message "You did not specify a variable")
 583       (save-excursion
 584         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 585               val val-start-pos locus)
 586           ;; Extract the value before setting up the output buffer,
 587           ;; in case `buffer' *is* the output buffer.
 588           (unless valvoid
 589             (with-selected-frame frame
 590               (with-current-buffer buffer
 591                 (setq val (symbol-value variable)
 592                       locus (variable-binding-locus variable)))))
 593           (help-setup-xref (list #'describe-variable variable buffer)
 594                            (interactive-p))
 595           (with-help-window (help-buffer)
 596             (with-current-buffer buffer
 597               (prin1 variable)
 598               (setq file-name (find-lisp-object-file-name variable 'defvar))
 599
 600               (if file-name
 601                   (progn
 602                     (princ " is a variable defined in `")
 603                     (princ (if (eq file-name 'C-source)
 604                                "C source code"
 605                              (file-name-nondirectory file-name)))
 606                     (princ "'.\n")
 607                     (with-current-buffer standard-output
 608                       (save-excursion
 609                         (re-search-backward "`\\([^`']+\\)'" nil t)
 610                         (help-xref-button 1 'help-variable-def
 611                                           variable file-name)))
 612                     (if valvoid
 613                         (princ "It is void as a variable.")
 614                       (princ "Its ")))
 615                 (if valvoid
 616                     (princ " is void as a variable.")
 617                   (princ "'s "))))
 618             (if valvoid
 619                 nil
 620               (with-current-buffer standard-output
 621                 (setq val-start-pos (point))
 622                 (princ "value is ")
 623                 (terpri)
 624                 (let ((from (point)))
 625                   (pp val)
 626                   ;; Hyperlinks in variable's value are quite frequently
 627                   ;; inappropriate e.g C-h v <RET> features <RET>
 628                   ;; (help-xref-on-pp from (point))
 629                   (if (< (point) (+ from 20))
 630                       (delete-region (1- from) from)))))
 631             (terpri)
 632
 633             (when locus
 634               (if (bufferp locus)
 635                   (princ (format "%socal in buffer %s; "
 636                                  (if (get variable 'permanent-local)
 637                                      "Permanently l" "L")
 638                                  (buffer-name)))
 639                 (princ (format "It is a frame-local variable; ")))
 640               (if (not (default-boundp variable))
 641                   (princ "globally void")
 642                 (let ((val (default-value variable)))
 643                   (with-current-buffer standard-output
 644                     (princ "global value is ")
 645                     (terpri)
 646                     ;; Fixme: pp can take an age if you happen to
 647                     ;; ask for a very large expression.  We should
 648                     ;; probably print it raw once and check it's a
 649                     ;; sensible size before prettyprinting.  -- fx
 650                     (let ((from (point)))
 651                       (pp val)
 652                       ;; See previous comment for this function.
 653                       ;; (help-xref-on-pp from (point))
 654                       (if (< (point) (+ from 20))
 655                           (delete-region (1- from) from))))))
 656               (terpri))
 657
 658             ;; If the value is large, move it to the end.
 659             (with-current-buffer standard-output
 660               (when (> (count-lines (point-min) (point-max)) 10)
 661                 ;; Note that setting the syntax table like below
 662                 ;; makes forward-sexp move over a `'s' at the end
 663                 ;; of a symbol.
 664                 (set-syntax-table emacs-lisp-mode-syntax-table)
 665                 (goto-char val-start-pos)
 666                 ;; The line below previously read as
 667                 ;; (delete-region (point) (progn (end-of-line) (point)))
 668                 ;; which suppressed display of the buffer local value for
 669                 ;; large values.
 670                 (when (looking-at "value is") (replace-match ""))
 671                 (save-excursion
 672                   (insert "\n\nValue:")
 673                   (set (make-local-variable 'help-button-cache)
 674                        (point-marker)))
 675                 (insert "value is shown ")
 676                 (insert-button "below"
 677                                'action help-button-cache
 678                                'follow-link t
 679                                'help-echo "mouse-2, RET: show value")
 680                 (insert ".\n")))
 681             (terpri)
 682
 683             (let* ((alias (condition-case nil
 684                               (indirect-variable variable)
 685                             (error variable)))
 686                    (obsolete (get variable 'byte-obsolete-variable))
 687                    (use (car obsolete))
 688                    (safe-var (get variable 'safe-local-variable))
 689                    (doc (or (documentation-property variable 'variable-documentation)
 690                             (documentation-property alias 'variable-documentation)))
 691                    (extra-line nil))
 692               ;; Add a note for variables that have been make-var-buffer-local.
 693               (when (and (local-variable-if-set-p variable)
 694                          (or (not (local-variable-p variable))
 695                              (with-temp-buffer
 696                                (local-variable-if-set-p variable))))
 697                 (setq extra-line t)
 698                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 699
 700               ;; Mention if it's an alias
 701               (unless (eq alias variable)
 702                 (setq extra-line t)
 703                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 704
 705               (when obsolete
 706                 (setq extra-line t)
 707                 (princ "  This variable is obsolete")
 708                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 709                 (princ (cond ((stringp use) (concat ";\n  " use))
 710                              (use (format ";\n  use `%s' instead." (car obsolete)))
 711                              (t ".")))
 712                 (terpri))
 713               (when safe-var
 714                 (setq extra-line t)
 715                 (princ "  This variable is safe as a file local variable ")
 716                 (princ "if its value\n  satisfies the predicate ")
 717                 (princ (if (byte-code-function-p safe-var)
 718                            "which is byte-compiled expression.\n"
 719                          (format "`%s'.\n" safe-var))))
 720
 721               (if extra-line (terpri))
 722               (princ "Documentation:\n")
 723               (with-current-buffer standard-output
 724                 (insert (or doc "Not documented as a variable."))))
 725
 726             ;; Make a link to customize if this variable can be customized.
 727             (when (custom-variable-p variable)
 728               (let ((customize-label "customize"))
 729                 (terpri)
 730                 (terpri)
 731                 (princ (concat "You can " customize-label " this variable."))
 732                 (with-current-buffer standard-output
 733                   (save-excursion
 734                     (re-search-backward
 735                      (concat "\\(" customize-label "\\)") nil t)
 736                     (help-xref-button 1 'help-customize-variable variable))))
 737               ;; Note variable's version or package version
 738               (let ((output (describe-variable-custom-version-info variable)))
 739                 (when output
 740                   (terpri)
 741                   (terpri)
 742                   (princ output))))
 743
 744             (save-excursion
 745               (set-buffer standard-output)
 746               ;; Return the text we displayed.
 747               (buffer-string))))))))
 748
 749
 750 ;;;###autoload
 751 (defun describe-syntax (&optional buffer)
 752   "Describe the syntax specifications in the syntax table of BUFFER.
 753 The descriptions are inserted in a help buffer, which is then displayed.
 754 BUFFER defaults to the current buffer."
 755   (interactive)
 756   (setq buffer (or buffer (current-buffer)))
 757   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 758   (with-help-window (help-buffer)
 759     (let ((table (with-current-buffer buffer (syntax-table))))
 760       (with-current-buffer standard-output
 761         (describe-vector table 'internal-describe-syntax-value)
 762         (while (setq table (char-table-parent table))
 763           (insert "\nThe parent syntax table is:")
 764           (describe-vector table 'internal-describe-syntax-value))))))
 765
 766 (defun help-describe-category-set (value)
 767   (insert (cond
 768            ((null value) "default")
 769            ((char-table-p value) "deeper char-table ...")
 770            (t (condition-case err
 771                   (category-set-mnemonics value)
 772                 (error "invalid"))))))
 773
 774 ;;;###autoload
 775 (defun describe-categories (&optional buffer)
 776   "Describe the category specifications in the current category table.
 777 The descriptions are inserted in a buffer, which is then displayed.
 778 If BUFFER is non-nil, then describe BUFFER's category table instead.
 779 BUFFER should be a buffer or a buffer name."
 780   (interactive)
 781   (setq buffer (or buffer (current-buffer)))
 782   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 783   (with-help-window (help-buffer)
 784     (let* ((table (with-current-buffer buffer (category-table)))
 785            (docs (char-table-extra-slot table 0)))
 786       (if (or (not (vectorp docs)) (/= (length docs) 95))
 787           (error "Invalid first extra slot in this category table\n"))
 788       (with-current-buffer standard-output
 789         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 790         (let ((pos (point)) (items 0) lines n)
 791           (dotimes (i 95)
 792             (if (aref docs i) (setq items (1+ items))))
 793           (setq lines (1+ (/ (1- items) 4)))
 794           (setq n 0)
 795           (dotimes (i 95)
 796             (let ((elt (aref docs i)))
 797               (when elt
 798                 (string-match ".*" elt)
 799                 (setq elt (match-string 0 elt))
 800                 (if (>= (length elt) 17)
 801                     (setq elt (concat (substring elt 0 14) "...")))
 802                 (if (< (point) (point-max))
 803                     (move-to-column (* 20 (/ n lines)) t))
 804                 (insert (+ i ?\s) ?: elt)
 805                 (if (< (point) (point-max))
 806                     (forward-line 1)
 807                   (insert "\n"))
 808                 (setq n (1+ n))
 809                 (if (= (% n lines) 0)
 810                     (goto-char pos))))))
 811         (goto-char (point-max))
 812         (insert "\n"
 813                 "character(s)\tcategory mnemonics\n"
 814                 "------------\t------------------")
 815         (describe-vector table 'help-describe-category-set)
 816         (insert "Legend of category mnemonics:\n")
 817         (dotimes (i 95)
 818           (let ((elt (aref docs i)))
 819             (when elt
 820               (if (string-match "\n" elt)
 821                   (setq elt (substring elt (match-end 0))))
 822               (insert (+ i ?\s) ": " elt "\n"))))
 823         (while (setq table (char-table-parent table))
 824           (insert "\nThe parent category table is:")
 825           (describe-vector table 'help-describe-category-set))))))
 826
 827 (provide 'help-fns)
 828
 829 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 830 ;;; help-fns.el ends here