lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el.
   2
   3 ;; Copyright (C) 1988, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; CHANGE LOG
  69 ;;; ===========================================================================
  70 ;;; 8/88 Olin
  71 ;;; Created.
  72 ;;;
  73 ;;; 2/15/89 Olin
  74 ;;; Removed -emacs flag from process invocation. It's only useful for
  75 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
  76 ;;; which messes things up royally. A bug.
  77 ;;;
  78 ;;; 5/22/90 Olin
  79 ;;; - Upgraded to use comint-send-string and comint-send-region.
  80 ;;; - run-scheme now offers to let you edit the command line if
  81 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  82 ;;;   has been removed.
  83 ;;; - Explicit references to process "scheme" have been replaced with
  84 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
  85 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  86 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  87 ;;;   and friends, but interested hackers might find a useful application
  88 ;;;   of this facility.
  89 ;;;
  90 ;;; 3/12/90 Olin
  91 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  92 ;;;   Tale suggested this.
  93
  94 ;;; Code:
  95
  96 (require 'scheme)
  97 (require 'comint)
  98
  99 ;;; INFERIOR SCHEME MODE STUFF
 100 ;;;============================================================================
 101
 102 (defvar inferior-scheme-mode-hook nil
 103   "*Hook for customising inferior-scheme mode.")
 104 (defvar inferior-scheme-mode-map nil)
 105
 106 (cond ((not inferior-scheme-mode-map)
 107        (setq inferior-scheme-mode-map
 108              (copy-keymap comint-mode-map))
 109        (define-key inferior-scheme-mode-map "\M-\C-x" ;gnu convention
 110                    'scheme-send-definition)
 111        (define-key inferior-scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp)
 112        (define-key inferior-scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 113        (define-key inferior-scheme-mode-map "\C-c\C-k" 'scheme-compile-file)
 114        (scheme-mode-commands inferior-scheme-mode-map)))
 115
 116 ;; Install the process communication commands in the scheme-mode keymap.
 117 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 118 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 119 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 120 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 121 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 122 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 123 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 124 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 125 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 126 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 127 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 128
 129 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 130   (define-key map [separator-eval] '("--"))
 131   (define-key map [compile-file]
 132     '("Compile Scheme File" . scheme-compile-file))
 133   (define-key map [load-file]
 134     '("Load Scheme File" . scheme-load-file))
 135   (define-key map [switch]
 136     '("Switch to Scheme" . switch-to-scheme))
 137   (define-key map [com-def-go]
 138     '("Compile Definitiion & Go" . scheme-compile-definition-and-go))
 139   (define-key map [com-def]
 140     '("Compile Definitiion" . scheme-compile-definition))
 141   (define-key map [send-def-go]
 142     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 143   (define-key map [send-def]
 144     '("Evaluate Last Definition" . scheme-send-definition))
 145   (define-key map [send-region-go]
 146     '("Evaluate Region & Go" . scheme-send-region-and-go))
 147   (define-key map [send-region]
 148     '("Evaluate Region" . scheme-send-region))
 149   (define-key map [send-sexp]
 150     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 151 )
 152
 153 (defvar scheme-buffer)
 154
 155 (defun inferior-scheme-mode ()
 156   "Major mode for interacting with an inferior Scheme process.
 157
 158 The following commands are available:
 159 \\{inferior-scheme-mode-map}
 160
 161 A Scheme process can be fired up with M-x run-scheme.
 162
 163 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 164 inferior-scheme-mode-hook (in that order).
 165
 166 You can send text to the inferior Scheme process from other buffers containing
 167 Scheme source.
 168     switch-to-scheme switches the current buffer to the Scheme process buffer.
 169     scheme-send-definition sends the current definition to the Scheme process.
 170     scheme-compile-definition compiles the current definition.
 171     scheme-send-region sends the current region to the Scheme process.
 172     scheme-compile-region compiles the current region.
 173
 174     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 175         scheme-send-region-and-go, and scheme-compile-region-and-go
 176         switch to the Scheme process buffer after sending their text.
 177 For information on running multiple processes in multiple buffers, see
 178 documentation for variable scheme-buffer.
 179
 180 Commands:
 181 Return after the end of the process' output sends the text from the
 182     end of process to point.
 183 Return before the end of the process' output copies the sexp ending at point
 184     to the end of the process' output, and sends it.
 185 Delete converts tabs to spaces as it moves back.
 186 Tab indents for Scheme; with argument, shifts rest
 187     of expression rigidly with the current line.
 188 C-M-q does Tab on each line starting within following expression.
 189 Paragraphs are separated only by blank lines.  Semicolons start comments.
 190 If you accidentally suspend your process, use \\[comint-continue-subjob]
 191 to continue it."
 192   (interactive)
 193   (comint-mode)
 194   ;; Customise in inferior-scheme-mode-hook
 195   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 196   (scheme-mode-variables)
 197   (setq major-mode 'inferior-scheme-mode)
 198   (setq mode-name "Inferior Scheme")
 199   (setq mode-line-process '(":%s"))
 200   (use-local-map inferior-scheme-mode-map)
 201   (setq comint-input-filter (function scheme-input-filter))
 202   (setq comint-get-old-input (function scheme-get-old-input))
 203   (run-hooks 'inferior-scheme-mode-hook))
 204
 205 (defvar inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 206   "*Input matching this regexp are not saved on the history list.
 207 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters.")
 208
 209 (defun scheme-input-filter (str)
 210   "Don't save anything matching inferior-scheme-filter-regexp"
 211   (not (string-match inferior-scheme-filter-regexp str)))
 212
 213 (defun scheme-get-old-input ()
 214   "Snarf the sexp ending at point"
 215   (save-excursion
 216     (let ((end (point)))
 217       (backward-sexp)
 218       (buffer-substring (point) end))))
 219
 220 (defun scheme-args-to-list (string)
 221   (let ((where (string-match "[ \t]" string)))
 222     (cond ((null where) (list string))
 223           ((not (= where 0))
 224            (cons (substring string 0 where)
 225                  (scheme-args-to-list (substring string (+ 1 where)
 226                                                  (length string)))))
 227           (t (let ((pos (string-match "[^ \t]" string)))
 228                (if (null pos)
 229                    nil
 230                  (scheme-args-to-list (substring string pos
 231                                                  (length string)))))))))
 232
 233 (defvar scheme-program-name "scheme"
 234   "*Program invoked by the run-scheme command")
 235
 236 ;;;###autoload
 237 (defun run-scheme (cmd)
 238   "Run an inferior Scheme process, input and output via buffer *scheme*.
 239 If there is a process already running in `*scheme*', switch to that buffer.
 240 With argument, allows you to edit the command line (default is value
 241 of `scheme-program-name').  Runs the hooks `inferior-scheme-mode-hook'
 242 \(after the `comint-mode-hook' is run).
 243 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 244
 245   (interactive (list (if current-prefix-arg
 246                          (read-string "Run Scheme: " scheme-program-name)
 247                          scheme-program-name)))
 248   (if (not (comint-check-proc "*scheme*"))
 249       (let ((cmdlist (scheme-args-to-list cmd)))
 250         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 251                            nil (cdr cmdlist)))
 252         (inferior-scheme-mode)))
 253   (setq scheme-program-name cmd)
 254   (setq scheme-buffer "*scheme*")
 255   (pop-to-buffer "*scheme*"))
 256 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 257
 258 (defun scheme-send-region (start end)
 259   "Send the current region to the inferior Scheme process."
 260   (interactive "r")
 261   (comint-send-region (scheme-proc) start end)
 262   (comint-send-string (scheme-proc) "\n"))
 263
 264 (defun scheme-send-definition ()
 265   "Send the current definition to the inferior Scheme process."
 266   (interactive)
 267   (save-excursion
 268    (end-of-defun)
 269    (let ((end (point)))
 270      (beginning-of-defun)
 271      (scheme-send-region (point) end))))
 272
 273 (defun scheme-send-last-sexp ()
 274   "Send the previous sexp to the inferior Scheme process."
 275   (interactive)
 276   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 277
 278 (defvar scheme-compile-exp-command "(compile '%s)"
 279   "*Template for issuing commands to compile arbitrary Scheme expressions.")
 280
 281 (defun scheme-compile-region (start end)
 282   "Compile the current region in the inferior Scheme process.
 283 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 284   (interactive "r")
 285   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 286                                             (format "(begin %s)"
 287                                                     (buffer-substring start end))))
 288   (comint-send-string (scheme-proc) "\n"))
 289
 290 (defun scheme-compile-definition ()
 291   "Compile the current definition in the inferior Scheme process."
 292   (interactive)
 293   (save-excursion
 294    (end-of-defun)
 295    (let ((end (point)))
 296      (beginning-of-defun)
 297      (scheme-compile-region (point) end))))
 298
 299 (defun switch-to-scheme (eob-p)
 300   "Switch to the scheme process buffer.
 301 With argument, positions cursor at end of buffer."
 302   (interactive "P")
 303   (if (get-buffer scheme-buffer)
 304       (pop-to-buffer scheme-buffer)
 305       (error "No current process buffer. See variable scheme-buffer."))
 306   (cond (eob-p
 307          (push-mark)
 308          (goto-char (point-max)))))
 309
 310 (defun scheme-send-region-and-go (start end)
 311   "Send the current region to the inferior Scheme process.
 312 Then switch to the process buffer."
 313   (interactive "r")
 314   (scheme-send-region start end)
 315   (switch-to-scheme t))
 316
 317 (defun scheme-send-definition-and-go ()
 318   "Send the current definition to the inferior Scheme.
 319 Then switch to the process buffer."
 320   (interactive)
 321   (scheme-send-definition)
 322   (switch-to-scheme t))
 323
 324 (defun scheme-compile-definition-and-go ()
 325   "Compile the current definition in the inferior Scheme.
 326 Then switch to the process buffer."
 327   (interactive)
 328   (scheme-compile-definition)
 329   (switch-to-scheme t))
 330
 331 (defun scheme-compile-region-and-go (start end)
 332   "Compile the current region in the inferior Scheme.
 333 Then switch to the process buffer."
 334   (interactive "r")
 335   (scheme-compile-region start end)
 336   (switch-to-scheme t))
 337
 338 (defvar scheme-source-modes '(scheme-mode)
 339   "*Used to determine if a buffer contains Scheme source code.
 340 If it's loaded into a buffer that is in one of these major modes, it's
 341 considered a scheme source file by scheme-load-file and scheme-compile-file.
 342 Used by these commands to determine defaults.")
 343
 344 (defvar scheme-prev-l/c-dir/file nil
 345   "Caches the last (directory . file) pair.
 346 Caches the last pair used in the last scheme-load-file or
 347 scheme-compile-file command. Used for determining the default in the
 348 next one.")
 349
 350 (defun scheme-load-file (file-name)
 351   "Load a Scheme file into the inferior Scheme process."
 352   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 353                                   scheme-source-modes t)) ; T because LOAD
 354                                                           ; needs an exact name
 355   (comint-check-source file-name) ; Check to see if buffer needs saved.
 356   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 357                                        (file-name-nondirectory file-name)))
 358   (comint-send-string (scheme-proc) (concat "(load \""
 359                                             file-name
 360                                             "\"\)\n")))
 361
 362 (defun scheme-compile-file (file-name)
 363   "Compile a Scheme file in the inferior Scheme process."
 364   (interactive (comint-get-source "Compile Scheme file: "
 365                                   scheme-prev-l/c-dir/file
 366                                   scheme-source-modes
 367                                   nil)) ; NIL because COMPILE doesn't
 368                                         ; need an exact name.
 369   (comint-check-source file-name) ; Check to see if buffer needs saved.
 370   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 371                                        (file-name-nondirectory file-name)))
 372   (comint-send-string (scheme-proc) (concat "(compile-file \""
 373                                             file-name
 374                                             "\"\)\n")))
 375
 376 \f
 377 (defvar scheme-buffer nil "*The current scheme process buffer.
 378
 379 MULTIPLE PROCESS SUPPORT
 380 ===========================================================================
 381 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 382 processes. To run multiple Scheme processes, you start the first up with
 383 \\[run-scheme]. It will be in a buffer named *scheme*. Rename this buffer
 384 with \\[rename-buffer]. You may now start up a new process with another
 385 \\[run-scheme]. It will be in a new buffer, named *scheme*. You can
 386 switch between the different process buffers with \\[switch-to-buffer].
 387
 388 Commands that send text from source buffers to Scheme processes --
 389 like scheme-send-definition or scheme-compile-region -- have to choose a
 390 process to send to, when you have more than one Scheme process around. This
 391 is determined by the global variable scheme-buffer. Suppose you
 392 have three inferior Schemes running:
 393     Buffer      Process
 394     foo         scheme
 395     bar         scheme<2>
 396     *scheme*    scheme<3>
 397 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 398 code, what process do you send it to?
 399
 400 - If you're in a process buffer (foo, bar, or *scheme*),
 401   you send it to that process.
 402 - If you're in some other buffer (e.g., a source file), you
 403   send it to the process attached to buffer scheme-buffer.
 404 This process selection is performed by function scheme-proc.
 405
 406 Whenever \\[run-scheme] fires up a new process, it resets scheme-buffer
 407 to be the new process's buffer. If you only run one process, this will
 408 do the right thing. If you run multiple processes, you can change
 409 scheme-buffer to another process buffer with \\[set-variable].
 410
 411 More sophisticated approaches are, of course, possible. If you find yourself
 412 needing to switch back and forth between multiple processes frequently,
 413 you may wish to consider ilisp.el, a larger, more sophisticated package
 414 for running inferior Lisp and Scheme processes. The approach taken here is
 415 for a minimal, simple implementation. Feel free to extend it.")
 416
 417 (defun scheme-proc ()
 418   "Returns the current scheme process. See variable scheme-buffer."
 419   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 420                                       (current-buffer)
 421                                       scheme-buffer))))
 422     (or proc
 423         (error "No current process. See variable scheme-buffer"))))
 424
 425
 426 ;;; Do the user's customisation...
 427
 428 (defvar cmuscheme-load-hook nil
 429   "This hook is run when cmuscheme is loaded in.
 430 This is a good place to put keybindings.")
 431
 432 (run-hooks 'cmuscheme-load-hook)
 433
 434 (provide 'cmuscheme)
 435
 436 ;;; cmuscheme.el ends here