lisp/info-look.el

   1 ;;; info-look.el --- major-mode-sensitive Info index lookup facility
   2 ;; An older version of this was known as libc.el.
   3
   4 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003,
   5 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   6
   7 ;; Author: Ralph Schleicher <rs@nunatak.allgaeu.org>
   8 ;;         (did not show signs of life (Nov 2001)  -stef)
   9 ;; Keywords: help languages
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Really cool code to lookup info indexes.
  31 ;; Try especially info-lookup-symbol (aka C-h S).
  32
  33 ;;; Code:
  34
  35 (require 'info)
  36
  37 (defgroup info-lookup nil
  38   "Major mode sensitive help agent."
  39   :group 'help :group 'languages)
  40
  41 (defvar info-lookup-mode nil
  42   "Symbol of the current buffer's help mode.
  43 Help is provided according to the buffer's major mode if value is nil.
  44 Automatically becomes buffer local when set in any fashion.")
  45 (make-variable-buffer-local 'info-lookup-mode)
  46
  47 (defcustom info-lookup-other-window-flag t
  48   "Non-nil means pop up the Info buffer in another window."
  49   :group 'info-lookup :type 'boolean)
  50
  51 (defcustom info-lookup-highlight-face 'match
  52   "Face for highlighting looked up help items.
  53 Setting this variable to nil disables highlighting."
  54   :group 'info-lookup :type 'face)
  55
  56 (defvar info-lookup-highlight-overlay nil
  57   "Overlay object used for highlighting.")
  58
  59 (defcustom info-lookup-file-name-alist
  60   '(("\\`ac\\(local\\|site\\|include\\)\\.m4\\'" . autoconf-mode))
  61   "Alist of file names handled specially.
  62 List elements are cons cells of the form
  63
  64     (REGEXP . MODE)
  65
  66 If a file name matches REGEXP, then use help mode MODE instead of the
  67 buffer's major mode."
  68   :group 'info-lookup :type '(repeat (cons (string :tag "Regexp")
  69                                            (symbol :tag "Mode"))))
  70
  71 (defvar info-lookup-history nil
  72   "History of previous input lines.")
  73
  74 (defvar info-lookup-alist nil
  75   "Alist of known help topics.
  76 Cons cells are of the form
  77
  78     (HELP-TOPIC . HELP-DATA)
  79
  80 HELP-TOPIC is the symbol of a help topic.
  81 HELP-DATA is a HELP-TOPIC's public data set.
  82  Value is an alist with elements of the form
  83
  84     (HELP-MODE REGEXP IGNORE-CASE DOC-SPEC PARSE-RULE OTHER-MODES)
  85
  86 HELP-MODE is a mode's symbol.
  87 REGEXP is a regular expression matching those help items whose
  88  documentation can be looked up via DOC-SPEC.
  89 IGNORE-CASE is non-nil if help items are case insensitive.
  90 DOC-SPEC is a list of documentation specifications of the form
  91
  92     (INFO-NODE TRANS-FUNC PREFIX SUFFIX)
  93
  94 INFO-NODE is the name (including file name part) of an Info index.
  95 TRANS-FUNC is a function translating index entries into help items;
  96  nil means add only those index entries matching REGEXP, a string
  97  means prepend string to the first word of all index entries.
  98 PREFIX and SUFFIX are parts of a regular expression.  If one of
  99  them is non-nil then search the help item's Info node for the
 100  first occurrence of the regular expression `PREFIX ITEM SUFFIX'.
 101  ITEM will be highlighted with `info-lookup-highlight-face' if this
 102  variable is not nil.
 103 PARSE-RULE is either the symbol name of a function or a regular
 104  expression for guessing the default help item at point.  Fuzzy
 105  regular expressions like \"[_a-zA-Z0-9]+\" do a better job if
 106  there are no clear delimiters; do not try to write too complex
 107  expressions.  PARSE-RULE defaults to REGEXP.
 108 OTHER-MODES is a list of cross references to other help modes.")
 109
 110 (defsubst info-lookup->topic-value (topic)
 111   (cdr (assoc topic info-lookup-alist)))
 112
 113 (defsubst info-lookup->mode-value (topic mode)
 114   (assoc mode (info-lookup->topic-value topic)))
 115
 116 (defsubst info-lookup->regexp (topic mode)
 117   (nth 1 (info-lookup->mode-value topic mode)))
 118
 119 (defsubst info-lookup->ignore-case (topic mode)
 120   (nth 2 (info-lookup->mode-value topic mode)))
 121
 122 (defsubst info-lookup->doc-spec (topic mode)
 123   (nth 3 (info-lookup->mode-value topic mode)))
 124
 125 (defsubst info-lookup->parse-rule (topic mode)
 126   (nth 4 (info-lookup->mode-value topic mode)))
 127
 128 (defsubst info-lookup->other-modes (topic mode)
 129   (nth 5 (info-lookup->mode-value topic mode)))
 130
 131 (defun info-lookup-add-help (&rest arg)
 132   "Add or update a help specification.
 133 Function arguments are one or more options of the form
 134
 135     KEYWORD ARGUMENT
 136
 137 KEYWORD is either `:topic', `:mode', `:regexp', `:ignore-case',
 138  `:doc-spec', `:parse-rule', or `:other-modes'.
 139 ARGUMENT has a value as explained in the documentation of the
 140  variable `info-lookup-alist'.
 141
 142 If no topic or mode option has been specified, then the help topic defaults
 143 to `symbol', and the help mode defaults to the current major mode."
 144   (apply 'info-lookup-add-help* nil arg))
 145
 146 (defun info-lookup-maybe-add-help (&rest arg)
 147   "Add a help specification if none is defined.
 148 See the documentation of the function `info-lookup-add-help'
 149 for more details."
 150   (apply 'info-lookup-add-help* t arg))
 151
 152 (defun info-lookup-add-help* (maybe &rest arg)
 153   (let (topic mode regexp ignore-case doc-spec
 154               parse-rule other-modes keyword value)
 155     (setq topic 'symbol
 156           mode major-mode
 157           regexp "\\w+")
 158     (while arg
 159       (setq keyword (car arg))
 160       (or (symbolp keyword)
 161           (error "Junk in argument list \"%S\"" arg))
 162       (setq arg (cdr arg))
 163       (and (null arg)
 164            (error "Keyword \"%S\" is missing an argument" keyword))
 165       (setq value (car arg)
 166             arg (cdr arg))
 167       (cond ((eq keyword :topic)
 168              (setq topic value))
 169             ((eq keyword :mode)
 170              (setq mode value))
 171             ((eq keyword :regexp)
 172              (setq regexp value))
 173             ((eq keyword :ignore-case)
 174              (setq ignore-case value))
 175             ((eq keyword :doc-spec)
 176              (setq doc-spec value))
 177             ((eq keyword :parse-rule)
 178              (setq parse-rule value))
 179             ((eq keyword :other-modes)
 180              (setq other-modes value))
 181             (t
 182              (error "Unknown keyword \"%S\"" keyword))))
 183     (or (and maybe (info-lookup->mode-value topic mode))
 184         (let* ((data (list regexp ignore-case doc-spec parse-rule other-modes))
 185                (topic-cell (or (assoc topic info-lookup-alist)
 186                                (car (setq info-lookup-alist
 187                                           (cons (cons topic nil)
 188                                                 info-lookup-alist)))))
 189                (mode-cell (assoc mode topic-cell)))
 190           (if (null mode-cell)
 191               (setcdr topic-cell (cons (cons mode data) (cdr topic-cell)))
 192             (setcdr mode-cell data))))
 193     nil))
 194
 195 (defvar info-lookup-cache nil
 196   "Cache storing data maintained automatically by the program.
 197 Value is an alist with cons cell of the form
 198
 199     (HELP-TOPIC . ((HELP-MODE INITIALIZED COMPLETIONS REFER-MODES) ...))
 200
 201 HELP-TOPIC is the symbol of a help topic.
 202 HELP-MODE is a mode's symbol.
 203 INITIALIZED is nil if HELP-MODE is uninitialized, t if
 204  HELP-MODE is initialized, and `0' means HELP-MODE is
 205  initialized but void.
 206 COMPLETIONS is an alist of documented help items.
 207 REFER-MODES is a list of other help modes to use.")
 208
 209 (defsubst info-lookup->cache (topic)
 210   (or (assoc topic info-lookup-cache)
 211       (car (setq info-lookup-cache
 212                  (cons (cons topic nil)
 213                        info-lookup-cache)))))
 214
 215 (defun info-lookup->topic-cache (topic)
 216   (cdr (info-lookup->cache topic)))
 217
 218 (defun info-lookup->mode-cache (topic mode)
 219   (assoc mode (info-lookup->topic-cache topic)))
 220
 221 (defun info-lookup->initialized (topic mode)
 222   (nth 1 (info-lookup->mode-cache topic mode)))
 223
 224 (defun info-lookup->completions (topic mode)
 225   (or (info-lookup->initialized topic mode)
 226       (info-lookup-setup-mode topic mode))
 227   (nth 2 (info-lookup->mode-cache topic mode)))
 228
 229 (defun info-lookup->refer-modes (topic mode)
 230   (or (info-lookup->initialized topic mode)
 231       (info-lookup-setup-mode topic mode))
 232   (nth 3 (info-lookup->mode-cache topic mode)))
 233
 234 (defun info-lookup->all-modes (topic mode)
 235   (cons mode (info-lookup->refer-modes topic mode)))
 236
 237 (defun info-lookup-quick-all-modes (topic mode)
 238   (cons mode (info-lookup->other-modes topic mode)))
 239
 240 ;;;###autoload
 241 (defun info-lookup-reset ()
 242   "Throw away all cached data.
 243 This command is useful if the user wants to start at the beginning without
 244 quitting Emacs, for example, after some Info documents were updated on the
 245 system."
 246   (interactive)
 247   (setq info-lookup-cache nil))
 248
 249 ;;;###autoload (put 'info-lookup-symbol 'info-file "emacs")
 250 ;;;###autoload
 251 (defun info-lookup-symbol (symbol &optional mode)
 252   "Display the definition of SYMBOL, as found in the relevant manual.
 253 When this command is called interactively, it reads SYMBOL from the
 254 minibuffer.  In the minibuffer, use M-n to yank the default argument
 255 value into the minibuffer so you can edit it.  The default symbol is the
 256 one found at point.
 257
 258 With prefix arg a query for the symbol help mode is offered."
 259   (interactive
 260    (info-lookup-interactive-arguments 'symbol current-prefix-arg))
 261   (info-lookup 'symbol symbol mode))
 262
 263 ;;;###autoload (put 'info-lookup-file 'info-file "emacs")
 264 ;;;###autoload
 265 (defun info-lookup-file (file &optional mode)
 266   "Display the documentation of a file.
 267 When this command is called interactively, it reads FILE from the minibuffer.
 268 In the minibuffer, use M-n to yank the default file name
 269 into the minibuffer so you can edit it.
 270 The default file name is the one found at point.
 271
 272 With prefix arg a query for the file help mode is offered."
 273   (interactive
 274    (info-lookup-interactive-arguments 'file current-prefix-arg))
 275   (info-lookup 'file file mode))
 276
 277 (defun info-lookup-interactive-arguments (topic &optional query)
 278   "Read and return argument value (and help mode) for help topic TOPIC.
 279 If optional argument QUERY is non-nil, query for the help mode."
 280   (let* ((mode (cond (query
 281                       (info-lookup-change-mode topic))
 282                      ((info-lookup->mode-value topic (info-lookup-select-mode))
 283                       info-lookup-mode)
 284                      ((info-lookup-change-mode topic))))
 285          (completions (info-lookup->completions topic mode))
 286          (default (info-lookup-guess-default topic mode))
 287          (completion-ignore-case (info-lookup->ignore-case topic mode))
 288          (enable-recursive-minibuffers t)
 289          (value (completing-read
 290                  (if default
 291                      (format "Describe %s (default %s): " topic default)
 292                    (format "Describe %s: " topic))
 293                  completions nil nil nil 'info-lookup-history default)))
 294     (list (if (equal value "") default value) mode)))
 295
 296 (defun info-lookup-select-mode ()
 297   (when (and (not info-lookup-mode) (buffer-file-name))
 298     (let ((file-name (file-name-nondirectory (buffer-file-name)))
 299           (file-name-alist info-lookup-file-name-alist))
 300       (while (and (not info-lookup-mode) file-name-alist)
 301         (when (string-match (caar file-name-alist) file-name)
 302           (setq info-lookup-mode (cdar file-name-alist)))
 303         (setq file-name-alist (cdr file-name-alist)))))
 304   (or info-lookup-mode (setq info-lookup-mode major-mode)))
 305
 306 (defun info-lookup-change-mode (topic)
 307   (let* ((completions (mapcar (lambda (arg)
 308                                 (cons (symbol-name (car arg)) (car arg)))
 309                               (info-lookup->topic-value topic)))
 310          (mode (completing-read
 311                 (format "Use %s help mode: " topic)
 312                 completions nil t nil 'info-lookup-history)))
 313     (or (setq mode (cdr (assoc mode completions)))
 314         (error "No %s help available" topic))
 315     (or (info-lookup->mode-value topic mode)
 316         (error "No %s help available for `%s'" topic mode))
 317     (setq info-lookup-mode mode)))
 318
 319 (defun info-lookup (topic item mode)
 320   "Display the documentation of a help item."
 321   (or mode (setq mode (info-lookup-select-mode)))
 322   (or (info-lookup->mode-value topic mode)
 323       (error "No %s help available for `%s'" topic mode))
 324   (let* ((completions (info-lookup->completions topic mode))
 325          (ignore-case (info-lookup->ignore-case topic mode))
 326          (entry (or (assoc (if ignore-case (downcase item) item) completions)
 327                     (assoc-string item completions t)
 328                     (error "Not documented as a %s: %s" topic (or item ""))))
 329          (modes (info-lookup->all-modes topic mode))
 330          (window (selected-window))
 331          found doc-spec node prefix suffix doc-found)
 332     (if (not (eq major-mode 'Info-mode))
 333         (if (not info-lookup-other-window-flag)
 334             (info)
 335           (progn
 336             (save-window-excursion (info))
 337             ;; Determine whether or not the Info buffer is visible in
 338             ;; another frame on the same display.  If it is, simply raise
 339             ;; that frame.  Otherwise, display it in another window.
 340             (let* ((window (get-buffer-window "*info*" t))
 341                    (info-frame (and window (window-frame window))))
 342               (if (and info-frame
 343                        (display-multi-frame-p)
 344                        (memq info-frame (frames-on-display-list))
 345                        (not (eq info-frame (selected-frame))))
 346                   (select-frame info-frame)
 347                 (switch-to-buffer-other-window "*info*"))))))
 348     (while (and (not found) modes)
 349       (setq doc-spec (info-lookup->doc-spec topic (car modes)))
 350       (while (and (not found) doc-spec)
 351         (setq node (nth 0 (car doc-spec))
 352               prefix (nth 2 (car doc-spec))
 353               suffix (nth 3 (car doc-spec)))
 354         (when (condition-case error-data
 355                   (progn
 356                     ;; Don't need Index menu fontifications here, and
 357                     ;; they slow down the lookup.
 358                     (let (Info-fontify-maximum-menu-size)
 359                       (Info-goto-node node)
 360                       (setq doc-found t)))
 361                 (error
 362                  (message "Cannot access Info node %s" node)
 363                  (sit-for 1)
 364                  nil))
 365           (condition-case nil
 366               (progn
 367                 ;; Don't use Info-menu, it forces case-fold-search to t
 368                 (let ((case-fold-search nil))
 369                   (re-search-forward
 370                    (concat "^\\* " (regexp-quote (or (cdr entry) (car entry)))
 371                            ":")))
 372                 (Info-follow-nearest-node)
 373                 (setq found t)
 374                 (if (or prefix suffix)
 375                     (let ((case-fold-search
 376                            (info-lookup->ignore-case topic (car modes)))
 377                           (buffer-read-only nil))
 378                       (goto-char (point-min))
 379                       (re-search-forward
 380                        (concat prefix (regexp-quote (car entry)) suffix))
 381                       (goto-char (match-beginning 0))
 382                       (and (display-color-p) info-lookup-highlight-face
 383                            ;; Search again for ITEM so that the first
 384                            ;; occurrence of ITEM will be highlighted.
 385                            (re-search-forward (regexp-quote (car entry)))
 386                            (let ((start (match-beginning 0))
 387                                  (end (match-end 0)))
 388                              (if (overlayp info-lookup-highlight-overlay)
 389                                  (move-overlay info-lookup-highlight-overlay
 390                                                start end (current-buffer))
 391                                (setq info-lookup-highlight-overlay
 392                                      (make-overlay start end))))
 393                            (overlay-put info-lookup-highlight-overlay
 394                                         'face info-lookup-highlight-face)))))
 395             (error nil)))
 396         (setq doc-spec (cdr doc-spec)))
 397       (setq modes (cdr modes)))
 398     ;; Alert the user if case was munged, and do this after bringing up the
 399     ;; info buffer since that can print messages
 400     (unless (or ignore-case
 401                 (string-equal item (car entry)))
 402       (message "Found in different case: %s" (car entry)))
 403     (or doc-found
 404         (error "Info documentation for lookup was not found"))
 405     ;; Don't leave the Info buffer if the help item couldn't be looked up.
 406     (if (and info-lookup-other-window-flag found)
 407         (select-window window))))
 408
 409 (defun info-lookup-setup-mode (topic mode)
 410   "Initialize the internal data structure."
 411   (or (info-lookup->initialized topic mode)
 412       (let (cell data (initialized 0) completions refer-modes)
 413         (if (not (info-lookup->mode-value topic mode))
 414             (message "No %s help available for `%s'" topic mode)
 415           ;; Recursively setup cross references.
 416           ;; But refer only to non-void modes.
 417           (dolist (arg (info-lookup->other-modes topic mode))
 418             (or (info-lookup->initialized topic arg)
 419                 (info-lookup-setup-mode topic arg))
 420             (and (eq (info-lookup->initialized topic arg) t)
 421                  (setq refer-modes (cons arg refer-modes))))
 422           (setq refer-modes (nreverse refer-modes))
 423           ;; Build the full completion alist.
 424           (setq completions
 425                 (nconc (condition-case nil
 426                            (info-lookup-make-completions topic mode)
 427                          (error nil))
 428                        (apply 'append
 429                               (mapcar (lambda (arg)
 430                                         (info-lookup->completions topic arg))
 431                                       refer-modes))))
 432           (setq initialized t))
 433         ;; Update `info-lookup-cache'.
 434         (setq cell (info-lookup->mode-cache topic mode)
 435               data (list initialized completions refer-modes))
 436         (if (not cell)
 437             (setcdr (info-lookup->cache topic)
 438                     (cons (cons mode data) (info-lookup->topic-cache topic)))
 439           (setcdr cell data))
 440         initialized)))
 441
 442 (defun info-lookup-make-completions (topic mode)
 443   "Create a unique alist from all index entries."
 444   (let ((doc-spec (info-lookup->doc-spec topic mode))
 445         (regexp (concat "^\\(" (info-lookup->regexp topic mode)
 446                         "\\)\\([ \t].*\\)?$"))
 447         Info-fontify-maximum-menu-size
 448         node trans entry item prefix result doc-found
 449         (buffer (get-buffer-create " temp-info-look")))
 450     (with-current-buffer buffer
 451       (Info-mode))
 452     (while doc-spec
 453       (setq node (nth 0 (car doc-spec))
 454             trans (cond ((eq (nth 1 (car doc-spec)) nil)
 455                          (lambda (arg)
 456                            (if (string-match regexp arg)
 457                                (match-string 1 arg))))
 458                         ((stringp (nth 1 (car doc-spec)))
 459                          (setq prefix (nth 1 (car doc-spec)))
 460                          (lambda (arg)
 461                            (if (string-match "^\\([^: \t\n]+\\)" arg)
 462                                (concat prefix (match-string 1 arg)))))
 463                         (t (nth 1 (car doc-spec)))))
 464       (with-current-buffer buffer
 465         (message "Processing Info node `%s'..." node)
 466         (when (condition-case error-data
 467                   (progn
 468                     (Info-goto-node node)
 469                     (setq doc-found t))
 470                 (error
 471                  (message "Cannot access Info node `%s'" node)
 472                  (sit-for 1)
 473                  nil))
 474           (condition-case nil
 475               (progn
 476                 (goto-char (point-min))
 477                 (and (search-forward "\n* Menu:" nil t)
 478                      (while (re-search-forward "\n\\* \\(.*\\): " nil t)
 479                        (setq entry (match-string 1)
 480                              item (funcall trans entry))
 481                        ;; `trans' can return nil if the regexp doesn't match.
 482                        (when (and item
 483                                   ;; Sometimes there's more than one Menu:
 484                                   (not (string= entry "Menu")))
 485                          (and (info-lookup->ignore-case topic mode)
 486                               (setq item (downcase item)))
 487                          (and (string-equal entry item)
 488                               (setq entry nil))
 489                          (and (or (assoc item result)
 490                                   (setq result (cons (cons item entry)
 491                                                      result))))))))
 492             (error nil))))
 493       (message "Processing Info node `%s'...done" node)
 494       (setq doc-spec (cdr doc-spec)))
 495     (or doc-found
 496         (error "Info documentation for lookup was not found"))
 497     result))
 498
 499 (defun info-lookup-guess-default (topic mode)
 500   "Return a guess for a symbol to look up, based on text around point.
 501 Try all related modes applicable to TOPIC and MODE.
 502 Return nil if there is nothing appropriate in the buffer near point."
 503   (let ((modes (info-lookup->all-modes topic mode))
 504         guess)
 505     (while (and (not guess) modes)
 506       (setq guess (info-lookup-guess-default* topic (car modes))
 507             modes (cdr modes)))
 508     ;; Collapse whitespace characters.
 509     (when guess
 510       (let ((pos 0))
 511         (while (string-match "[ \t\n]+" guess pos)
 512           (setq pos (1+ (match-beginning 0)))
 513           (setq guess (replace-match " " t t guess)))))
 514     guess))
 515
 516 (defun info-lookup-guess-default* (topic mode)
 517   (let ((case-fold-search (info-lookup->ignore-case topic mode))
 518         (rule (or (info-lookup->parse-rule topic mode)
 519                   (info-lookup->regexp topic mode)))
 520         (start (point)) end regexp subexp result)
 521     (save-excursion
 522       (if (symbolp rule)
 523           (setq result (funcall rule))
 524         (if (consp rule)
 525             (setq regexp (car rule)
 526                   subexp (cdr rule))
 527           (setq regexp rule
 528                 subexp 0))
 529         ;; If at start of symbol, don't go back to end of previous one.
 530         (if (save-match-data
 531               (looking-at "[ \t\n]"))
 532             (skip-chars-backward " \t\n"))
 533         (setq end (point))
 534         (while (and (re-search-backward regexp nil t)
 535                     (looking-at regexp)
 536                     (>= (match-end 0) end))
 537           (setq result (match-string subexp)))
 538         (if (not result)
 539             (progn
 540               (goto-char start)
 541               (skip-chars-forward " \t\n")
 542               (and (looking-at regexp)
 543                    (setq result (match-string subexp)))))))
 544     result))
 545
 546 (defun info-lookup-guess-c-symbol ()
 547   "Get the C symbol at point."
 548   (condition-case nil
 549       (progn
 550         (skip-syntax-backward "w_")
 551         (let ((start (point)) prefix name)
 552           ;; Test for a leading `struct', `union', or `enum' keyword
 553           ;; but ignore names like `foo_struct'.
 554           (setq prefix (and (< (skip-chars-backward " \t\n") 0)
 555                             (< (skip-chars-backward "_a-zA-Z0-9") 0)
 556                             (looking-at "\\(struct\\|union\\|enum\\)\\s ")
 557                             (concat (match-string 1) " ")))
 558           (goto-char start)
 559           (and (looking-at "[_a-zA-Z][_a-zA-Z0-9]*")
 560                (setq name (match-string 0)))
 561           ;; Caveat!  Look forward if point is at `struct' etc.
 562           (and (not prefix)
 563                (or (string-equal name "struct")
 564                    (string-equal name "union")
 565                    (string-equal name "enum"))
 566                (looking-at "[a-z]+\\s +\\([_a-zA-Z][_a-zA-Z0-9]*\\)")
 567                (setq prefix (concat name " ")
 568                      name (match-string 1)))
 569           (and (or prefix name)
 570                (concat prefix name))))
 571     (error nil)))
 572
 573 (defun info-lookup-guess-custom-symbol ()
 574   "Get symbol at point in custom buffers."
 575   (condition-case nil
 576       (save-excursion
 577         (let ((case-fold-search t)
 578               (ignored-chars "][()`',:.\" \t\n")
 579               (significant-chars "^][()`',:.\" \t\n")
 580               beg end)
 581           (cond
 582            ((and (memq (get-char-property (point) 'face)
 583                          '(custom-variable-tag custom-variable-tag-face))
 584                    (setq beg (previous-single-char-property-change
 585                               (point) 'face nil (line-beginning-position)))
 586                    (setq end (next-single-char-property-change
 587                               (point) 'face nil (line-end-position)))
 588                    (> end beg))
 589             (subst-char-in-string
 590              ?\s ?\- (buffer-substring-no-properties beg end)))
 591            ((or (and (looking-at (concat "[" significant-chars "]"))
 592                      (save-excursion
 593                        (skip-chars-backward significant-chars)
 594                        (setq beg (point)))
 595                      (skip-chars-forward significant-chars)
 596                      (setq end (point))
 597                      (> end beg))
 598                 (and (looking-at "[ \t\n]")
 599                      (looking-back (concat "[" significant-chars "]"))
 600                      (setq end (point))
 601                      (skip-chars-backward significant-chars)
 602                      (setq beg (point))
 603                      (> end beg))
 604                 (and (skip-chars-forward ignored-chars)
 605                      (setq beg (point))
 606                      (skip-chars-forward significant-chars)
 607                      (setq end (point))
 608                      (> end beg)))
 609             (buffer-substring-no-properties beg end)))))
 610     (error nil)))
 611
 612 ;;;###autoload
 613 (defun info-complete-symbol (&optional mode)
 614   "Perform completion on symbol preceding point."
 615   (interactive)
 616   (info-complete 'symbol
 617                  (or mode
 618                      (if (info-lookup->mode-value
 619                           'symbol (info-lookup-select-mode))
 620                          info-lookup-mode
 621                        (info-lookup-change-mode 'symbol)))))
 622
 623 ;;;###autoload
 624 (defun info-complete-file (&optional mode)
 625   "Perform completion on file preceding point."
 626   (interactive)
 627   (info-complete 'file
 628                  (or mode
 629                      (if (info-lookup->mode-value
 630                           'file (info-lookup-select-mode))
 631                          info-lookup-mode
 632                        (info-lookup-change-mode 'file)))))
 633
 634 (defun info-complete (topic mode)
 635   "Try to complete a help item."
 636   (barf-if-buffer-read-only)
 637   (or mode (setq mode (info-lookup-select-mode)))
 638   (or (info-lookup->mode-value topic mode)
 639       (error "No %s completion available for `%s'" topic mode))
 640   (let ((modes (info-lookup-quick-all-modes topic mode))
 641         (start (point))
 642         try)
 643     (while (and (not try) modes)
 644       (setq mode (car modes)
 645             modes (cdr modes)
 646             try (info-lookup-guess-default* topic mode))
 647       (goto-char start))
 648     (and (not try)
 649          (error "Found no %S to complete" topic))
 650     (let ((completions (info-lookup->completions topic mode))
 651           (completion-ignore-case (info-lookup->ignore-case topic mode))
 652           completion)
 653       (setq completion (try-completion try completions))
 654       (cond ((not completion)
 655              (ding)
 656              (message "No match"))
 657             ((stringp completion)
 658              (or (assoc completion completions)
 659                  (setq completion (completing-read
 660                                    (format "Complete %S: " topic)
 661                                    completions nil t completion
 662                                    info-lookup-history)))
 663              ;; Find the original symbol and zap it.
 664              (end-of-line)
 665              (while (and (search-backward try nil t)
 666                          (< start (point))))
 667              (replace-match "")
 668              (insert completion))
 669             (t
 670              (message "%s is complete"
 671                       (capitalize (prin1-to-string topic))))))))
 672
 673 \f
 674 ;;; Initialize some common modes.
 675
 676 (info-lookup-maybe-add-help
 677  :mode 'c-mode :topic 'symbol
 678  :regexp "\\(struct \\|union \\|enum \\)?[_a-zA-Z][_a-zA-Z0-9]*"
 679  :doc-spec '(("(libc)Function Index" nil
 680               "^[ \t]+-+ \\(Function\\|Macro\\): .*\\<" "\\>")
 681              ;; prefix/suffix has to match things like
 682              ;;   " -- Macro: int F_DUPFD"
 683              ;;   " -- Variable: char * tzname [2]"
 684              ;;   "`DBL_MAX'"    (texinfo @table)
 685              ;; suffix "\\>" is not used because that sends DBL_MAX to
 686              ;; DBL_MAX_EXP ("_" is a non-word char)
 687              ("(libc)Variable Index" nil
 688               "^\\([ \t]+-+ \\(Variable\\|Macro\\): .*\\<\\|`\\)"
 689               "\\( \\|'?$\\)")
 690              ("(libc)Type Index" nil
 691               "^[ \t]+-+ Data Type: \\<" "\\>")
 692              ("(termcap)Var Index" nil
 693               "^[ \t]*`" "'"))
 694  :parse-rule 'info-lookup-guess-c-symbol)
 695
 696 (info-lookup-maybe-add-help
 697  :mode 'c-mode :topic 'file
 698  :regexp "[_a-zA-Z0-9./+-]+"
 699  :doc-spec '(("(libc)File Index")))
 700
 701 (info-lookup-maybe-add-help
 702  :mode 'bison-mode
 703  :regexp "[:;|]\\|%\\([%{}]\\|[_a-z]+\\)\\|YY[_A-Z]+\\|yy[_a-z]+"
 704  :doc-spec '(("(bison)Index" nil
 705               "`" "'"))
 706  :parse-rule "[:;|]\\|%\\([%{}]\\|[_a-zA-Z][_a-zA-Z0-9]*\\)"
 707  :other-modes '(c-mode))
 708
 709 (info-lookup-maybe-add-help
 710  :mode 'makefile-mode
 711  :regexp "\\$[^({]\\|\\.[_A-Z]*\\|[_a-zA-Z][_a-zA-Z0-9-]*"
 712  :doc-spec '(("(make)Name Index" nil
 713               "^[ \t]*`" "'")
 714              ("(automake)Macro and Variable Index" nil
 715               "^[ \t]*`" "'"))
 716  :parse-rule "\\$[^({]\\|\\.[_A-Z]*\\|[_a-zA-Z0-9-]+"
 717  :other-modes '(automake-mode))
 718
 719 (info-lookup-maybe-add-help
 720  :mode 'texinfo-mode
 721  :regexp "@\\([a-zA-Z]+\\|[^a-zA-Z]\\)"
 722  :doc-spec '(("(texinfo)Command and Variable Index"
 723               ;; Ignore Emacs commands and prepend a `@'.
 724               (lambda (item)
 725                 (if (string-match "^\\([a-zA-Z]+\\|[^a-zA-Z]\\)\\( .*\\)?$" item)
 726                     (concat "@" (match-string 1 item))))
 727               "`" "[' ]")))
 728
 729 (info-lookup-maybe-add-help
 730  :mode 'm4-mode
 731  :regexp "[_a-zA-Z][_a-zA-Z0-9]*"
 732  :doc-spec '(("(m4)Macro index"))
 733  :parse-rule "[_a-zA-Z0-9]+")
 734
 735 (info-lookup-maybe-add-help
 736  :mode 'autoconf-mode
 737  :regexp "A[CM]_[_A-Z0-9]+"
 738  :doc-spec '(;; Autoconf Macro Index entries are without an "AC_" prefix,
 739              ;; but with "AH_" or "AU_" for those.  So add "AC_" if there
 740              ;; isn't already an "A._".
 741              ("(autoconf)Autoconf Macro Index"
 742               (lambda (item)
 743                 (if (string-match "^A._" item) item (concat "AC_" item)))
 744               "^[ \t]+-+ \\(Macro\\|Variable\\): .*\\<" "\\>")
 745              ;; M4 Macro Index entries are without "AS_" prefixes, and
 746              ;; mostly without "m4_" prefixes.  "dnl" is an exception, not
 747              ;; wanting any prefix.  So AS_ is added back to upper-case
 748              ;; names, m4_ to others which don't already an m4_.
 749              ("(autoconf)M4 Macro Index"
 750               (lambda (item)
 751                 (let ((case-fold-search nil))
 752                   (cond ((or (string-equal item "dnl")
 753                              (string-match "^m4_" item))
 754                          item)
 755                         ((string-match "^[A-Z0-9_]+$" item)
 756                          (concat "AS_" item))
 757                         (t
 758                          (concat "m4_" item)))))
 759               "^[ \t]+-+ Macro: .*\\<" "\\>")
 760              ;; Autotest Macro Index entries are without "AT_".
 761              ("(autoconf)Autotest Macro Index" "AT_"
 762               "^[ \t]+-+ Macro: .*\\<" "\\>")
 763              ;; This is for older versions (probably pre autoconf 2.5x):
 764              ("(autoconf)Macro Index" "AC_"
 765               "^[ \t]+-+ \\(Macro\\|Variable\\): .*\\<" "\\>")
 766              ;; Automake has index entries for its notes on various autoconf
 767              ;; macros (eg. AC_PROG_CC).  Ensure this is after the autoconf
 768              ;; index, so as to prefer the autoconf docs.
 769              ("(automake)Macro and Variable Index" nil
 770               "^[ \t]*`" "'"))
 771  ;; Autoconf symbols are M4 macros.  Thus use M4's parser.
 772  :parse-rule 'ignore
 773  :other-modes '(m4-mode))
 774
 775 (info-lookup-maybe-add-help
 776  :mode 'awk-mode
 777  :regexp "[_a-zA-Z]+"
 778  :doc-spec '(("(gawk)Index"
 779               (lambda (item)
 780                 (let ((case-fold-search nil))
 781                   (cond
 782                    ;; `BEGIN' and `END'.
 783                    ((string-match "^\\([A-Z]+\\) special pattern\\b" item)
 784                     (match-string 1 item))
 785                    ;; `if', `while', `do', ...
 786                    ((string-match "^\\([a-z]+\\) statement\\b" item)
 787                     (if (not (string-equal (match-string 1 item) "control"))
 788                         (match-string 1 item)))
 789                    ;; `NR', `NF', ...
 790                    ((string-match "^[A-Z]+$" item)
 791                     item)
 792                    ;; Built-in functions (matches to many entries).
 793                    ((string-match "^[a-z]+$" item)
 794                     item))))
 795               "`" "\\([ \t]*([^)]*)\\)?'")))
 796
 797 (info-lookup-maybe-add-help
 798  :mode 'perl-mode
 799  :regexp "[$@%][^a-zA-Z]\\|\\$\\^[A-Z]\\|[$@%]?[a-zA-Z][_a-zA-Z0-9]*"
 800  :doc-spec '(("(perl5)Function Index"
 801               (lambda (item)
 802                 (if (string-match "^\\([a-zA-Z0-9]+\\)" item)
 803                     (match-string 1 item)))
 804               "^" "\\b")
 805              ("(perl5)Variable Index"
 806               (lambda (item)
 807                 ;; Work around bad formatted array variables.
 808                 (let ((sym (cond ((or (string-match "^\\$\\(.\\|@@\\)$" item)
 809                                       (string-match "^\\$\\^[A-Z]$" item))
 810                                   item)
 811                                  ((string-match
 812                                    "^\\([$%@]\\|@@\\)?[_a-zA-Z0-9]+" item)
 813                                   (match-string 0 item))
 814                                  (t ""))))
 815                   (if (string-match "@@" sym)
 816                       (setq sym (concat (substring sym 0 (match-beginning 0))
 817                                         (substring sym (1- (match-end 0))))))
 818                   (if (string-equal sym "") nil sym)))
 819               "^" "\\b"))
 820  :parse-rule "[$@%]?\\([_a-zA-Z0-9]+\\|[^a-zA-Z]\\)")
 821
 822 (info-lookup-maybe-add-help
 823  :mode 'cperl-mode
 824  :regexp "[$@%][^a-zA-Z]\\|\\$\\^[A-Z]\\|[$@%]?[a-zA-Z][_a-zA-Z0-9]*"
 825  :other-modes '(perl-mode))
 826
 827 (info-lookup-maybe-add-help
 828  :mode 'latex-mode
 829  :regexp "\\\\\\([a-zA-Z]+\\|[^a-zA-Z]\\)"
 830  :doc-spec '(("(latex)Command Index" nil
 831               "`" "\\({[^}]*}\\)?'")))
 832
 833 (info-lookup-maybe-add-help
 834  :mode 'emacs-lisp-mode
 835  :regexp "[^][()`',\" \t\n]+"
 836  :doc-spec '(;; Commands with key sequences appear in nodes as `foo' and
 837              ;; those without as `M-x foo'.
 838              ("(emacs)Command Index"  nil "`\\(M-x[ \t\n]+\\)?" "'")
 839              ;; Variables normally appear in nodes as just `foo'.
 840              ("(emacs)Variable Index" nil "`" "'")
 841              ;; Almost all functions, variables, etc appear in nodes as
 842              ;; " -- Function: foo" etc.  A small number of aliases and
 843              ;; symbols appear only as `foo', and will miss out on exact
 844              ;; positions.  Allowing `foo' would hit too many false matches
 845              ;; for things that should go to Function: etc, and those latter
 846              ;; are much more important.  Perhaps this could change if some
 847              ;; sort of fallback match scheme existed.
 848              ("(elisp)Index"          nil "^ -+ .*: " "\\( \\|$\\)")))
 849
 850 (info-lookup-maybe-add-help
 851  :mode 'lisp-interaction-mode
 852  :regexp "[^][()`',\" \t\n]+"
 853  :parse-rule 'ignore
 854  :other-modes '(emacs-lisp-mode))
 855
 856 (info-lookup-maybe-add-help
 857  :mode 'lisp-mode
 858  :regexp "[^()`',\" \t\n]+"
 859  :parse-rule 'ignore
 860  :other-modes '(emacs-lisp-mode))
 861
 862 (info-lookup-maybe-add-help
 863  :mode 'scheme-mode
 864  :regexp "[^()`',\" \t\n]+"
 865  :ignore-case t
 866  ;; Aubrey Jaffer's rendition from <URL:ftp://ftp-swiss.ai.mit.edu/pub/scm>
 867  :doc-spec '(("(r5rs)Index" nil
 868               "^[ \t]+-+ [^:]+:[ \t]*" "\\b")))
 869
 870 (info-lookup-maybe-add-help
 871  :mode 'octave-mode
 872  :regexp "[_a-zA-Z0-9]+"
 873  :doc-spec '(("(octave)Function Index" nil
 874               "^ -+ [^:]+:[ ]+\\(\\[[^=]*=[ ]+\\)?" nil)
 875              ("(octave)Variable Index" nil "^ -+ [^:]+:[ ]+" nil)
 876              ;; Catch lines of the form "xyz statement"
 877              ("(octave)Concept Index"
 878               (lambda (item)
 879                 (cond
 880                  ((string-match "^\\([A-Z]+\\) statement\\b" item)
 881                     (match-string 1 item))
 882                  (t nil)))
 883               nil; "^ -+ [^:]+:[ ]+" don't think this prefix is useful here.
 884               nil)))
 885
 886 (info-lookup-maybe-add-help
 887  :mode 'maxima-mode
 888  :ignore-case t
 889  :regexp "[a-zA-Z0-9_%]+"
 890  :doc-spec '( ("(maxima)Function and Variable Index" nil
 891                "^ -+ [^:]+:[ ]+\\(\\[[^=]*=[ ]+\\)?" nil)))
 892
 893 (info-lookup-maybe-add-help
 894  :mode 'inferior-maxima-mode
 895  :regexp "[a-zA-Z0-9_%]+"
 896  :other-modes '(maxima-mode))
 897
 898 ;; coreutils and bash builtins overlap in places, eg. printf, so there's a
 899 ;; question which should come first.  Some of the coreutils descriptions are
 900 ;; more detailed, but if bash is usually /bin/sh on a GNU system then the
 901 ;; builtins will be what's normally run.
 902 ;;
 903 ;; Maybe special variables like $? should be matched as $?, not just ?.
 904 ;; This would avoid a clash between variable $! and negation !, or variable
 905 ;; $# and comment # (though comment # is not currently indexed in bash).
 906 ;; Unfortunately if $? etc is the symbol, then we wouldn't be taken to the
 907 ;; exact spot in the relevant node, since the bash manual has just `?' etc
 908 ;; there.  Maybe an extension to the prefix/suffix scheme could help this.
 909
 910 (info-lookup-maybe-add-help
 911  :mode 'sh-mode :topic 'symbol
 912  ;; bash has "." and ":" in its index, but those chars will probably never
 913  ;; work in info, so don't bother matching them in the regexp.
 914  :regexp "\\([a-zA-Z0-9_-]+\\|[!{}@*#?$]\\|\\[\\[?\\|]]?\\)"
 915  :doc-spec '(("(bash)Builtin Index"       nil "^`" "[ .']")
 916              ("(bash)Reserved Word Index" nil "^`" "[ .']")
 917              ("(bash)Variable Index"      nil "^`" "[ .']")
 918              ;; coreutils (version 4.5.10) doesn't have a separate program
 919              ;; index, so exclude extraneous stuff (most of it) by demanding
 920              ;; "[a-z]+" in the trans-func.
 921              ("(coreutils)Index"
 922               (lambda (item) (if (string-match "\\`[a-z]+\\'" item) item)))
 923              ;; diff (version 2.8.1) has only a few programs, index entries
 924              ;; are things like "foo invocation".
 925              ("(diff)Index"
 926               (lambda (item)
 927                 (if (string-match "\\`\\([a-z]+\\) invocation\\'" item)
 928                     (match-string 1 item))))
 929              ;; there's no plain "sed" index entry as such, mung another
 930              ;; hopefully unique one to get to the invocation section
 931              ("(sed)Concept Index"
 932               (lambda (item)
 933                 (if (string-equal item "Standard input, processing as input")
 934                     "sed")))
 935              ;; there's no plain "awk" or "gawk" index entries, mung other
 936              ;; hopefully unique ones to get to the command line options
 937              ("(gawk)Index"
 938               (lambda (item)
 939                 (cond ((string-equal item "gawk, extensions, disabling")
 940                        "awk")
 941                       ((string-equal item "gawk, versions of, information about, printing")
 942                        "gawk"))))))
 943
 944 ;; This misses some things which occur as node names but not in the
 945 ;; index.  Unfortunately it also picks up the wrong one of multiple
 946 ;; entries for the same term in some cases.  --fx
 947 (info-lookup-maybe-add-help
 948  :mode 'cfengine-mode
 949  :regexp "[[:alnum:]_]+\\(?:()\\)?"
 950  :doc-spec '(("(cfengine-Reference)Variable Index"
 951               (lambda (item)
 952                 ;; Index entries may be like `IsPlain()'
 953                 (if (string-match "\\([[:alnum:]_]+\\)()" item)
 954                     (match-string 1 item)
 955                   item))
 956               ;; This gets functions in evaluated classes.  Other
 957               ;; possible patterns don't seem to work too well.
 958               "`" "(")))
 959
 960 (info-lookup-maybe-add-help
 961  :mode 'custom-mode
 962  :ignore-case t
 963  :regexp "[^][()`',:\" \t\n]+"
 964  :parse-rule 'info-lookup-guess-custom-symbol
 965  :other-modes '(emacs-lisp-mode))
 966
 967 (info-lookup-maybe-add-help
 968  :mode 'help-mode
 969  :regexp "[^][()`',:\" \t\n]+"
 970  :other-modes '(emacs-lisp-mode))
 971 \f
 972 (provide 'info-look)
 973
 974 ;;; arch-tag: 0f1e3ea3-32a2-4461-bbab-3cff93539a74
 975 ;;; info-look.el ends here