lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar comint-prompt-regexp)
  31
  32 ;;; Customizable settings
  33 ;;; Switching tooltips on/off
  34
  35 ;; We don't set track-mouse globally because this is a big redisplay
  36 ;; problem in buffers having a pre-command-hook or such installed,
  37 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
  38 ;; set-buffer prevents redisplay optimizations, so every mouse motion
  39 ;; would be accompanied by a full redisplay.
  40
  41 (define-minor-mode tooltip-mode
  42   "Toggle Tooltip display.
  43 With ARG, turn tooltip mode on if and only if ARG is positive."
  44   :global t
  45   :init-value (not (or noninteractive
  46                        emacs-basic-display
  47                        (not (display-graphic-p))
  48                        (not (fboundp 'x-show-tip))))
  49   :initialize 'custom-initialize-safe-default
  50   :group 'tooltip
  51   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
  52     (error "Sorry, tooltips are not yet available on this system"))
  53   (if tooltip-mode
  54       (progn
  55         (add-hook 'pre-command-hook 'tooltip-hide)
  56         (add-hook 'tooltip-hook 'tooltip-help-tips))
  57     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  58       (remove-hook 'pre-command-hook 'tooltip-hide))
  59     (remove-hook 'tooltip-hook 'tooltip-help-tips))
  60   (setq show-help-function
  61         (if tooltip-mode 'tooltip-show-help nil)))
  62
  63 (defgroup tooltip nil
  64   "Customization group for the `tooltip' package."
  65   :group 'help
  66   :group 'gud
  67   :group 'mouse
  68   :group 'tools
  69   :version "21.1"
  70   :tag "Tool Tips")
  71
  72 (defcustom tooltip-delay 0.7
  73   "Seconds to wait before displaying a tooltip the first time."
  74   :type 'number
  75   :group 'tooltip)
  76
  77 (defcustom tooltip-short-delay 0.1
  78   "Seconds to wait between subsequent tooltips on different items."
  79   :type 'number
  80   :group 'tooltip)
  81
  82 (defcustom tooltip-recent-seconds 1
  83   "Display tooltips if changing tip items within this many seconds.
  84 Do so after `tooltip-short-delay'."
  85   :type 'number
  86   :group 'tooltip)
  87
  88 (defcustom tooltip-hide-delay 10
  89   "Hide tooltips automatically after this many seconds."
  90   :type 'number
  91   :group 'tooltip)
  92
  93 (defcustom tooltip-x-offset 5
  94   "X offset, in pixels, for the display of tooltips.
  95 The offset is relative to the position of the mouse.  It must
  96 be chosen so that the tooltip window doesn't contain the mouse
  97 when it pops up.
  98
  99 If `tooltip-frame-parameters' includes the `left' parameter,
 100 the value of `tooltip-x-offset' is ignored."
 101   :type 'integer
 102   :group 'tooltip)
 103
 104 (defcustom tooltip-y-offset +20
 105   "Y offset, in pixels, for the display of tooltips.
 106 The offset is relative to the position of the mouse.  It must
 107 be chosen so that the tooltip window doesn't contain the mouse
 108 when it pops up.
 109
 110 If `tooltip-frame-parameters' includes the `top' parameter,
 111 the value of `tooltip-y-offset' is ignored."
 112   :type 'integer
 113   :group 'tooltip)
 114
 115 (defcustom tooltip-frame-parameters
 116   '((name . "tooltip")
 117     (internal-border-width . 2)
 118     (border-width . 1))
 119   "Frame parameters used for tooltips.
 120
 121 If `left' or `top' parameters are included, they specify the absolute
 122 position to pop up the tooltip."
 123   :type 'sexp
 124   :group 'tooltip)
 125
 126 (defface tooltip
 127   '((((class color))
 128      :background "lightyellow"
 129      :foreground "black"
 130      :inherit variable-pitch)
 131     (t
 132      :inherit variable-pitch))
 133   "Face for tooltips."
 134   :group 'tooltip
 135   :group 'basic-faces)
 136
 137 (defcustom tooltip-use-echo-area nil
 138   "Use the echo area instead of tooltip frames for help and GUD tooltips."
 139   :type 'boolean
 140   :group 'tooltip)
 141
 142 \f
 143 ;;; Variables that are not customizable.
 144
 145 (defvar tooltip-hook nil
 146   "Functions to call to display tooltips.
 147 Each function is called with one argument EVENT which is a copy of
 148 the last mouse movement event that occurred.")
 149
 150 (defvar tooltip-timeout-id nil
 151   "The id of the timeout started when Emacs becomes idle.")
 152
 153 (defvar tooltip-last-mouse-motion-event nil
 154   "A copy of the last mouse motion event seen.")
 155
 156 (defvar tooltip-hide-time nil
 157   "Time when the last tooltip was hidden.")
 158
 159 (defvar gud-tooltip-mode) ;; Prevent warning.
 160
 161 ;;; Event accessors
 162
 163 (defun tooltip-event-buffer (event)
 164   "Return the buffer over which event EVENT occurred.
 165 This might return nil if the event did not occur over a buffer."
 166   (let ((window (posn-window (event-end event))))
 167     (and window (window-buffer window))))
 168
 169 \f
 170 ;;; Timeout for tooltip display
 171
 172 (defun tooltip-delay ()
 173   "Return the delay in seconds for the next tooltip."
 174   (let ((delay tooltip-delay)
 175         (now (float-time)))
 176     (when (and tooltip-hide-time
 177                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 178       (setq delay tooltip-short-delay))
 179     delay))
 180
 181 (defun tooltip-cancel-delayed-tip ()
 182   "Disable the tooltip timeout."
 183   (when tooltip-timeout-id
 184     (disable-timeout tooltip-timeout-id)
 185     (setq tooltip-timeout-id nil)))
 186
 187 (defun tooltip-start-delayed-tip ()
 188   "Add a one-shot timeout to call function `tooltip-timeout'."
 189   (setq tooltip-timeout-id
 190         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 191
 192 (defun tooltip-timeout (object)
 193   "Function called when timer with id `tooltip-timeout-id' fires."
 194   (run-hook-with-args-until-success 'tooltip-hook
 195                                     tooltip-last-mouse-motion-event))
 196
 197 \f
 198 ;;; Displaying tips
 199
 200 (defun tooltip-set-param (alist key value)
 201   "Change the value of KEY in alist ALIST to VALUE.
 202 If there's no association for KEY in ALIST, add one, otherwise
 203 change the existing association.  Value is the resulting alist."
 204   (let ((param (assq key alist)))
 205     (if (consp param)
 206         (setcdr param value)
 207       (push (cons key value) alist))
 208     alist))
 209
 210 (defun tooltip-show (text &optional use-echo-area)
 211   "Show a tooltip window displaying TEXT.
 212
 213 Text larger than `x-max-tooltip-size' is clipped.
 214
 215 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 216 parameters, they determine the x and y position where the tooltip
 217 is displayed.  Otherwise, the tooltip pops at offsets specified by
 218 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 219 position.
 220
 221 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 222 in echo area."
 223   (if use-echo-area
 224       (message "%s" text)
 225     (condition-case error
 226         (let ((params (copy-sequence tooltip-frame-parameters))
 227               (fg (face-attribute 'tooltip :foreground))
 228               (bg (face-attribute 'tooltip :background)))
 229           (when (stringp fg)
 230             (setq params (tooltip-set-param params 'foreground-color fg))
 231             (setq params (tooltip-set-param params 'border-color fg)))
 232           (when (stringp bg)
 233             (setq params (tooltip-set-param params 'background-color bg)))
 234           (x-show-tip (propertize text 'face 'tooltip)
 235                       (selected-frame)
 236                       params
 237                       tooltip-hide-delay
 238                       tooltip-x-offset
 239                       tooltip-y-offset))
 240       (error
 241        (message "Error while displaying tooltip: %s" error)
 242        (sit-for 1)
 243        (message "%s" text)))))
 244
 245 (defun tooltip-hide (&optional ignored-arg)
 246   "Hide a tooltip, if one is displayed.
 247 Value is non-nil if tooltip was open."
 248   (tooltip-cancel-delayed-tip)
 249   (when (x-hide-tip)
 250     (setq tooltip-hide-time (float-time))))
 251
 252 \f
 253 ;;; Debugger-related functions
 254
 255 (defun tooltip-identifier-from-point (point)
 256   "Extract the identifier at POINT, if any.
 257 Value is nil if no identifier exists at point.  Identifier extraction
 258 is based on the current syntax table."
 259   (save-excursion
 260     (goto-char point)
 261     (let ((start (progn (skip-syntax-backward "w_") (point))))
 262       (unless (looking-at "[0-9]")
 263         (skip-syntax-forward "w_")
 264         (when (> (point) start)
 265           (buffer-substring start (point)))))))
 266
 267 (defmacro tooltip-region-active-p ()
 268   "Value is non-nil if the region is currently active."
 269   (if (string-match "^GNU" (emacs-version))
 270       `(and transient-mark-mode mark-active)
 271     `(region-active-p)))
 272
 273 (defun tooltip-expr-to-print (event)
 274   "Return an expression that should be printed for EVENT.
 275 If a region is active and the mouse is inside the region, print
 276 the region.  Otherwise, figure out the identifier around the point
 277 where the mouse is."
 278   (save-excursion
 279     (set-buffer (tooltip-event-buffer event))
 280     (let ((point (posn-point (event-end event))))
 281       (if (tooltip-region-active-p)
 282           (when (and (<= (region-beginning) point) (<= point (region-end)))
 283             (buffer-substring (region-beginning) (region-end)))
 284         (tooltip-identifier-from-point point)))))
 285
 286 (defun tooltip-process-prompt-regexp (process)
 287   "Return regexp matching the prompt of PROCESS at the end of a string.
 288 The prompt is taken from the value of `comint-prompt-regexp' in
 289 the buffer of PROCESS."
 290   (let ((prompt-regexp (save-excursion
 291                          (set-buffer (process-buffer process))
 292                          comint-prompt-regexp)))
 293     ;; Most start with `^' but the one for `sdb' cannot be easily
 294     ;; stripped.  Code the prompt for `sdb' fixed here.
 295     (if (= (aref prompt-regexp 0) ?^)
 296         (setq prompt-regexp (substring prompt-regexp 1))
 297       (setq prompt-regexp "\\*"))
 298     (concat "\n*" prompt-regexp "$")))
 299
 300 (defun tooltip-strip-prompt (process output)
 301   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 302   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 303     (save-match-data
 304       (when (string-match prompt-regexp output)
 305         (setq output (substring output 0 (match-beginning 0)))))
 306     output))
 307
 308 \f
 309 ;;; Tooltip help.
 310
 311 (defvar tooltip-help-message nil
 312   "The last help message received via `tooltip-show-help'.")
 313
 314 (defun tooltip-show-help (msg)
 315   "Function installed as `show-help-function'.
 316 MSG is either a help string to display, or nil to cancel the display."
 317   (let ((previous-help tooltip-help-message))
 318     (setq tooltip-help-message msg)
 319     (cond ((null msg)
 320            ;; Cancel display.  This also cancels a delayed tip, if
 321            ;; there is one.
 322            (tooltip-hide))
 323           ((equal previous-help msg)
 324            ;; Same help as before (but possibly the mouse has moved).
 325            ;; Keep what we have.
 326            )
 327           (t
 328            ;; A different help.  Remove a previous tooltip, and
 329            ;; display a new one, with some delay.
 330            (tooltip-hide)
 331            (tooltip-start-delayed-tip)))))
 332
 333 (defun tooltip-help-tips (event)
 334   "Hook function to display a help tooltip.
 335 This is installed on the hook `tooltip-hook', which is run when
 336 the timer with id `tooltip-timeout-id' fires.
 337 Value is non-nil if this function handled the tip."
 338   (when (stringp tooltip-help-message)
 339     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 340     t))
 341
 342 (provide 'tooltip)
 343
 344 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 345 ;;; tooltip.el ends here