lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985, 1986, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file is autoloaded to handle certain conditions
  29 ;; detected by the file-locking code within Emacs.
  30 ;; The two entry points are `ask-user-about-lock' and
  31 ;; `ask-user-about-supersession-threat'.
  32
  33 ;;; Code:
  34
  35 (put 'file-locked 'error-conditions '(file-locked file-error error))
  36 (put 'file-locked 'error-message "File is locked")
  37
  38 ;;;###autoload
  39 (defun ask-user-about-lock (file opponent)
  40   "Ask user what to do when he wants to edit FILE but it is locked by OPPONENT.
  41 This function has a choice of three things to do:
  42   do (signal 'file-locked (list FILE OPPONENT))
  43     to refrain from editing the file
  44   return t (grab the lock on the file)
  45   return nil (edit the file even though it is locked).
  46 You can redefine this function to choose among those three alternatives
  47 in any way you like."
  48   (discard-input)
  49   (save-window-excursion
  50     (let (answer short-opponent short-file)
  51       (setq short-file
  52             (if (> (length file) 22)
  53                 (concat "..." (substring file (- (length file) 22)))
  54               file))
  55       (setq short-opponent
  56             (if (> (length opponent) 25)
  57                 (save-match-data
  58                   (string-match " (pid [0-9]+)" opponent)
  59                   (concat (substring opponent 0 13) "..."
  60                           (match-string 0 opponent)))
  61               opponent))
  62       (while (null answer)
  63         (message "%s locked by %s: (s, q, p, ?)? "
  64                  short-file short-opponent)
  65         (let ((tem (let ((inhibit-quit t)
  66                          (cursor-in-echo-area t))
  67                      (prog1 (downcase (read-char))
  68                             (setq quit-flag nil)))))
  69           (if (= tem help-char)
  70               (ask-user-about-lock-help)
  71             (setq answer (assoc tem '((?s . t)
  72                                       (?q . yield)
  73                                       (?\C-g . yield)
  74                                       (?p . nil)
  75                                       (?? . help))))
  76             (cond ((null answer)
  77                    (beep)
  78                    (message "Please type q, s, or p; or ? for help")
  79                    (sit-for 3))
  80                   ((eq (cdr answer) 'help)
  81                    (ask-user-about-lock-help)
  82                    (setq answer nil))
  83                   ((eq (cdr answer) 'yield)
  84                    (signal 'file-locked (list file opponent)))))))
  85       (cdr answer))))
  86
  87 (defun ask-user-about-lock-help ()
  88   (with-output-to-temp-buffer "*Help*"
  89     (princ "It has been detected that you want to modify a file that someone else has
  90 already started modifying in EMACS.
  91
  92 You can <s>teal the file; The other user becomes the
  93   intruder if (s)he ever unmodifies the file and then changes it again.
  94 You can <p>roceed; you edit at your own (and the other user's) risk.
  95 You can <q>uit; don't modify this file.")
  96     (save-excursion
  97       (set-buffer standard-output)
  98       (help-mode))))
  99
 100 (put
 101  'file-supersession 'error-conditions '(file-supersession file-error error))
 102
 103 ;;;###autoload
 104 (defun ask-user-about-supersession-threat (fn)
 105   "Ask a user who is about to modify an obsolete buffer what to do.
 106 This function has two choices: it can return, in which case the modification
 107 of the buffer will proceed, or it can (signal 'file-supersession (file)),
 108 in which case the proposed buffer modification will not be made.
 109
 110 You can rewrite this to use any criterion you like to choose which one to do.
 111 The buffer in question is current when this function is called."
 112   (discard-input)
 113   (save-window-excursion
 114     (let (answer)
 115       (while (null answer)
 116         (message "%s changed on disk; really edit the buffer? (y, n, r or C-h) "
 117                  (file-name-nondirectory fn))
 118         (let ((tem (downcase (let ((cursor-in-echo-area t))
 119                                (read-char-exclusive)))))
 120           (setq answer
 121                 (if (= tem help-char)
 122                     'help
 123                   (cdr (assoc tem '((?n . yield)
 124                                     (?\C-g . yield)
 125                                     (?y . proceed)
 126                                     (?r . revert)
 127                                     (?? . help))))))
 128           (cond ((null answer)
 129                  (beep)
 130                  (message "Please type y, n or r; or ? for help")
 131                  (sit-for 3))
 132                 ((eq answer 'help)
 133                  (ask-user-about-supersession-help)
 134                  (setq answer nil))
 135                 ((eq answer 'revert)
 136                  (revert-buffer nil (not (buffer-modified-p)))
 137                                         ; ask confirmation iff buffer modified
 138                  (signal 'file-supersession
 139                          (list "File reverted" fn)))
 140                 ((eq answer 'yield)
 141                  (signal 'file-supersession
 142                          (list "File changed on disk" fn))))))
 143       (message
 144         "File on disk now will become a backup file if you save these changes.")
 145       (setq buffer-backed-up nil))))
 146
 147 (defun ask-user-about-supersession-help ()
 148   (with-output-to-temp-buffer "*Help*"
 149     (princ "You want to modify a buffer whose disk file has changed
 150 since you last read it in or saved it with this buffer.
 151
 152 If you say `y' to go ahead and modify this buffer,
 153 you risk ruining the work of whoever rewrote the file.
 154 If you say `r' to revert, the contents of the buffer are refreshed
 155 from the file on disk.
 156 If you say `n', the change you started to make will be aborted.
 157
 158 Usually, you should type `n' and then `M-x revert-buffer',
 159 to get the latest version of the file, then make the change again.")
 160     (save-excursion
 161       (set-buffer standard-output)
 162       (help-mode))))
 163
 164 ;;; arch-tag: a61c5b60-e1c8-44fd-894a-c617f4dfc639
 165 ;;; userlock.el ends here