lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el
   2
   3 ;; Copyright (C) 1988, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; CHANGE LOG
  69 ;;; ===========================================================================
  70 ;;; 8/88 Olin
  71 ;;; Created.
  72 ;;;
  73 ;;; 2/15/89 Olin
  74 ;;; Removed -emacs flag from process invocation. It's only useful for
  75 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
  76 ;;; which messes things up royally. A bug.
  77 ;;;
  78 ;;; 5/22/90 Olin
  79 ;;; - Upgraded to use comint-send-string and comint-send-region.
  80 ;;; - run-scheme now offers to let you edit the command line if
  81 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  82 ;;;   has been removed.
  83 ;;; - Explicit references to process "scheme" have been replaced with
  84 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
  85 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  86 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  87 ;;;   and friends, but interested hackers might find a useful application
  88 ;;;   of this facility.
  89 ;;;
  90 ;;; 3/12/90 Olin
  91 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  92 ;;;   Tale suggested this.
  93
  94 ;;; Code:
  95
  96 (require 'scheme)
  97 (require 'comint)
  98
  99
 100 (defgroup cmuscheme nil
 101   "Run a scheme process in a buffer."
 102   :group 'scheme)
 103
 104 ;;; INFERIOR SCHEME MODE STUFF
 105 ;;;============================================================================
 106
 107 (defcustom inferior-scheme-mode-hook nil
 108   "*Hook for customising inferior-scheme mode."
 109   :type 'hook
 110   :group 'cmuscheme)
 111
 112 (defvar inferior-scheme-mode-map
 113   (let ((m (make-sparse-keymap)))
 114     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 115     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 116     (define-key m "\C-c\C-l" 'scheme-load-file)
 117     (define-key m "\C-c\C-k" 'scheme-compile-file)
 118     (scheme-mode-commands m)
 119     m))
 120
 121 ;; Install the process communication commands in the scheme-mode keymap.
 122 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 123 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 124 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 125 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 126 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 127 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 128 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 129 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 130 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 131 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 132 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 133
 134 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 135   (define-key map [separator-eval] '("--"))
 136   (define-key map [compile-file]
 137     '("Compile Scheme File" . scheme-compile-file))
 138   (define-key map [load-file]
 139     '("Load Scheme File" . scheme-load-file))
 140   (define-key map [switch]
 141     '("Switch to Scheme" . switch-to-scheme))
 142   (define-key map [com-def-go]
 143     '("Compile Definitiion & Go" . scheme-compile-definition-and-go))
 144   (define-key map [com-def]
 145     '("Compile Definitiion" . scheme-compile-definition))
 146   (define-key map [send-def-go]
 147     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 148   (define-key map [send-def]
 149     '("Evaluate Last Definition" . scheme-send-definition))
 150   (define-key map [send-region-go]
 151     '("Evaluate Region & Go" . scheme-send-region-and-go))
 152   (define-key map [send-region]
 153     '("Evaluate Region" . scheme-send-region))
 154   (define-key map [send-sexp]
 155     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 156 )
 157
 158 (defvar scheme-buffer)
 159
 160 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 161   "Major mode for interacting with an inferior Scheme process.
 162
 163 The following commands are available:
 164 \\{inferior-scheme-mode-map}
 165
 166 A Scheme process can be fired up with M-x run-scheme.
 167
 168 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 169 inferior-scheme-mode-hook (in that order).
 170
 171 You can send text to the inferior Scheme process from other buffers containing
 172 Scheme source.
 173     switch-to-scheme switches the current buffer to the Scheme process buffer.
 174     scheme-send-definition sends the current definition to the Scheme process.
 175     scheme-compile-definition compiles the current definition.
 176     scheme-send-region sends the current region to the Scheme process.
 177     scheme-compile-region compiles the current region.
 178
 179     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 180         scheme-send-region-and-go, and scheme-compile-region-and-go
 181         switch to the Scheme process buffer after sending their text.
 182 For information on running multiple processes in multiple buffers, see
 183 documentation for variable scheme-buffer.
 184
 185 Commands:
 186 Return after the end of the process' output sends the text from the
 187     end of process to point.
 188 Return before the end of the process' output copies the sexp ending at point
 189     to the end of the process' output, and sends it.
 190 Delete converts tabs to spaces as it moves back.
 191 Tab indents for Scheme; with argument, shifts rest
 192     of expression rigidly with the current line.
 193 C-M-q does Tab on each line starting within following expression.
 194 Paragraphs are separated only by blank lines.  Semicolons start comments.
 195 If you accidentally suspend your process, use \\[comint-continue-subjob]
 196 to continue it."
 197   ;; Customise in inferior-scheme-mode-hook
 198   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 199   (scheme-mode-variables)
 200   (setq mode-line-process '(":%s"))
 201   (setq comint-input-filter (function scheme-input-filter))
 202   (setq comint-get-old-input (function scheme-get-old-input)))
 203
 204 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 205   "*Input matching this regexp are not saved on the history list.
 206 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 207   :type 'regexp
 208   :group 'cmuscheme)
 209
 210 (defun scheme-input-filter (str)
 211   "Don't save anything matching `inferior-scheme-filter-regexp'."
 212   (not (string-match inferior-scheme-filter-regexp str)))
 213
 214 (defun scheme-get-old-input ()
 215   "Snarf the sexp ending at point."
 216   (save-excursion
 217     (let ((end (point)))
 218       (backward-sexp)
 219       (buffer-substring (point) end))))
 220
 221 (defun scheme-args-to-list (string)
 222   (let ((where (string-match "[ \t]" string)))
 223     (cond ((null where) (list string))
 224           ((not (= where 0))
 225            (cons (substring string 0 where)
 226                  (scheme-args-to-list (substring string (+ 1 where)
 227                                                  (length string)))))
 228           (t (let ((pos (string-match "[^ \t]" string)))
 229                (if (null pos)
 230                    nil
 231                  (scheme-args-to-list (substring string pos
 232                                                  (length string)))))))))
 233
 234 ;;;###autoload
 235 (defun run-scheme (cmd)
 236   "Run an inferior Scheme process, input and output via buffer *scheme*.
 237 If there is a process already running in `*scheme*', switch to that buffer.
 238 With argument, allows you to edit the command line (default is value
 239 of `scheme-program-name').  Runs the hooks `inferior-scheme-mode-hook'
 240 \(after the `comint-mode-hook' is run).
 241 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 242
 243   (interactive (list (if current-prefix-arg
 244                          (read-string "Run Scheme: " scheme-program-name)
 245                          scheme-program-name)))
 246   (if (not (comint-check-proc "*scheme*"))
 247       (let ((cmdlist (scheme-args-to-list cmd)))
 248         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 249                            nil (cdr cmdlist)))
 250         (inferior-scheme-mode)))
 251   (setq scheme-program-name cmd)
 252   (setq scheme-buffer "*scheme*")
 253   (pop-to-buffer "*scheme*"))
 254 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 255
 256 (defun scheme-send-region (start end)
 257   "Send the current region to the inferior Scheme process."
 258   (interactive "r")
 259   (comint-send-region (scheme-proc) start end)
 260   (comint-send-string (scheme-proc) "\n"))
 261
 262 (defun scheme-send-definition ()
 263   "Send the current definition to the inferior Scheme process."
 264   (interactive)
 265   (save-excursion
 266    (end-of-defun)
 267    (let ((end (point)))
 268      (beginning-of-defun)
 269      (scheme-send-region (point) end))))
 270
 271 (defun scheme-send-last-sexp ()
 272   "Send the previous sexp to the inferior Scheme process."
 273   (interactive)
 274   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 275
 276 (defcustom scheme-compile-exp-command "(compile '%s)"
 277   "*Template for issuing commands to compile arbitrary Scheme expressions."
 278   :type 'string
 279   :group 'cmuscheme)
 280
 281 (defun scheme-compile-region (start end)
 282   "Compile the current region in the inferior Scheme process.
 283 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 284   (interactive "r")
 285   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 286                                             (format "(begin %s)"
 287                                                     (buffer-substring start end))))
 288   (comint-send-string (scheme-proc) "\n"))
 289
 290 (defun scheme-compile-definition ()
 291   "Compile the current definition in the inferior Scheme process."
 292   (interactive)
 293   (save-excursion
 294    (end-of-defun)
 295    (let ((end (point)))
 296      (beginning-of-defun)
 297      (scheme-compile-region (point) end))))
 298
 299 (defun switch-to-scheme (eob-p)
 300   "Switch to the scheme process buffer.
 301 With argument, position cursor at end of buffer."
 302   (interactive "P")
 303   (if (get-buffer scheme-buffer)
 304       (pop-to-buffer scheme-buffer)
 305       (error "No current process buffer.  See variable `scheme-buffer'"))
 306   (cond (eob-p
 307          (push-mark)
 308          (goto-char (point-max)))))
 309
 310 (defun scheme-send-region-and-go (start end)
 311   "Send the current region to the inferior Scheme process.
 312 Then switch to the process buffer."
 313   (interactive "r")
 314   (scheme-send-region start end)
 315   (switch-to-scheme t))
 316
 317 (defun scheme-send-definition-and-go ()
 318   "Send the current definition to the inferior Scheme.
 319 Then switch to the process buffer."
 320   (interactive)
 321   (scheme-send-definition)
 322   (switch-to-scheme t))
 323
 324 (defun scheme-compile-definition-and-go ()
 325   "Compile the current definition in the inferior Scheme.
 326 Then switch to the process buffer."
 327   (interactive)
 328   (scheme-compile-definition)
 329   (switch-to-scheme t))
 330
 331 (defun scheme-compile-region-and-go (start end)
 332   "Compile the current region in the inferior Scheme.
 333 Then switch to the process buffer."
 334   (interactive "r")
 335   (scheme-compile-region start end)
 336   (switch-to-scheme t))
 337
 338 (defcustom scheme-source-modes '(scheme-mode)
 339   "*Used to determine if a buffer contains Scheme source code.
 340 If it's loaded into a buffer that is in one of these major modes, it's
 341 considered a scheme source file by `scheme-load-file' and `scheme-compile-file'.
 342 Used by these commands to determine defaults."
 343   :type '(repeat function)
 344   :group 'cmuscheme)
 345
 346 (defvar scheme-prev-l/c-dir/file nil
 347   "Caches the last (directory . file) pair.
 348 Caches the last pair used in the last `scheme-load-file' or
 349 `scheme-compile-file' command. Used for determining the default in the
 350 next one.")
 351
 352 (defun scheme-load-file (file-name)
 353   "Load a Scheme file FILE-NAME into the inferior Scheme process."
 354   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 355                                   scheme-source-modes t)) ; t because `load'
 356                                                           ; needs an exact name
 357   (comint-check-source file-name) ; Check to see if buffer needs saved.
 358   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 359                                        (file-name-nondirectory file-name)))
 360   (comint-send-string (scheme-proc) (concat "(load \""
 361                                             file-name
 362                                             "\"\)\n")))
 363
 364 (defun scheme-compile-file (file-name)
 365   "Compile a Scheme file FILE-NAME in the inferior Scheme process."
 366   (interactive (comint-get-source "Compile Scheme file: "
 367                                   scheme-prev-l/c-dir/file
 368                                   scheme-source-modes
 369                                   nil)) ; nil because COMPILE doesn't
 370                                         ; need an exact name.
 371   (comint-check-source file-name) ; Check to see if buffer needs saved.
 372   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 373                                        (file-name-nondirectory file-name)))
 374   (comint-send-string (scheme-proc) (concat "(compile-file \""
 375                                             file-name
 376                                             "\"\)\n")))
 377
 378 \f
 379 (defvar scheme-buffer nil "*The current scheme process buffer.
 380
 381 MULTIPLE PROCESS SUPPORT
 382 ===========================================================================
 383 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 384 processes.  To run multiple Scheme processes, you start the first up with
 385 \\[run-scheme].  It will be in a buffer named *scheme*.  Rename this buffer
 386 with \\[rename-buffer].  You may now start up a new process with another
 387 \\[run-scheme].  It will be in a new buffer, named *scheme*.  You can
 388 switch between the different process buffers with \\[switch-to-buffer].
 389
 390 Commands that send text from source buffers to Scheme processes --
 391 like `scheme-send-definition' or `scheme-compile-region' -- have to choose a
 392 process to send to, when you have more than one Scheme process around.  This
 393 is determined by the global variable `scheme-buffer'.  Suppose you
 394 have three inferior Schemes running:
 395     Buffer      Process
 396     foo         scheme
 397     bar         scheme<2>
 398     *scheme*    scheme<3>
 399 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 400 code, what process do you send it to?
 401
 402 - If you're in a process buffer (foo, bar, or *scheme*),
 403   you send it to that process.
 404 - If you're in some other buffer (e.g., a source file), you
 405   send it to the process attached to buffer `scheme-buffer'.
 406 This process selection is performed by function `scheme-proc'.
 407
 408 Whenever \\[run-scheme] fires up a new process, it resets `scheme-buffer'
 409 to be the new process's buffer.  If you only run one process, this will
 410 do the right thing.  If you run multiple processes, you can change
 411 `scheme-buffer' to another process buffer with \\[set-variable].
 412
 413 More sophisticated approaches are, of course, possible.  If you find yourself
 414 needing to switch back and forth between multiple processes frequently,
 415 you may wish to consider ilisp.el, a larger, more sophisticated package
 416 for running inferior Lisp and Scheme processes.  The approach taken here is
 417 for a minimal, simple implementation.  Feel free to extend it.")
 418
 419 (defun scheme-proc ()
 420   "Return the current scheme process.  See variable `scheme-buffer'."
 421   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 422                                       (current-buffer)
 423                                       scheme-buffer))))
 424     (or proc
 425         (error "No current process.  See variable `scheme-buffer'"))))
 426
 427
 428 ;;; Do the user's customisation...
 429
 430 (defcustom cmuscheme-load-hook nil
 431   "This hook is run when cmuscheme is loaded in.
 432 This is a good place to put keybindings."
 433   :type 'hook
 434   :group 'cmuscheme)
 435
 436 (run-hooks 'cmuscheme-load-hook)
 437
 438 (provide 'cmuscheme)
 439
 440 ;;; cmuscheme.el ends here