lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'syntax)
  29
  30 (defvar comint-prompt-regexp)
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40 \f
  41 ;;; Switching tooltips on/off
  42
  43 (define-minor-mode tooltip-mode
  44   "Toggle Tooltip mode.
  45 With a prefix argument ARG, enable Tooltip mode if ARG is positive,
  46 and disable it otherwise.  If called from Lisp, enable the mode
  47 if ARG is omitted or nil.
  48
  49 When this global minor mode is enabled, Emacs displays help
  50 text (e.g. for buttons and menu items that you put the mouse on)
  51 in a pop-up window.
  52
  53 When Tooltip mode is disabled, Emacs displays help text in the
  54 echo area, instead of making a pop-up window."
  55   :global t
  56   ;; Even if we start on a text-only terminal, make this non-nil by
  57   ;; default because we can open a graphical frame later (multi-tty).
  58   :init-value t
  59   :initialize 'custom-initialize-delay
  60   :group 'tooltip
  61   (if (and tooltip-mode (fboundp 'x-show-tip))
  62       (progn
  63         (add-hook 'pre-command-hook 'tooltip-hide)
  64         (add-hook 'tooltip-functions 'tooltip-help-tips))
  65     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  66       (remove-hook 'pre-command-hook 'tooltip-hide))
  67     (remove-hook 'tooltip-functions 'tooltip-help-tips))
  68   (setq show-help-function
  69         (if tooltip-mode 'tooltip-show-help 'tooltip-show-help-non-mode)))
  70
  71 \f
  72 ;;; Customizable settings
  73
  74 (defcustom tooltip-delay 0.7
  75   "Seconds to wait before displaying a tooltip the first time."
  76   :type 'number
  77   :group 'tooltip)
  78
  79 (defcustom tooltip-short-delay 0.1
  80   "Seconds to wait between subsequent tooltips on different items."
  81   :type 'number
  82   :group 'tooltip)
  83
  84 (defcustom tooltip-recent-seconds 1
  85   "Display tooltips if changing tip items within this many seconds.
  86 Do so after `tooltip-short-delay'."
  87   :type 'number
  88   :group 'tooltip)
  89
  90 (defcustom tooltip-hide-delay 10
  91   "Hide tooltips automatically after this many seconds."
  92   :type 'number
  93   :group 'tooltip)
  94
  95 (defcustom tooltip-x-offset 5
  96   "X offset, in pixels, for the display of tooltips.
  97 The offset is the distance between the X position of the mouse and
  98 the left border of the tooltip window.  It must be chosen so that the
  99 tooltip window doesn't contain the mouse when it pops up, or it may
 100 interfere with clicking where you wish.
 101
 102 If `tooltip-frame-parameters' includes the `left' parameter,
 103 the value of `tooltip-x-offset' is ignored."
 104   :type 'integer
 105   :group 'tooltip)
 106
 107 (defcustom tooltip-y-offset +20
 108   "Y offset, in pixels, for the display of tooltips.
 109 The offset is the distance between the Y position of the mouse and
 110 the top border of the tooltip window.  It must be chosen so that the
 111 tooltip window doesn't contain the mouse when it pops up, or it may
 112 interfere with clicking where you wish.
 113
 114 If `tooltip-frame-parameters' includes the `top' parameter,
 115 the value of `tooltip-y-offset' is ignored."
 116   :type 'integer
 117   :group 'tooltip)
 118
 119 (defcustom tooltip-frame-parameters
 120   '((name . "tooltip")
 121     (internal-border-width . 2)
 122     (border-width . 1))
 123   "Frame parameters used for tooltips.
 124
 125 If `left' or `top' parameters are included, they specify the absolute
 126 position to pop up the tooltip.
 127
 128 Note that font and color parameters are ignored, and the attributes
 129 of the `tooltip' face are used instead."
 130   :type 'sexp
 131   :group 'tooltip)
 132
 133 (defface tooltip
 134   '((((class color))
 135      :background "lightyellow"
 136      :foreground "black"
 137      :inherit variable-pitch)
 138     (t
 139      :inherit variable-pitch))
 140   "Face for tooltips."
 141   :group 'tooltip
 142   :group 'basic-faces)
 143
 144 (defcustom tooltip-use-echo-area nil
 145   "Use the echo area instead of tooltip frames for help and GUD tooltips.
 146 This variable is obsolete; instead of setting it to t, disable
 147 `tooltip-mode' (which has a similar effect)."
 148   :type 'boolean
 149   :group 'tooltip)
 150
 151 (make-obsolete-variable 'tooltip-use-echo-area
 152                         "disable Tooltip mode instead" "24.1" 'set)
 153
 154 \f
 155 ;;; Variables that are not customizable.
 156
 157 (define-obsolete-variable-alias 'tooltip-hook 'tooltip-functions "23.1")
 158
 159 (defvar tooltip-functions nil
 160   "Functions to call to display tooltips.
 161 Each function is called with one argument EVENT which is a copy
 162 of the last mouse movement event that occurred.  If one of these
 163 functions displays the tooltip, it should return non-nil and the
 164 rest are not called.")
 165
 166 (defvar tooltip-timeout-id nil
 167   "The id of the timeout started when Emacs becomes idle.")
 168
 169 (defvar tooltip-last-mouse-motion-event nil
 170   "A copy of the last mouse motion event seen.")
 171
 172 (defvar tooltip-hide-time nil
 173   "Time when the last tooltip was hidden.")
 174
 175 (defvar gud-tooltip-mode) ;; Prevent warning.
 176
 177 ;;; Event accessors
 178
 179 (defun tooltip-event-buffer (event)
 180   "Return the buffer over which event EVENT occurred.
 181 This might return nil if the event did not occur over a buffer."
 182   (let ((window (posn-window (event-end event))))
 183     (and window (window-buffer window))))
 184
 185 \f
 186 ;;; Timeout for tooltip display
 187
 188 (defun tooltip-delay ()
 189   "Return the delay in seconds for the next tooltip."
 190   (if (and tooltip-hide-time
 191            (< (- (float-time) tooltip-hide-time) tooltip-recent-seconds))
 192       tooltip-short-delay
 193     tooltip-delay))
 194
 195 (defun tooltip-cancel-delayed-tip ()
 196   "Disable the tooltip timeout."
 197   (when tooltip-timeout-id
 198     (disable-timeout tooltip-timeout-id)
 199     (setq tooltip-timeout-id nil)))
 200
 201 (defun tooltip-start-delayed-tip ()
 202   "Add a one-shot timeout to call function `tooltip-timeout'."
 203   (setq tooltip-timeout-id
 204         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 205
 206 (defun tooltip-timeout (_object)
 207   "Function called when timer with id `tooltip-timeout-id' fires."
 208   (run-hook-with-args-until-success 'tooltip-functions
 209                                     tooltip-last-mouse-motion-event))
 210
 211 \f
 212 ;;; Displaying tips
 213
 214 (defun tooltip-set-param (alist key value)
 215   "Change the value of KEY in alist ALIST to VALUE.
 216 If there's no association for KEY in ALIST, add one, otherwise
 217 change the existing association.  Value is the resulting alist."
 218   (declare (obsolete "use (setf (alist-get ..) ..) instead" "25.1"))
 219   (setf (alist-get key alist) value)
 220   alist)
 221
 222 (declare-function x-show-tip "xfns.c"
 223                   (string &optional frame parms timeout dx dy))
 224
 225 (defun tooltip-show (text &optional use-echo-area)
 226   "Show a tooltip window displaying TEXT.
 227
 228 Text larger than `x-max-tooltip-size' is clipped.
 229
 230 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 231 parameters, they determine the x and y position where the tooltip
 232 is displayed.  Otherwise, the tooltip pops at offsets specified by
 233 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 234 position.
 235
 236 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 237 in echo area."
 238   (if use-echo-area
 239       (tooltip-show-help-non-mode text)
 240     (condition-case error
 241         (let ((params (copy-sequence tooltip-frame-parameters))
 242               (fg (face-attribute 'tooltip :foreground))
 243               (bg (face-attribute 'tooltip :background)))
 244           (when (stringp fg)
 245             (setf (alist-get 'foreground-color params) fg)
 246             (setf (alist-get 'border-color params) fg))
 247           (when (stringp bg)
 248             (setf (alist-get 'background-color params) bg))
 249           (x-show-tip (propertize text 'face 'tooltip)
 250                       (selected-frame)
 251                       params
 252                       tooltip-hide-delay
 253                       tooltip-x-offset
 254                       tooltip-y-offset))
 255       (error
 256        (message "Error while displaying tooltip: %s" error)
 257        (sit-for 1)
 258        (message "%s" text)))))
 259
 260 (declare-function x-hide-tip "xfns.c" ())
 261
 262 (defun tooltip-hide (&optional _ignored-arg)
 263   "Hide a tooltip, if one is displayed.
 264 Value is non-nil if tooltip was open."
 265   (tooltip-cancel-delayed-tip)
 266   (when (x-hide-tip)
 267     (setq tooltip-hide-time (float-time))))
 268
 269 \f
 270 ;;; Debugger-related functions
 271
 272 (defun tooltip-identifier-from-point (point)
 273   "Extract the identifier at POINT, if any.
 274 Value is nil if no identifier exists at point.  Identifier extraction
 275 is based on the current syntax table."
 276   (save-excursion
 277     (goto-char point)
 278     (let* ((start (progn (skip-syntax-backward "w_") (point)))
 279            (pstate (syntax-ppss)))
 280       (unless (or (looking-at "[0-9]")
 281                   (nth 3 pstate)
 282                   (nth 4 pstate))
 283         (skip-syntax-forward "w_")
 284         (when (> (point) start)
 285           (buffer-substring start (point)))))))
 286
 287 (defun tooltip-expr-to-print (event)
 288   "Return an expression that should be printed for EVENT.
 289 If a region is active and the mouse is inside the region, print
 290 the region.  Otherwise, figure out the identifier around the point
 291 where the mouse is."
 292   (with-current-buffer (tooltip-event-buffer event)
 293     (let ((point (posn-point (event-end event))))
 294       (if (use-region-p)
 295           (when (and (<= (region-beginning) point) (<= point (region-end)))
 296             (buffer-substring (region-beginning) (region-end)))
 297         (tooltip-identifier-from-point point)))))
 298
 299 (defun tooltip-process-prompt-regexp (process)
 300   "Return regexp matching the prompt of PROCESS at the end of a string.
 301 The prompt is taken from the value of `comint-prompt-regexp' in
 302 the buffer of PROCESS."
 303   (let ((prompt-regexp (with-current-buffer (process-buffer process)
 304                          comint-prompt-regexp)))
 305     (concat "\n*"
 306             ;; Most start with `^' but the one for `sdb' cannot be easily
 307             ;; stripped.  Code the prompt for `sdb' fixed here.
 308             (if (= (aref prompt-regexp 0) ?^)
 309                 (substring prompt-regexp 1)
 310               "\\*")
 311             "$")))
 312
 313 (defun tooltip-strip-prompt (process output)
 314   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 315   (save-match-data
 316     (if (string-match (tooltip-process-prompt-regexp process) output)
 317         (substring output 0 (match-beginning 0))
 318       output)))
 319
 320 \f
 321 ;;; Tooltip help.
 322
 323 (defvar tooltip-help-message nil
 324   "The last help message received via `show-help-function'.
 325 This is used by `tooltip-show-help' and
 326 `tooltip-show-help-non-mode'.")
 327
 328 (defvar tooltip-previous-message nil
 329   "The previous content of the echo area.")
 330
 331 (defun tooltip-show-help-non-mode (help)
 332   "Function installed as `show-help-function' when Tooltip mode is off.
 333 It is also called if Tooltip mode is on, for text-only displays."
 334   (when (and (not (window-minibuffer-p)) ;Don't overwrite minibuffer contents.
 335              (not cursor-in-echo-area))  ;Don't overwrite a prompt.
 336     (cond
 337      ((stringp help)
 338       (setq help (replace-regexp-in-string "\n" ", " help))
 339       (unless (or tooltip-previous-message
 340                   (equal-including-properties help (current-message))
 341                   (and (stringp tooltip-help-message)
 342                        (equal-including-properties tooltip-help-message
 343                                                    (current-message))))
 344         (setq tooltip-previous-message (current-message)))
 345       (setq tooltip-help-message help)
 346       (let ((message-truncate-lines t)
 347             (message-log-max nil))
 348         (message "%s" help)))
 349      ((stringp tooltip-previous-message)
 350       (let ((message-log-max nil))
 351         (message "%s" tooltip-previous-message)
 352         (setq tooltip-previous-message nil)))
 353      (t
 354       (message nil)))))
 355
 356 (defun tooltip-show-help (msg)
 357   "Function installed as `show-help-function'.
 358 MSG is either a help string to display, or nil to cancel the display."
 359   (if (display-graphic-p)
 360       (let ((previous-help tooltip-help-message))
 361         (setq tooltip-help-message msg)
 362         (cond ((null msg)
 363                ;; Cancel display.  This also cancels a delayed tip, if
 364                ;; there is one.
 365                (tooltip-hide))
 366               ((equal-including-properties previous-help msg)
 367                ;; Same help as before (but possibly the mouse has moved).
 368                ;; Keep what we have.
 369                )
 370               (t
 371                ;; A different help.  Remove a previous tooltip, and
 372                ;; display a new one, with some delay.
 373                (tooltip-hide)
 374                (tooltip-start-delayed-tip))))
 375     ;; On text-only displays, try `tooltip-show-help-non-mode'.
 376     (tooltip-show-help-non-mode msg)))
 377
 378 (defun tooltip-help-tips (_event)
 379   "Hook function to display a help tooltip.
 380 This is installed on the hook `tooltip-functions', which
 381 is run when the timer with id `tooltip-timeout-id' fires.
 382 Value is non-nil if this function handled the tip."
 383   (when (stringp tooltip-help-message)
 384     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 385     t))
 386
 387 (provide 'tooltip)
 388
 389 ;;; tooltip.el ends here