lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2015 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This code implements GNU Emacs's built-in help system, the one invoked by
  28 ;; `M-x help-for-help'.
  29
  30 ;;; Code:
  31
  32 ;; Get the macro make-help-screen when this is compiled,
  33 ;; or run interpreted, but not when the compiled code is loaded.
  34 (eval-when-compile (require 'help-macro))
  35
  36 ;; This makes `with-output-to-temp-buffer' buffers use `help-mode'.
  37 (add-hook 'temp-buffer-setup-hook 'help-mode-setup)
  38 (add-hook 'temp-buffer-show-hook 'help-mode-finish)
  39
  40 ;; `help-window-point-marker' is a marker you can move to a valid
  41 ;; position of the buffer shown in the help window in order to override
  42 ;; the standard positioning mechanism (`point-min') chosen by
  43 ;; `with-output-to-temp-buffer' and `with-temp-buffer-window'.
  44 ;; `with-help-window' has this point nowhere before exiting.  Currently
  45 ;; used by `view-lossage' to assert that the last keystrokes are always
  46 ;; visible.
  47 (defvar help-window-point-marker (make-marker)
  48   "Marker to override default `window-point' in help windows.")
  49
  50 (defvar help-window-old-frame nil
  51   "Frame selected at the time `with-help-window' is invoked.")
  52
  53 (defvar help-map
  54   (let ((map (make-sparse-keymap)))
  55     (define-key map (char-to-string help-char) 'help-for-help)
  56     (define-key map [help] 'help-for-help)
  57     (define-key map [f1] 'help-for-help)
  58     (define-key map "." 'display-local-help)
  59     (define-key map "?" 'help-for-help)
  60
  61     (define-key map "\C-a" 'about-emacs)
  62     (define-key map "\C-c" 'describe-copying)
  63     (define-key map "\C-d" 'view-emacs-debugging)
  64     (define-key map "\C-e" 'view-external-packages)
  65     (define-key map "\C-f" 'view-emacs-FAQ)
  66     (define-key map "\C-m" 'view-order-manuals)
  67     (define-key map "\C-n" 'view-emacs-news)
  68     (define-key map "\C-o" 'describe-distribution)
  69     (define-key map "\C-p" 'view-emacs-problems)
  70     (define-key map "\C-t" 'view-emacs-todo)
  71     (define-key map "\C-w" 'describe-no-warranty)
  72
  73     ;; This does not fit the pattern, but it is natural given the C-\ command.
  74     (define-key map "\C-\\" 'describe-input-method)
  75
  76     (define-key map "C" 'describe-coding-system)
  77     (define-key map "F" 'Info-goto-emacs-command-node)
  78     (define-key map "I" 'describe-input-method)
  79     (define-key map "K" 'Info-goto-emacs-key-command-node)
  80     (define-key map "L" 'describe-language-environment)
  81     (define-key map "S" 'info-lookup-symbol)
  82
  83     (define-key map "a" 'apropos-command)
  84     (define-key map "b" 'describe-bindings)
  85     (define-key map "c" 'describe-key-briefly)
  86     (define-key map "d" 'apropos-documentation)
  87     (define-key map "e" 'view-echo-area-messages)
  88     (define-key map "f" 'describe-function)
  89     (define-key map "g" 'describe-gnu-project)
  90     (define-key map "h" 'view-hello-file)
  91
  92     (define-key map "i" 'info)
  93     (define-key map "4i" 'info-other-window)
  94
  95     (define-key map "k" 'describe-key)
  96     (define-key map "l" 'view-lossage)
  97     (define-key map "m" 'describe-mode)
  98     (define-key map "o" 'describe-function-or-variable)
  99     (define-key map "n" 'view-emacs-news)
 100     (define-key map "p" 'finder-by-keyword)
 101     (define-key map "P" 'describe-package)
 102     (define-key map "r" 'info-emacs-manual)
 103     (define-key map "s" 'describe-syntax)
 104     (define-key map "t" 'help-with-tutorial)
 105     (define-key map "w" 'where-is)
 106     (define-key map "v" 'describe-variable)
 107     (define-key map "q" 'help-quit)
 108     map)
 109   "Keymap for characters following the Help key.")
 110
 111 (define-key global-map (char-to-string help-char) 'help-command)
 112 (define-key global-map [help] 'help-command)
 113 (define-key global-map [f1] 'help-command)
 114 (fset 'help-command help-map)
 115
 116 ;; insert-button makes the action nil if it is not store somewhere
 117 (defvar help-button-cache nil)
 118
 119 \f
 120 (defun help-quit ()
 121   "Just exit from the Help command's command loop."
 122   (interactive)
 123   nil)
 124
 125 (defvar help-return-method nil
 126   "What to do to \"exit\" the help buffer.
 127 This is a list
 128  (WINDOW . t)              delete the selected window (and possibly its frame,
 129                            see `quit-window'), go to WINDOW.
 130  (WINDOW . quit-window)    do quit-window, then select WINDOW.
 131  (WINDOW BUF START POINT)  display BUF at START, POINT, then select WINDOW.")
 132
 133 (define-obsolete-function-alias 'print-help-return-message 'help-print-return-message "23.2")
 134 (defun help-print-return-message (&optional function)
 135   "Display or return message saying how to restore windows after help command.
 136 This function assumes that `standard-output' is the help buffer.
 137 It computes a message, and applies the optional argument FUNCTION to it.
 138 If FUNCTION is nil, it applies `message', thus displaying the message.
 139 In addition, this function sets up `help-return-method', which see, that
 140 specifies what to do when the user exits the help buffer.
 141
 142 Do not call this in the scope of `with-help-window'."
 143   (and (not (get-buffer-window standard-output))
 144        (let ((first-message
 145               (cond ((or
 146                       pop-up-frames
 147                       (special-display-p (buffer-name standard-output)))
 148                      (setq help-return-method (cons (selected-window) t))
 149                      ;; If the help output buffer is a special display buffer,
 150                      ;; don't say anything about how to get rid of it.
 151                      ;; First of all, the user will do that with the window
 152                      ;; manager, not with Emacs.
 153                      ;; Secondly, the buffer has not been displayed yet,
 154                      ;; so we don't know whether its frame will be selected.
 155                      nil)
 156                     ((not (one-window-p t))
 157                      (setq help-return-method
 158                            (cons (selected-window) 'quit-window))
 159                      "Type \\[display-buffer] RET to restore the other window.")
 160                     (pop-up-windows
 161                      (setq help-return-method (cons (selected-window) t))
 162                      "Type \\[delete-other-windows] to remove help window.")
 163                     (t
 164                      (setq help-return-method
 165                            (list (selected-window) (window-buffer)
 166                                  (window-start) (window-point)))
 167                      "Type \\[switch-to-buffer] RET to remove help window."))))
 168          (funcall (or function 'message)
 169                   (concat
 170                    (if first-message
 171                        (substitute-command-keys first-message))
 172                    (if first-message "  ")
 173                    ;; If the help buffer will go in a separate frame,
 174                    ;; it's no use mentioning a command to scroll, so don't.
 175                    (if (or pop-up-windows
 176                            (special-display-p (buffer-name standard-output)))
 177                        nil
 178                      (if (same-window-p (buffer-name standard-output))
 179                          ;; Say how to scroll this window.
 180                          (substitute-command-keys
 181                           "\\[scroll-up] to scroll the help.")
 182                        ;; Say how to scroll some other window.
 183                        (substitute-command-keys
 184                         "\\[scroll-other-window] to scroll the help."))))))))
 185
 186 ;; So keyboard macro definitions are documented correctly
 187 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 188
 189 (defalias 'help 'help-for-help-internal)
 190 ;; find-function can find this.
 191 (defalias 'help-for-help 'help-for-help-internal)
 192 ;; It can't find this, but nobody will look.
 193 (make-help-screen help-for-help-internal
 194   (purecopy "Type a help option: [abcCdefFgiIkKlLmnprstvw.] C-[cdefmnoptw] or ?")
 195   ;; Don't purecopy this one, because it's not evaluated (it's
 196   ;; directly used as a docstring in a function definition, so it'll
 197   ;; be moved to the DOC file anyway: no need for purecopying it).
 198   "You have typed %THIS-KEY%, the help character.  Type a Help option:
 199 \(Use SPC or DEL to scroll through this text.  Type \\<help-map>\\[help-quit] to exit the Help command.)
 200
 201 a PATTERN   Show commands whose name matches the PATTERN (a list of words
 202               or a regexp).  See also the `apropos' command.
 203 b           Display all key bindings.
 204 c KEYS      Display the command name run by the given key sequence.
 205 C CODING    Describe the given coding system, or RET for current ones.
 206 d PATTERN   Show a list of functions, variables, and other items whose
 207               documentation matches the PATTERN (a list of words or a regexp).
 208 e           Go to the *Messages* buffer which logs echo-area messages.
 209 f FUNCTION  Display documentation for the given function.
 210 F COMMAND   Show the Emacs manual's section that describes the command.
 211 g           Display information about the GNU project.
 212 h           Display the HELLO file which illustrates various scripts.
 213 i           Start the Info documentation reader: read included manuals.
 214 I METHOD    Describe a specific input method, or RET for current.
 215 k KEYS      Display the full documentation for the key sequence.
 216 K KEYS      Show the Emacs manual's section for the command bound to KEYS.
 217 l           Show last 300 input keystrokes (lossage).
 218 L LANG-ENV  Describes a specific language environment, or RET for current.
 219 m           Display documentation of current minor modes and current major mode,
 220               including their special commands.
 221 n           Display news of recent Emacs changes.
 222 o SYMBOL    Display the given function or variable's documentation and value.
 223 p TOPIC     Find packages matching a given topic keyword.
 224 P PACKAGE   Describe the given Emacs Lisp package.
 225 r           Display the Emacs manual in Info mode.
 226 s           Display contents of current syntax table, plus explanations.
 227 S SYMBOL    Show the section for the given symbol in the Info manual
 228               for the programming language used in this buffer.
 229 t           Start the Emacs learn-by-doing tutorial.
 230 v VARIABLE  Display the given variable's documentation and value.
 231 w COMMAND   Display which keystrokes invoke the given command (where-is).
 232 .           Display any available local help at point in the echo area.
 233
 234 C-a         Information about Emacs.
 235 C-c         Emacs copying permission (GNU General Public License).
 236 C-d         Instructions for debugging GNU Emacs.
 237 C-e         External packages and information about Emacs.
 238 C-f         Emacs FAQ.
 239 C-m         How to order printed Emacs manuals.
 240 C-n         News of recent Emacs changes.
 241 C-o         Emacs ordering and distribution information.
 242 C-p         Info about known Emacs problems.
 243 C-t         Emacs TODO list.
 244 C-w         Information on absence of warranty for GNU Emacs."
 245   help-map)
 246
 247 \f
 248
 249 (defun function-called-at-point ()
 250   "Return a function around point or else called by the list containing point.
 251 If that doesn't give a function, return nil."
 252   (with-syntax-table emacs-lisp-mode-syntax-table
 253     (or (condition-case ()
 254             (save-excursion
 255               (or (not (zerop (skip-syntax-backward "_w")))
 256                   (eq (char-syntax (following-char)) ?w)
 257                   (eq (char-syntax (following-char)) ?_)
 258                   (forward-sexp -1))
 259               (skip-chars-forward "'")
 260               (let ((obj (read (current-buffer))))
 261                 (and (symbolp obj) (fboundp obj) obj)))
 262           (error nil))
 263         (condition-case ()
 264             (save-excursion
 265               (save-restriction
 266                 (narrow-to-region (max (point-min)
 267                                        (- (point) 1000)) (point-max))
 268                 ;; Move up to surrounding paren, then after the open.
 269                 (backward-up-list 1)
 270                 (forward-char 1)
 271                 ;; If there is space here, this is probably something
 272                 ;; other than a real Lisp function call, so ignore it.
 273                 (if (looking-at "[ \t]")
 274                     (error "Probably not a Lisp function call"))
 275                 (let ((obj (read (current-buffer))))
 276                   (and (symbolp obj) (fboundp obj) obj))))
 277           (error nil))
 278         (let* ((str (find-tag-default))
 279                (sym (if str (intern-soft str))))
 280           (if (and sym (fboundp sym))
 281               sym
 282             (save-match-data
 283               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 284                 (setq sym (intern-soft (match-string 1 str)))
 285                 (and (fboundp sym) sym))))))))
 286
 287 \f
 288 ;;; `User' help functions
 289
 290 (defun view-help-file (file &optional dir)
 291   (view-file (expand-file-name file (or dir data-directory)))
 292   (goto-address-mode 1)
 293   (goto-char (point-min)))
 294
 295 (defun describe-distribution ()
 296   "Display info on how to obtain the latest version of GNU Emacs."
 297   (interactive)
 298   (view-help-file "DISTRIB"))
 299
 300 (defun describe-copying ()
 301   "Display info on how you may redistribute copies of GNU Emacs."
 302   (interactive)
 303   (view-help-file "COPYING"))
 304
 305 ;; Maybe this command should just be removed.
 306 (defun describe-gnu-project ()
 307   "Browse online information on the GNU project."
 308   (interactive)
 309   (browse-url "http://www.gnu.org/gnu/thegnuproject.html"))
 310
 311 (define-obsolete-function-alias 'describe-project 'describe-gnu-project "22.2")
 312
 313 (defun describe-no-warranty ()
 314   "Display info on all the kinds of warranty Emacs does NOT have."
 315   (interactive)
 316   (describe-copying)
 317   (let (case-fold-search)
 318     (search-forward "Disclaimer of Warranty")
 319     (forward-line 0)
 320     (recenter 0)))
 321
 322 (defun describe-prefix-bindings ()
 323   "Describe the bindings of the prefix used to reach this command.
 324 The prefix described consists of all but the last event
 325 of the key sequence that ran this command."
 326   (interactive)
 327   (let ((key (this-command-keys)))
 328     (describe-bindings
 329      (if (stringp key)
 330          (substring key 0 (1- (length key)))
 331        (let ((prefix (make-vector (1- (length key)) nil))
 332              (i 0))
 333          (while (< i (length prefix))
 334            (aset prefix i (aref key i))
 335            (setq i (1+ i)))
 336          prefix)))))
 337 ;; Make C-h after a prefix, when not specifically bound,
 338 ;; run describe-prefix-bindings.
 339 (setq prefix-help-command 'describe-prefix-bindings)
 340
 341 (defun view-emacs-news (&optional version)
 342   "Display info on recent changes to Emacs.
 343 With argument, display info only for the selected version."
 344   (interactive "P")
 345   (unless version
 346     (setq version emacs-major-version))
 347   (when (consp version)
 348     (let* ((all-versions
 349             (let (res)
 350               (mapc
 351                (lambda (file)
 352                  (with-temp-buffer
 353                    (insert-file-contents
 354                     (expand-file-name file data-directory))
 355                    (while (re-search-forward
 356                            (if (member file '("NEWS.18" "NEWS.1-17"))
 357                                "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 358                              "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t)
 359                      (setq res (cons (match-string-no-properties 1) res)))))
 360                (cons "NEWS"
 361                      (directory-files data-directory nil
 362                                       "^NEWS\\.[0-9][-0-9]*$" nil)))
 363               (sort (delete-dups res) (lambda (a b) (string< b a)))))
 364            (current (car all-versions)))
 365       (setq version (completing-read
 366                      (format "Read NEWS for the version (default %s): " current)
 367                      all-versions nil nil nil nil current))
 368       (if (integerp (string-to-number version))
 369           (setq version (string-to-number version))
 370         (unless (or (member version all-versions)
 371                     (<= (string-to-number version) (string-to-number current)))
 372           (error "No news about version %s" version)))))
 373   (when (integerp version)
 374     (cond ((<= version 12)
 375            (setq version (format "1.%d" version)))
 376           ((<= version 18)
 377            (setq version (format "%d" version)))
 378           ((> version emacs-major-version)
 379            (error "No news about Emacs %d (yet)" version))))
 380   (let* ((vn (if (stringp version)
 381                  (string-to-number version)
 382                version))
 383          (file (cond
 384                 ((>= vn emacs-major-version) "NEWS")
 385                 ((< vn 18) "NEWS.1-17")
 386                 (t (format "NEWS.%d" vn))))
 387          res)
 388     (view-file (expand-file-name file data-directory))
 389     (widen)
 390     (goto-char (point-min))
 391     (when (stringp version)
 392       (when (re-search-forward
 393              (concat (if (< vn 19)
 394                          "Changes in Emacs[ \t]*"
 395                        "^\* [^0-9\n]*") version "$")
 396              nil t)
 397         (beginning-of-line)
 398         (narrow-to-region
 399          (point)
 400          (save-excursion
 401            (while (and (setq res
 402                              (re-search-forward
 403                               (if (< vn 19)
 404                                   "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 405                                 "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t))
 406                        (equal (match-string-no-properties 1) version)))
 407            (or res (goto-char (point-max)))
 408            (beginning-of-line)
 409            (point)))))))
 410
 411 (defun view-emacs-todo (&optional _arg)
 412   "Display the Emacs TODO list."
 413   (interactive "P")
 414   (view-help-file "TODO"))
 415
 416 (define-obsolete-function-alias 'view-todo 'view-emacs-todo "22.2")
 417
 418
 419 (defun view-echo-area-messages ()
 420   "View the log of recent echo-area messages: the `*Messages*' buffer.
 421 The number of messages retained in that buffer
 422 is specified by the variable `message-log-max'."
 423   (interactive)
 424   (with-current-buffer (messages-buffer)
 425     (goto-char (point-max))
 426     (display-buffer (current-buffer))))
 427
 428 (defun view-order-manuals ()
 429   "Display information on how to buy printed copies of Emacs manuals."
 430   (interactive)
 431 ;;  (view-help-file "ORDERS")
 432   (info "(emacs)Printed Books"))
 433
 434 (defun view-emacs-FAQ ()
 435   "Display the Emacs Frequently Asked Questions (FAQ) file."
 436   (interactive)
 437   ;; (find-file-read-only (expand-file-name "FAQ" data-directory))
 438   (info "(efaq)"))
 439
 440 (defun view-emacs-problems ()
 441   "Display info on known problems with Emacs and possible workarounds."
 442   (interactive)
 443   (view-help-file "PROBLEMS"))
 444
 445 (defun view-emacs-debugging ()
 446   "Display info on how to debug Emacs problems."
 447   (interactive)
 448   (view-help-file "DEBUG"))
 449
 450 ;; This used to visit MORE.STUFF; maybe it should just be removed.
 451 (defun view-external-packages ()
 452   "Display info on where to get more Emacs packages."
 453   (interactive)
 454   (info "(efaq)Packages that do not come with Emacs"))
 455
 456 (defun view-lossage ()
 457   "Display last few input keystrokes and the commands run.
 458
 459 To record all your input, use `open-dribble-file'."
 460   (interactive)
 461   (help-setup-xref (list #'view-lossage)
 462                    (called-interactively-p 'interactive))
 463   (with-help-window (help-buffer)
 464     (princ " ")
 465     (princ (mapconcat (lambda (key)
 466                         (cond
 467                          ((and (consp key) (null (car key)))
 468                           (format "[%s]\n" (if (symbolp (cdr key)) (cdr key)
 469                                            "anonymous-command")))
 470                          ((or (integerp key) (symbolp key) (listp key))
 471                           (single-key-description key))
 472                          (t
 473                           (prin1-to-string key nil))))
 474                       (recent-keys 'include-cmds)
 475                       " "))
 476     (with-current-buffer standard-output
 477       (goto-char (point-min))
 478       (while (not (eobp))
 479         (move-to-column 50)
 480         (unless (eolp)
 481           (fill-region (line-beginning-position) (line-end-position)))
 482         (forward-line 1))
 483       ;; jidanni wants to see the last keystrokes immediately.
 484       (set-marker help-window-point-marker (point)))))
 485
 486 \f
 487 ;; Key bindings
 488
 489 (defun describe-bindings (&optional prefix buffer)
 490   "Display a buffer showing a list of all defined keys, and their definitions.
 491 The keys are displayed in order of precedence.
 492
 493 The optional argument PREFIX, if non-nil, should be a key sequence;
 494 then we display only bindings that start with that prefix.
 495 The optional argument BUFFER specifies which buffer's bindings
 496 to display (default, the current buffer).  BUFFER can be a buffer
 497 or a buffer name."
 498   (interactive)
 499   (or buffer (setq buffer (current-buffer)))
 500   (help-setup-xref (list #'describe-bindings prefix buffer)
 501                    (called-interactively-p 'interactive))
 502   (with-help-window (help-buffer)
 503     ;; Be aware that `describe-buffer-bindings' puts its output into
 504     ;; the current buffer.
 505     (with-current-buffer (help-buffer)
 506       (describe-buffer-bindings buffer prefix))))
 507
 508 ;; This function used to be in keymap.c.
 509 (defun describe-bindings-internal (&optional menus prefix)
 510   "Show a list of all defined keys, and their definitions.
 511 We put that list in a buffer, and display the buffer.
 512
 513 The optional argument MENUS, if non-nil, says to mention menu bindings.
 514 \(Ordinarily these are omitted from the output.)
 515 The optional argument PREFIX, if non-nil, should be a key sequence;
 516 then we display only bindings that start with that prefix."
 517   (declare (obsolete describe-buffer-bindings "24.4"))
 518   (let ((buf (current-buffer)))
 519     (with-help-window (help-buffer)
 520       ;; Be aware that `describe-buffer-bindings' puts its output into
 521       ;; the current buffer.
 522       (with-current-buffer (help-buffer)
 523         (describe-buffer-bindings buf prefix menus)))))
 524
 525 (defun where-is (definition &optional insert)
 526   "Print message listing key sequences that invoke the command DEFINITION.
 527 Argument is a command definition, usually a symbol with a function definition.
 528 If INSERT (the prefix arg) is non-nil, insert the message in the buffer."
 529   (interactive
 530    (let ((fn (function-called-at-point))
 531          (enable-recursive-minibuffers t)
 532          val)
 533      (setq val (completing-read
 534                 (if fn
 535                     (format "Where is command (default %s): " fn)
 536                   "Where is command: ")
 537                 obarray 'commandp t nil nil
 538                 (and fn (symbol-name fn))))
 539      (list (unless (equal val "") (intern val))
 540            current-prefix-arg)))
 541   (unless definition (error "No command"))
 542   (let ((func (indirect-function definition))
 543         (defs nil)
 544         (standard-output (if insert (current-buffer) standard-output)))
 545     ;; In DEFS, find all symbols that are aliases for DEFINITION.
 546     (mapatoms (lambda (symbol)
 547                 (and (fboundp symbol)
 548                      (not (eq symbol definition))
 549                      (eq func (condition-case ()
 550                                   (indirect-function symbol)
 551                                 (error symbol)))
 552                      (push symbol defs))))
 553     ;; Look at all the symbols--first DEFINITION,
 554     ;; then its aliases.
 555     (dolist (symbol (cons definition defs))
 556       (let* ((remapped (command-remapping symbol))
 557              (keys (where-is-internal
 558                     symbol overriding-local-map nil nil remapped))
 559              (keys (mapconcat 'key-description keys ", "))
 560              string)
 561         (setq string
 562               (if insert
 563                   (if (> (length keys) 0)
 564                       (if remapped
 565                           (format "%s (%s) (remapped from %s)"
 566                                   keys remapped symbol)
 567                         (format "%s (%s)" keys symbol))
 568                     (format "M-x %s RET" symbol))
 569                 (if (> (length keys) 0)
 570                     (if remapped
 571                         (format "%s is remapped to %s which is on %s"
 572                                 symbol remapped keys)
 573                       (format "%s is on %s" symbol keys))
 574                   ;; If this is the command the user asked about,
 575                   ;; and it is not on any key, say so.
 576                   ;; For other symbols, its aliases, say nothing
 577                   ;; about them unless they are on keys.
 578                   (if (eq symbol definition)
 579                       (format "%s is not on any key" symbol)))))
 580         (when string
 581           (unless (eq symbol definition)
 582             (princ ";\n its alias "))
 583           (princ string)))))
 584   nil)
 585
 586 (defun help-key-description (key untranslated)
 587   (let ((string (key-description key)))
 588     (if (or (not untranslated)
 589             (and (eq (aref untranslated 0) ?\e) (not (eq (aref key 0) ?\e))))
 590         string
 591       (let ((otherstring (key-description untranslated)))
 592         (if (equal string otherstring)
 593             string
 594           (format "%s (translated from %s)" string otherstring))))))
 595
 596 (defun describe-key-briefly (&optional key insert untranslated)
 597   "Print the name of the function KEY invokes.  KEY is a string.
 598 If INSERT (the prefix arg) is non-nil, insert the message in the buffer.
 599 If non-nil, UNTRANSLATED is a vector of the untranslated events.
 600 It can also be a number in which case the untranslated events from
 601 the last key hit are used.
 602
 603 If KEY is a menu item or a tool-bar button that is disabled, this command
 604 temporarily enables it to allow getting help on disabled items and buttons."
 605   (interactive
 606    (let ((enable-disabled-menus-and-buttons t)
 607          (cursor-in-echo-area t)
 608          saved-yank-menu)
 609      (unwind-protect
 610          (let (key)
 611            ;; If yank-menu is empty, populate it temporarily, so that
 612            ;; "Select and Paste" menu can generate a complete event.
 613            (when (null (cdr yank-menu))
 614              (setq saved-yank-menu (copy-sequence yank-menu))
 615              (menu-bar-update-yank-menu "(any string)" nil))
 616            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 617            ;; Clear the echo area message (Bug#7014).
 618            (message nil)
 619            ;; If KEY is a down-event, read and discard the
 620            ;; corresponding up-event.  Note that there are also
 621            ;; down-events on scroll bars and mode lines: the actual
 622            ;; event then is in the second element of the vector.
 623            (and (vectorp key)
 624                 (let ((last-idx (1- (length key))))
 625                   (and (eventp (aref key last-idx))
 626                        (memq 'down (event-modifiers (aref key last-idx)))))
 627                 (read-event))
 628            (list
 629             key
 630             (if current-prefix-arg (prefix-numeric-value current-prefix-arg))
 631             1))
 632        ;; Put yank-menu back as it was, if we changed it.
 633        (when saved-yank-menu
 634          (setq yank-menu (copy-sequence saved-yank-menu))
 635          (fset 'yank-menu (cons 'keymap yank-menu))))))
 636   (if (numberp untranslated)
 637       (setq untranslated (this-single-command-raw-keys)))
 638   (let* ((event (if (and (symbolp (aref key 0))
 639                          (> (length key) 1)
 640                          (consp (aref key 1)))
 641                     (aref key 1)
 642                   (aref key 0)))
 643          (modifiers (event-modifiers event))
 644          (standard-output (if insert (current-buffer) standard-output))
 645          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 646                             (memq 'drag modifiers)) " at that spot" ""))
 647          (defn (key-binding key t))
 648          key-desc)
 649     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 650     (if (and (eq defn nil)
 651              (stringp (aref key (1- (length key))))
 652              (eq (key-binding (substring key 0 -1)) 'yank-menu))
 653         (setq defn 'menu-bar-select-yank))
 654     ;; Don't bother user with strings from (e.g.) the select-paste menu.
 655     (if (stringp (aref key (1- (length key))))
 656         (aset key (1- (length key)) "(any string)"))
 657     (if (and (> (length untranslated) 0)
 658              (stringp (aref untranslated (1- (length untranslated)))))
 659         (aset untranslated (1- (length untranslated)) "(any string)"))
 660     ;; Now describe the key, perhaps as changed.
 661     (setq key-desc (help-key-description key untranslated))
 662     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 663         (princ (format "%s%s is undefined" key-desc mouse-msg))
 664       (princ (format "%s%s runs the command %S" key-desc mouse-msg defn)))))
 665
 666 (defun help--key-binding-keymap (key &optional accept-default no-remap position)
 667   "Return a keymap holding a binding for KEY within current keymaps.
 668 The effect of the arguments KEY, ACCEPT-DEFAULT, NO-REMAP and
 669 POSITION is as documented in the function `key-binding'."
 670   (let* ((active-maps (current-active-maps t position))
 671          map found)
 672     ;; We loop over active maps like key-binding does.
 673     (while (and
 674             (not found)
 675             (setq map (pop active-maps)))
 676       (setq found (lookup-key map key accept-default))
 677       (when (integerp found)
 678         ;; The first `found' characters of KEY were found but not the
 679         ;; whole sequence.
 680         (setq found nil)))
 681     (when found
 682       (if (and (symbolp found)
 683                (not no-remap)
 684                (command-remapping found))
 685           ;; The user might want to know in which map the binding is
 686           ;; found, or in which map the remapping is found.  The
 687           ;; default is to show the latter.
 688           (help--key-binding-keymap (vector 'remap found))
 689         map))))
 690
 691 (defun help--binding-locus (key position)
 692   "Describe in which keymap KEY is defined.
 693 Return a symbol pointing to that keymap if one exists ; otherwise
 694 return nil."
 695   (let ((map (help--key-binding-keymap key t nil position)))
 696     (when map
 697       (catch 'found
 698         (let ((advertised-syms (nconc
 699                                 (list 'overriding-terminal-local-map
 700                                       'overriding-local-map)
 701                                 (delq nil
 702                                       (mapcar
 703                                        (lambda (mode-and-map)
 704                                          (let ((mode (car mode-and-map)))
 705                                            (when (symbol-value mode)
 706                                              (intern-soft
 707                                               (format "%s-map" mode)))))
 708                                        minor-mode-map-alist))
 709                                 (list 'global-map
 710                                       (intern-soft (format "%s-map" major-mode)))))
 711               found)
 712           ;; Look into these advertised symbols first.
 713           (dolist (sym advertised-syms)
 714             (when (and
 715                    (boundp sym)
 716                    (eq map (symbol-value sym)))
 717               (throw 'found sym)))
 718           ;; Only look in other symbols otherwise.
 719           (mapatoms
 720            (lambda (x)
 721              (when (and (boundp x)
 722                         ;; Avoid let-bound symbols.
 723                         (special-variable-p x)
 724                         (eq (symbol-value x) map))
 725                (throw 'found x))))
 726           nil)))))
 727
 728 (defun describe-key (&optional key untranslated up-event)
 729   "Display documentation of the function invoked by KEY.
 730 KEY can be any kind of a key sequence; it can include keyboard events,
 731 mouse events, and/or menu events.  When calling from a program,
 732 pass KEY as a string or a vector.
 733
 734 If non-nil, UNTRANSLATED is a vector of the corresponding untranslated events.
 735 It can also be a number, in which case the untranslated events from
 736 the last key sequence entered are used.
 737 UP-EVENT is the up-event that was discarded by reading KEY, or nil.
 738
 739 If KEY is a menu item or a tool-bar button that is disabled, this command
 740 temporarily enables it to allow getting help on disabled items and buttons."
 741   (interactive
 742    (let ((enable-disabled-menus-and-buttons t)
 743          (cursor-in-echo-area t)
 744          saved-yank-menu)
 745      (unwind-protect
 746          (let (key)
 747            ;; If yank-menu is empty, populate it temporarily, so that
 748            ;; "Select and Paste" menu can generate a complete event.
 749            (when (null (cdr yank-menu))
 750              (setq saved-yank-menu (copy-sequence yank-menu))
 751              (menu-bar-update-yank-menu "(any string)" nil))
 752            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 753            (list
 754             key
 755             (prefix-numeric-value current-prefix-arg)
 756             ;; If KEY is a down-event, read and include the
 757             ;; corresponding up-event.  Note that there are also
 758             ;; down-events on scroll bars and mode lines: the actual
 759             ;; event then is in the second element of the vector.
 760             (and (vectorp key)
 761                  (let ((last-idx (1- (length key))))
 762                    (and (eventp (aref key last-idx))
 763                         (memq 'down (event-modifiers (aref key last-idx)))))
 764                  (or (and (eventp (aref key 0))
 765                           (memq 'down (event-modifiers (aref key 0)))
 766                           ;; However, for the C-down-mouse-2 popup
 767                           ;; menu, there is no subsequent up-event.  In
 768                           ;; this case, the up-event is the next
 769                           ;; element in the supplied vector.
 770                           (= (length key) 1))
 771                      (and (> (length key) 1)
 772                           (eventp (aref key 1))
 773                           (memq 'down (event-modifiers (aref key 1)))))
 774                  (read-event))))
 775        ;; Put yank-menu back as it was, if we changed it.
 776        (when saved-yank-menu
 777          (setq yank-menu (copy-sequence saved-yank-menu))
 778          (fset 'yank-menu (cons 'keymap yank-menu))))))
 779   (if (numberp untranslated)
 780       (setq untranslated (this-single-command-raw-keys)))
 781   (let* ((event (aref key (if (and (symbolp (aref key 0))
 782                                    (> (length key) 1)
 783                                    (consp (aref key 1)))
 784                               1
 785                             0)))
 786          (modifiers (event-modifiers event))
 787          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 788                             (memq 'drag modifiers)) " at that spot" ""))
 789          (defn (key-binding key t))
 790          key-locus key-locus-up key-locus-up-tricky
 791          defn-up defn-up-tricky ev-type
 792          mouse-1-remapped mouse-1-tricky)
 793
 794     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 795     (when (and (eq defn nil)
 796                (stringp (aref key (1- (length key))))
 797                (eq (key-binding (substring key 0 -1)) 'yank-menu))
 798       (setq defn 'menu-bar-select-yank))
 799     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 800         (message "%s%s is undefined"
 801                  (help-key-description key untranslated) mouse-msg)
 802       (help-setup-xref (list #'describe-function defn)
 803                        (called-interactively-p 'interactive))
 804       ;; Don't bother user with strings from (e.g.) the select-paste menu.
 805       (when (stringp (aref key (1- (length key))))
 806         (aset key (1- (length key)) "(any string)"))
 807       (when (and untranslated
 808                  (stringp (aref untranslated (1- (length untranslated)))))
 809         (aset untranslated (1- (length untranslated))
 810               "(any string)"))
 811       ;; Need to do this before erasing *Help* buffer in case event
 812       ;; is a mouse click in an existing *Help* buffer.
 813       (when up-event
 814         (setq ev-type (event-basic-type up-event))
 815         (let ((sequence (vector up-event)))
 816           (when (and (eq ev-type 'mouse-1)
 817                      mouse-1-click-follows-link
 818                      (not (eq mouse-1-click-follows-link 'double))
 819                      (setq mouse-1-remapped
 820                            (mouse-on-link-p (event-start up-event))))
 821             (setq mouse-1-tricky (and (integerp mouse-1-click-follows-link)
 822                                       (> mouse-1-click-follows-link 0)))
 823             (cond ((stringp mouse-1-remapped)
 824                    (setq sequence mouse-1-remapped))
 825                   ((vectorp mouse-1-remapped)
 826                    (setcar up-event (elt mouse-1-remapped 0)))
 827                   (t (setcar up-event 'mouse-2))))
 828           (setq defn-up (key-binding sequence nil nil (event-start up-event)))
 829           (setq key-locus-up (help--binding-locus sequence (event-start up-event)))
 830           (when mouse-1-tricky
 831             (setq sequence (vector up-event))
 832             (aset sequence 0 'mouse-1)
 833             (setq defn-up-tricky (key-binding sequence nil nil (event-start up-event)))
 834             (setq key-locus-up-tricky (help--binding-locus sequence (event-start up-event))))))
 835       (setq key-locus (help--binding-locus key (event-start event)))
 836       (with-help-window (help-buffer)
 837         (princ (help-key-description key untranslated))
 838         (princ (format "%s runs the command %S%s, which is "
 839                        mouse-msg defn (if key-locus
 840                                           (format " (found in %s)" key-locus)
 841                                         "")))
 842         (describe-function-1 defn)
 843         (when up-event
 844           (unless (or (null defn-up)
 845                       (integerp defn-up)
 846                       (equal defn-up 'undefined))
 847             (princ (format "
 848
 849 ----------------- up-event %s----------------
 850
 851 %s%s%s runs the command %S%s, which is "
 852                            (if mouse-1-tricky "(short click) " "")
 853                            (key-description (vector up-event))
 854                            mouse-msg
 855                            (if mouse-1-remapped
 856                                " is remapped to <mouse-2>, which" "")
 857                            defn-up (if key-locus-up
 858                                        (format " (found in %s)" key-locus-up)
 859                                      "")))
 860             (describe-function-1 defn-up))
 861           (unless (or (null defn-up-tricky)
 862                       (integerp defn-up-tricky)
 863                       (eq defn-up-tricky 'undefined))
 864             (princ (format "
 865
 866 ----------------- up-event (long click) ----------------
 867
 868 Pressing <%S>%s for longer than %d milli-seconds
 869 runs the command %S%s, which is "
 870                            ev-type mouse-msg
 871                            mouse-1-click-follows-link
 872                            defn-up-tricky (if key-locus-up-tricky
 873                                               (format " (found in %s)" key-locus-up-tricky)
 874                                             "")))
 875             (describe-function-1 defn-up-tricky)))))))
 876 \f
 877 (defun describe-mode (&optional buffer)
 878   "Display documentation of current major mode and minor modes.
 879 A brief summary of the minor modes comes first, followed by the
 880 major mode description.  This is followed by detailed
 881 descriptions of the minor modes, each on a separate page.
 882
 883 For this to work correctly for a minor mode, the mode's indicator
 884 variable \(listed in `minor-mode-alist') must also be a function
 885 whose documentation describes the minor mode.
 886
 887 If called from Lisp with a non-nil BUFFER argument, display
 888 documentation for the major and minor modes of that buffer."
 889   (interactive "@")
 890   (unless buffer (setq buffer (current-buffer)))
 891   (help-setup-xref (list #'describe-mode buffer)
 892                    (called-interactively-p 'interactive))
 893   ;; For the sake of help-do-xref and help-xref-go-back,
 894   ;; don't switch buffers before calling `help-buffer'.
 895   (with-help-window (help-buffer)
 896     (with-current-buffer buffer
 897       (let (minor-modes)
 898         ;; Older packages do not register in minor-mode-list but only in
 899         ;; minor-mode-alist.
 900         (dolist (x minor-mode-alist)
 901           (setq x (car x))
 902           (unless (memq x minor-mode-list)
 903             (push x minor-mode-list)))
 904         ;; Find enabled minor mode we will want to mention.
 905         (dolist (mode minor-mode-list)
 906           ;; Document a minor mode if it is listed in minor-mode-alist,
 907           ;; non-nil, and has a function definition.
 908           (let ((fmode (or (get mode :minor-mode-function) mode)))
 909             (and (boundp mode) (symbol-value mode)
 910                  (fboundp fmode)
 911                  (let ((pretty-minor-mode
 912                         (if (string-match "\\(\\(-minor\\)?-mode\\)?\\'"
 913                                           (symbol-name fmode))
 914                             (capitalize
 915                              (substring (symbol-name fmode)
 916                                         0 (match-beginning 0)))
 917                           fmode)))
 918                    (push (list fmode pretty-minor-mode
 919                                (format-mode-line (assq mode minor-mode-alist)))
 920                          minor-modes)))))
 921         (setq minor-modes
 922               (sort minor-modes
 923                     (lambda (a b) (string-lessp (cadr a) (cadr b)))))
 924         (when minor-modes
 925           (princ "Enabled minor modes:\n")
 926           (make-local-variable 'help-button-cache)
 927           (with-current-buffer standard-output
 928             (dolist (mode minor-modes)
 929               (let ((mode-function (nth 0 mode))
 930                     (pretty-minor-mode (nth 1 mode))
 931                     (indicator (nth 2 mode)))
 932                 (add-text-properties 0 (length pretty-minor-mode)
 933                                      '(face bold) pretty-minor-mode)
 934                 (save-excursion
 935                   (goto-char (point-max))
 936                   (princ "\n\f\n")
 937                   (push (point-marker) help-button-cache)
 938                   ;; Document the minor modes fully.
 939                   (insert pretty-minor-mode)
 940                   (princ (format " minor mode (%s):\n"
 941                                  (if (zerop (length indicator))
 942                                      "no indicator"
 943                                    (format "indicator%s"
 944                                            indicator))))
 945                   (princ (documentation mode-function)))
 946                 (insert-button pretty-minor-mode
 947                                'action (car help-button-cache)
 948                                'follow-link t
 949                                'help-echo "mouse-2, RET: show full information")
 950                 (newline)))
 951             (forward-line -1)
 952             (fill-paragraph nil)
 953             (forward-line 1))
 954
 955           (princ "\n(Information about these minor modes follows the major mode info.)\n\n"))
 956         ;; Document the major mode.
 957         (let ((mode mode-name))
 958           (with-current-buffer standard-output
 959             (let ((start (point)))
 960               (insert (format-mode-line mode nil nil buffer))
 961               (add-text-properties start (point) '(face bold)))))
 962         (princ " mode")
 963         (let* ((mode major-mode)
 964                (file-name (find-lisp-object-file-name mode nil)))
 965           (when file-name
 966             (princ (concat " defined in `" (file-name-nondirectory file-name) "'"))
 967             ;; Make a hyperlink to the library.
 968             (with-current-buffer standard-output
 969               (save-excursion
 970                 (re-search-backward "`\\([^`']+\\)'" nil t)
 971                 (help-xref-button 1 'help-function-def mode file-name)))))
 972         (princ ":\n")
 973         (princ (documentation major-mode)))))
 974   ;; For the sake of IELM and maybe others
 975   nil)
 976
 977
 978 (defun describe-minor-mode (minor-mode)
 979   "Display documentation of a minor mode given as MINOR-MODE.
 980 MINOR-MODE can be a minor mode symbol or a minor mode indicator string
 981 appeared on the mode-line."
 982   (interactive (list (completing-read
 983                       "Minor mode: "
 984                               (nconc
 985                                (describe-minor-mode-completion-table-for-symbol)
 986                                (describe-minor-mode-completion-table-for-indicator)
 987                                ))))
 988   (if (symbolp minor-mode)
 989       (setq minor-mode (symbol-name minor-mode)))
 990   (let ((symbols (describe-minor-mode-completion-table-for-symbol))
 991         (indicators (describe-minor-mode-completion-table-for-indicator)))
 992     (cond
 993      ((member minor-mode symbols)
 994       (describe-minor-mode-from-symbol (intern minor-mode)))
 995      ((member minor-mode indicators)
 996       (describe-minor-mode-from-indicator minor-mode))
 997      (t
 998       (error "No such minor mode: %s" minor-mode)))))
 999
1000 ;; symbol
1001 (defun describe-minor-mode-completion-table-for-symbol ()
1002   ;; In order to list up all minor modes, minor-mode-list
1003   ;; is used here instead of minor-mode-alist.
1004   (delq nil (mapcar 'symbol-name minor-mode-list)))
1005
1006 (defun describe-minor-mode-from-symbol (symbol)
1007   "Display documentation of a minor mode given as a symbol, SYMBOL"
1008   (interactive (list (intern (completing-read
1009                               "Minor mode symbol: "
1010                               (describe-minor-mode-completion-table-for-symbol)))))
1011   (if (fboundp symbol)
1012       (describe-function symbol)
1013     (describe-variable symbol)))
1014
1015 ;; indicator
1016 (defun describe-minor-mode-completion-table-for-indicator ()
1017   (delq nil
1018         (mapcar (lambda (x)
1019                   (let ((i (format-mode-line x)))
1020                     ;; remove first space if existed
1021                     (cond
1022                      ((= 0 (length i))
1023                       nil)
1024                      ((eq (aref i 0) ?\s)
1025                       (substring i 1))
1026                      (t
1027                       i))))
1028                 minor-mode-alist)))
1029
1030 (defun describe-minor-mode-from-indicator (indicator)
1031   "Display documentation of a minor mode specified by INDICATOR.
1032 If you call this function interactively, you can give indicator which
1033 is currently activated with completion."
1034   (interactive (list
1035                 (completing-read
1036                  "Minor mode indicator: "
1037                  (describe-minor-mode-completion-table-for-indicator))))
1038   (let ((minor-mode (lookup-minor-mode-from-indicator indicator)))
1039     (if minor-mode
1040         (describe-minor-mode-from-symbol minor-mode)
1041       (error "Cannot find minor mode for `%s'" indicator))))
1042
1043 (defun lookup-minor-mode-from-indicator (indicator)
1044   "Return a minor mode symbol from its indicator on the mode line."
1045   ;; remove first space if existed
1046   (if (and (< 0 (length indicator))
1047            (eq (aref indicator 0) ?\s))
1048       (setq indicator (substring indicator 1)))
1049   (let ((minor-modes minor-mode-alist)
1050         result)
1051     (while minor-modes
1052       (let* ((minor-mode (car (car minor-modes)))
1053              (anindicator (format-mode-line
1054                            (car (cdr (car minor-modes))))))
1055         ;; remove first space if existed
1056         (if (and (stringp anindicator)
1057                  (> (length anindicator) 0)
1058                  (eq (aref anindicator 0) ?\s))
1059             (setq anindicator (substring anindicator 1)))
1060         (if (equal indicator anindicator)
1061             (setq result minor-mode
1062                   minor-modes nil)
1063           (setq minor-modes (cdr minor-modes)))))
1064     result))
1065 \f
1066 ;;; Automatic resizing of temporary buffers.
1067 (defcustom temp-buffer-max-height
1068   (lambda (buffer)
1069     (if (eq (selected-window) (frame-root-window))
1070         (/ (x-display-pixel-height) (frame-char-height) 2)
1071       (/ (- (frame-height) 2) 2)))
1072   "Maximum height of a window displaying a temporary buffer.
1073 This is effective only when Temp Buffer Resize mode is enabled.
1074 The value is the maximum height (in lines) which
1075 `resize-temp-buffer-window' will give to a window displaying a
1076 temporary buffer.  It can also be a function to be called to
1077 choose the height for such a buffer.  It gets one argument, the
1078 buffer, and should return a positive integer.  At the time the
1079 function is called, the window to be resized is selected."
1080   :type '(choice integer function)
1081   :group 'help
1082   :version "24.3")
1083
1084 (defcustom temp-buffer-max-width
1085   (lambda (buffer)
1086     (if (eq (selected-window) (frame-root-window))
1087         (/ (x-display-pixel-width) (frame-char-width) 2)
1088       (/ (- (frame-width) 2) 2)))
1089   "Maximum width of a window displaying a temporary buffer.
1090 This is effective only when Temp Buffer Resize mode is enabled.
1091 The value is the maximum width (in columns) which
1092 `resize-temp-buffer-window' will give to a window displaying a
1093 temporary buffer.  It can also be a function to be called to
1094 choose the width for such a buffer.  It gets one argument, the
1095 buffer, and should return a positive integer.  At the time the
1096 function is called, the window to be resized is selected."
1097   :type '(choice integer function)
1098   :group 'help
1099   :version "24.4")
1100
1101 (define-minor-mode temp-buffer-resize-mode
1102   "Toggle auto-resizing temporary buffer windows (Temp Buffer Resize Mode).
1103 With a prefix argument ARG, enable Temp Buffer Resize mode if ARG
1104 is positive, and disable it otherwise.  If called from Lisp,
1105 enable the mode if ARG is omitted or nil.
1106
1107 When Temp Buffer Resize mode is enabled, the windows in which we
1108 show a temporary buffer are automatically resized in height to
1109 fit the buffer's contents, but never more than
1110 `temp-buffer-max-height' nor less than `window-min-height'.
1111
1112 A window is resized only if it has been specially created for the
1113 buffer.  Windows that have shown another buffer before are not
1114 resized.  A frame is resized only if `fit-frame-to-buffer' is
1115 non-nil.
1116
1117 This mode is used by `help', `apropos' and `completion' buffers,
1118 and some others."
1119   :global t :group 'help
1120   (if temp-buffer-resize-mode
1121       ;; `help-make-xrefs' may add a `back' button and thus increase the
1122       ;; text size, so `resize-temp-buffer-window' must be run *after* it.
1123       (add-hook 'temp-buffer-show-hook 'resize-temp-buffer-window 'append)
1124     (remove-hook 'temp-buffer-show-hook 'resize-temp-buffer-window)))
1125
1126 (defun resize-temp-buffer-window (&optional window)
1127   "Resize WINDOW to fit its contents.
1128 WINDOW must be a live window and defaults to the selected one.
1129 Do not resize if WINDOW was not created by `display-buffer'.
1130
1131 If WINDOW is part of a vertical combination, restrain its new
1132 size by `temp-buffer-max-height' and do not resize if its minimum
1133 accessible position is scrolled out of view.  If WINDOW is part
1134 of a horizontal combination, restrain its new size by
1135 `temp-buffer-max-width'.  In both cases, the value of the option
1136 `fit-window-to-buffer-horizontally' can inhibit resizing.
1137
1138 If WINDOW is the root window of its frame, resize the frame
1139 provided `fit-frame-to-buffer' is non-nil.
1140
1141 This function may call `preserve-window-size' to preserve the
1142 size of WINDOW."
1143   (setq window (window-normalize-window window t))
1144   (let ((height (if (functionp temp-buffer-max-height)
1145                     (with-selected-window window
1146                       (funcall temp-buffer-max-height (window-buffer)))
1147                   temp-buffer-max-height))
1148         (width (if (functionp temp-buffer-max-width)
1149                    (with-selected-window window
1150                      (funcall temp-buffer-max-width (window-buffer)))
1151                  temp-buffer-max-width))
1152         (quit-cadr (cadr (window-parameter window 'quit-restore))))
1153     ;; Resize WINDOW iff it was made by `display-buffer'.
1154     (when (or (and (eq quit-cadr 'window)
1155                    (or (and (window-combined-p window)
1156                             (not (eq fit-window-to-buffer-horizontally
1157                                      'only))
1158                             (pos-visible-in-window-p (point-min) window))
1159                        (and (window-combined-p window t)
1160                             fit-window-to-buffer-horizontally)))
1161               (and (eq quit-cadr 'frame)
1162                      fit-frame-to-buffer
1163                      (eq window (frame-root-window window))))
1164         (fit-window-to-buffer window height nil width nil t))))
1165
1166 ;;; Help windows.
1167 (defcustom help-window-select nil
1168   "Non-nil means select help window for viewing.
1169 Choices are:
1170
1171  never (nil) Select help window only if there is no other window
1172              on its frame.
1173
1174  other       Select help window if and only if it appears on the
1175              previously selected frame, that frame contains at
1176              least two other windows and the help window is
1177              either new or showed a different buffer before.
1178
1179  always (t)  Always select the help window.
1180
1181 If this option is non-nil and the help window appears on another
1182 frame, then give that frame input focus too.  Note also that if
1183 the help window appears on another frame, it may get selected and
1184 its frame get input focus even if this option is nil.
1185
1186 This option has effect if and only if the help window was created
1187 by `with-help-window'."
1188   :type '(choice (const :tag "never (nil)" nil)
1189                  (const :tag "other" other)
1190                  (const :tag "always (t)" t))
1191   :group 'help
1192   :version "23.1")
1193
1194 (defcustom help-enable-auto-load t
1195   "Whether Help commands can perform autoloading.
1196 If non-nil, whenever \\[describe-function] is called for an
1197 autoloaded function whose docstring contains any key substitution
1198 construct (see `substitute-command-keys'), the library is loaded,
1199 so that the documentation can show the right key bindings."
1200   :type 'boolean
1201   :group 'help
1202   :version "24.3")
1203
1204 (defun help-window-display-message (quit-part window &optional scroll)
1205   "Display message telling how to quit and scroll help window.
1206 QUIT-PART is a string telling how to quit the help window WINDOW.
1207 Optional argument SCROLL non-nil means tell how to scroll WINDOW.
1208 SCROLL equal `other' means tell how to scroll the \"other\"
1209 window."
1210   (let ((scroll-part
1211          (cond
1212           ;; If we don't have QUIT-PART we probably reuse a window
1213           ;; showing the same buffer so we don't show any message.
1214           ((not quit-part) nil)
1215           ((pos-visible-in-window-p
1216             (with-current-buffer (window-buffer window)
1217               (point-max)) window t)
1218            ;; Buffer end is at least partially visible, no need to talk
1219            ;; about scrolling.
1220            ".")
1221           ((eq scroll 'other)
1222            ", \\[scroll-other-window] to scroll help.")
1223           (scroll ", \\[scroll-up] to scroll help."))))
1224     (message "%s"
1225      (substitute-command-keys (concat quit-part scroll-part)))))
1226
1227 (defun help-window-setup (window &optional value)
1228   "Set up help window WINDOW for `with-help-window'.
1229 WINDOW is the window used for displaying the help buffer.
1230 Return VALUE."
1231   (let* ((help-buffer (when (window-live-p window)
1232                         (window-buffer window)))
1233          (help-setup (when (window-live-p window)
1234                        (car (window-parameter window 'quit-restore))))
1235          (frame (window-frame window)))
1236
1237     (when help-buffer
1238       ;; Handle `help-window-point-marker'.
1239       (when (eq (marker-buffer help-window-point-marker) help-buffer)
1240         (set-window-point window help-window-point-marker)
1241         ;; Reset `help-window-point-marker'.
1242         (set-marker help-window-point-marker nil))
1243
1244       ;; If the help window appears on another frame, select it if
1245       ;; `help-window-select' is non-nil and give that frame input focus
1246       ;; too.  See also Bug#19012.
1247       (when (and help-window-select
1248                  (frame-live-p help-window-old-frame)
1249                  (not (eq frame help-window-old-frame)))
1250         (select-window window)
1251         (select-frame-set-input-focus frame))
1252
1253       (cond
1254        ((or (eq window (selected-window))
1255             ;; If the help window is on the selected frame, select
1256             ;; it if `help-window-select' is t or `help-window-select'
1257             ;; is 'other, the frame contains at least three windows, and
1258             ;; the help window did show another buffer before.  See also
1259             ;; Bug#11039.
1260             (and (eq frame (selected-frame))
1261                  (or (eq help-window-select t)
1262                      (and (eq help-window-select 'other)
1263                           (> (length (window-list nil 'no-mini)) 2)
1264                           (not (eq help-setup 'same))))
1265                  (select-window window)))
1266         ;; The help window is or gets selected ...
1267         (help-window-display-message
1268          (cond
1269           ((eq help-setup 'window)
1270            ;; ... and is new, ...
1271            "Type \"q\" to delete help window")
1272           ((eq help-setup 'frame)
1273            ;; ... on a new frame, ...
1274            "Type \"q\" to quit the help frame")
1275           ((eq help-setup 'other)
1276            ;; ... or displayed some other buffer before.
1277            "Type \"q\" to restore previous buffer"))
1278          window t))
1279        ((and (eq (window-frame window) help-window-old-frame)
1280              (= (length (window-list nil 'no-mini)) 2))
1281         ;; There are two windows on the help window's frame and the
1282         ;; other one is the selected one.
1283         (help-window-display-message
1284          (cond
1285           ((eq help-setup 'window)
1286            "Type \\[delete-other-windows] to delete the help window")
1287           ((eq help-setup 'other)
1288            "Type \"q\" in help window to restore its previous buffer"))
1289          window 'other))
1290        (t
1291         ;; The help window is not selected ...
1292         (help-window-display-message
1293          (cond
1294           ((eq help-setup 'window)
1295            ;; ... and is new, ...
1296            "Type \"q\" in help window to delete it")
1297           ((eq help-setup 'other)
1298            ;; ... or displayed some other buffer before.
1299            "Type \"q\" in help window to restore previous buffer"))
1300          window))))
1301     ;; Return VALUE.
1302     value))
1303
1304 ;; `with-help-window' is a wrapper for `with-temp-buffer-window'
1305 ;; providing the following additional twists:
1306
1307 ;; (1) It puts the buffer in `help-mode' (via `help-mode-setup') and
1308 ;;     adds cross references (via `help-mode-finish').
1309
1310 ;; (2) It issues a message telling how to scroll and quit the help
1311 ;;     window (via `help-window-setup').
1312
1313 ;; (3) An option (customizable via `help-window-select') to select the
1314 ;;     help window automatically.
1315
1316 ;; (4) A marker (`help-window-point-marker') to move point in the help
1317 ;;     window to an arbitrary buffer position.
1318 (defmacro with-help-window (buffer-name &rest body)
1319   "Display buffer named BUFFER-NAME in a help window.
1320 Evaluate the forms in BODY with standard output bound to a buffer
1321 called BUFFER-NAME (creating it if it does not exist), put that
1322 buffer in `help-mode', display the buffer in a window (see
1323 `with-temp-buffer-window' for details) and issue a message how to
1324 deal with that \"help\" window when it's no more needed.  Select
1325 the help window if the current value of the user option
1326 `help-window-select' says so.  Return last value in BODY."
1327   (declare (indent 1) (debug t))
1328   `(progn
1329      ;; Make `help-window-point-marker' point nowhere.  The only place
1330      ;; where this should be set to a buffer position is within BODY.
1331      (set-marker help-window-point-marker nil)
1332      (let ((temp-buffer-window-setup-hook
1333             (cons 'help-mode-setup temp-buffer-window-setup-hook))
1334            (temp-buffer-window-show-hook
1335             (cons 'help-mode-finish temp-buffer-window-show-hook)))
1336        (setq help-window-old-frame (selected-frame))
1337        (with-temp-buffer-window
1338         ,buffer-name nil 'help-window-setup (progn ,@body)))))
1339
1340 ;; Called from C, on encountering `help-char' when reading a char.
1341 ;; Don't print to *Help*; that would clobber Help history.
1342 (defun help-form-show ()
1343   "Display the output of a non-nil `help-form'."
1344   (let ((msg (eval help-form)))
1345     (if (stringp msg)
1346         (with-output-to-temp-buffer " *Char Help*"
1347           (princ msg)))))
1348
1349 \f
1350 ;; The following functions used to be in help-fns.el, which is not preloaded.
1351 ;; But for various reasons, they are more widely needed, so they were
1352 ;; moved to this file, which is preloaded.  http://debbugs.gnu.org/17001
1353
1354 (defun help-split-fundoc (docstring def)
1355   "Split a function DOCSTRING into the actual doc and the usage info.
1356 Return (USAGE . DOC) or nil if there's no usage info, where USAGE info
1357 is a string describing the argument list of DEF, such as
1358 \"(apply FUNCTION &rest ARGUMENTS)\".
1359 DEF is the function whose usage we're looking for in DOCSTRING."
1360   ;; Functions can get the calling sequence at the end of the doc string.
1361   ;; In cases where `function' has been fset to a subr we can't search for
1362   ;; function's name in the doc string so we use `fn' as the anonymous
1363   ;; function name instead.
1364   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
1365     (cons (format "(%s%s"
1366                   ;; Replace `fn' with the actual function name.
1367                   (if (symbolp def) def "anonymous")
1368                   (match-string 1 docstring))
1369           (unless (zerop (match-beginning 0))
1370             (substring docstring 0 (match-beginning 0))))))
1371
1372 (defun help-add-fundoc-usage (docstring arglist)
1373   "Add the usage info to DOCSTRING.
1374 If DOCSTRING already has a usage info, then just return it unchanged.
1375 The usage info is built from ARGLIST.  DOCSTRING can be nil.
1376 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
1377   (unless (stringp docstring) (setq docstring ""))
1378   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring)
1379           (eq arglist t))
1380       docstring
1381     (concat docstring
1382             (if (string-match "\n?\n\\'" docstring)
1383                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
1384               "\n\n")
1385             (if (and (stringp arglist)
1386                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
1387                 (concat "(fn" (match-string 1 arglist) ")")
1388               (format "%S" (help-make-usage 'fn arglist))))))
1389
1390 (defun help-function-arglist (def &optional preserve-names)
1391   "Return a formal argument list for the function DEF.
1392 IF PRESERVE-NAMES is non-nil, return a formal arglist that uses
1393 the same names as used in the original source code, when possible."
1394   ;; Handle symbols aliased to other symbols.
1395   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
1396   ;; If definition is a macro, find the function inside it.
1397   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
1398   (cond
1399    ((and (byte-code-function-p def) (listp (aref def 0))) (aref def 0))
1400    ((eq (car-safe def) 'lambda) (nth 1 def))
1401    ((eq (car-safe def) 'closure) (nth 2 def))
1402    ((or (and (byte-code-function-p def) (integerp (aref def 0)))
1403         (subrp def))
1404     (or (when preserve-names
1405           (let* ((doc (condition-case nil (documentation def) (error nil)))
1406                  (docargs (if doc (car (help-split-fundoc doc nil))))
1407                  (arglist (if docargs
1408                               (cdar (read-from-string (downcase docargs)))))
1409                  (valid t))
1410             ;; Check validity.
1411             (dolist (arg arglist)
1412               (unless (and (symbolp arg)
1413                            (let ((name (symbol-name arg)))
1414                              (if (eq (aref name 0) ?&)
1415                                  (memq arg '(&rest &optional))
1416                                (not (string-match "\\." name)))))
1417                 (setq valid nil)))
1418             (when valid arglist)))
1419         (let* ((args-desc (if (not (subrp def))
1420                               (aref def 0)
1421                             (let ((a (subr-arity def)))
1422                               (logior (car a)
1423                                       (if (numberp (cdr a))
1424                                           (lsh (cdr a) 8)
1425                                         (lsh 1 7))))))
1426                (max (lsh args-desc -8))
1427                (min (logand args-desc 127))
1428                (rest (logand args-desc 128))
1429                (arglist ()))
1430           (dotimes (i min)
1431             (push (intern (concat "arg" (number-to-string (1+ i)))) arglist))
1432           (when (> max min)
1433             (push '&optional arglist)
1434             (dotimes (i (- max min))
1435               (push (intern (concat "arg" (number-to-string (+ 1 i min))))
1436                     arglist)))
1437           (unless (zerop rest) (push '&rest arglist) (push 'rest arglist))
1438           (nreverse arglist))))
1439    ((and (autoloadp def) (not (eq (nth 4 def) 'keymap)))
1440     "[Arg list not available until function definition is loaded.]")
1441    (t t)))
1442
1443 (defun help-make-usage (function arglist)
1444   (cons (if (symbolp function) function 'anonymous)
1445         (mapcar (lambda (arg)
1446                   (if (not (symbolp arg)) arg
1447                     (let ((name (symbol-name arg)))
1448                       (cond
1449                        ((string-match "\\`&" name) arg)
1450                        ((string-match "\\`_." name)
1451                         (intern (upcase (substring name 1))))
1452                        (t (intern (upcase name)))))))
1453                 arglist)))
1454
1455 \f
1456 (provide 'help)
1457
1458 ;;; help.el ends here