lisp/info-look.el

   1 ;;; info-look.el --- major-mode-sensitive Info index lookup facility
   2 ;; An older version of this was known as libc.el.
   3
   4 ;; Copyright (C) 1995-1999, 2001-2011 Free Software Foundation, Inc.
   5
   6 ;; Author: Ralph Schleicher <rs@nunatak.allgaeu.org>
   7 ;;         (did not show signs of life (Nov 2001)  -stef)
   8 ;; Keywords: help languages
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Really cool code to lookup info indexes.
  28 ;; Try especially info-lookup-symbol (aka C-h S).
  29
  30 ;;; Code:
  31
  32 (require 'info)
  33
  34 (defgroup info-lookup nil
  35   "Major mode sensitive help agent."
  36   :group 'help :group 'languages)
  37
  38 (defvar info-lookup-mode nil
  39   "Symbol of the current buffer's help mode.
  40 Help is provided according to the buffer's major mode if value is nil.
  41 Automatically becomes buffer local when set in any fashion.")
  42 (make-variable-buffer-local 'info-lookup-mode)
  43
  44 (defcustom info-lookup-other-window-flag t
  45   "Non-nil means pop up the Info buffer in another window."
  46   :group 'info-lookup :type 'boolean)
  47
  48 (defcustom info-lookup-highlight-face 'match
  49   "Face for highlighting looked up help items.
  50 Setting this variable to nil disables highlighting."
  51   :group 'info-lookup :type 'face)
  52
  53 (defvar info-lookup-highlight-overlay nil
  54   "Overlay object used for highlighting.")
  55
  56 (defcustom info-lookup-file-name-alist
  57   '(("\\`ac\\(local\\|site\\|include\\)\\.m4\\'" . autoconf-mode))
  58   "Alist of file names handled specially.
  59 List elements are cons cells of the form
  60
  61     (REGEXP . MODE)
  62
  63 If a file name matches REGEXP, then use help mode MODE instead of the
  64 buffer's major mode."
  65   :group 'info-lookup :type '(repeat (cons (string :tag "Regexp")
  66                                            (symbol :tag "Mode"))))
  67
  68 (defvar info-lookup-history nil
  69   "History of previous input lines.")
  70
  71 (defvar info-lookup-alist nil
  72   "Alist of known help topics.
  73 Cons cells are of the form
  74
  75     (HELP-TOPIC . HELP-DATA)
  76
  77 HELP-TOPIC is the symbol of a help topic.
  78 HELP-DATA is a HELP-TOPIC's public data set.
  79  Value is an alist with elements of the form
  80
  81     (HELP-MODE REGEXP IGNORE-CASE DOC-SPEC PARSE-RULE OTHER-MODES)
  82
  83 HELP-MODE is a mode's symbol.
  84 REGEXP is a regular expression matching those help items whose
  85  documentation can be looked up via DOC-SPEC.
  86 IGNORE-CASE is non-nil if help items are case insensitive.
  87 DOC-SPEC is a list of documentation specifications of the form
  88
  89     (INFO-NODE TRANS-FUNC PREFIX SUFFIX)
  90
  91 INFO-NODE is the name (including file name part) of an Info index.
  92 TRANS-FUNC is a function translating index entries into help items;
  93  nil means add only those index entries matching REGEXP, a string
  94  means prepend string to the first word of all index entries.
  95 PREFIX and SUFFIX are parts of a regular expression.  If one of
  96  them is non-nil then search the help item's Info node for the
  97  first occurrence of the regular expression `PREFIX ITEM SUFFIX'.
  98  ITEM will be highlighted with `info-lookup-highlight-face' if this
  99  variable is not nil.
 100 PARSE-RULE is either the symbol name of a function or a regular
 101  expression for guessing the default help item at point.  Fuzzy
 102  regular expressions like \"[_a-zA-Z0-9]+\" do a better job if
 103  there are no clear delimiters; do not try to write too complex
 104  expressions.  PARSE-RULE defaults to REGEXP.
 105 OTHER-MODES is a list of cross references to other help modes.")
 106
 107 (defsubst info-lookup->topic-value (topic)
 108   (cdr (assoc topic info-lookup-alist)))
 109
 110 (defsubst info-lookup->mode-value (topic mode)
 111   (assoc mode (info-lookup->topic-value topic)))
 112
 113 (defsubst info-lookup->regexp (topic mode)
 114   (nth 1 (info-lookup->mode-value topic mode)))
 115
 116 (defsubst info-lookup->ignore-case (topic mode)
 117   (nth 2 (info-lookup->mode-value topic mode)))
 118
 119 (defsubst info-lookup->doc-spec (topic mode)
 120   (nth 3 (info-lookup->mode-value topic mode)))
 121
 122 (defsubst info-lookup->parse-rule (topic mode)
 123   (nth 4 (info-lookup->mode-value topic mode)))
 124
 125 (defsubst info-lookup->other-modes (topic mode)
 126   (nth 5 (info-lookup->mode-value topic mode)))
 127
 128 (defun info-lookup-add-help (&rest arg)
 129   "Add or update a help specification.
 130 Function arguments are one or more options of the form
 131
 132     KEYWORD ARGUMENT
 133
 134 KEYWORD is either `:topic', `:mode', `:regexp', `:ignore-case',
 135  `:doc-spec', `:parse-rule', or `:other-modes'.
 136 ARGUMENT has a value as explained in the documentation of the
 137  variable `info-lookup-alist'.
 138
 139 If no topic or mode option has been specified, then the help topic defaults
 140 to `symbol', and the help mode defaults to the current major mode."
 141   (apply 'info-lookup-add-help* nil arg))
 142
 143 (defun info-lookup-maybe-add-help (&rest arg)
 144   "Add a help specification if none is defined.
 145 See the documentation of the function `info-lookup-add-help'
 146 for more details."
 147   (apply 'info-lookup-add-help* t arg))
 148
 149 (defun info-lookup-add-help* (maybe &rest arg)
 150   (let (topic mode regexp ignore-case doc-spec
 151               parse-rule other-modes keyword value)
 152     (setq topic 'symbol
 153           mode major-mode
 154           regexp "\\w+")
 155     (while arg
 156       (setq keyword (car arg))
 157       (or (symbolp keyword)
 158           (error "Junk in argument list \"%S\"" arg))
 159       (setq arg (cdr arg))
 160       (and (null arg)
 161            (error "Keyword \"%S\" is missing an argument" keyword))
 162       (setq value (car arg)
 163             arg (cdr arg))
 164       (cond ((eq keyword :topic)
 165              (setq topic value))
 166             ((eq keyword :mode)
 167              (setq mode value))
 168             ((eq keyword :regexp)
 169              (setq regexp value))
 170             ((eq keyword :ignore-case)
 171              (setq ignore-case value))
 172             ((eq keyword :doc-spec)
 173              (setq doc-spec value))
 174             ((eq keyword :parse-rule)
 175              (setq parse-rule value))
 176             ((eq keyword :other-modes)
 177              (setq other-modes value))
 178             (t
 179              (error "Unknown keyword \"%S\"" keyword))))
 180     (or (and maybe (info-lookup->mode-value topic mode))
 181         (let* ((data (list regexp ignore-case doc-spec parse-rule other-modes))
 182                (topic-cell (or (assoc topic info-lookup-alist)
 183                                (car (setq info-lookup-alist
 184                                           (cons (cons topic nil)
 185                                                 info-lookup-alist)))))
 186                (mode-cell (assoc mode topic-cell)))
 187           (if (null mode-cell)
 188               (setcdr topic-cell (cons (cons mode data) (cdr topic-cell)))
 189             (setcdr mode-cell data))))
 190     nil))
 191
 192 (defvar info-lookup-cache nil
 193   "Cache storing data maintained automatically by the program.
 194 Value is an alist with cons cell of the form
 195
 196     (HELP-TOPIC . ((HELP-MODE INITIALIZED COMPLETIONS REFER-MODES) ...))
 197
 198 HELP-TOPIC is the symbol of a help topic.
 199 HELP-MODE is a mode's symbol.
 200 INITIALIZED is nil if HELP-MODE is uninitialized, t if
 201  HELP-MODE is initialized, and `0' means HELP-MODE is
 202  initialized but void.
 203 COMPLETIONS is an alist of documented help items.
 204 REFER-MODES is a list of other help modes to use.")
 205
 206 (defsubst info-lookup->cache (topic)
 207   (or (assoc topic info-lookup-cache)
 208       (car (setq info-lookup-cache
 209                  (cons (cons topic nil)
 210                        info-lookup-cache)))))
 211
 212 (defun info-lookup->topic-cache (topic)
 213   (cdr (info-lookup->cache topic)))
 214
 215 (defun info-lookup->mode-cache (topic mode)
 216   (assoc mode (info-lookup->topic-cache topic)))
 217
 218 (defun info-lookup->initialized (topic mode)
 219   (nth 1 (info-lookup->mode-cache topic mode)))
 220
 221 (defun info-lookup->completions (topic mode)
 222   (or (info-lookup->initialized topic mode)
 223       (info-lookup-setup-mode topic mode))
 224   (nth 2 (info-lookup->mode-cache topic mode)))
 225
 226 (defun info-lookup->refer-modes (topic mode)
 227   (or (info-lookup->initialized topic mode)
 228       (info-lookup-setup-mode topic mode))
 229   (nth 3 (info-lookup->mode-cache topic mode)))
 230
 231 (defun info-lookup->all-modes (topic mode)
 232   (cons mode (info-lookup->refer-modes topic mode)))
 233
 234 (defun info-lookup-quick-all-modes (topic mode)
 235   (cons mode (info-lookup->other-modes topic mode)))
 236
 237 ;;;###autoload
 238 (defun info-lookup-reset ()
 239   "Throw away all cached data.
 240 This command is useful if the user wants to start at the beginning without
 241 quitting Emacs, for example, after some Info documents were updated on the
 242 system."
 243   (interactive)
 244   (setq info-lookup-cache nil))
 245
 246 ;;;###autoload (put 'info-lookup-symbol 'info-file "emacs")
 247 ;;;###autoload
 248 (defun info-lookup-symbol (symbol &optional mode)
 249   "Display the definition of SYMBOL, as found in the relevant manual.
 250 When this command is called interactively, it reads SYMBOL from the
 251 minibuffer.  In the minibuffer, use M-n to yank the default argument
 252 value into the minibuffer so you can edit it.  The default symbol is the
 253 one found at point.
 254
 255 With prefix arg a query for the symbol help mode is offered."
 256   (interactive
 257    (info-lookup-interactive-arguments 'symbol current-prefix-arg))
 258   (info-lookup 'symbol symbol mode))
 259
 260 ;;;###autoload (put 'info-lookup-file 'info-file "emacs")
 261 ;;;###autoload
 262 (defun info-lookup-file (file &optional mode)
 263   "Display the documentation of a file.
 264 When this command is called interactively, it reads FILE from the minibuffer.
 265 In the minibuffer, use M-n to yank the default file name
 266 into the minibuffer so you can edit it.
 267 The default file name is the one found at point.
 268
 269 With prefix arg a query for the file help mode is offered."
 270   (interactive
 271    (info-lookup-interactive-arguments 'file current-prefix-arg))
 272   (info-lookup 'file file mode))
 273
 274 (defun info-lookup-interactive-arguments (topic &optional query)
 275   "Read and return argument value (and help mode) for help topic TOPIC.
 276 If optional argument QUERY is non-nil, query for the help mode."
 277   (let* ((mode (cond (query
 278                       (info-lookup-change-mode topic))
 279                      ((info-lookup->mode-value topic (info-lookup-select-mode))
 280                       info-lookup-mode)
 281                      ((info-lookup-change-mode topic))))
 282          (completions (info-lookup->completions topic mode))
 283          (default (info-lookup-guess-default topic mode))
 284          (completion-ignore-case (info-lookup->ignore-case topic mode))
 285          (enable-recursive-minibuffers t)
 286          (value (completing-read
 287                  (if default
 288                      (format "Describe %s (default %s): " topic default)
 289                    (format "Describe %s: " topic))
 290                  completions nil nil nil 'info-lookup-history default)))
 291     (list (if (equal value "") default value) mode)))
 292
 293 (defun info-lookup-select-mode ()
 294   (when (and (not info-lookup-mode) (buffer-file-name))
 295     (let ((file-name (file-name-nondirectory (buffer-file-name)))
 296           (file-name-alist info-lookup-file-name-alist))
 297       (while (and (not info-lookup-mode) file-name-alist)
 298         (when (string-match (caar file-name-alist) file-name)
 299           (setq info-lookup-mode (cdar file-name-alist)))
 300         (setq file-name-alist (cdr file-name-alist)))))
 301   (or info-lookup-mode (setq info-lookup-mode major-mode)))
 302
 303 (defun info-lookup-change-mode (topic)
 304   (let* ((completions (mapcar (lambda (arg)
 305                                 (cons (symbol-name (car arg)) (car arg)))
 306                               (info-lookup->topic-value topic)))
 307          (mode (completing-read
 308                 (format "Use %s help mode: " topic)
 309                 completions nil t nil 'info-lookup-history)))
 310     (or (setq mode (cdr (assoc mode completions)))
 311         (error "No %s help available" topic))
 312     (or (info-lookup->mode-value topic mode)
 313         (error "No %s help available for `%s'" topic mode))
 314     (setq info-lookup-mode mode)))
 315
 316 (defun info-lookup (topic item mode)
 317   "Display the documentation of a help item."
 318   (or mode (setq mode (info-lookup-select-mode)))
 319   (or (info-lookup->mode-value topic mode)
 320       (error "No %s help available for `%s'" topic mode))
 321   (let* ((completions (info-lookup->completions topic mode))
 322          (ignore-case (info-lookup->ignore-case topic mode))
 323          (entry (or (assoc (if ignore-case (downcase item) item) completions)
 324                     (assoc-string item completions t)
 325                     (error "Not documented as a %s: %s" topic (or item ""))))
 326          (modes (info-lookup->all-modes topic mode))
 327          (window (selected-window))
 328          (new-Info-history
 329           ;; Avoid clobbering Info-history with nodes searched during
 330           ;; lookup.  If lookup succeeds set `Info-history' to
 331           ;; `new-Info-history'.
 332           (when (get-buffer "*info*")
 333             (with-current-buffer "*info*"
 334               (cons (list Info-current-file Info-current-node (point))
 335                     Info-history))))
 336          found doc-spec node prefix suffix doc-found)
 337     (unless (eq major-mode 'Info-mode)
 338       (if (not info-lookup-other-window-flag)
 339           (info)
 340         (save-window-excursion (info))
 341         (let* ((info-window (get-buffer-window "*info*" t))
 342                (info-frame (and info-window (window-frame info-window))))
 343           (if (and info-frame
 344                    (not (eq info-frame (selected-frame)))
 345                    (display-multi-frame-p)
 346                    (memq info-frame (frames-on-display-list)))
 347               ;; *info* is visible in another frame on same display.
 348               ;; Raise that frame and select the window.
 349               (progn
 350                 (select-window info-window)
 351                 (raise-frame info-frame))
 352             ;; In any other case, switch to *info* in another window.
 353             (switch-to-buffer-other-window "*info*")))))
 354     (while (and (not found) modes)
 355       (setq doc-spec (info-lookup->doc-spec topic (car modes)))
 356       (while (and (not found) doc-spec)
 357         (setq node (nth 0 (car doc-spec))
 358               prefix (nth 2 (car doc-spec))
 359               suffix (nth 3 (car doc-spec)))
 360         (when (condition-case error-data
 361                   (progn
 362                     ;; Don't need Index menu fontifications here, and
 363                     ;; they slow down the lookup.
 364                     (let (Info-fontify-maximum-menu-size
 365                           Info-history-list)
 366                       (Info-goto-node node)
 367                       (setq doc-found t)))
 368                 (error
 369                  (message "Cannot access Info node %s" node)
 370                  (sit-for 1)
 371                  nil))
 372           (condition-case nil
 373               (progn
 374                 ;; Don't use Info-menu, it forces case-fold-search to t
 375                 (let ((case-fold-search nil))
 376                   (re-search-forward
 377                    (concat "^\\* " (regexp-quote (or (cdr entry) (car entry)))
 378                            ":")))
 379                 (Info-follow-nearest-node)
 380                 (setq found t)
 381                 (if (or prefix suffix)
 382                     (let ((case-fold-search
 383                            (info-lookup->ignore-case topic (car modes)))
 384                           (buffer-read-only nil))
 385                       (goto-char (point-min))
 386                       (re-search-forward
 387                        (concat prefix (regexp-quote (car entry)) suffix))
 388                       (goto-char (match-beginning 0))
 389                       (and (display-color-p) info-lookup-highlight-face
 390                            ;; Search again for ITEM so that the first
 391                            ;; occurrence of ITEM will be highlighted.
 392                            (re-search-forward (regexp-quote (car entry)))
 393                            (let ((start (match-beginning 0))
 394                                  (end (match-end 0)))
 395                              (if (overlayp info-lookup-highlight-overlay)
 396                                  (move-overlay info-lookup-highlight-overlay
 397                                                start end (current-buffer))
 398                                (setq info-lookup-highlight-overlay
 399                                      (make-overlay start end))))
 400                            (overlay-put info-lookup-highlight-overlay
 401                                         'face info-lookup-highlight-face)))))
 402             (error nil)))
 403         (setq doc-spec (cdr doc-spec)))
 404       (setq modes (cdr modes)))
 405     ;; Alert the user if case was munged, and do this after bringing up the
 406     ;; info buffer since that can print messages
 407     (unless (or ignore-case
 408                 (string-equal item (car entry)))
 409       (message "Found in different case: %s" (car entry)))
 410     (when found
 411       (setq Info-history new-Info-history))
 412     (or doc-found
 413         (error "Info documentation for lookup was not found"))
 414     ;; Don't leave the Info buffer if the help item couldn't be looked up.
 415     (if (and info-lookup-other-window-flag found)
 416         (select-window window))))
 417
 418 (defun info-lookup-setup-mode (topic mode)
 419   "Initialize the internal data structure."
 420   (or (info-lookup->initialized topic mode)
 421       (let ((initialized 0)
 422             cell data completions refer-modes Info-history-list)
 423         (if (not (info-lookup->mode-value topic mode))
 424             (message "No %s help available for `%s'" topic mode)
 425           ;; Recursively setup cross references.
 426           ;; But refer only to non-void modes.
 427           (dolist (arg (info-lookup->other-modes topic mode))
 428             (or (info-lookup->initialized topic arg)
 429                 (info-lookup-setup-mode topic arg))
 430             (and (eq (info-lookup->initialized topic arg) t)
 431                  (setq refer-modes (cons arg refer-modes))))
 432           (setq refer-modes (nreverse refer-modes))
 433           ;; Build the full completion alist.
 434           (setq completions
 435                 (nconc (condition-case nil
 436                            (info-lookup-make-completions topic mode)
 437                          (error nil))
 438                        (apply 'append
 439                               (mapcar (lambda (arg)
 440                                         (info-lookup->completions topic arg))
 441                                       refer-modes))))
 442           (setq initialized t))
 443         ;; Update `info-lookup-cache'.
 444         (setq cell (info-lookup->mode-cache topic mode)
 445               data (list initialized completions refer-modes))
 446         (if (not cell)
 447             (setcdr (info-lookup->cache topic)
 448                     (cons (cons mode data) (info-lookup->topic-cache topic)))
 449           (setcdr cell data))
 450         initialized)))
 451
 452 (defun info-lookup-make-completions (topic mode)
 453   "Create a unique alist from all index entries."
 454   (let ((doc-spec (info-lookup->doc-spec topic mode))
 455         (regexp (concat "^\\(" (info-lookup->regexp topic mode)
 456                         "\\)\\([ \t].*\\)?$"))
 457         Info-history-list Info-fontify-maximum-menu-size
 458         node trans entry item prefix result doc-found
 459         (buffer (get-buffer-create " temp-info-look")))
 460     (with-current-buffer buffer
 461       (Info-mode))
 462     (while doc-spec
 463       (setq node (nth 0 (car doc-spec))
 464             trans (cond ((eq (nth 1 (car doc-spec)) nil)
 465                          (lambda (arg)
 466                            (if (string-match regexp arg)
 467                                (match-string 1 arg))))
 468                         ((stringp (nth 1 (car doc-spec)))
 469                          (setq prefix (nth 1 (car doc-spec)))
 470                          (lambda (arg)
 471                            (if (string-match "^\\([^: \t\n]+\\)" arg)
 472                                (concat prefix (match-string 1 arg)))))
 473                         (t (nth 1 (car doc-spec)))))
 474       (with-current-buffer buffer
 475         (message "Processing Info node `%s'..." node)
 476         (when (condition-case error-data
 477                   (progn
 478                     (Info-goto-node node)
 479                     (setq doc-found t))
 480                 (error
 481                  (message "Cannot access Info node `%s'" node)
 482                  (sit-for 1)
 483                  nil))
 484           (condition-case nil
 485               (progn
 486                 (goto-char (point-min))
 487                 (and (search-forward "\n* Menu:" nil t)
 488                      (while (re-search-forward "\n\\* \\(.*\\): " nil t)
 489                        (setq entry (match-string 1)
 490                              item (funcall trans entry))
 491                        ;; `trans' can return nil if the regexp doesn't match.
 492                        (when (and item
 493                                   ;; Sometimes there's more than one Menu:
 494                                   (not (string= entry "Menu")))
 495                          (and (info-lookup->ignore-case topic mode)
 496                               (setq item (downcase item)))
 497                          (and (string-equal entry item)
 498                               (setq entry nil))
 499                          (and (or (assoc item result)
 500                                   (setq result (cons (cons item entry)
 501                                                      result))))))))
 502             (error nil))))
 503       (message "Processing Info node `%s'...done" node)
 504       (setq doc-spec (cdr doc-spec)))
 505     (or doc-found
 506         (error "Info documentation for lookup was not found"))
 507     result))
 508
 509 (defun info-lookup-guess-default (topic mode)
 510   "Return a guess for a symbol to look up, based on text around point.
 511 Try all related modes applicable to TOPIC and MODE.
 512 Return nil if there is nothing appropriate in the buffer near point."
 513   (let ((modes (info-lookup->all-modes topic mode))
 514         guess)
 515     (while (and (not guess) modes)
 516       (setq guess (info-lookup-guess-default* topic (car modes))
 517             modes (cdr modes)))
 518     ;; Collapse whitespace characters.
 519     (when guess
 520       (let ((pos 0))
 521         (while (string-match "[ \t\n]+" guess pos)
 522           (setq pos (1+ (match-beginning 0)))
 523           (setq guess (replace-match " " t t guess)))))
 524     guess))
 525
 526 (defun info-lookup-guess-default* (topic mode)
 527   (let ((case-fold-search (info-lookup->ignore-case topic mode))
 528         (rule (or (info-lookup->parse-rule topic mode)
 529                   (info-lookup->regexp topic mode)))
 530         (start (point)) end regexp subexp result)
 531     (save-excursion
 532       (if (symbolp rule)
 533           (setq result (funcall rule))
 534         (if (consp rule)
 535             (setq regexp (car rule)
 536                   subexp (cdr rule))
 537           (setq regexp rule
 538                 subexp 0))
 539         ;; If at start of symbol, don't go back to end of previous one.
 540         (if (save-match-data
 541               (looking-at "[ \t\n]"))
 542             (skip-chars-backward " \t\n"))
 543         (setq end (point))
 544         (while (and (re-search-backward regexp nil t)
 545                     (looking-at regexp)
 546                     (>= (match-end 0) end))
 547           (setq result (match-string subexp)))
 548         (if (not result)
 549             (progn
 550               (goto-char start)
 551               (skip-chars-forward " \t\n")
 552               (and (looking-at regexp)
 553                    (setq result (match-string subexp)))))))
 554     result))
 555
 556 (defun info-lookup-guess-c-symbol ()
 557   "Get the C symbol at point."
 558   (condition-case nil
 559       (progn
 560         (skip-syntax-backward "w_")
 561         (let ((start (point)) prefix name)
 562           ;; Test for a leading `struct', `union', or `enum' keyword
 563           ;; but ignore names like `foo_struct'.
 564           (setq prefix (and (< (skip-chars-backward " \t\n") 0)
 565                             (< (skip-chars-backward "_a-zA-Z0-9") 0)
 566                             (looking-at "\\(struct\\|union\\|enum\\)\\s ")
 567                             (concat (match-string 1) " ")))
 568           (goto-char start)
 569           (and (looking-at "[_a-zA-Z][_a-zA-Z0-9]*")
 570                (setq name (match-string 0)))
 571           ;; Caveat!  Look forward if point is at `struct' etc.
 572           (and (not prefix)
 573                (or (string-equal name "struct")
 574                    (string-equal name "union")
 575                    (string-equal name "enum"))
 576                (looking-at "[a-z]+\\s +\\([_a-zA-Z][_a-zA-Z0-9]*\\)")
 577                (setq prefix (concat name " ")
 578                      name (match-string 1)))
 579           (and (or prefix name)
 580                (concat prefix name))))
 581     (error nil)))
 582
 583 (defun info-lookup-guess-custom-symbol ()
 584   "Get symbol at point in custom buffers."
 585   (condition-case nil
 586       (save-excursion
 587         (let ((case-fold-search t)
 588               (ignored-chars "][()`',:.\" \t\n")
 589               (significant-chars "^][()`',:.\" \t\n")
 590               beg end)
 591           (cond
 592            ((and (memq (get-char-property (point) 'face)
 593                          '(custom-variable-tag custom-variable-tag-face))
 594                    (setq beg (previous-single-char-property-change
 595                               (point) 'face nil (line-beginning-position)))
 596                    (setq end (next-single-char-property-change
 597                               (point) 'face nil (line-end-position)))
 598                    (> end beg))
 599             (subst-char-in-string
 600              ?\s ?\- (buffer-substring-no-properties beg end)))
 601            ((or (and (looking-at (concat "[" significant-chars "]"))
 602                      (save-excursion
 603                        (skip-chars-backward significant-chars)
 604                        (setq beg (point)))
 605                      (skip-chars-forward significant-chars)
 606                      (setq end (point))
 607                      (> end beg))
 608                 (and (looking-at "[ \t\n]")
 609                      (looking-back (concat "[" significant-chars "]"))
 610                      (setq end (point))
 611                      (skip-chars-backward significant-chars)
 612                      (setq beg (point))
 613                      (> end beg))
 614                 (and (skip-chars-forward ignored-chars)
 615                      (setq beg (point))
 616                      (skip-chars-forward significant-chars)
 617                      (setq end (point))
 618                      (> end beg)))
 619             (buffer-substring-no-properties beg end)))))
 620     (error nil)))
 621
 622 ;;;###autoload
 623 (defun info-complete-symbol (&optional mode)
 624   "Perform completion on symbol preceding point."
 625   (interactive)
 626   (info-complete 'symbol
 627                  (or mode
 628                      (if (info-lookup->mode-value
 629                           'symbol (info-lookup-select-mode))
 630                          info-lookup-mode
 631                        (info-lookup-change-mode 'symbol)))))
 632
 633 ;;;###autoload
 634 (defun info-complete-file (&optional mode)
 635   "Perform completion on file preceding point."
 636   (interactive)
 637   (info-complete 'file
 638                  (or mode
 639                      (if (info-lookup->mode-value
 640                           'file (info-lookup-select-mode))
 641                          info-lookup-mode
 642                        (info-lookup-change-mode 'file)))))
 643
 644 (defun info-complete (topic mode)
 645   "Try to complete a help item."
 646   (barf-if-buffer-read-only)
 647   (or mode (setq mode (info-lookup-select-mode)))
 648   (or (info-lookup->mode-value topic mode)
 649       (error "No %s completion available for `%s'" topic mode))
 650   (let ((modes (info-lookup-quick-all-modes topic mode))
 651         (start (point))
 652         try)
 653     (while (and (not try) modes)
 654       (setq mode (car modes)
 655             modes (cdr modes)
 656             try (info-lookup-guess-default* topic mode))
 657       (goto-char start))
 658     (and (not try)
 659          (error "Found no %S to complete" topic))
 660     (let ((completions (info-lookup->completions topic mode))
 661           (completion-ignore-case (info-lookup->ignore-case topic mode))
 662           completion)
 663       (setq completion (try-completion try completions))
 664       (cond ((not completion)
 665              (ding)
 666              (message "No match"))
 667             ((stringp completion)
 668              (or (assoc completion completions)
 669                  (setq completion (completing-read
 670                                    (format "Complete %S: " topic)
 671                                    completions nil t completion
 672                                    info-lookup-history)))
 673              ;; Find the original symbol and zap it.
 674              (end-of-line)
 675              (while (and (search-backward try nil t)
 676                          (< start (point))))
 677              (replace-match "")
 678              (insert completion))
 679             (t
 680              (message "%s is complete"
 681                       (capitalize (prin1-to-string topic))))))))
 682
 683 \f
 684 ;;; Initialize some common modes.
 685
 686 (info-lookup-maybe-add-help
 687  :mode 'c-mode :topic 'symbol
 688  :regexp "\\(struct \\|union \\|enum \\)?[_a-zA-Z][_a-zA-Z0-9]*"
 689  :doc-spec '(("(libc)Function Index" nil
 690               "^[ \t]+-+ \\(Function\\|Macro\\): .*\\<" "\\>")
 691              ;; prefix/suffix has to match things like
 692              ;;   " -- Macro: int F_DUPFD"
 693              ;;   " -- Variable: char * tzname [2]"
 694              ;;   "`DBL_MAX'"    (texinfo @table)
 695              ;; suffix "\\>" is not used because that sends DBL_MAX to
 696              ;; DBL_MAX_EXP ("_" is a non-word char)
 697              ("(libc)Variable Index" nil
 698               "^\\([ \t]+-+ \\(Variable\\|Macro\\): .*\\<\\|`\\)"
 699               "\\( \\|'?$\\)")
 700              ("(libc)Type Index" nil
 701               "^[ \t]+-+ Data Type: \\<" "\\>")
 702              ("(termcap)Var Index" nil
 703               "^[ \t]*`" "'"))
 704  :parse-rule 'info-lookup-guess-c-symbol)
 705
 706 (info-lookup-maybe-add-help
 707  :mode 'c-mode :topic 'file
 708  :regexp "[_a-zA-Z0-9./+-]+"
 709  :doc-spec '(("(libc)File Index")))
 710
 711 (info-lookup-maybe-add-help
 712  :mode 'bison-mode
 713  :regexp "[:;|]\\|%\\([%{}]\\|[_a-z]+\\)\\|YY[_A-Z]+\\|yy[_a-z]+"
 714  :doc-spec '(("(bison)Index" nil
 715               "`" "'"))
 716  :parse-rule "[:;|]\\|%\\([%{}]\\|[_a-zA-Z][_a-zA-Z0-9]*\\)"
 717  :other-modes '(c-mode))
 718
 719 (info-lookup-maybe-add-help
 720  :mode 'makefile-mode
 721  :regexp "\\$[^({]\\|\\.[_A-Z]*\\|[_a-zA-Z][_a-zA-Z0-9-]*"
 722  :doc-spec '(("(make)Name Index" nil
 723               "^[ \t]*`" "'")
 724              ("(automake)Macro and Variable Index" nil
 725               "^[ \t]*`" "'"))
 726  :parse-rule "\\$[^({]\\|\\.[_A-Z]*\\|[_a-zA-Z0-9-]+"
 727  :other-modes '(automake-mode))
 728
 729 (info-lookup-maybe-add-help
 730  :mode 'texinfo-mode
 731  :regexp "@\\([a-zA-Z]+\\|[^a-zA-Z]\\)"
 732  :doc-spec '(("(texinfo)Command and Variable Index"
 733               ;; Ignore Emacs commands and prepend a `@'.
 734               (lambda (item)
 735                 (if (string-match "^\\([a-zA-Z]+\\|[^a-zA-Z]\\)\\( .*\\)?$" item)
 736                     (concat "@" (match-string 1 item))))
 737               "`" "[' ]")))
 738
 739 (info-lookup-maybe-add-help
 740  :mode 'm4-mode
 741  :regexp "[_a-zA-Z][_a-zA-Z0-9]*"
 742  :doc-spec '(("(m4)Macro index"))
 743  :parse-rule "[_a-zA-Z0-9]+")
 744
 745 (info-lookup-maybe-add-help
 746  :mode 'autoconf-mode
 747  :regexp "A[CM]_[_A-Z0-9]+"
 748  :doc-spec '(;; Autoconf Macro Index entries are without an "AC_" prefix,
 749              ;; but with "AH_" or "AU_" for those.  So add "AC_" if there
 750              ;; isn't already an "A._".
 751              ("(autoconf)Autoconf Macro Index"
 752               (lambda (item)
 753                 (if (string-match "^A._" item) item (concat "AC_" item)))
 754               "^[ \t]+-+ \\(Macro\\|Variable\\): .*\\<" "\\>")
 755              ;; M4 Macro Index entries are without "AS_" prefixes, and
 756              ;; mostly without "m4_" prefixes.  "dnl" is an exception, not
 757              ;; wanting any prefix.  So AS_ is added back to upper-case
 758              ;; names (if needed), m4_ to others which don't already an m4_.
 759              ("(autoconf)M4 Macro Index"
 760               (lambda (item)
 761                 (let ((case-fold-search nil))
 762                   (cond ((or (string-equal item "dnl")
 763                              (string-match "^m4_" item)
 764                              ;; Autoconf 2.62 index includes some macros
 765                              ;; (e.g., AS_HELP_STRING), so avoid prefixing.
 766                              (string-match "^AS_" item))
 767                          item)
 768                         ((string-match "^[A-Z0-9_]+$" item)
 769                          (concat "AS_" item))
 770                         (t
 771                          (concat "m4_" item)))))
 772               "^[ \t]+-+ Macro: .*\\<" "\\>")
 773              ;; Autotest Macro Index entries are without "AT_".
 774              ("(autoconf)Autotest Macro Index" "AT_"
 775               "^[ \t]+-+ Macro: .*\\<" "\\>")
 776              ;; This is for older versions (probably pre autoconf 2.5x):
 777              ("(autoconf)Macro Index" "AC_"
 778               "^[ \t]+-+ \\(Macro\\|Variable\\): .*\\<" "\\>")
 779              ;; Automake has index entries for its notes on various autoconf
 780              ;; macros (eg. AC_PROG_CC).  Ensure this is after the autoconf
 781              ;; index, so as to prefer the autoconf docs.
 782              ("(automake)Macro and Variable Index" nil
 783               "^[ \t]*`" "'"))
 784  ;; Autoconf symbols are M4 macros.  Thus use M4's parser.
 785  :parse-rule 'ignore
 786  :other-modes '(m4-mode))
 787
 788 (info-lookup-maybe-add-help
 789  :mode 'awk-mode
 790  :regexp "[_a-zA-Z]+"
 791  :doc-spec '(("(gawk)Index"
 792               (lambda (item)
 793                 (let ((case-fold-search nil))
 794                   (cond
 795                    ;; `BEGIN' and `END'.
 796                    ((string-match "^\\([A-Z]+\\) special pattern\\b" item)
 797                     (match-string 1 item))
 798                    ;; `if', `while', `do', ...
 799                    ((string-match "^\\([a-z]+\\) statement\\b" item)
 800                     (if (not (string-equal (match-string 1 item) "control"))
 801                         (match-string 1 item)))
 802                    ;; `NR', `NF', ...
 803                    ((string-match "^[A-Z]+$" item)
 804                     item)
 805                    ;; Built-in functions (matches to many entries).
 806                    ((string-match "^[a-z]+$" item)
 807                     item))))
 808               "`" "\\([ \t]*([^)]*)\\)?'")))
 809
 810 (info-lookup-maybe-add-help
 811  :mode 'perl-mode
 812  :regexp "[$@%][^a-zA-Z]\\|\\$\\^[A-Z]\\|[$@%]?[a-zA-Z][_a-zA-Z0-9]*"
 813  :doc-spec '(("(perl5)Function Index"
 814               (lambda (item)
 815                 (if (string-match "^\\([a-zA-Z0-9]+\\)" item)
 816                     (match-string 1 item)))
 817               "^" "\\b")
 818              ("(perl5)Variable Index"
 819               (lambda (item)
 820                 ;; Work around bad formatted array variables.
 821                 (let ((sym (cond ((or (string-match "^\\$\\(.\\|@@\\)$" item)
 822                                       (string-match "^\\$\\^[A-Z]$" item))
 823                                   item)
 824                                  ((string-match
 825                                    "^\\([$%@]\\|@@\\)?[_a-zA-Z0-9]+" item)
 826                                   (match-string 0 item))
 827                                  (t ""))))
 828                   (if (string-match "@@" sym)
 829                       (setq sym (concat (substring sym 0 (match-beginning 0))
 830                                         (substring sym (1- (match-end 0))))))
 831                   (if (string-equal sym "") nil sym)))
 832               "^" "\\b"))
 833  :parse-rule "[$@%]?\\([_a-zA-Z0-9]+\\|[^a-zA-Z]\\)")
 834
 835 (info-lookup-maybe-add-help
 836  :mode 'cperl-mode
 837  :regexp "[$@%][^a-zA-Z]\\|\\$\\^[A-Z]\\|[$@%]?[a-zA-Z][_a-zA-Z0-9]*"
 838  :other-modes '(perl-mode))
 839
 840 (info-lookup-maybe-add-help
 841  :mode 'latex-mode
 842  :regexp "\\\\\\([a-zA-Z]+\\|[^a-zA-Z]\\)"
 843  :doc-spec '(("(latex)Command Index" nil
 844               "`" "\\({[^}]*}\\)?'")))
 845
 846 (info-lookup-maybe-add-help
 847  :mode 'emacs-lisp-mode
 848  :regexp "[^][()`',\" \t\n]+"
 849  :doc-spec '(;; Commands with key sequences appear in nodes as `foo' and
 850              ;; those without as `M-x foo'.
 851              ("(emacs)Command Index"  nil "`\\(M-x[ \t\n]+\\)?" "'")
 852              ;; Variables normally appear in nodes as just `foo'.
 853              ("(emacs)Variable Index" nil "`" "'")
 854              ;; Almost all functions, variables, etc appear in nodes as
 855              ;; " -- Function: foo" etc.  A small number of aliases and
 856              ;; symbols appear only as `foo', and will miss out on exact
 857              ;; positions.  Allowing `foo' would hit too many false matches
 858              ;; for things that should go to Function: etc, and those latter
 859              ;; are much more important.  Perhaps this could change if some
 860              ;; sort of fallback match scheme existed.
 861              ("(elisp)Index"          nil "^ -+ .*: " "\\( \\|$\\)")))
 862
 863 ;; docstrings talk about elisp, so have apropos-mode follow emacs-lisp-mode
 864 (info-lookup-maybe-add-help
 865  :mode 'apropos-mode
 866  :regexp "[^][()`',\" \t\n]+" ;; same as emacs-lisp-mode above
 867  :other-modes '(emacs-lisp-mode))
 868
 869 (info-lookup-maybe-add-help
 870  :mode 'lisp-interaction-mode
 871  :regexp "[^][()`',\" \t\n]+"
 872  :parse-rule 'ignore
 873  :other-modes '(emacs-lisp-mode))
 874
 875 (info-lookup-maybe-add-help
 876  :mode 'lisp-mode
 877  :regexp "[^()`',\" \t\n]+"
 878  :parse-rule 'ignore
 879  :other-modes '(emacs-lisp-mode))
 880
 881 (info-lookup-maybe-add-help
 882  :mode 'scheme-mode
 883  :regexp "[^()`',\" \t\n]+"
 884  :ignore-case t
 885  ;; Aubrey Jaffer's rendition from <URL:ftp://ftp-swiss.ai.mit.edu/pub/scm>
 886  :doc-spec '(("(r5rs)Index" nil
 887               "^[ \t]+-+ [^:]+:[ \t]*" "\\b")))
 888
 889 (info-lookup-maybe-add-help
 890  :mode 'octave-mode
 891  :regexp "[_a-zA-Z0-9]+\\|\\s.+\\|[-!=^|*/.\\,><~&+]\\{1,3\\}\\|[][();,\"']"
 892  :doc-spec '(("(octave)Function Index" nil
 893               "^ -+ [^:]+:[ ]+\\(\\[[^=]*=[ ]+\\)?" nil)
 894              ("(octave)Variable Index" nil "^ -+ [^:]+:[ ]+" nil)
 895              ("(octave)Operator Index" nil nil nil)
 896              ;; Catch lines of the form "xyz statement"
 897              ("(octave)Concept Index"
 898               (lambda (item)
 899                 (cond
 900                  ((string-match "^\\([A-Z]+\\) statement\\b" item)
 901                     (match-string 1 item))
 902                  (t nil)))
 903               nil; "^ -+ [^:]+:[ ]+" don't think this prefix is useful here.
 904               nil)))
 905
 906 (info-lookup-maybe-add-help
 907  :mode 'maxima-mode
 908  :ignore-case t
 909  :regexp "[a-zA-Z0-9_%]+"
 910  :doc-spec '( ("(maxima)Function and Variable Index" nil
 911                "^ -+ [^:]+:[ ]+\\(\\[[^=]*=[ ]+\\)?" nil)))
 912
 913 (info-lookup-maybe-add-help
 914  :mode 'inferior-maxima-mode
 915  :regexp "[a-zA-Z0-9_%]+"
 916  :other-modes '(maxima-mode))
 917
 918 ;; coreutils and bash builtins overlap in places, eg. printf, so there's a
 919 ;; question which should come first.  Some of the coreutils descriptions are
 920 ;; more detailed, but if bash is usually /bin/sh on a GNU system then the
 921 ;; builtins will be what's normally run.
 922 ;;
 923 ;; Maybe special variables like $? should be matched as $?, not just ?.
 924 ;; This would avoid a clash between variable $! and negation !, or variable
 925 ;; $# and comment # (though comment # is not currently indexed in bash).
 926 ;; Unfortunately if $? etc is the symbol, then we wouldn't be taken to the
 927 ;; exact spot in the relevant node, since the bash manual has just `?' etc
 928 ;; there.  Maybe an extension to the prefix/suffix scheme could help this.
 929
 930 (info-lookup-maybe-add-help
 931  :mode 'sh-mode :topic 'symbol
 932  ;; bash has "." and ":" in its index, but those chars will probably never
 933  ;; work in info, so don't bother matching them in the regexp.
 934  :regexp "\\([a-zA-Z0-9_-]+\\|[!{}@*#?$]\\|\\[\\[?\\|]]?\\)"
 935  :doc-spec '(("(bash)Builtin Index"       nil "^`" "[ .']")
 936              ("(bash)Reserved Word Index" nil "^`" "[ .']")
 937              ("(bash)Variable Index"      nil "^`" "[ .']")
 938
 939              ;; coreutils (version 4.5.10) doesn't have a separate program
 940              ;; index, so exclude extraneous stuff (most of it) by demanding
 941              ;; "[a-z]+" in the trans-func.
 942              ;; coreutils version 8.1 has node "Concept Index" and past
 943              ;; versions have node "Index", look for both, whichever is
 944              ;; absent is quietly ignored
 945              ("(coreutils)Index"
 946               (lambda (item) (if (string-match "\\`[a-z]+\\'" item) item)))
 947              ("(coreutils)Concept Index"
 948               (lambda (item) (if (string-match "\\`[a-z]+\\'" item) item)))
 949
 950              ;; diff (version 2.8.1) has only a few programs, index entries
 951              ;; are things like "foo invocation".
 952              ("(diff)Index"
 953               (lambda (item)
 954                 (if (string-match "\\`\\([a-z]+\\) invocation\\'" item)
 955                     (match-string 1 item))))
 956              ;; there's no plain "sed" index entry as such, mung another
 957              ;; hopefully unique one to get to the invocation section
 958              ("(sed)Concept Index"
 959               (lambda (item)
 960                 (if (string-equal item "Standard input, processing as input")
 961                     "sed")))
 962              ;; there's no plain "awk" or "gawk" index entries, mung other
 963              ;; hopefully unique ones to get to the command line options
 964              ("(gawk)Index"
 965               (lambda (item)
 966                 (cond ((string-equal item "gawk, extensions, disabling")
 967                        "awk")
 968                       ((string-equal item "gawk, versions of, information about, printing")
 969                        "gawk"))))))
 970
 971 ;; This misses some things which occur as node names but not in the
 972 ;; index.  Unfortunately it also picks up the wrong one of multiple
 973 ;; entries for the same term in some cases.  --fx
 974 (info-lookup-maybe-add-help
 975  :mode 'cfengine-mode
 976  :regexp "[[:alnum:]_]+\\(?:()\\)?"
 977  :doc-spec '(("(cfengine-Reference)Variable Index"
 978               (lambda (item)
 979                 ;; Index entries may be like `IsPlain()'
 980                 (if (string-match "\\([[:alnum:]_]+\\)()" item)
 981                     (match-string 1 item)
 982                   item))
 983               ;; This gets functions in evaluated classes.  Other
 984               ;; possible patterns don't seem to work too well.
 985               "`" "(")))
 986
 987 (info-lookup-maybe-add-help
 988  :mode 'Custom-mode
 989  :ignore-case t
 990  :regexp "[^][()`',:\" \t\n]+"
 991  :parse-rule 'info-lookup-guess-custom-symbol
 992  :other-modes '(emacs-lisp-mode))
 993
 994 (info-lookup-maybe-add-help
 995  :mode 'help-mode
 996  :regexp "[^][()`',:\" \t\n]+"
 997  :other-modes '(emacs-lisp-mode))
 998 \f
 999 (provide 'info-look)
1000
1001 ;;; info-look.el ends here