lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing
   2
   3 ;; Copyright (C) 1985, 1989, 1994-1995, 1997, 2000-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: Inge Frick <inge@nada.kth.se>
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the `view' minor mode documented in the Emacs
  28 ;; user's manual.
  29 ;; View mode entry and exit is done through the functions view-mode-enter
  30 ;; and view-mode-exit.  Use these functions to enter or exit view-mode from
  31 ;; emacs lisp programs.
  32 ;; We use both view- and View- as prefix for symbols.  View- is used as
  33 ;; prefix for commands that have a key binding.  view- is used for commands
  34 ;; without key binding.  The purpose of this is to make it easier for a
  35 ;; user to use command name completion.
  36
  37 ;;; Suggested key bindings:
  38 ;;
  39 ;; (define-key ctl-x-4-map "v" 'view-file-other-window)  ; ^x4v
  40 ;; (define-key ctl-x-5-map "v" 'view-file-other-frame)  ; ^x5v
  41 ;;
  42 ;; You could also bind view-file, view-buffer, view-buffer-other-window and
  43 ;; view-buffer-other-frame to keys.
  44 \f
  45 ;;; Code:
  46
  47 (defgroup view nil
  48   "Peruse file or buffer without editing."
  49   :link '(function-link view-mode)
  50   :link '(custom-manual "(emacs)Misc File Ops")
  51   :group 'wp)
  52
  53 (defcustom view-highlight-face 'highlight
  54    "The face used for highlighting the match found by View mode search."
  55    :type 'face
  56    :group 'view)
  57
  58 (defcustom view-scroll-auto-exit nil
  59   "Non-nil means scrolling past the end of buffer exits View mode.
  60 A value of nil means attempting to scroll past the end of the buffer,
  61 only rings the bell and gives a message on how to leave."
  62   :type 'boolean
  63   :group 'view)
  64
  65 (defcustom view-try-extend-at-buffer-end nil
  66  "Non-nil means try to load more of file when reaching end of buffer.
  67 This variable is mainly intended to be temporarily set to non-nil by
  68 the F command in view-mode, but you can set it to t if you want the action
  69 for all scroll commands in view mode."
  70   :type 'boolean
  71   :group 'view)
  72
  73 ;;;###autoload
  74 (defcustom view-remove-frame-by-deleting t
  75   "Determine how View mode removes a frame no longer needed.
  76 If nil, make an icon of the frame.  If non-nil, delete the frame."
  77   :type 'boolean
  78   :group 'view
  79   :version "23.1")
  80
  81 (defcustom view-exits-all-viewing-windows nil
  82   "Non-nil means restore all windows used to view buffer.
  83 Commands that restore windows when finished viewing a buffer,
  84 apply to all windows that display the buffer and have restore
  85 information.  If `view-exits-all-viewing-windows' is nil, only
  86 the selected window is considered for restoring."
  87   :type 'boolean
  88   :group 'view)
  89
  90 (defcustom view-inhibit-help-message nil
  91   "Non-nil inhibits the help message shown upon entering View mode."
  92   :type 'boolean
  93   :group 'view
  94   :version "22.1")
  95
  96 ;;;###autoload
  97 (defvar view-mode nil
  98   "Non-nil if View mode is enabled.
  99 Don't change this variable directly, you must change it by one of the
 100 functions that enable or disable view mode.")
 101 ;;;###autoload
 102 (make-variable-buffer-local 'view-mode)
 103
 104 (defcustom view-mode-hook nil
 105   "Normal hook run when starting to view a buffer or file."
 106   :type 'hook
 107   :group 'view)
 108 \f
 109 (defvar view-old-buffer-read-only nil)
 110 (make-variable-buffer-local 'view-old-buffer-read-only)
 111
 112 (defvar view-old-Helper-return-blurb)
 113 (make-variable-buffer-local 'view-old-Helper-return-blurb)
 114
 115 (defvar view-page-size nil
 116   "Default number of lines to scroll by View page commands.
 117 If nil that means use the window size.")
 118 (make-variable-buffer-local 'view-page-size)
 119
 120 (defvar view-half-page-size nil
 121   "Default number of lines to scroll by View half page commands.
 122 If nil that means use half the window size.")
 123 (make-variable-buffer-local 'view-half-page-size)
 124
 125 (defvar view-last-regexp nil)
 126 (make-variable-buffer-local 'view-last-regexp) ; Global is better???
 127
 128 (defvar view-return-to-alist nil
 129   "What to do with used windows and where to go when finished viewing buffer.
 130 This is local in each buffer being viewed.
 131 It is added to by `view-mode-enter' when starting to view a buffer and
 132 subtracted from by `view-mode-exit' when finished viewing the buffer.
 133
 134 See RETURN-TO-ALIST argument of function `view-mode-exit' for the format of
 135 `view-return-to-alist'.")
 136 (make-obsolete-variable
 137  'view-return-to-alist "this variable is no more used." "24.1")
 138 (make-variable-buffer-local 'view-return-to-alist)
 139 (put 'view-return-to-alist 'permanent-local t)
 140
 141 (defvar view-exit-action nil
 142   "If non-nil, a function with one argument (a buffer) called when finished viewing.
 143 Commands like \\[view-file] and \\[view-file-other-window] may
 144 set this to bury or kill the viewed buffer.
 145 Observe that the buffer viewed might not appear in any window at
 146 the time this function is called.")
 147 (make-variable-buffer-local 'view-exit-action)
 148
 149 (defvar view-no-disable-on-exit nil
 150   "If non-nil, View mode \"exit\" commands don't actually disable View mode.
 151 Instead, these commands just switch buffers or windows.
 152 This is set in certain buffers by specialized features such as help commands
 153 that use View mode automatically.")
 154
 155 (defvar view-overlay nil
 156   "Overlay used to display where a search operation found its match.
 157 This is local in each buffer, once it is used.")
 158 (make-variable-buffer-local 'view-overlay)
 159 \f
 160 ;; Define keymap inside defvar to make it easier to load changes.
 161 ;; Some redundant "less"-like key bindings below have been commented out.
 162 (defvar view-mode-map
 163   (let ((map (make-sparse-keymap)))
 164     (define-key map "C" 'View-kill-and-leave)
 165     (define-key map "c" 'View-leave)
 166     (define-key map "Q" 'View-quit-all)
 167     (define-key map "E" 'View-exit-and-edit)
 168     ;; (define-key map "v" 'View-exit)
 169     (define-key map "e" 'View-exit)
 170     (define-key map "q" 'View-quit)
 171     ;; (define-key map "N" 'View-search-last-regexp-backward)
 172     (define-key map "p" 'View-search-last-regexp-backward)
 173     (define-key map "n" 'View-search-last-regexp-forward)
 174     ;; (define-key map "?" 'View-search-regexp-backward) ; Less does this.
 175     (define-key map "\\" 'View-search-regexp-backward)
 176     (define-key map "/" 'View-search-regexp-forward)
 177     (define-key map "r" 'isearch-backward)
 178     (define-key map "s" 'isearch-forward)
 179     (define-key map "m" 'point-to-register)
 180     (define-key map "'" 'register-to-point)
 181     (define-key map "x" 'exchange-point-and-mark)
 182     (define-key map "@" 'View-back-to-mark)
 183     (define-key map "." 'set-mark-command)
 184     (define-key map "%" 'View-goto-percent)
 185     ;; (define-key map "G" 'View-goto-line-last)
 186     (define-key map "g" 'View-goto-line)
 187     (define-key map "=" 'what-line)
 188     (define-key map "F" 'View-revert-buffer-scroll-page-forward)
 189     ;; (define-key map "k" 'View-scroll-line-backward)
 190     (define-key map "y" 'View-scroll-line-backward)
 191     ;; (define-key map "j" 'View-scroll-line-forward)
 192     (define-key map "\n" 'View-scroll-line-forward)
 193     (define-key map "\r" 'View-scroll-line-forward)
 194     (define-key map "u" 'View-scroll-half-page-backward)
 195     (define-key map "d" 'View-scroll-half-page-forward)
 196     (define-key map "z" 'View-scroll-page-forward-set-page-size)
 197     (define-key map "w" 'View-scroll-page-backward-set-page-size)
 198     ;; (define-key map "b" 'View-scroll-page-backward)
 199     (define-key map "\C-?" 'View-scroll-page-backward)
 200     ;; (define-key map "f" 'View-scroll-page-forward)
 201     (define-key map " " 'View-scroll-page-forward)
 202     (define-key map "o" 'View-scroll-to-buffer-end)
 203     (define-key map ">" 'end-of-buffer)
 204     (define-key map "<" 'beginning-of-buffer)
 205     (define-key map "-" 'negative-argument)
 206     (define-key map "9" 'digit-argument)
 207     (define-key map "8" 'digit-argument)
 208     (define-key map "7" 'digit-argument)
 209     (define-key map "6" 'digit-argument)
 210     (define-key map "5" 'digit-argument)
 211     (define-key map "4" 'digit-argument)
 212     (define-key map "3" 'digit-argument)
 213     (define-key map "2" 'digit-argument)
 214     (define-key map "1" 'digit-argument)
 215     (define-key map "0" 'digit-argument)
 216     (define-key map "H" 'describe-mode)
 217     (define-key map "?" 'describe-mode) ; Maybe do as less instead? See above.
 218     (define-key map "h" 'describe-mode)
 219     map))
 220 \f
 221 ;;; Commands that enter or exit view mode.
 222
 223 ;; This is used when view mode is exited, to make sure we don't try to
 224 ;; kill a buffer modified by the user.  A buffer in view mode can
 225 ;; become modified if the user types C-x C-q, edits the buffer, then
 226 ;; types C-x C-q again to return to view mode.
 227 ;;;###autoload
 228 (defun kill-buffer-if-not-modified (buf)
 229   "Like `kill-buffer', but does nothing if the buffer is modified."
 230   (let ((buf (get-buffer buf)))
 231     (and buf (not (buffer-modified-p buf))
 232          (kill-buffer buf))))
 233
 234 ;;;###autoload
 235 (defun view-file (file)
 236   "View FILE in View mode, returning to previous buffer when done.
 237 Emacs commands editing the buffer contents are not available; instead, a
 238 special set of commands (mostly letters and punctuation) are defined for
 239 moving around in the buffer.
 240 Space scrolls forward, Delete scrolls backward.
 241 For a list of all View commands, type H or h while viewing.
 242
 243 This command runs the normal hook `view-mode-hook'."
 244   (interactive "fView file: ")
 245   (unless (file-exists-p file) (error "%s does not exist" file))
 246   (let ((had-a-buf (get-file-buffer file))
 247         (buffer (find-file-noselect file)))
 248     (view-buffer buffer (and (not had-a-buf) 'kill-buffer-if-not-modified))))
 249
 250 ;;;###autoload
 251 (defun view-file-other-window (file)
 252   "View FILE in View mode in another window.
 253 When done, return that window to its previous buffer, and kill the
 254 buffer visiting FILE if unmodified and if it wasn't visited before.
 255
 256 Emacs commands editing the buffer contents are not available; instead,
 257 a special set of commands (mostly letters and punctuation)
 258 are defined for moving around in the buffer.
 259 Space scrolls forward, Delete scrolls backward.
 260 For a list of all View commands, type H or h while viewing.
 261
 262 This command runs the normal hook `view-mode-hook'."
 263   (interactive "fIn other window view file: ")
 264   (unless (file-exists-p file) (error "%s does not exist" file))
 265   (let ((had-a-buf (get-file-buffer file))
 266         (buf-to-view (find-file-noselect file)))
 267     (view-buffer-other-window buf-to-view nil
 268                               (and (not had-a-buf)
 269                                    'kill-buffer-if-not-modified))))
 270
 271 ;;;###autoload
 272 (defun view-file-other-frame (file)
 273   "View FILE in View mode in another frame.
 274 When done, kill the buffer visiting FILE if unmodified and if it wasn't
 275 visited before; also, maybe delete other frame and/or return to previous
 276 buffer.
 277
 278 Emacs commands editing the buffer contents are not available; instead,
 279 a special set of commands (mostly letters and punctuation)
 280 are defined for moving around in the buffer.
 281 Space scrolls forward, Delete scrolls backward.
 282 For a list of all View commands, type H or h while viewing.
 283
 284 This command runs the normal hook `view-mode-hook'."
 285   (interactive "fIn other frame view file: ")
 286   (unless (file-exists-p file) (error "%s does not exist" file))
 287   (let ((had-a-buf (get-file-buffer file))
 288         (buf-to-view (find-file-noselect file)))
 289     (view-buffer-other-frame buf-to-view nil
 290                              (and (not had-a-buf)
 291                                   'kill-buffer-if-not-modified))))
 292
 293
 294 ;;;###autoload
 295 (defun view-buffer (buffer &optional exit-action)
 296   "View BUFFER in View mode, returning to previous buffer when done.
 297 Emacs commands editing the buffer contents are not available; instead, a
 298 special set of commands (mostly letters and punctuation) are defined for
 299 moving around in the buffer.
 300 Space scrolls forward, Delete scrolls backward.
 301 For a list of all View commands, type H or h while viewing.
 302
 303 This command runs the normal hook `view-mode-hook'.
 304
 305 Optional argument EXIT-ACTION is either nil or a function with buffer as
 306 argument.  This function is called when finished viewing buffer.  Use
 307 this argument instead of explicitly setting `view-exit-action'.
 308
 309 Do not set EXIT-ACTION to `kill-buffer' when BUFFER visits a
 310 file: Users may suspend viewing in order to modify the buffer.
 311 Exiting View mode will then discard the user's edits.  Setting
 312 EXIT-ACTION to `kill-buffer-if-not-modified' avoids this."
 313   (interactive "bView buffer: ")
 314   (if (with-current-buffer buffer
 315         (and (eq (get major-mode 'mode-class)
 316                  'special)
 317              (null buffer-file-name)))
 318       (progn
 319         (switch-to-buffer buffer)
 320         (message "Not using View mode because the major mode is special"))
 321     (switch-to-buffer buffer)
 322     (view-mode-enter nil exit-action)))
 323
 324 ;;;###autoload
 325 (defun view-buffer-other-window (buffer &optional not-return exit-action)
 326   "View BUFFER in View mode in another window.
 327 Emacs commands editing the buffer contents are not available;
 328 instead, a special set of commands (mostly letters and
 329 punctuation) are defined for moving around in the buffer.
 330 Space scrolls forward, Delete scrolls backward.
 331 For a list of all View commands, type H or h while viewing.
 332
 333 This command runs the normal hook `view-mode-hook'.
 334
 335 Optional argument NOT-RETURN is ignored.
 336
 337 Optional argument EXIT-ACTION is either nil or a function with buffer as
 338 argument.  This function is called when finished viewing buffer.  Use
 339 this argument instead of explicitly setting `view-exit-action'."
 340   (interactive "bIn other window view buffer:\nP")
 341   (let ((pop-up-windows t))
 342     (pop-to-buffer buffer t))
 343   (view-mode-enter nil exit-action))
 344
 345 ;;;###autoload
 346 (defun view-buffer-other-frame (buffer &optional not-return exit-action)
 347   "View BUFFER in View mode in another frame.
 348 Emacs commands editing the buffer contents are not available;
 349 instead, a special set of commands (mostly letters and
 350 punctuation) are defined for moving around in the buffer.
 351 Space scrolls forward, Delete scrolls backward.
 352 For a list of all View commands, type H or h while viewing.
 353
 354 This command runs the normal hook `view-mode-hook'.
 355
 356 Optional argument NOT-RETURN is ignored.
 357
 358 Optional argument EXIT-ACTION is either nil or a function with buffer as
 359 argument.  This function is called when finished viewing buffer.  Use
 360 this argument instead of explicitly setting `view-exit-action'."
 361   (interactive "bView buffer in other frame: \nP")
 362   (let ((pop-up-frames t))
 363     (pop-to-buffer buffer t))
 364   (view-mode-enter nil exit-action))
 365 \f
 366 ;;;###autoload
 367 (define-minor-mode view-mode
 368   ;; In the following documentation string we have to use some explicit key
 369   ;; bindings instead of using the \\[] construction.  The reason for this
 370   ;; is that most commands have more than one key binding.
 371   "Toggle View mode, a minor mode for viewing text but not editing it.
 372 With prefix argument ARG, turn View mode on if ARG is positive, otherwise
 373 turn it off.
 374
 375 Emacs commands that do not change the buffer contents are available as usual.
 376 Kill commands insert text in kill buffers but do not delete.  Other commands
 377 \(among them most letters and punctuation) beep and tell that the buffer is
 378 read-only.
 379 \\<view-mode-map>
 380 The following additional commands are provided.  Most commands take prefix
 381 arguments.  Page commands default to \"page size\" lines which is almost a whole
 382 window full, or number of lines set by \\[View-scroll-page-forward-set-page-size] or \\[View-scroll-page-backward-set-page-size].  Half page commands default to
 383 and set \"half page size\" lines which initially is half a window full.  Search
 384 commands default to a repeat count of one.
 385
 386 H, h, ?  This message.
 387 Digits  provide prefix arguments.
 388 \\[negative-argument]   negative prefix argument.
 389 \\[beginning-of-buffer] move to the beginning of buffer.
 390 >       move to the end of buffer.
 391 \\[View-scroll-to-buffer-end]   scroll so that buffer end is at last line of window.
 392 SPC     scroll forward \"page size\" lines.
 393           With prefix scroll forward prefix lines.
 394 DEL     scroll backward \"page size\" lines.
 395           With prefix scroll backward prefix lines.
 396 \\[View-scroll-page-forward-set-page-size]      like  \\[View-scroll-page-forward]  but with prefix sets \"page size\" to prefix.
 397 \\[View-scroll-page-backward-set-page-size]     like  \\[View-scroll-page-backward]  but with prefix sets \"page size\" to prefix.
 398 \\[View-scroll-half-page-forward]       scroll forward \"half page size\" lines.  With prefix, sets
 399           \"half page size\" to prefix lines and scrolls forward that much.
 400 \\[View-scroll-half-page-backward]      scroll backward \"half page size\" lines.  With prefix, sets
 401           \"half page size\" to prefix lines and scrolls backward that much.
 402 RET, LFD  scroll forward one line.  With prefix scroll forward prefix line(s).
 403 y       scroll backward one line.  With prefix scroll backward prefix line(s).
 404 \\[View-revert-buffer-scroll-page-forward]      revert-buffer if necessary and scroll forward.
 405           Use this to view a changing file.
 406 \\[what-line]   prints the current line number.
 407 \\[View-goto-percent]   goes prefix argument (default 100) percent into buffer.
 408 \\[View-goto-line]      goes to line given by prefix argument (default first line).
 409 .       set the mark.
 410 x       exchanges point and mark.
 411 \\[View-back-to-mark]   return to mark and pops mark ring.
 412           Mark ring is pushed at start of every successful search and when
 413           jump to line occurs.  The mark is set on jump to buffer start or end.
 414 \\[point-to-register]   save current position in character register.
 415 '       go to position saved in character register.
 416 s       do forward incremental search.
 417 r       do reverse incremental search.
 418 \\[View-search-regexp-forward]  searches forward for regular expression, starting after current page.
 419           ! and @ have a special meaning at the beginning of the regexp.
 420           ! means search for a line with no match for regexp.  @ means start
 421           search at beginning (end for backward search) of buffer.
 422 \\      searches backward for regular expression, starting before current page.
 423 \\[View-search-last-regexp-forward]     searches forward for last regular expression.
 424 p       searches backward for last regular expression.
 425 \\[View-quit]   quit View mode, restoring this window and buffer to previous state.
 426           \\[View-quit] is the normal way to leave view mode.
 427 \\[View-exit]   exit View mode but stay in current buffer.  Use this if you started
 428           viewing a buffer (file) and find out you want to edit it.
 429           This command restores the previous read-only status of the buffer.
 430 \\[View-exit-and-edit]  exit View mode, and make the current buffer editable
 431           even if it was not editable before entry to View mode.
 432 \\[View-quit-all]       quit View mode, restoring all windows to previous state.
 433 \\[View-leave]  quit View mode and maybe switch buffers, but don't kill this buffer.
 434 \\[View-kill-and-leave] quit View mode, kill current buffer and go back to other buffer.
 435
 436 The effect of \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] depends on how view-mode was entered.  If it was
 437 entered by view-file, view-file-other-window, view-file-other-frame, or
 438 \\[dired-view-file] \(\\[view-file], \\[view-file-other-window],
 439 \\[view-file-other-frame], or the Dired mode v command),
 440 then \\[View-quit] will try to kill the current buffer.
 441 If view-mode was entered from another buffer, by \\[view-buffer],
 442 \\[view-buffer-other-window], \\[view-buffer-other frame], \\[view-file],
 443 \\[view-file-other-window], or \\[view-file-other-frame],
 444 then \\[View-leave], \\[View-quit] and \\[View-kill-and-leave] will return to that buffer.
 445
 446 Entry to view-mode runs the normal hook `view-mode-hook'."
 447   :lighter " View" :keymap view-mode-map
 448   (if view-mode (view-mode-enable) (view-mode-disable)))
 449 \f
 450 (defun view-mode-enable ()
 451   "Turn on View mode."
 452   ;; Always leave view mode before changing major mode.
 453   ;; This is to guarantee that the buffer-read-only variable is restored.
 454   (add-hook 'change-major-mode-hook 'view-mode-disable nil t)
 455   (setq view-mode t
 456         view-page-size nil
 457         view-half-page-size nil
 458         view-old-buffer-read-only buffer-read-only
 459         buffer-read-only t)
 460   (if (boundp 'Helper-return-blurb)
 461       (setq view-old-Helper-return-blurb (and (boundp 'Helper-return-blurb)
 462                                               Helper-return-blurb)
 463             Helper-return-blurb
 464             (format "continue viewing %s"
 465                     (if (buffer-file-name)
 466                         (file-name-nondirectory (buffer-file-name))
 467                       (buffer-name)))))
 468   (force-mode-line-update)
 469   (run-hooks 'view-mode-hook))
 470
 471 (defun view-mode-disable ()
 472   "Turn off View mode."
 473   (remove-hook 'change-major-mode-hook 'view-mode-disable t)
 474   (and view-overlay (delete-overlay view-overlay))
 475   (force-mode-line-update)
 476   ;; Calling toggle-read-only while View mode is enabled
 477   ;; sets view-read-only to t as a buffer-local variable
 478   ;; after exiting View mode.  That arranges that the next toggle-read-only
 479   ;; will reenable View mode.
 480   ;; Cancelling View mode in any other way should cancel that, too,
 481   ;; so that View mode stays off if toggle-read-only is called.
 482   (if (local-variable-p 'view-read-only)
 483       (kill-local-variable 'view-read-only))
 484   (setq view-mode nil)
 485   (if (boundp 'Helper-return-blurb)
 486       (setq Helper-return-blurb view-old-Helper-return-blurb))
 487   (if buffer-read-only
 488       (setq buffer-read-only view-old-buffer-read-only)))
 489
 490 ;;;###autoload
 491 (defun view-return-to-alist-update (buffer &optional item)
 492   "Update `view-return-to-alist' of buffer BUFFER.
 493 Remove from `view-return-to-alist' all entries referencing dead
 494 windows.  Optional argument ITEM non-nil means add ITEM to
 495 `view-return-to-alist' after purging.  For a decsription of items
 496 that can be added see the RETURN-TO-ALIST argument of the
 497 function `view-mode-exit'.  If `view-return-to-alist' contains an
 498 entry for the selected window, purge that entry from
 499 `view-return-to-alist' before adding ITEM."
 500   (with-current-buffer buffer
 501     (when view-return-to-alist
 502       (let* ((list view-return-to-alist)
 503              entry entry-window last)
 504         (while list
 505           (setq entry (car list))
 506           (setq entry-window (car entry))
 507           (if (and (windowp entry-window)
 508                    (or (and item (eq entry-window (selected-window)))
 509                        (not (window-live-p entry-window))))
 510               ;; Remove that entry.
 511               (if last
 512                   (setcdr last (cdr list))
 513                 (setq view-return-to-alist
 514                       (cdr view-return-to-alist)))
 515             ;; Leave entry alone.
 516             (setq last entry))
 517           (setq list (cdr list)))))
 518     ;; Add ITEM.
 519     (when item
 520       (setq view-return-to-alist
 521             (cons item view-return-to-alist)))))
 522 (make-obsolete 'view-return-to-alist-update "this function has no effect." "24.1")
 523
 524 ;;;###autoload
 525 (defun view-mode-enter (&optional quit-restore exit-action)
 526   "Enter View mode and set up exit from view mode depending on optional arguments.
 527 Optional argument QUIT-RESTORE if non-nil must specify a valid
 528 entry for quitting and restoring any window showing the current
 529 buffer.  This entry replaces any parameter installed by
 530 `display-buffer' and is used by `view-mode-exit'.
 531
 532 Optional argument EXIT-ACTION, if non-nil, must specify a
 533 function that takes a buffer as argument.  This function will be
 534 called by `view-mode-exit'.
 535
 536 For a list of all View commands, type H or h while viewing.
 537
 538 This function runs the normal hook `view-mode-hook'."
 539   (when quit-restore
 540     (dolist (window (get-buffer-window-list nil nil t))
 541       (set-window-parameter window 'quit-restore quit-restore)))
 542
 543   (when exit-action
 544     (setq view-exit-action exit-action))
 545
 546   (unless view-mode
 547     (view-mode-enable)
 548     (force-mode-line-update)
 549     (unless view-inhibit-help-message
 550       (message "%s"
 551                (substitute-command-keys "\
 552 View mode: type \\[help-command] for help, \\[describe-mode] for commands, \\[View-quit] to quit.")))))
 553 \f
 554 ;; This is awful because it assumes that the selected window shows the
 555 ;; current buffer when this is called.
 556 (defun view-mode-exit (&optional exit-only exit-action all-windows)
 557   "Exit View mode in various ways.
 558 If all arguments are nil, remove the current buffer from the
 559 selected window using the `quit-restore' information associated
 560 with the selected window.  If optional argument ALL-WINDOWS or
 561 `view-exits-all-viewing-windows' are non-nil, remove the current
 562 buffer from all windows showing it.
 563
 564 Optional argument EXIT-ONLY non-nil means just exit `view-mode'
 565 \(unless `view-no-disable-on-exit' is non-nil) but do not change
 566 the associations of any windows with the current buffer.
 567
 568 EXIT-ACTION, if non-nil, must specify a function that is called
 569 with the current buffer as argument and is called after disabling
 570 `view-mode' and removing any associations of windows with the
 571 current buffer. "
 572   (when view-mode
 573     (let ((buffer (window-buffer)))
 574       (unless view-no-disable-on-exit
 575         (view-mode-disable))
 576
 577       (unless exit-only
 578         (cond
 579          ((or all-windows view-exits-all-viewing-windows)
 580           (dolist (window (get-buffer-window-list))
 581             (quit-window nil window)))
 582          ((eq (window-buffer) (current-buffer))
 583           (quit-window)))
 584
 585         (when exit-action
 586           (funcall exit-action buffer))
 587         (force-mode-line-update)))))
 588 \f
 589 (defun View-exit ()
 590   "Exit View mode but stay in current buffer."
 591   (interactive)
 592   (view-mode-exit t))
 593
 594 ;;;###autoload
 595 (defun View-exit-and-edit ()
 596   "Exit View mode and make the current buffer editable."
 597   (interactive)
 598   (let ((view-old-buffer-read-only nil)
 599         (view-no-disable-on-exit nil))
 600     (view-mode-exit t)))
 601
 602 (defun View-leave ()
 603   "Quit View mode and maybe switch buffers, but don't kill this buffer."
 604   (interactive)
 605   (view-mode-exit))
 606
 607 (defun View-quit ()
 608   "Quit View mode, trying to restore window and buffer to previous state.
 609 Maybe kill this buffer.  Try to restore selected window to previous state
 610 and go to previous buffer or window."
 611   (interactive)
 612   (view-mode-exit nil view-exit-action))
 613
 614 (defun View-quit-all ()
 615   "Quit View mode, trying to restore windows and buffers to previous state.
 616 Maybe kill current buffer.  Try to restore all windows viewing buffer to
 617 previous state and go to previous buffer or window."
 618   (interactive)
 619   (view-mode-exit nil view-exit-action t))
 620
 621 (defun View-kill-and-leave ()
 622   "Quit View mode, kill current buffer and return to previous buffer."
 623   (interactive)
 624   (view-mode-exit nil (or view-exit-action 'kill-buffer) t))
 625 \f
 626
 627 ;;; Some help routines.
 628
 629 (defun view-window-size ()
 630   ;; Return the height of the current window, excluding the mode line.
 631   ;; Using `window-line-height' accounts for variable-height fonts.
 632   (let ((h (window-line-height -1)))
 633     (if h
 634         (1+ (nth 1 h))
 635       ;; This should not happen, but if `window-line-height' returns
 636       ;; nil, fall back on `window-height'.
 637       (1- (window-height)))))
 638
 639 ;; (defun view-last-command (&optional who what)
 640 ;;  (setq view-last-command-entry this-command)
 641 ;;  (setq view-last-command who)
 642 ;;  (setq view-last-command-argument what))
 643
 644 ;; (defun View-repeat-last-command ()
 645 ;;  "Repeat last command issued in View mode."
 646 ;;  (interactive)
 647 ;;  (if (and view-last-command
 648 ;;         (eq view-last-command-entry last-command))
 649 ;;      (funcall view-last-command view-last-command-argument))
 650 ;;  (setq this-command view-last-command-entry))
 651
 652 (defun view-recenter ()
 653   ;; Recenter point in window and redisplay normally.
 654   (recenter '(1)))
 655
 656 (defun view-page-size-default (lines)
 657   ;; If LINES is nil, 0, or larger than `view-window-size', return nil.
 658   ;; Otherwise, return LINES.
 659   (and lines
 660        (not (zerop (setq lines (prefix-numeric-value lines))))
 661        (<= (abs lines)
 662            (abs (- (view-window-size) next-screen-context-lines)))
 663        (abs lines)))
 664
 665 (defun view-set-half-page-size-default (lines)
 666   ;; Get and maybe set half page size.
 667   (if (not lines) (or view-half-page-size
 668                       (/ (view-window-size) 2))
 669     (setq view-half-page-size
 670           (if (zerop (setq lines (prefix-numeric-value lines)))
 671               (/ (view-window-size) 2)
 672             (view-page-size-default lines)))))
 673
 674
 675 ;;; Commands for moving around in the buffer.
 676
 677 (defun View-goto-percent (&optional percent)
 678   "Move to end (or prefix PERCENT) of buffer in View mode.
 679 Display is centered at point.
 680 Also set the mark at the position where point was."
 681   (interactive "P")
 682   (push-mark)
 683   (goto-char
 684    (if percent
 685        (+ (point-min)
 686           (floor (* (- (point-max) (point-min)) 0.01
 687                     (max 0 (min 100 (prefix-numeric-value percent))))))
 688      (point-max)))
 689   (view-recenter))
 690
 691 ;; (defun View-goto-line-last (&optional line)
 692 ;; "Move to last (or prefix LINE) line in View mode.
 693 ;; Display is centered at LINE.
 694 ;; Sets mark at starting position and pushes mark ring."
 695 ;;  (interactive "P")
 696 ;;  (push-mark)
 697 ;;  (if line (goto-line (prefix-numeric-value line))
 698 ;;    (goto-char (point-max))
 699 ;;    (beginning-of-line))
 700 ;;  (view-recenter))
 701
 702 (defun View-goto-line (&optional line)
 703   "Move to first (or prefix LINE) line in View mode.
 704 Display is centered at LINE.
 705 Also set the mark at the position where point was."
 706   (interactive "p")
 707   (push-mark)
 708   (goto-char (point-min))
 709   (forward-line (1- line))
 710   (view-recenter))
 711
 712 (defun View-back-to-mark (&optional _ignore)
 713   "Return to last mark set in View mode, else beginning of file.
 714 Display that line at the center of the window.
 715 This command pops the mark ring, so that successive
 716 invocations return to earlier marks."
 717   (interactive)
 718   (goto-char (or (mark t) (point-min)))
 719   (pop-mark)
 720   (view-recenter))
 721 \f
 722 (defun view-scroll-lines (lines backward default maxdefault)
 723   ;; This function does the job for all the scrolling commands.
 724   ;; Scroll forward LINES lines.  If BACKWARD is non-nil, scroll backwards.
 725   ;; If LINES is negative scroll in the other direction.
 726   ;; If LINES is 0 or nil, scroll DEFAULT lines (if DEFAULT is nil, scroll
 727   ;; by one page).  If MAXDEFAULT is non-nil, scroll no more than a window.
 728   (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 729       (setq lines default))
 730   (when (and lines (< lines 0))
 731     (setq backward (not backward) lines (- lines)))
 732   (when (and maxdefault lines (> lines (view-window-size)))
 733     (setq lines nil))
 734   (cond (backward (scroll-down lines))
 735         ((view-really-at-end)
 736          (if view-scroll-auto-exit
 737              (View-quit)
 738            (ding)
 739            (view-end-message)))
 740         (t (scroll-up lines)
 741            (if (view-really-at-end) (view-end-message)))))
 742
 743 (defun view-really-at-end ()
 744   ;; Return true if buffer end visible.  Maybe revert buffer and test.
 745   (and (pos-visible-in-window-p (point-max))
 746        (let ((buf (current-buffer))
 747              (bufname (buffer-name))
 748              (file (buffer-file-name)))
 749          (or (not view-try-extend-at-buffer-end)
 750              (null file)
 751              (verify-visited-file-modtime buf)
 752              (not (file-exists-p file))
 753              (when (buffer-modified-p buf)
 754                (setq file (file-name-nondirectory file))
 755                (not (yes-or-no-p
 756                      (format
 757                       "File %s changed on disk.  Discard your edits%s? "
 758                       file
 759                       (if (string= bufname file) ""
 760                         (concat " in " bufname))))))
 761              (progn
 762                (revert-buffer t t t)
 763                (pos-visible-in-window-p (point-max)))))))
 764
 765 (defun view-end-message ()
 766   ;; Tell that we are at end of buffer.
 767   (goto-char (point-max))
 768   (if (window-parameter nil 'quit-restore)
 769       (message "End of buffer.  Type %s to quit viewing."
 770                (substitute-command-keys
 771                 (if view-scroll-auto-exit "\\[View-scroll-page-forward]"
 772                   "\\[View-quit]")))
 773     (message "End of buffer")))
 774 \f
 775 (defun View-scroll-to-buffer-end ()
 776   "Scroll backward or forward so that buffer end is at last line of window."
 777   (interactive)
 778   (let ((p (if (pos-visible-in-window-p (point-max)) (point))))
 779     (goto-char (point-max))
 780     (recenter -1)
 781     (and p (goto-char p))))
 782
 783 (defun View-scroll-page-forward (&optional lines)
 784   "Scroll \"page size\" or prefix LINES lines forward in View mode.
 785 Exit if end of text is visible and `view-scroll-auto-exit' is non-nil.
 786 \"page size\" is whole window full, or number of lines set by
 787 \\[View-scroll-page-forward-set-page-size] or
 788 \\[View-scroll-page-backward-set-page-size].
 789 If LINES is more than a window-full, only the last window-full is shown."
 790   (interactive "P")
 791   (view-scroll-lines lines nil (view-page-size-default view-page-size) nil))
 792
 793 (defun View-scroll-page-backward (&optional lines)
 794   "Scroll \"page size\" or prefix LINES lines backward in View mode.
 795 See also `View-scroll-page-forward'."
 796   (interactive "P")
 797   (view-scroll-lines lines t (view-page-size-default view-page-size) nil))
 798
 799 (defun View-scroll-page-forward-set-page-size (&optional lines)
 800   "Scroll forward LINES lines in View mode, setting the \"page size\".
 801 This is the number of lines which \\[View-scroll-page-forward] and
 802 \\[View-scroll-page-backward] scroll by default.
 803 If LINES is omitted or = 0, sets \"page size\" to window height and
 804 scrolls forward that much, otherwise scrolls forward LINES lines and sets
 805 \"page size\" to the minimum of window height and the absolute value of LINES.
 806 See also `View-scroll-page-forward'."
 807   (interactive "P")
 808   (view-scroll-lines lines nil
 809                      (setq view-page-size (view-page-size-default lines))
 810                      nil))
 811
 812 (defun View-scroll-page-backward-set-page-size (&optional lines)
 813   "Scroll backward prefix LINES lines in View mode, setting the \"page size\".
 814 See also `View-scroll-page-forward-set-page-size'."
 815   (interactive "P")
 816   (view-scroll-lines lines t
 817                      (setq view-page-size (view-page-size-default lines))
 818                      nil))
 819
 820 (defun View-scroll-line-forward (&optional lines)
 821   "Scroll forward one line (or prefix LINES lines) in View mode.
 822 See also `View-scroll-page-forward', but note that scrolling is limited
 823 to minimum of LINES and one window-full."
 824   (interactive "P")
 825   (view-scroll-lines lines nil 1 t))
 826
 827 (defun View-scroll-line-backward (&optional lines)
 828   "Scroll backward one line (or prefix LINES lines) in View mode.
 829 See also `View-scroll-line-forward'."
 830   (interactive "P")
 831   (view-scroll-lines lines t 1 t))
 832
 833 (defun View-scroll-half-page-forward (&optional lines)
 834   "Scroll forward a \"half page\" (or prefix LINES) lines in View mode.
 835 If LINES is not omitted, the \"half page size\" is set to the minimum of
 836 window height and the absolute value of LINES.
 837 LINES=0 resets \"half page size\" to half window height."
 838   (interactive "P")
 839   (view-scroll-lines lines nil (view-set-half-page-size-default lines) t))
 840
 841 (defun View-scroll-half-page-backward (&optional lines)
 842   "Scroll backward a \"half page\" (or prefix LINES) lines in View mode.
 843 See also `View-scroll-half-page-forward'."
 844   (interactive "P")
 845   (view-scroll-lines lines t (view-set-half-page-size-default lines) t))
 846
 847 (defun View-revert-buffer-scroll-page-forward (&optional lines)
 848   "Scroll forward, reverting buffer if needed, in View mode.
 849 If buffer has not been changed and the corresponding file is newer, first
 850 revert the buffer, then scroll.
 851 This command is useful if you are viewing a changing file.
 852
 853 The prefix argument LINES says how many lines to scroll.
 854 If you don't specify a prefix argument, it uses the number of lines set by
 855 \\[View-scroll-page-forward-set-page-size] or
 856 \\[View-scroll-page-backward-set-page-size].
 857 If LINES is more than a window-full, only the last window-full is shown."
 858   (interactive "P")
 859   (let ((view-scroll-auto-exit nil)
 860         (view-try-extend-at-buffer-end t))
 861     (view-scroll-lines lines nil (view-page-size-default view-page-size) nil)))
 862 \f
 863 (defun View-search-regexp-forward (n regexp)
 864   "Search forward for first (or prefix Nth) occurrence of REGEXP in View mode.
 865
 866 Displays line found at center of window.  Sets mark at starting position and
 867 pushes mark ring.
 868
 869 Characters @ and ! are special at the beginning of REGEXP.  They modify
 870 the search rather than become part of the pattern searched for.
 871 @ means search all the buffer i.e. start search at the beginning of buffer.
 872 ! means search for a line that contains no match for the pattern.
 873 If REGEXP is empty or only consist of these control characters, then
 874 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 875 for use by later search commands.
 876
 877 The variable `view-highlight-face' controls the face that is used
 878 for highlighting the match that is found."
 879   (interactive "p\nsSearch forward (regexp): ")
 880   (view-search n regexp))
 881
 882 (defun View-search-regexp-backward (n regexp)
 883   "Search backward for first (or prefix Nth) occurrence of REGEXP in View mode.
 884
 885 Displays line found at center of window.  Sets mark at starting position and
 886 pushes mark ring.
 887
 888 Characters @ and ! are special at the beginning of REGEXP.  They modify
 889 the search rather than become part of the pattern searched for.
 890 @ means search all the buffer i.e. start search at the end of buffer.
 891 ! means search for a line that contains no match for the pattern.
 892 If REGEXP is empty or only consist of these control characters, then
 893 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 894 for use by later search commands.
 895
 896 The variable `view-highlight-face' controls the face that is used
 897 for highlighting the match that is found."
 898   (interactive "p\nsSearch backward (regexp): ")
 899   (view-search (- n) regexp))
 900
 901 (defun View-search-last-regexp-forward (n) "\
 902 Search forward for first (or prefix Nth) instance of last regexp in View mode.
 903 Displays line found at center of window.  Sets mark at starting position and
 904 pushes mark ring.
 905
 906 The variable `view-highlight-face' controls the face that is used
 907 for highlighting the match that is found."
 908   (interactive "p")
 909   (view-search n nil))
 910
 911 (defun View-search-last-regexp-backward (n) "\
 912 Search backward for first (or prefix Nth) instance of last regexp in View mode.
 913 Displays line found at center of window.  Sets mark at starting position and
 914 pushes mark ring.
 915
 916 The variable `view-highlight-face' controls the face that is used
 917 for highlighting the match that is found."
 918   (interactive "p")
 919   (view-search (- n) nil))
 920
 921 (defun view-search (times regexp)
 922   ;; This function does the job for all the View-search- commands.
 923   ;; Search for the TIMESt match for REGEXP.  If TIMES is negative
 924   ;; search backwards.  If REGEXP is nil use `view-last-regexp'.
 925   ;; Characters "!" and "@" have a special meaning at the beginning of
 926   ;; REGEXP and are removed from REGEXP before the search "!" means
 927   ;; search for lines with no match for REGEXP.  "@" means search in
 928   ;; the whole buffer, don't start searching from the present point.
 929   (let (where no end ln)
 930     (cond
 931      ((and regexp (> (length regexp) 0)
 932            (or (not (memq (string-to-char regexp) '(?! ?@)))
 933                (progn
 934                  (if (member (substring regexp 0 2) '("!@" "@!"))
 935                      (setq end t no t ln 2)
 936                    (setq no (not (setq end (eq ?@ (string-to-char regexp))))
 937                          ln 1))
 938                  (> (length (setq regexp (substring regexp ln))) 0))))
 939       (setq view-last-regexp (if no (list regexp) regexp)))
 940      ((consp view-last-regexp)
 941       (setq regexp (car view-last-regexp))
 942       (unless (setq no (not no)) (setq view-last-regexp regexp)))
 943      (view-last-regexp (setq regexp view-last-regexp)
 944                        (if no (setq view-last-regexp (list regexp))))
 945      (t (error "No previous View-mode search")))
 946     (save-excursion
 947       (if end (goto-char (if (< times 0) (point-max) (point-min)))
 948         (move-to-window-line (if (< times 0) 0 -1)))
 949       (if (if no (view-search-no-match-lines times regexp)
 950             (re-search-forward regexp nil t times))
 951           (setq where (point))))
 952     (if where
 953         (progn
 954           (push-mark)
 955           (goto-char where)
 956           (if view-overlay
 957               (move-overlay view-overlay (match-beginning 0) (match-end 0))
 958             (setq view-overlay
 959                   (make-overlay (match-beginning 0) (match-end 0))))
 960           (overlay-put view-overlay 'face view-highlight-face)
 961           (beginning-of-line)
 962           (view-recenter))
 963       (message "Can't find occurrence %d of %s%s"
 964                times (if no "no " "") regexp)
 965       (sit-for 4))))
 966
 967 ;; This is the dumb approach, looking at each line.  The original
 968 ;; version of this function looked like it might have been trying to
 969 ;; do something clever, but not succeeding:
 970 ;; http://lists.gnu.org/archive/html/bug-gnu-emacs/2007-09/msg00073.html
 971 (defun view-search-no-match-lines (times regexp)
 972   "Search for the TIMESth occurrence of a line with no match for REGEXP.
 973 If such a line is found, return non-nil and set the match-data to that line.
 974 If TIMES is negative, search backwards."
 975   (let ((step (if (>= times 0) 1
 976                 (setq times (- times))
 977                 -1)))
 978     ;; Note that we do not check the current line.
 979     (while (and (> times 0)
 980                 (zerop (forward-line step)))
 981       ;; (forward-line 1) returns 0 on moving within the last line.
 982       (if (eobp)
 983           (setq times -1)
 984         (or (re-search-forward regexp (line-end-position) t)
 985             (setq times (1- times))))))
 986   (and (zerop times)
 987        (looking-at ".*")))
 988
 989 (provide 'view)
 990
 991 ;;; view.el ends here