lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; File name completion does not do partial completion of directories
  82 ;; on the path, e.g., "/u/b/f" will not complete to "/usr/bin/foo",
  83 ;; but you can put *'s in the path to accomplish this:  "/u*/b*/f".
  84 ;; Stars are required for performance reasons.
  85
  86 ;; In addition, this package includes a feature for accessing include
  87 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  88 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  89 ;; list of directories in which to search for include files.  Completion
  90 ;; is supported in include file names.
  91
  92
  93 ;;; Code:
  94
  95 (defgroup partial-completion nil
  96   "Partial Completion of items."
  97   :prefix "pc-"
  98   :group 'minibuffer
  99   :group 'convenience)
 100
 101 ;;;###autoload
 102 (defcustom partial-completion-mode nil
 103   "Toggle Partial Completion mode.
 104 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 105 nil) is enhanced so that if some string is divided into words and each word is
 106 delimited by a character in `PC-word-delimiters', partial words are completed
 107 as much as possible and `*' characters are treated likewise in file names.
 108 This variable should be set only with \\[customize], which is equivalent
 109 to using the function `partial-completion-mode'."
 110   :set (lambda (symbol value)
 111          (partial-completion-mode (or value 0)))
 112   :initialize 'custom-initialize-default
 113   :type 'boolean
 114   :group 'partial-completion
 115   :require 'complete)
 116
 117 (defcustom PC-first-char 'find-file
 118   "*Control how the first character of a string is to be interpreted.
 119 If nil, the first character of a string is not taken literally if it is a word
 120 delimiter, so that \".e\" matches \"*.e*\".
 121 If t, the first character of a string is always taken literally even if it is a
 122 word delimiter, so that \".e\" matches \".e*\".
 123 If non-nil and non-t, the first character is taken literally only for file name
 124 completion."
 125   :type '(choice (const :tag "delimiter" nil)
 126                  (const :tag "literal" t)
 127                  (other :tag "find-file" find-file))
 128   :group 'partial-completion)
 129
 130 (defcustom PC-meta-flag t
 131   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 132 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 133   :type 'boolean
 134   :group 'partial-completion)
 135
 136 (defcustom PC-word-delimiters "-_. "
 137   "*A string of characters treated as word delimiters for completion.
 138 Some arcane rules:
 139 If `]' is in this string, it must come first.
 140 If `^' is in this string, it must not come first.
 141 If `-' is in this string, it must come first or right after `]'.
 142 In other words, if S is this string, then `[S]' must be a legal Emacs regular
 143 expression (not containing character ranges like `a-z')."
 144   :type 'string
 145   :group 'partial-completion)
 146
 147 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 148   "*A list of directories in which to look for include files.
 149 If nil, means use the colon-separated path in the variable $INCPATH instead."
 150   :type '(repeat directory)
 151   :group 'partial-completion)
 152
 153 (defcustom PC-disable-includes nil
 154   "*If non-nil, include-file support in \\[find-file] is disabled."
 155   :type 'boolean
 156   :group 'partial-completion)
 157
 158 (defvar PC-default-bindings t
 159   "If non-nil, default partial completion key bindings are suppressed.")
 160
 161 (defvar PC-env-vars-alist nil
 162   "A list of the environment variable names and values.")
 163
 164 \f
 165 (defvar PC-old-read-file-name-internal nil)
 166
 167 ;;;###autoload
 168 (defun partial-completion-mode (&optional arg)
 169   "Toggle Partial Completion mode.
 170 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 171
 172 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 173 nil) is enhanced so that if some string is divided into words and each word is
 174 delimited by a character in `PC-word-delimiters', partial words are completed
 175 as much as possible.
 176
 177 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 178 command begins with that sequence of characters, and
 179 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 180 other file in that directory begin with that sequence of characters.
 181
 182 Unless `PC-disable-includes' is non-nil, the \"<...>\" sequence is interpreted
 183 specially in \\[find-file].  For example,
 184 \\[find-file] <sys/time.h> RET finds the file /usr/include/sys/time.h.
 185 See also the variable `PC-include-file-path'."
 186   (interactive "P")
 187   (let ((on-p (if arg
 188                   (> (prefix-numeric-value arg) 0)
 189                 (not partial-completion-mode))))
 190     ;; Deal with key bindings...
 191     (PC-bindings on-p)
 192     ;; Deal with include file feature...
 193     (cond ((not on-p)
 194            (remove-hook 'find-file-not-found-hooks 'PC-look-for-include-file))
 195           ((not PC-disable-includes)
 196            (add-hook 'find-file-not-found-hooks 'PC-look-for-include-file)))
 197     ;; ... with some underhand redefining.
 198     (cond ((and (not on-p) (functionp PC-old-read-file-name-internal))
 199            (fset 'read-file-name-internal PC-old-read-file-name-internal))
 200           ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 201            (setq PC-old-read-file-name-internal
 202                  (symbol-function 'read-file-name-internal))
 203            (fset 'read-file-name-internal
 204                  'PC-read-include-file-name-internal)))
 205     (when (and on-p (null PC-env-vars-alist))
 206       (setq PC-env-vars-alist
 207             (mapcar (lambda (string)
 208                       (let ((d (string-match "=" string)))
 209                         (cons (concat "$" (substring string 0 d))
 210                               (and d (substring string (1+ d))))))
 211                     process-environment)))
 212     ;; Finally set the mode variable.
 213     (setq partial-completion-mode on-p)))
 214
 215 (defun PC-bindings (bind)
 216   (let ((completion-map minibuffer-local-completion-map)
 217         (must-match-map minibuffer-local-must-match-map))
 218     (cond ((not bind)
 219            ;; These bindings are the default bindings.  It would be better to
 220            ;; restore the previous bindings.
 221            (define-key completion-map "\t"      'minibuffer-complete)
 222            (define-key completion-map " "       'minibuffer-complete-word)
 223            (define-key completion-map "?"       'minibuffer-completion-help)
 224
 225            (define-key must-match-map "\t"      'minibuffer-complete)
 226            (define-key must-match-map " "       'minibuffer-complete-word)
 227            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 228            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 229            (define-key must-match-map "?"       'minibuffer-completion-help)
 230
 231            (define-key global-map "\e\t"        'complete-symbol))
 232           (PC-default-bindings
 233            (define-key completion-map "\t"      'PC-complete)
 234            (define-key completion-map " "       'PC-complete-word)
 235            (define-key completion-map "?"       'PC-completion-help)
 236
 237            (define-key completion-map "\e\t"    'PC-complete)
 238            (define-key completion-map "\e "     'PC-complete-word)
 239            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 240            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 241            (define-key completion-map "\e?"     'PC-completion-help)
 242
 243            (define-key must-match-map "\t"      'PC-complete)
 244            (define-key must-match-map " "       'PC-complete-word)
 245            (define-key must-match-map "\r"      'PC-complete-and-exit)
 246            (define-key must-match-map "\n"      'PC-complete-and-exit)
 247            (define-key must-match-map "?"       'PC-completion-help)
 248
 249            (define-key must-match-map "\e\t"    'PC-complete)
 250            (define-key must-match-map "\e "     'PC-complete-word)
 251            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 252            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 253            (define-key must-match-map "\e?"     'PC-completion-help)
 254
 255            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 256
 257 ;; Because the `partial-completion-mode' option is defined before the
 258 ;; `partial-completion-mode' command and its callee, we give the former a
 259 ;; default `:initialize' keyword value.  Otherwise, the `:set' keyword value
 260 ;; would be called to initialise the variable value, and that would call the
 261 ;; as-yet undefined `partial-completion-mode' function.
 262 ;; Since the default `:initialize' keyword value (obviously) does not turn on
 263 ;; Partial Completion Mode, we do that here, once the `partial-completion-mode'
 264 ;; function and its callee are defined.
 265 (when partial-completion-mode
 266   (partial-completion-mode t))
 267 \f
 268 (defun PC-complete ()
 269   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 270 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 271 name which consists of three or more words, the first beginning with \"b\"
 272 and the third beginning with \"di\".
 273
 274 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 275 `beginning-of-defun', so this would produce a list of completions
 276 just like when normal Emacs completions are ambiguous.
 277
 278 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 279 \".\", and SPC."
 280   (interactive)
 281   (if (PC-was-meta-key)
 282       (minibuffer-complete)
 283     ;; If the previous command was not this one,
 284     ;; never scroll, always retry completion.
 285     (or (eq last-command this-command)
 286         (setq minibuffer-scroll-window nil))
 287     (let ((window minibuffer-scroll-window))
 288       ;; If there's a fresh completion window with a live buffer,
 289       ;; and this command is repeated, scroll that window.
 290       (if (and window (window-buffer window)
 291                (buffer-name (window-buffer window)))
 292           (save-excursion
 293             (set-buffer (window-buffer window))
 294             (if (pos-visible-in-window-p (point-max) window)
 295                 (set-window-start window (point-min) nil)
 296               (scroll-other-window)))
 297         (PC-do-completion nil)))))
 298
 299
 300 (defun PC-complete-word ()
 301   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 302 See `PC-complete' for details.
 303 This can be bound to other keys, like `-' and `.', if you wish."
 304   (interactive)
 305   (if (eq (PC-was-meta-key) PC-meta-flag)
 306       (if (eq last-command-char ? )
 307           (minibuffer-complete-word)
 308         (self-insert-command 1))
 309     (self-insert-command 1)
 310     (if (eobp)
 311         (PC-do-completion 'word))))
 312
 313
 314 (defun PC-complete-space ()
 315   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 316 See `PC-complete' for details.
 317 This is suitable for binding to other keys which should act just like SPC."
 318   (interactive)
 319   (if (eq (PC-was-meta-key) PC-meta-flag)
 320       (minibuffer-complete-word)
 321     (insert " ")
 322     (if (eobp)
 323         (PC-do-completion 'word))))
 324
 325
 326 (defun PC-complete-and-exit ()
 327   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 328 See `PC-complete' for details."
 329   (interactive)
 330   (if (eq (PC-was-meta-key) PC-meta-flag)
 331       (minibuffer-complete-and-exit)
 332     (PC-do-complete-and-exit)))
 333
 334 (defun PC-force-complete-and-exit ()
 335   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 336 See `PC-complete' for details."
 337   (interactive)
 338   (let ((minibuffer-completion-confirm nil))
 339     (PC-do-complete-and-exit)))
 340
 341 (defun PC-do-complete-and-exit ()
 342   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 343       (exit-minibuffer)
 344     (let ((flag (PC-do-completion 'exit)))
 345       (and flag
 346            (if (or (eq flag 'complete)
 347                    (not minibuffer-completion-confirm))
 348                (exit-minibuffer)
 349              (PC-temp-minibuffer-message " [Confirm]"))))))
 350
 351
 352 (defun PC-completion-help ()
 353   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 354 See `PC-complete' for details."
 355   (interactive)
 356   (if (eq (PC-was-meta-key) PC-meta-flag)
 357       (minibuffer-completion-help)
 358     (PC-do-completion 'help)))
 359
 360 (defun PC-was-meta-key ()
 361   (or (/= (length (this-command-keys)) 1)
 362       (let ((key (aref (this-command-keys) 0)))
 363         (if (integerp key)
 364             (>= key 128)
 365           (not (null (memq 'meta (event-modifiers key))))))))
 366
 367
 368 (defvar PC-ignored-extensions 'empty-cache)
 369 (defvar PC-delims 'empty-cache)
 370 (defvar PC-ignored-regexp nil)
 371 (defvar PC-word-failed-flag nil)
 372 (defvar PC-delim-regex nil)
 373 (defvar PC-ndelims-regex nil)
 374 (defvar PC-delims-list nil)
 375
 376 (defvar PC-completion-as-file-name-predicate
 377   (function
 378    (lambda ()
 379      (memq minibuffer-completion-table
 380            '(read-file-name-internal read-directory-name-internal))))
 381    "A function testing whether a minibuffer completion now will work filename-style.
 382 The function takes no arguments, and typically looks at the value
 383 of `minibuffer-completion-table' and the minibuffer contents.")
 384
 385 (defun PC-do-completion (&optional mode beg end)
 386   (or beg (setq beg (minibuffer-prompt-end)))
 387   (or end (setq end (point-max)))
 388   (let* ((table minibuffer-completion-table)
 389          (pred minibuffer-completion-predicate)
 390          (filename (funcall PC-completion-as-file-name-predicate))
 391          (dirname nil)
 392          (dirlength 0)
 393          (str (buffer-substring beg end))
 394          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 395          (ambig nil)
 396          basestr
 397          env-on
 398          regex
 399          p offset
 400          (poss nil)
 401          helpposs
 402          (case-fold-search completion-ignore-case))
 403
 404     ;; Check if buffer contents can already be considered complete
 405     (if (and (eq mode 'exit)
 406              (PC-is-complete-p str table pred))
 407         'complete
 408
 409       ;; Do substitutions in directory names
 410       (and filename
 411            (setq basestr (or (file-name-directory str) ""))
 412            (setq dirlength (length basestr))
 413            ;; Do substitutions in directory names
 414            (setq p (substitute-in-file-name basestr))
 415            (not (string-equal basestr p))
 416            (setq str (concat p (file-name-nondirectory str)))
 417            (progn
 418              (delete-region beg end)
 419              (insert str)
 420              (setq end (+ beg (length str)))))
 421
 422       ;; Prepare various delimiter strings
 423       (or (equal PC-word-delimiters PC-delims)
 424           (setq PC-delims PC-word-delimiters
 425                 PC-delim-regex (concat "[" PC-delims "]")
 426                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 427                 PC-delims-list (append PC-delims nil)))
 428
 429       ;; Look for wildcard expansions in directory name
 430       (and filename
 431            (string-match "\\*.*/" str)
 432            (let ((pat str)
 433                  files)
 434              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 435              (while (setq p (string-match PC-delim-regex pat p))
 436                (setq pat (concat (substring pat 0 p)
 437                                  "*"
 438                                  (substring pat p))
 439                      p (+ p 2)))
 440              (setq files (PC-expand-many-files (concat pat "*")))
 441              (if files
 442                  (let ((dir (file-name-directory (car files)))
 443                        (p files))
 444                    (while (and (setq p (cdr p))
 445                                (equal dir (file-name-directory (car p)))))
 446                    (if p
 447                        (setq filename nil table nil pred nil
 448                              ambig t)
 449                      (delete-region beg end)
 450                      (setq str (concat dir (file-name-nondirectory str)))
 451                      (insert str)
 452                      (setq end (+ beg (length str)))))
 453                (setq filename nil table nil pred nil))))
 454
 455       ;; Strip directory name if appropriate
 456       (if filename
 457           (if incname
 458               (setq basestr (substring str incname)
 459                     dirname (substring str 0 incname))
 460             (setq basestr (file-name-nondirectory str)
 461                   dirname (file-name-directory str))
 462             ;; Make sure str is consistent with its directory and basename
 463             ;; parts.  This is important on DOZe'NT systems when str only
 464             ;; includes a drive letter, like in "d:".
 465             (setq str (concat dirname basestr)))
 466         (setq basestr str))
 467
 468       ;; Convert search pattern to a standard regular expression
 469       (setq regex (regexp-quote basestr)
 470             offset (if (and (> (length regex) 0)
 471                             (not (eq (aref basestr 0) ?\*))
 472                             (or (eq PC-first-char t)
 473                                 (and PC-first-char filename))) 1 0)
 474             p offset)
 475       (while (setq p (string-match PC-delim-regex regex p))
 476         (if (eq (aref regex p) ? )
 477             (setq regex (concat (substring regex 0 p)
 478                                 PC-ndelims-regex
 479                                 PC-delim-regex
 480                                 (substring regex (1+ p)))
 481                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 482           (let ((bump (if (memq (aref regex p)
 483                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 484                           -1 0)))
 485             (setq regex (concat (substring regex 0 (+ p bump))
 486                                 PC-ndelims-regex
 487                                 (substring regex (+ p bump)))
 488                   p (+ p (length PC-ndelims-regex) 1)))))
 489       (setq p 0)
 490       (if filename
 491           (while (setq p (string-match "\\\\\\*" regex p))
 492             (setq regex (concat (substring regex 0 p)
 493                                 "[^/]*"
 494                                 (substring regex (+ p 2))))))
 495       ;;(setq the-regex regex)
 496       (setq regex (concat "\\`" regex))
 497
 498       (and (> (length basestr) 0)
 499            (= (aref basestr 0) ?$)
 500            (setq env-on t
 501                  table PC-env-vars-alist
 502                  pred nil))
 503
 504       ;; Find an initial list of possible completions
 505       (if (not (setq p (string-match (concat PC-delim-regex
 506                                              (if filename "\\|\\*" ""))
 507                                      str
 508                                      (+ (length dirname) offset))))
 509
 510           ;; Minibuffer contains no hyphens -- simple case!
 511           (setq poss (all-completions (if env-on
 512                                           basestr str)
 513                                       table
 514                                       pred))
 515
 516         ;; Use all-completions to do an initial cull.  This is a big win,
 517         ;; since all-completions is written in C!
 518         (let ((compl (all-completions (if env-on
 519                                           (file-name-nondirectory (substring str 0 p))
 520                                         (substring str 0 p))
 521                                         table
 522                                         pred)))
 523           (setq p compl)
 524           (while p
 525             (and (string-match regex (car p))
 526                  (progn
 527                    (set-text-properties 0 (length (car p)) '() (car p))
 528                    (setq poss (cons (car p) poss))))
 529             (setq p (cdr p)))))
 530
 531       ;; Now we have a list of possible completions
 532       (cond
 533
 534        ;; No valid completions found
 535        ((null poss)
 536         (if (and (eq mode 'word)
 537                  (not PC-word-failed-flag))
 538             (let ((PC-word-failed-flag t))
 539               (delete-backward-char 1)
 540               (PC-do-completion 'word))
 541           (beep)
 542           (PC-temp-minibuffer-message (if ambig
 543                                           " [Ambiguous dir name]"
 544                                         (if (eq mode 'help)
 545                                             " [No completions]"
 546                                           " [No match]")))
 547           nil))
 548
 549        ;; More than one valid completion found
 550        ((or (cdr (setq helpposs poss))
 551             (memq mode '(help word)))
 552
 553         ;; Handle completion-ignored-extensions
 554         (and filename
 555              (not (eq mode 'help))
 556              (let ((p2 poss))
 557
 558                ;; Build a regular expression representing the extensions list
 559                (or (equal completion-ignored-extensions PC-ignored-extensions)
 560                    (setq PC-ignored-regexp
 561                          (concat "\\("
 562                                  (mapconcat
 563                                   'regexp-quote
 564                                   (setq PC-ignored-extensions
 565                                         completion-ignored-extensions)
 566                                   "\\|")
 567                                  "\\)\\'")))
 568
 569                ;; Check if there are any without an ignored extension.
 570                ;; Also ignore `.' and `..'.
 571                (setq p nil)
 572                (while p2
 573                  (or (string-match PC-ignored-regexp (car p2))
 574                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 575                      (setq p (cons (car p2) p)))
 576                  (setq p2 (cdr p2)))
 577
 578                ;; If there are "good" names, use them
 579                (and p (setq poss p))))
 580
 581         ;; Is the actual string one of the possible completions?
 582         (setq p (and (not (eq mode 'help)) poss))
 583         (while (and p
 584                     (not (string-equal (car p) basestr)))
 585           (setq p (cdr p)))
 586         (and p (null mode)
 587              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 588         (if (and p
 589                  (not (and (null mode)
 590                            (eq this-command last-command))))
 591             t
 592
 593           ;; If ambiguous, try for a partial completion
 594           (let ((improved nil)
 595                 prefix
 596                 (pt nil)
 597                 (skip "\\`"))
 598
 599             ;; Check if next few letters are the same in all cases
 600             (if (and (not (eq mode 'help))
 601                      (setq prefix (try-completion "" (mapcar 'list poss))))
 602                 (let ((first t) i)
 603                   (if (eq mode 'word)
 604                       (setq prefix (PC-chop-word prefix basestr)))
 605                   (goto-char (+ beg (length dirname)))
 606                   (while (and (progn
 607                                 (setq i 0)
 608                                 (while (< i (length prefix))
 609                                   (if (and (< (point) end)
 610                                            (eq (aref prefix i)
 611                                                (following-char)))
 612                                       (forward-char 1)
 613                                     (if (and (< (point) end)
 614                                              (or (and (looking-at " ")
 615                                                       (memq (aref prefix i)
 616                                                             PC-delims-list))
 617                                                  (eq (downcase (aref prefix i))
 618                                                      (downcase
 619                                                       (following-char)))))
 620                                         (progn
 621                                           (delete-char 1)
 622                                           (setq end (1- end)))
 623                                       (and filename (looking-at "\\*")
 624                                            (progn
 625                                              (delete-char 1)
 626                                              (setq end (1- end))))
 627                                       (setq improved t))
 628                                     (insert (substring prefix i (1+ i)))
 629                                     (setq end (1+ end)))
 630                                   (setq i (1+ i)))
 631                                 (or pt (equal (point) beg)
 632                                     (setq pt (point)))
 633                                 (looking-at PC-delim-regex))
 634                               (setq skip (concat skip
 635                                                  (regexp-quote prefix)
 636                                                  PC-ndelims-regex)
 637                                     prefix (try-completion
 638                                             ""
 639                                             (mapcar
 640                                              (function
 641                                               (lambda (x)
 642                                                 (list
 643                                                  (and (string-match skip x)
 644                                                       (substring
 645                                                        x
 646                                                        (match-end 0))))))
 647                                              poss)))
 648                               (or (> i 0) (> (length prefix) 0))
 649                               (or (not (eq mode 'word))
 650                                   (and first (> (length prefix) 0)
 651                                        (setq first nil
 652                                              prefix (substring prefix 0 1))))))
 653                   (goto-char (if (eq mode 'word) end
 654                                (or pt beg)))))
 655
 656             (if (and (eq mode 'word)
 657                      (not PC-word-failed-flag))
 658
 659                 (if improved
 660
 661                     ;; We changed it... would it be complete without the space?
 662                     (if (PC-is-complete-p (buffer-substring 1 (1- end))
 663                                           table pred)
 664                         (delete-region (1- end) end)))
 665
 666               (if improved
 667
 668                   ;; We changed it... enough to be complete?
 669                   (and (eq mode 'exit)
 670                        (PC-is-complete-p (field-string) table pred))
 671
 672                 ;; If totally ambiguous, display a list of completions
 673                 (if (or completion-auto-help
 674                         (eq mode 'help))
 675                     (with-output-to-temp-buffer "*Completions*"
 676                       (display-completion-list (sort helpposs 'string-lessp))
 677                       (save-excursion
 678                         (set-buffer standard-output)
 679                         ;; Record which part of the buffer we are completing
 680                         ;; so that choosing a completion from the list
 681                         ;; knows how much old text to replace.
 682                         (setq completion-base-size dirlength)))
 683                   (PC-temp-minibuffer-message " [Next char not unique]"))
 684                 nil)))))
 685
 686        ;; Only one possible completion
 687        (t
 688         (if (and (equal basestr (car poss))
 689                  (not (and env-on filename)))
 690             (if (null mode)
 691                 (PC-temp-minibuffer-message " [Sole completion]"))
 692           (delete-region beg end)
 693           (insert (format "%s"
 694                           (if filename
 695                               (substitute-in-file-name (concat dirname (car poss)))
 696                             (car poss)))))
 697         t)))))
 698
 699
 700 (defun PC-is-complete-p (str table pred)
 701   (let ((res (if (listp table)
 702                  (assoc str table)
 703                (if (vectorp table)
 704                    (or (equal str "nil")   ; heh, heh, heh
 705                        (intern-soft str table))
 706                  (funcall table str pred 'lambda)))))
 707     (and res
 708          (or (not pred)
 709              (and (not (listp table)) (not (vectorp table)))
 710              (funcall pred res))
 711          res)))
 712
 713 (defun PC-chop-word (new old)
 714   (let ((i -1)
 715         (j -1))
 716     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 717                 (setq j (string-match PC-delim-regex new (1+ j)))))
 718     (if (and j
 719              (or (not PC-word-failed-flag)
 720                  (setq j (string-match PC-delim-regex new (1+ j)))))
 721         (substring new 0 (1+ j))
 722       new)))
 723
 724 (defvar PC-not-minibuffer nil)
 725
 726 (defun PC-temp-minibuffer-message (message)
 727   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 728   (cond (PC-not-minibuffer
 729          (message message)
 730          (sit-for 2)
 731          (message ""))
 732         ((fboundp 'temp-minibuffer-message)
 733          (temp-minibuffer-message message))
 734         (t
 735          (let ((point-max (point-max)))
 736            (save-excursion
 737              (goto-char point-max)
 738              (insert message))
 739            (let ((inhibit-quit t))
 740              (sit-for 2)
 741              (delete-region point-max (point-max))
 742              (when quit-flag
 743                (setq quit-flag nil
 744                      unread-command-events '(7))))))))
 745
 746
 747 (defun PC-lisp-complete-symbol ()
 748   "Perform completion on Lisp symbol preceding point.
 749 That symbol is compared against the symbols that exist
 750 and any additional characters determined by what is there
 751 are inserted.
 752 If the symbol starts just after an open-parenthesis,
 753 only symbols with function definitions are considered.
 754 Otherwise, all symbols with function definitions, values
 755 or properties are considered."
 756   (interactive)
 757   (let* ((end (point))
 758          (buffer-syntax (syntax-table))
 759          (beg (unwind-protect
 760                   (save-excursion
 761                     (if lisp-mode-syntax-table
 762                         (set-syntax-table lisp-mode-syntax-table))
 763                     (backward-sexp 1)
 764                     (while (= (char-syntax (following-char)) ?\')
 765                       (forward-char 1))
 766                     (point))
 767                 (set-syntax-table buffer-syntax)))
 768          (minibuffer-completion-table obarray)
 769          (minibuffer-completion-predicate
 770           (if (eq (char-after (1- beg)) ?\()
 771               'fboundp
 772             (function (lambda (sym)
 773                         (or (boundp sym) (fboundp sym)
 774                             (symbol-plist sym))))))
 775          (PC-not-minibuffer t))
 776     (PC-do-completion nil beg end)))
 777
 778 (defun PC-complete-as-file-name ()
 779    "Perform completion on file names preceding point.
 780  Environment vars are converted to their values."
 781    (interactive)
 782    (let* ((end (point))
 783           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 784                                        (point-min) t)
 785                    (+ (point) 2)
 786                    (point-min)))
 787           (minibuffer-completion-table 'read-file-name-internal)
 788           (minibuffer-completion-predicate "")
 789           (PC-not-minibuffer t))
 790      (goto-char end)
 791      (PC-do-completion nil beg end)))
 792
 793 ;;; Use the shell to do globbing.
 794 ;;; This could now use file-expand-wildcards instead.
 795
 796 (defun PC-expand-many-files (name)
 797   (save-excursion
 798     (set-buffer (generate-new-buffer " *Glob Output*"))
 799     (erase-buffer)
 800     (shell-command (concat "echo " name) t)
 801     (goto-char (point-min))
 802     (if (looking-at ".*No match")
 803         nil
 804       (insert "(\"")
 805       (while (search-forward " " nil t)
 806         (delete-backward-char 1)
 807         (insert "\" \""))
 808       (goto-char (point-max))
 809       (delete-backward-char 1)
 810       (insert "\")")
 811       (goto-char (point-min))
 812       (let ((files (read (current-buffer))) (p nil))
 813         (kill-buffer (current-buffer))
 814         (or (equal completion-ignored-extensions PC-ignored-extensions)
 815             (setq PC-ignored-regexp
 816                   (concat "\\("
 817                           (mapconcat
 818                            'regexp-quote
 819                            (setq PC-ignored-extensions
 820                                  completion-ignored-extensions)
 821                            "\\|")
 822                           "\\)\\'")))
 823         (setq p nil)
 824         (while files
 825           (or (string-match PC-ignored-regexp (car files))
 826               (setq p (cons (car files) p)))
 827           (setq files (cdr files)))
 828         p))))
 829
 830 ;;; Facilities for loading C header files.  This is independent from the
 831 ;;; main completion code.  See also the variable `PC-include-file-path'
 832 ;;; at top of this file.
 833
 834 (defun PC-look-for-include-file ()
 835   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 836       (let ((name (substring (buffer-file-name)
 837                              (match-beginning 1) (match-end 1)))
 838             (punc (aref (buffer-file-name) (match-beginning 0)))
 839             (path nil)
 840             new-buf)
 841         (kill-buffer (current-buffer))
 842         (if (equal name "")
 843             (save-excursion
 844               (set-buffer (car (buffer-list)))
 845               (save-excursion
 846                 (beginning-of-line)
 847                 (if (looking-at
 848                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 849                     (setq name (buffer-substring (match-beginning 1)
 850                                                  (match-end 1))
 851                           punc (char-after (1- (match-beginning 1))))
 852                   ;; Suggested by Frank Siebenlist:
 853                   (if (or (looking-at
 854                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 855                           (looking-at
 856                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 857                           (looking-at
 858                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 859                       (progn
 860                         (setq name (buffer-substring (match-beginning 1)
 861                                                      (match-end 1))
 862                               punc ?\<
 863                               path load-path)
 864                         (if (string-match "\\.elc$" name)
 865                             (setq name (substring name 0 -1))
 866                           (or (string-match "\\.el$" name)
 867                               (setq name (concat name ".el")))))
 868                     (error "Not on an #include line"))))))
 869         (or (string-match "\\.[[:alnum:]]+$" name)
 870             (setq name (concat name ".h")))
 871         (if (eq punc ?\<)
 872             (let ((path (or path (PC-include-file-path))))
 873               (while (and path
 874                           (not (file-exists-p
 875                                 (concat (file-name-as-directory (car path))
 876                                         name))))
 877                 (setq path (cdr path)))
 878               (if path
 879                   (setq name (concat (file-name-as-directory (car path)) name))
 880                 (error "No such include file: <%s>" name)))
 881           (let ((dir (save-excursion
 882                        (set-buffer (car (buffer-list)))
 883                        default-directory)))
 884             (if (file-exists-p (concat dir name))
 885                 (setq name (concat dir name))
 886               (error "No such include file: `%s'" name))))
 887         (setq new-buf (get-file-buffer name))
 888         (if new-buf
 889             ;; no need to verify last-modified time for this!
 890             (set-buffer new-buf)
 891           (setq new-buf (create-file-buffer name))
 892           (set-buffer new-buf)
 893           (erase-buffer)
 894           (insert-file-contents name t))
 895         ;; Returning non-nil with the new buffer current
 896         ;; is sufficient to tell find-file to use it.
 897         t)
 898     nil))
 899
 900 (defun PC-include-file-path ()
 901   (or PC-include-file-path
 902       (let ((env (getenv "INCPATH"))
 903             (path nil)
 904             pos)
 905         (or env (error "No include file path specified"))
 906         (while (setq pos (string-match ":[^:]+$" env))
 907           (setq path (cons (substring env (1+ pos)) path)
 908                 env (substring env 0 pos)))
 909         path)))
 910
 911 ;;; This is adapted from lib-complete.el, by Mike Williams.
 912 (defun PC-include-file-all-completions (file search-path &optional full)
 913   "Return all completions for FILE in any directory on SEARCH-PATH.
 914 If optional third argument FULL is non-nil, returned pathnames should be
 915 absolute rather than relative to some directory on the SEARCH-PATH."
 916   (setq search-path
 917         (mapcar '(lambda (dir)
 918                    (if dir (file-name-as-directory dir) default-directory))
 919                 search-path))
 920   (if (file-name-absolute-p file)
 921       ;; It's an absolute file name, so don't need search-path
 922       (progn
 923         (setq file (expand-file-name file))
 924         (file-name-all-completions
 925          (file-name-nondirectory file) (file-name-directory file)))
 926     (let ((subdir (file-name-directory file))
 927           (ndfile (file-name-nondirectory file))
 928           file-lists)
 929       ;; Append subdirectory part to each element of search-path
 930       (if subdir
 931           (setq search-path
 932                 (mapcar '(lambda (dir) (concat dir subdir))
 933                         search-path)
 934                 file ))
 935       ;; Make list of completions in each directory on search-path
 936       (while search-path
 937         (let* ((dir (car search-path))
 938                (subdir (if full dir subdir)))
 939           (if (file-directory-p dir)
 940               (progn
 941                 (setq file-lists
 942                       (cons
 943                        (mapcar '(lambda (file) (concat subdir file))
 944                                (file-name-all-completions ndfile
 945                                                           (car search-path)))
 946                        file-lists))))
 947           (setq search-path (cdr search-path))))
 948       ;; Compress out duplicates while building complete list (slloooow!)
 949       (let ((sorted (sort (apply 'nconc file-lists)
 950                           '(lambda (x y) (not (string-lessp x y)))))
 951             compressed)
 952         (while sorted
 953           (if (equal (car sorted) (car compressed)) nil
 954             (setq compressed (cons (car sorted) compressed)))
 955           (setq sorted (cdr sorted)))
 956         compressed))))
 957
 958 (defun PC-read-include-file-name-internal (string dir action)
 959   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 960       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 961              (str2 (substring string (match-beginning 0)))
 962              (completion-table
 963               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 964                       (PC-include-file-all-completions
 965                        name (PC-include-file-path)))))
 966         (cond
 967          ((not completion-table) nil)
 968          ((eq action nil) (try-completion str2 completion-table nil))
 969          ((eq action t) (all-completions str2 completion-table nil))
 970          ((eq action 'lambda)
 971           (eq (try-completion str2 completion-table nil) t))))
 972     (funcall PC-old-read-file-name-internal string dir action)))
 973 \f
 974
 975 (provide 'complete)
 976
 977 ;;; End.