lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Maintainer: FSF
   8 ;; Keywords: internal
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl))
  31
  32 (declare-function xw-defined-colors "term/x-win" (&optional frame))
  33
  34 (defvar help-xref-stack-item)
  35
  36 (defvar face-name-history nil
  37   "History list for some commands that read face names.
  38 Maximum length of the history list is determined by the value
  39 of `history-length', which see.")
  40
  41 \f
  42 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  43 ;;; Font selection.
  44 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  45
  46 (defgroup font-selection nil
  47   "Influencing face font selection."
  48   :group 'faces)
  49
  50
  51 (defcustom face-font-selection-order
  52   '(:width :height :weight :slant)
  53   "A list specifying how face font selection chooses fonts.
  54 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  55 must appear once in the list, and the list must not contain any other
  56 elements.  Font selection first tries to find a best matching font
  57 for those face attributes that appear before in the list.  For
  58 example, if `:slant' appears before `:height', font selection first
  59 tries to find a font with a suitable slant, even if this results in
  60 a font height that isn't optimal."
  61   :tag "Font selection order"
  62   :type '(list symbol symbol symbol symbol)
  63   :group 'font-selection
  64   :set #'(lambda (symbol value)
  65            (set-default symbol value)
  66            (internal-set-font-selection-order value)))
  67
  68
  69 ;; In the absence of Fontconfig support, Monospace and Sans Serif are
  70 ;; unavailable, and we fall back on the courier and helv families,
  71 ;; which are generally available.
  72 (defcustom face-font-family-alternatives
  73   '(("Monospace" "courier" "fixed")
  74     ("courier" "CMU Typewriter Text" "fixed")
  75     ("Sans Serif" "helv" "helvetica" "arial" "fixed")
  76     ("helv" "helvetica" "arial" "fixed"))
  77   "Alist of alternative font family names.
  78 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  79 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  80 ALTERNATIVE2 etc."
  81   :tag "Alternative font families to try"
  82   :type '(repeat (repeat string))
  83   :group 'font-selection
  84   :set #'(lambda (symbol value)
  85            (set-default symbol value)
  86            (internal-set-alternative-font-family-alist value)))
  87
  88
  89 ;; This is defined originally in xfaces.c.
  90 (defcustom face-font-registry-alternatives
  91   (if (eq system-type 'windows-nt)
  92       '(("iso8859-1" "ms-oemlatin")
  93         ("gb2312.1980" "gb2312" "gbk" "gb18030")
  94         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  95         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  96         ("muletibetan-2" "muletibetan-0"))
  97     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk" "gb18030")
  98       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  99       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
 100       ("muletibetan-2" "muletibetan-0")))
 101   "Alist of alternative font registry names.
 102 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
 103 If fonts of registry REGISTRY can be loaded, font selection
 104 tries to find a best matching font among all fonts of registry
 105 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
 106   :tag "Alternative font registries to try"
 107   :type '(repeat (repeat string))
 108   :version "21.1"
 109   :group 'font-selection
 110   :set #'(lambda (symbol value)
 111            (set-default symbol value)
 112            (internal-set-alternative-font-registry-alist value)))
 113
 114 \f
 115 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 116 ;;; Creation, copying.
 117 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 118
 119
 120 (defun face-list ()
 121   "Return a list of all defined face names."
 122   (mapcar #'car face-new-frame-defaults))
 123
 124
 125 ;;; ### If not frame-local initialize by what X resources?
 126
 127 (defun make-face (face &optional no-init-from-resources)
 128   "Define a new face with name FACE, a symbol.
 129 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 130 variants of FACE from X resources.  (X resources recognized are found
 131 in the global variable `face-x-resources'.)  If FACE is already known
 132 as a face, leave it unmodified.  Value is FACE."
 133   (interactive (list (read-from-minibuffer
 134                       "Make face: " nil nil t 'face-name-history)))
 135   (unless (facep face)
 136     ;; Make frame-local faces (this also makes the global one).
 137     (dolist (frame (frame-list))
 138       (internal-make-lisp-face face frame))
 139     ;; Add the face to the face menu.
 140     (when (fboundp 'facemenu-add-new-face)
 141       (facemenu-add-new-face face))
 142     ;; Define frame-local faces for all frames from X resources.
 143     (unless no-init-from-resources
 144       (make-face-x-resource-internal face)))
 145   face)
 146
 147
 148 (defun make-empty-face (face)
 149   "Define a new, empty face with name FACE.
 150 If the face already exists, it is left unmodified.  Value is FACE."
 151   (interactive (list (read-from-minibuffer
 152                       "Make empty face: " nil nil t 'face-name-history)))
 153   (make-face face 'no-init-from-resources))
 154
 155
 156 (defun copy-face (old-face new-face &optional frame new-frame)
 157   "Define a face just like OLD-FACE, with name NEW-FACE.
 158
 159 If NEW-FACE already exists as a face, it is modified to be like
 160 OLD-FACE.  If it doesn't already exist, it is created.
 161
 162 If the optional argument FRAME is given as a frame, NEW-FACE is
 163 changed on FRAME only.
 164 If FRAME is t, the frame-independent default specification for OLD-FACE
 165 is copied to NEW-FACE.
 166 If FRAME is nil, copying is done for the frame-independent defaults
 167 and for each existing frame.
 168
 169 If the optional fourth argument NEW-FRAME is given,
 170 copy the information from face OLD-FACE on frame FRAME
 171 to NEW-FACE on frame NEW-FRAME.  In this case, FRAME may not be nil."
 172   (let ((inhibit-quit t))
 173     (if (null frame)
 174         (progn
 175           (when new-frame
 176             (error "Copying face %s from all frames to one frame"
 177                    old-face))
 178           (make-empty-face new-face)
 179           (dolist (frame (frame-list))
 180             (copy-face old-face new-face frame))
 181           (copy-face old-face new-face t))
 182       (make-empty-face new-face)
 183       (internal-copy-lisp-face old-face new-face frame new-frame))
 184     new-face))
 185
 186
 187 \f
 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 189 ;;; Obsolete functions
 190 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 191
 192 ;; The functions in this section are defined because Lisp packages use
 193 ;; them, despite the prefix `internal-' suggesting that they are
 194 ;; private to the face implementation.
 195
 196 (defun internal-find-face (name &optional frame)
 197   "Retrieve the face named NAME.
 198 Return nil if there is no such face.
 199 If NAME is already a face, it is simply returned.
 200 The optional argument FRAME is ignored."
 201   (facep name))
 202 (make-obsolete 'internal-find-face 'facep "21.1")
 203
 204
 205 (defun internal-get-face (name &optional frame)
 206   "Retrieve the face named NAME; error if there is none.
 207 If NAME is already a face, it is simply returned.
 208 The optional argument FRAME is ignored."
 209   (or (facep name)
 210       (check-face name)))
 211 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 212
 213 \f
 214 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 215 ;;; Predicates, type checks.
 216 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 217
 218 (defun facep (face)
 219   "Return non-nil if FACE is a face name; nil otherwise.
 220 A face name can be a string or a symbol."
 221   (internal-lisp-face-p face))
 222
 223
 224 (defun check-face (face)
 225   "Signal an error if FACE doesn't name a face.
 226 Value is FACE."
 227   (unless (facep face)
 228     (error "Not a face: %s" face))
 229   face)
 230
 231
 232 ;; The ID returned is not to be confused with the internally used IDs
 233 ;; of realized faces.  The ID assigned to Lisp faces is used to
 234 ;; support faces in display table entries.
 235
 236 (defun face-id (face &optional frame)
 237   "Return the internal ID of face with name FACE.
 238 If FACE is a face-alias, return the ID of the target face.
 239 The optional argument FRAME is ignored, since the internal face ID
 240 of a face name is the same for all frames."
 241   (check-face face)
 242   (or (get face 'face)
 243       (face-id (get face 'face-alias))))
 244
 245 (defun face-equal (face1 face2 &optional frame)
 246   "Non-nil if faces FACE1 and FACE2 are equal.
 247 Faces are considered equal if all their attributes are equal.
 248 If the optional argument FRAME is given, report on FACE1 and FACE2 in that frame.
 249 If FRAME is t, report on the defaults for FACE1 and FACE2 (for new frames).
 250 If FRAME is omitted or nil, use the selected frame."
 251   (internal-lisp-face-equal-p face1 face2 frame))
 252
 253
 254 (defun face-differs-from-default-p (face &optional frame)
 255   "Return non-nil if FACE displays differently from the default face.
 256 If the optional argument FRAME is given, report on face FACE in that frame.
 257 If FRAME is t, report on the defaults for face FACE (for new frames).
 258 If FRAME is omitted or nil, use the selected frame."
 259   (let ((attrs
 260          (delq :inherit (mapcar 'car face-attribute-name-alist)))
 261         (differs nil))
 262     (while (and attrs (not differs))
 263       (let* ((attr (pop attrs))
 264              (attr-val (face-attribute face attr frame t)))
 265         (when (and
 266                (not (eq attr-val 'unspecified))
 267                (display-supports-face-attributes-p (list attr attr-val)
 268                                                    frame))
 269           (setq differs attr))))
 270     differs))
 271
 272
 273 (defun face-nontrivial-p (face &optional frame)
 274   "True if face FACE has some non-nil attribute.
 275 If the optional argument FRAME is given, report on face FACE in that frame.
 276 If FRAME is t, report on the defaults for face FACE (for new frames).
 277 If FRAME is omitted or nil, use the selected frame."
 278   (not (internal-lisp-face-empty-p face frame)))
 279
 280
 281 \f
 282 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 283 ;;; Setting face attributes from X resources.
 284 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 285
 286 (defcustom face-x-resources
 287   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 288     (:foundry (".attributeFoundry" . "Face.AttributeFoundry"))
 289     (:width (".attributeWidth" . "Face.AttributeWidth"))
 290     (:height (".attributeHeight" . "Face.AttributeHeight"))
 291     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 292     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 293     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 294     (:background (".attributeBackground" . "Face.AttributeBackground"))
 295     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 296     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 297     (:box (".attributeBox" . "Face.AttributeBox"))
 298     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 299     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 300     (:stipple
 301      (".attributeStipple" . "Face.AttributeStipple")
 302      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 303     (:bold (".attributeBold" . "Face.AttributeBold"))
 304     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 305     (:font (".attributeFont" . "Face.AttributeFont"))
 306     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 307   "List of X resources and classes for face attributes.
 308 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 309 the name of a face attribute, and each ENTRY is a cons of the form
 310 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 311 X resource class for the attribute."
 312   :type '(repeat (cons symbol (repeat (cons string string))))
 313   :group 'faces)
 314
 315
 316 (declare-function internal-face-x-get-resource "xfaces.c"
 317                   (resource class frame))
 318
 319 (declare-function internal-set-lisp-face-attribute-from-resource "xfaces.c"
 320                   (face attr value &optional frame))
 321
 322 (defun set-face-attribute-from-resource (face attribute resource class frame)
 323   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 324 Value is the attribute value specified by the resource, or nil
 325 if not present.  This function displays a message if the resource
 326 specifies an invalid attribute."
 327   (let* ((face-name (face-name face))
 328          (value (internal-face-x-get-resource (concat face-name resource)
 329                                               class frame)))
 330     (when value
 331       (condition-case ()
 332           (internal-set-lisp-face-attribute-from-resource
 333            face attribute (downcase value) frame)
 334         (error
 335          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 336                   face-name frame attribute value))))
 337     value))
 338
 339
 340 (defun set-face-attributes-from-resources (face frame)
 341   "Set attributes of FACE from X resources for FRAME."
 342   (when (memq (framep frame) '(x w32))
 343     (dolist (definition face-x-resources)
 344       (let ((attribute (car definition)))
 345         (dolist (entry (cdr definition))
 346           (set-face-attribute-from-resource face attribute (car entry)
 347                                             (cdr entry) frame))))))
 348
 349
 350 (defun make-face-x-resource-internal (face &optional frame)
 351   "Fill frame-local FACE on FRAME from X resources.
 352 FRAME nil or not specified means do it for all frames."
 353   (if (null frame)
 354       (dolist (frame (frame-list))
 355         (set-face-attributes-from-resources face frame))
 356     (set-face-attributes-from-resources face frame)))
 357
 358
 359 \f
 360 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 361 ;;; Retrieving face attributes.
 362 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 363
 364 (defun face-name (face)
 365   "Return the name of face FACE."
 366   (symbol-name (check-face face)))
 367
 368
 369 (defun face-all-attributes (face &optional frame)
 370   "Return an alist stating the attributes of FACE.
 371 Each element of the result has the form (ATTR-NAME . ATTR-VALUE).
 372 Normally the value describes the default attributes,
 373 but if you specify FRAME, the value describes the attributes
 374 of FACE on FRAME."
 375   (mapcar (lambda (pair)
 376             (let ((attr (car pair)))
 377               (cons attr (face-attribute face attr (or frame t)))))
 378           face-attribute-name-alist))
 379
 380 (defun face-attribute (face attribute &optional frame inherit)
 381   "Return the value of FACE's ATTRIBUTE on FRAME.
 382 If the optional argument FRAME is given, report on face FACE in that frame.
 383 If FRAME is t, report on the defaults for face FACE (for new frames).
 384 If FRAME is omitted or nil, use the selected frame.
 385
 386 If INHERIT is nil, only attributes directly defined by FACE are considered,
 387   so the return value may be `unspecified', or a relative value.
 388 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 389   faces specified by its `:inherit' attribute; however the return value
 390   may still be `unspecified' or relative.
 391 If INHERIT is a face or a list of faces, then the result is further merged
 392   with that face (or faces), until it becomes specified and absolute.
 393
 394 To ensure that the return value is always specified and absolute, use a
 395 value of `default' for INHERIT; this will resolve any unspecified or
 396 relative values by merging with the `default' face (which is always
 397 completely specified)."
 398   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 399     (when (and inherit (face-attribute-relative-p attribute value))
 400       ;; VALUE is relative, so merge with inherited faces
 401       (let ((inh-from (face-attribute face :inherit frame)))
 402         (unless (or (null inh-from) (eq inh-from 'unspecified))
 403           (condition-case nil
 404               (setq value
 405                     (face-attribute-merged-with attribute value inh-from frame))
 406             ;; The `inherit' attribute may point to non existent faces.
 407             (error nil)))))
 408     (when (and inherit
 409                (not (eq inherit t))
 410                (face-attribute-relative-p attribute value))
 411       ;; We should merge with INHERIT as well
 412       (setq value (face-attribute-merged-with attribute value inherit frame)))
 413     value))
 414
 415 (defun face-attribute-merged-with (attribute value faces &optional frame)
 416   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 417 FACES may be either a single face or a list of faces.
 418 \[This is an internal function.]"
 419   (cond ((not (face-attribute-relative-p attribute value))
 420          value)
 421         ((null faces)
 422          value)
 423         ((consp faces)
 424          (face-attribute-merged-with
 425           attribute
 426           (face-attribute-merged-with attribute value (car faces) frame)
 427           (cdr faces)
 428           frame))
 429         (t
 430          (merge-face-attribute attribute
 431                                value
 432                                (face-attribute faces attribute frame t)))))
 433
 434
 435 (defmacro face-attribute-specified-or (value &rest body)
 436   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 437   (let ((temp (make-symbol "value")))
 438     `(let ((,temp ,value))
 439        (if (not (eq ,temp 'unspecified))
 440            ,temp
 441          ,@body))))
 442
 443 (defun face-foreground (face &optional frame inherit)
 444   "Return the foreground color name of FACE, or nil if unspecified.
 445 If the optional argument FRAME is given, report on face FACE in that frame.
 446 If FRAME is t, report on the defaults for face FACE (for new frames).
 447 If FRAME is omitted or nil, use the selected frame.
 448
 449 If INHERIT is nil, only a foreground color directly defined by FACE is
 450   considered, so the return value may be nil.
 451 If INHERIT is t, and FACE doesn't define a foreground color, then any
 452   foreground color that FACE inherits through its `:inherit' attribute
 453   is considered as well; however the return value may still be nil.
 454 If INHERIT is a face or a list of faces, then it is used to try to
 455   resolve an unspecified foreground color.
 456
 457 To ensure that a valid color is always returned, use a value of
 458 `default' for INHERIT; this will resolve any unspecified values by
 459 merging with the `default' face (which is always completely specified)."
 460   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 461                                nil))
 462
 463 (defun face-background (face &optional frame inherit)
 464   "Return the background color name of FACE, or nil if unspecified.
 465 If the optional argument FRAME is given, report on face FACE in that frame.
 466 If FRAME is t, report on the defaults for face FACE (for new frames).
 467 If FRAME is omitted or nil, use the selected frame.
 468
 469 If INHERIT is nil, only a background color directly defined by FACE is
 470   considered, so the return value may be nil.
 471 If INHERIT is t, and FACE doesn't define a background color, then any
 472   background color that FACE inherits through its `:inherit' attribute
 473   is considered as well; however the return value may still be nil.
 474 If INHERIT is a face or a list of faces, then it is used to try to
 475   resolve an unspecified background color.
 476
 477 To ensure that a valid color is always returned, use a value of
 478 `default' for INHERIT; this will resolve any unspecified values by
 479 merging with the `default' face (which is always completely specified)."
 480   (face-attribute-specified-or (face-attribute face :background frame inherit)
 481                                nil))
 482
 483 (defun face-stipple (face &optional frame inherit)
 484  "Return the stipple pixmap name of FACE, or nil if unspecified.
 485 If the optional argument FRAME is given, report on face FACE in that frame.
 486 If FRAME is t, report on the defaults for face FACE (for new frames).
 487 If FRAME is omitted or nil, use the selected frame.
 488
 489 If INHERIT is nil, only a stipple directly defined by FACE is
 490   considered, so the return value may be nil.
 491 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 492   that FACE inherits through its `:inherit' attribute is considered as
 493   well; however the return value may still be nil.
 494 If INHERIT is a face or a list of faces, then it is used to try to
 495   resolve an unspecified stipple.
 496
 497 To ensure that a valid stipple or nil is always returned, use a value of
 498 `default' for INHERIT; this will resolve any unspecified values by merging
 499 with the `default' face (which is always completely specified)."
 500   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 501                                nil))
 502
 503
 504 (defalias 'face-background-pixmap 'face-stipple)
 505
 506
 507 (defun face-underline-p (face &optional frame)
 508  "Return non-nil if FACE is underlined.
 509 If the optional argument FRAME is given, report on face FACE in that frame.
 510 If FRAME is t, report on the defaults for face FACE (for new frames).
 511 If FRAME is omitted or nil, use the selected frame."
 512  (eq (face-attribute face :underline frame) t))
 513
 514
 515 (defun face-inverse-video-p (face &optional frame)
 516  "Return non-nil if FACE is in inverse video on FRAME.
 517 If the optional argument FRAME is given, report on face FACE in that frame.
 518 If FRAME is t, report on the defaults for face FACE (for new frames).
 519 If FRAME is omitted or nil, use the selected frame."
 520  (eq (face-attribute face :inverse-video frame) t))
 521
 522
 523 (defun face-bold-p (face &optional frame)
 524   "Return non-nil if the font of FACE is bold on FRAME.
 525 If the optional argument FRAME is given, report on face FACE in that frame.
 526 If FRAME is t, report on the defaults for face FACE (for new frames).
 527 If FRAME is omitted or nil, use the selected frame.
 528 Use `face-attribute' for finer control."
 529   (let ((bold (face-attribute face :weight frame)))
 530     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 531
 532
 533 (defun face-italic-p (face &optional frame)
 534   "Return non-nil if the font of FACE is italic on FRAME.
 535 If the optional argument FRAME is given, report on face FACE in that frame.
 536 If FRAME is t, report on the defaults for face FACE (for new frames).
 537 If FRAME is omitted or nil, use the selected frame.
 538 Use `face-attribute' for finer control."
 539   (let ((italic (face-attribute face :slant frame)))
 540     (memq italic '(italic oblique))))
 541
 542
 543 \f
 544 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 545 ;;; Face documentation.
 546 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 547
 548 (defun face-documentation (face)
 549   "Get the documentation string for FACE.
 550 If FACE is a face-alias, get the documentation for the target face."
 551   (let ((alias (get face 'face-alias))
 552         doc)
 553     (if alias
 554         (progn
 555           (setq doc (get alias 'face-documentation))
 556           (format "%s is an alias for the face `%s'.%s" face alias
 557                   (if doc (format "\n%s" doc)
 558                     "")))
 559       (get face 'face-documentation))))
 560
 561
 562 (defun set-face-documentation (face string)
 563   "Set the documentation string for FACE to STRING."
 564   ;; Perhaps the text should go in DOC.
 565   (put face 'face-documentation (purecopy string)))
 566
 567
 568 (defalias 'face-doc-string 'face-documentation)
 569 (defalias 'set-face-doc-string 'set-face-documentation)
 570
 571
 572 \f
 573 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 574 ;; Setting face attributes.
 575 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 576
 577
 578 (defun set-face-attribute (face frame &rest args)
 579   "Set attributes of FACE on FRAME from ARGS.
 580
 581 FRAME nil means change attributes on all frames.  FRAME t means change
 582 the default for new frames (this is done automatically each time an
 583 attribute is changed on all frames).
 584
 585 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 586 face attribute name. All attributes can be set to `unspecified';
 587 this fact is not further mentioned below.
 588
 589 The following attributes are recognized:
 590
 591 `:family'
 592
 593 VALUE must be a string specifying the font family, e.g. ``monospace'',
 594 or a fontset alias name.  If a font family is specified, wild-cards `*'
 595 and `?' are allowed.
 596
 597 `:foundry'
 598
 599 VALUE must be a string specifying the font foundry,
 600 e.g. ``adobe''.  If a font foundry is specified, wild-cards `*'
 601 and `?' are allowed.
 602
 603 `:width'
 604
 605 VALUE specifies the relative proportionate width of the font to use.
 606 It must be one of the symbols `ultra-condensed', `extra-condensed',
 607 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 608 `extra-expanded', or `ultra-expanded'.
 609
 610 `:height'
 611
 612 VALUE must be either an integer specifying the height of the font to use
 613 in 1/10 pt, a floating point number specifying the amount by which to
 614 scale any underlying face, or a function, which is called with the old
 615 height (from the underlying face), and should return the new height.
 616
 617 `:weight'
 618
 619 VALUE specifies the weight of the font to use.  It must be one of the
 620 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 621 `semi-light', `light', `extra-light', `ultra-light'.
 622
 623 `:slant'
 624
 625 VALUE specifies the slant of the font to use.  It must be one of the
 626 symbols `italic', `oblique', `normal', `reverse-italic', or
 627 `reverse-oblique'.
 628
 629 `:foreground', `:background'
 630
 631 VALUE must be a color name, a string.
 632
 633 `:underline'
 634
 635 VALUE specifies whether characters in FACE should be underlined.  If
 636 VALUE is t, underline with foreground color of the face.  If VALUE is
 637 a string, underline with that color.  If VALUE is nil, explicitly
 638 don't underline.
 639
 640 `:overline'
 641
 642 VALUE specifies whether characters in FACE should be overlined.  If
 643 VALUE is t, overline with foreground color of the face.  If VALUE is a
 644 string, overline with that color.  If VALUE is nil, explicitly don't
 645 overline.
 646
 647 `:strike-through'
 648
 649 VALUE specifies whether characters in FACE should be drawn with a line
 650 striking through them.  If VALUE is t, use the foreground color of the
 651 face.  If VALUE is a string, strike-through with that color.  If VALUE
 652 is nil, explicitly don't strike through.
 653
 654 `:box'
 655
 656 VALUE specifies whether characters in FACE should have a box drawn
 657 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 658 VALUE is t, draw a box with lines of width 1 in the foreground color
 659 of the face.  If VALUE is a string, the string must be a color name,
 660 and the box is drawn in that color with a line width of 1.  Otherwise,
 661 VALUE must be a property list of the form `(:line-width WIDTH
 662 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 663 the property list, a default value will be used for the value, as
 664 specified below.  WIDTH specifies the width of the lines to draw; it
 665 defaults to 1.  If WIDTH is negative, the absolute value is the width
 666 of the lines, and draw top/bottom lines inside the characters area,
 667 not around it.  COLOR is the name of the color to draw in, default is
 668 the foreground color of the face for simple boxes, and the background
 669 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 670 should be draw.  If STYLE is `released-button', draw a box looking
 671 like a released 3D button.  If STYLE is `pressed-button' draw a box
 672 that appears like a pressed button.  If STYLE is nil, the default if
 673 the property list doesn't contain a style specification, draw a 2D
 674 box.
 675
 676 `:inverse-video'
 677
 678 VALUE specifies whether characters in FACE should be displayed in
 679 inverse video.  VALUE must be one of t or nil.
 680
 681 `:stipple'
 682
 683 If VALUE is a string, it must be the name of a file of pixmap data.
 684 The directories listed in the `x-bitmap-file-path' variable are
 685 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 686 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 687 is a string containing the raw bits of the bitmap.  VALUE nil means
 688 explicitly don't use a stipple pattern.
 689
 690 For convenience, attributes `:family', `:foundry', `:width',
 691 `:height', `:weight', and `:slant' may also be set in one step
 692 from an X font name:
 693
 694 `:font'
 695
 696 Set font-related face attributes from VALUE.  VALUE must be a valid
 697 XLFD font name.  If it is a font name pattern, the first matching font
 698 will be used.
 699
 700 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 701 be used to specify that a bold or italic font should be used.  VALUE
 702 must be t or nil in that case.  A value of `unspecified' is not allowed.
 703
 704 `:inherit'
 705
 706 VALUE is the name of a face from which to inherit attributes, or a list
 707 of face names.  Attributes from inherited faces are merged into the face
 708 like an underlying face would be, with higher priority than underlying faces."
 709   (setq args (purecopy args))
 710   (let ((where (if (null frame) 0 frame))
 711         (spec args)
 712         family foundry)
 713     ;; If we set the new-frame defaults, this face is modified outside Custom.
 714     (if (memq where '(0 t))
 715         (put (or (get face 'face-alias) face) 'face-modified t))
 716     ;; If family and/or foundry are specified, set it first.  Certain
 717     ;; face attributes, e.g. :weight semi-condensed, are not supported
 718     ;; in every font.  See bug#1127.
 719     (while spec
 720       (cond ((eq (car spec) :family)
 721              (setq family (cadr spec)))
 722             ((eq (car spec) :foundry)
 723              (setq foundry (cadr spec))))
 724       (setq spec (cddr spec)))
 725     (when (or family foundry)
 726       (when (and (stringp family)
 727                  (string-match "\\([^-]*\\)-\\([^-]*\\)" family))
 728         (unless foundry
 729           (setq foundry (match-string 1 family)))
 730         (setq family (match-string 2 family)))
 731       (when (stringp family)
 732         (internal-set-lisp-face-attribute face :family (purecopy family)
 733                                           where))
 734       (when (stringp foundry)
 735         (internal-set-lisp-face-attribute face :foundry (purecopy foundry)
 736                                           where)))
 737     (while args
 738       (unless (memq (car args) '(:family :foundry))
 739         (internal-set-lisp-face-attribute face (car args)
 740                                           (purecopy (cadr args))
 741                                           where))
 742       (setq args (cddr args)))))
 743
 744 (defun make-face-bold (face &optional frame noerror)
 745   "Make the font of FACE be bold, if possible.
 746 FRAME nil or not specified means change face on all frames.
 747 Argument NOERROR is ignored and retained for compatibility.
 748 Use `set-face-attribute' for finer control of the font weight."
 749   (interactive (list (read-face-name "Make which face bold")))
 750   (set-face-attribute face frame :weight 'bold))
 751
 752
 753 (defun make-face-unbold (face &optional frame noerror)
 754   "Make the font of FACE be non-bold, if possible.
 755 FRAME nil or not specified means change face on all frames.
 756 Argument NOERROR is ignored and retained for compatibility."
 757   (interactive (list (read-face-name "Make which face non-bold")))
 758   (set-face-attribute face frame :weight 'normal))
 759
 760
 761 (defun make-face-italic (face &optional frame noerror)
 762   "Make the font of FACE be italic, if possible.
 763 FRAME nil or not specified means change face on all frames.
 764 Argument NOERROR is ignored and retained for compatibility.
 765 Use `set-face-attribute' for finer control of the font slant."
 766   (interactive (list (read-face-name "Make which face italic")))
 767   (set-face-attribute face frame :slant 'italic))
 768
 769
 770 (defun make-face-unitalic (face &optional frame noerror)
 771   "Make the font of FACE be non-italic, if possible.
 772 FRAME nil or not specified means change face on all frames.
 773 Argument NOERROR is ignored and retained for compatibility."
 774   (interactive (list (read-face-name "Make which face non-italic")))
 775   (set-face-attribute face frame :slant 'normal))
 776
 777
 778 (defun make-face-bold-italic (face &optional frame noerror)
 779   "Make the font of FACE be bold and italic, if possible.
 780 FRAME nil or not specified means change face on all frames.
 781 Argument NOERROR is ignored and retained for compatibility.
 782 Use `set-face-attribute' for finer control of font weight and slant."
 783   (interactive (list (read-face-name "Make which face bold-italic")))
 784   (set-face-attribute face frame :weight 'bold :slant 'italic))
 785
 786
 787 (defun set-face-font (face font &optional frame)
 788   "Change font-related attributes of FACE to those of FONT (a string).
 789 FRAME nil or not specified means change face on all frames.
 790 This sets the attributes `:family', `:foundry', `:width',
 791 `:height', `:weight', and `:slant'.  When called interactively,
 792 prompt for the face and font."
 793   (interactive (read-face-and-attribute :font))
 794   (set-face-attribute face frame :font font))
 795
 796
 797 ;; Implementation note: Emulating gray background colors with a
 798 ;; stipple pattern is now part of the face realization process, and is
 799 ;; done in C depending on the frame on which the face is realized.
 800
 801 (defun set-face-background (face color &optional frame)
 802   "Change the background color of face FACE to COLOR (a string).
 803 FRAME nil or not specified means change face on all frames.
 804 COLOR can be a system-defined color name (see `list-colors-display')
 805 or a hex spec of the form #RRGGBB.
 806 When called interactively, prompts for the face and color."
 807   (interactive (read-face-and-attribute :background))
 808   (set-face-attribute face frame :background (or color 'unspecified)))
 809
 810
 811 (defun set-face-foreground (face color &optional frame)
 812   "Change the foreground color of face FACE to COLOR (a string).
 813 FRAME nil or not specified means change face on all frames.
 814 COLOR can be a system-defined color name (see `list-colors-display')
 815 or a hex spec of the form #RRGGBB.
 816 When called interactively, prompts for the face and color."
 817   (interactive (read-face-and-attribute :foreground))
 818   (set-face-attribute face frame :foreground (or color 'unspecified)))
 819
 820
 821 (defun set-face-stipple (face stipple &optional frame)
 822   "Change the stipple pixmap of face FACE to STIPPLE.
 823 FRAME nil or not specified means change face on all frames.
 824 STIPPLE should be a string, the name of a file of pixmap data.
 825 The directories listed in the `x-bitmap-file-path' variable are searched.
 826
 827 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 828 where WIDTH and HEIGHT are the size in pixels,
 829 and DATA is a string, containing the raw bits of the bitmap."
 830   (interactive (read-face-and-attribute :stipple))
 831   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 832
 833
 834 (defun set-face-underline-p (face underline &optional frame)
 835   "Specify whether face FACE is underlined.
 836 UNDERLINE nil means FACE explicitly doesn't underline.
 837 UNDERLINE non-nil means FACE explicitly does underlining
 838 with the same of the foreground color.
 839 If UNDERLINE is a string, underline with the color named UNDERLINE.
 840 FRAME nil or not specified means change face on all frames.
 841 Use `set-face-attribute' to ``unspecify'' underlining."
 842   (interactive
 843    (let ((list (read-face-and-attribute :underline)))
 844      (list (car list) (eq (car (cdr list)) t))))
 845   (set-face-attribute face frame :underline underline))
 846
 847 (define-obsolete-function-alias 'set-face-underline
 848                                 'set-face-underline-p "22.1")
 849
 850
 851 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 852   "Specify whether face FACE is in inverse video.
 853 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 854 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 855 FRAME nil or not specified means change face on all frames.
 856 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 857   (interactive
 858    (let ((list (read-face-and-attribute :inverse-video)))
 859      (list (car list) (eq (car (cdr list)) t))))
 860   (set-face-attribute face frame :inverse-video inverse-video-p))
 861
 862
 863 (defun set-face-bold-p (face bold-p &optional frame)
 864   "Specify whether face FACE is bold.
 865 BOLD-P non-nil means FACE should explicitly display bold.
 866 BOLD-P nil means FACE should explicitly display non-bold.
 867 FRAME nil or not specified means change face on all frames.
 868 Use `set-face-attribute' or `modify-face' for finer control."
 869   (if (null bold-p)
 870       (make-face-unbold face frame)
 871     (make-face-bold face frame)))
 872
 873
 874 (defun set-face-italic-p (face italic-p &optional frame)
 875   "Specify whether face FACE is italic.
 876 ITALIC-P non-nil means FACE should explicitly display italic.
 877 ITALIC-P nil means FACE should explicitly display non-italic.
 878 FRAME nil or not specified means change face on all frames.
 879 Use `set-face-attribute' or `modify-face' for finer control."
 880   (if (null italic-p)
 881       (make-face-unitalic face frame)
 882     (make-face-italic face frame)))
 883
 884
 885 (defalias 'set-face-background-pixmap 'set-face-stipple)
 886
 887
 888 (defun invert-face (face &optional frame)
 889   "Swap the foreground and background colors of FACE.
 890 If FRAME is omitted or nil, it means change face on all frames.
 891 If FACE specifies neither foreground nor background color,
 892 set its foreground and background to the background and foreground
 893 of the default face.  Value is FACE."
 894   (interactive (list (read-face-name "Invert face")))
 895   (let ((fg (face-attribute face :foreground frame))
 896         (bg (face-attribute face :background frame)))
 897     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 898         (set-face-attribute face frame :foreground bg :background fg)
 899       (set-face-attribute face frame
 900                           :foreground
 901                           (face-attribute 'default :background frame)
 902                           :background
 903                           (face-attribute 'default :foreground frame))))
 904   face)
 905
 906 \f
 907 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 908 ;;; Interactively modifying faces.
 909 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 910
 911 (defun read-face-name (prompt &optional string-describing-default multiple)
 912   "Read a face, defaulting to the face or faces on the char after point.
 913 If it has the property `read-face-name', that overrides the `face' property.
 914 PROMPT should be a string that describes what the caller will do with the face;
 915 it should not end in a space.
 916 STRING-DESCRIBING-DEFAULT should describe what default the caller will use if
 917 the user just types RET; you can omit it.
 918 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 919 Otherwise, return a single face."
 920   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 921                       (get-char-property (point) 'face)))
 922         (aliasfaces nil)
 923         (nonaliasfaces nil)
 924         faces)
 925     ;; Try to get a face name from the buffer.
 926     (if (memq (intern-soft (thing-at-point 'symbol)) (face-list))
 927         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 928     ;; Add the named faces that the `face' property uses.
 929     (if (and (listp faceprop)
 930              ;; Don't treat an attribute spec as a list of faces.
 931              (not (keywordp (car faceprop)))
 932              (not (memq (car faceprop) '(foreground-color background-color))))
 933         (dolist (f faceprop)
 934           (if (symbolp f)
 935               (push f faces)))
 936       (if (symbolp faceprop)
 937           (push faceprop faces)))
 938     (delete-dups faces)
 939
 940     ;; Build up the completion tables.
 941     (mapatoms (lambda (s)
 942                 (if (custom-facep s)
 943                     (if (get s 'face-alias)
 944                         (push (symbol-name s) aliasfaces)
 945                       (push (symbol-name s) nonaliasfaces)))))
 946
 947     ;; If we only want one, and the default is more than one,
 948     ;; discard the unwanted ones now.
 949     (unless multiple
 950       (if faces
 951           (setq faces (list (car faces)))))
 952     (require 'crm)
 953     (let* ((input
 954             ;; Read the input.
 955             (completing-read-multiple
 956              (if (or faces string-describing-default)
 957                  (format "%s (default %s): " prompt
 958                          (if faces (mapconcat 'symbol-name faces ",")
 959                            string-describing-default))
 960                (format "%s: " prompt))
 961              (completion-table-in-turn nonaliasfaces aliasfaces)
 962              nil t nil 'face-name-history
 963              (if faces (mapconcat 'symbol-name faces ","))))
 964            ;; Canonicalize the output.
 965            (output
 966             (cond ((or (equal input "") (equal input '("")))
 967                    faces)
 968                   ((stringp input)
 969                    (mapcar 'intern (split-string input ", *" t)))
 970                   ((listp input)
 971                    (mapcar 'intern input))
 972                   (input))))
 973       ;; Return either a list of faces or just one face.
 974       (if multiple
 975           output
 976         (car output)))))
 977
 978 ;; Not defined without X, but behind window-system test.
 979 (defvar x-bitmap-file-path)
 980
 981 (defun face-valid-attribute-values (attribute &optional frame)
 982   "Return valid values for face attribute ATTRIBUTE.
 983 The optional argument FRAME is used to determine available fonts
 984 and colors.  If it is nil or not specified, the selected frame is
 985 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 986 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 987 an integer value."
 988   (let ((valid
 989          (case attribute
 990            (:family
 991             (if (window-system frame)
 992                 (mapcar (lambda (x) (cons x x))
 993                         (font-family-list))
 994               ;; Only one font on TTYs.
 995               (list (cons "default" "default"))))
 996            (:foundry
 997             (list nil))
 998            (:width
 999             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
1000                     font-width-table))
1001            (:weight
1002             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
1003                     font-weight-table))
1004            (:slant
1005             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
1006                     font-slant-table))
1007            (:inverse-video
1008             (mapcar #'(lambda (x) (cons (symbol-name x) x))
1009                     (internal-lisp-face-attribute-values attribute)))
1010            ((:underline :overline :strike-through :box)
1011             (if (window-system frame)
1012                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
1013                                (internal-lisp-face-attribute-values attribute))
1014                        (mapcar #'(lambda (c) (cons c c))
1015                                (defined-colors frame)))
1016               (mapcar #'(lambda (x) (cons (symbol-name x) x))
1017                       (internal-lisp-face-attribute-values attribute))))
1018            ((:foreground :background)
1019             (mapcar #'(lambda (c) (cons c c))
1020                     (defined-colors frame)))
1021            ((:height)
1022             'integerp)
1023            (:stipple
1024             (and (memq (window-system frame) '(x ns)) ; No stipple on w32
1025                  (mapcar #'list
1026                          (apply #'nconc
1027                                 (mapcar (lambda (dir)
1028                                           (and (file-readable-p dir)
1029                                                (file-directory-p dir)
1030                                                (directory-files dir)))
1031                                         x-bitmap-file-path)))))
1032            (:inherit
1033             (cons '("none" . nil)
1034                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
1035                           (face-list))))
1036            (t
1037             (error "Internal error")))))
1038     (if (and (listp valid) (not (memq attribute '(:inherit))))
1039         (nconc (list (cons "unspecified" 'unspecified)) valid)
1040       valid)))
1041
1042
1043 (defvar face-attribute-name-alist
1044   '((:family . "font family")
1045     (:foundry . "font foundry")
1046     (:width . "character set width")
1047     (:height . "height in 1/10 pt")
1048     (:weight . "weight")
1049     (:slant . "slant")
1050     (:underline . "underline")
1051     (:overline . "overline")
1052     (:strike-through . "strike-through")
1053     (:box . "box")
1054     (:inverse-video . "inverse-video display")
1055     (:foreground . "foreground color")
1056     (:background . "background color")
1057     (:stipple . "background stipple")
1058     (:inherit . "inheritance"))
1059   "An alist of descriptive names for face attributes.
1060 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
1061 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
1062 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
1063
1064
1065 (defun face-descriptive-attribute-name (attribute)
1066   "Return a descriptive name for ATTRIBUTE."
1067   (cdr (assq attribute face-attribute-name-alist)))
1068
1069
1070 (defun face-read-string (face default name &optional completion-alist)
1071   "Interactively read a face attribute string value.
1072 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
1073 default string to return if no new value is entered.  NAME is a
1074 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
1075 alist of valid values, if non-nil.
1076
1077 Entering nothing accepts the default string DEFAULT.
1078 Value is the new attribute value."
1079   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
1080   ;; each word in a string separately).
1081   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
1082   (let* ((completion-ignore-case t)
1083          (value (completing-read
1084                  (if default
1085                      (format "%s for face `%s' (default %s): "
1086                              name face default)
1087                    (format "%s for face `%s': " name face))
1088                  completion-alist nil nil nil nil default)))
1089     (if (equal value "") default value)))
1090
1091
1092 (defun face-read-integer (face default name)
1093   "Interactively read an integer face attribute value.
1094 FACE is the face whose attribute is read.  DEFAULT is the default
1095 value to return if no new value is entered.  NAME is a descriptive
1096 name of the attribute for prompting.  Value is the new attribute value."
1097   (let ((new-value
1098          (face-read-string face
1099                            (format "%s" default)
1100                            name
1101                            (list (cons "unspecified" 'unspecified)))))
1102     (cond ((equal new-value "unspecified")
1103            'unspecified)
1104           ((member new-value '("unspecified-fg" "unspecified-bg"))
1105            new-value)
1106           (t
1107            (string-to-number new-value)))))
1108
1109
1110 (defun read-face-attribute (face attribute &optional frame)
1111   "Interactively read a new value for FACE's ATTRIBUTE.
1112 Optional argument FRAME nil or unspecified means read an attribute value
1113 of a global face.  Value is the new attribute value."
1114   (let* ((old-value (face-attribute face attribute frame))
1115          (attribute-name (face-descriptive-attribute-name attribute))
1116          (valid (face-valid-attribute-values attribute frame))
1117          new-value)
1118     ;; Represent complex attribute values as strings by printing them
1119     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1120     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1121     ;; SHADOW)'.
1122     (when (and (or (eq attribute :stipple)
1123                    (eq attribute :box))
1124                (or (consp old-value)
1125                    (vectorp old-value)))
1126       (setq old-value (prin1-to-string old-value)))
1127     (cond ((listp valid)
1128            (let ((default
1129                    (or (car (rassoc old-value valid))
1130                        (format "%s" old-value))))
1131              (setq new-value
1132                    (face-read-string face default attribute-name valid))
1133              (if (equal new-value default)
1134                  ;; Nothing changed, so don't bother with all the stuff
1135                  ;; below.  In particular, this avoids a non-tty color
1136                  ;; from being canonicalized for a tty when the user
1137                  ;; just uses the default.
1138                  (setq new-value old-value)
1139                ;; Terminal frames can support colors that don't appear
1140                ;; explicitly in VALID, using color approximation code
1141                ;; in tty-colors.el.
1142                (when (and (memq attribute '(:foreground :background))
1143                           (not (memq (window-system frame) '(x w32 ns)))
1144                           (not (member new-value
1145                                        '("unspecified"
1146                                          "unspecified-fg" "unspecified-bg"))))
1147                  (setq new-value (car (tty-color-desc new-value frame))))
1148                (when (assoc new-value valid)
1149                  (setq new-value (cdr (assoc new-value valid)))))))
1150           ((eq valid 'integerp)
1151            (setq new-value (face-read-integer face old-value attribute-name)))
1152           (t (error "Internal error")))
1153     ;; Convert stipple and box value text we read back to a list or
1154     ;; vector if it looks like one.  This makes the assumption that a
1155     ;; pixmap file name won't start with an open-paren.
1156     (when (and (or (eq attribute :stipple)
1157                    (eq attribute :box))
1158                (stringp new-value)
1159                (string-match "^[[(]" new-value))
1160       (setq new-value (read new-value)))
1161     new-value))
1162
1163 (declare-function fontset-list "fontset.c" ())
1164 (declare-function x-list-fonts "xfaces.c"
1165                   (pattern &optional face frame maximum width))
1166
1167 (defun read-face-font (face &optional frame)
1168   "Read the name of a font for FACE on FRAME.
1169 If optional argument FRAME is nil or omitted, use the selected frame."
1170   (let ((completion-ignore-case t))
1171     (completing-read (format "Set font attributes of face `%s' from font: " face)
1172                      (append (fontset-list) (x-list-fonts "*" nil frame)))))
1173
1174
1175 (defun read-all-face-attributes (face &optional frame)
1176   "Interactively read all attributes for FACE.
1177 If optional argument FRAME is nil or omitted, use the selected frame.
1178 Value is a property list of attribute names and new values."
1179   (let (result)
1180     (dolist (attribute face-attribute-name-alist result)
1181       (setq result (cons (car attribute)
1182                          (cons (read-face-attribute face (car attribute) frame)
1183                                result))))))
1184
1185 (defun modify-face (&optional face foreground background stipple
1186                               bold-p italic-p underline inverse-p frame)
1187   "Modify attributes of faces interactively.
1188 If optional argument FRAME is nil or omitted, modify the face used
1189 for newly created frame, i.e. the global face.
1190 For non-interactive use, `set-face-attribute' is preferred.
1191 When called from Lisp, if FACE is nil, all arguments but FRAME are ignored
1192 and the face and its settings are obtained by querying the user."
1193   (interactive)
1194   (if face
1195       (set-face-attribute face frame
1196                           :foreground (or foreground 'unspecified)
1197                           :background (or background 'unspecified)
1198                           :stipple stipple
1199                           :bold bold-p
1200                           :italic italic-p
1201                           :underline underline
1202                           :inverse-video inverse-p)
1203     (setq face (read-face-name "Modify face"))
1204     (apply #'set-face-attribute face frame
1205            (read-all-face-attributes face frame))))
1206
1207 (defun read-face-and-attribute (attribute &optional frame)
1208   "Read face name and face attribute value.
1209 ATTRIBUTE is the attribute whose new value is read.
1210 FRAME nil or unspecified means read attribute value of global face.
1211 Value is a list (FACE NEW-VALUE) where FACE is the face read
1212 \(a symbol), and NEW-VALUE is value read."
1213   (cond ((eq attribute :font)
1214          (let* ((prompt "Set font-related attributes of face")
1215                 (face (read-face-name prompt))
1216                 (font (read-face-font face frame)))
1217            (list face font)))
1218         (t
1219          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1220                 (prompt (format "Set %s of face" attribute-name))
1221                 (face (read-face-name prompt))
1222                 (new-value (read-face-attribute face attribute frame)))
1223            (list face new-value)))))
1224
1225
1226 \f
1227 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1228 ;;; Listing faces.
1229 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1230
1231 (defvar list-faces-sample-text
1232   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1233   "*Text string to display as the sample text for `list-faces-display'.")
1234
1235
1236 ;; The name list-faces would be more consistent, but let's avoid a
1237 ;; conflict with Lucid, which uses that name differently.
1238
1239 (defvar help-xref-stack)
1240 (defun list-faces-display (&optional regexp)
1241   "List all faces, using the same sample text in each.
1242 The sample text is a string that comes from the variable
1243 `list-faces-sample-text'.
1244
1245 If REGEXP is non-nil, list only those faces with names matching
1246 this regular expression.  When called interactively with a prefix
1247 arg, prompt for a regular expression."
1248   (interactive (list (and current-prefix-arg
1249                           (read-regexp "List faces matching regexp"))))
1250   (let ((all-faces (zerop (length regexp)))
1251         (frame (selected-frame))
1252         (max-length 0)
1253         faces line-format
1254         disp-frame window face-name)
1255     ;; We filter and take the max length in one pass
1256     (setq faces
1257           (delq nil
1258                 (mapcar (lambda (f)
1259                           (let ((s (symbol-name f)))
1260                             (when (or all-faces (string-match regexp s))
1261                               (setq max-length (max (length s) max-length))
1262                               f)))
1263                         (sort (face-list) #'string-lessp))))
1264     (unless faces
1265       (error "No faces matching \"%s\"" regexp))
1266     (setq max-length (1+ max-length)
1267           line-format (format "%%-%ds" max-length))
1268     (with-help-window "*Faces*"
1269       (save-excursion
1270         (set-buffer standard-output)
1271         (setq truncate-lines t)
1272         (insert
1273          (substitute-command-keys
1274           (concat
1275            "Use "
1276            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1277            "\\[help-follow] on a face name to customize it\n"
1278            "or on its sample text for a description of the face.\n\n")))
1279         (setq help-xref-stack nil)
1280         (dolist (face faces)
1281           (setq face-name (symbol-name face))
1282           (insert (format line-format face-name))
1283           ;; Hyperlink to a customization buffer for the face.  Using
1284           ;; the help xref mechanism may not be the best way.
1285           (save-excursion
1286             (save-match-data
1287               (search-backward face-name)
1288               (setq help-xref-stack-item `(list-faces-display ,regexp))
1289               (help-xref-button 0 'help-customize-face face)))
1290           (let ((beg (point))
1291                 (line-beg (line-beginning-position)))
1292             (insert list-faces-sample-text)
1293             ;; Hyperlink to a help buffer for the face.
1294             (save-excursion
1295               (save-match-data
1296                 (search-backward list-faces-sample-text)
1297                 (help-xref-button 0 'help-face face)))
1298             (insert "\n")
1299             (put-text-property beg (1- (point)) 'face face)
1300             ;; Make all face commands default to the proper face
1301             ;; anywhere in the line.
1302             (put-text-property line-beg (1- (point)) 'read-face-name face)
1303             ;; If the sample text has multiple lines, line up all of them.
1304             (goto-char beg)
1305             (forward-line 1)
1306             (while (not (eobp))
1307               (insert-char ?\s max-length)
1308               (forward-line 1))))
1309         (goto-char (point-min))))
1310     ;; If the *Faces* buffer appears in a different frame,
1311     ;; copy all the face definitions from FRAME,
1312     ;; so that the display will reflect the frame that was selected.
1313     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1314     (setq disp-frame (if window (window-frame window)
1315                        (car (frame-list))))
1316     (or (eq frame disp-frame)
1317         (let ((faces (face-list)))
1318           (while faces
1319             (copy-face (car faces) (car faces) frame disp-frame)
1320             (setq faces (cdr faces)))))))
1321
1322
1323 (defun describe-face (face &optional frame)
1324   "Display the properties of face FACE on FRAME.
1325 Interactively, FACE defaults to the faces of the character after point
1326 and FRAME defaults to the selected frame.
1327
1328 If the optional argument FRAME is given, report on face FACE in that frame.
1329 If FRAME is t, report on the defaults for face FACE (for new frames).
1330 If FRAME is omitted or nil, use the selected frame."
1331   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1332   (let* ((attrs '((:family . "Family")
1333                   (:foundry . "Foundry")
1334                   (:width . "Width")
1335                   (:height . "Height")
1336                   (:weight . "Weight")
1337                   (:slant . "Slant")
1338                   (:foreground . "Foreground")
1339                   (:background . "Background")
1340                   (:underline . "Underline")
1341                   (:overline . "Overline")
1342                   (:strike-through . "Strike-through")
1343                   (:box . "Box")
1344                   (:inverse-video . "Inverse")
1345                   (:stipple . "Stipple")
1346                   (:font . "Font")
1347                   (:fontset . "Fontset")
1348                   (:inherit . "Inherit")))
1349         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1350                                         attrs))))
1351     (help-setup-xref (list #'describe-face face)
1352                      (called-interactively-p 'interactive))
1353     (unless face
1354       (setq face 'default))
1355     (if (not (listp face))
1356         (setq face (list face)))
1357     (with-help-window (help-buffer)
1358       (save-excursion
1359         (set-buffer standard-output)
1360         (dolist (f face)
1361           (if (stringp f) (setq f (intern f)))
1362           ;; We may get called for anonymous faces (i.e., faces
1363           ;; expressed using prop-value plists).  Those can't be
1364           ;; usefully customized, so ignore them.
1365           (when (symbolp f)
1366             (insert "Face: " (symbol-name f))
1367             (if (not (facep f))
1368                 (insert "   undefined face.\n")
1369               (let ((customize-label "customize this face")
1370                     file-name)
1371                 (insert (concat " (" (propertize "sample" 'font-lock-face f) ")"))
1372                 (princ (concat " (" customize-label ")\n"))
1373                 ;; FIXME not sure how much of this belongs here, and
1374                 ;; how much in `face-documentation'.  The latter is
1375                 ;; not used much, but needs to return nil for
1376                 ;; undocumented faces.
1377                 (let ((alias (get f 'face-alias))
1378                       (face f)
1379                       obsolete)
1380                   (when alias
1381                     (setq face alias)
1382                     (insert
1383                      (format "\n  %s is an alias for the face `%s'.\n%s"
1384                              f alias
1385                              (if (setq obsolete (get f 'obsolete-face))
1386                                  (format "  This face is obsolete%s; use `%s' instead.\n"
1387                                          (if (stringp obsolete)
1388                                              (format " since %s" obsolete)
1389                                            "")
1390                                          alias)
1391                                ""))))
1392                   (insert "\nDocumentation:\n"
1393                           (or (face-documentation face)
1394                               "Not documented as a face.")
1395                           "\n\n"))
1396                 (with-current-buffer standard-output
1397                   (save-excursion
1398                     (re-search-backward
1399                      (concat "\\(" customize-label "\\)") nil t)
1400                     (help-xref-button 1 'help-customize-face f)))
1401                 (setq file-name (find-lisp-object-file-name f 'defface))
1402                 (when file-name
1403                   (princ "Defined in `")
1404                   (princ (file-name-nondirectory file-name))
1405                   (princ "'")
1406                   ;; Make a hyperlink to the library.
1407                   (save-excursion
1408                     (re-search-backward "`\\([^`']+\\)'" nil t)
1409                     (help-xref-button 1 'help-face-def f file-name))
1410                   (princ ".")
1411                   (terpri)
1412                   (terpri))
1413                 (dolist (a attrs)
1414                   (let ((attr (face-attribute f (car a) frame)))
1415                     (insert (make-string (- max-width (length (cdr a))) ?\s)
1416                             (cdr a) ": " (format "%s" attr))
1417                     (if (and (eq (car a) :inherit)
1418                              (not (eq attr 'unspecified)))
1419                         ;; Make a hyperlink to the parent face.
1420                         (save-excursion
1421                           (re-search-backward ": \\([^:]+\\)" nil t)
1422                           (help-xref-button 1 'help-face attr)))
1423                     (insert "\n")))))
1424             (terpri)))))))
1425
1426 \f
1427 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1428 ;;; Face specifications (defface).
1429 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1430
1431 ;; Parameter FRAME Is kept for call compatibility to with previous
1432 ;; face implementation.
1433
1434 (defun face-attr-construct (face &optional frame)
1435   "Return a `defface'-style attribute list for FACE on FRAME.
1436 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1437 face attributes of FACE where ATTRIBUTE is the attribute name and
1438 VALUE is the specified value of that attribute."
1439   (let (result)
1440     (dolist (entry face-attribute-name-alist result)
1441       (let* ((attribute (car entry))
1442              (value (face-attribute face attribute)))
1443         (unless (eq value 'unspecified)
1444           (setq result (nconc (list attribute value) result)))))))
1445
1446
1447 (defun face-spec-set-match-display (display frame)
1448   "Non-nil if DISPLAY matches FRAME.
1449 DISPLAY is part of a spec such as can be used in `defface'.
1450 If FRAME is nil, the current FRAME is used."
1451   (let* ((conjuncts display)
1452          conjunct req options
1453          ;; t means we have succeeded against all the conjuncts in
1454          ;; DISPLAY that have been tested so far.
1455          (match t))
1456     (if (eq conjuncts t)
1457         (setq conjuncts nil))
1458     (while (and conjuncts match)
1459       (setq conjunct (car conjuncts)
1460             conjuncts (cdr conjuncts)
1461             req (car conjunct)
1462             options (cdr conjunct)
1463             match (cond ((eq req 'type)
1464                          (or (memq (window-system frame) options)
1465                              ;; FIXME: This should be revisited to use
1466                              ;; display-graphic-p, provided that the
1467                              ;; color selection depends on the number
1468                              ;; of supported colors, and all defface's
1469                              ;; are changed to look at number of colors
1470                              ;; instead of (type graphic) etc.
1471                              (and (null (window-system frame))
1472                                   (memq 'tty options))
1473                              (and (memq 'motif options)
1474                                   (featurep 'motif))
1475                              (and (memq 'gtk options)
1476                                   (featurep 'gtk))
1477                              (and (memq 'lucid options)
1478                                   (featurep 'x-toolkit)
1479                                   (not (featurep 'motif))
1480                                   (not (featurep 'gtk)))
1481                              (and (memq 'x-toolkit options)
1482                                   (featurep 'x-toolkit))))
1483                         ((eq req 'min-colors)
1484                          (>= (display-color-cells frame) (car options)))
1485                         ((eq req 'class)
1486                          (memq (frame-parameter frame 'display-type) options))
1487                         ((eq req 'background)
1488                          (memq (frame-parameter frame 'background-mode)
1489                                options))
1490                         ((eq req 'supports)
1491                          (display-supports-face-attributes-p options frame))
1492                         (t (error "Unknown req `%S' with options `%S'"
1493                                   req options)))))
1494     match))
1495
1496
1497 (defun face-spec-choose (spec &optional frame)
1498   "Choose the proper attributes for FRAME, out of SPEC.
1499 If SPEC is nil, return nil."
1500   (unless frame
1501     (setq frame (selected-frame)))
1502   (let ((tail spec)
1503         result defaults)
1504     (while tail
1505       (let* ((entry (pop tail))
1506              (display (car entry))
1507              (attrs (cdr entry))
1508              thisval)
1509         ;; Get the attributes as actually specified by this alternative.
1510         (setq thisval
1511               (if (null (cdr attrs)) ;; was (listp (car attrs))
1512                   ;; Old-style entry, the attribute list is the
1513                   ;; first element.
1514                   (car attrs)
1515                 attrs))
1516
1517         ;; If the condition is `default', that sets the default
1518         ;; for following conditions.
1519         (if (eq display 'default)
1520             (setq defaults thisval)
1521           ;; Otherwise, if it matches, use it.
1522           (when (face-spec-set-match-display display frame)
1523             (setq result thisval)
1524             (setq tail nil)))))
1525     (if defaults (append result defaults) result)))
1526
1527
1528 (defun face-spec-reset-face (face &optional frame)
1529   "Reset all attributes of FACE on FRAME to unspecified."
1530   (let ((attrs face-attribute-name-alist))
1531     (while attrs
1532       (let ((attr-and-name (car attrs)))
1533         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1534       (setq attrs (cdr attrs)))))
1535
1536
1537 (defun face-spec-set (face spec &optional for-defface)
1538   "Set FACE's face spec, which controls its appearance, to SPEC.
1539 If FOR-DEFFACE is t, set the base spec, the one that `defface'
1540   and Custom set.  (In that case, the caller must put it in the
1541   appropriate property, because that depends on the caller.)
1542 If FOR-DEFFACE is nil, set the overriding spec (and store it
1543   in the `face-override-spec' property of FACE).
1544
1545 The appearance of FACE is controlled by the base spec,
1546 by any custom theme specs on top of that, and by the
1547 overriding spec on top of all the rest.
1548
1549 FOR-DEFFACE can also be a frame, in which case we set the
1550 frame-specific attributes of FACE for that frame based on SPEC.
1551 That usage is deprecated.
1552
1553 See `defface' for information about the format and meaning of SPEC."
1554   (if (framep for-defface)
1555       ;; Handle the deprecated case where third arg is a frame.
1556       (face-spec-set-2 face for-defface spec)
1557     (if for-defface
1558         ;; When we reset the face based on its custom spec, then it is
1559         ;; unmodified as far as Custom is concerned.
1560         (put (or (get face 'face-alias) face) 'face-modified nil)
1561       ;; When we change a face based on a spec from outside custom,
1562       ;; record it for future frames.
1563       (put (or (get face 'face-alias) face) 'face-override-spec spec))
1564     ;; Reset each frame according to the rules implied by all its specs.
1565     (dolist (frame (frame-list))
1566       (face-spec-recalc face frame))))
1567
1568 (defun face-spec-recalc (face frame)
1569   "Reset the face attributes of FACE on FRAME according to its specs.
1570 This applies the defface/custom spec first, then the custom theme specs,
1571 then the override spec."
1572   (face-spec-reset-face face frame)
1573   (let ((face-sym (or (get face 'face-alias) face)))
1574     (or (get face 'customized-face)
1575         (get face 'saved-face)
1576         (face-spec-set-2 face frame (face-default-spec face)))
1577     (let ((theme-faces (reverse (get face-sym 'theme-face))))
1578       (dolist (spec theme-faces)
1579         (face-spec-set-2 face frame (cadr spec))))
1580     (face-spec-set-2 face frame (get face-sym 'face-override-spec))))
1581
1582 (defun face-spec-set-2 (face frame spec)
1583   "Set the face attributes of FACE on FRAME according to SPEC."
1584   (let* ((spec (face-spec-choose spec frame))
1585          attrs)
1586     (while spec
1587       (when (assq (car spec) face-x-resources)
1588         (push (car spec) attrs)
1589         (push (cadr spec) attrs))
1590       (setq spec (cddr spec)))
1591     (apply 'set-face-attribute face frame (nreverse attrs))))
1592
1593 (defun face-attr-match-p (face attrs &optional frame)
1594   "Return t if attributes of FACE match values in plist ATTRS.
1595 Optional parameter FRAME is the frame whose definition of FACE
1596 is used.  If nil or omitted, use the selected frame."
1597   (unless frame
1598     (setq frame (selected-frame)))
1599   (let ((list face-attribute-name-alist)
1600         (match t))
1601     (while (and match (not (null list)))
1602       (let* ((attr (car (car list)))
1603              (specified-value
1604               (if (plist-member attrs attr)
1605                   (plist-get attrs attr)
1606                 'unspecified))
1607              (value-now (face-attribute face attr frame)))
1608         (setq match (equal specified-value value-now))
1609         (setq list (cdr list))))
1610     match))
1611
1612 (defun face-spec-match-p (face spec &optional frame)
1613   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1614   (face-attr-match-p face (face-spec-choose spec frame) frame))
1615
1616 (defsubst face-default-spec (face)
1617   "Return the default face-spec for FACE, ignoring any user customization.
1618 If there is no default for FACE, return nil."
1619   (get face 'face-defface-spec))
1620
1621 (defsubst face-user-default-spec (face)
1622   "Return the user's customized face-spec for FACE, or the default if none.
1623 If there is neither a user setting nor a default for FACE, return nil."
1624   (or (get face 'customized-face)
1625       (get face 'saved-face)
1626       (face-default-spec face)))
1627
1628 \f
1629 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1630 ;;; Frame-type independent color support.
1631 ;;; We keep the old x-* names as aliases for back-compatibility.
1632 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1633
1634 (defun defined-colors (&optional frame)
1635   "Return a list of colors supported for a particular frame.
1636 The argument FRAME specifies which frame to try.
1637 The value may be different for frames on different display types.
1638 If FRAME doesn't support colors, the value is nil.
1639 If FRAME is nil, that stands for the selected frame."
1640   (if (memq (framep (or frame (selected-frame))) '(x w32 ns))
1641       (xw-defined-colors frame)
1642     (mapcar 'car (tty-color-alist frame))))
1643 (defalias 'x-defined-colors 'defined-colors)
1644
1645 (declare-function xw-color-defined-p "xfns.c" (color &optional frame))
1646
1647 (defun color-defined-p (color &optional frame)
1648   "Return non-nil if color COLOR is supported on frame FRAME.
1649 If FRAME is omitted or nil, use the selected frame.
1650 If COLOR is the symbol `unspecified' or one of the strings
1651 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1652   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1653       nil
1654     (if (member (framep (or frame (selected-frame))) '(x w32 ns))
1655         (xw-color-defined-p color frame)
1656       (numberp (tty-color-translate color frame)))))
1657 (defalias 'x-color-defined-p 'color-defined-p)
1658
1659 (declare-function xw-color-values "xfns.c" (color &optional frame))
1660
1661 (defun color-values (color &optional frame)
1662   "Return a description of the color named COLOR on frame FRAME.
1663 The value is a list of integer RGB values--(RED GREEN BLUE).
1664 These values appear to range from 0 to 65280 or 65535, depending
1665 on the system; white is \(65280 65280 65280\) or \(65535 65535 65535\).
1666 If FRAME is omitted or nil, use the selected frame.
1667 If FRAME cannot display COLOR, the value is nil.
1668 If COLOR is the symbol `unspecified' or one of the strings
1669 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1670   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1671       nil
1672     (if (memq (framep (or frame (selected-frame))) '(x w32 ns))
1673         (xw-color-values color frame)
1674       (tty-color-values color frame))))
1675 (defalias 'x-color-values 'color-values)
1676
1677 (declare-function xw-display-color-p "xfns.c" (&optional terminal))
1678
1679 (defun display-color-p (&optional display)
1680   "Return t if DISPLAY supports color.
1681 The optional argument DISPLAY specifies which display to ask about.
1682 DISPLAY should be either a frame or a display name (a string).
1683 If omitted or nil, that stands for the selected frame's display."
1684   (if (memq (framep-on-display display) '(x w32 ns))
1685       (xw-display-color-p display)
1686     (tty-display-color-p display)))
1687 (defalias 'x-display-color-p 'display-color-p)
1688
1689 (declare-function x-display-grayscale-p "xfns.c" (&optional terminal))
1690
1691 (defun display-grayscale-p (&optional display)
1692   "Return non-nil if frames on DISPLAY can display shades of gray."
1693   (let ((frame-type (framep-on-display display)))
1694     (cond
1695      ((memq frame-type '(x w32 ns))
1696       (x-display-grayscale-p display))
1697      (t
1698       (> (tty-color-gray-shades display) 2)))))
1699
1700 (defun read-color (&optional prompt convert-to-RGB-p allow-empty-name-p msg-p)
1701   "Read a color name or RGB hex value: #RRRRGGGGBBBB.
1702 Completion is available for color names, but not for RGB hex strings.
1703 If the user inputs an RGB hex string, it must have the form
1704 #XXXXXXXXXXXX or XXXXXXXXXXXX, where each X is a hex digit.  The
1705 number of Xs must be a multiple of 3, with the same number of Xs for
1706 each of red, green, and blue.  The order is red, green, blue.
1707
1708 In addition to standard color names and RGB hex values, the following
1709 are available as color candidates.  In each case, the corresponding
1710 color is used.
1711
1712  * `foreground at point'   - foreground under the cursor
1713  * `background at point'   - background under the cursor
1714
1715 Checks input to be sure it represents a valid color.  If not, raises
1716 an error (but see exception for empty input with non-nil
1717 ALLOW-EMPTY-NAME-P).
1718
1719 Optional arg PROMPT is the prompt; if nil, uses a default prompt.
1720
1721 Interactively, or with optional arg CONVERT-TO-RGB-P non-nil, converts
1722 an input color name to an RGB hex string.  Returns the RGB hex string.
1723
1724 Optional arg ALLOW-EMPTY-NAME-P controls what happens if the user
1725 enters an empty color name (that is, just hits `RET').  If non-nil,
1726 then returns an empty color name, \"\".  If nil, then raises an error.
1727 Programs must test for \"\" if ALLOW-EMPTY-NAME-P is non-nil.  They
1728 can then perform an appropriate action in case of empty input.
1729
1730 Interactively, or with optional arg MSG-P non-nil, echoes the color in
1731 a message."
1732   (interactive "i\np\ni\np")    ; Always convert to RGB interactively.
1733   (let* ((completion-ignore-case t)
1734          (colors (append '("foreground at point" "background at point")
1735                          (defined-colors)))
1736          (color (completing-read (or prompt "Color (name or #R+G+B+): ")
1737                                  colors))
1738          hex-string)
1739     (cond ((string= "foreground at point" color)
1740            (setq color (foreground-color-at-point)))
1741           ((string= "background at point" color)
1742            (setq color (background-color-at-point))))
1743     (unless color
1744       (setq color ""))
1745     (setq hex-string
1746           (string-match "^#?\\([a-fA-F0-9][a-fA-F0-9][a-fA-F0-9]\\)+$" color))
1747     (if (and allow-empty-name-p (string= "" color))
1748         ""
1749       (when (and hex-string (not (eq (aref color 0) ?#)))
1750         (setq color (concat "#" color))) ; No #; add it.
1751       (unless hex-string
1752         (when (or (string= "" color) (not (test-completion color colors)))
1753           (error "No such color: %S" color))
1754         (when convert-to-RGB-p
1755           (let ((components (x-color-values color)))
1756             (unless components (error "No such color: %S" color))
1757             (unless (string-match "^#\\([a-fA-F0-9][a-fA-F0-9][a-fA-F0-9]\\)+$" color)
1758               (setq color (format "#%04X%04X%04X"
1759                                   (logand 65535 (nth 0 components))
1760                                   (logand 65535 (nth 1 components))
1761                                   (logand 65535 (nth 2 components))))))))
1762       (when msg-p (message "Color: `%s'" color))
1763       color)))
1764
1765 ;; Commented out because I decided it is better to include the
1766 ;; duplicates in read-color's completion list.
1767
1768 ;; (defun defined-colors-without-duplicates ()
1769 ;;   "Return the list of defined colors, without the no-space versions.
1770 ;; For each color name, we keep the variant that DOES have spaces."
1771 ;;   (let ((result (copy-sequence (defined-colors)))
1772 ;;         to-be-rejected)
1773 ;;     (save-match-data
1774 ;;       (dolist (this result)
1775 ;;         (if (string-match " " this)
1776 ;;             (push (replace-regexp-in-string " " ""
1777 ;;                                             this)
1778 ;;                   to-be-rejected)))
1779 ;;       (dolist (elt to-be-rejected)
1780 ;;         (let ((as-found (car (member-ignore-case elt result))))
1781 ;;           (setq result (delete as-found result)))))
1782 ;;     result))
1783
1784 (defun face-at-point ()
1785   "Return the face of the character after point.
1786 If it has more than one face, return the first one.
1787 Return nil if it has no specified face."
1788   (let* ((faceprop (or (get-char-property (point) 'read-face-name)
1789                        (get-char-property (point) 'face)
1790                        'default))
1791          (face (cond ((symbolp faceprop) faceprop)
1792                      ;; List of faces (don't treat an attribute spec).
1793                      ;; Just use the first face.
1794                      ((and (consp faceprop) (not (keywordp (car faceprop)))
1795                            (not (memq (car faceprop)
1796                                       '(foreground-color background-color))))
1797                       (car faceprop))
1798                      (t nil))))         ; Invalid face value.
1799     (if (facep face) face nil)))
1800
1801 (defun foreground-color-at-point ()
1802   "Return the foreground color of the character after point."
1803   ;; `face-at-point' alone is not sufficient.  It only gets named faces.
1804   ;; Need also pick up any face properties that are not associated with named faces.
1805   (let ((face (or (face-at-point)
1806                   (get-char-property (point) 'read-face-name)
1807                   (get-char-property (point) 'face))))
1808     (cond ((and face (symbolp face))
1809            (let ((value (face-foreground face nil 'default)))
1810              (if (member value '("unspecified-fg" "unspecified-bg"))
1811                  nil
1812                value)))
1813           ((consp face)
1814            (cond ((memq 'foreground-color face) (cdr (memq 'foreground-color face)))
1815                  ((memq ':foreground face) (cadr (memq ':foreground face)))))
1816           (t nil))))                    ; Invalid face value.
1817
1818 (defun background-color-at-point ()
1819   "Return the background color of the character after point."
1820   ;; `face-at-point' alone is not sufficient.  It only gets named faces.
1821   ;; Need also pick up any face properties that are not associated with named faces.
1822   (let ((face (or (face-at-point)
1823                   (get-char-property (point) 'read-face-name)
1824                   (get-char-property (point) 'face))))
1825     (cond ((and face (symbolp face))
1826            (let ((value (face-background face nil 'default)))
1827              (if (member value '("unspecified-fg" "unspecified-bg"))
1828                  nil
1829                value)))
1830           ((consp face)
1831            (cond ((memq 'background-color face) (cdr (memq 'background-color face)))
1832                  ((memq ':background face) (cadr (memq ':background face)))))
1833           (t nil))))                    ; Invalid face value.
1834 \f
1835 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1836 ;;; Background mode.
1837 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1838
1839 (defcustom frame-background-mode nil
1840   "The brightness of the background.
1841 Set this to the symbol `dark' if your background color is dark,
1842 `light' if your background is light, or nil (automatic by default)
1843 if you want Emacs to examine the brightness for you.  Don't set this
1844 variable with `setq'; this won't have the expected effect."
1845   :group 'faces
1846   :set #'(lambda (var value)
1847            (set-default var value)
1848            (mapc 'frame-set-background-mode (frame-list)))
1849   :initialize 'custom-initialize-changed
1850   :type '(choice (const dark)
1851                  (const light)
1852                  (const :tag "automatic" nil)))
1853
1854
1855 (declare-function x-get-resource "frame.c"
1856                   (attribute class &optional component subclass))
1857
1858 (defvar inhibit-frame-set-background-mode nil)
1859
1860 (defun frame-set-background-mode (frame)
1861   "Set up display-dependent faces on FRAME.
1862 Display-dependent faces are those which have different definitions
1863 according to the `background-mode' and `display-type' frame parameters."
1864   (unless inhibit-frame-set-background-mode
1865     (let* ((bg-resource
1866             (and (window-system frame)
1867                  (x-get-resource "backgroundMode" "BackgroundMode")))
1868            (bg-color (frame-parameter frame 'background-color))
1869            (terminal-bg-mode (terminal-parameter frame 'background-mode))
1870            (tty-type (tty-type frame))
1871            (default-bg-mode
1872              (if (or (window-system frame)
1873                      (and tty-type
1874                           (string-match "^\\(xterm\\|\\rxvt\\|dtterm\\|eterm\\)"
1875                                         tty-type)))
1876                  'light
1877                'dark))
1878            (non-default-bg-mode (if (eq default-bg-mode 'light) 'dark 'light))
1879            (bg-mode
1880             (cond (frame-background-mode)
1881                   (bg-resource (intern (downcase bg-resource)))
1882                   (terminal-bg-mode)
1883                   ((equal bg-color "unspecified-fg") ; inverted colors
1884                    non-default-bg-mode)
1885                   ((not (color-values bg-color frame))
1886                    default-bg-mode)
1887                   ((>= (apply '+ (color-values bg-color frame))
1888                        ;; Just looking at the screen, colors whose
1889                        ;; values add up to .6 of the white total
1890                        ;; still look dark to me.
1891                        (* (apply '+ (color-values "white" frame)) .6))
1892                    'light)
1893                   (t 'dark)))
1894            (display-type
1895             (cond ((null (window-system frame))
1896                    (if (tty-display-color-p frame) 'color 'mono))
1897                   ((display-color-p frame)
1898                    'color)
1899                   ((x-display-grayscale-p frame)
1900                    'grayscale)
1901                   (t 'mono)))
1902            (old-bg-mode
1903             (frame-parameter frame 'background-mode))
1904            (old-display-type
1905             (frame-parameter frame 'display-type)))
1906
1907       (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1908         (let ((locally-modified-faces nil)
1909               ;; Prevent face-spec-recalc from calling this function
1910               ;; again, resulting in a loop (bug#911).
1911               (inhibit-frame-set-background-mode t))
1912           ;; Before modifying the frame parameters, collect a list of
1913           ;; faces that don't match what their face-spec says they
1914           ;; should look like.  We then avoid changing these faces
1915           ;; below.  These are the faces whose attributes were
1916           ;; modified on FRAME.  We use a negative list on the
1917           ;; assumption that most faces will be unmodified, so we can
1918           ;; avoid consing in the common case.
1919           (dolist (face (face-list))
1920             (and (not (get face 'face-override-spec))
1921                  (not (face-spec-match-p face
1922                                          (face-user-default-spec face)
1923                                          (selected-frame)))
1924                  (push face locally-modified-faces)))
1925           ;; Now change to the new frame parameters
1926           (modify-frame-parameters frame
1927                                    (list (cons 'background-mode bg-mode)
1928                                          (cons 'display-type display-type)))
1929           ;; For all named faces, choose face specs matching the new frame
1930           ;; parameters, unless they have been locally modified.
1931           (dolist (face (face-list))
1932             (unless (memq face locally-modified-faces)
1933               (face-spec-recalc face frame))))))))
1934
1935 \f
1936 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1937 ;;; Frame creation.
1938 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1939
1940 (declare-function x-parse-geometry "frame.c" (string))
1941
1942 (defun x-handle-named-frame-geometry (parameters)
1943   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1944 Value is the new parameter list."
1945   ;; Note that `x-resource-name' has a global meaning.
1946   (let ((x-resource-name (or (cdr (assq 'name parameters))
1947                              (cdr (assq 'name default-frame-alist)))))
1948     (when x-resource-name
1949       ;; Before checking X resources, we must have an X connection.
1950       (or (window-system)
1951           (x-display-list)
1952           (x-open-connection (or (cdr (assq 'display parameters))
1953                                  x-display-name)))
1954       (let (res-geometry parsed)
1955         (and (setq res-geometry (x-get-resource "geometry" "Geometry"))
1956              (setq parsed (x-parse-geometry res-geometry))
1957              (setq parameters
1958                    (append parameters default-frame-alist parsed
1959                            ;; If the resource specifies a position,
1960                            ;; take note of that.
1961                            (if (or (assq 'top parsed) (assq 'left parsed))
1962                                '((user-position . t) (user-size . t)))))))))
1963   parameters)
1964
1965
1966 (defun x-handle-reverse-video (frame parameters)
1967   "Handle the reverse-video frame parameter and X resource.
1968 `x-create-frame' does not handle this one."
1969   (when (cdr (or (assq 'reverse parameters)
1970                  (assq 'reverse default-frame-alist)
1971                  (let ((resource (x-get-resource "reverseVideo"
1972                                                  "ReverseVideo")))
1973                    (if resource
1974                        (cons nil (member (downcase resource)
1975                                          '("on" "true")))))))
1976       (let* ((params (frame-parameters frame))
1977              (bg (cdr (assq 'foreground-color params)))
1978              (fg (cdr (assq 'background-color params))))
1979         (modify-frame-parameters frame
1980                                  (list (cons 'foreground-color fg)
1981                                        (cons 'background-color bg)))
1982         (if (equal bg (cdr (assq 'border-color params)))
1983             (modify-frame-parameters frame
1984                                      (list (cons 'border-color fg))))
1985         (if (equal bg (cdr (assq 'mouse-color params)))
1986             (modify-frame-parameters frame
1987                                      (list (cons 'mouse-color fg))))
1988         (if (equal bg (cdr (assq 'cursor-color params)))
1989             (modify-frame-parameters frame
1990                                      (list (cons 'cursor-color fg)))))))
1991
1992 (declare-function x-create-frame "xfns.c" (parms))
1993 (declare-function x-setup-function-keys "term/x-win" (frame))
1994
1995 (defun x-create-frame-with-faces (&optional parameters)
1996   "Create a frame from optional frame parameters PARAMETERS.
1997 Parameters not specified by PARAMETERS are taken from
1998 `default-frame-alist'.  If PARAMETERS specify a frame name,
1999 handle X geometry resources for that name.  If either PARAMETERS
2000 or `default-frame-alist' contains a `reverse' parameter, or
2001 the X resource ``reverseVideo'' is present, handle that.
2002 Value is the new frame created."
2003   (setq parameters (x-handle-named-frame-geometry parameters))
2004   (let* ((params (copy-tree parameters))
2005          (visibility-spec (assq 'visibility parameters))
2006          (delayed-params '(foreground-color background-color font
2007                            border-color cursor-color mouse-color
2008                            visibility scroll-bar-foreground
2009                            scroll-bar-background))
2010          frame success)
2011     (dolist (param delayed-params)
2012       (setq params (assq-delete-all param params)))
2013     (setq frame (x-create-frame `((visibility . nil) . ,params)))
2014     (unwind-protect
2015         (progn
2016           (x-setup-function-keys frame)
2017           (x-handle-reverse-video frame parameters)
2018           (frame-set-background-mode frame)
2019           (face-set-after-frame-default frame parameters)
2020           (if (null visibility-spec)
2021               (make-frame-visible frame)
2022             (modify-frame-parameters frame (list visibility-spec)))
2023           (setq success t))
2024       (unless success
2025         (delete-frame frame)))
2026     frame))
2027
2028 (defun face-set-after-frame-default (frame &optional parameters)
2029   "Initialize the frame-local faces of FRAME.
2030 Calculate the face definitions using the face specs, custom theme
2031 settings, X resources, and `face-new-frame-defaults'.
2032 Finally, apply any relevant face attributes found amongst the
2033 frame parameters in PARAMETERS and `default-frame-alist'."
2034   (dolist (face (nreverse (face-list)))
2035     (condition-case ()
2036         (progn
2037           ;; Initialize faces from face spec and custom theme.
2038           (face-spec-recalc face frame)
2039           ;; X resouces for the default face are applied during
2040           ;; x-create-frame.
2041           (and (not (eq face 'default))
2042                (memq (window-system frame) '(x w32))
2043                (make-face-x-resource-internal face frame))
2044           ;; Apply attributes specified by face-new-frame-defaults
2045           (internal-merge-in-global-face face frame))
2046       ;; Don't let invalid specs prevent frame creation.
2047       (error nil)))
2048   ;; Apply attributes specified by frame parameters.
2049   (let ((face-params '((foreground-color default :foreground)
2050                        (background-color default :background)
2051                        (font default :font)
2052                        (border-color border :background)
2053                        (cursor-color cursor :background)
2054                        (scroll-bar-foreground scroll-bar :foreground)
2055                        (scroll-bar-background scroll-bar :background)
2056                        (mouse-color mouse :background))))
2057     (dolist (param face-params)
2058       (let* ((param-name (nth 0 param))
2059              (value (cdr (or (assq param-name parameters)
2060                              (assq param-name default-frame-alist)))))
2061         (if value
2062             (set-face-attribute (nth 1 param) frame
2063                                 (nth 2 param) value))))))
2064
2065 (defun tty-handle-reverse-video (frame parameters)
2066   "Handle the reverse-video frame parameter for terminal frames."
2067   (when (cdr (or (assq 'reverse parameters)
2068                  (assq 'reverse default-frame-alist)))
2069     (let* ((params (frame-parameters frame))
2070            (bg (cdr (assq 'foreground-color params)))
2071            (fg (cdr (assq 'background-color params))))
2072       (modify-frame-parameters frame
2073                                (list (cons 'foreground-color fg)
2074                                      (cons 'background-color bg)))
2075       (if (equal bg (cdr (assq 'mouse-color params)))
2076           (modify-frame-parameters frame
2077                                    (list (cons 'mouse-color fg))))
2078       (if (equal bg (cdr (assq 'cursor-color params)))
2079           (modify-frame-parameters frame
2080                                    (list (cons 'cursor-color fg)))))))
2081
2082
2083 (defun tty-create-frame-with-faces (&optional parameters)
2084   "Create a frame from optional frame parameters PARAMETERS.
2085 Parameters not specified by PARAMETERS are taken from
2086 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
2087 contains a `reverse' parameter, handle that.  Value is the new frame
2088 created."
2089   (let ((frame (make-terminal-frame parameters))
2090         success)
2091     (unwind-protect
2092         (with-selected-frame frame
2093           (tty-handle-reverse-video frame (frame-parameters frame))
2094
2095           (unless (terminal-parameter frame 'terminal-initted)
2096             (set-terminal-parameter frame 'terminal-initted t)
2097             (set-locale-environment nil frame)
2098             (tty-run-terminal-initialization frame))
2099           (frame-set-background-mode frame)
2100           (face-set-after-frame-default frame parameters)
2101           (setq success t))
2102       (unless success
2103         (delete-frame frame)))
2104     frame))
2105
2106 (defun tty-find-type (pred type)
2107   "Return the longest prefix of TYPE to which PRED returns non-nil.
2108 TYPE should be a tty type name such as \"xterm-16color\".
2109
2110 The function tries only those prefixes that are followed by a
2111 dash or underscore in the original type name, like \"xterm\" in
2112 the above example."
2113   (let (hyphend)
2114     (while (and type
2115                 (not (funcall pred type)))
2116       ;; Strip off last hyphen and what follows, then try again
2117       (setq type
2118             (if (setq hyphend (string-match "[-_][^-_]+$" type))
2119                 (substring type 0 hyphend)
2120               nil))))
2121   type)
2122
2123 (defun tty-run-terminal-initialization (frame &optional type)
2124   "Run the special initialization code for the terminal type of FRAME.
2125 The optional TYPE parameter may be used to override the autodetected
2126 terminal type to a different value."
2127   (setq type (or type (tty-type frame)))
2128   ;; Load library for our terminal type.
2129   ;; User init file can set term-file-prefix to nil to prevent this.
2130   (with-selected-frame frame
2131     (unless (null term-file-prefix)
2132       (let* (term-init-func)
2133         ;; First, load the terminal initialization file, if it is
2134         ;; available and it hasn't been loaded already.
2135         (tty-find-type #'(lambda (type)
2136                            (let ((file (locate-library (concat term-file-prefix type))))
2137                              (and file
2138                                   (or (assoc file load-history)
2139                                       (load file t t)))))
2140                        type)
2141         ;; Next, try to find a matching initialization function, and call it.
2142         (tty-find-type #'(lambda (type)
2143                            (fboundp (setq term-init-func
2144                                           (intern (concat "terminal-init-" type)))))
2145                        type)
2146         (when (fboundp term-init-func)
2147           (funcall term-init-func))
2148         (set-terminal-parameter frame 'terminal-initted term-init-func)))))
2149
2150 ;; Called from C function init_display to initialize faces of the
2151 ;; dumped terminal frame on startup.
2152
2153 (defun tty-set-up-initial-frame-faces ()
2154   (let ((frame (selected-frame)))
2155     (frame-set-background-mode frame)
2156     (face-set-after-frame-default frame)))
2157
2158
2159
2160 \f
2161 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2162 ;;; Compatiblity with 20.2
2163 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2164
2165 ;; Update a frame's faces when we change its default font.
2166
2167 (defalias 'frame-update-faces 'ignore "")
2168 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
2169
2170 ;; Update the colors of FACE, after FRAME's own colors have been
2171 ;; changed.
2172
2173 (define-obsolete-function-alias 'frame-update-face-colors
2174     'frame-set-background-mode "21.1")
2175
2176 \f
2177 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2178 ;;; Standard faces.
2179 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2180
2181 (defgroup basic-faces nil
2182   "The standard faces of Emacs."
2183   :group 'faces)
2184
2185 (defface default
2186   '((t nil)) ; If this were nil, face-defface-spec would not be set.
2187   "Basic default face."
2188   :group 'basic-faces)
2189
2190 (defface bold
2191   '((t :weight bold))
2192   "Basic bold face."
2193   :group 'basic-faces)
2194
2195 (defface italic
2196   '((((supports :slant italic))
2197      :slant italic)
2198     (((supports :underline t))
2199      :underline t)
2200     (t
2201      ;; default to italic, even it doesn't appear to be supported,
2202      ;; because in some cases the display engine will do it's own
2203      ;; workaround (to `dim' on ttys)
2204      :slant italic))
2205   "Basic italic face."
2206   :group 'basic-faces)
2207
2208 (defface bold-italic
2209   '((t :weight bold :slant italic))
2210   "Basic bold-italic face."
2211   :group 'basic-faces)
2212
2213 (defface underline
2214   '((((supports :underline t))
2215      :underline t)
2216     (((supports :weight bold))
2217      :weight bold)
2218     (t :underline t))
2219   "Basic underlined face."
2220   :group 'basic-faces)
2221
2222 (defface fixed-pitch
2223   '((t :family "Monospace"))
2224   "The basic fixed-pitch face."
2225   :group 'basic-faces)
2226
2227 (defface variable-pitch
2228   '((t :family "Sans Serif"))
2229   "The basic variable-pitch face."
2230   :group 'basic-faces)
2231
2232 (defface shadow
2233   '((((class color grayscale) (min-colors 88) (background light))
2234      :foreground "grey50")
2235     (((class color grayscale) (min-colors 88) (background dark))
2236      :foreground "grey70")
2237     (((class color) (min-colors 8) (background light))
2238      :foreground "green")
2239     (((class color) (min-colors 8) (background dark))
2240      :foreground "yellow"))
2241   "Basic face for shadowed text."
2242   :group 'basic-faces
2243   :version "22.1")
2244
2245 (defface link
2246   '((((class color) (min-colors 88) (background light))
2247      :foreground "blue1" :underline t)
2248     (((class color) (background light))
2249      :foreground "blue" :underline t)
2250     (((class color) (min-colors 88) (background dark))
2251      :foreground "cyan1" :underline t)
2252     (((class color) (background dark))
2253      :foreground "cyan" :underline t)
2254     (t :inherit underline))
2255   "Basic face for unvisited links."
2256   :group 'basic-faces
2257   :version "22.1")
2258
2259 (defface link-visited
2260   '((default :inherit link)
2261     (((class color) (background light)) :foreground "magenta4")
2262     (((class color) (background dark)) :foreground "violet"))
2263   "Basic face for visited links."
2264   :group 'basic-faces
2265   :version "22.1")
2266
2267 (defface highlight
2268   '((((class color) (min-colors 88) (background light))
2269      :background "darkseagreen2")
2270     (((class color) (min-colors 88) (background dark))
2271      :background "darkolivegreen")
2272     (((class color) (min-colors 16) (background light))
2273      :background "darkseagreen2")
2274     (((class color) (min-colors 16) (background dark))
2275      :background "darkolivegreen")
2276     (((class color) (min-colors 8))
2277      :background "green" :foreground "black")
2278     (t :inverse-video t))
2279   "Basic face for highlighting."
2280   :group 'basic-faces)
2281
2282 ;; Region face: under NS, default to the system-defined selection
2283 ;; color (optimized for the fixed white background of other apps),
2284 ;; if background is light.
2285 (defface region
2286   '((((class color) (min-colors 88) (background dark))
2287      :background "blue3")
2288     (((class color) (min-colors 88) (background light) (type ns))
2289      :background "ns_selection_color")
2290     (((class color) (min-colors 88) (background light))
2291      :background "lightgoldenrod2")
2292     (((class color) (min-colors 16) (background dark))
2293      :background "blue3")
2294     (((class color) (min-colors 16) (background light))
2295      :background "lightgoldenrod2")
2296     (((class color) (min-colors 8))
2297      :background "blue" :foreground "white")
2298     (((type tty) (class mono))
2299      :inverse-video t)
2300     (t :background "gray"))
2301   "Basic face for highlighting the region."
2302   :version "21.1"
2303   :group 'basic-faces)
2304
2305 (defface secondary-selection
2306   '((((class color) (min-colors 88) (background light))
2307      :background "yellow1")
2308     (((class color) (min-colors 88) (background dark))
2309      :background "SkyBlue4")
2310     (((class color) (min-colors 16) (background light))
2311      :background "yellow")
2312     (((class color) (min-colors 16) (background dark))
2313      :background "SkyBlue4")
2314     (((class color) (min-colors 8))
2315      :background "cyan" :foreground "black")
2316     (t :inverse-video t))
2317   "Basic face for displaying the secondary selection."
2318   :group 'basic-faces)
2319
2320 (defface trailing-whitespace
2321   '((((class color) (background light))
2322      :background "red1")
2323     (((class color) (background dark))
2324      :background "red1")
2325     (t :inverse-video t))
2326   "Basic face for highlighting trailing whitespace."
2327   :version "21.1"
2328   :group 'whitespace-faces      ; like `show-trailing-whitespace'
2329   :group 'basic-faces)
2330
2331 (defface escape-glyph
2332   '((((background dark)) :foreground "cyan")
2333     ;; See the comment in minibuffer-prompt for
2334     ;; the reason not to use blue on MS-DOS.
2335     (((type pc)) :foreground "magenta")
2336     ;; red4 is too dark, but some say blue is too loud.
2337     ;; brown seems to work ok. -- rms.
2338     (t :foreground "brown"))
2339   "Face for characters displayed as sequences using `^' or `\\'."
2340   :group 'basic-faces
2341   :version "22.1")
2342
2343 (defface nobreak-space
2344   '((((class color) (min-colors 88)) :inherit escape-glyph :underline t)
2345     (((class color) (min-colors 8)) :background "magenta")
2346     (t :inverse-video t))
2347   "Face for displaying nobreak space."
2348   :group 'basic-faces
2349   :version "22.1")
2350
2351 (defgroup mode-line-faces nil
2352   "Faces used in the mode line."
2353   :group 'mode-line
2354   :group 'faces
2355   :version "22.1")
2356
2357 (defface mode-line
2358   '((((class color) (min-colors 88))
2359      :box (:line-width -1 :style released-button)
2360      :background "grey75" :foreground "black")
2361     (t
2362      :inverse-video t))
2363   "Basic mode line face for selected window."
2364   :version "21.1"
2365   :group 'mode-line-faces
2366   :group 'basic-faces)
2367 ;; No need to define aliases of this form for new faces.
2368 (define-obsolete-face-alias 'modeline 'mode-line "21.1")
2369
2370 (defface mode-line-inactive
2371   '((default
2372      :inherit mode-line)
2373     (((class color) (min-colors 88) (background light))
2374      :weight light
2375      :box (:line-width -1 :color "grey75" :style nil)
2376      :foreground "grey20" :background "grey90")
2377     (((class color) (min-colors 88) (background dark) )
2378      :weight light
2379      :box (:line-width -1 :color "grey40" :style nil)
2380      :foreground "grey80" :background "grey30"))
2381   "Basic mode line face for non-selected windows."
2382   :version "22.1"
2383   :group 'mode-line-faces
2384   :group 'basic-faces)
2385 (define-obsolete-face-alias 'modeline-inactive 'mode-line-inactive "22.1")
2386
2387 (defface mode-line-highlight
2388   '((((class color) (min-colors 88))
2389      :box (:line-width 2 :color "grey40" :style released-button))
2390     (t
2391      :inherit highlight))
2392   "Basic mode line face for highlighting."
2393   :version "22.1"
2394   :group 'mode-line-faces
2395   :group 'basic-faces)
2396 (define-obsolete-face-alias 'modeline-highlight 'mode-line-highlight "22.1")
2397
2398 (defface mode-line-emphasis
2399   '((t (:weight bold)))
2400   "Face used to emphasize certain mode line features.
2401 Use the face `mode-line-highlight' for features that can be selected."
2402   :version "23.1"
2403   :group 'mode-line-faces
2404   :group 'basic-faces)
2405
2406 (defface mode-line-buffer-id
2407   '((t (:weight bold)))
2408   "Face used for buffer identification parts of the mode line."
2409   :version "22.1"
2410   :group 'mode-line-faces
2411   :group 'basic-faces)
2412 (define-obsolete-face-alias 'modeline-buffer-id 'mode-line-buffer-id "22.1")
2413
2414 (defface header-line
2415   '((default
2416      :inherit mode-line)
2417     (((type tty))
2418      ;; This used to be `:inverse-video t', but that doesn't look very
2419      ;; good when combined with inverse-video mode-lines and multiple
2420      ;; windows.  Underlining looks better, and is more consistent with
2421      ;; the window-system face variants, which deemphasize the
2422      ;; header-line in relation to the mode-line face.  If a terminal
2423      ;; can't underline, then the header-line will end up without any
2424      ;; highlighting; this may be too confusing in general, although it
2425      ;; happens to look good with the only current use of header-lines,
2426      ;; the info browser. XXX
2427      :inverse-video nil        ;Override the value inherited from mode-line.
2428      :underline t)
2429     (((class color grayscale) (background light))
2430      :background "grey90" :foreground "grey20"
2431      :box nil)
2432     (((class color grayscale) (background dark))
2433      :background "grey20" :foreground "grey90"
2434      :box nil)
2435     (((class mono) (background light))
2436      :background "white" :foreground "black"
2437      :inverse-video nil
2438      :box nil
2439      :underline t)
2440     (((class mono) (background dark))
2441      :background "black" :foreground "white"
2442      :inverse-video nil
2443      :box nil
2444      :underline t))
2445   "Basic header-line face."
2446   :version "21.1"
2447   :group 'basic-faces)
2448
2449 (defface vertical-border
2450   '((((type tty)) :inherit mode-line-inactive))
2451   "Face used for vertical window dividers on ttys."
2452   :version "22.1"
2453   :group 'basic-faces)
2454
2455 (defface minibuffer-prompt
2456   '((((background dark)) :foreground "cyan")
2457     ;; Don't use blue because many users of the MS-DOS port customize
2458     ;; their foreground color to be blue.
2459     (((type pc)) :foreground "magenta")
2460     (t :foreground "medium blue"))
2461   "Face for minibuffer prompts.
2462 By default, Emacs automatically adds this face to the value of
2463 `minibuffer-prompt-properties', which is a list of text properties
2464 used to display the prompt text."
2465   :version "22.1"
2466   :group 'basic-faces)
2467
2468 (setq minibuffer-prompt-properties
2469       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
2470
2471 (defface fringe
2472   '((((class color) (background light))
2473      :background "grey95")
2474     (((class color) (background dark))
2475      :background "grey10")
2476     (t
2477      :background "gray"))
2478   "Basic face for the fringes to the left and right of windows under X."
2479   :version "21.1"
2480   :group 'frames
2481   :group 'basic-faces)
2482
2483 (defface scroll-bar '((t nil))
2484   "Basic face for the scroll bar colors under X."
2485   :version "21.1"
2486   :group 'frames
2487   :group 'basic-faces)
2488
2489 (defface border '((t nil))
2490   "Basic face for the frame border under X."
2491   :version "21.1"
2492   :group 'frames
2493   :group 'basic-faces)
2494
2495 (defface cursor '((t nil))
2496   "Basic face for the cursor color under X.
2497 Note: Other faces cannot inherit from the cursor face."
2498   :version "21.1"
2499   :group 'cursor
2500   :group 'basic-faces)
2501
2502 (put 'cursor 'face-no-inherit t)
2503
2504 (defface mouse '((t nil))
2505   "Basic face for the mouse color under X."
2506   :version "21.1"
2507   :group 'mouse
2508   :group 'basic-faces)
2509
2510 (defface tool-bar
2511   '((default
2512      :box (:line-width 1 :style released-button)
2513      :foreground "black")
2514     (((type x w32 ns) (class color))
2515      :background "grey75")
2516     (((type x) (class mono))
2517      :background "grey"))
2518   "Basic tool-bar face."
2519   :version "21.1"
2520   :group 'basic-faces)
2521
2522 (defface menu
2523   '((((type tty))
2524      :inverse-video t)
2525     (((type x-toolkit))
2526      )
2527     (t
2528      :inverse-video t))
2529   "Basic face for the font and colors of the menu bar and popup menus."
2530   :version "21.1"
2531   :group 'menu
2532   :group 'basic-faces)
2533
2534 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
2535   "Face to highlight argument names in *Help* buffers."
2536   :group 'help)
2537 \f
2538 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2539 ;;; Manipulating font names.
2540 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2541
2542 ;; This is here for compatibilty with Emacs 20.2.  For example,
2543 ;; international/fontset.el uses x-resolve-font-name.  The following
2544 ;; functions are not used in the face implementation itself.
2545
2546 (defvar x-font-regexp nil)
2547 (defvar x-font-regexp-head nil)
2548 (defvar x-font-regexp-weight nil)
2549 (defvar x-font-regexp-slant nil)
2550
2551 (defconst x-font-regexp-weight-subnum 1)
2552 (defconst x-font-regexp-slant-subnum 2)
2553 (defconst x-font-regexp-swidth-subnum 3)
2554 (defconst x-font-regexp-adstyle-subnum 4)
2555
2556 ;;; Regexps matching font names in "Host Portable Character Representation."
2557 ;;;
2558 (let ((-                "[-?]")
2559       (foundry          "[^-]+")
2560       (family           "[^-]+")
2561       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2562 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2563       (weight\?         "\\([^-]*\\)")                                  ; 1
2564       (slant            "\\([ior]\\)")                                  ; 2
2565 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2566       (slant\?          "\\([^-]?\\)")                                  ; 2
2567 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2568       (swidth           "\\([^-]*\\)")                                  ; 3
2569 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2570       (adstyle          "\\([^-]*\\)")                                  ; 4
2571       (pixelsize        "[0-9]+")
2572       (pointsize        "[0-9][0-9]+")
2573       (resx             "[0-9][0-9]+")
2574       (resy             "[0-9][0-9]+")
2575       (spacing          "[cmp?*]")
2576       (avgwidth         "[0-9]+")
2577       (registry         "[^-]+")
2578       (encoding         "[^-]+")
2579       )
2580   (setq x-font-regexp
2581         (concat "\\`\\*?[-?*]"
2582                 foundry - family - weight\? - slant\? - swidth - adstyle -
2583                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2584                 registry - encoding "\\*?\\'"
2585                 ))
2586   (setq x-font-regexp-head
2587         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2588                 "\\([-*?]\\|\\'\\)"))
2589   (setq x-font-regexp-slant (concat - slant -))
2590   (setq x-font-regexp-weight (concat - weight -))
2591   nil)
2592
2593
2594 (defun x-resolve-font-name (pattern &optional face frame)
2595   "Return a font name matching PATTERN.
2596 All wildcards in PATTERN are instantiated.
2597 If PATTERN is nil, return the name of the frame's base font, which never
2598 contains wildcards.
2599 Given optional arguments FACE and FRAME, return a font which is
2600 also the same size as FACE on FRAME, or fail."
2601   (or (symbolp face)
2602       (setq face (face-name face)))
2603   (and (eq frame t)
2604        (setq frame nil))
2605   (if pattern
2606       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2607       (let ((fonts (x-list-fonts pattern face frame 1)))
2608         (or fonts
2609             (if face
2610                 (if (string-match "\\*" pattern)
2611                     (if (null (face-font face))
2612                         (error "No matching fonts are the same height as the frame default font")
2613                       (error "No matching fonts are the same height as face `%s'" face))
2614                   (if (null (face-font face))
2615                       (error "Height of font `%s' doesn't match the frame default font"
2616                              pattern)
2617                     (error "Height of font `%s' doesn't match face `%s'"
2618                            pattern face)))
2619               (error "No fonts match `%s'" pattern)))
2620         (car fonts))
2621     (cdr (assq 'font (frame-parameters (selected-frame))))))
2622
2623
2624 (defun x-frob-font-weight (font which)
2625   (let ((case-fold-search t))
2626     (cond ((string-match x-font-regexp font)
2627            (concat (substring font 0
2628                               (match-beginning x-font-regexp-weight-subnum))
2629                    which
2630                    (substring font (match-end x-font-regexp-weight-subnum)
2631                               (match-beginning x-font-regexp-adstyle-subnum))
2632                    ;; Replace the ADD_STYLE_NAME field with *
2633                    ;; because the info in it may not be the same
2634                    ;; for related fonts.
2635                    "*"
2636                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2637           ((string-match x-font-regexp-head font)
2638            (concat (substring font 0 (match-beginning 1)) which
2639                    (substring font (match-end 1))))
2640           ((string-match x-font-regexp-weight font)
2641            (concat (substring font 0 (match-beginning 1)) which
2642                    (substring font (match-end 1)))))))
2643 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2644
2645 (defun x-frob-font-slant (font which)
2646   (let ((case-fold-search t))
2647     (cond ((string-match x-font-regexp font)
2648            (concat (substring font 0
2649                               (match-beginning x-font-regexp-slant-subnum))
2650                    which
2651                    (substring font (match-end x-font-regexp-slant-subnum)
2652                               (match-beginning x-font-regexp-adstyle-subnum))
2653                    ;; Replace the ADD_STYLE_NAME field with *
2654                    ;; because the info in it may not be the same
2655                    ;; for related fonts.
2656                    "*"
2657                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2658           ((string-match x-font-regexp-head font)
2659            (concat (substring font 0 (match-beginning 2)) which
2660                    (substring font (match-end 2))))
2661           ((string-match x-font-regexp-slant font)
2662            (concat (substring font 0 (match-beginning 1)) which
2663                    (substring font (match-end 1)))))))
2664 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2665
2666 ;; These aliases are here so that we don't get warnings about obsolete
2667 ;; functions from the byte compiler.
2668 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2669 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2670
2671 (defun x-make-font-bold (font)
2672   "Given an X font specification, make a bold version of it.
2673 If that can't be done, return nil."
2674   (internal-frob-font-weight font "bold"))
2675 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2676
2677 (defun x-make-font-demibold (font)
2678   "Given an X font specification, make a demibold version of it.
2679 If that can't be done, return nil."
2680   (internal-frob-font-weight font "demibold"))
2681 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2682
2683 (defun x-make-font-unbold (font)
2684   "Given an X font specification, make a non-bold version of it.
2685 If that can't be done, return nil."
2686   (internal-frob-font-weight font "medium"))
2687 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2688
2689 (defun x-make-font-italic (font)
2690   "Given an X font specification, make an italic version of it.
2691 If that can't be done, return nil."
2692   (internal-frob-font-slant font "i"))
2693 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2694
2695 (defun x-make-font-oblique (font) ; you say tomayto...
2696   "Given an X font specification, make an oblique version of it.
2697 If that can't be done, return nil."
2698   (internal-frob-font-slant font "o"))
2699 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2700
2701 (defun x-make-font-unitalic (font)
2702   "Given an X font specification, make a non-italic version of it.
2703 If that can't be done, return nil."
2704   (internal-frob-font-slant font "r"))
2705 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2706
2707 (defun x-make-font-bold-italic (font)
2708   "Given an X font specification, make a bold and italic version of it.
2709 If that can't be done, return nil."
2710   (and (setq font (internal-frob-font-weight font "bold"))
2711        (internal-frob-font-slant font "i")))
2712 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2713
2714 (provide 'faces)
2715
2716 ;; arch-tag: 19a4759f-2963-445f-b004-425b9aadd7d6
2717 ;;; faces.el ends here