lisp/mwheel.el

   1 ;;; mwheel.el --- Wheel mouse support
   2
   3 ;; Copyright (C) 1998, 2000-2018 Free Software Foundation, Inc.
   4 ;; Maintainer: William M. Perry <wmperry@gnu.org>
   5 ;; Keywords: mouse
   6 ;; Package: emacs
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This code will enable the use of the infamous 'wheel' on the new
  26 ;; crop of mice.  Under XFree86 and the XSuSE X Servers, the wheel
  27 ;; events are sent as button4/button5 events.
  28
  29 ;; I for one would prefer some way of converting the button4/button5
  30 ;; events into different event types, like 'mwheel-up' or
  31 ;; 'mwheel-down', but I cannot find a way to do this very easily (or
  32 ;; portably), so for now I just live with it.
  33
  34 ;; To enable this code, simply put this at the top of your .emacs
  35 ;; file:
  36 ;;
  37 ;; (mouse-wheel-mode 1)
  38
  39 ;;; Code:
  40
  41 (require 'custom)
  42 (require 'timer)
  43
  44 (defvar mouse-wheel-mode)
  45
  46 ;; Setter function for mouse-button user-options.  Switch Mouse Wheel
  47 ;; mode off and on again so that the old button is unbound and
  48 ;; new button is bound to mwheel-scroll.
  49
  50 (defun mouse-wheel-change-button (var button)
  51   (set-default var button)
  52   ;; Sync the bindings.
  53   (when (bound-and-true-p mouse-wheel-mode) (mouse-wheel-mode 1)))
  54
  55 (defvar mouse-wheel-down-button 4)
  56 (make-obsolete-variable 'mouse-wheel-down-button
  57                         'mouse-wheel-down-event
  58                         "22.1")
  59 (defcustom mouse-wheel-down-event
  60   (if (or (featurep 'w32-win) (featurep 'ns-win))
  61       'wheel-up
  62     (intern (format "mouse-%s" mouse-wheel-down-button)))
  63   "Event used for scrolling down."
  64   :group 'mouse
  65   :type 'symbol
  66   :set 'mouse-wheel-change-button)
  67
  68 (defvar mouse-wheel-up-button 5)
  69 (make-obsolete-variable 'mouse-wheel-up-button
  70                         'mouse-wheel-up-event
  71                         "22.1")
  72 (defcustom mouse-wheel-up-event
  73   (if (or (featurep 'w32-win) (featurep 'ns-win))
  74       'wheel-down
  75     (intern (format "mouse-%s" mouse-wheel-up-button)))
  76   "Event used for scrolling up."
  77   :group 'mouse
  78   :type 'symbol
  79   :set 'mouse-wheel-change-button)
  80
  81 (defvar mouse-wheel-click-button 2)
  82 (make-obsolete-variable 'mouse-wheel-click-button
  83                         'mouse-wheel-click-event
  84                         "22.1")
  85 (defcustom mouse-wheel-click-event
  86   (intern (format "mouse-%s" mouse-wheel-click-button))
  87   "Event that should be temporarily inhibited after mouse scrolling.
  88 The mouse wheel is typically on the mouse-2 button, so it may easily
  89 happen that text is accidentally yanked into the buffer when
  90 scrolling with the mouse wheel.  To prevent that, this variable can be
  91 set to the event sent when clicking on the mouse wheel button."
  92   :group 'mouse
  93   :type 'symbol
  94   :set 'mouse-wheel-change-button)
  95
  96 (defcustom mouse-wheel-inhibit-click-time 0.35
  97   "Time in seconds to inhibit clicking on mouse wheel button after scroll."
  98   :group 'mouse
  99   :type 'number)
 100
 101 (defcustom mouse-wheel-scroll-amount '(5 ((shift) . 1) ((control) . nil))
 102   "Amount to scroll windows by when spinning the mouse wheel.
 103 This is an alist mapping the modifier key to the amount to scroll when
 104 the wheel is moved with the modifier key depressed.
 105 Elements of the list have the form (MODIFIERS . AMOUNT) or just AMOUNT if
 106 MODIFIERS is nil.
 107
 108 AMOUNT should be the number of lines to scroll, or nil for near full
 109 screen.  It can also be a floating point number, specifying the fraction of
 110 a full screen to scroll.  A near full screen is `next-screen-context-lines'
 111 less than a full screen."
 112   :group 'mouse
 113   :type '(cons
 114           (choice :tag "Normal"
 115                   (const :tag "Full screen" :value nil)
 116                   (integer :tag "Specific # of lines")
 117                   (float :tag "Fraction of window")
 118                   (cons
 119                    (repeat (choice :tag "modifier"
 120                                    (const alt) (const control) (const hyper)
 121                                    (const meta) (const shift) (const super)))
 122                    (choice :tag "scroll amount"
 123                            (const :tag "Full screen" :value nil)
 124                            (integer :tag "Specific # of lines")
 125                            (float :tag "Fraction of window"))))
 126           (repeat
 127            (cons
 128             (repeat (choice :tag "modifier"
 129                             (const alt) (const control) (const hyper)
 130                             (const meta) (const shift) (const super)))
 131             (choice :tag "scroll amount"
 132                     (const :tag "Full screen" :value nil)
 133                     (integer :tag "Specific # of lines")
 134                     (float :tag "Fraction of window")))))
 135   :set 'mouse-wheel-change-button)
 136
 137 (defcustom mouse-wheel-progressive-speed t
 138   "If non-nil, the faster the user moves the wheel, the faster the scrolling.
 139 Note that this has no effect when `mouse-wheel-scroll-amount' specifies
 140 a \"near full screen\" scroll or when the mouse wheel sends key instead
 141 of button events."
 142   :group 'mouse
 143   :type 'boolean)
 144
 145 (defcustom mouse-wheel-follow-mouse t
 146   "Whether the mouse wheel should scroll the window that the mouse is over.
 147 This can be slightly disconcerting, but some people prefer it."
 148   :group 'mouse
 149   :type 'boolean)
 150
 151 ;;; For tilt-scroll
 152 ;;;
 153 (defcustom mwheel-tilt-scroll-p nil
 154   "Enable scroll using tilting mouse wheel."
 155   :group 'mouse
 156   :type 'boolean
 157   :version "26.1")
 158
 159 (defcustom mwheel-flip-direction nil
 160   "Swap direction of 'wheel-right and 'wheel-left."
 161   :group 'mouse
 162   :type 'boolean
 163   :version "26.1")
 164
 165 (defcustom mwheel-scroll-left-function 'scroll-left
 166   "Function that does the job of scrolling left."
 167   :group 'mouse
 168   :type 'function
 169   :version "26.1")
 170
 171 (defcustom mwheel-scroll-right-function 'scroll-right
 172   "Function that does the job of scrolling right."
 173   :group 'mouse
 174   :type 'function
 175   :version "26.1")
 176
 177 (eval-and-compile
 178   (if (fboundp 'event-button)
 179       (fset 'mwheel-event-button 'event-button)
 180     (defun mwheel-event-button (event)
 181       (let ((x (event-basic-type event)))
 182         ;; Map mouse-wheel events to appropriate buttons
 183         (if (eq 'mouse-wheel x)
 184             (let ((amount (car (cdr (cdr (cdr event))))))
 185               (if (< amount 0)
 186                   mouse-wheel-up-event
 187                 mouse-wheel-down-event))
 188           x))))
 189
 190   (if (fboundp 'event-window)
 191       (fset 'mwheel-event-window 'event-window)
 192     (defun mwheel-event-window (event)
 193       (posn-window (event-start event)))))
 194
 195 (defvar mwheel-inhibit-click-event-timer nil
 196   "Timer running while mouse wheel click event is inhibited.")
 197
 198 (defun mwheel-inhibit-click-timeout ()
 199   "Handler for `mwheel-inhibit-click-event-timer'."
 200   (setq mwheel-inhibit-click-event-timer nil)
 201   (remove-hook 'pre-command-hook 'mwheel-filter-click-events))
 202
 203 (defun mwheel-filter-click-events ()
 204   "Discard `mouse-wheel-click-event' while scrolling the mouse."
 205   (if (eq (event-basic-type last-input-event) mouse-wheel-click-event)
 206       (setq this-command 'ignore)))
 207
 208 (defvar mwheel-scroll-up-function 'scroll-up
 209   "Function that does the job of scrolling upward.")
 210
 211 (defvar mwheel-scroll-down-function 'scroll-down
 212   "Function that does the job of scrolling downward.")
 213
 214 (defvar mouse-wheel-left-event
 215   (if (or (featurep 'w32-win) (featurep 'ns-win))
 216       'wheel-left
 217     (intern "mouse-6"))
 218   "Event used for scrolling left.")
 219
 220 (defvar mouse-wheel-right-event
 221   (if (or (featurep 'w32-win) (featurep 'ns-win))
 222       'wheel-right
 223     (intern "mouse-7"))
 224   "Event used for scrolling right.")
 225
 226 (defun mwheel-scroll (event)
 227   "Scroll up or down according to the EVENT.
 228 This should be bound only to mouse buttons 4, 5, 6, and 7 on
 229 non-Windows systems."
 230   (interactive (list last-input-event))
 231   (let* ((selected-window (selected-window))
 232          (scroll-window
 233           (or (catch 'found
 234                 (let* ((window (if mouse-wheel-follow-mouse
 235                                    (mwheel-event-window event)
 236                                  (selected-window)))
 237                        (frame (when (window-live-p window)
 238                                 (frame-parameter
 239                                  (window-frame window) 'mouse-wheel-frame))))
 240                   (when (frame-live-p frame)
 241                     (let* ((pos (mouse-absolute-pixel-position))
 242                            (pos-x (car pos))
 243                            (pos-y (cdr pos)))
 244                       (walk-window-tree
 245                        (lambda (window-1)
 246                          (let ((edges (window-edges window-1 nil t t)))
 247                            (when (and (<= (nth 0 edges) pos-x)
 248                                       (<= pos-x (nth 2 edges))
 249                                       (<= (nth 1 edges) pos-y)
 250                                       (<= pos-y (nth 3 edges)))
 251                              (throw 'found window-1))))
 252                        frame nil t)))))
 253               (mwheel-event-window event)))
 254          (old-point
 255           (and (eq scroll-window selected-window)
 256                (eq (car-safe transient-mark-mode) 'only)
 257                (window-point)))
 258          (mods
 259           (delq 'click (delq 'double (delq 'triple (event-modifiers event)))))
 260          (amt (assoc mods mouse-wheel-scroll-amount)))
 261     (unless (eq scroll-window selected-window)
 262       ;; Mark window to be scrolled for redisplay.
 263       (select-window scroll-window 'mark-for-redisplay))
 264     ;; Extract the actual amount or find the element that has no modifiers.
 265     (if amt (setq amt (cdr amt))
 266       (let ((list-elt mouse-wheel-scroll-amount))
 267         (while (consp (setq amt (pop list-elt))))))
 268     (if (floatp amt) (setq amt (1+ (truncate (* amt (window-height))))))
 269     (when (and mouse-wheel-progressive-speed (numberp amt))
 270       ;; When the double-mouse-N comes in, a mouse-N has been executed already,
 271       ;; So by adding things up we get a squaring up (1, 3, 6, 10, 15, ...).
 272       (setq amt (* amt (event-click-count event))))
 273     (when (numberp amt) (setq amt (* amt (event-line-count event))))
 274     (unwind-protect
 275         (let ((button (mwheel-event-button event)))
 276           (cond ((eq button mouse-wheel-down-event)
 277                  (condition-case nil (funcall mwheel-scroll-down-function amt)
 278                    ;; Make sure we do indeed scroll to the beginning of
 279                    ;; the buffer.
 280                    (beginning-of-buffer
 281                     (unwind-protect
 282                         (funcall mwheel-scroll-down-function)
 283                       ;; If the first scroll succeeded, then some scrolling
 284                       ;; is possible: keep scrolling til the beginning but
 285                       ;; do not signal an error.  For some reason, we have
 286                       ;; to do it even if the first scroll signaled an
 287                       ;; error, because otherwise the window is recentered
 288                       ;; for a reason that escapes me.  This problem seems
 289                       ;; to only affect scroll-down.  --Stef
 290                       (set-window-start (selected-window) (point-min))))))
 291                 ((eq button mouse-wheel-up-event)
 292                  (condition-case nil (funcall mwheel-scroll-up-function amt)
 293                    ;; Make sure we do indeed scroll to the end of the buffer.
 294                    (end-of-buffer (while t (funcall mwheel-scroll-up-function)))))
 295                 ((eq button mouse-wheel-left-event) ; for tilt scroll
 296                  (when mwheel-tilt-scroll-p
 297                    (funcall (if mwheel-flip-direction
 298                                 mwheel-scroll-right-function
 299                               mwheel-scroll-left-function) amt)))
 300                 ((eq button mouse-wheel-right-event) ; for tilt scroll
 301                  (when mwheel-tilt-scroll-p
 302                    (funcall (if mwheel-flip-direction
 303                                 mwheel-scroll-left-function
 304                               mwheel-scroll-right-function) amt)))
 305                 (t (error "Bad binding in mwheel-scroll"))))
 306       (if (eq scroll-window selected-window)
 307           ;; If there is a temporarily active region, deactivate it if
 308           ;; scrolling moved point.
 309           (when (and old-point (/= old-point (window-point)))
 310             ;; Call `deactivate-mark' at the original position, so that
 311             ;; the original region is saved to the X selection.
 312             (let ((new-point (window-point)))
 313               (goto-char old-point)
 314               (deactivate-mark)
 315               (goto-char new-point)))
 316         (select-window selected-window t))))
 317
 318   (when (and mouse-wheel-click-event mouse-wheel-inhibit-click-time)
 319     (if mwheel-inhibit-click-event-timer
 320         (cancel-timer mwheel-inhibit-click-event-timer)
 321       (add-hook 'pre-command-hook 'mwheel-filter-click-events))
 322     (setq mwheel-inhibit-click-event-timer
 323           (run-with-timer mouse-wheel-inhibit-click-time nil
 324                           'mwheel-inhibit-click-timeout))))
 325
 326 (put 'mwheel-scroll 'scroll-command t)
 327
 328 (defvar mwheel-installed-bindings nil)
 329
 330 (define-minor-mode mouse-wheel-mode
 331   "Toggle mouse wheel support (Mouse Wheel mode).
 332 With a prefix argument ARG, enable Mouse Wheel mode if ARG is
 333 positive, and disable it otherwise.  If called from Lisp, enable
 334 the mode if ARG is omitted or nil."
 335   :init-value t
 336   ;; We'd like to use custom-initialize-set here so the setup is done
 337   ;; before dumping, but at the point where the defcustom is evaluated,
 338   ;; the corresponding function isn't defined yet, so
 339   ;; custom-initialize-set signals an error.
 340   :initialize 'custom-initialize-delay
 341   :global t
 342   :group 'mouse
 343   ;; Remove previous bindings, if any.
 344   (while mwheel-installed-bindings
 345     (let ((key (pop mwheel-installed-bindings)))
 346       (when (eq (lookup-key (current-global-map) key) 'mwheel-scroll)
 347         (global-unset-key key))))
 348   ;; Setup bindings as needed.
 349   (when mouse-wheel-mode
 350     (dolist (event (list mouse-wheel-down-event mouse-wheel-up-event mouse-wheel-right-event mouse-wheel-left-event))
 351       (dolist (key (mapcar (lambda (amt) `[(,@(if (consp amt) (car amt)) ,event)])
 352                            mouse-wheel-scroll-amount))
 353         (global-set-key key 'mwheel-scroll)
 354         (push key mwheel-installed-bindings)))))
 355
 356 ;;; Compatibility entry point
 357 ;; preloaded ;;;###autoload
 358 (defun mwheel-install (&optional uninstall)
 359   "Enable mouse wheel support."
 360   (mouse-wheel-mode (if uninstall -1 1)))
 361
 362 (provide 'mwheel)
 363
 364 ;;; mwheel.el ends here