lisp/calculator.el

   1 ;;; calculator.el --- a [not so] simple calculator for Emacs
   2
   3 ;; Copyright (C) 1998, 2000, 2001, 2002, 2003, 2004,  2005, 2006, 2007,
   4 ;;   2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Eli Barzilay <eli@barzilay.org>
   7 ;; Keywords: tools, convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;;=====================================================================
  25 ;;; Commentary:
  26 ;;
  27 ;; A calculator for Emacs.
  28 ;; Why should you reach for your mouse to get xcalc (calc.exe, gcalc or
  29 ;; whatever), when you have Emacs running already?
  30 ;;
  31 ;; If this is not part of your Emacs distribution, then simply bind
  32 ;; `calculator' to a key and make it an autoloaded function, e.g.:
  33 ;;   (autoload 'calculator "calculator"
  34 ;;     "Run the Emacs calculator." t)
  35 ;;   (global-set-key [(control return)] 'calculator)
  36 ;;
  37 ;; Written by Eli Barzilay: Maze is Life!  eli@barzilay.org
  38 ;;                                         http://www.barzilay.org/
  39 ;;
  40 ;; For latest version, check
  41 ;;     http://www.barzilay.org/misc/calculator.el
  42 ;;
  43
  44 ;;; History:
  45 ;; I hate history.
  46
  47 (eval-when-compile (require 'cl))
  48
  49 ;;;=====================================================================
  50 ;;; Customization:
  51
  52 (defgroup calculator nil
  53   "Simple Emacs calculator."
  54   :prefix "calculator"
  55   :version "21.1"
  56   :group 'tools
  57   :group 'convenience)
  58
  59 (defcustom calculator-electric-mode nil
  60   "*Run `calculator' electrically, in the echo area.
  61 Electric mode saves some place but changes the way you interact with the
  62 calculator."
  63   :type  'boolean
  64   :group 'calculator)
  65
  66 (defcustom calculator-use-menu t
  67   "*Make `calculator' create a menu.
  68 Note that this requires easymenu.  Must be set before loading."
  69   :type  'boolean
  70   :group 'calculator)
  71
  72 (defcustom calculator-bind-escape nil
  73   "*If non-nil, set escape to exit the calculator."
  74   :type  'boolean
  75   :group 'calculator)
  76
  77 (defcustom calculator-unary-style 'postfix
  78   "*Value is either 'prefix or 'postfix.
  79 This determines the default behavior of unary operators."
  80   :type    '(choice (const prefix) (const postfix))
  81   :group   'calculator)
  82
  83 (defcustom calculator-prompt "Calc=%s> "
  84   "*The prompt used by the Emacs calculator.
  85 It should contain a \"%s\" somewhere that will indicate the i/o radixes;
  86 this will be a two-character string as described in the documentation
  87 for `calculator-mode'."
  88   :type  'string
  89   :group 'calculator)
  90
  91 (defcustom calculator-number-digits 3
  92   "*The calculator's number of digits used for standard display.
  93 Used by the `calculator-standard-display' function - it will use the
  94 format string \"%.NC\" where this number is N and C is a character given
  95 at runtime."
  96   :type  'integer
  97   :group 'calculator)
  98
  99 (defcustom calculator-radix-grouping-mode t
 100   "*Use digit grouping in radix output mode.
 101 If this is set, chunks of `calculator-radix-grouping-digits' characters
 102 will be separated by `calculator-radix-grouping-separator' when in radix
 103 output mode is active (determined by `calculator-output-radix')."
 104   :type  'boolean
 105   :group 'calculator)
 106
 107 (defcustom calculator-radix-grouping-digits 4
 108   "*The number of digits used for grouping display in radix modes.
 109 See `calculator-radix-grouping-mode'."
 110   :type  'integer
 111   :group 'calculator)
 112
 113 (defcustom calculator-radix-grouping-separator "'"
 114   "*The separator used in radix grouping display.
 115 See `calculator-radix-grouping-mode'."
 116   :type  'string
 117   :group 'calculator)
 118
 119 (defcustom calculator-remove-zeros t
 120   "*Non-nil value means delete all redundant zero decimal digits.
 121 If this value is not t, and not nil, redundant zeros are removed except
 122 for one and if it is nil, nothing is removed.
 123 Used by the `calculator-remove-zeros' function."
 124   :type  '(choice (const t) (const leave-decimal) (const nil))
 125   :group 'calculator)
 126
 127 (defcustom calculator-displayer '(std ?n)
 128   "*A displayer specification for numerical values.
 129 This is the displayer used to show all numbers in an expression.  Result
 130 values will be displayed according to the first element of
 131 `calculator-displayers'.
 132
 133 The displayer is a symbol, a string or an expression.  A symbol should
 134 be the name of a one-argument function, a string is used with a single
 135 argument and an expression will be evaluated with the variable `num'
 136 bound to whatever should be displayed.  If it is a function symbol, it
 137 should be able to handle special symbol arguments, currently 'left and
 138 'right which will be sent by special keys to modify display parameters
 139 associated with the displayer function (for example to change the number
 140 of digits displayed).
 141
 142 An exception to the above is the case of the list (std C) where C is a
 143 character, in this case the `calculator-standard-displayer' function
 144 will be used with this character for a format string."
 145   :group 'calculator)
 146
 147 (defcustom calculator-displayers
 148   '(((std ?n) "Standard display, decimal point or scientific")
 149     (calculator-eng-display "Eng display")
 150     ((std ?f) "Standard display, decimal point")
 151     ((std ?e) "Standard display, scientific")
 152     ("%S"     "Emacs printer"))
 153   "*A list of displayers.
 154 Each element is a list of a displayer and a description string.  The
 155 first element is the one which is currently used, this is for the display
 156 of result values not values in expressions.  A displayer specification
 157 is the same as the values that can be stored in `calculator-displayer'.
 158
 159 `calculator-rotate-displayer' rotates this list."
 160   :type  'sexp
 161   :group 'calculator)
 162
 163 (defcustom calculator-paste-decimals t
 164   "*If non-nil, convert pasted integers so they have a decimal point.
 165 This makes it possible to paste big integers since they will be read as
 166 floats, otherwise the Emacs reader will fail on them."
 167   :type  'boolean
 168   :group 'calculator)
 169
 170 (defcustom calculator-copy-displayer nil
 171   "*If non-nil, this is any value that can be used for
 172 `calculator-displayer', to format a string before copying it with
 173 `calculator-copy'.  If nil, then `calculator-displayer's normal value is
 174 used."
 175   :type  'boolean
 176   :group 'calculator)
 177
 178 (defcustom calculator-2s-complement nil
 179   "*If non-nil, show negative numbers in 2s complement in radix modes.
 180 Otherwise show as a negative number."
 181   :type  'boolean
 182   :group 'calculator)
 183
 184 (defcustom calculator-mode-hook nil
 185   "*List of hook functions for `calculator-mode' to run.
 186 Note: if `calculator-electric-mode' is on, then this hook will get
 187 activated in the minibuffer - in that case it should not do much more
 188 than local key settings and other effects that will change things
 189 outside the scope of calculator related code."
 190   :type  'hook
 191   :group 'calculator)
 192
 193 (defcustom calculator-user-registers nil
 194   "*An association list of user-defined register bindings.
 195 Each element in this list is a list of a character and a number that
 196 will be stored in that character's register.
 197
 198 For example, use this to define the golden ratio number:
 199   (setq calculator-user-registers '((?g .  1.61803398875)))
 200 before you load calculator."
 201   :type  '(repeat (cons character number))
 202   :set   '(lambda (_ val)
 203             (and (boundp 'calculator-registers)
 204                  (setq calculator-registers
 205                        (append val calculator-registers)))
 206             (setq calculator-user-registers val))
 207   :group 'calculator)
 208
 209 (defcustom calculator-user-operators nil
 210   "*A list of additional operators.
 211 This is a list in the same format as specified in the documentation for
 212 `calculator-operators', that you can use to bind additional calculator
 213 operators.  It is probably not a good idea to modify this value with
 214 `customize' since it is too complex...
 215
 216 Examples:
 217
 218 * A very simple one, adding a postfix \"x-to-y\" conversion keys, using
 219   t as a prefix key:
 220
 221   (setq calculator-user-operators
 222         '((\"tf\" cl-to-fr (+ 32 (/ (* X 9) 5)) 1)
 223           (\"tc\" fr-to-cl (/ (* (- X 32) 5) 9) 1)
 224           (\"tp\" kg-to-lb (/ X 0.453592)       1)
 225           (\"tk\" lb-to-kg (* X 0.453592)       1)
 226           (\"tF\" mt-to-ft (/ X 0.3048)         1)
 227           (\"tM\" ft-to-mt (* X 0.3048)         1)))
 228
 229 * Using a function-like form is very simple, X for an argument (Y the
 230   second in case of a binary operator), TX is a truncated version of X
 231   and F does a recursive call, Here is a [very inefficient] Fibonacci
 232   number calculation:
 233
 234   (add-to-list 'calculator-user-operators
 235                '(\"F\" fib (if (<= TX 1)
 236                          1
 237                          (+ (F (- TX 1)) (F (- TX 2)))) 0))
 238
 239   Note that this will be either postfix or prefix, according to
 240   `calculator-unary-style'."
 241   :type  '(repeat (list string symbol sexp integer integer))
 242   :group 'calculator)
 243
 244 ;;;=====================================================================
 245 ;;; Code:
 246
 247 ;;;---------------------------------------------------------------------
 248 ;;; Variables
 249
 250 (defvar calculator-initial-operators
 251   '(;; "+"/"-" have keybindings of themselves, not calculator-ops
 252     ("=" =     identity        1 -1)
 253     (nobind "+" +  +           2  4)
 254     (nobind "-" -  -           2  4)
 255     (nobind "+" +  +          -1  9)
 256     (nobind "-" -  -          -1  9)
 257     ("(" \(    identity       -1 -1)
 258     (")" \)    identity       +1 10)
 259     ;; normal keys
 260     ("|"  or   (logior TX TY)  2  2)
 261     ("#"  xor  (logxor TX TY)  2  2)
 262     ("&"  and  (logand TX TY)  2  3)
 263     ("*"  *    *               2  5)
 264     ("/"  /    /               2  5)
 265     ("\\" div  (/ TX TY)       2  5)
 266     ("%"  rem  (% TX TY)       2  5)
 267     ("L"  log  log             2  6)
 268     ("S"  sin  (sin DX)        x  6)
 269     ("C"  cos  (cos DX)        x  6)
 270     ("T"  tan  (tan DX)        x  6)
 271     ("IS" asin (D (asin X))    x  6)
 272     ("IC" acos (D (acos X))    x  6)
 273     ("IT" atan (D (atan X))    x  6)
 274     ("Q"  sqrt sqrt            x  7)
 275     ("^"  ^    calculator-expt 2  7)
 276     ("!"  !    calculator-fact x  7)
 277     (";"  1/   (/ 1 X)         1  7)
 278     ("_"  -    -               1  8)
 279     ("~"  ~    (lognot TX)     x  8)
 280     (">"  repR calculator-repR 1  8)
 281     ("<"  repL calculator-repL 1  8)
 282     ("v"  avg  (/ (apply '+ L) (length L)) 0 8)
 283     ("l"  tot  (apply '+ L)    0 8)
 284     )
 285   "A list of initial operators.
 286 This is a list in the same format as `calculator-operators'.  Whenever
 287 `calculator' starts, it looks at the value of this variable, and if it
 288 is not empty, its contents is prepended to `calculator-operators' and
 289 the appropriate key bindings are made.
 290
 291 This variable is then reset to nil.  Don't use this if you want to add
 292 user-defined operators, use `calculator-user-operators' instead.")
 293
 294 (defvar calculator-operators nil
 295   "The calculator operators, each a list with:
 296
 297 1. The key that is bound to for this operation (usually a string);
 298
 299 2. The displayed symbol for this function;
 300
 301 3. The function symbol, or a form that uses the variables `X' and `Y',
 302    (if it is a binary operator), `TX' and `TY' (truncated integer
 303    versions), `DX' (converted to radians if degrees mode is on), `D'
 304    (function for converting radians to degrees if deg mode is on), `L'
 305    (list of saved values), `F' (function for recursive iteration calls)
 306    and evaluates to the function value - these variables are capital;
 307
 308 4. The function's arity, optional, one of: 2 => binary, -1 => prefix
 309    unary, +1 => postfix unary, 0 => a 0-arg operator func, non-number =>
 310    postfix/prefix as determined by `calculator-unary-style' (the
 311    default);
 312
 313 5. The function's precedence - should be in the range of 1 (lowest) to
 314    9 (highest) (optional, defaults to 1);
 315
 316 It it possible have a unary prefix version of a binary operator if it
 317 comes later in this list.  If the list begins with the symbol 'nobind,
 318 then no key binding will take place - this is only useful for predefined
 319 keys.
 320
 321 Use `calculator-user-operators' to add operators to this list, see its
 322 documentation for an example.")
 323
 324 (defvar calculator-stack nil
 325   "Stack contents - operations and operands.")
 326
 327 (defvar calculator-curnum nil
 328   "Current number being entered (as a string).")
 329
 330 (defvar calculator-stack-display nil
 331   "Cons of the stack and its string representation.")
 332
 333 (defvar calculator-char-radix
 334   '((?D . nil) (?B . bin) (?O . oct) (?H . hex) (?X . hex))
 335   "A table to convert input characters to corresponding radix symbols.")
 336
 337 (defvar calculator-output-radix nil
 338   "The mode for display, one of: nil (decimal), 'bin, 'oct or 'hex.")
 339
 340 (defvar calculator-input-radix nil
 341   "The mode for input, one of: nil (decimal), 'bin, 'oct or 'hex.")
 342
 343 (defvar calculator-deg nil
 344   "Non-nil if trig functions operate on degrees instead of radians.")
 345
 346 (defvar calculator-saved-list nil
 347   "A list of saved values collected.")
 348
 349 (defvar calculator-saved-ptr 0
 350   "The pointer to the current saved number.")
 351
 352 (defvar calculator-add-saved nil
 353   "Bound to t when a value should be added to the saved-list.")
 354
 355 (defvar calculator-display-fragile nil
 356   "When non-nil, we see something that the next digit should replace.")
 357
 358 (defvar calculator-buffer nil
 359   "The current calculator buffer.")
 360
 361 (defvar calculator-eng-extra nil
 362   "Internal value used by `calculator-eng-display'.")
 363
 364 (defvar calculator-eng-tmp-show nil
 365   "Internal value used by `calculator-eng-display'.")
 366
 367 (defvar calculator-last-opXY nil
 368   "The last binary operation and its arguments.
 369 Used for repeating operations in calculator-repR/L.")
 370
 371 (defvar calculator-registers ; use user-bindings first
 372   (append calculator-user-registers (list (cons ?e e) (cons ?p pi)))
 373   "The association list of calculator register values.")
 374
 375 (defvar calculator-saved-global-map nil
 376   "Saved global key map.")
 377
 378 (defvar calculator-restart-other-mode nil
 379   "Used to hack restarting with the electric mode changed.")
 380
 381 ;;;---------------------------------------------------------------------
 382 ;;; Key bindings
 383
 384 (defvar calculator-mode-map nil
 385   "The calculator key map.")
 386
 387 (or calculator-mode-map
 388   (let ((map (make-sparse-keymap)))
 389     (suppress-keymap map t)
 390     (define-key map "i" nil)
 391     (define-key map "o" nil)
 392     (let ((p
 393            '((calculator-open-paren  "[")
 394              (calculator-close-paren "]")
 395              (calculator-op-or-exp   "+" "-" [kp-add] [kp-subtract])
 396              (calculator-digit       "0" "1" "2" "3" "4" "5" "6" "7" "8"
 397                                      "9" "a" "b" "c" "d" "f"
 398                                      [kp-0] [kp-1] [kp-2] [kp-3] [kp-4]
 399                                      [kp-5] [kp-6] [kp-7] [kp-8] [kp-9])
 400              (calculator-op          [kp-divide] [kp-multiply])
 401              (calculator-decimal     "." [kp-decimal])
 402              (calculator-exp         "e")
 403              (calculator-dec/deg-mode "D")
 404              (calculator-set-register "s")
 405              (calculator-get-register "g")
 406              (calculator-radix-mode        "H" "X" "O" "B")
 407              (calculator-radix-input-mode  "id" "ih" "ix" "io" "ib"
 408                                            "iD" "iH" "iX" "iO" "iB")
 409              (calculator-radix-output-mode "od" "oh" "ox" "oo" "ob"
 410                                            "oD" "oH" "oX" "oO" "oB")
 411              (calculator-rotate-displayer      "'")
 412              (calculator-rotate-displayer-back "\"")
 413              (calculator-displayer-prev        "{")
 414              (calculator-displayer-next        "}")
 415              (calculator-saved-up      [up] [?\C-p])
 416              (calculator-saved-down    [down] [?\C-n])
 417              (calculator-quit          "q" [?\C-g])
 418              (calculator-enter         [enter] [linefeed] [kp-enter]
 419                                        [return] [?\r] [?\n])
 420              (calculator-save-on-list  " " [space])
 421              (calculator-clear-saved   [?\C-c] [(control delete)])
 422              (calculator-save-and-quit [(control return)]
 423                                        [(control kp-enter)])
 424              (calculator-paste         [insert] [(shift insert)]
 425                                        [paste] [mouse-2] [?\C-y])
 426              (calculator-clear         [delete] [?\C-?] [?\C-d])
 427              (calculator-help          [?h] [??] [f1] [help])
 428              (calculator-copy          [(control insert)] [copy])
 429              (calculator-backspace     [backspace])
 430              )))
 431       (while p
 432         ;; reverse the keys so first defs come last - makes the more
 433         ;; sensible bindings visible in the menu
 434         (let ((func (car (car p))) (keys (reverse (cdr (car p)))))
 435           (while keys
 436             (define-key map (car keys) func)
 437             (setq keys (cdr keys))))
 438         (setq p (cdr p))))
 439     (if calculator-bind-escape
 440       (progn (define-key map [?\e] 'calculator-quit)
 441              (define-key map [escape] 'calculator-quit))
 442       (define-key map [?\e ?\e ?\e] 'calculator-quit))
 443     ;; make C-h work in text-mode
 444     (or window-system (define-key map [?\C-h] 'calculator-backspace))
 445     ;; set up a menu
 446     (if (and calculator-use-menu (not (boundp 'calculator-menu)))
 447       (let ((radix-selectors
 448              (mapcar (lambda (x)
 449                        `([,(nth 0 x)
 450                           (calculator-radix-mode ,(nth 2 x))
 451                           :style radio
 452                           :keys ,(nth 2 x)
 453                           :selected
 454                           (and
 455                            (eq calculator-input-radix ',(nth 1 x))
 456                            (eq calculator-output-radix ',(nth 1 x)))]
 457                          [,(concat (nth 0 x) " Input")
 458                           (calculator-radix-input-mode ,(nth 2 x))
 459                           :keys ,(concat "i" (downcase (nth 2 x)))
 460                           :style radio
 461                           :selected
 462                           (eq calculator-input-radix ',(nth 1 x))]
 463                          [,(concat (nth 0 x) " Output")
 464                           (calculator-radix-output-mode ,(nth 2 x))
 465                           :keys ,(concat "o" (downcase (nth 2 x)))
 466                           :style radio
 467                           :selected
 468                           (eq calculator-output-radix ',(nth 1 x))]))
 469                      '(("Decimal"     nil "D")
 470                        ("Binary"      bin "B")
 471                        ("Octal"       oct "O")
 472                        ("Hexadecimal" hex "H"))))
 473             (op '(lambda (name key)
 474                         `[,name (calculator-op ,key) :keys ,key])))
 475         (easy-menu-define
 476          calculator-menu map "Calculator menu."
 477          `("Calculator"
 478            ["Help"
 479             (let ((last-command 'calculator-help)) (calculator-help))
 480             :keys "?"]
 481            "---"
 482            ["Copy"  calculator-copy]
 483            ["Paste" calculator-paste]
 484            "---"
 485            ["Electric mode"
 486             (progn (calculator-quit)
 487                    (setq calculator-restart-other-mode t)
 488                    (run-with-timer 0.1 nil '(lambda () (message nil)))
 489                    ;; the message from the menu will be visible,
 490                    ;; couldn't make it go away...
 491                    (calculator))
 492             :active (not calculator-electric-mode)]
 493            ["Normal mode"
 494             (progn (setq calculator-restart-other-mode t)
 495                    (calculator-quit))
 496             :active calculator-electric-mode]
 497            "---"
 498            ("Functions"
 499             ,(funcall op "Repeat-right" ">")
 500             ,(funcall op "Repeat-left"  "<")
 501             "------General------"
 502             ,(funcall op "Reciprocal"   ";")
 503             ,(funcall op "Log"          "L")
 504             ,(funcall op "Square-root"  "Q")
 505             ,(funcall op "Factorial"    "!")
 506             "------Trigonometric------"
 507             ,(funcall op "Sinus"        "S")
 508             ,(funcall op "Cosine"       "C")
 509             ,(funcall op "Tangent"      "T")
 510             ,(funcall op "Inv-Sinus"    "IS")
 511             ,(funcall op "Inv-Cosine"   "IC")
 512             ,(funcall op "Inv-Tangent"  "IT")
 513             "------Bitwise------"
 514             ,(funcall op "Or"           "|")
 515             ,(funcall op "Xor"          "#")
 516             ,(funcall op "And"          "&")
 517             ,(funcall op "Not"          "~"))
 518            ("Saved List"
 519             ["Eval+Save"      calculator-save-on-list]
 520             ["Prev number"    calculator-saved-up]
 521             ["Next number"    calculator-saved-down]
 522             ["Delete current" calculator-clear
 523              :active (and calculator-display-fragile
 524                           calculator-saved-list
 525                           (= (car calculator-stack)
 526                              (nth calculator-saved-ptr
 527                                   calculator-saved-list)))]
 528             ["Delete all" calculator-clear-saved]
 529             "---"
 530             ,(funcall op "List-total"   "l")
 531             ,(funcall op "List-average" "v"))
 532            ("Registers"
 533             ["Get register" calculator-get-register]
 534             ["Set register" calculator-set-register])
 535            ("Modes"
 536             ["Radians"
 537              (progn
 538                (and (or calculator-input-radix calculator-output-radix)
 539                     (calculator-radix-mode "D"))
 540                (and calculator-deg (calculator-dec/deg-mode)))
 541              :keys "D"
 542              :style radio
 543              :selected (not (or calculator-input-radix
 544                                 calculator-output-radix
 545                                 calculator-deg))]
 546             ["Degrees"
 547              (progn
 548                (and (or calculator-input-radix calculator-output-radix)
 549                     (calculator-radix-mode "D"))
 550                (or calculator-deg (calculator-dec/deg-mode)))
 551              :keys "D"
 552              :style radio
 553              :selected (and calculator-deg
 554                             (not (or calculator-input-radix
 555                                      calculator-output-radix)))]
 556             "---"
 557             ,@(mapcar 'car radix-selectors)
 558             ("Separate I/O"
 559              ,@(mapcar (lambda (x) (nth 1 x)) radix-selectors)
 560              "---"
 561              ,@(mapcar (lambda (x) (nth 2 x)) radix-selectors)))
 562            ("Decimal Display"
 563             ,@(mapcar (lambda (d)
 564                         (vector (cadr d)
 565                                 ;; Note: inserts actual object here
 566                                 `(calculator-rotate-displayer ',d)))
 567                       calculator-displayers)
 568             "---"
 569             ["Change Prev Display" calculator-displayer-prev]
 570             ["Change Next Display" calculator-displayer-next])
 571            "---"
 572            ["Copy+Quit" calculator-save-and-quit]
 573            ["Quit"      calculator-quit]))))
 574     (setq calculator-mode-map map)))
 575
 576 ;;;---------------------------------------------------------------------
 577 ;;; Startup and mode stuff
 578
 579 (defun calculator-mode ()
 580   ;; this help is also used as the major help screen
 581   "A [not so] simple calculator for Emacs.
 582
 583 This calculator is used in the same way as other popular calculators
 584 like xcalc or calc.exe - but using an Emacs interface.
 585
 586 Expressions are entered using normal infix notation, parens are used as
 587 normal.  Unary functions are usually postfix, but some depends on the
 588 value of `calculator-unary-style' (if the style for an operator below is
 589 specified, then it is fixed, otherwise it depends on this variable).
 590 `+' and `-' can be used as either binary operators or prefix unary
 591 operators.  Numbers can be entered with exponential notation using `e',
 592 except when using a non-decimal radix mode for input (in this case `e'
 593 will be the hexadecimal digit).  If the result of a calculation is too
 594 large (out of range for Emacs), the value of \"inf\" is returned.
 595
 596 Here are the editing keys:
 597 * `RET' `='      evaluate the current expression
 598 * `C-insert'     copy the whole current expression to the `kill-ring'
 599 * `C-return'     evaluate, save result the `kill-ring' and exit
 600 * `insert'       paste a number if the one was copied (normally)
 601 * `delete' `C-d' clear last argument or whole expression (hit twice)
 602 * `backspace'    delete a digit or a previous expression element
 603 * `h' `?'        pop-up a quick reference help
 604 * `ESC' `q'      exit (`ESC' can be used if `calculator-bind-escape' is
 605                  non-nil, otherwise use three consecutive `ESC's)
 606
 607 These operators are pre-defined:
 608 * `+' `-' `*' `/' the common binary operators
 609 * `\\' `%'         integer division and reminder
 610 * `_' `;'         postfix unary negation and reciprocal
 611 * `^' `L'         binary operators for x^y and log(x) in base y
 612 * `Q' `!'         unary square root and factorial
 613 * `S' `C' `T'     unary trigonometric operators - sin, cos and tan
 614 * `|' `#' `&' `~' bitwise operators - or, xor, and, not
 615
 616 The trigonometric functions can be inverted if prefixed with an `I', see
 617 below for the way to use degrees instead of the default radians.
 618
 619 Two special postfix unary operators are `>' and `<': whenever a binary
 620 operator is performed, it is remembered along with its arguments; then
 621 `>' (`<') will apply the same operator with the same right (left)
 622 argument.
 623
 624 hex/oct/bin modes can be set for input and for display separately.
 625 Another toggle-able mode is for using degrees instead of radians for
 626 trigonometric functions.
 627 The keys to switch modes are (`X' is shortcut for `H'):
 628 * `D'             switch to all-decimal mode, or toggle degrees/radians
 629 * `B' `O' `H' `X' binary/octal/hexadecimal modes for input & display
 630 * `i' `o'         followed by one of `D' `B' `O' `H' `X' (case
 631                   insensitive) sets only the input or display radix mode
 632 The prompt indicates the current modes:
 633 * \"D=\": degrees mode;
 634 * \"?=\": (? is B/O/H) this is the radix for both input and output;
 635 * \"=?\": (? is B/O/H) the display radix (when input is decimal);
 636 * \"??\": (? is D/B/O/H) 1st char for input radix, 2nd for display.
 637
 638 Also, the quote key can be used to switch display modes for decimal
 639 numbers (double-quote rotates back), and the two brace characters
 640 \(\"{\" and \"}\" change display parameters that these displayers use (if
 641 they handle such).  If output is using any radix mode, then these keys
 642 toggle digit grouping mode and the chunk size.
 643
 644 Values can be saved for future reference in either a list of saved
 645 values, or in registers.
 646
 647 The list of saved values is useful for statistics operations on some
 648 collected data.  It is possible to navigate in this list, and if the
 649 value shown is the current one on the list, an indication is displayed
 650 as \"[N]\" if this is the last number and there are N numbers, or
 651 \"[M/N]\" if the M-th value is shown.
 652 * `SPC'            evaluate the current value as usual, but also adds
 653                    the result to the list of saved values
 654 * `l' `v'          computes total / average of saved values
 655 * `up' `C-p'       browse to the previous value in the list
 656 * `down' `C-n'     browse to the next value in the list
 657 * `delete' `C-d'   remove current value from the list (if it is on it)
 658 * `C-delete' `C-c' delete the whole list
 659
 660 Registers are variable-like place-holders for values:
 661 * `s' followed by a character attach the current value to that character
 662 * `g' followed by a character fetches the attached value
 663
 664 There are many variables that can be used to customize the calculator.
 665 Some interesting customization variables are:
 666 * `calculator-electric-mode'  use only the echo-area electrically.
 667 * `calculator-unary-style'    set most unary ops to pre/postfix style.
 668 * `calculator-user-registers' to define user-preset registers.
 669 * `calculator-user-operators' to add user-defined operators.
 670 See the documentation for these variables, and \"calculator.el\" for
 671 more information.
 672
 673 \\{calculator-mode-map}"
 674   (interactive)
 675   (kill-all-local-variables)
 676   (setq major-mode 'calculator-mode)
 677   (setq mode-name "Calculator")
 678   (use-local-map calculator-mode-map)
 679   (run-mode-hooks 'calculator-mode-hook))
 680
 681 (eval-when-compile (require 'electric) (require 'ehelp))
 682
 683 ;;;###autoload
 684 (defun calculator ()
 685   "Run the Emacs calculator.
 686 See the documentation for `calculator-mode' for more information."
 687   (interactive)
 688   (if calculator-restart-other-mode
 689     (setq calculator-electric-mode (not calculator-electric-mode)))
 690   (if calculator-initial-operators
 691     (progn (calculator-add-operators calculator-initial-operators)
 692            (setq calculator-initial-operators nil)
 693            ;; don't change this since it is a customization variable,
 694            ;; its set function will add any new operators
 695            (calculator-add-operators calculator-user-operators)))
 696   (setq calculator-buffer (get-buffer-create "*calculator*"))
 697   (if calculator-electric-mode
 698     (save-window-excursion
 699       (progn (require 'electric) (message nil)) ; hide load message
 700       (let (old-g-map old-l-map (echo-keystrokes 0)
 701             (garbage-collection-messages nil)) ; no gc msg when electric
 702         (set-window-buffer (minibuffer-window) calculator-buffer)
 703         (select-window (minibuffer-window))
 704         (calculator-reset)
 705         (calculator-update-display)
 706         (setq old-l-map (current-local-map))
 707         (setq old-g-map (current-global-map))
 708         (setq calculator-saved-global-map (current-global-map))
 709         (use-local-map nil)
 710         (use-global-map calculator-mode-map)
 711         (run-hooks 'calculator-mode-hook)
 712         (unwind-protect
 713             (catch 'calculator-done
 714               (Electric-command-loop
 715                'calculator-done
 716                ;; can't use 'noprompt, bug in electric.el
 717                '(lambda () 'noprompt)
 718                nil
 719                (lambda (x y) (calculator-update-display))))
 720           (and calculator-buffer
 721                (catch 'calculator-done (calculator-quit)))
 722           (use-local-map old-l-map)
 723           (use-global-map old-g-map))))
 724     (progn
 725       (cond
 726         ((not (get-buffer-window calculator-buffer))
 727          (let ((split-window-keep-point nil)
 728                (window-min-height 2))
 729            ;; maybe leave two lines for our window because of the normal
 730            ;; `raised' modeline in Emacs 21
 731            (select-window
 732             (split-window-vertically
 733              ;; If the modeline might interfere with the calculator buffer,
 734              ;; use 3 lines instead.
 735              (if (and (fboundp 'face-attr-construct)
 736                       (let* ((dh (plist-get (face-attr-construct 'default) :height))
 737                              (mf (face-attr-construct 'modeline))
 738                              (mh (plist-get mf :height)))
 739                         ;; If the modeline is shorter than the default,
 740                         ;; stick with 2 lines.  (It may be necessary to
 741                         ;; check how much shorter.)
 742                         (and
 743                          (not
 744                           (or (and (integerp dh)
 745                                    (integerp mh)
 746                                    (< mh dh))
 747                               (and (numberp mh)
 748                                    (not (integerp mh))
 749                                    (< mh 1))))
 750                          (or
 751                           ;; If the modeline is taller than the default,
 752                           ;; use 3 lines.
 753                           (and (integerp dh)
 754                                (integerp mh)
 755                                (> mh dh))
 756                           (and (numberp mh)
 757                                (not (integerp mh))
 758                                (> mh 1))
 759                           ;; If the modeline has a box with non-negative line-width,
 760                           ;; use 3 lines.
 761                           (let* ((bx (plist-get mf :box))
 762                                  (lh (plist-get bx :line-width)))
 763                             (and bx
 764                                  (or
 765                                   (not lh)
 766                                   (> lh 0))))
 767                           ;; If the modeline has an overline, use 3 lines.
 768                           (plist-get (face-attr-construct 'modeline) :overline)))))
 769                -3 -2)))
 770            (switch-to-buffer calculator-buffer)))
 771         ((not (eq (current-buffer) calculator-buffer))
 772          (select-window (get-buffer-window calculator-buffer))))
 773       (calculator-mode)
 774       (setq buffer-read-only t)
 775       (calculator-reset)
 776       (message "Hit `?' For a quick help screen.")))
 777   (if (and calculator-restart-other-mode calculator-electric-mode)
 778     (calculator)))
 779
 780 (defun calculator-message (string &rest arguments)
 781   "Same as `message', but special handle of electric mode."
 782   (apply 'message string arguments)
 783   (if calculator-electric-mode
 784     (progn (sit-for 1) (message nil))))
 785
 786 ;;;---------------------------------------------------------------------
 787 ;;; Operators
 788
 789 (defun calculator-op-arity (op)
 790   "Return OP's arity, 2, +1 or -1."
 791   (let ((arity (or (nth 3 op) 'x)))
 792     (if (numberp arity)
 793       arity
 794       (if (eq calculator-unary-style 'postfix) +1 -1))))
 795
 796 (defun calculator-op-prec (op)
 797   "Return OP's precedence for reducing when inserting into the stack.
 798 Defaults to 1."
 799   (or (nth 4 op) 1))
 800
 801 (defun calculator-add-operators (more-ops)
 802   "This function handles operator addition.
 803 Adds MORE-OPS to `calculator-operator', called initially to handle
 804 `calculator-initial-operators' and `calculator-user-operators'."
 805   (let ((added-ops nil))
 806     (while more-ops
 807       (or (eq (car (car more-ops)) 'nobind)
 808           (let ((i -1) (key (car (car more-ops))))
 809             ;; make sure the key is undefined, so it's easy to define
 810             ;; prefix keys
 811             (while (< (setq i (1+ i)) (length key))
 812               (or (keymapp
 813                    (lookup-key calculator-mode-map
 814                                (substring key 0 (1+ i))))
 815                   (progn
 816                     (define-key
 817                       calculator-mode-map (substring key 0 (1+ i)) nil)
 818                     (setq i (length key)))))
 819             (define-key calculator-mode-map key 'calculator-op)))
 820       (setq added-ops (cons (if (eq (car (car more-ops)) 'nobind)
 821                               (cdr (car more-ops))
 822                               (car more-ops))
 823                             added-ops))
 824       (setq more-ops (cdr more-ops)))
 825     ;; added-ops come first, but in correct order
 826     (setq calculator-operators
 827           (append (nreverse added-ops) calculator-operators))))
 828
 829 ;;;---------------------------------------------------------------------
 830 ;;; Display stuff
 831
 832 (defun calculator-reset ()
 833   "Reset calculator variables."
 834   (or calculator-restart-other-mode
 835       (setq calculator-stack           nil
 836             calculator-curnum          nil
 837             calculator-stack-display   nil
 838             calculator-display-fragile nil))
 839   (setq calculator-restart-other-mode nil)
 840   (calculator-update-display))
 841
 842 (defun calculator-get-prompt ()
 843   "Return a string to display.
 844 The string is set not to exceed the screen width."
 845   (let* ((calculator-prompt
 846           (format calculator-prompt
 847                   (cond
 848                     ((or calculator-output-radix calculator-input-radix)
 849                      (if (eq calculator-output-radix
 850                              calculator-input-radix)
 851                        (concat
 852                         (char-to-string
 853                          (car (rassq calculator-output-radix
 854                                      calculator-char-radix)))
 855                         "=")
 856                        (concat
 857                         (if calculator-input-radix
 858                           (char-to-string
 859                            (car (rassq calculator-input-radix
 860                                        calculator-char-radix)))
 861                           "=")
 862                         (char-to-string
 863                          (car (rassq calculator-output-radix
 864                                      calculator-char-radix))))))
 865                     (calculator-deg "D=")
 866                     (t "=="))))
 867          (prompt
 868           (concat calculator-prompt
 869                   (cdr calculator-stack-display)
 870                   (cond (calculator-curnum
 871                          ;; number being typed
 872                          (concat calculator-curnum "_"))
 873                         ((and (= 1 (length calculator-stack))
 874                               calculator-display-fragile)
 875                          ;; only the result is shown, next number will
 876                          ;; restart
 877                          nil)
 878                         (t
 879                          ;; waiting for a number or an operator
 880                          "?"))))
 881          (trim (- (length prompt) (1- (window-width)))))
 882     (if (<= trim 0)
 883       prompt
 884       (concat calculator-prompt
 885               (substring prompt (+ trim (length calculator-prompt)))))))
 886
 887 (defun calculator-string-to-number (str)
 888   "Convert the given STR to a number, according to the value of
 889 `calculator-input-radix'."
 890   (if calculator-input-radix
 891     (let ((radix
 892            (cdr (assq calculator-input-radix
 893                       '((bin . 2) (oct . 8) (hex . 16)))))
 894           (i -1) (value 0) (new-value 0))
 895       ;; assume mostly valid input (e.g., characters in range)
 896       (while (< (setq i (1+ i)) (length str))
 897         (setq new-value
 898               (let* ((ch (upcase (aref str i)))
 899                      (n (cond ((< ch ?0)  nil)
 900                               ((<= ch ?9) (- ch ?0))
 901                               ((< ch ?A)  nil)
 902                               ((<= ch ?Z) (- ch (- ?A 10)))
 903                               (t          nil))))
 904                 (if (and n (<= 0 n) (< n radix))
 905                   (+ n (* radix value))
 906                   (progn
 907                     (calculator-message
 908                      "Warning: Ignoring bad input character `%c'." ch)
 909                     (sit-for 1)
 910                     value))))
 911         (if (if (< new-value 0) (> value 0) (< value 0))
 912           (calculator-message "Warning: Overflow in input."))
 913         (setq value new-value))
 914       value)
 915     (car (read-from-string
 916           (cond ((equal "." str) "0.0")
 917                 ((string-match "[eE][+-]?$" str) (concat str "0"))
 918                 ((string-match "\\.[0-9]\\|[eE]" str) str)
 919                 ((string-match "\\." str)
 920                  ;; do this because Emacs reads "23." as an integer
 921                  (concat str "0"))
 922                 ((stringp str) (concat str ".0"))
 923                 (t "0.0"))))))
 924
 925 (defun calculator-curnum-value ()
 926   "Get the numeric value of the displayed number string as a float."
 927   (calculator-string-to-number calculator-curnum))
 928
 929 (defun calculator-rotate-displayer (&optional new-disp)
 930   "Switch to the next displayer on the `calculator-displayers' list.
 931 Can be called with an optional argument NEW-DISP to force rotation to
 932 that argument.
 933 If radix output mode is active, toggle digit grouping."
 934   (interactive)
 935   (cond
 936     (calculator-output-radix
 937      (setq calculator-radix-grouping-mode
 938            (not calculator-radix-grouping-mode))
 939      (calculator-message
 940       "Digit grouping mode %s."
 941       (if calculator-radix-grouping-mode "ON" "OFF")))
 942     (t
 943      (setq calculator-displayers
 944            (if (and new-disp (memq new-disp calculator-displayers))
 945              (let ((tmp nil))
 946                (while (not (eq (car calculator-displayers) new-disp))
 947                  (setq tmp (cons (car calculator-displayers) tmp))
 948                  (setq calculator-displayers
 949                        (cdr calculator-displayers)))
 950                (setq calculator-displayers
 951                      (nconc calculator-displayers (nreverse tmp))))
 952              (nconc (cdr calculator-displayers)
 953                     (list (car calculator-displayers)))))
 954      (calculator-message
 955       "Using %s." (cadr (car calculator-displayers)))))
 956   (calculator-enter))
 957
 958 (defun calculator-rotate-displayer-back ()
 959   "Like `calculator-rotate-displayer', but rotates modes back.
 960 If radix output mode is active, toggle digit grouping."
 961   (interactive)
 962   (calculator-rotate-displayer (car (last calculator-displayers))))
 963
 964 (defun calculator-displayer-prev ()
 965   "Send the current displayer function a 'left argument.
 966 This is used to modify display arguments (if the current displayer
 967 function supports this).
 968 If radix output mode is active, increase the grouping size."
 969   (interactive)
 970   (if calculator-output-radix
 971     (progn (setq calculator-radix-grouping-digits
 972                  (1+ calculator-radix-grouping-digits))
 973            (calculator-enter))
 974     (and (car calculator-displayers)
 975          (let ((disp (caar calculator-displayers)))
 976            (cond
 977              ((symbolp disp) (funcall disp 'left))
 978              ((and (consp disp) (eq 'std (car disp)))
 979               (calculator-standard-displayer 'left (cadr disp))))))))
 980
 981 (defun calculator-displayer-next ()
 982   "Send the current displayer function a 'right argument.
 983 This is used to modify display arguments (if the current displayer
 984 function supports this).
 985 If radix output mode is active, decrease the grouping size."
 986   (interactive)
 987   (if calculator-output-radix
 988     (progn (setq calculator-radix-grouping-digits
 989                  (max 2 (1- calculator-radix-grouping-digits)))
 990            (calculator-enter))
 991     (and (car calculator-displayers)
 992          (let ((disp (caar calculator-displayers)))
 993            (cond
 994              ((symbolp disp) (funcall disp 'right))
 995              ((and (consp disp) (eq 'std (car disp)))
 996               (calculator-standard-displayer 'right (cadr disp))))))))
 997
 998 (defun calculator-remove-zeros (numstr)
 999   "Get a number string NUMSTR and remove unnecessary zeroes.
1000 the behavior of this function is controlled by
1001 `calculator-remove-zeros'."
1002   (cond ((and (eq calculator-remove-zeros t)
1003               (string-match "\\.0+\\([eE][+-]?[0-9]*\\)?$" numstr))
1004          ;; remove all redundant zeros leaving an integer
1005          (if (match-beginning 1)
1006            (concat (substring numstr 0 (match-beginning 0))
1007                    (match-string 1 numstr))
1008            (substring numstr 0 (match-beginning 0))))
1009         ((and calculator-remove-zeros
1010               (string-match
1011                "\\..\\([0-9]*[1-9]\\)?\\(0+\\)\\([eE][+-]?[0-9]*\\)?$"
1012                numstr))
1013          ;; remove zeros, except for first after the "."
1014          (if (match-beginning 3)
1015            (concat (substring numstr 0 (match-beginning 2))
1016                    (match-string 3 numstr))
1017            (substring numstr 0 (match-beginning 2))))
1018         (t numstr)))
1019
1020 (defun calculator-standard-displayer (num char)
1021   "Standard display function, used to display NUM.
1022 Its behavior is determined by `calculator-number-digits' and the given
1023 CHAR argument (both will be used to compose a format string).  If the
1024 char is \"n\" then this function will choose one between %f or %e, this
1025 is a work around %g jumping to exponential notation too fast.
1026
1027 The special 'left and 'right symbols will make it change the current
1028 number of digits displayed (`calculator-number-digits').
1029
1030 It will also remove redundant zeros from the result."
1031   (if (symbolp num)
1032     (cond ((eq num 'left)
1033            (and (> calculator-number-digits 0)
1034                 (setq calculator-number-digits
1035                       (1- calculator-number-digits))
1036                 (calculator-enter)))
1037           ((eq num 'right)
1038            (setq calculator-number-digits
1039                  (1+ calculator-number-digits))
1040            (calculator-enter)))
1041     (let ((str (if (zerop num)
1042                  "0"
1043                  (format
1044                   (concat "%."
1045                           (number-to-string calculator-number-digits)
1046                           (if (eq char ?n)
1047                             (let ((n (abs num)))
1048                               (if (or (< n 0.001) (> n 1e8)) "e" "f"))
1049                             (string char)))
1050                   num))))
1051       (calculator-remove-zeros str))))
1052
1053 (defun calculator-eng-display (num)
1054   "Display NUM in engineering notation.
1055 The number of decimal digits used is controlled by
1056 `calculator-number-digits', so to change it at runtime you have to use
1057 the 'left or 'right when one of the standard modes is used."
1058   (if (symbolp num)
1059     (cond ((eq num 'left)
1060            (setq calculator-eng-extra
1061                  (if calculator-eng-extra
1062                    (1+ calculator-eng-extra)
1063                    1))
1064            (let ((calculator-eng-tmp-show t)) (calculator-enter)))
1065           ((eq num 'right)
1066            (setq calculator-eng-extra
1067                  (if calculator-eng-extra
1068                    (1- calculator-eng-extra)
1069                    -1))
1070            (let ((calculator-eng-tmp-show t)) (calculator-enter))))
1071     (let ((exp 0))
1072       (and (not (= 0 num))
1073            (progn
1074              (while (< (abs num) 1.0)
1075                (setq num (* num 1000.0)) (setq exp (- exp 3)))
1076              (while (> (abs num) 999.0)
1077                (setq num (/ num 1000.0)) (setq exp (+ exp 3)))
1078              (and calculator-eng-tmp-show
1079                   (not (= 0 calculator-eng-extra))
1080                   (let ((i calculator-eng-extra))
1081                     (while (> i 0)
1082                       (setq num (* num 1000.0)) (setq exp (- exp 3))
1083                       (setq i (1- i)))
1084                     (while (< i 0)
1085                       (setq num (/ num 1000.0)) (setq exp (+ exp 3))
1086                       (setq i (1+ i)))))))
1087       (or calculator-eng-tmp-show (setq calculator-eng-extra nil))
1088       (let ((str (format (concat "%." (number-to-string
1089                                        calculator-number-digits)
1090                                  "f")
1091                          num)))
1092         (concat (let ((calculator-remove-zeros
1093                        ;; make sure we don't leave integers
1094                        (and calculator-remove-zeros 'x)))
1095                   (calculator-remove-zeros str))
1096                 "e" (number-to-string exp))))))
1097
1098 (defun calculator-number-to-string (num)
1099   "Convert NUM to a displayable string."
1100   (cond
1101     ((and (numberp num) calculator-output-radix)
1102      ;; print with radix - for binary I convert the octal number
1103      (let ((str (format (if (eq calculator-output-radix 'hex) "%x" "%o")
1104                         (calculator-truncate
1105                          (if calculator-2s-complement num (abs num))))))
1106        (if (eq calculator-output-radix 'bin)
1107          (let ((i -1) (s ""))
1108            (while (< (setq i (1+ i)) (length str))
1109              (setq s
1110                    (concat s
1111                            (cdr (assq (aref str i)
1112                                       '((?0 . "000") (?1 . "001")
1113                                         (?2 . "010") (?3 . "011")
1114                                         (?4 . "100") (?5 . "101")
1115                                         (?6 . "110") (?7 . "111")))))))
1116            (string-match "^0*\\(.+\\)" s)
1117            (setq str (match-string 1 s))))
1118        (if calculator-radix-grouping-mode
1119          (let ((d (/ (length str) calculator-radix-grouping-digits))
1120                (r (% (length str) calculator-radix-grouping-digits)))
1121            (while (>= (setq d (1- d)) (if (zerop r) 1 0))
1122              (let ((i (+ r (* d calculator-radix-grouping-digits))))
1123                (setq str (concat (substring str 0 i)
1124                                  calculator-radix-grouping-separator
1125                                  (substring str i)))))))
1126        (upcase
1127         (if (and (not calculator-2s-complement) (< num 0))
1128           (concat "-" str)
1129           str))))
1130     ((and (numberp num) calculator-displayer)
1131      (cond
1132        ((stringp calculator-displayer)
1133         (format calculator-displayer num))
1134        ((symbolp calculator-displayer)
1135         (funcall calculator-displayer num))
1136        ((and (consp calculator-displayer)
1137              (eq 'std (car calculator-displayer)))
1138         (calculator-standard-displayer num (cadr calculator-displayer)))
1139        ((listp calculator-displayer)
1140         (eval calculator-displayer))
1141        (t (prin1-to-string num t))))
1142     ;; operators are printed here
1143     (t (prin1-to-string (nth 1 num) t))))
1144
1145 (defun calculator-update-display (&optional force)
1146   "Update the display.
1147 If optional argument FORCE is non-nil, don't use the cached string."
1148   (set-buffer calculator-buffer)
1149   ;; update calculator-stack-display
1150   (if (or force
1151           (not (eq (car calculator-stack-display) calculator-stack)))
1152     (setq calculator-stack-display
1153           (cons calculator-stack
1154                 (if calculator-stack
1155                   (concat
1156                    (let ((calculator-displayer
1157                           (if (and calculator-displayers
1158                                    (= 1 (length calculator-stack)))
1159                             ;; customizable display for a single value
1160                             (caar calculator-displayers)
1161                             calculator-displayer)))
1162                      (mapconcat 'calculator-number-to-string
1163                                 (reverse calculator-stack)
1164                                 " "))
1165                    " "
1166                    (and calculator-display-fragile
1167                         calculator-saved-list
1168                         (= (car calculator-stack)
1169                            (nth calculator-saved-ptr
1170                                 calculator-saved-list))
1171                         (if (= 0 calculator-saved-ptr)
1172                           (format "[%s]" (length calculator-saved-list))
1173                           (format "[%s/%s]"
1174                                   (- (length calculator-saved-list)
1175                                      calculator-saved-ptr)
1176                                   (length calculator-saved-list)))))
1177                   ""))))
1178   (let ((inhibit-read-only t))
1179     (erase-buffer)
1180     (insert (calculator-get-prompt)))
1181   (set-buffer-modified-p nil)
1182   (if calculator-display-fragile
1183     (goto-char (1+ (length calculator-prompt)))
1184     (goto-char (1- (point)))))
1185
1186 ;;;---------------------------------------------------------------------
1187 ;;; Stack computations
1188
1189 (defun calculator-reduce-stack (prec)
1190   "Reduce the stack using top operator.
1191 PREC is a precedence - reduce everything with higher precedence."
1192   (while
1193       (cond
1194         ((and (cdr (cdr calculator-stack))         ; have three values
1195               (consp   (nth 0 calculator-stack))   ; two operators & num
1196               (numberp (nth 1 calculator-stack))
1197               (consp   (nth 2 calculator-stack))
1198               (eq '\) (nth 1 (nth 0 calculator-stack)))
1199               (eq '\( (nth 1 (nth 2 calculator-stack))))
1200          ;; reduce "... ( x )" --> "... x"
1201          (setq calculator-stack
1202                (cons (nth 1 calculator-stack)
1203                      (nthcdr 3 calculator-stack)))
1204          ;; another iteration
1205          t)
1206         ((and (cdr (cdr calculator-stack))         ; have three values
1207               (numberp (nth 0 calculator-stack))   ; two nums & operator
1208               (consp   (nth 1 calculator-stack))
1209               (numberp (nth 2 calculator-stack))
1210               (= 2 (calculator-op-arity            ; binary operator
1211                     (nth 1 calculator-stack)))
1212               (<= prec                             ; with higher prec.
1213                   (calculator-op-prec (nth 1 calculator-stack))))
1214          ;; reduce "... x op y" --> "... r", r is the result
1215          (setq calculator-stack
1216                (cons (calculator-funcall
1217                       (nth 2 (nth 1 calculator-stack))
1218                       (nth 2 calculator-stack)
1219                       (nth 0 calculator-stack))
1220                      (nthcdr 3 calculator-stack)))
1221          ;; another iteration
1222          t)
1223         ((and (>= (length calculator-stack) 2)     ; have two values
1224               (numberp (nth 0 calculator-stack))   ; number & operator
1225               (consp   (nth 1 calculator-stack))
1226               (= -1 (calculator-op-arity           ; prefix-unary op
1227                      (nth 1 calculator-stack)))
1228               (<= prec                             ; with higher prec.
1229                   (calculator-op-prec (nth 1 calculator-stack))))
1230          ;; reduce "... op x" --> "... r" for prefix op
1231          (setq calculator-stack
1232                (cons (calculator-funcall
1233                       (nth 2 (nth 1 calculator-stack))
1234                       (nth 0 calculator-stack))
1235                      (nthcdr 2 calculator-stack)))
1236          ;; another iteration
1237          t)
1238         ((and (cdr calculator-stack)               ; have two values
1239               (consp   (nth 0 calculator-stack))   ; operator & number
1240               (numberp (nth 1 calculator-stack))
1241               (= +1 (calculator-op-arity           ; postfix-unary op
1242                      (nth 0 calculator-stack)))
1243               (<= prec                             ; with higher prec.
1244                   (calculator-op-prec (nth 0 calculator-stack))))
1245          ;; reduce "... x op" --> "... r" for postfix op
1246          (setq calculator-stack
1247                (cons (calculator-funcall
1248                       (nth 2 (nth 0 calculator-stack))
1249                       (nth 1 calculator-stack))
1250                      (nthcdr 2 calculator-stack)))
1251          ;; another iteration
1252          t)
1253         ((and calculator-stack                     ; have one value
1254               (consp (nth 0 calculator-stack))     ; an operator
1255               (= 0 (calculator-op-arity            ; 0-ary op
1256                     (nth 0 calculator-stack))))
1257          ;; reduce "... op" --> "... r" for 0-ary op
1258          (setq calculator-stack
1259                (cons (calculator-funcall
1260                       (nth 2 (nth 0 calculator-stack)))
1261                      (nthcdr 1 calculator-stack)))
1262          ;; another iteration
1263          t)
1264         ((and (cdr calculator-stack)               ; have two values
1265               (numberp (nth 0 calculator-stack))   ; both numbers
1266               (numberp (nth 1 calculator-stack)))
1267          ;; get rid of redundant numbers:
1268          ;;   reduce "... y x" --> "... x"
1269          ;; needed for 0-ary ops that puts more values
1270          (setcdr calculator-stack (cdr (cdr calculator-stack))))
1271         (t ;; no more iterations
1272            nil))))
1273
1274 (defun calculator-funcall (f &optional X Y)
1275   "If F is a symbol, evaluate (F X Y).
1276 Otherwise, it should be a list, evaluate it with X, Y bound to the
1277 arguments."
1278   ;; remember binary ops for calculator-repR/L
1279   (if Y (setq calculator-last-opXY (list f X Y)))
1280   (condition-case nil
1281       ;; there used to be code here that returns 0 if the result was
1282       ;; smaller than calculator-epsilon (1e-15).  I don't think this is
1283       ;; necessary now.
1284       (if (symbolp f)
1285         (cond ((and X Y) (funcall f X Y))
1286               (X         (funcall f X))
1287               (t         (funcall f)))
1288         ;; f is an expression
1289         (let* ((__f__ f) ; so we can get this value below...
1290                (TX (calculator-truncate X))
1291                (TY (and Y (calculator-truncate Y)))
1292                (DX (if calculator-deg (/ (* X pi) 180) X))
1293                (L  calculator-saved-list)
1294                (Fbound (fboundp 'F))
1295                (Fsave  (and Fbound (symbol-function 'F)))
1296                (Dbound (fboundp 'D))
1297                (Dsave  (and Dbound (symbol-function 'D))))
1298           ;; a shortened version of flet
1299           (fset 'F (function
1300                     (lambda (&optional x y)
1301                       (calculator-funcall __f__ x y))))
1302           (fset 'D (function
1303                     (lambda (x)
1304                       (if calculator-deg (/ (* x 180) pi) x))))
1305           (unwind-protect (eval f)
1306             (if Fbound (fset 'F Fsave) (fmakunbound 'F))
1307             (if Dbound (fset 'D Dsave) (fmakunbound 'D)))))
1308     (error 0)))
1309
1310 ;;;---------------------------------------------------------------------
1311 ;;; Input interaction
1312
1313 (defun calculator-last-input (&optional keys)
1314   "Last char (or event or event sequence) that was read.
1315 Optional string argument KEYS will force using it as the keys entered."
1316   (let ((inp (or keys (this-command-keys))))
1317     (if (or (stringp inp) (not (arrayp inp)))
1318       inp
1319       ;; this translates kp-x to x and [tries to] create a string to
1320       ;; lookup operators
1321       (let* ((i -1) (converted-str (make-string (length inp) ? )) k)
1322         ;; converts an array to a string the ops lookup with keypad
1323         ;; input
1324         (while (< (setq i (1+ i)) (length inp))
1325           (setq k (aref inp i))
1326           ;; if Emacs will someday have a event-key, then this would
1327           ;; probably be modified anyway
1328           (and (if (fboundp 'key-press-event-p) (key-press-event-p k))
1329                (if (fboundp 'event-key)
1330                    (and (event-key k) (setq k (event-key k)))))
1331           ;; assume all symbols are translatable with an ascii-character
1332           (and (symbolp k)
1333                (setq k (or (get k 'ascii-character) ? )))
1334           (aset converted-str i k))
1335         converted-str))))
1336
1337 (defun calculator-clear-fragile (&optional op)
1338   "Clear the fragile flag if it was set, then maybe reset all.
1339 OP is the operator (if any) that caused this call."
1340   (if (and calculator-display-fragile
1341            (or (not op)
1342                (= -1 (calculator-op-arity op))
1343                (= 0 (calculator-op-arity op))))
1344     ;; reset if last calc finished, and now get a num or prefix or 0-ary
1345     ;; op
1346     (calculator-reset))
1347   (setq calculator-display-fragile nil))
1348
1349 (defun calculator-digit ()
1350   "Enter a single digit."
1351   (interactive)
1352   (let ((inp (aref (calculator-last-input) 0)))
1353     (if (and (or calculator-display-fragile
1354                  (not (numberp (car calculator-stack))))
1355              (cond
1356                ((not calculator-input-radix)     (<= inp ?9))
1357                ((eq calculator-input-radix 'bin) (<= inp ?1))
1358                ((eq calculator-input-radix 'oct) (<= inp ?7))
1359                (t t)))
1360       ;; enter digit if starting a new computation or have an op on the
1361       ;; stack
1362       (progn
1363         (calculator-clear-fragile)
1364         (let ((digit (upcase (char-to-string inp))))
1365           (if (equal calculator-curnum "0")
1366             (setq calculator-curnum nil))
1367           (setq calculator-curnum
1368                 (concat (or calculator-curnum "") digit)))
1369         (calculator-update-display)))))
1370
1371 (defun calculator-decimal ()
1372   "Enter a decimal period."
1373   (interactive)
1374   (if (and (not calculator-input-radix)
1375            (or calculator-display-fragile
1376                (not (numberp (car calculator-stack))))
1377            (not (and calculator-curnum
1378                      (string-match "[.eE]" calculator-curnum))))
1379     ;; enter the period on the same condition as a digit, only if no
1380     ;; period or exponent entered yet
1381     (progn
1382       (calculator-clear-fragile)
1383       (setq calculator-curnum (concat (or calculator-curnum "0") "."))
1384       (calculator-update-display))))
1385
1386 (defun calculator-exp ()
1387   "Enter an `E' exponent character, or a digit in hex input mode."
1388   (interactive)
1389   (if calculator-input-radix
1390     (calculator-digit)
1391     (if (and (or calculator-display-fragile
1392                  (not (numberp (car calculator-stack))))
1393              (not (and calculator-curnum
1394                        (string-match "[eE]" calculator-curnum))))
1395       ;; same condition as above, also no E so far
1396       (progn
1397         (calculator-clear-fragile)
1398         (setq calculator-curnum (concat (or calculator-curnum "1") "e"))
1399         (calculator-update-display)))))
1400
1401 (defun calculator-op (&optional keys)
1402   "Enter an operator on the stack, doing all necessary reductions.
1403 Optional string argument KEYS will force using it as the keys entered."
1404   (interactive)
1405   (catch 'op-error
1406     (let* ((last-inp (calculator-last-input keys))
1407            (op (assoc last-inp calculator-operators)))
1408       (calculator-clear-fragile op)
1409       (if (and calculator-curnum (/= (calculator-op-arity op) 0))
1410         (setq calculator-stack
1411               (cons (calculator-curnum-value) calculator-stack)))
1412       (setq calculator-curnum nil)
1413       (if (and (= 2 (calculator-op-arity op))
1414                (not (and calculator-stack
1415                          (numberp (nth 0 calculator-stack)))))
1416         ;; we have a binary operator but no number - search for a prefix
1417         ;; version
1418         (let ((rest-ops calculator-operators))
1419           (while (not (equal last-inp (car (car rest-ops))))
1420             (setq rest-ops (cdr rest-ops)))
1421           (setq op (assoc last-inp (cdr rest-ops)))
1422           (if (not (and op (= -1 (calculator-op-arity op))))
1423             ;;(error "Binary operator without a first operand")
1424             (progn
1425               (calculator-message
1426                "Binary operator without a first operand")
1427               (throw 'op-error nil)))))
1428       (calculator-reduce-stack
1429        (cond ((eq (nth 1 op) '\() 10)
1430              ((eq (nth 1 op) '\)) 0)
1431              (t (calculator-op-prec op))))
1432       (if (or (and (= -1 (calculator-op-arity op))
1433                    (numberp (car calculator-stack)))
1434               (and (/= (calculator-op-arity op) -1)
1435                    (/= (calculator-op-arity op) 0)
1436                    (not (numberp (car calculator-stack)))))
1437         ;;(error "Unterminated expression")
1438         (progn
1439           (calculator-message "Unterminated expression")
1440           (throw 'op-error nil)))
1441       (setq calculator-stack (cons op calculator-stack))
1442       (calculator-reduce-stack (calculator-op-prec op))
1443       (and (= (length calculator-stack) 1)
1444            (numberp (nth 0 calculator-stack))
1445            ;; the display is fragile if it contains only one number
1446            (setq calculator-display-fragile t)
1447            ;; add number to the saved-list
1448            calculator-add-saved
1449            (if (= 0 calculator-saved-ptr)
1450              (setq calculator-saved-list
1451                    (cons (car calculator-stack) calculator-saved-list))
1452              (let ((p (nthcdr (1- calculator-saved-ptr)
1453                               calculator-saved-list)))
1454                (setcdr p (cons (car calculator-stack) (cdr p))))))
1455       (calculator-update-display))))
1456
1457 (defun calculator-op-or-exp ()
1458   "Either enter an operator or a digit.
1459 Used with +/- for entering them as digits in numbers like 1e-3 (there is
1460 no need for negative numbers since these are handled by unary
1461 operators)."
1462   (interactive)
1463   (if (and (not calculator-display-fragile)
1464            calculator-curnum
1465            (string-match "[eE]$" calculator-curnum))
1466     (calculator-digit)
1467     (calculator-op)))
1468
1469 ;;;---------------------------------------------------------------------
1470 ;;; Input/output modes (not display)
1471
1472 (defun calculator-dec/deg-mode ()
1473   "Set decimal mode for display & input, if decimal, toggle deg mode."
1474   (interactive)
1475   (if calculator-curnum
1476     (setq calculator-stack
1477           (cons (calculator-curnum-value) calculator-stack)))
1478   (setq calculator-curnum nil)
1479   (if (or calculator-input-radix calculator-output-radix)
1480     (progn (setq calculator-input-radix nil)
1481            (setq calculator-output-radix nil))
1482     ;; already decimal - toggle degrees mode
1483     (setq calculator-deg (not calculator-deg)))
1484   (calculator-update-display t))
1485
1486 (defun calculator-radix-mode (&optional keys)
1487   "Set input and display radix modes.
1488 Optional string argument KEYS will force using it as the keys entered."
1489   (interactive)
1490   (calculator-radix-input-mode keys)
1491   (calculator-radix-output-mode keys))
1492
1493 (defun calculator-radix-input-mode (&optional keys)
1494   "Set input radix modes.
1495 Optional string argument KEYS will force using it as the keys entered."
1496   (interactive)
1497   (if calculator-curnum
1498     (setq calculator-stack
1499           (cons (calculator-curnum-value) calculator-stack)))
1500   (setq calculator-curnum nil)
1501   (setq calculator-input-radix
1502         (let ((inp (calculator-last-input keys)))
1503           (cdr (assq (upcase (aref inp (1- (length inp))))
1504                      calculator-char-radix))))
1505   (calculator-update-display))
1506
1507 (defun calculator-radix-output-mode (&optional keys)
1508   "Set display radix modes.
1509 Optional string argument KEYS will force using it as the keys entered."
1510   (interactive)
1511   (if calculator-curnum
1512     (setq calculator-stack
1513           (cons (calculator-curnum-value) calculator-stack)))
1514   (setq calculator-curnum nil)
1515   (setq calculator-output-radix
1516         (let ((inp (calculator-last-input keys)))
1517           (cdr (assq (upcase (aref inp (1- (length inp))))
1518                      calculator-char-radix))))
1519   (calculator-update-display t))
1520
1521 ;;;---------------------------------------------------------------------
1522 ;;; Saved values list
1523
1524 (defun calculator-save-on-list ()
1525   "Evaluate current expression, put result on the saved values list."
1526   (interactive)
1527   (let ((calculator-add-saved t)) ; marks the result to be added
1528     (calculator-enter)))
1529
1530 (defun calculator-clear-saved ()
1531   "Clear the list of saved values in `calculator-saved-list'."
1532   (interactive)
1533   (setq calculator-saved-list nil)
1534   (setq calculator-saved-ptr 0)
1535   (calculator-update-display t))
1536
1537 (defun calculator-saved-move (n)
1538   "Go N elements up the list of saved values."
1539   (interactive)
1540   (and calculator-saved-list
1541        (or (null calculator-stack) calculator-display-fragile)
1542        (progn
1543          (setq calculator-saved-ptr
1544                (max (min (+ n calculator-saved-ptr)
1545                          (length calculator-saved-list))
1546                     0))
1547          (if (nth calculator-saved-ptr calculator-saved-list)
1548            (setq calculator-stack
1549                  (list (nth calculator-saved-ptr calculator-saved-list))
1550                  calculator-display-fragile t)
1551            (calculator-reset))
1552          (calculator-update-display))))
1553
1554 (defun calculator-saved-up ()
1555   "Go up the list of saved values."
1556   (interactive)
1557   (calculator-saved-move +1))
1558
1559 (defun calculator-saved-down ()
1560   "Go down the list of saved values."
1561   (interactive)
1562   (calculator-saved-move -1))
1563
1564 ;;;---------------------------------------------------------------------
1565 ;;; Misc functions
1566
1567 (defun calculator-open-paren ()
1568   "Equivalents of `(' use this."
1569   (interactive)
1570   (calculator-op "("))
1571
1572 (defun calculator-close-paren ()
1573   "Equivalents of `)' use this."
1574   (interactive)
1575   (calculator-op ")"))
1576
1577 (defun calculator-enter ()
1578   "Evaluate current expression."
1579   (interactive)
1580   (calculator-op "="))
1581
1582 (defun calculator-backspace ()
1583   "Backward delete a single digit or a stack element."
1584   (interactive)
1585   (if calculator-curnum
1586     (setq calculator-curnum
1587           (if (> (length calculator-curnum) 1)
1588             (substring calculator-curnum
1589                        0 (1- (length calculator-curnum)))
1590             nil))
1591     (setq calculator-stack (cdr calculator-stack)))
1592   (calculator-update-display))
1593
1594 (defun calculator-clear ()
1595   "Clear current number."
1596   (interactive)
1597   (setq calculator-curnum nil)
1598   (cond
1599     ;; if the current number is from the saved-list - remove it
1600     ((and calculator-display-fragile
1601           calculator-saved-list
1602           (= (car calculator-stack)
1603              (nth calculator-saved-ptr calculator-saved-list)))
1604      (if (= 0 calculator-saved-ptr)
1605        (setq calculator-saved-list (cdr calculator-saved-list))
1606        (let ((p (nthcdr (1- calculator-saved-ptr)
1607                         calculator-saved-list)))
1608          (setcdr p (cdr (cdr p)))
1609          (setq calculator-saved-ptr (1- calculator-saved-ptr))))
1610      (if calculator-saved-list
1611        (setq calculator-stack
1612              (list (nth calculator-saved-ptr calculator-saved-list)))
1613        (calculator-reset)))
1614     ;; reset if fragile or double clear
1615     ((or calculator-display-fragile (eq last-command this-command))
1616      (calculator-reset)))
1617   (calculator-update-display))
1618
1619 (defun calculator-copy ()
1620   "Copy current number to the `kill-ring'."
1621   (interactive)
1622   (let ((calculator-displayer
1623          (or calculator-copy-displayer calculator-displayer))
1624         (calculator-displayers
1625          (if calculator-copy-displayer nil calculator-displayers)))
1626     (calculator-enter)
1627     ;; remove trailing spaces and an index
1628     (let ((s (cdr calculator-stack-display)))
1629       (and s
1630            (if (string-match "^\\([^ ]+\\) *\\(\\[[0-9/]+\\]\\)? *$" s)
1631              (setq s (match-string 1 s)))
1632            (kill-new s)))))
1633
1634 (defun calculator-set-register (reg)
1635   "Set a register value for REG."
1636   (interactive "cRegister to store into: ")
1637   (let* ((as  (assq reg calculator-registers))
1638          (val (progn (calculator-enter) (car calculator-stack))))
1639     (if as
1640       (setcdr as val)
1641       (setq calculator-registers
1642             (cons (cons reg val) calculator-registers)))
1643     (calculator-message "[%c] := %S" reg val)))
1644
1645 (defun calculator-put-value (val)
1646   "Paste VAL as if entered.
1647 Used by `calculator-paste' and `get-register'."
1648   (if (and (numberp val)
1649            ;; (not calculator-curnum)
1650            (or calculator-display-fragile
1651                (not (numberp (car calculator-stack)))))
1652     (progn
1653       (calculator-clear-fragile)
1654       (setq calculator-curnum (let ((calculator-displayer "%S"))
1655                                 (calculator-number-to-string val)))
1656       (calculator-update-display))))
1657
1658 (defun calculator-paste ()
1659   "Paste a value from the `kill-ring'."
1660   (interactive)
1661   (calculator-put-value
1662    (let ((str (replace-regexp-in-string
1663                "^ *\\(.+[^ ]\\) *$" "\\1" (current-kill 0))))
1664      (and (not calculator-input-radix)
1665           calculator-paste-decimals
1666           (string-match "\\([0-9]+\\)\\(\\.[0-9]+\\)?\\(e[0-9]+\\)?"
1667                         str)
1668           (or (match-string 1 str)
1669               (match-string 2 str)
1670               (match-string 3 str))
1671           (setq str (concat (or (match-string 1 str) "0")
1672                             (or (match-string 2 str) ".0")
1673                             (or (match-string 3 str) ""))))
1674      (condition-case nil (calculator-string-to-number str)
1675        (error nil)))))
1676
1677 (defun calculator-get-register (reg)
1678   "Get a value from a register REG."
1679   (interactive "cRegister to get value from: ")
1680   (calculator-put-value (cdr (assq reg calculator-registers))))
1681
1682 (defun calculator-help ()
1683   ;; this is used as the quick reference screen you get with `h'
1684   "Quick reference:
1685 * numbers/operators/parens/./e - enter expressions
1686   + - * / \\(div) %(rem) _(-X,postfix) ;(1/X,postfix) ^(exp) L(og)
1687   Q(sqrt) !(fact) S(in) C(os) T(an) |(or) #(xor) &(and) ~(not)
1688 * >/< repeats last binary operation with its 2nd (1st) arg as postfix op
1689 * I inverses next trig function        * '/\"/{} - display/display args
1690 * D         - switch to all-decimal, or toggle deg/rad mode
1691 * B/O/H/X   - binary/octal/hex mode for i/o (X is a shortcut for H)
1692 * i/o       - prefix for d/b/o/x - set only input/output modes
1693 * enter/=   - evaluate current expr.   * s/g      - set/get a register
1694 * space     - evaluate & save on list  * l/v      - list total/average
1695 * up/down/C-p/C-n - browse saved       * C-delete - clear all saved
1696 * C-insert  - copy whole expr.         * C-return - evaluate, copy, exit
1697 * insert    - paste a number           * backspace- delete backwards
1698 * delete    - clear argument or list value or whole expression (twice)
1699 * escape/q  - exit."
1700   (interactive)
1701   (if (eq last-command 'calculator-help)
1702     (let ((mode-name "Calculator")
1703           (major-mode 'calculator-mode)
1704           (g-map (current-global-map))
1705           (win (selected-window)))
1706       (require 'ehelp)
1707       (if calculator-electric-mode
1708         (use-global-map calculator-saved-global-map))
1709       (if (or (not calculator-electric-mode)
1710               ;; XEmacs has a problem with electric-describe-mode
1711               (featurep 'xemacs))
1712         (describe-mode)
1713         (electric-describe-mode))
1714       (if calculator-electric-mode
1715         (use-global-map g-map))
1716       (select-window win) ; these are for XEmacs (also below)
1717       (message nil))
1718     (let ((one (one-window-p t))
1719           (win (selected-window))
1720           (help-buf (get-buffer-create "*Help*")))
1721       (save-window-excursion
1722         (with-output-to-temp-buffer "*Help*"
1723           (princ (documentation 'calculator-help)))
1724         (if one
1725           (shrink-window-if-larger-than-buffer
1726            (get-buffer-window help-buf)))
1727         (message
1728          "`%s' again for more help, any other key continues normally."
1729          (calculator-last-input))
1730         (select-window win)
1731         (sit-for 360))
1732       (select-window win))))
1733
1734 (defun calculator-quit ()
1735   "Quit calculator."
1736   (interactive)
1737   (set-buffer calculator-buffer)
1738   (let ((inhibit-read-only t)) (erase-buffer))
1739   (if (not calculator-electric-mode)
1740     (progn
1741       (condition-case nil
1742           (while (get-buffer-window calculator-buffer)
1743             (delete-window (get-buffer-window calculator-buffer)))
1744         (error nil))
1745       (kill-buffer calculator-buffer)))
1746   (setq calculator-buffer nil)
1747   (message "Calculator done.")
1748   (if calculator-electric-mode (throw 'calculator-done nil)))
1749
1750 (defun calculator-save-and-quit ()
1751   "Quit the calculator, saving the result on the `kill-ring'."
1752   (interactive)
1753   (calculator-enter)
1754   (calculator-copy)
1755   (calculator-quit))
1756
1757 (defun calculator-repR (x)
1758   "Repeats the last binary operation with its second argument and X.
1759 To use this, apply a binary operator (evaluate it), then call this."
1760   (if calculator-last-opXY
1761     ;; avoid rebinding calculator-last-opXY
1762     (let ((calculator-last-opXY calculator-last-opXY))
1763       (calculator-funcall
1764        (car calculator-last-opXY) x (nth 2 calculator-last-opXY)))
1765     x))
1766
1767 (defun calculator-repL (x)
1768   "Repeats the last binary operation with its first argument and X.
1769 To use this, apply a binary operator (evaluate it), then call this."
1770   (if calculator-last-opXY
1771     ;; avoid rebinding calculator-last-opXY
1772     (let ((calculator-last-opXY calculator-last-opXY))
1773       (calculator-funcall
1774        (car calculator-last-opXY) (nth 1 calculator-last-opXY) x))
1775     x))
1776
1777 (defun calculator-integer-p (x)
1778   "Non-nil if X is equal to an integer."
1779   (condition-case nil
1780       (= x (ftruncate x))
1781     (error nil)))
1782
1783 (defun calculator-expt (x y)
1784   "Compute X^Y, dealing with errors appropriately."
1785   (condition-case
1786       nil
1787       (expt x y)
1788     (domain-error 0.0e+NaN)
1789     (range-error
1790      (cond
1791       ((and (< x 1.0) (> x -1.0))
1792        ;; For small x, the range error comes from large y.
1793        0.0)
1794       ((and (> x 0.0) (< y 0.0))
1795        ;; For large positive x and negative y, the range error
1796        ;; comes from large negative y.
1797        0.0)
1798       ((and (> x 0.0) (> y 0.0))
1799        ;; For large positive x and positive y, the range error
1800        ;; comes from large y.
1801        1.0e+INF)
1802       ;; For the rest, x must be large and negative.
1803       ;; The range errors come from large integer y.
1804       ((< y 0.0)
1805        0.0)
1806       ((eq (logand (truncate y) 1) 1)   ; expansion of cl `oddp'
1807        ;; If y is odd
1808        -1.0e+INF)
1809       (t
1810        ;;
1811        1.0e+INF)))
1812     (error 0.0e+NaN)))
1813
1814 (defun calculator-fact (x)
1815   "Simple factorial of X."
1816   (if (and (>= x 0)
1817            (calculator-integer-p x))
1818       (if (= (calculator-expt (/ x 3.0) x) 1.0e+INF)
1819           1.0e+INF
1820         (let ((r (if (<= x 10) 1 1.0)))
1821           (while (> x 0)
1822             (setq r (* r (truncate x)))
1823             (setq x (1- x)))
1824           (+ 0.0 r)))
1825     (if (= x 1.0e+INF)
1826         x
1827       0.0e+NaN)))
1828
1829 (defun calculator-truncate (n)
1830   "Truncate N, return 0 in case of overflow."
1831   (condition-case nil (truncate n) (error 0)))
1832
1833
1834 (provide 'calculator)
1835
1836 ;; arch-tag: a1b9766c-af8a-4a74-b466-65ad8eeb0c73
1837 ;;; calculator.el ends here