lisp/buff-menu.el

   1 ;;; buff-menu.el --- buffer menu main function and support functions -*- coding:utf-8 -*-
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Edit, delete, or change attributes of all currently active Emacs
  27 ;; buffers from a list summarizing their state.  A good way to browse
  28 ;; any special or scratch buffers you have loaded, since you can't find
  29 ;; them by filename.  The single entry point is `list-buffers',
  30 ;; normally bound to C-x C-b.
  31
  32 ;;; Change Log:
  33
  34 ;; Buffer-menu-view: New function
  35 ;; Buffer-menu-view-other-window: New function
  36
  37 ;; Merged by esr with recent mods to Emacs 19 buff-menu, 23 Mar 1993
  38 ;;
  39 ;; Modified by Bob Weiner, Motorola, Inc., 4/14/89
  40 ;;
  41 ;; Added optional backup argument to 'Buffer-menu-unmark' to make it undelete
  42 ;; current entry and then move to previous one.
  43 ;;
  44 ;; Based on FSF code dating back to 1985.
  45
  46 ;;; Code:
  47
  48 ;;Trying to preserve the old window configuration works well in
  49 ;;simple scenarios, when you enter the buffer menu, use it, and exit it.
  50 ;;But it does strange things when you switch back to the buffer list buffer
  51 ;;with C-x b, later on, when the window configuration is different.
  52 ;;The choice seems to be, either restore the window configuration
  53 ;;in all cases, or in no cases.
  54 ;;I decided it was better not to restore the window config at all. -- rms.
  55
  56 ;;But since then, I changed buffer-menu to use the selected window,
  57 ;;so q now once again goes back to the previous window configuration.
  58
  59 ;;(defvar Buffer-menu-window-config nil
  60 ;;  "Window configuration saved from entry to `buffer-menu'.")
  61
  62 ;; Put buffer *Buffer List* into proper mode right away
  63 ;; so that from now on even list-buffers is enough to get a buffer menu.
  64
  65 (defgroup Buffer-menu nil
  66   "Show a menu of all buffers in a buffer."
  67   :group 'tools
  68   :group 'convenience)
  69
  70 (defcustom Buffer-menu-use-header-line t
  71   "*Non-nil means to use an immovable header-line."
  72   :type 'boolean
  73   :group 'Buffer-menu)
  74
  75 (defface buffer-menu-buffer
  76   '((t (:weight bold)))
  77   "Face used to highlight buffer names in the buffer menu."
  78   :group 'Buffer-menu)
  79 (put 'Buffer-menu-buffer 'face-alias 'buffer-menu-buffer)
  80
  81 (defcustom Buffer-menu-buffer+size-width 26
  82   "*How wide to jointly make the buffer name and size columns."
  83   :type 'number
  84   :group 'Buffer-menu)
  85
  86 (defcustom Buffer-menu-mode-width 16
  87   "*How wide to make the mode name column."
  88   :type 'number
  89   :group 'Buffer-menu)
  90
  91 (defcustom Buffer-menu-use-frame-buffer-list t
  92   "If non-nil, the Buffer Menu uses the selected frame's buffer list.
  93 Buffers that were never selected in that frame are listed at the end.
  94 If the value is nil, the Buffer Menu uses the global buffer list.
  95 This variable matters if the Buffer Menu is sorted by visited order,
  96 as it is by default."
  97   :type 'boolean
  98   :group 'Buffer-menu
  99   :version "22.1")
 100
 101 ;; This should get updated & resorted when you click on a column heading
 102 (defvar Buffer-menu-sort-column nil
 103   "Which column to sort the menu on.
 104 Use 2 to sort by buffer names, or 5 to sort by file names.
 105 A nil value means sort by visited order (the default).")
 106
 107 (defconst Buffer-menu-buffer-column 4)
 108
 109 (defvar Buffer-menu-files-only nil
 110   "Non-nil if the current buffer-menu lists only file buffers.
 111 This variable determines whether reverting the buffer lists only
 112 file buffers.  It affects both manual reverting and reverting by
 113 Auto Revert Mode.")
 114
 115 (make-variable-buffer-local 'Buffer-menu-files-only)
 116
 117 (defvar Info-current-file) ;; from info.el
 118 (defvar Info-current-node) ;; from info.el
 119
 120 (defvar Buffer-menu-mode-map
 121   (let ((map (make-keymap)))
 122     (suppress-keymap map t)
 123     (define-key map "q" 'quit-window)
 124     (define-key map "v" 'Buffer-menu-select)
 125     (define-key map "2" 'Buffer-menu-2-window)
 126     (define-key map "1" 'Buffer-menu-1-window)
 127     (define-key map "f" 'Buffer-menu-this-window)
 128     (define-key map "e" 'Buffer-menu-this-window)
 129     (define-key map "\C-m" 'Buffer-menu-this-window)
 130     (define-key map "o" 'Buffer-menu-other-window)
 131     (define-key map "\C-o" 'Buffer-menu-switch-other-window)
 132     (define-key map "s" 'Buffer-menu-save)
 133     (define-key map "d" 'Buffer-menu-delete)
 134     (define-key map "k" 'Buffer-menu-delete)
 135     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
 136     (define-key map "\C-k" 'Buffer-menu-delete)
 137     (define-key map "x" 'Buffer-menu-execute)
 138     (define-key map " " 'next-line)
 139     (define-key map "n" 'next-line)
 140     (define-key map "p" 'previous-line)
 141     (define-key map "\177" 'Buffer-menu-backup-unmark)
 142     (define-key map "~" 'Buffer-menu-not-modified)
 143     (define-key map "?" 'describe-mode)
 144     (define-key map "u" 'Buffer-menu-unmark)
 145     (define-key map "m" 'Buffer-menu-mark)
 146     (define-key map "t" 'Buffer-menu-visit-tags-table)
 147     (define-key map "%" 'Buffer-menu-toggle-read-only)
 148     (define-key map "b" 'Buffer-menu-bury)
 149     (define-key map "g" 'Buffer-menu-revert)
 150     (define-key map "V" 'Buffer-menu-view)
 151     (define-key map "T" 'Buffer-menu-toggle-files-only)
 152     (define-key map [mouse-2] 'Buffer-menu-mouse-select)
 153     (define-key map [follow-link] 'mouse-face)
 154     map)
 155   "Local keymap for `Buffer-menu-mode' buffers.")
 156
 157 ;; Buffer Menu mode is suitable only for specially formatted data.
 158 (put 'Buffer-menu-mode 'mode-class 'special)
 159
 160 (define-derived-mode Buffer-menu-mode nil "Buffer Menu"
 161   "Major mode for editing a list of buffers.
 162 Each line describes one of the buffers in Emacs.
 163 Letters do not insert themselves; instead, they are commands.
 164 \\<Buffer-menu-mode-map>
 165 \\[Buffer-menu-mouse-select] -- select buffer you click on, in place of the buffer menu.
 166 \\[Buffer-menu-this-window] -- select current line's buffer in place of the buffer menu.
 167 \\[Buffer-menu-other-window] -- select that buffer in another window,
 168   so the buffer menu buffer remains visible in its window.
 169 \\[Buffer-menu-view] -- select current line's buffer, but in view-mode.
 170 \\[Buffer-menu-view-other-window] -- select that buffer in
 171   another window, in view-mode.
 172 \\[Buffer-menu-switch-other-window] -- make another window display that buffer.
 173 \\[Buffer-menu-mark] -- mark current line's buffer to be displayed.
 174 \\[Buffer-menu-select] -- select current line's buffer.
 175   Also show buffers marked with m, in other windows.
 176 \\[Buffer-menu-1-window] -- select that buffer in full-frame window.
 177 \\[Buffer-menu-2-window] -- select that buffer in one window,
 178   together with buffer selected before this one in another window.
 179 \\[Buffer-menu-visit-tags-table] -- visit-tags-table this buffer.
 180 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 181 \\[Buffer-menu-save] -- mark that buffer to be saved, and move down.
 182 \\[Buffer-menu-delete] -- mark that buffer to be deleted, and move down.
 183 \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted, and move up.
 184 \\[Buffer-menu-execute] -- delete or save marked buffers.
 185 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 186   With prefix argument, also move up one line.
 187 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 188 \\[Buffer-menu-toggle-read-only] -- toggle read-only status of buffer on this line.
 189 \\[Buffer-menu-revert] -- update the list of buffers.
 190 \\[Buffer-menu-toggle-files-only] -- toggle whether the menu displays only file buffers.
 191 \\[Buffer-menu-bury] -- bury the buffer listed on this line."
 192   (set (make-local-variable 'revert-buffer-function)
 193        'Buffer-menu-revert-function)
 194   (set (make-local-variable 'buffer-stale-function)
 195        #'(lambda (&optional noconfirm) 'fast))
 196   (setq truncate-lines t)
 197   (setq buffer-read-only t))
 198
 199 ;; This function exists so we can make the doc string of Buffer-menu-mode
 200 ;; look nice.
 201 (defun Buffer-menu-revert ()
 202   "Update the list of buffers."
 203   (interactive)
 204   (revert-buffer))
 205
 206 (defun Buffer-menu-revert-function (ignore1 ignore2)
 207   (or (eq buffer-undo-list t)
 208       (setq buffer-undo-list nil))
 209   ;; We can not use save-excursion here.  The buffer gets erased.
 210   (let ((opoint (point))
 211         (eobp (eobp))
 212         (ocol (current-column))
 213         (oline (progn (move-to-column 4)
 214                       (get-text-property (point) 'buffer)))
 215         (prop (point-min))
 216         ;; do not make undo records for the reversion.
 217         (buffer-undo-list t))
 218     ;; We can be called by Auto Revert Mode with the "*Buffer Menu*"
 219     ;; temporarily the current buffer.  Make sure that the
 220     ;; interactively current buffer is correctly identified with a `.'
 221     ;; by `list-buffers-noselect'.
 222     (with-current-buffer (window-buffer)
 223       (list-buffers-noselect Buffer-menu-files-only))
 224     (if oline
 225         (while (setq prop (next-single-property-change prop 'buffer))
 226           (when (eq (get-text-property prop 'buffer) oline)
 227             (goto-char prop)
 228             (move-to-column ocol)))
 229       (goto-char (if eobp (point-max) opoint)))))
 230
 231 (defun Buffer-menu-toggle-files-only (arg)
 232   "Toggle whether the current buffer-menu displays only file buffers.
 233 With a positive ARG display only file buffers.  With zero or
 234 negative ARG, display other buffers as well."
 235   (interactive "P")
 236   (setq Buffer-menu-files-only
 237         (cond ((not arg) (not Buffer-menu-files-only))
 238               ((> (prefix-numeric-value arg) 0) t)))
 239   (revert-buffer))
 240
 241 \f
 242 (defun Buffer-menu-buffer (error-if-non-existent-p)
 243   "Return buffer described by this line of buffer menu."
 244   (let* ((where (save-excursion
 245                   (beginning-of-line)
 246                   (+ (point) Buffer-menu-buffer-column)))
 247          (name (and (not (eobp)) (get-text-property where 'buffer-name)))
 248          (buf (and (not (eobp)) (get-text-property where 'buffer))))
 249     (if name
 250         (or (get-buffer name)
 251             (and buf (buffer-name buf) buf)
 252             (if error-if-non-existent-p
 253                 (error "No buffer named `%s'" name)
 254               nil))
 255       (or (and buf (buffer-name buf) buf)
 256           (if error-if-non-existent-p
 257               (error "No buffer on this line")
 258             nil)))))
 259 \f
 260 (defun buffer-menu (&optional arg)
 261   "Make a menu of buffers so you can save, delete or select them.
 262 With argument, show only buffers that are visiting files.
 263 Type ? after invocation to get help on commands available.
 264 Type q to remove the buffer menu from the display.
 265
 266 The first column shows `>' for a buffer you have
 267 marked to be displayed, `D' for one you have marked for
 268 deletion, and `.' for the current buffer.
 269
 270 The C column has a `.' for the buffer from which you came.
 271 The R column has a `%' if the buffer is read-only.
 272 The M column has a `*' if it is modified,
 273 or `S' if you have marked it for saving.
 274 After this come the buffer name, its size in characters,
 275 its major mode, and the visited file name (if any)."
 276   (interactive "P")
 277 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 278   (switch-to-buffer (list-buffers-noselect arg))
 279   (message
 280    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 281
 282 (defun buffer-menu-other-window (&optional arg)
 283   "Display a list of buffers in another window.
 284 With the buffer list buffer, you can save, delete or select the buffers.
 285 With argument, show only buffers that are visiting files.
 286 Type ? after invocation to get help on commands available.
 287 Type q to remove the buffer menu from the display.
 288 For more information, see the function `buffer-menu'."
 289   (interactive "P")
 290 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 291   (switch-to-buffer-other-window (list-buffers-noselect arg))
 292   (message
 293    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 294
 295 (defun Buffer-menu-no-header ()
 296   (beginning-of-line)
 297   (if (or Buffer-menu-use-header-line
 298           (not (eq (char-after) ?C)))
 299       t
 300     (ding)
 301     (forward-line 1)
 302     nil))
 303
 304 (defun Buffer-menu-mark ()
 305   "Mark buffer on this line for being displayed by \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 306   (interactive)
 307   (when (Buffer-menu-no-header)
 308     (let ((buffer-read-only nil))
 309       (delete-char 1)
 310       (insert ?>)
 311       (forward-line 1))))
 312
 313 (defun Buffer-menu-unmark (&optional backup)
 314   "Cancel all requested operations on buffer on this line and move down.
 315 Optional prefix arg means move up."
 316   (interactive "P")
 317   (when (Buffer-menu-no-header)
 318     (let* ((buf (Buffer-menu-buffer t))
 319            (mod (buffer-modified-p buf))
 320            (readonly (save-excursion (set-buffer buf) buffer-read-only))
 321            (buffer-read-only nil))
 322       (delete-char 3)
 323       (insert (if readonly (if mod " %*" " % ") (if mod "  *" "   ")))))
 324   (forward-line (if backup -1 1)))
 325
 326 (defun Buffer-menu-backup-unmark ()
 327   "Move up and cancel all requested operations on buffer on line above."
 328   (interactive)
 329   (forward-line -1)
 330   (Buffer-menu-unmark)
 331   (forward-line -1))
 332
 333 (defun Buffer-menu-delete (&optional arg)
 334   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command.
 335 Prefix arg is how many buffers to delete.
 336 Negative arg means delete backwards."
 337   (interactive "p")
 338   (when (Buffer-menu-no-header)
 339     (let ((buffer-read-only nil))
 340       (if (or (null arg) (= arg 0))
 341           (setq arg 1))
 342       (while (> arg 0)
 343         (delete-char 1)
 344         (insert ?D)
 345         (forward-line 1)
 346         (setq arg (1- arg)))
 347       (while (and (< arg 0)
 348                   (Buffer-menu-no-header))
 349         (delete-char 1)
 350         (insert ?D)
 351         (forward-line -1)
 352         (setq arg (1+ arg))))))
 353
 354 (defun Buffer-menu-delete-backwards (&optional arg)
 355   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command
 356 and then move up one line.  Prefix arg means move that many lines."
 357   (interactive "p")
 358   (Buffer-menu-delete (- (or arg 1))))
 359
 360 (defun Buffer-menu-save ()
 361   "Mark buffer on this line to be saved by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 362   (interactive)
 363   (when (Buffer-menu-no-header)
 364     (let ((buffer-read-only nil))
 365       (forward-char 2)
 366       (delete-char 1)
 367       (insert ?S)
 368       (forward-line 1))))
 369
 370 (defun Buffer-menu-not-modified (&optional arg)
 371   "Mark buffer on this line as unmodified (no changes to save)."
 372   (interactive "P")
 373   (save-excursion
 374     (set-buffer (Buffer-menu-buffer t))
 375     (set-buffer-modified-p arg))
 376   (save-excursion
 377    (beginning-of-line)
 378    (forward-char 2)
 379    (if (= (char-after) (if arg ?\s ?*))
 380        (let ((buffer-read-only nil))
 381          (delete-char 1)
 382          (insert (if arg ?* ?\s))))))
 383
 384 (defun Buffer-menu-beginning ()
 385   (goto-char (point-min))
 386   (unless Buffer-menu-use-header-line
 387     (forward-line)))
 388
 389 (defun Buffer-menu-execute ()
 390   "Save and/or delete buffers marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-save] or \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 391   (interactive)
 392   (save-excursion
 393     (Buffer-menu-beginning)
 394     (while (re-search-forward "^..S" nil t)
 395       (let ((modp nil))
 396         (save-excursion
 397           (set-buffer (Buffer-menu-buffer t))
 398           (save-buffer)
 399           (setq modp (buffer-modified-p)))
 400         (let ((buffer-read-only nil))
 401           (delete-char -1)
 402           (insert (if modp ?* ?\s))))))
 403   (save-excursion
 404     (Buffer-menu-beginning)
 405     (let ((buff-menu-buffer (current-buffer))
 406           (buffer-read-only nil))
 407       (while (re-search-forward "^D" nil t)
 408         (forward-char -1)
 409         (let ((buf (Buffer-menu-buffer nil)))
 410           (or (eq buf nil)
 411               (eq buf buff-menu-buffer)
 412               (save-excursion (kill-buffer buf)))
 413           (if (and buf (buffer-name buf))
 414             (progn (delete-char 1)
 415                    (insert ?\s))
 416           (delete-region (point) (progn (forward-line 1) (point)))
 417             (unless (bobp)
 418               (forward-char -1))))))))
 419
 420 (defun Buffer-menu-select ()
 421   "Select this line's buffer; also display buffers marked with `>'.
 422 You can mark buffers with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command.
 423 This command deletes and replaces all the previously existing windows
 424 in the selected frame."
 425   (interactive)
 426   (let ((buff (Buffer-menu-buffer t))
 427         (menu (current-buffer))
 428         (others ())
 429         tem)
 430     (Buffer-menu-beginning)
 431     (while (re-search-forward "^>" nil t)
 432       (setq tem (Buffer-menu-buffer t))
 433       (let ((buffer-read-only nil))
 434         (delete-char -1)
 435         (insert ?\s))
 436       (or (eq tem buff) (memq tem others) (setq others (cons tem others))))
 437     (setq others (nreverse others)
 438           tem (/ (1- (frame-height)) (1+ (length others))))
 439     (delete-other-windows)
 440     (switch-to-buffer buff)
 441     (or (eq menu buff)
 442         (bury-buffer menu))
 443     (if (equal (length others) 0)
 444         (progn
 445 ;;;       ;; Restore previous window configuration before displaying
 446 ;;;       ;; selected buffers.
 447 ;;;       (if Buffer-menu-window-config
 448 ;;;           (progn
 449 ;;;             (set-window-configuration Buffer-menu-window-config)
 450 ;;;             (setq Buffer-menu-window-config nil)))
 451           (switch-to-buffer buff))
 452       (while others
 453         (split-window nil tem)
 454         (other-window 1)
 455         (switch-to-buffer (car others))
 456         (setq others (cdr others)))
 457       (other-window 1)                          ;back to the beginning!
 458 )))
 459
 460
 461 \f
 462 (defun Buffer-menu-visit-tags-table ()
 463   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 464   (interactive)
 465   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 466     (if file
 467         (visit-tags-table file)
 468       (error "Specified buffer has no file"))))
 469
 470 (defun Buffer-menu-1-window ()
 471   "Select this line's buffer, alone, in full frame."
 472   (interactive)
 473   (switch-to-buffer (Buffer-menu-buffer t))
 474   (bury-buffer (other-buffer))
 475   (delete-other-windows))
 476
 477 (defun Buffer-menu-mouse-select (event)
 478   "Select the buffer whose line you click on."
 479   (interactive "e")
 480   (let (buffer)
 481     (save-excursion
 482       (set-buffer (window-buffer (posn-window (event-end event))))
 483       (save-excursion
 484         (goto-char (posn-point (event-end event)))
 485         (setq buffer (Buffer-menu-buffer t))))
 486     (select-window (posn-window (event-end event)))
 487     (if (and (window-dedicated-p (selected-window))
 488              (eq (selected-window) (frame-root-window)))
 489         (switch-to-buffer-other-frame buffer)
 490       (switch-to-buffer buffer))))
 491
 492 (defun Buffer-menu-this-window ()
 493   "Select this line's buffer in this window."
 494   (interactive)
 495   (switch-to-buffer (Buffer-menu-buffer t)))
 496
 497 (defun Buffer-menu-other-window ()
 498   "Select this line's buffer in other window, leaving buffer menu visible."
 499   (interactive)
 500   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 501
 502 (defun Buffer-menu-switch-other-window ()
 503   "Make the other window select this line's buffer.
 504 The current window remains selected."
 505   (interactive)
 506   (let ((pop-up-windows t)
 507         same-window-buffer-names
 508         same-window-regexps)
 509     (display-buffer (Buffer-menu-buffer t))))
 510
 511 (defun Buffer-menu-2-window ()
 512   "Select this line's buffer, with previous buffer in second window."
 513   (interactive)
 514   (let ((buff (Buffer-menu-buffer t))
 515         (menu (current-buffer))
 516         (pop-up-windows t)
 517         same-window-buffer-names
 518         same-window-regexps)
 519     (delete-other-windows)
 520     (switch-to-buffer (other-buffer))
 521     (pop-to-buffer buff)
 522     (bury-buffer menu)))
 523
 524 (defun Buffer-menu-toggle-read-only ()
 525   "Toggle read-only status of buffer on this line, perhaps via version control."
 526   (interactive)
 527   (let (char)
 528     (save-excursion
 529       (set-buffer (Buffer-menu-buffer t))
 530       (vc-toggle-read-only)
 531       (setq char (if buffer-read-only ?% ?\s)))
 532     (save-excursion
 533       (beginning-of-line)
 534       (forward-char 1)
 535       (if (/= (following-char) char)
 536           (let (buffer-read-only)
 537             (delete-char 1)
 538             (insert char))))))
 539
 540 (defun Buffer-menu-bury ()
 541   "Bury the buffer listed on this line."
 542   (interactive)
 543   (when (Buffer-menu-no-header)
 544     (save-excursion
 545       (beginning-of-line)
 546       (bury-buffer (Buffer-menu-buffer t))
 547       (let ((line (buffer-substring (point) (progn (forward-line 1) (point))))
 548             (buffer-read-only nil))
 549         (delete-region (point) (progn (forward-line -1) (point)))
 550         (goto-char (point-max))
 551         (insert line))
 552       (message "Buried buffer moved to the end"))))
 553
 554
 555 (defun Buffer-menu-view ()
 556   "View this line's buffer in View mode."
 557   (interactive)
 558   (view-buffer (Buffer-menu-buffer t)))
 559
 560
 561 (defun Buffer-menu-view-other-window ()
 562   "View this line's buffer in View mode in another window."
 563   (interactive)
 564   (view-buffer-other-window (Buffer-menu-buffer t)))
 565 \f
 566
 567 (define-key ctl-x-map "\C-b" 'list-buffers)
 568
 569 (defun list-buffers (&optional files-only)
 570   "Display a list of names of existing buffers.
 571 The list is displayed in a buffer named `*Buffer List*'.
 572 Note that buffers with names starting with spaces are omitted.
 573 Non-null optional arg FILES-ONLY means mention only file buffers.
 574
 575 For more information, see the function `buffer-menu'."
 576   (interactive "P")
 577   (display-buffer (list-buffers-noselect files-only)))
 578
 579 (defun Buffer-menu-buffer+size (name size &optional name-props size-props)
 580   (if (> (+ (length name) (length size) 2) Buffer-menu-buffer+size-width)
 581       (setq name
 582             (if (string-match "<[0-9]+>$" name)
 583                 (concat (substring name 0
 584                                    (- Buffer-menu-buffer+size-width
 585                                       (max (length size) 3)
 586                                       (match-end 0)
 587                                       (- (match-beginning 0))
 588                                       2))
 589                         ":"             ; narrow ellipsis
 590                         (match-string 0 name))
 591               (concat (substring name 0
 592                                  (- Buffer-menu-buffer+size-width
 593                                     (max (length size) 3)
 594                                     2))
 595                       ":")))            ; narrow ellipsis
 596     ;; Don't put properties on (buffer-name).
 597     (setq name (copy-sequence name)))
 598   (add-text-properties 0 (length name) name-props name)
 599   (add-text-properties 0 (length size) size-props size)
 600   (concat name
 601           (make-string (- Buffer-menu-buffer+size-width
 602                           (length name)
 603                           (length size))
 604                        ?\s)
 605           size))
 606
 607 (defun Buffer-menu-sort (column)
 608   "Sort the buffer menu by COLUMN."
 609   (interactive "P")
 610   (when column
 611     (setq column (prefix-numeric-value column))
 612     (if (< column 2) (setq column 2))
 613     (if (> column 5) (setq column 5)))
 614   (setq Buffer-menu-sort-column column)
 615   (let (buffer-read-only l buf m1 m2)
 616     (save-excursion
 617       (Buffer-menu-beginning)
 618       (while (not (eobp))
 619         (when (buffer-live-p (setq buf (get-text-property (+ (point) 4) 'buffer)))
 620           (setq m1 (char-after)
 621                 m1 (if (memq m1 '(?> ?D)) m1)
 622                 m2 (char-after (+ (point) 2))
 623                 m2 (if (eq m2 ?S) m2))
 624           (if (or m1 m2)
 625               (push (list buf m1 m2) l)))
 626         (forward-line)))
 627     (Buffer-menu-revert)
 628     (setq buffer-read-only)
 629     (save-excursion
 630       (Buffer-menu-beginning)
 631       (while (not (eobp))
 632         (when (setq buf (assq (get-text-property (+ (point) 4) 'buffer) l))
 633           (setq m1 (cadr buf)
 634                 m2 (cadr (cdr buf)))
 635           (when m1
 636             (delete-char 1)
 637             (insert m1)
 638             (backward-char 1))
 639           (when m2
 640             (forward-char 2)
 641             (delete-char 1)
 642             (insert m2)))
 643         (forward-line)))))
 644
 645 (defun Buffer-menu-sort-by-column (&optional e)
 646   "Sort the buffer menu by the column clicked on."
 647   (interactive (list last-input-event))
 648   (if e (mouse-select-window e))
 649   (let* ((pos (event-start e))
 650          (obj (posn-object pos))
 651          (col (if obj
 652                   (get-text-property (cdr obj) 'column (car obj))
 653                 (get-text-property (posn-point pos) 'column))))
 654     (Buffer-menu-sort col)))
 655
 656 (defvar Buffer-menu-sort-button-map
 657   (let ((map (make-sparse-keymap)))
 658     ;; This keymap handles both nil and non-nil values for
 659     ;; Buffer-menu-use-header-line.
 660     (define-key map [header-line mouse-1] 'Buffer-menu-sort-by-column)
 661     (define-key map [header-line mouse-2] 'Buffer-menu-sort-by-column)
 662     (define-key map [mouse-2] 'Buffer-menu-sort-by-column)
 663     (define-key map [follow-link] 'mouse-face)
 664     (define-key map "\C-m" 'Buffer-menu-sort-by-column)
 665     map)
 666   "Local keymap for Buffer menu sort buttons.")
 667
 668 (defun Buffer-menu-make-sort-button (name column)
 669   (if (equal column Buffer-menu-sort-column) (setq column nil))
 670   (propertize name
 671               'column column
 672               'help-echo (concat
 673                           (if Buffer-menu-use-header-line
 674                               "mouse-1, mouse-2: sort by "
 675                             "mouse-2, RET: sort by ")
 676                           (if column (downcase name) "visited order"))
 677               'mouse-face 'highlight
 678               'keymap Buffer-menu-sort-button-map))
 679
 680 (defun list-buffers-noselect (&optional files-only buffer-list)
 681   "Create and return a buffer with a list of names of existing buffers.
 682 The buffer is named `*Buffer List*'.
 683 Note that buffers with names starting with spaces are omitted.
 684 Non-null optional arg FILES-ONLY means mention only file buffers.
 685
 686 If BUFFER-LIST is non-nil, it should be a list of buffers;
 687 it means list those buffers and no others.
 688
 689 For more information, see the function `buffer-menu'."
 690   (let* ((old-buffer (current-buffer))
 691          (standard-output standard-output)
 692          (mode-end (make-string (- Buffer-menu-mode-width 2) ?\s))
 693          (header (concat "CRM "
 694                          (Buffer-menu-buffer+size
 695                           (Buffer-menu-make-sort-button "Buffer" 2)
 696                           (Buffer-menu-make-sort-button "Size" 3))
 697                          "  "
 698                          (Buffer-menu-make-sort-button "Mode" 4) mode-end
 699                          (Buffer-menu-make-sort-button "File" 5) "\n"))
 700          list desired-point)
 701     (when Buffer-menu-use-header-line
 702       (let ((pos 0))
 703         ;; Turn whitespace chars in the header into stretch specs so
 704         ;; they work regardless of the header-line face.
 705         (while (string-match "[ \t\n]+" header pos)
 706           (setq pos (match-end 0))
 707           (put-text-property (match-beginning 0) pos 'display
 708                              ;; Assume fixed-size chars in the buffer.
 709                              (list 'space :align-to pos)
 710                              header)))
 711       ;; Try to better align the one-char headers.
 712       (put-text-property 0 3 'face 'fixed-pitch header)
 713       ;; Add a "dummy" leading space to align the beginning of the header
 714       ;; line with the beginning of the text (rather than with the left
 715       ;; scrollbar or the left fringe).  --Stef
 716       (setq header (concat (propertize " " 'display '(space :align-to 0))
 717                            header)))
 718     (with-current-buffer (get-buffer-create "*Buffer List*")
 719       (setq buffer-read-only nil)
 720       (erase-buffer)
 721       (setq standard-output (current-buffer))
 722       (unless Buffer-menu-use-header-line
 723         ;; Use U+2014 (EM DASH) to underline if possible, else use ASCII
 724         ;; (i.e. U+002D, HYPHEN-MINUS).
 725         (let ((underline (if (char-displayable-p ?\u2014) ?\u2014 ?-)))
 726           (insert header
 727                   (apply 'string
 728                          (mapcar (lambda (c)
 729                                    (if (memq c '(?\n ?\s)) c underline))
 730                                  header)))))
 731       ;; Collect info for every buffer we're interested in.
 732       (dolist (buffer (or buffer-list
 733                           (buffer-list
 734                            (when Buffer-menu-use-frame-buffer-list
 735                              (selected-frame)))))
 736         (with-current-buffer buffer
 737           (let ((name (buffer-name))
 738                 (file buffer-file-name))
 739             (unless (and (not buffer-list)
 740                          (or
 741                           ;; Don't mention internal buffers.
 742                           (and (string= (substring name 0 1) " ") (null file))
 743                           ;; Maybe don't mention buffers without files.
 744                           (and files-only (not file))
 745                           (string= name "*Buffer List*")))
 746               ;; Otherwise output info.
 747               (let ((mode (concat (format-mode-line mode-name nil nil buffer)
 748                                   (if mode-line-process
 749                                       (format-mode-line mode-line-process
 750                                                         nil nil buffer))))
 751                     (bits (string
 752                            (if (eq buffer old-buffer) ?. ?\s)
 753                            ;; Handle readonly status.  The output buffer
 754                            ;; is special cased to appear readonly; it is
 755                            ;; actually made so at a later date.
 756                            (if (or (eq buffer standard-output)
 757                                    buffer-read-only)
 758                                ?% ?\s)
 759                            ;; Identify modified buffers.
 760                            (if (buffer-modified-p) ?* ?\s)
 761                            ;; Space separator.
 762                            ?\s)))
 763                 (unless file
 764                   ;; No visited file.  Check local value of
 765                   ;; list-buffers-directory and, for Info buffers,
 766                   ;; Info-current-file.
 767                   (cond ((and (boundp 'list-buffers-directory)
 768                               list-buffers-directory)
 769                          (setq file list-buffers-directory))
 770                         ((eq major-mode 'Info-mode)
 771                          (setq file Info-current-file)
 772                          (cond
 773                           ((equal file "dir")
 774                            (setq file "*Info Directory*"))
 775                           ((eq file 'apropos)
 776                            (setq file "*Info Apropos*"))
 777                           ((eq file 'history)
 778                            (setq file "*Info History*"))
 779                           ((eq file 'toc)
 780                            (setq file "*Info TOC*"))
 781                           ((not (stringp file))  ;; avoid errors
 782                            (setq file nil))
 783                           (t
 784                            (setq file (concat "("
 785                                               (file-name-nondirectory file)
 786                                               ")"
 787                                               Info-current-node)))))))
 788                 (push (list buffer bits name (buffer-size) mode file)
 789                       list))))))
 790       ;; Preserve the original buffer-list ordering, just in case.
 791       (setq list (nreverse list))
 792       ;; Place the buffers's info in the output buffer, sorted if necessary.
 793       (dolist (buffer
 794                (if Buffer-menu-sort-column
 795                    (sort list
 796                          (if (eq Buffer-menu-sort-column 3)
 797                              (lambda (a b)
 798                                (< (nth Buffer-menu-sort-column a)
 799                                   (nth Buffer-menu-sort-column b)))
 800                            (lambda (a b)
 801                              (string< (nth Buffer-menu-sort-column a)
 802                                       (nth Buffer-menu-sort-column b)))))
 803                  list))
 804         (if (eq (car buffer) old-buffer)
 805             (setq desired-point (point)))
 806         (insert (cadr buffer)
 807                 ;; Put the buffer name into a text property
 808                 ;; so we don't have to extract it from the text.
 809                 ;; This way we avoid problems with unusual buffer names.
 810                 (let ((name (nth 2 buffer))
 811                       (size (int-to-string (nth 3 buffer))))
 812                       (Buffer-menu-buffer+size name size
 813                          `(buffer-name ,name
 814                                        buffer ,(car buffer)
 815                                        font-lock-face buffer-menu-buffer
 816                                        mouse-face highlight
 817                                        help-echo
 818                                        ,(if (>= (length name)
 819                                                 (- Buffer-menu-buffer+size-width
 820                                                    (max (length size) 3)
 821                                                    2))
 822                                             name
 823                                           "mouse-2: select this buffer"))))
 824                   "  "
 825                 (if (> (length (nth 4 buffer)) Buffer-menu-mode-width)
 826                     (substring (nth 4 buffer) 0 Buffer-menu-mode-width)
 827                   (nth 4 buffer)))
 828         (when (nth 5 buffer)
 829           (indent-to (+ Buffer-menu-buffer-column Buffer-menu-buffer+size-width
 830                         Buffer-menu-mode-width 4) 1)
 831           (princ (abbreviate-file-name (nth 5 buffer))))
 832         (princ "\n"))
 833       (Buffer-menu-mode)
 834       (when Buffer-menu-use-header-line
 835         (setq header-line-format header))
 836       ;; DESIRED-POINT doesn't have to be set; it is not when the
 837       ;; current buffer is not displayed for some reason.
 838       (and desired-point
 839            (goto-char desired-point))
 840       (setq Buffer-menu-files-only files-only)
 841       (set-buffer-modified-p nil)
 842       (current-buffer))))
 843
 844 ;; arch-tag: e7dfcfc9-6cb2-46e4-bf55-8ef1936d83c6
 845 ;;; buff-menu.el ends here