lisp/erc/erc-truncate.el

   1 ;;; erc-truncate.el --- Functions for truncating ERC buffers
   2
   3 ;; Copyright (C) 2003, 2004, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Andreas Fuchs <asf@void.at>
   6 ;; Keywords: IRC, chat, client, Internet, logging
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This implements buffer truncation (and optional log file writing
  26 ;; support for the Emacs IRC client. Use `erc-truncate-mode' to switch
  27 ;; on. Use `erc-enable-logging' to enable logging of the stuff which
  28 ;; is getting truncated.
  29
  30 ;;; Code:
  31
  32 (require 'erc)
  33
  34 (defgroup erc-truncate nil
  35   "Truncate buffers when they reach a certain size"
  36   :group 'erc)
  37
  38 (defcustom erc-max-buffer-size 30000
  39   "*Maximum size in chars of each ERC buffer.
  40 Used only when auto-truncation is enabled.
  41 \(see `erc-truncate-buffer' and `erc-insert-post-hook')."
  42   :group 'erc-truncate
  43   :type 'integer)
  44
  45 ;;;###autoload (autoload 'erc-truncate-mode "erc-truncate" nil t)
  46 (define-erc-module truncate nil
  47   "Truncate a query buffer if it gets too large.
  48 This prevents the query buffer from getting too large, which can
  49 bring any grown Emacs to its knees after a few days worth of
  50 tracking heavy-traffic channels."
  51   ;;enable
  52   ((add-hook 'erc-insert-post-hook 'erc-truncate-buffer))
  53   ;; disable
  54   ((remove-hook 'erc-insert-post-hook 'erc-truncate-buffer)))
  55
  56 ;;;###autoload
  57 (defun erc-truncate-buffer-to-size (size &optional buffer)
  58   "Truncates the buffer to the size SIZE.
  59 If BUFFER is not provided, the current buffer is assumed.  The deleted
  60 region is logged if `erc-logging-enabled' returns non-nil."
  61   ;; If buffer is non-nil, but get-buffer does not return anything,
  62   ;; then this is a bug.  If buffer is a buffer name, get the buffer
  63   ;; object.  If buffer is nil, use the current buffer.
  64   (if (not buffer)
  65       (setq buffer (current-buffer))
  66     (unless (get-buffer buffer)
  67       (error "erc-truncate-buffer-to-size: %S is not a buffer" buffer)))
  68   (when (> (buffer-size buffer) (+ size 512))
  69     (save-excursion
  70       (set-buffer buffer)
  71       ;; Note that when erc-insert-post-hook runs, the buffer is
  72       ;; narrowed to the new message.  So do this delicate widening.
  73       ;; I am not sure, I think this was not recommended behavior in
  74       ;; Emacs 20.
  75       (save-restriction
  76         (widen)
  77         (let ((end (- erc-insert-marker size)))
  78           ;; truncate at line boundaries
  79           (goto-char end)
  80           (beginning-of-line)
  81           (setq end (point))
  82           ;; try to save the current buffer using
  83           ;; `erc-save-buffer-in-logs'.  We use this, in case the
  84           ;; user has both `erc-save-buffer-in-logs' and
  85           ;; `erc-truncate-buffer' in `erc-insert-post-hook'.  If
  86           ;; this is the case, only the non-saved part of the current
  87           ;; buffer should be saved.  Rather than appending the
  88           ;; deleted part of the buffer to the log file.
  89           ;;
  90           ;; Alternatively this could be made conditional on:
  91           ;; (not (memq 'erc-save-buffer-in-logs
  92           ;;             erc-insert-post-hook))
  93           ;; Comments?
  94           (when (and (boundp 'erc-enable-logging)
  95                      erc-enable-logging
  96                      (erc-logging-enabled buffer))
  97             (erc-save-buffer-in-logs))
  98           ;; disable undoing for the truncating
  99           (buffer-disable-undo)
 100           (let ((inhibit-read-only t))
 101             (delete-region (point-min) end)))
 102         (buffer-enable-undo)))))
 103
 104 ;;;###autoload
 105 (defun erc-truncate-buffer ()
 106   "Truncates the current buffer to `erc-max-buffer-size'.
 107 Meant to be used in hooks, like `erc-insert-post-hook'."
 108   (interactive)
 109   (erc-truncate-buffer-to-size erc-max-buffer-size))
 110
 111 (provide 'erc-truncate)
 112 ;;; erc-truncate.el ends here
 113 ;;
 114 ;; Local Variables:
 115 ;; indent-tabs-mode: t
 116 ;; tab-width: 8
 117 ;; End:
 118
 119 ;; arch-tag: 22a2ea78-871f-4870-8f1e-efe534170311