lisp/pcmpl-linux.el

   1 ;;; pcmpl-linux.el --- functions for dealing with GNU/Linux completions
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; These functions are for use with GNU/Linux.  Since they depend on a
  24 ;; certain knowledge of the layout of such systems, they probably
  25 ;; won't work very well on other operating systems.
  26
  27 ;;; Code:
  28
  29 (provide 'pcmpl-linux)
  30
  31 (require 'pcomplete)
  32
  33 (defgroup pcmpl-linux nil
  34   "Functions for dealing with GNU/Linux completions."
  35   :group 'pcomplete)
  36
  37 ;; Functions:
  38
  39 ;;;###autoload
  40 (defun pcomplete/kill ()
  41   "Completion for GNU/Linux `kill', using /proc filesystem."
  42   (if (pcomplete-match "^-\\(.*\\)" 0)
  43       (pcomplete-here
  44        (pcomplete-uniqify-list
  45         (split-string
  46          (pcomplete-process-result "kill" "-l")))
  47        (pcomplete-match-string 1 0)))
  48   (while (pcomplete-here
  49           (if (file-directory-p "/proc")
  50               (let ((default-directory "/proc/"))
  51                 (mapcar 'directory-file-name
  52                         (pcomplete-entries "[0-9]+/$"))))
  53           nil 'identity)))
  54
  55 ;;;###autoload
  56 (defun pcomplete/umount ()
  57   "Completion for GNU/Linux `umount'."
  58   (pcomplete-opt "hVafrnvt(pcmpl-linux-fs-types)")
  59   (while (pcomplete-here (pcmpl-linux-mounted-directories)
  60                          nil 'identity)))
  61
  62 ;;;###autoload
  63 (defun pcomplete/mount ()
  64   "Completion for GNU/Linux `mount'."
  65   (pcomplete-opt "hVanfFrsvwt(pcmpl-linux-fs-types)o?L?U?")
  66   (while (pcomplete-here (pcomplete-entries) nil 'identity)))
  67
  68 (defun pcmpl-linux-fs-types ()
  69   "Return a list of available fs modules on GNU/Linux systems."
  70   (let ((kernel-ver (pcomplete-process-result "uname" "-r")))
  71     (mapcar
  72      (function
  73       (lambda (fsobj)
  74         (substring fsobj 0 (- (length fsobj) 2))))
  75      (let ((default-directory
  76              (concat "/lib/modules/" kernel-ver "/fs/")))
  77        (pcomplete-entries "\\.o$")))))
  78
  79 (defun pcmpl-linux-mounted-directories ()
  80   "Return a list of mounted directory names."
  81   (let (points)
  82     (when (file-readable-p "/etc/mtab")
  83       (with-temp-buffer
  84         (insert-file-contents-literally "/etc/mtab")
  85         (while (not (eobp))
  86           (let* ((line (buffer-substring (point) (line-end-position)))
  87                  (args (split-string line " ")))
  88             (setq points (cons (nth 1 args) points)))
  89           (forward-line)))
  90       (pcomplete-uniqify-list points))))
  91
  92 (defun pcmpl-linux-mountable-directories ()
  93   "Return a list of mountable directory names."
  94   (let (points)
  95     (when (file-readable-p "/etc/fstab")
  96       (with-temp-buffer
  97         (insert-file-contents-literally "/etc/fstab")
  98         (while (not (eobp))
  99           (let* ((line (buffer-substring (point) (line-end-position)))
 100                  (args (split-string line "\\s-+")))
 101             (setq points (cons (nth 1 args) points)))
 102           (forward-line)))
 103       (pcomplete-pare-list
 104        (pcomplete-uniqify-list points)
 105        (cons "swap" (pcmpl-linux-mounted-directories))))))
 106
 107 ;; arch-tag: bb0961a6-a623-463d-92c6-497c317293b1
 108 ;;; pcmpl-linux.el ends here