m4/stddef_h.m4

   1 dnl A placeholder for POSIX 2008 <stddef.h>, for platforms that have issues.
   2 # stddef_h.m4 serial 3
   3 dnl Copyright (C) 2009-2011 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_STDDEF_H],
   9 [
  10   AC_REQUIRE([gl_STDDEF_H_DEFAULTS])
  11   AC_REQUIRE([gt_TYPE_WCHAR_T])
  12   if test $gt_cv_c_wchar_t = no; then
  13     HAVE_WCHAR_T=0
  14     STDDEF_H=stddef.h
  15   fi
  16   AC_CACHE_CHECK([whether NULL can be used in arbitrary expressions],
  17     [gl_cv_decl_null_works],
  18     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
  19       int test[2 * (sizeof NULL == sizeof (void *)) -1];
  20 ]])],
  21       [gl_cv_decl_null_works=yes],
  22       [gl_cv_decl_null_works=no])])
  23   if test $gl_cv_decl_null_works = no; then
  24     REPLACE_NULL=1
  25     STDDEF_H=stddef.h
  26   fi
  27   if test -n "$STDDEF_H"; then
  28     gl_NEXT_HEADERS([stddef.h])
  29   fi
  30 ])
  31
  32 AC_DEFUN([gl_STDDEF_MODULE_INDICATOR],
  33 [
  34   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  35   AC_REQUIRE([gl_STDDEF_H_DEFAULTS])
  36   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  37 ])
  38
  39 AC_DEFUN([gl_STDDEF_H_DEFAULTS],
  40 [
  41   dnl Assume proper GNU behavior unless another module says otherwise.
  42   REPLACE_NULL=0;                AC_SUBST([REPLACE_NULL])
  43   HAVE_WCHAR_T=1;                AC_SUBST([HAVE_WCHAR_T])
  44   STDDEF_H='';                   AC_SUBST([STDDEF_H])
  45 ])