lisp/url/url.el

   1 ;;; url.el --- Uniform Resource Locator retrieval tool
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Author: Bill Perry <wmperry@gnu.org>
   7 ;; Keywords: comm, data, processes, hypermedia
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Registered URI schemes: http://www.iana.org/assignments/uri-schemes
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'mailcap)
  33
  34 (eval-when-compile
  35   (require 'mm-decode)
  36   (require 'mm-view))
  37
  38 (require 'url-vars)
  39 (require 'url-cookie)
  40 (require 'url-history)
  41 (require 'url-expand)
  42 (require 'url-privacy)
  43 (require 'url-methods)
  44 (require 'url-proxy)
  45 (require 'url-parse)
  46 (require 'url-util)
  47
  48
  49 (defcustom url-configuration-directory
  50   (locate-user-emacs-file "url/" ".url/")
  51   "Directory used by the URL package for cookies, history, etc."
  52   :type 'directory
  53   :group 'url)
  54
  55 (defun url-do-setup ()
  56   "Setup the URL package.
  57 This is to avoid conflict with user settings if URL is dumped with
  58 Emacs."
  59   (unless url-setup-done
  60
  61     ;; Make OS/2 happy
  62     ;;(push '("http" "80") tcp-binary-process-input-services)
  63
  64     (mailcap-parse-mailcaps)
  65     (mailcap-parse-mimetypes)
  66
  67     ;; Register all the authentication schemes we can handle
  68     (url-register-auth-scheme "basic" nil 4)
  69     (url-register-auth-scheme "digest" nil 7)
  70
  71     (setq url-cookie-file
  72           (or url-cookie-file
  73               (expand-file-name "cookies" url-configuration-directory)))
  74
  75     (setq url-history-file
  76           (or url-history-file
  77               (expand-file-name "history" url-configuration-directory)))
  78
  79     ;; Parse the global history file if it exists, so that it can be used
  80     ;; for URL completion, etc.
  81     (url-history-parse-history)
  82     (url-history-setup-save-timer)
  83
  84     ;; Ditto for cookies
  85     (url-cookie-setup-save-timer)
  86     (url-cookie-parse-file url-cookie-file)
  87
  88     ;; Read in proxy gateways
  89     (let ((noproxy (and (not (assoc "no_proxy" url-proxy-services))
  90                         (or (getenv "NO_PROXY")
  91                             (getenv "no_PROXY")
  92                             (getenv "no_proxy")))))
  93       (if noproxy
  94           (setq url-proxy-services
  95                 (cons (cons "no_proxy"
  96                             (concat "\\("
  97                                     (mapconcat
  98                                      (lambda (x)
  99                                        (cond
 100                                         ((= x ?,) "\\|")
 101                                         ((= x ? ) "")
 102                                         ((= x ?.) (regexp-quote "."))
 103                                         ((= x ?*) ".*")
 104                                         ((= x ??) ".")
 105                                         (t (char-to-string x))))
 106                                      noproxy "") "\\)"))
 107                       url-proxy-services))))
 108
 109     (url-setup-privacy-info)
 110     (run-hooks 'url-load-hook)
 111     (setq url-setup-done t)))
 112
 113 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 114 ;;; Retrieval functions
 115 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 116
 117 (defvar url-redirect-buffer nil
 118   "New buffer into which the retrieval will take place.
 119 Sometimes while retrieving a URL, the URL library needs to use another buffer
 120 than the one returned initially by `url-retrieve'.  In this case, it sets this
 121 variable in the original buffer as a forwarding pointer.")
 122
 123 ;;;###autoload
 124 (defun url-retrieve (url callback &optional cbargs)
 125   "Retrieve URL asynchronously and call CALLBACK with CBARGS when finished.
 126 URL is either a string or a parsed URL.
 127
 128 CALLBACK is called when the object has been completely retrieved, with
 129 the current buffer containing the object, and any MIME headers associated
 130 with it.  It is called as (apply CALLBACK STATUS CBARGS).
 131 STATUS is a list with an even number of elements representing
 132 what happened during the request, with most recent events first,
 133 or an empty list if no events have occurred.  Each pair is one of:
 134
 135 \(:redirect REDIRECTED-TO) - the request was redirected to this URL
 136 \(:error (ERROR-SYMBOL . DATA)) - an error occurred.  The error can be
 137 signaled with (signal ERROR-SYMBOL DATA).
 138
 139 Return the buffer URL will load into, or nil if the process has
 140 already completed (i.e. URL was a mailto URL or similar; in this case
 141 the callback is not called).
 142
 143 The variables `url-request-data', `url-request-method' and
 144 `url-request-extra-headers' can be dynamically bound around the
 145 request; dynamic binding of other variables doesn't necessarily
 146 take effect."
 147 ;;; XXX: There is code in Emacs that does dynamic binding
 148 ;;; of the following variables around url-retrieve:
 149 ;;; url-standalone-mode, url-gateway-unplugged, w3-honor-stylesheets,
 150 ;;; url-confirmation-func, url-cookie-multiple-line,
 151 ;;; url-cookie-{{,secure-}storage,confirmation}
 152 ;;; url-standalone-mode and url-gateway-unplugged should work as
 153 ;;; usual.  url-confirmation-func is only used in nnwarchive.el and
 154 ;;; webmail.el; the latter should be updated.  Is
 155 ;;; url-cookie-multiple-line needed anymore?  The other url-cookie-*
 156 ;;; are (for now) only used in synchronous retrievals.
 157   (url-retrieve-internal url callback (cons nil cbargs)))
 158
 159 (defun url-retrieve-internal (url callback cbargs)
 160   "Internal function; external interface is `url-retrieve'.
 161 CBARGS is what the callback will actually receive - the first item is
 162 the list of events, as described in the docstring of `url-retrieve'."
 163   (url-do-setup)
 164   (url-gc-dead-buffers)
 165   (if (stringp url)
 166        (set-text-properties 0 (length url) nil url))
 167   (if (not (vectorp url))
 168       (setq url (url-generic-parse-url url)))
 169   (if (not (functionp callback))
 170       (error "Must provide a callback function to url-retrieve"))
 171   (unless (url-type url)
 172     (error "Bad url: %s" (url-recreate-url url)))
 173   (let ((loader (url-scheme-get-property (url-type url) 'loader))
 174         (url-using-proxy (if (url-host url)
 175                              (url-find-proxy-for-url url (url-host url))))
 176         (buffer nil)
 177         (asynch (url-scheme-get-property (url-type url) 'asynchronous-p)))
 178     (if url-using-proxy
 179         (setq asynch t
 180               loader 'url-proxy))
 181     (if asynch
 182         (setq buffer (funcall loader url callback cbargs))
 183       (setq buffer (funcall loader url))
 184       (if buffer
 185           (with-current-buffer buffer
 186             (apply callback cbargs))))
 187     (if url-history-track
 188         (url-history-update-url url (current-time)))
 189     buffer))
 190
 191 ;;;###autoload
 192 (defun url-retrieve-synchronously (url)
 193   "Retrieve URL synchronously.
 194 Return the buffer containing the data, or nil if there are no data
 195 associated with it (the case for dired, info, or mailto URLs that need
 196 no further processing).  URL is either a string or a parsed URL."
 197   (url-do-setup)
 198
 199   (lexical-let ((retrieval-done nil)
 200                 (asynch-buffer nil))
 201     (setq asynch-buffer
 202           (url-retrieve url (lambda (&rest ignored)
 203                               (url-debug 'retrieval "Synchronous fetching done (%S)" (current-buffer))
 204                               (setq retrieval-done t
 205                                     asynch-buffer (current-buffer)))))
 206     (if (null asynch-buffer)
 207         ;; We do not need to do anything, it was a mailto or something
 208         ;; similar that takes processing completely outside of the URL
 209         ;; package.
 210         nil
 211       (let ((proc (get-buffer-process asynch-buffer)))
 212         ;; If the access method was synchronous, `retrieval-done' should
 213         ;; hopefully already be set to t.  If it is nil, and `proc' is also
 214         ;; nil, it implies that the async process is not running in
 215         ;; asynch-buffer.  This happens e.g. for FTP files.  In such a case
 216         ;; url-file.el should probably set something like a `url-process'
 217         ;; buffer-local variable so we can find the exact process that we
 218         ;; should be waiting for.  In the mean time, we'll just wait for any
 219         ;; process output.
 220         (while (not retrieval-done)
 221           (url-debug 'retrieval
 222                      "Spinning in url-retrieve-synchronously: %S (%S)"
 223                      retrieval-done asynch-buffer)
 224           (if (buffer-local-value 'url-redirect-buffer asynch-buffer)
 225               (setq proc (get-buffer-process
 226                           (setq asynch-buffer
 227                                 (buffer-local-value 'url-redirect-buffer
 228                                                     asynch-buffer))))
 229             (if (and proc (memq (process-status proc)
 230                                 '(closed exit signal failed))
 231                      ;; Make sure another process hasn't been started.
 232                      (eq proc (or (get-buffer-process asynch-buffer) proc)))
 233                 ;; FIXME: It's not clear whether url-retrieve's callback is
 234                 ;; guaranteed to be called or not.  It seems that url-http
 235                 ;; decides sometimes consciously not to call it, so it's not
 236                 ;; clear that it's a bug, but even then we need to decide how
 237                 ;; url-http can then warn us that the download has completed.
 238                 ;; In the mean time, we use this here workaround.
 239                 ;; XXX: The callback must always be called.  Any
 240                 ;; exception is a bug that should be fixed, not worked
 241                 ;; around.
 242                 (progn ;; Call delete-process so we run any sentinel now.
 243                   (delete-process proc)
 244                   (setq retrieval-done t)))
 245             ;; We used to use `sit-for' here, but in some cases it wouldn't
 246             ;; work because apparently pending keyboard input would always
 247             ;; interrupt it before it got a chance to handle process input.
 248             ;; `sleep-for' was tried but it lead to other forms of
 249             ;; hanging.  --Stef
 250             (unless (or (with-local-quit
 251                           (accept-process-output proc))
 252                         (null proc))
 253               ;; accept-process-output returned nil, maybe because the process
 254               ;; exited (and may have been replaced with another).  If we got
 255               ;; a quit, just stop.
 256               (when quit-flag
 257                 (delete-process proc))
 258               (setq proc (and (not quit-flag)
 259                               (get-buffer-process asynch-buffer)))))))
 260       asynch-buffer)))
 261
 262 (defun url-mm-callback (&rest ignored)
 263   (let ((handle (mm-dissect-buffer t)))
 264     (url-mark-buffer-as-dead (current-buffer))
 265     (with-current-buffer
 266         (generate-new-buffer (url-recreate-url url-current-object))
 267       (if (eq (mm-display-part handle) 'external)
 268           (progn
 269             (set-process-sentinel
 270              ;; Fixme: this shouldn't have to know the form of the
 271              ;; undisplayer produced by `mm-display-part'.
 272              (get-buffer-process (cdr (mm-handle-undisplayer handle)))
 273              `(lambda (proc event)
 274                 (mm-destroy-parts (quote ,handle))))
 275             (message "Viewing externally")
 276             (kill-buffer (current-buffer)))
 277         (display-buffer (current-buffer))
 278         (add-hook 'kill-buffer-hook
 279                   `(lambda () (mm-destroy-parts ',handle))
 280                   nil
 281                   t)))))
 282
 283 (defun url-mm-url (url)
 284   "Retrieve URL and pass to the appropriate viewing application."
 285   ;; These requires could advantageously be moved to url-mm-callback or
 286   ;; turned into autoloads, but I suspect that it would introduce some bugs
 287   ;; because loading those files from a process sentinel or filter may
 288   ;; result in some undesirable carner cases.
 289   (require 'mm-decode)
 290   (require 'mm-view)
 291   (url-retrieve url 'url-mm-callback nil))
 292
 293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 294 ;;; Miscellaneous
 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 296 (defvar url-dead-buffer-list nil)
 297
 298 (defun url-mark-buffer-as-dead (buff)
 299   (push buff url-dead-buffer-list))
 300
 301 (defun url-gc-dead-buffers ()
 302   (let ((buff))
 303     (while (setq buff (pop url-dead-buffer-list))
 304       (if (buffer-live-p buff)
 305           (kill-buffer buff)))))
 306
 307 (cond
 308  ((fboundp 'display-warning)
 309   (defalias 'url-warn 'display-warning))
 310  ((fboundp 'warn)
 311   (defun url-warn (class message &optional level)
 312     (warn "(%s/%s) %s" class (or level 'warning) message)))
 313  (t
 314   (defun url-warn (class message &optional level)
 315     (with-current-buffer (get-buffer-create "*URL-WARNINGS*")
 316       (goto-char (point-max))
 317       (save-excursion
 318         (insert (format "(%s/%s) %s\n" class (or level 'warning) message)))
 319       (display-buffer (current-buffer))))))
 320
 321 (provide 'url)
 322
 323 ;; arch-tag: bc182f1f-d187-4f10-b961-47af2066579a
 324 ;;; url.el ends here