lisp/wid-edit.el

   1 ;;; wid-edit.el --- Functions for creating and using widgets -*-byte-compile-dynamic: t;-*-
   2 ;;
   3 ;; Copyright (C) 1996,97,1999,2000,01,02,2003, 2004  Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Maintainer: FSF
   7 ;; Keywords: extensions
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Wishlist items (from widget.texi):
  27
  28 ;; * The `menu-choice' tag should be prettier, something like the
  29 ;;   abbreviated menus in Open Look.
  30
  31 ;; * Finish `:tab-order'.
  32
  33 ;; * Make indentation work with glyphs and proportional fonts.
  34
  35 ;; * Add commands to show overview of object and class hierarchies to
  36 ;;   the browser.
  37
  38 ;; * Find a way to disable mouse highlight for inactive widgets.
  39
  40 ;; * Find a way to make glyphs look inactive.
  41
  42 ;; * Add `key-binding' widget.
  43
  44 ;; * Add `widget' widget for editing widget specifications.
  45
  46 ;; * Find clean way to implement variable length list.  See
  47 ;;   `TeX-printer-list' for an explanation.
  48
  49 ;; * `C-h' in `widget-prompt-value' should give type specific help.
  50
  51 ;; * A mailto widget. [This should work OK as a url-link if with
  52 ;;   browse-url-browser-function' set up appropriately.]
  53
  54 ;;; Commentary:
  55 ;;
  56 ;; See `widget.el'.
  57
  58 ;;; Code:
  59
  60 ;;; Compatibility.
  61
  62 (defun widget-event-point (event)
  63   "Character position of the end of event if that exists, or nil."
  64   (posn-point (event-end event)))
  65
  66 (defun widget-button-release-event-p (event)
  67   "Non-nil if EVENT is a mouse-button-release event object."
  68   (and (eventp event)
  69        (memq (event-basic-type event) '(mouse-1 mouse-2 mouse-3))
  70        (or (memq 'click (event-modifiers event))
  71            (memq  'drag (event-modifiers event)))))
  72
  73 ;;; Customization.
  74
  75 (defgroup widgets nil
  76   "Customization support for the Widget Library."
  77   :link '(custom-manual "(widget)Top")
  78   :link '(emacs-library-link :tag "Lisp File" "widget.el")
  79   :prefix "widget-"
  80   :group 'extensions
  81   :group 'hypermedia)
  82
  83 (defgroup widget-documentation nil
  84   "Options controling the display of documentation strings."
  85   :group 'widgets)
  86
  87 (defgroup widget-faces nil
  88   "Faces used by the widget library."
  89   :group 'widgets
  90   :group 'faces)
  91
  92 (defvar widget-documentation-face 'widget-documentation-face
  93   "Face used for documentation strings in widgets.
  94 This exists as a variable so it can be set locally in certain buffers.")
  95
  96 (defface widget-documentation-face '((((class color)
  97                                        (background dark))
  98                                       (:foreground "lime green"))
  99                                      (((class color)
 100                                        (background light))
 101                                       (:foreground "dark green"))
 102                                      (t nil))
 103   "Face used for documentation text."
 104   :group 'widget-documentation
 105   :group 'widget-faces)
 106
 107 (defvar widget-button-face 'widget-button-face
 108   "Face used for buttons in widgets.
 109 This exists as a variable so it can be set locally in certain buffers.")
 110
 111 (defface widget-button-face '((t (:weight bold)))
 112   "Face used for widget buttons."
 113   :group 'widget-faces)
 114
 115 (defcustom widget-mouse-face 'highlight
 116   "Face used for widget buttons when the mouse is above them."
 117   :type 'face
 118   :group 'widget-faces)
 119
 120 ;; TTY gets special definitions here and in the next defface, because
 121 ;; the gray colors defined for other displays cause black text on a black
 122 ;; background, at least on light-background TTYs.
 123 (defface widget-field-face '((((type tty))
 124                               :background "yellow3"
 125                               :foreground "black")
 126                              (((class grayscale color)
 127                                (background light))
 128                               :background "gray85")
 129                              (((class grayscale color)
 130                                (background dark))
 131                               :background "dim gray")
 132                              (t
 133                               :slant italic))
 134   "Face used for editable fields."
 135   :group 'widget-faces)
 136
 137 (defface widget-single-line-field-face '((((type tty))
 138                                           :background "green3"
 139                                           :foreground "black")
 140                                          (((class grayscale color)
 141                                            (background light))
 142                                           :background "gray85")
 143                                          (((class grayscale color)
 144                                            (background dark))
 145                                           :background "dim gray")
 146                                          (t
 147                                           :slant italic))
 148   "Face used for editable fields spanning only a single line."
 149   :group 'widget-faces)
 150
 151 ;;; This causes display-table to be loaded, and not usefully.
 152 ;;;(defvar widget-single-line-display-table
 153 ;;;  (let ((table (make-display-table)))
 154 ;;;    (aset table 9  "^I")
 155 ;;;    (aset table 10 "^J")
 156 ;;;    table)
 157 ;;;  "Display table used for single-line editable fields.")
 158
 159 ;;;(when (fboundp 'set-face-display-table)
 160 ;;;  (set-face-display-table 'widget-single-line-field-face
 161 ;;;                       widget-single-line-display-table))
 162
 163 ;;; Utility functions.
 164 ;;
 165 ;; These are not really widget specific.
 166
 167 (defun widget-princ-to-string (object)
 168   "Return string representation of OBJECT, any Lisp object.
 169 No quoting characters are used; no delimiters are printed around
 170 the contents of strings."
 171   (with-output-to-string
 172       (princ object)))
 173
 174 (defun widget-clear-undo ()
 175   "Clear all undo information."
 176   (buffer-disable-undo (current-buffer))
 177   (buffer-enable-undo))
 178
 179 (defcustom widget-menu-max-size 40
 180   "Largest number of items allowed in a popup-menu.
 181 Larger menus are read through the minibuffer."
 182   :group 'widgets
 183   :type 'integer)
 184
 185 (defcustom widget-menu-max-shortcuts 40
 186   "Largest number of items for which it works to choose one with a character.
 187 For a larger number of items, the minibuffer is used."
 188   :group 'widgets
 189   :type 'integer)
 190
 191 (defcustom widget-menu-minibuffer-flag nil
 192   "*Control how to ask for a choice from the keyboard.
 193 Non-nil means use the minibuffer;
 194 nil means read a single character."
 195   :group 'widgets
 196   :type 'boolean)
 197
 198 (defun widget-choose (title items &optional event)
 199   "Choose an item from a list.
 200
 201 First argument TITLE is the name of the list.
 202 Second argument ITEMS is a list whose members are either
 203  (NAME . VALUE), to indicate selectable items, or just strings to
 204  indicate unselectable items.
 205 Optional third argument EVENT is an input event.
 206
 207 The user is asked to choose between each NAME from the items alist,
 208 and the VALUE of the chosen element will be returned.  If EVENT is a
 209 mouse event, and the number of elements in items is less than
 210 `widget-menu-max-size', a popup menu will be used, otherwise the
 211 minibuffer."
 212   (cond ((and (< (length items) widget-menu-max-size)
 213               event (display-popup-menus-p))
 214          ;; Mouse click.
 215          (x-popup-menu event
 216                        (list title (cons "" items))))
 217         ((or widget-menu-minibuffer-flag
 218              (> (length items) widget-menu-max-shortcuts))
 219          ;; Read the choice of name from the minibuffer.
 220          (setq items (widget-remove-if 'stringp items))
 221          (let ((val (completing-read (concat title ": ") items nil t)))
 222            (if (stringp val)
 223                (let ((try (try-completion val items)))
 224                  (when (stringp try)
 225                    (setq val try))
 226                  (cdr (assoc val items))))))
 227         (t
 228          ;; Construct a menu of the choices
 229          ;; and then use it for prompting for a single character.
 230          (let* ((overriding-terminal-local-map (make-sparse-keymap))
 231                 (next-digit ?0)
 232                 map choice some-choice-enabled value)
 233            ;; Define SPC as a prefix char to get to this menu.
 234            (define-key overriding-terminal-local-map " "
 235              (setq map (make-sparse-keymap title)))
 236            (with-current-buffer (get-buffer-create " widget-choose")
 237              (erase-buffer)
 238              (insert "Available choices:\n\n")
 239              (while items
 240                (setq choice (car items) items (cdr items))
 241                (if (consp choice)
 242                    (let* ((name (car choice))
 243                          (function (cdr choice)))
 244                      (insert (format "%c = %s\n" next-digit name))
 245                      (define-key map (vector next-digit) function)
 246                      (setq some-choice-enabled t)))
 247                ;; Allocate digits to disabled alternatives
 248                ;; so that the digit of a given alternative never varies.
 249                (setq next-digit (1+ next-digit)))
 250              (insert "\nC-g = Quit"))
 251            (or some-choice-enabled
 252                (error "None of the choices is currently meaningful"))
 253            (define-key map [?\C-g] 'keyboard-quit)
 254            (define-key map [t] 'keyboard-quit)
 255            (define-key map [?\M-\C-v] 'scroll-other-window)
 256            (define-key map [?\M--] 'negative-argument)
 257            (setcdr map (nreverse (cdr map)))
 258            ;; Read a char with the menu, and return the result
 259            ;; that corresponds to it.
 260            (save-window-excursion
 261              (let ((buf (get-buffer " widget-choose")))
 262                (fit-window-to-buffer (display-buffer buf))
 263                (let ((cursor-in-echo-area t)
 264                      keys
 265                      (char 0)
 266                      (arg 1))
 267                  (while (not (or (and (>= char ?0) (< char next-digit))
 268                                  (eq value 'keyboard-quit)))
 269                    ;; Unread a SPC to lead to our new menu.
 270                    (setq unread-command-events (cons ?\  unread-command-events))
 271                    (setq keys (read-key-sequence title))
 272                    (setq value
 273                          (lookup-key overriding-terminal-local-map keys t)
 274                          char (string-to-char (substring keys 1)))
 275                    (cond ((eq value 'scroll-other-window)
 276                           (let ((minibuffer-scroll-window
 277                                  (get-buffer-window buf)))
 278                             (if (> 0 arg)
 279                                 (scroll-other-window-down
 280                                  (window-height minibuffer-scroll-window))
 281                               (scroll-other-window))
 282                             (setq arg 1)))
 283                          ((eq value 'negative-argument)
 284                           (setq arg -1))
 285                          (t
 286                           (setq arg 1)))))))
 287            (when (eq value 'keyboard-quit)
 288              (error "Canceled"))
 289            value))))
 290
 291 (defun widget-remove-if (predictate list)
 292   (let (result (tail list))
 293     (while tail
 294       (or (funcall predictate (car tail))
 295           (setq result (cons (car tail) result)))
 296       (setq tail (cdr tail)))
 297     (nreverse result)))
 298
 299 ;;; Widget text specifications.
 300 ;;
 301 ;; These functions are for specifying text properties.
 302
 303 ;; We can set it to nil now that get_local_map uses get_pos_property.
 304 (defconst widget-field-add-space nil
 305   "Non-nil means add extra space at the end of editable text fields.
 306 If you don't add the space, it will become impossible to edit a zero
 307 size field.")
 308
 309 (defvar widget-field-use-before-change t
 310   "Non-nil means use `before-change-functions' to track editable fields.
 311 This enables the use of undo, but doesn't work on Emacs 19.34 and earlier.
 312 Using before hooks also means that the :notify function can't know the
 313 new value.")
 314
 315 (defun widget-specify-field (widget from to)
 316   "Specify editable button for WIDGET between FROM and TO."
 317   ;; Terminating space is not part of the field, but necessary in
 318   ;; order for local-map to work.  Remove next sexp if local-map works
 319   ;; at the end of the overlay.
 320   (save-excursion
 321     (goto-char to)
 322     (cond ((null (widget-get widget :size))
 323            (forward-char 1))
 324           (widget-field-add-space
 325            (insert-and-inherit " ")))
 326     (setq to (point)))
 327   (let ((keymap (widget-get widget :keymap))
 328         (face (or (widget-get widget :value-face) 'widget-field-face))
 329         (help-echo (widget-get widget :help-echo))
 330         (follow-link (widget-get widget :follow-link))
 331         (rear-sticky
 332          (or (not widget-field-add-space) (widget-get widget :size))))
 333     (if (functionp help-echo)
 334       (setq help-echo 'widget-mouse-help))
 335     (when (= (char-before to) ?\n)
 336       ;; When the last character in the field is a newline, we want to
 337       ;; give it a `field' char-property of `boundary', which helps the
 338       ;; C-n/C-p act more naturally when entering/leaving the field.  We
 339      ;; do this by making a small secondary overlay to contain just that
 340       ;; one character.
 341       (let ((overlay (make-overlay (1- to) to nil t nil)))
 342         (overlay-put overlay 'field 'boundary)
 343         ;; We need the real field for tabbing.
 344         (overlay-put overlay 'real-field widget)
 345         ;; Use `local-map' here, not `keymap', so that normal editing
 346         ;; works in the field when, say, Custom uses `suppress-keymap'.
 347         (overlay-put overlay 'local-map keymap)
 348         (overlay-put overlay 'face face)
 349         (overlay-put overlay 'follow-link follow-link)
 350         (overlay-put overlay 'help-echo help-echo))
 351       (setq to (1- to))
 352       (setq rear-sticky t))
 353     (let ((overlay (make-overlay from to nil nil rear-sticky)))
 354       (widget-put widget :field-overlay overlay)
 355       ;;(overlay-put overlay 'detachable nil)
 356       (overlay-put overlay 'field widget)
 357       (overlay-put overlay 'local-map keymap)
 358       (overlay-put overlay 'face face)
 359       (overlay-put overlay 'follow-link follow-link)
 360       (overlay-put overlay 'help-echo help-echo)))
 361   (widget-specify-secret widget))
 362
 363 (defun widget-specify-secret (field)
 364   "Replace text in FIELD with value of `:secret', if non-nil."
 365   (let ((secret (widget-get field :secret))
 366         (size (widget-get field :size)))
 367     (when secret
 368       (let ((begin (widget-field-start field))
 369             (end (widget-field-end field)))
 370         (when size
 371           (while (and (> end begin)
 372                       (eq (char-after (1- end)) ?\ ))
 373             (setq end (1- end))))
 374         (while (< begin end)
 375           (let ((old (char-after begin)))
 376             (unless (eq old secret)
 377               (subst-char-in-region begin (1+ begin) old secret)
 378               (put-text-property begin (1+ begin) 'secret old))
 379             (setq begin (1+ begin))))))))
 380
 381 (defun widget-specify-button (widget from to)
 382   "Specify button for WIDGET between FROM and TO."
 383   (let ((overlay (make-overlay from to nil t nil))
 384         (follow-link (widget-get widget :follow-link))
 385         (help-echo (widget-get widget :help-echo)))
 386     (widget-put widget :button-overlay overlay)
 387     (if (functionp help-echo)
 388       (setq help-echo 'widget-mouse-help))
 389     (overlay-put overlay 'button widget)
 390     (overlay-put overlay 'keymap (widget-get widget :keymap))
 391     (overlay-put overlay 'evaporate t)
 392     ;; We want to avoid the face with image buttons.
 393     (unless (widget-get widget :suppress-face)
 394       (overlay-put overlay 'face (widget-apply widget :button-face-get))
 395       ; Text terminals cannot change mouse pointer shape, so use mouse
 396       ; face instead.
 397       (or (display-graphic-p)
 398           (overlay-put overlay 'mouse-face widget-mouse-face)))
 399     (overlay-put overlay 'pointer 'hand)
 400     (overlay-put overlay 'follow-link follow-link)
 401     (overlay-put overlay 'help-echo help-echo)))
 402
 403 (defun widget-mouse-help (window overlay point)
 404   "Help-echo callback for widgets whose :help-echo is a function."
 405   (with-current-buffer (overlay-buffer overlay)
 406     (let* ((widget (widget-at (overlay-start overlay)))
 407            (help-echo (if widget (widget-get widget :help-echo))))
 408       (if (functionp help-echo)
 409           (funcall help-echo widget)
 410         help-echo))))
 411
 412 (defun widget-specify-sample (widget from to)
 413   "Specify sample for WIDGET between FROM and TO."
 414   (let ((overlay (make-overlay from to nil t nil)))
 415     (overlay-put overlay 'face (widget-apply widget :sample-face-get))
 416     (overlay-put overlay 'evaporate t)
 417     (widget-put widget :sample-overlay overlay)))
 418
 419 (defun widget-specify-doc (widget from to)
 420   "Specify documentation for WIDGET between FROM and TO."
 421   (let ((overlay (make-overlay from to nil t nil)))
 422     (overlay-put overlay 'widget-doc widget)
 423     (overlay-put overlay 'face widget-documentation-face)
 424     (overlay-put overlay 'evaporate t)
 425     (widget-put widget :doc-overlay overlay)))
 426
 427 (defmacro widget-specify-insert (&rest form)
 428   "Execute FORM without inheriting any text properties."
 429   `(save-restriction
 430     (let ((inhibit-read-only t)
 431           (inhibit-modification-hooks t))
 432       (narrow-to-region (point) (point))
 433       (prog1 (progn ,@form)
 434         (goto-char (point-max))))))
 435
 436 (defface widget-inactive-face '((((class grayscale color)
 437                                   (background dark))
 438                                  (:foreground "light gray"))
 439                                 (((class grayscale color)
 440                                   (background light))
 441                                  (:foreground "dim gray"))
 442                                 (t
 443                                  (:slant italic)))
 444   "Face used for inactive widgets."
 445   :group 'widget-faces)
 446
 447 (defun widget-specify-inactive (widget from to)
 448   "Make WIDGET inactive for user modifications."
 449   (unless (widget-get widget :inactive)
 450     (let ((overlay (make-overlay from to nil t nil)))
 451       (overlay-put overlay 'face 'widget-inactive-face)
 452       ;; This is disabled, as it makes the mouse cursor change shape.
 453       ;; (overlay-put overlay 'mouse-face 'widget-inactive-face)
 454       (overlay-put overlay 'evaporate t)
 455       (overlay-put overlay 'priority 100)
 456       (overlay-put overlay 'modification-hooks '(widget-overlay-inactive))
 457       (widget-put widget :inactive overlay))))
 458
 459 (defun widget-overlay-inactive (&rest junk)
 460   "Ignoring the arguments, signal an error."
 461   (unless inhibit-read-only
 462     (error "The widget here is not active")))
 463
 464
 465 (defun widget-specify-active (widget)
 466   "Make WIDGET active for user modifications."
 467   (let ((inactive (widget-get widget :inactive)))
 468     (when inactive
 469       (delete-overlay inactive)
 470       (widget-put widget :inactive nil))))
 471
 472 ;;; Widget Properties.
 473
 474 (defsubst widget-type (widget)
 475   "Return the type of WIDGET, a symbol."
 476   (car widget))
 477
 478 ;;;###autoload
 479 (defun widgetp (widget)
 480   "Return non-nil iff WIDGET is a widget."
 481   (if (symbolp widget)
 482       (get widget 'widget-type)
 483     (and (consp widget)
 484          (symbolp (car widget))
 485          (get (car widget) 'widget-type))))
 486
 487 (defun widget-get-indirect (widget property)
 488   "In WIDGET, get the value of PROPERTY.
 489 If the value is a symbol, return its binding.
 490 Otherwise, just return the value."
 491   (let ((value (widget-get widget property)))
 492     (if (symbolp value)
 493         (symbol-value value)
 494       value)))
 495
 496 (defun widget-member (widget property)
 497   "Non-nil iff there is a definition in WIDGET for PROPERTY."
 498   (cond ((plist-member (cdr widget) property)
 499          t)
 500         ((car widget)
 501          (widget-member (get (car widget) 'widget-type) property))
 502         (t nil)))
 503
 504 (defun widget-value (widget)
 505   "Extract the current value of WIDGET."
 506   (widget-apply widget
 507                 :value-to-external (widget-apply widget :value-get)))
 508
 509 (defun widget-value-set (widget value)
 510   "Set the current value of WIDGET to VALUE."
 511   (widget-apply widget
 512                 :value-set (widget-apply widget
 513                                          :value-to-internal value)))
 514
 515 (defun widget-default-get (widget)
 516   "Extract the default external value of WIDGET."
 517   (widget-apply widget :value-to-external
 518                 (or (widget-get widget :value)
 519                     (widget-apply widget :default-get))))
 520
 521 (defun widget-match-inline (widget vals)
 522   "In WIDGET, match the start of VALS."
 523   (cond ((widget-get widget :inline)
 524          (widget-apply widget :match-inline vals))
 525         ((and (listp vals)
 526               (widget-apply widget :match (car vals)))
 527          (cons (list (car vals)) (cdr vals)))
 528         (t nil)))
 529
 530 (defun widget-apply-action (widget &optional event)
 531   "Apply :action in WIDGET in response to EVENT."
 532   (if (widget-apply widget :active)
 533       (widget-apply widget :action event)
 534     (error "Attempt to perform action on inactive widget")))
 535
 536 ;;; Helper functions.
 537 ;;
 538 ;; These are widget specific.
 539
 540 ;;;###autoload
 541 (defun widget-prompt-value (widget prompt &optional value unbound)
 542   "Prompt for a value matching WIDGET, using PROMPT.
 543 The current value is assumed to be VALUE, unless UNBOUND is non-nil."
 544   (unless (listp widget)
 545     (setq widget (list widget)))
 546   (setq prompt (format "[%s] %s" (widget-type widget) prompt))
 547   (setq widget (widget-convert widget))
 548   (let ((answer (widget-apply widget :prompt-value prompt value unbound)))
 549     (unless (widget-apply widget :match answer)
 550       (error "Value does not match %S type" (car widget)))
 551     answer))
 552
 553 (defun widget-get-sibling (widget)
 554   "Get the item WIDGET is assumed to toggle.
 555 This is only meaningful for radio buttons or checkboxes in a list."
 556   (let* ((children (widget-get (widget-get widget :parent) :children))
 557          child)
 558     (catch 'child
 559       (while children
 560         (setq child (car children)
 561               children (cdr children))
 562         (when (eq (widget-get child :button) widget)
 563           (throw 'child child)))
 564       nil)))
 565
 566 (defun widget-map-buttons (function &optional buffer maparg)
 567   "Map FUNCTION over the buttons in BUFFER.
 568 FUNCTION is called with the arguments WIDGET and MAPARG.
 569
 570 If FUNCTION returns non-nil, the walk is cancelled.
 571
 572 The arguments MAPARG, and BUFFER default to nil and (current-buffer),
 573 respectively."
 574   (let ((cur (point-min))
 575         (widget nil)
 576         (overlays (if buffer
 577                       (with-current-buffer buffer (overlay-lists))
 578                     (overlay-lists))))
 579     (setq overlays (append (car overlays) (cdr overlays)))
 580     (while (setq cur (pop overlays))
 581       (setq widget (overlay-get cur 'button))
 582       (if (and widget (funcall function widget maparg))
 583           (setq overlays nil)))))
 584
 585 ;;; Images.
 586
 587 (defcustom widget-image-directory (file-name-as-directory
 588                                    (expand-file-name "custom" data-directory))
 589   "Where widget button images are located.
 590 If this variable is nil, widget will try to locate the directory
 591 automatically."
 592   :group 'widgets
 593   :type 'directory)
 594
 595 (defcustom widget-image-enable t
 596   "If non nil, use image buttons in widgets when available."
 597   :version "21.1"
 598   :group 'widgets
 599   :type 'boolean)
 600
 601 (defcustom widget-image-conversion
 602   '((xpm ".xpm") (gif ".gif") (png ".png") (jpeg ".jpg" ".jpeg")
 603     (xbm ".xbm"))
 604   "Conversion alist from image formats to file name suffixes."
 605   :group 'widgets
 606   :type '(repeat (cons :format "%v"
 607                        (symbol :tag "Image Format" unknown)
 608                        (repeat :tag "Suffixes"
 609                                (string :format "%v")))))
 610
 611 (defun widget-image-find (image)
 612   "Create a graphical button from IMAGE.
 613 IMAGE should either already be an image, or be a file name sans
 614 extension (xpm, xbm, gif, jpg, or png) located in
 615 `widget-image-directory' or otherwise where `find-image' will find it."
 616   (cond ((not (and image widget-image-enable (display-graphic-p)))
 617          ;; We don't want or can't use images.
 618          nil)
 619         ((and (consp image)
 620               (eq 'image (car image)))
 621          ;; Already an image spec.  Use it.
 622          image)
 623         ((stringp image)
 624          ;; A string.  Look it up in relevant directories.
 625          (let* ((load-path (cons widget-image-directory load-path))
 626                 specs)
 627            (dolist (elt widget-image-conversion)
 628              (dolist (ext (cdr elt))
 629                (push (list :type (car elt) :file (concat image ext)) specs)))
 630            (setq specs (nreverse specs))
 631            (find-image specs)))
 632         (t
 633          ;; Oh well.
 634          nil)))
 635
 636 (defvar widget-button-pressed-face 'widget-button-pressed-face
 637   "Face used for pressed buttons in widgets.
 638 This exists as a variable so it can be set locally in certain
 639 buffers.")
 640
 641 (defun widget-image-insert (widget tag image &optional down inactive)
 642   "In WIDGET, insert the text TAG or, if supported, IMAGE.
 643 IMAGE should either be an image or an image file name sans extension
 644 \(xpm, xbm, gif, jpg, or png) located in `widget-image-directory'.
 645
 646 Optional arguments DOWN and INACTIVE are used instead of IMAGE when the
 647 button is pressed or inactive, respectively.  These are currently ignored."
 648   (if (and (display-graphic-p)
 649            (setq image (widget-image-find image)))
 650       (progn (widget-put widget :suppress-face t)
 651              (insert-image image
 652                            (propertize
 653                             tag 'mouse-face widget-button-pressed-face)))
 654     (insert tag)))
 655
 656 ;;; Buttons.
 657
 658 (defgroup widget-button nil
 659   "The look of various kinds of buttons."
 660   :group 'widgets)
 661
 662 (defcustom widget-button-prefix ""
 663   "String used as prefix for buttons."
 664   :type 'string
 665   :group 'widget-button)
 666
 667 (defcustom widget-button-suffix ""
 668   "String used as suffix for buttons."
 669   :type 'string
 670   :group 'widget-button)
 671
 672 ;;; Creating Widgets.
 673
 674 ;;;###autoload
 675 (defun widget-create (type &rest args)
 676   "Create widget of TYPE.
 677 The optional ARGS are additional keyword arguments."
 678   (let ((widget (apply 'widget-convert type args)))
 679     (widget-apply widget :create)
 680     widget))
 681
 682 (defun widget-create-child-and-convert (parent type &rest args)
 683   "As part of the widget PARENT, create a child widget TYPE.
 684 The child is converted, using the keyword arguments ARGS."
 685   (let ((widget (apply 'widget-convert type args)))
 686     (widget-put widget :parent parent)
 687     (unless (widget-get widget :indent)
 688       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 689                                     (or (widget-get widget :extra-offset) 0)
 690                                     (widget-get parent :offset))))
 691     (widget-apply widget :create)
 692     widget))
 693
 694 (defun widget-create-child (parent type)
 695   "Create widget of TYPE."
 696   (let ((widget (widget-copy type)))
 697     (widget-put widget :parent parent)
 698     (unless (widget-get widget :indent)
 699       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 700                                     (or (widget-get widget :extra-offset) 0)
 701                                     (widget-get parent :offset))))
 702     (widget-apply widget :create)
 703     widget))
 704
 705 (defun widget-create-child-value (parent type value)
 706   "Create widget of TYPE with value VALUE."
 707   (let ((widget (widget-copy type)))
 708     (widget-put widget :value (widget-apply widget :value-to-internal value))
 709     (widget-put widget :parent parent)
 710     (unless (widget-get widget :indent)
 711       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 712                                     (or (widget-get widget :extra-offset) 0)
 713                                     (widget-get parent :offset))))
 714     (widget-apply widget :create)
 715     widget))
 716
 717 ;;;###autoload
 718 (defun widget-delete (widget)
 719   "Delete WIDGET."
 720   (widget-apply widget :delete))
 721
 722 (defun widget-copy (widget)
 723   "Make a deep copy of WIDGET."
 724   (widget-apply (copy-sequence widget) :copy))
 725
 726 (defun widget-convert (type &rest args)
 727   "Convert TYPE to a widget without inserting it in the buffer.
 728 The optional ARGS are additional keyword arguments."
 729   ;; Don't touch the type.
 730   (let* ((widget (if (symbolp type)
 731                      (list type)
 732                    (copy-sequence type)))
 733          (current widget)
 734          done
 735          (keys args))
 736     ;; First set the :args keyword.
 737     (while (cdr current)                ;Look in the type.
 738       (if (and (keywordp (cadr current))
 739                ;; If the last element is a keyword,
 740                ;; it is still the :args element,
 741                ;; even though it is a keyword.
 742                (cddr current))
 743           (if (eq (cadr current) :args)
 744               ;; If :args is explicitly specified, obey it.
 745               (setq current nil)
 746             ;; Some other irrelevant keyword.
 747             (setq current (cdr (cdr current))))
 748         (setcdr current (list :args (cdr current)))
 749         (setq current nil)))
 750     (while (and args (not done))        ;Look in ARGS.
 751       (cond ((eq (car args) :args)
 752              ;; Handle explicit specification of :args.
 753              (setq args (cadr args)
 754                    done t))
 755             ((keywordp (car args))
 756              (setq args (cddr args)))
 757             (t (setq done t))))
 758     (when done
 759       (widget-put widget :args args))
 760     ;; Then Convert the widget.
 761     (setq type widget)
 762     (while type
 763       (let ((convert-widget (plist-get (cdr type) :convert-widget)))
 764         (if convert-widget
 765             (setq widget (funcall convert-widget widget))))
 766       (setq type (get (car type) 'widget-type)))
 767     ;; Finally set the keyword args.
 768     (while keys
 769       (let ((next (nth 0 keys)))
 770         (if (keywordp next)
 771             (progn
 772               (widget-put widget next (nth 1 keys))
 773               (setq keys (nthcdr 2 keys)))
 774           (setq keys nil))))
 775     ;; Convert the :value to internal format.
 776     (if (widget-member widget :value)
 777         (widget-put widget
 778                     :value (widget-apply widget
 779                                          :value-to-internal
 780                                          (widget-get widget :value))))
 781     ;; Return the newly create widget.
 782     widget))
 783
 784 ;;;###autoload
 785 (defun widget-insert (&rest args)
 786   "Call `insert' with ARGS even if surrounding text is read only."
 787   (let ((inhibit-read-only t)
 788         (inhibit-modification-hooks t))
 789     (apply 'insert args)))
 790
 791 (defun widget-convert-text (type from to
 792                                  &optional button-from button-to
 793                                  &rest args)
 794   "Return a widget of type TYPE with endpoint FROM TO.
 795 Optional ARGS are extra keyword arguments for TYPE.
 796 and TO will be used as the widgets end points. If optional arguments
 797 BUTTON-FROM and BUTTON-TO are given, these will be used as the widgets
 798 button end points.
 799 Optional ARGS are extra keyword arguments for TYPE."
 800   (let ((widget (apply 'widget-convert type :delete 'widget-leave-text args))
 801         (from (copy-marker from))
 802         (to (copy-marker to)))
 803     (set-marker-insertion-type from t)
 804     (set-marker-insertion-type to nil)
 805     (widget-put widget :from from)
 806     (widget-put widget :to to)
 807     (when button-from
 808       (widget-specify-button widget button-from button-to))
 809     widget))
 810
 811 (defun widget-convert-button (type from to &rest args)
 812   "Return a widget of type TYPE with endpoint FROM TO.
 813 Optional ARGS are extra keyword arguments for TYPE.
 814 No text will be inserted to the buffer, instead the text between FROM
 815 and TO will be used as the widgets end points, as well as the widgets
 816 button end points."
 817   (apply 'widget-convert-text type from to from to args))
 818
 819 (defun widget-leave-text (widget)
 820   "Remove markers and overlays from WIDGET and its children."
 821   (let ((button (widget-get widget :button-overlay))
 822         (sample (widget-get widget :sample-overlay))
 823         (doc (widget-get widget :doc-overlay))
 824         (field (widget-get widget :field-overlay)))
 825     (set-marker (widget-get widget :from) nil)
 826     (set-marker (widget-get widget :to) nil)
 827     (when button
 828       (delete-overlay button))
 829     (when sample
 830       (delete-overlay sample))
 831     (when doc
 832       (delete-overlay doc))
 833     (when field
 834       (delete-overlay field))
 835     (mapc 'widget-leave-text (widget-get widget :children))))
 836
 837 ;;; Keymap and Commands.
 838
 839 ;;;###autoload
 840 (defvar widget-keymap
 841   (let ((map (make-sparse-keymap)))
 842     (define-key map "\t" 'widget-forward)
 843     (define-key map [(shift tab)] 'widget-backward)
 844     (define-key map [backtab] 'widget-backward)
 845     (define-key map [down-mouse-2] 'widget-button-click)
 846     (define-key map "\C-m" 'widget-button-press)
 847     map)
 848   "Keymap containing useful binding for buffers containing widgets.
 849 Recommended as a parent keymap for modes using widgets.")
 850
 851 (defvar widget-global-map global-map
 852   "Keymap used for events a widget does not handle itself.")
 853 (make-variable-buffer-local 'widget-global-map)
 854
 855 (defvar widget-field-keymap
 856   (let ((map (copy-keymap widget-keymap)))
 857     (define-key map "\C-k" 'widget-kill-line)
 858     (define-key map "\M-\t" 'widget-complete)
 859     (define-key map "\C-m" 'widget-field-activate)
 860     ;; Since the widget code uses a `field' property to identify fields,
 861     ;; ordinary beginning-of-line does the right thing.
 862     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 863     (define-key map "\C-e" 'widget-end-of-line)
 864     map)
 865   "Keymap used inside an editable field.")
 866
 867 (defvar widget-text-keymap
 868   (let ((map (copy-keymap widget-keymap)))
 869     ;; Since the widget code uses a `field' property to identify fields,
 870     ;; ordinary beginning-of-line does the right thing.
 871     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 872     (define-key map "\C-e" 'widget-end-of-line)
 873     map)
 874   "Keymap used inside a text field.")
 875
 876 (defun widget-field-activate (pos &optional event)
 877   "Invoke the editable field at point."
 878   (interactive "@d")
 879   (let ((field (widget-field-at pos)))
 880     (if field
 881         (widget-apply-action field event)
 882       (call-interactively
 883        (lookup-key widget-global-map (this-command-keys))))))
 884
 885 (defface widget-button-pressed-face
 886   '((((class color))
 887      (:foreground "red"))
 888     (t
 889      (:weight bold :underline t)))
 890   "Face used for pressed buttons."
 891   :group 'widget-faces)
 892
 893 (defun widget-button-click (event)
 894   "Invoke the button that the mouse is pointing at."
 895   (interactive "e")
 896   (if (widget-event-point event)
 897       (let* ((pos (widget-event-point event))
 898              (start (event-start event))
 899              (button (get-char-property
 900                       pos 'button (and (windowp (posn-window start))
 901                                        (window-buffer (posn-window start))))))
 902         (if button
 903             ;; Mouse click on a widget button.  Do the following
 904             ;; in a save-excursion so that the click on the button
 905             ;; doesn't change point.
 906             (save-selected-window
 907               (select-window (posn-window (event-start event)))
 908               (save-excursion
 909                 (goto-char (posn-point (event-start event)))
 910                 (let* ((overlay (widget-get button :button-overlay))
 911                        (face (overlay-get overlay 'face))
 912                        (mouse-face (overlay-get overlay 'mouse-face)))
 913                   (unwind-protect
 914                       ;; Read events, including mouse-movement events
 915                       ;; until we receive a release event.  Highlight/
 916                       ;; unhighlight the button the mouse was initially
 917                       ;; on when we move over it.
 918                       (save-excursion
 919                         (when face      ; avoid changing around image
 920                           (overlay-put overlay
 921                                        'face widget-button-pressed-face)
 922                           (overlay-put overlay
 923                                        'mouse-face widget-button-pressed-face))
 924                         (unless (widget-apply button :mouse-down-action event)
 925                           (let ((track-mouse t))
 926                             (while (not (widget-button-release-event-p event))
 927                               (setq event (read-event)
 928                                     pos (widget-event-point event))
 929                               (if (and pos
 930                                        (eq (get-char-property pos 'button)
 931                                            button))
 932                                   (when face
 933                                     (overlay-put overlay
 934                                                  'face
 935                                                  widget-button-pressed-face)
 936                                     (overlay-put overlay
 937                                                  'mouse-face
 938                                                  widget-button-pressed-face))
 939                                 (overlay-put overlay 'face face)
 940                                 (overlay-put overlay 'mouse-face mouse-face)))))
 941
 942                         ;; When mouse is released over the button, run
 943                         ;; its action function.
 944                         (when (and pos
 945                                    (eq (get-char-property pos 'button) button))
 946                           (widget-apply-action button event)))
 947                     (overlay-put overlay 'face face)
 948                     (overlay-put overlay 'mouse-face mouse-face))))
 949
 950               (unless (pos-visible-in-window-p (widget-event-point event))
 951                 (mouse-set-point event)
 952                 (beginning-of-line)
 953                 (recenter))
 954               )
 955
 956             (let ((up t) command)
 957               ;; Mouse click not on a widget button.  Find the global
 958               ;; command to run, and check whether it is bound to an
 959               ;; up event.
 960               (mouse-set-point event)
 961               (if (memq (event-basic-type event) '(mouse-1 down-mouse-1))
 962                   (cond ((setq command  ;down event
 963                                (lookup-key widget-global-map [down-mouse-1]))
 964                          (setq up nil))
 965                         ((setq command  ;up event
 966                                (lookup-key widget-global-map [mouse-1]))))
 967                 (cond ((setq command    ;down event
 968                              (lookup-key widget-global-map [down-mouse-2]))
 969                        (setq up nil))
 970                       ((setq command    ;up event
 971                              (lookup-key widget-global-map [mouse-2])))))
 972               (when up
 973                 ;; Don't execute up events twice.
 974                 (while (not (widget-button-release-event-p event))
 975                   (setq event (read-event))))
 976               (when command
 977                 (call-interactively command)))))
 978     (message "You clicked somewhere weird.")))
 979
 980 (defun widget-button-press (pos &optional event)
 981   "Invoke button at POS."
 982   (interactive "@d")
 983   (let ((button (get-char-property pos 'button)))
 984     (if button
 985         (widget-apply-action button event)
 986       (let ((command (lookup-key widget-global-map (this-command-keys))))
 987         (when (commandp command)
 988           (call-interactively command))))))
 989
 990 (defun widget-tabable-at (&optional pos)
 991   "Return the tabable widget at POS, or nil.
 992 POS defaults to the value of (point)."
 993   (let ((widget (widget-at pos)))
 994     (if widget
 995         (let ((order (widget-get widget :tab-order)))
 996           (if order
 997               (if (>= order 0)
 998                   widget)
 999             widget)))))
1000
1001 (defvar widget-use-overlay-change t
1002   "If non-nil, use overlay change functions to tab around in the buffer.
1003 This is much faster, but doesn't work reliably on Emacs 19.34.")
1004
1005 (defun widget-move (arg)
1006   "Move point to the ARG next field or button.
1007 ARG may be negative to move backward."
1008   (or (bobp) (> arg 0) (backward-char))
1009   (let ((wrapped 0)
1010         (number arg)
1011         (old (widget-tabable-at)))
1012     ;; Forward.
1013     (while (> arg 0)
1014       (cond ((eobp)
1015              (goto-char (point-min))
1016              (setq wrapped (1+ wrapped)))
1017             (widget-use-overlay-change
1018              (goto-char (next-overlay-change (point))))
1019             (t
1020              (forward-char 1)))
1021       (and (= wrapped 2)
1022            (eq arg number)
1023            (error "No buttons or fields found"))
1024       (let ((new (widget-tabable-at)))
1025         (when new
1026           (unless (eq new old)
1027             (setq arg (1- arg))
1028             (setq old new)))))
1029     ;; Backward.
1030     (while (< arg 0)
1031       (cond ((bobp)
1032              (goto-char (point-max))
1033              (setq wrapped (1+ wrapped)))
1034             (widget-use-overlay-change
1035              (goto-char (previous-overlay-change (point))))
1036             (t
1037              (backward-char 1)))
1038       (and (= wrapped 2)
1039            (eq arg number)
1040            (error "No buttons or fields found"))
1041       (let ((new (widget-tabable-at)))
1042         (when new
1043           (unless (eq new old)
1044             (setq arg (1+ arg))))))
1045     (let ((new (widget-tabable-at)))
1046       (while (eq (widget-tabable-at) new)
1047         (backward-char)))
1048     (forward-char))
1049   (widget-echo-help (point))
1050   (run-hooks 'widget-move-hook))
1051
1052 (defun widget-forward (arg)
1053   "Move point to the next field or button.
1054 With optional ARG, move across that many fields."
1055   (interactive "p")
1056   (run-hooks 'widget-forward-hook)
1057   (widget-move arg))
1058
1059 (defun widget-backward (arg)
1060   "Move point to the previous field or button.
1061 With optional ARG, move across that many fields."
1062   (interactive "p")
1063   (run-hooks 'widget-backward-hook)
1064   (widget-move (- arg)))
1065
1066 ;; Since the widget code uses a `field' property to identify fields,
1067 ;; ordinary beginning-of-line does the right thing.
1068 (defalias 'widget-beginning-of-line 'beginning-of-line)
1069
1070 (defun widget-end-of-line ()
1071   "Go to end of field or end of line, whichever is first.
1072 Trailing spaces at the end of padded fields are not considered part of
1073 the field."
1074   (interactive)
1075   ;; Ordinary end-of-line does the right thing, because we're inside
1076   ;; text with a `field' property.
1077   (end-of-line)
1078   (unless (eolp)
1079     ;; ... except that we want to ignore trailing spaces in fields that
1080     ;; aren't terminated by a newline, because they are used as padding,
1081     ;; and ignored when extracting the entered value of the field.
1082     (skip-chars-backward " " (field-beginning (1- (point))))))
1083
1084 (defun widget-kill-line ()
1085   "Kill to end of field or end of line, whichever is first."
1086   (interactive)
1087   (let* ((field (widget-field-find (point)))
1088          (end (and field (widget-field-end field))))
1089     (if (and field (> (line-beginning-position 2) end))
1090         (kill-region (point) end)
1091       (call-interactively 'kill-line))))
1092
1093 (defcustom widget-complete-field (lookup-key global-map "\M-\t")
1094   "Default function to call for completion inside fields."
1095   :options '(ispell-complete-word complete-tag lisp-complete-symbol)
1096   :type 'function
1097   :group 'widgets)
1098
1099 (defun widget-narrow-to-field ()
1100   "Narrow to field"
1101   (interactive)
1102   (let ((field (widget-field-find (point))))
1103     (if field
1104         (narrow-to-region (line-beginning-position) (line-end-position)))))
1105
1106 (defun widget-complete ()
1107   "Complete content of editable field from point.
1108 When not inside a field, move to the previous button or field."
1109   (interactive)
1110   (let ((field (widget-field-find (point))))
1111     (if field
1112         (save-restriction
1113           (widget-narrow-to-field)
1114           (widget-apply field :complete))
1115           (error "Not in an editable field"))))
1116
1117 ;;; Setting up the buffer.
1118
1119 (defvar widget-field-new nil
1120   "List of all newly created editable fields in the buffer.")
1121 (make-variable-buffer-local 'widget-field-new)
1122
1123 (defvar widget-field-list nil
1124   "List of all editable fields in the buffer.")
1125 (make-variable-buffer-local 'widget-field-list)
1126
1127 (defun widget-at (&optional pos)
1128   "The button or field at POS (default, point)."
1129   (or (get-char-property (or pos (point)) 'button)
1130       (widget-field-at pos)))
1131
1132 ;;;###autoload
1133 (defun widget-setup ()
1134   "Setup current buffer so editing string widgets works."
1135   (let ((inhibit-read-only t)
1136         (inhibit-modification-hooks t)
1137         field)
1138     (while widget-field-new
1139       (setq field (car widget-field-new)
1140             widget-field-new (cdr widget-field-new)
1141             widget-field-list (cons field widget-field-list))
1142       (let ((from (car (widget-get field :field-overlay)))
1143             (to (cdr (widget-get field :field-overlay))))
1144         (widget-specify-field field
1145                               (marker-position from) (marker-position to))
1146         (set-marker from nil)
1147         (set-marker to nil))))
1148   (widget-clear-undo)
1149   (widget-add-change))
1150
1151 (defvar widget-field-last nil)
1152 ;; Last field containing point.
1153 (make-variable-buffer-local 'widget-field-last)
1154
1155 (defvar widget-field-was nil)
1156 ;; The widget data before the change.
1157 (make-variable-buffer-local 'widget-field-was)
1158
1159 (defun widget-field-at (pos)
1160   "Return the widget field at POS, or nil if none."
1161   (let ((field (get-char-property (or pos (point)) 'field)))
1162     (if (eq field 'boundary)
1163         (get-char-property (or pos (point)) 'real-field)
1164       field)))
1165
1166 (defun widget-field-buffer (widget)
1167   "Return the buffer of WIDGET's editing field."
1168   (let ((overlay (widget-get widget :field-overlay)))
1169     (cond ((overlayp overlay)
1170            (overlay-buffer overlay))
1171           ((consp overlay)
1172            (marker-buffer (car overlay))))))
1173
1174 (defun widget-field-start (widget)
1175   "Return the start of WIDGET's editing field."
1176   (let ((overlay (widget-get widget :field-overlay)))
1177     (if (overlayp overlay)
1178         (overlay-start overlay)
1179       (car overlay))))
1180
1181 (defun widget-field-end (widget)
1182   "Return the end of WIDGET's editing field."
1183   (let ((overlay (widget-get widget :field-overlay)))
1184     ;; Don't subtract one if local-map works at the end of the overlay,
1185     ;; or if a special `boundary' field has been added after the widget
1186     ;; field.
1187     (if (overlayp overlay)
1188         (if (and (not (eq (get-char-property (overlay-end overlay)
1189                                              'field
1190                                              (widget-field-buffer widget))
1191                           'boundary))
1192                  (or widget-field-add-space
1193                      (null (widget-get widget :size))))
1194             (1- (overlay-end overlay))
1195           (overlay-end overlay))
1196       (cdr overlay))))
1197
1198 (defun widget-field-find (pos)
1199   "Return the field at POS.
1200 Unlike (get-char-property POS 'field) this, works with empty fields too."
1201   (let ((fields widget-field-list)
1202         field found)
1203     (while fields
1204       (setq field (car fields)
1205             fields (cdr fields))
1206       (when (and (<= (widget-field-start field) pos)
1207                  (<= pos (widget-field-end field)))
1208         (when found
1209           (error "Overlapping fields"))
1210         (setq found field)))
1211     found))
1212
1213 (defun widget-before-change (from to)
1214   ;; This is how, for example, a variable changes its state to `modified'.
1215   ;; when it is being edited.
1216   (unless inhibit-read-only
1217     (let ((from-field (widget-field-find from))
1218           (to-field (widget-field-find to)))
1219       (cond ((not (eq from-field to-field))
1220              (add-hook 'post-command-hook 'widget-add-change nil t)
1221              (signal 'text-read-only
1222                      '("Change should be restricted to a single field")))
1223             ((null from-field)
1224              (add-hook 'post-command-hook 'widget-add-change nil t)
1225              (signal 'text-read-only
1226                      '("Attempt to change text outside editable field")))
1227             (widget-field-use-before-change
1228              (widget-apply from-field :notify from-field))))))
1229
1230 (defun widget-add-change ()
1231   (remove-hook 'post-command-hook 'widget-add-change t)
1232   (add-hook 'before-change-functions 'widget-before-change nil t)
1233   (add-hook 'after-change-functions 'widget-after-change nil t))
1234
1235 (defun widget-after-change (from to old)
1236   "Adjust field size and text properties."
1237   (let ((field (widget-field-find from))
1238         (other (widget-field-find to)))
1239     (when field
1240       (unless (eq field other)
1241         (error "Change in different fields"))
1242       (let ((size (widget-get field :size)))
1243         (when size
1244           (let ((begin (widget-field-start field))
1245                 (end (widget-field-end field)))
1246             (cond ((< (- end begin) size)
1247                    ;; Field too small.
1248                    (save-excursion
1249                      (goto-char end)
1250                      (insert-char ?\  (- (+ begin size) end))))
1251                   ((> (- end begin) size)
1252                    ;; Field too large and
1253                    (if (or (< (point) (+ begin size))
1254                            (> (point) end))
1255                        ;; Point is outside extra space.
1256                        (setq begin (+ begin size))
1257                      ;; Point is within the extra space.
1258                      (setq begin (point)))
1259                    (save-excursion
1260                      (goto-char end)
1261                      (while (and (eq (preceding-char) ?\ )
1262                                  (> (point) begin))
1263                        (delete-backward-char 1)))))))
1264         (widget-specify-secret field))
1265       (widget-apply field :notify field))))
1266
1267 ;;; Widget Functions
1268 ;;
1269 ;; These functions are used in the definition of multiple widgets.
1270
1271 (defun widget-parent-action (widget &optional event)
1272   "Tell :parent of WIDGET to handle the :action.
1273 Optional EVENT is the event that triggered the action."
1274   (widget-apply (widget-get widget :parent) :action event))
1275
1276 (defun widget-children-value-delete (widget)
1277   "Delete all :children and :buttons in WIDGET."
1278   (mapc 'widget-delete (widget-get widget :children))
1279   (widget-put widget :children nil)
1280   (mapc 'widget-delete (widget-get widget :buttons))
1281   (widget-put widget :buttons nil))
1282
1283 (defun widget-children-validate (widget)
1284   "All the :children must be valid."
1285   (let ((children (widget-get widget :children))
1286         child found)
1287     (while (and children (not found))
1288       (setq child (car children)
1289             children (cdr children)
1290             found (widget-apply child :validate)))
1291     found))
1292
1293 (defun widget-child-value-get (widget)
1294   "Get the value of the first member of :children in WIDGET."
1295   (widget-value (car (widget-get widget :children))))
1296
1297 (defun widget-child-value-inline (widget)
1298   "Get the inline value of the first member of :children in WIDGET."
1299   (widget-apply (car (widget-get widget :children)) :value-inline))
1300
1301 (defun widget-child-validate (widget)
1302   "The result of validating the first member of :children in WIDGET."
1303   (widget-apply (car (widget-get widget :children)) :validate))
1304
1305 (defun widget-type-value-create (widget)
1306   "Convert and instantiate the value of the :type attribute of WIDGET.
1307 Store the newly created widget in the :children attribute.
1308
1309 The value of the :type attribute should be an unconverted widget type."
1310   (let ((value (widget-get widget :value))
1311         (type (widget-get widget :type)))
1312     (widget-put widget :children
1313                 (list (widget-create-child-value widget
1314                                                  (widget-convert type)
1315                                                  value)))))
1316
1317 (defun widget-type-default-get (widget)
1318   "Get default value from the :type attribute of WIDGET.
1319
1320 The value of the :type attribute should be an unconverted widget type."
1321   (widget-default-get (widget-convert (widget-get widget :type))))
1322
1323 (defun widget-type-match (widget value)
1324   "Non-nil if the :type value of WIDGET matches VALUE.
1325
1326 The value of the :type attribute should be an unconverted widget type."
1327   (widget-apply (widget-convert (widget-get widget :type)) :match value))
1328
1329 (defun widget-types-copy (widget)
1330   "Copy :args as widget types in WIDGET."
1331   (widget-put widget :args (mapcar 'widget-copy (widget-get widget :args)))
1332   widget)
1333
1334 ;; Made defsubst to speed up face editor creation.
1335 (defsubst widget-types-convert-widget (widget)
1336   "Convert :args as widget types in WIDGET."
1337   (widget-put widget :args (mapcar 'widget-convert (widget-get widget :args)))
1338   widget)
1339
1340 (defun widget-value-convert-widget (widget)
1341   "Initialize :value from :args in WIDGET."
1342   (let ((args (widget-get widget :args)))
1343     (when args
1344       (widget-put widget :value (car args))
1345       ;; Don't convert :value here, as this is done in `widget-convert'.
1346       ;; (widget-put widget :value (widget-apply widget
1347       ;;                                      :value-to-internal (car args)))
1348       (widget-put widget :args nil)))
1349   widget)
1350
1351 (defun widget-value-value-get (widget)
1352   "Return the :value property of WIDGET."
1353   (widget-get widget :value))
1354
1355 ;;; The `default' Widget.
1356
1357 (define-widget 'default nil
1358   "Basic widget other widgets are derived from."
1359   :value-to-internal (lambda (widget value) value)
1360   :value-to-external (lambda (widget value) value)
1361   :button-prefix 'widget-button-prefix
1362   :button-suffix 'widget-button-suffix
1363   :complete 'widget-default-complete
1364   :create 'widget-default-create
1365   :indent nil
1366   :offset 0
1367   :format-handler 'widget-default-format-handler
1368   :button-face-get 'widget-default-button-face-get
1369   :sample-face-get 'widget-default-sample-face-get
1370   :delete 'widget-default-delete
1371   :copy 'identity
1372   :value-set 'widget-default-value-set
1373   :value-inline 'widget-default-value-inline
1374   :value-delete 'ignore
1375   :default-get 'widget-default-default-get
1376   :menu-tag-get 'widget-default-menu-tag-get
1377   :validate #'ignore
1378   :active 'widget-default-active
1379   :activate 'widget-specify-active
1380   :deactivate 'widget-default-deactivate
1381   :mouse-down-action #'ignore
1382   :action 'widget-default-action
1383   :notify 'widget-default-notify
1384   :prompt-value 'widget-default-prompt-value)
1385
1386 (defun widget-default-complete (widget)
1387   "Call the value of the :complete-function property of WIDGET.
1388 If that does not exists, call the value of `widget-complete-field'."
1389   (call-interactively (or (widget-get widget :complete-function)
1390                           widget-complete-field)))
1391
1392 (defun widget-default-create (widget)
1393   "Create WIDGET at point in the current buffer."
1394   (widget-specify-insert
1395    (let ((from (point))
1396          button-begin button-end
1397          sample-begin sample-end
1398          doc-begin doc-end
1399          value-pos)
1400      (insert (widget-get widget :format))
1401      (goto-char from)
1402      ;; Parse escapes in format.
1403      (while (re-search-forward "%\\(.\\)" nil t)
1404        (let ((escape (char-after (match-beginning 1))))
1405          (delete-backward-char 2)
1406          (cond ((eq escape ?%)
1407                 (insert ?%))
1408                ((eq escape ?\[)
1409                 (setq button-begin (point))
1410                 (insert (widget-get-indirect widget :button-prefix)))
1411                ((eq escape ?\])
1412                 (insert (widget-get-indirect widget :button-suffix))
1413                 (setq button-end (point)))
1414                ((eq escape ?\{)
1415                 (setq sample-begin (point)))
1416                ((eq escape ?\})
1417                 (setq sample-end (point)))
1418                ((eq escape ?n)
1419                 (when (widget-get widget :indent)
1420                   (insert ?\n)
1421                   (insert-char ?  (widget-get widget :indent))))
1422                ((eq escape ?t)
1423                 (let ((image (widget-get widget :tag-glyph))
1424                       (tag (widget-get widget :tag)))
1425                   (cond (image
1426                          (widget-image-insert widget (or tag "image") image))
1427                         (tag
1428                          (insert tag))
1429                         (t
1430                          (princ (widget-get widget :value)
1431                                 (current-buffer))))))
1432                ((eq escape ?d)
1433                 (let ((doc (widget-get widget :doc)))
1434                   (when doc
1435                     (setq doc-begin (point))
1436                     (insert doc)
1437                     (while (eq (preceding-char) ?\n)
1438                       (delete-backward-char 1))
1439                     (insert ?\n)
1440                     (setq doc-end (point)))))
1441                ((eq escape ?v)
1442                 (if (and button-begin (not button-end))
1443                     (widget-apply widget :value-create)
1444                   (setq value-pos (point))))
1445                (t
1446                 (widget-apply widget :format-handler escape)))))
1447      ;; Specify button, sample, and doc, and insert value.
1448      (and button-begin button-end
1449           (widget-specify-button widget button-begin button-end))
1450      (and sample-begin sample-end
1451           (widget-specify-sample widget sample-begin sample-end))
1452      (and doc-begin doc-end
1453           (widget-specify-doc widget doc-begin doc-end))
1454      (when value-pos
1455        (goto-char value-pos)
1456        (widget-apply widget :value-create)))
1457    (let ((from (point-min-marker))
1458          (to (point-max-marker)))
1459      (set-marker-insertion-type from t)
1460      (set-marker-insertion-type to nil)
1461      (widget-put widget :from from)
1462      (widget-put widget :to to)))
1463   (widget-clear-undo))
1464
1465 (defun widget-default-format-handler (widget escape)
1466   ;; We recognize the %h escape by default.
1467   (let* ((buttons (widget-get widget :buttons)))
1468     (cond ((eq escape ?h)
1469            (let* ((doc-property (widget-get widget :documentation-property))
1470                   (doc-try (cond ((widget-get widget :doc))
1471                                  ((functionp doc-property)
1472                                   (funcall doc-property
1473                                            (widget-get widget :value)))
1474                                  ((symbolp doc-property)
1475                                   (documentation-property
1476                                    (widget-get widget :value)
1477                                    doc-property))))
1478                   (doc-text (and (stringp doc-try)
1479                                  (> (length doc-try) 1)
1480                                  doc-try))
1481                   (doc-indent (widget-get widget :documentation-indent)))
1482              (when doc-text
1483                (and (eq (preceding-char) ?\n)
1484                     (widget-get widget :indent)
1485                     (insert-char ?  (widget-get widget :indent)))
1486                ;; The `*' in the beginning is redundant.
1487                (when (eq (aref doc-text  0) ?*)
1488                  (setq doc-text (substring doc-text 1)))
1489                ;; Get rid of trailing newlines.
1490                (when (string-match "\n+\\'" doc-text)
1491                  (setq doc-text (substring doc-text 0 (match-beginning 0))))
1492                (push (widget-create-child-and-convert
1493                       widget 'documentation-string
1494                       :indent (cond ((numberp doc-indent )
1495                                      doc-indent)
1496                                     ((null doc-indent)
1497                                      nil)
1498                                     (t 0))
1499                       doc-text)
1500                      buttons))))
1501           (t
1502            (error "Unknown escape `%c'" escape)))
1503     (widget-put widget :buttons buttons)))
1504
1505 (defun widget-default-button-face-get (widget)
1506   ;; Use :button-face or widget-button-face
1507   (or (widget-get widget :button-face)
1508       (let ((parent (widget-get widget :parent)))
1509         (if parent
1510             (widget-apply parent :button-face-get)
1511           widget-button-face))))
1512
1513 (defun widget-default-sample-face-get (widget)
1514   ;; Use :sample-face.
1515   (widget-get widget :sample-face))
1516
1517 (defun widget-default-delete (widget)
1518   "Remove widget from the buffer."
1519   (let ((from (widget-get widget :from))
1520         (to (widget-get widget :to))
1521         (inactive-overlay (widget-get widget :inactive))
1522         (button-overlay (widget-get widget :button-overlay))
1523         (sample-overlay (widget-get widget :sample-overlay))
1524         (doc-overlay (widget-get widget :doc-overlay))
1525         (inhibit-modification-hooks t)
1526         (inhibit-read-only t))
1527     (widget-apply widget :value-delete)
1528     (widget-children-value-delete widget)
1529     (when inactive-overlay
1530       (delete-overlay inactive-overlay))
1531     (when button-overlay
1532       (delete-overlay button-overlay))
1533     (when sample-overlay
1534       (delete-overlay sample-overlay))
1535     (when doc-overlay
1536       (delete-overlay doc-overlay))
1537     (when (< from to)
1538       ;; Kludge: this doesn't need to be true for empty formats.
1539       (delete-region from to))
1540     (set-marker from nil)
1541     (set-marker to nil))
1542   (widget-clear-undo))
1543
1544 (defun widget-default-value-set (widget value)
1545   "Recreate widget with new value."
1546   (let* ((old-pos (point))
1547          (from (copy-marker (widget-get widget :from)))
1548          (to (copy-marker (widget-get widget :to)))
1549          (offset (if (and (<= from old-pos) (<= old-pos to))
1550                      (if (>= old-pos (1- to))
1551                          (- old-pos to 1)
1552                        (- old-pos from)))))
1553     ;;??? Bug: this ought to insert the new value before deleting the old one,
1554     ;; so that markers on either side of the value automatically
1555     ;; stay on the same side.  -- rms.
1556     (save-excursion
1557       (goto-char (widget-get widget :from))
1558       (widget-apply widget :delete)
1559       (widget-put widget :value value)
1560       (widget-apply widget :create))
1561     (if offset
1562         (if (< offset 0)
1563             (goto-char (+ (widget-get widget :to) offset 1))
1564           (goto-char (min (+ from offset) (1- (widget-get widget :to))))))))
1565
1566 (defun widget-default-value-inline (widget)
1567   "Wrap value in a list unless it is inline."
1568   (if (widget-get widget :inline)
1569       (widget-value widget)
1570     (list (widget-value widget))))
1571
1572 (defun widget-default-default-get (widget)
1573   "Get `:value'."
1574   (widget-get widget :value))
1575
1576 (defun widget-default-menu-tag-get (widget)
1577   "Use tag or value for menus."
1578   (or (widget-get widget :menu-tag)
1579       (widget-get widget :tag)
1580       (widget-princ-to-string (widget-get widget :value))))
1581
1582 (defun widget-default-active (widget)
1583   "Return t iff this widget active (user modifiable)."
1584   (or (widget-get widget :always-active)
1585       (and (not (widget-get widget :inactive))
1586            (let ((parent (widget-get widget :parent)))
1587              (or (null parent)
1588                  (widget-apply parent :active))))))
1589
1590 (defun widget-default-deactivate (widget)
1591   "Make WIDGET inactive for user modifications."
1592   (widget-specify-inactive widget
1593                            (widget-get widget :from)
1594                            (widget-get widget :to)))
1595
1596 (defun widget-default-action (widget &optional event)
1597   "Notify the parent when a widget changes."
1598   (let ((parent (widget-get widget :parent)))
1599     (when parent
1600       (widget-apply parent :notify widget event))))
1601
1602 (defun widget-default-notify (widget child &optional event)
1603   "Pass notification to parent."
1604   (widget-default-action widget event))
1605
1606 (defun widget-default-prompt-value (widget prompt value unbound)
1607   "Read an arbitrary value.  Stolen from `set-variable'."
1608 ;; (let ((initial (if unbound
1609 ;; nil
1610 ;; It would be nice if we could do a `(cons val 1)' here.
1611 ;; (prin1-to-string (custom-quote value))))))
1612   (eval-minibuffer prompt))
1613
1614 ;;; The `item' Widget.
1615
1616 (define-widget 'item 'default
1617   "Constant items for inclusion in other widgets."
1618   :convert-widget 'widget-value-convert-widget
1619   :value-create 'widget-item-value-create
1620   :value-delete 'ignore
1621   :value-get 'widget-value-value-get
1622   :match 'widget-item-match
1623   :match-inline 'widget-item-match-inline
1624   :action 'widget-item-action
1625   :format "%t\n")
1626
1627 (defun widget-item-value-create (widget)
1628   "Insert the printed representation of the value."
1629   (princ (widget-get widget :value) (current-buffer)))
1630
1631 (defun widget-item-match (widget value)
1632   ;; Match if the value is the same.
1633   (equal (widget-get widget :value) value))
1634
1635 (defun widget-item-match-inline (widget values)
1636   ;; Match if the value is the same.
1637   (let ((value (widget-get widget :value)))
1638     (and (listp value)
1639          (<= (length value) (length values))
1640          (let ((head (widget-sublist values 0 (length value))))
1641            (and (equal head value)
1642                 (cons head (widget-sublist values (length value))))))))
1643
1644 (defun widget-sublist (list start &optional end)
1645   "Return the sublist of LIST from START to END.
1646 If END is omitted, it defaults to the length of LIST."
1647   (if (> start 0) (setq list (nthcdr start list)))
1648   (if end
1649       (unless (<= end start)
1650         (setq list (copy-sequence list))
1651         (setcdr (nthcdr (- end start 1) list) nil)
1652         list)
1653     (copy-sequence list)))
1654
1655 (defun widget-item-action (widget &optional event)
1656   ;; Just notify itself.
1657   (widget-apply widget :notify widget event))
1658
1659 ;;; The `push-button' Widget.
1660
1661 ;; (defcustom widget-push-button-gui t
1662 ;;   "If non nil, use GUI push buttons when available."
1663 ;;   :group 'widgets
1664 ;;   :type 'boolean)
1665
1666 ;; Cache already created GUI objects.
1667 ;; (defvar widget-push-button-cache nil)
1668
1669 (defcustom widget-push-button-prefix "["
1670   "String used as prefix for buttons."
1671   :type 'string
1672   :group 'widget-button)
1673
1674 (defcustom widget-push-button-suffix "]"
1675   "String used as suffix for buttons."
1676   :type 'string
1677   :group 'widget-button)
1678
1679 (define-widget 'push-button 'item
1680   "A pushable button."
1681   :button-prefix ""
1682   :button-suffix ""
1683   :value-create 'widget-push-button-value-create
1684   :format "%[%v%]")
1685
1686 (defun widget-push-button-value-create (widget)
1687   "Insert text representing the `on' and `off' states."
1688   (let* ((tag (or (widget-get widget :tag)
1689                   (widget-get widget :value)))
1690          (tag-glyph (widget-get widget :tag-glyph))
1691          (text (concat widget-push-button-prefix
1692                        tag widget-push-button-suffix)))
1693     (if tag-glyph
1694         (widget-image-insert widget text tag-glyph)
1695       (insert text))))
1696
1697 ;; (defun widget-gui-action (widget)
1698 ;;   "Apply :action for WIDGET."
1699 ;;   (widget-apply-action widget (this-command-keys)))
1700
1701 ;;; The `link' Widget.
1702
1703 (defcustom widget-link-prefix "["
1704   "String used as prefix for links."
1705   :type 'string
1706   :group 'widget-button)
1707
1708 (defcustom widget-link-suffix "]"
1709   "String used as suffix for links."
1710   :type 'string
1711   :group 'widget-button)
1712
1713 (define-widget 'link 'item
1714   "An embedded link."
1715   :button-prefix 'widget-link-prefix
1716   :button-suffix 'widget-link-suffix
1717   :follow-link "\C-m"
1718   :help-echo "Follow the link."
1719   :format "%[%t%]")
1720
1721 ;;; The `info-link' Widget.
1722
1723 (define-widget 'info-link 'link
1724   "A link to an info file."
1725   :action 'widget-info-link-action)
1726
1727 (defun widget-info-link-action (widget &optional event)
1728   "Open the info node specified by WIDGET."
1729   (info (widget-value widget)))
1730
1731 ;;; The `url-link' Widget.
1732
1733 (define-widget 'url-link 'link
1734   "A link to an www page."
1735   :action 'widget-url-link-action)
1736
1737 (defun widget-url-link-action (widget &optional event)
1738   "Open the url specified by WIDGET."
1739   (browse-url (widget-value widget)))
1740
1741 ;;; The `function-link' Widget.
1742
1743 (define-widget 'function-link 'link
1744   "A link to an Emacs function."
1745   :action 'widget-function-link-action)
1746
1747 (defun widget-function-link-action (widget &optional event)
1748   "Show the function specified by WIDGET."
1749   (describe-function (widget-value widget)))
1750
1751 ;;; The `variable-link' Widget.
1752
1753 (define-widget 'variable-link 'link
1754   "A link to an Emacs variable."
1755   :action 'widget-variable-link-action)
1756
1757 (defun widget-variable-link-action (widget &optional event)
1758   "Show the variable specified by WIDGET."
1759   (describe-variable (widget-value widget)))
1760
1761 ;;; The `file-link' Widget.
1762
1763 (define-widget 'file-link 'link
1764   "A link to a file."
1765   :action 'widget-file-link-action)
1766
1767 (defun widget-file-link-action (widget &optional event)
1768   "Find the file specified by WIDGET."
1769   (find-file (widget-value widget)))
1770
1771 ;;; The `emacs-library-link' Widget.
1772
1773 (define-widget 'emacs-library-link 'link
1774   "A link to an Emacs Lisp library file."
1775   :action 'widget-emacs-library-link-action)
1776
1777 (defun widget-emacs-library-link-action (widget &optional event)
1778   "Find the Emacs Library file specified by WIDGET."
1779   (find-file (locate-library (widget-value widget))))
1780
1781 ;;; The `emacs-commentary-link' Widget.
1782
1783 (define-widget 'emacs-commentary-link 'link
1784   "A link to Commentary in an Emacs Lisp library file."
1785   :action 'widget-emacs-commentary-link-action)
1786
1787 (defun widget-emacs-commentary-link-action (widget &optional event)
1788   "Find the Commentary section of the Emacs file specified by WIDGET."
1789   (finder-commentary (widget-value widget)))
1790
1791 ;;; The `editable-field' Widget.
1792
1793 (define-widget 'editable-field 'default
1794   "An editable text field."
1795   :convert-widget 'widget-value-convert-widget
1796   :keymap widget-field-keymap
1797   :format "%v"
1798   :help-echo "M-TAB: complete field; RET: enter value"
1799   :value ""
1800   :prompt-internal 'widget-field-prompt-internal
1801   :prompt-history 'widget-field-history
1802   :prompt-value 'widget-field-prompt-value
1803   :action 'widget-field-action
1804   :validate 'widget-field-validate
1805   :valid-regexp ""
1806   :error "Field's value doesn't match allowed forms"
1807   :value-create 'widget-field-value-create
1808   :value-delete 'widget-field-value-delete
1809   :value-get 'widget-field-value-get
1810   :match 'widget-field-match)
1811
1812 (defvar widget-field-history nil
1813   "History of field minibuffer edits.")
1814
1815 (defun widget-field-prompt-internal (widget prompt initial history)
1816   "Read string for WIDGET promptinhg with PROMPT.
1817 INITIAL is the initial input and HISTORY is a symbol containing
1818 the earlier input."
1819   (read-string prompt initial history))
1820
1821 (defun widget-field-prompt-value (widget prompt value unbound)
1822   "Prompt for a string."
1823   (widget-apply widget
1824                 :value-to-external
1825                 (widget-apply widget
1826                               :prompt-internal prompt
1827                               (unless unbound
1828                                 (cons (widget-apply widget
1829                                                     :value-to-internal value)
1830                                       0))
1831                               (widget-get widget :prompt-history))))
1832
1833 (defvar widget-edit-functions nil)
1834
1835 (defun widget-field-action (widget &optional event)
1836   "Move to next field."
1837   (widget-forward 1)
1838   (run-hook-with-args 'widget-edit-functions widget))
1839
1840 (defun widget-field-validate (widget)
1841   "Valid if the content matches `:valid-regexp'."
1842   (unless (string-match (widget-get widget :valid-regexp)
1843                         (widget-apply widget :value-get))
1844     widget))
1845
1846 (defun widget-field-value-create (widget)
1847   "Create an editable text field."
1848   (let ((size (widget-get widget :size))
1849         (value (widget-get widget :value))
1850         (from (point))
1851         ;; This is changed to a real overlay in `widget-setup'.  We
1852         ;; need the end points to behave differently until
1853         ;; `widget-setup' is called.
1854         (overlay (cons (make-marker) (make-marker))))
1855     (widget-put widget :field-overlay overlay)
1856     (insert value)
1857     (and size
1858          (< (length value) size)
1859          (insert-char ?\  (- size (length value))))
1860     (unless (memq widget widget-field-list)
1861       (setq widget-field-new (cons widget widget-field-new)))
1862     (move-marker (cdr overlay) (point))
1863     (set-marker-insertion-type (cdr overlay) nil)
1864     (when (null size)
1865       (insert ?\n))
1866     (move-marker (car overlay) from)
1867     (set-marker-insertion-type (car overlay) t)))
1868
1869 (defun widget-field-value-delete (widget)
1870   "Remove the widget from the list of active editing fields."
1871   (setq widget-field-list (delq widget widget-field-list))
1872   (setq widget-field-new (delq widget widget-field-new))
1873   ;; These are nil if the :format string doesn't contain `%v'.
1874   (let ((overlay (widget-get widget :field-overlay)))
1875     (when (overlayp overlay)
1876       (delete-overlay overlay))))
1877
1878 (defun widget-field-value-get (widget)
1879   "Return current text in editing field."
1880   (let ((from (widget-field-start widget))
1881         (to (widget-field-end widget))
1882         (buffer (widget-field-buffer widget))
1883         (size (widget-get widget :size))
1884         (secret (widget-get widget :secret))
1885         (old (current-buffer)))
1886     (if (and from to)
1887         (progn
1888           (set-buffer buffer)
1889           (while (and size
1890                       (not (zerop size))
1891                       (> to from)
1892                       (eq (char-after (1- to)) ?\ ))
1893             (setq to (1- to)))
1894           (let ((result (buffer-substring-no-properties from to)))
1895             (when secret
1896               (let ((index 0))
1897                 (while (< (+ from index) to)
1898                   (aset result index
1899                         (get-char-property (+ from index) 'secret))
1900                   (setq index (1+ index)))))
1901             (set-buffer old)
1902             result))
1903       (widget-get widget :value))))
1904
1905 (defun widget-field-match (widget value)
1906   ;; Match any string.
1907   (stringp value))
1908
1909 ;;; The `text' Widget.
1910
1911 (define-widget 'text 'editable-field
1912   "A multiline text area."
1913   :keymap widget-text-keymap)
1914
1915 ;;; The `menu-choice' Widget.
1916
1917 (define-widget 'menu-choice 'default
1918   "A menu of options."
1919   :convert-widget  'widget-types-convert-widget
1920   :copy 'widget-types-copy
1921   :format "%[%t%]: %v"
1922   :case-fold t
1923   :tag "choice"
1924   :void '(item :format "invalid (%t)\n")
1925   :value-create 'widget-choice-value-create
1926   :value-get 'widget-child-value-get
1927   :value-inline 'widget-child-value-inline
1928   :default-get 'widget-choice-default-get
1929   :mouse-down-action 'widget-choice-mouse-down-action
1930   :action 'widget-choice-action
1931   :error "Make a choice"
1932   :validate 'widget-choice-validate
1933   :match 'widget-choice-match
1934   :match-inline 'widget-choice-match-inline)
1935
1936 (defun widget-choice-value-create (widget)
1937   "Insert the first choice that matches the value."
1938   (let ((value (widget-get widget :value))
1939         (args (widget-get widget :args))
1940         (explicit (widget-get widget :explicit-choice))
1941         current)
1942     (if (and explicit (equal value (widget-get widget :explicit-choice-value)))
1943         (progn
1944           ;; If the user specified the choice for this value,
1945           ;; respect that choice as long as the value is the same.
1946           (widget-put widget :children (list (widget-create-child-value
1947                                               widget explicit value)))
1948           (widget-put widget :choice explicit))
1949       (while args
1950         (setq current (car args)
1951               args (cdr args))
1952         (when (widget-apply current :match value)
1953           (widget-put widget :children (list (widget-create-child-value
1954                                               widget current value)))
1955           (widget-put widget :choice current)
1956           (setq args nil
1957                 current nil)))
1958       (when current
1959         (let ((void (widget-get widget :void)))
1960           (widget-put widget :children (list (widget-create-child-and-convert
1961                                               widget void :value value)))
1962           (widget-put widget :choice void))))))
1963
1964 (defun widget-choice-default-get (widget)
1965   ;; Get default for the first choice.
1966   (widget-default-get (car (widget-get widget :args))))
1967
1968 (defcustom widget-choice-toggle nil
1969   "If non-nil, a binary choice will just toggle between the values.
1970 Otherwise, the user will explicitly have to choose between the values
1971 when he invoked the menu."
1972   :type 'boolean
1973   :group 'widgets)
1974
1975 (defun widget-choice-mouse-down-action (widget &optional event)
1976   ;; Return non-nil if we need a menu.
1977   (let ((args (widget-get widget :args))
1978         (old (widget-get widget :choice)))
1979     (cond ((not (display-popup-menus-p))
1980            ;; No place to pop up a menu.
1981            nil)
1982           ((< (length args) 2)
1983            ;; Empty or singleton list, just return the value.
1984            nil)
1985           ((> (length args) widget-menu-max-size)
1986            ;; Too long, prompt.
1987            nil)
1988           ((> (length args) 2)
1989            ;; Reasonable sized list, use menu.
1990            t)
1991           ((and widget-choice-toggle (memq old args))
1992            ;; We toggle.
1993            nil)
1994           (t
1995            ;; Ask which of the two.
1996            t))))
1997
1998 (defun widget-choice-action (widget &optional event)
1999   ;; Make a choice.
2000   (let ((args (widget-get widget :args))
2001         (old (widget-get widget :choice))
2002         (tag (widget-apply widget :menu-tag-get))
2003         (completion-ignore-case (widget-get widget :case-fold))
2004         this-explicit
2005         current choices)
2006     ;; Remember old value.
2007     (if (and old (not (widget-apply widget :validate)))
2008         (let* ((external (widget-value widget))
2009                (internal (widget-apply old :value-to-internal external)))
2010           (widget-put old :value internal)))
2011     ;; Find new choice.
2012     (setq current
2013           (cond ((= (length args) 0)
2014                  nil)
2015                 ((= (length args) 1)
2016                  (nth 0 args))
2017                 ((and widget-choice-toggle
2018                       (= (length args) 2)
2019                       (memq old args))
2020                  (if (eq old (nth 0 args))
2021                      (nth 1 args)
2022                    (nth 0 args)))
2023                 (t
2024                  (while args
2025                    (setq current (car args)
2026                          args (cdr args))
2027                    (setq choices
2028                          (cons (cons (widget-apply current :menu-tag-get)
2029                                      current)
2030                                choices)))
2031                  (setq this-explicit t)
2032                  (widget-choose tag (reverse choices) event))))
2033     (when current
2034       ;; If this was an explicit user choice,
2035       ;; record the choice, and the record the value it was made for.
2036       ;; widget-choice-value-create will respect this choice,
2037       ;; as long as the value is the same.
2038       (when this-explicit
2039         (widget-put widget :explicit-choice current)
2040         (widget-put widget :explicit-choice-value (widget-get widget :value)))
2041       (widget-value-set widget (widget-default-get current))
2042       (widget-setup)
2043       (widget-apply widget :notify widget event)))
2044   (run-hook-with-args 'widget-edit-functions widget))
2045
2046 (defun widget-choice-validate (widget)
2047   ;; Valid if we have made a valid choice.
2048   (if (eq (widget-get widget :void) (widget-get widget :choice))
2049       widget
2050     (widget-apply (car (widget-get widget :children)) :validate)))
2051
2052 (defun widget-choice-match (widget value)
2053   ;; Matches if one of the choices matches.
2054   (let ((args (widget-get widget :args))
2055         current found)
2056     (while (and args (not found))
2057       (setq current (car args)
2058             args (cdr args)
2059             found (widget-apply current :match value)))
2060     found))
2061
2062 (defun widget-choice-match-inline (widget values)
2063   ;; Matches if one of the choices matches.
2064   (let ((args (widget-get widget :args))
2065         current found)
2066     (while (and args (null found))
2067       (setq current (car args)
2068             args (cdr args)
2069             found (widget-match-inline current values)))
2070     found))
2071
2072 ;;; The `toggle' Widget.
2073
2074 (define-widget 'toggle 'item
2075   "Toggle between two states."
2076   :format "%[%v%]\n"
2077   :value-create 'widget-toggle-value-create
2078   :action 'widget-toggle-action
2079   :match (lambda (widget value) t)
2080   :on "on"
2081   :off "off")
2082
2083 (defun widget-toggle-value-create (widget)
2084   "Insert text representing the `on' and `off' states."
2085   (if (widget-value widget)
2086       (let ((image (widget-get widget :on-glyph)))
2087         (and (display-graphic-p)
2088              (listp image)
2089              (not (eq (car image) 'image))
2090              (widget-put widget :on-glyph (setq image (eval image))))
2091         (widget-image-insert widget
2092                              (widget-get widget :on)
2093                              image))
2094     (let ((image (widget-get widget :off-glyph)))
2095       (and (display-graphic-p)
2096            (listp image)
2097            (not (eq (car image) 'image))
2098            (widget-put widget :off-glyph (setq image (eval image))))
2099       (widget-image-insert widget (widget-get widget :off) image))))
2100
2101 (defun widget-toggle-action (widget &optional event)
2102   ;; Toggle value.
2103   (widget-value-set widget (not (widget-value widget)))
2104   (widget-apply widget :notify widget event)
2105   (run-hook-with-args 'widget-edit-functions widget))
2106
2107 ;;; The `checkbox' Widget.
2108
2109 (define-widget 'checkbox 'toggle
2110   "A checkbox toggle."
2111   :button-suffix ""
2112   :button-prefix ""
2113   :format "%[%v%]"
2114   :on "[X]"
2115   ;; We could probably do the same job as the images using single
2116   ;; space characters in a boxed face with a stretch specification to
2117   ;; make them square.
2118   :on-glyph '(create-image "\300\300\141\143\067\076\034\030"
2119                            'xbm t :width 8 :height 8
2120                            :background "grey75" ; like default mode line
2121                            :foreground "black"
2122                            :relief -2
2123                            :ascent 'center)
2124   :off "[ ]"
2125   :off-glyph '(create-image (make-string 8 0)
2126                             'xbm t :width 8 :height 8
2127                             :background "grey75"
2128                             :foreground "black"
2129                             :relief -2
2130                             :ascent 'center)
2131   :help-echo "Toggle this item."
2132   :action 'widget-checkbox-action)
2133
2134 (defun widget-checkbox-action (widget &optional event)
2135   "Toggle checkbox, notify parent, and set active state of sibling."
2136   (widget-toggle-action widget event)
2137   (let ((sibling (widget-get-sibling widget)))
2138     (when sibling
2139       (if (widget-value widget)
2140           (widget-apply sibling :activate)
2141         (widget-apply sibling :deactivate)))))
2142
2143 ;;; The `checklist' Widget.
2144
2145 (define-widget 'checklist 'default
2146   "A multiple choice widget."
2147   :convert-widget 'widget-types-convert-widget
2148   :copy 'widget-types-copy
2149   :format "%v"
2150   :offset 4
2151   :entry-format "%b %v"
2152   :greedy nil
2153   :value-create 'widget-checklist-value-create
2154   :value-get 'widget-checklist-value-get
2155   :validate 'widget-checklist-validate
2156   :match 'widget-checklist-match
2157   :match-inline 'widget-checklist-match-inline)
2158
2159 (defun widget-checklist-value-create (widget)
2160   ;; Insert all values
2161   (let ((alist (widget-checklist-match-find widget (widget-get widget :value)))
2162         (args (widget-get widget :args)))
2163     (while args
2164       (widget-checklist-add-item widget (car args) (assq (car args) alist))
2165       (setq args (cdr args)))
2166     (widget-put widget :children (nreverse (widget-get widget :children)))))
2167
2168 (defun widget-checklist-add-item (widget type chosen)
2169   "Create checklist item in WIDGET of type TYPE.
2170 If the item is checked, CHOSEN is a cons whose cdr is the value."
2171   (and (eq (preceding-char) ?\n)
2172        (widget-get widget :indent)
2173        (insert-char ?  (widget-get widget :indent)))
2174   (widget-specify-insert
2175    (let* ((children (widget-get widget :children))
2176           (buttons (widget-get widget :buttons))
2177           (button-args (or (widget-get type :sibling-args)
2178                            (widget-get widget :button-args)))
2179           (from (point))
2180           child button)
2181      (insert (widget-get widget :entry-format))
2182      (goto-char from)
2183      ;; Parse % escapes in format.
2184      (while (re-search-forward "%\\([bv%]\\)" nil t)
2185        (let ((escape (char-after (match-beginning 1))))
2186          (delete-backward-char 2)
2187          (cond ((eq escape ?%)
2188                 (insert ?%))
2189                ((eq escape ?b)
2190                 (setq button (apply 'widget-create-child-and-convert
2191                                     widget 'checkbox
2192                                     :value (not (null chosen))
2193                                     button-args)))
2194                ((eq escape ?v)
2195                 (setq child
2196                       (cond ((not chosen)
2197                              (let ((child (widget-create-child widget type)))
2198                                (widget-apply child :deactivate)
2199                                child))
2200                             ((widget-get type :inline)
2201                              (widget-create-child-value
2202                               widget type (cdr chosen)))
2203                             (t
2204                              (widget-create-child-value
2205                               widget type (car (cdr chosen)))))))
2206                (t
2207                 (error "Unknown escape `%c'" escape)))))
2208      ;; Update properties.
2209      (and button child (widget-put child :button button))
2210      (and button (widget-put widget :buttons (cons button buttons)))
2211      (and child (widget-put widget :children (cons child children))))))
2212
2213 (defun widget-checklist-match (widget values)
2214   ;; All values must match a type in the checklist.
2215   (and (listp values)
2216        (null (cdr (widget-checklist-match-inline widget values)))))
2217
2218 (defun widget-checklist-match-inline (widget values)
2219   ;; Find the values which match a type in the checklist.
2220   (let ((greedy (widget-get widget :greedy))
2221         (args (copy-sequence (widget-get widget :args)))
2222         found rest)
2223     (while values
2224       (let ((answer (widget-checklist-match-up args values)))
2225         (cond (answer
2226                (let ((vals (widget-match-inline answer values)))
2227                  (setq found (append found (car vals))
2228                        values (cdr vals)
2229                        args (delq answer args))))
2230               (greedy
2231                (setq rest (append rest (list (car values)))
2232                      values (cdr values)))
2233               (t
2234                (setq rest (append rest values)
2235                      values nil)))))
2236     (cons found rest)))
2237
2238 (defun widget-checklist-match-find (widget vals)
2239   "Find the vals which match a type in the checklist.
2240 Return an alist of (TYPE MATCH)."
2241   (let ((greedy (widget-get widget :greedy))
2242         (args (copy-sequence (widget-get widget :args)))
2243         found)
2244     (while vals
2245       (let ((answer (widget-checklist-match-up args vals)))
2246         (cond (answer
2247                (let ((match (widget-match-inline answer vals)))
2248                  (setq found (cons (cons answer (car match)) found)
2249                        vals (cdr match)
2250                        args (delq answer args))))
2251               (greedy
2252                (setq vals (cdr vals)))
2253               (t
2254                (setq vals nil)))))
2255     found))
2256
2257 (defun widget-checklist-match-up (args vals)
2258   "Return the first type from ARGS that matches VALS."
2259   (let (current found)
2260     (while (and args (null found))
2261       (setq current (car args)
2262             args (cdr args)
2263             found (widget-match-inline current vals)))
2264     (if found
2265         current)))
2266
2267 (defun widget-checklist-value-get (widget)
2268   ;; The values of all selected items.
2269   (let ((children (widget-get widget :children))
2270         child result)
2271     (while children
2272       (setq child (car children)
2273             children (cdr children))
2274       (if (widget-value (widget-get child :button))
2275           (setq result (append result (widget-apply child :value-inline)))))
2276     result))
2277
2278 (defun widget-checklist-validate (widget)
2279   ;; Ticked chilren must be valid.
2280   (let ((children (widget-get widget :children))
2281         child button found)
2282     (while (and children (not found))
2283       (setq child (car children)
2284             children (cdr children)
2285             button (widget-get child :button)
2286             found (and (widget-value button)
2287                        (widget-apply child :validate))))
2288     found))
2289
2290 ;;; The `option' Widget
2291
2292 (define-widget 'option 'checklist
2293   "An widget with an optional item."
2294   :inline t)
2295
2296 ;;; The `choice-item' Widget.
2297
2298 (define-widget 'choice-item 'item
2299   "Button items that delegate action events to their parents."
2300   :action 'widget-parent-action
2301   :format "%[%t%] \n")
2302
2303 ;;; The `radio-button' Widget.
2304
2305 (define-widget 'radio-button 'toggle
2306   "A radio button for use in the `radio' widget."
2307   :notify 'widget-radio-button-notify
2308   :format "%[%v%]"
2309   :button-suffix ""
2310   :button-prefix ""
2311   :on "(*)"
2312   :on-glyph "radio1"
2313   :off "( )"
2314   :off-glyph "radio0")
2315
2316 (defun widget-radio-button-notify (widget child &optional event)
2317   ;; Tell daddy.
2318   (widget-apply (widget-get widget :parent) :action widget event))
2319
2320 ;;; The `radio-button-choice' Widget.
2321
2322 (define-widget 'radio-button-choice 'default
2323   "Select one of multiple options."
2324   :convert-widget 'widget-types-convert-widget
2325   :copy 'widget-types-copy
2326   :offset 4
2327   :format "%v"
2328   :entry-format "%b %v"
2329   :value-create 'widget-radio-value-create
2330   :value-get 'widget-radio-value-get
2331   :value-inline 'widget-radio-value-inline
2332   :value-set 'widget-radio-value-set
2333   :error "You must push one of the buttons"
2334   :validate 'widget-radio-validate
2335   :match 'widget-choice-match
2336   :match-inline 'widget-choice-match-inline
2337   :action 'widget-radio-action)
2338
2339 (defun widget-radio-value-create (widget)
2340   ;; Insert all values
2341   (let ((args (widget-get widget :args))
2342         arg)
2343     (while args
2344       (setq arg (car args)
2345             args (cdr args))
2346       (widget-radio-add-item widget arg))))
2347
2348 (defun widget-radio-add-item (widget type)
2349   "Add to radio widget WIDGET a new radio button item of type TYPE."
2350   ;; (setq type (widget-convert type))
2351   (and (eq (preceding-char) ?\n)
2352        (widget-get widget :indent)
2353        (insert-char ?  (widget-get widget :indent)))
2354   (widget-specify-insert
2355    (let* ((value (widget-get widget :value))
2356           (children (widget-get widget :children))
2357           (buttons (widget-get widget :buttons))
2358           (button-args (or (widget-get type :sibling-args)
2359                            (widget-get widget :button-args)))
2360           (from (point))
2361           (chosen (and (null (widget-get widget :choice))
2362                        (widget-apply type :match value)))
2363           child button)
2364      (insert (widget-get widget :entry-format))
2365      (goto-char from)
2366      ;; Parse % escapes in format.
2367      (while (re-search-forward "%\\([bv%]\\)" nil t)
2368        (let ((escape (char-after (match-beginning 1))))
2369          (delete-backward-char 2)
2370          (cond ((eq escape ?%)
2371                 (insert ?%))
2372                ((eq escape ?b)
2373                 (setq button (apply 'widget-create-child-and-convert
2374                                     widget 'radio-button
2375                                     :value (not (null chosen))
2376                                     button-args)))
2377                ((eq escape ?v)
2378                 (setq child (if chosen
2379                                 (widget-create-child-value
2380                                  widget type value)
2381                               (widget-create-child widget type)))
2382                 (unless chosen
2383                   (widget-apply child :deactivate)))
2384                (t
2385                 (error "Unknown escape `%c'" escape)))))
2386      ;; Update properties.
2387      (when chosen
2388        (widget-put widget :choice type))
2389      (when button
2390        (widget-put child :button button)
2391        (widget-put widget :buttons (nconc buttons (list button))))
2392      (when child
2393        (widget-put widget :children (nconc children (list child))))
2394      child)))
2395
2396 (defun widget-radio-value-get (widget)
2397   ;; Get value of the child widget.
2398   (let ((chosen (widget-radio-chosen widget)))
2399     (and chosen (widget-value chosen))))
2400
2401 (defun widget-radio-chosen (widget)
2402   "Return the widget representing the chosen radio button."
2403   (let ((children (widget-get widget :children))
2404         current found)
2405     (while children
2406       (setq current (car children)
2407             children (cdr children))
2408       (when (widget-apply (widget-get current :button) :value-get)
2409         (setq found current
2410               children nil)))
2411     found))
2412
2413 (defun widget-radio-value-inline (widget)
2414   ;; Get value of the child widget.
2415   (let ((children (widget-get widget :children))
2416         current found)
2417     (while children
2418       (setq current (car children)
2419             children (cdr children))
2420       (when (widget-apply (widget-get current :button) :value-get)
2421         (setq found (widget-apply current :value-inline)
2422               children nil)))
2423     found))
2424
2425 (defun widget-radio-value-set (widget value)
2426   ;; We can't just delete and recreate a radio widget, since children
2427   ;; can be added after the original creation and won't be recreated
2428   ;; by `:create'.
2429   (let ((children (widget-get widget :children))
2430         current found)
2431     (while children
2432       (setq current (car children)
2433             children (cdr children))
2434       (let* ((button (widget-get current :button))
2435              (match (and (not found)
2436                          (widget-apply current :match value))))
2437         (widget-value-set button match)
2438         (if match
2439             (progn
2440               (widget-value-set current value)
2441               (widget-apply current :activate))
2442           (widget-apply current :deactivate))
2443         (setq found (or found match))))))
2444
2445 (defun widget-radio-validate (widget)
2446   ;; Valid if we have made a valid choice.
2447   (let ((children (widget-get widget :children))
2448         current found button)
2449     (while (and children (not found))
2450       (setq current (car children)
2451             children (cdr children)
2452             button (widget-get current :button)
2453             found (widget-apply button :value-get)))
2454     (if found
2455         (widget-apply current :validate)
2456       widget)))
2457
2458 (defun widget-radio-action (widget child event)
2459   ;; Check if a radio button was pressed.
2460   (let ((children (widget-get widget :children))
2461         (buttons (widget-get widget :buttons))
2462         current)
2463     (when (memq child buttons)
2464       (while children
2465         (setq current (car children)
2466               children (cdr children))
2467         (let* ((button (widget-get current :button)))
2468           (cond ((eq child button)
2469                  (widget-value-set button t)
2470                  (widget-apply current :activate))
2471                 ((widget-value button)
2472                  (widget-value-set button nil)
2473                  (widget-apply current :deactivate)))))))
2474   ;; Pass notification to parent.
2475   (widget-apply widget :notify child event))
2476
2477 ;;; The `insert-button' Widget.
2478
2479 (define-widget 'insert-button 'push-button
2480   "An insert button for the `editable-list' widget."
2481   :tag "INS"
2482   :help-echo "Insert a new item into the list at this position."
2483   :action 'widget-insert-button-action)
2484
2485 (defun widget-insert-button-action (widget &optional event)
2486   ;; Ask the parent to insert a new item.
2487   (widget-apply (widget-get widget :parent)
2488                 :insert-before (widget-get widget :widget)))
2489
2490 ;;; The `delete-button' Widget.
2491
2492 (define-widget 'delete-button 'push-button
2493   "A delete button for the `editable-list' widget."
2494   :tag "DEL"
2495   :help-echo "Delete this item from the list."
2496   :action 'widget-delete-button-action)
2497
2498 (defun widget-delete-button-action (widget &optional event)
2499   ;; Ask the parent to insert a new item.
2500   (widget-apply (widget-get widget :parent)
2501                 :delete-at (widget-get widget :widget)))
2502
2503 ;;; The `editable-list' Widget.
2504
2505 ;; (defcustom widget-editable-list-gui nil
2506 ;;   "If non nil, use GUI push-buttons in editable list when available."
2507 ;;   :type 'boolean
2508 ;;   :group 'widgets)
2509
2510 (define-widget 'editable-list 'default
2511   "A variable list of widgets of the same type."
2512   :convert-widget 'widget-types-convert-widget
2513   :copy 'widget-types-copy
2514   :offset 12
2515   :format "%v%i\n"
2516   :format-handler 'widget-editable-list-format-handler
2517   :entry-format "%i %d %v"
2518   :value-create 'widget-editable-list-value-create
2519   :value-get 'widget-editable-list-value-get
2520   :validate 'widget-children-validate
2521   :match 'widget-editable-list-match
2522   :match-inline 'widget-editable-list-match-inline
2523   :insert-before 'widget-editable-list-insert-before
2524   :delete-at 'widget-editable-list-delete-at)
2525
2526 (defun widget-editable-list-format-handler (widget escape)
2527   ;; We recognize the insert button.
2528     ;; (let ((widget-push-button-gui widget-editable-list-gui))
2529     (cond ((eq escape ?i)
2530            (and (widget-get widget :indent)
2531                 (insert-char ?\  (widget-get widget :indent)))
2532            (apply 'widget-create-child-and-convert
2533                   widget 'insert-button
2534                   (widget-get widget :append-button-args)))
2535           (t
2536            (widget-default-format-handler widget escape)))
2537     ;; )
2538   )
2539
2540 (defun widget-editable-list-value-create (widget)
2541   ;; Insert all values
2542   (let* ((value (widget-get widget :value))
2543          (type (nth 0 (widget-get widget :args)))
2544          children)
2545     (widget-put widget :value-pos (copy-marker (point)))
2546     (set-marker-insertion-type (widget-get widget :value-pos) t)
2547     (while value
2548       (let ((answer (widget-match-inline type value)))
2549         (if answer
2550             (setq children (cons (widget-editable-list-entry-create
2551                                   widget
2552                                   (if (widget-get type :inline)
2553                                       (car answer)
2554                                     (car (car answer)))
2555                                   t)
2556                                  children)
2557                   value (cdr answer))
2558           (setq value nil))))
2559     (widget-put widget :children (nreverse children))))
2560
2561 (defun widget-editable-list-value-get (widget)
2562   ;; Get value of the child widget.
2563   (apply 'append (mapcar (lambda (child) (widget-apply child :value-inline))
2564                          (widget-get widget :children))))
2565
2566 (defun widget-editable-list-match (widget value)
2567   ;; Value must be a list and all the members must match the type.
2568   (and (listp value)
2569        (null (cdr (widget-editable-list-match-inline widget value)))))
2570
2571 (defun widget-editable-list-match-inline (widget value)
2572   (let ((type (nth 0 (widget-get widget :args)))
2573         (ok t)
2574         found)
2575     (while (and value ok)
2576       (let ((answer (widget-match-inline type value)))
2577         (if answer
2578             (setq found (append found (car answer))
2579                   value (cdr answer))
2580           (setq ok nil))))
2581     (cons found value)))
2582
2583 (defun widget-editable-list-insert-before (widget before)
2584   ;; Insert a new child in the list of children.
2585   (save-excursion
2586     (let ((children (widget-get widget :children))
2587           (inhibit-read-only t)
2588           before-change-functions
2589           after-change-functions)
2590       (cond (before
2591              (goto-char (widget-get before :entry-from)))
2592             (t
2593              (goto-char (widget-get widget :value-pos))))
2594       (let ((child (widget-editable-list-entry-create
2595                     widget nil nil)))
2596         (when (< (widget-get child :entry-from) (widget-get widget :from))
2597           (set-marker (widget-get widget :from)
2598                       (widget-get child :entry-from)))
2599         (if (eq (car children) before)
2600             (widget-put widget :children (cons child children))
2601           (while (not (eq (car (cdr children)) before))
2602             (setq children (cdr children)))
2603           (setcdr children (cons child (cdr children)))))))
2604   (widget-setup)
2605   (widget-apply widget :notify widget))
2606
2607 (defun widget-editable-list-delete-at (widget child)
2608   ;; Delete child from list of children.
2609   (save-excursion
2610     (let ((buttons (copy-sequence (widget-get widget :buttons)))
2611           button
2612           (inhibit-read-only t)
2613           before-change-functions
2614           after-change-functions)
2615       (while buttons
2616         (setq button (car buttons)
2617               buttons (cdr buttons))
2618         (when (eq (widget-get button :widget) child)
2619           (widget-put widget
2620                       :buttons (delq button (widget-get widget :buttons)))
2621           (widget-delete button))))
2622     (let ((entry-from (widget-get child :entry-from))
2623           (entry-to (widget-get child :entry-to))
2624           (inhibit-read-only t)
2625           before-change-functions
2626           after-change-functions)
2627       (widget-delete child)
2628       (delete-region entry-from entry-to)
2629       (set-marker entry-from nil)
2630       (set-marker entry-to nil))
2631     (widget-put widget :children (delq child (widget-get widget :children))))
2632   (widget-setup)
2633   (widget-apply widget :notify widget))
2634
2635 (defun widget-editable-list-entry-create (widget value conv)
2636   ;; Create a new entry to the list.
2637   (let ((type (nth 0 (widget-get widget :args)))
2638         ;; (widget-push-button-gui widget-editable-list-gui)
2639         child delete insert)
2640     (widget-specify-insert
2641      (save-excursion
2642        (and (widget-get widget :indent)
2643             (insert-char ?\  (widget-get widget :indent)))
2644        (insert (widget-get widget :entry-format)))
2645      ;; Parse % escapes in format.
2646      (while (re-search-forward "%\\(.\\)" nil t)
2647        (let ((escape (char-after (match-beginning 1))))
2648          (delete-backward-char 2)
2649          (cond ((eq escape ?%)
2650                 (insert ?%))
2651                ((eq escape ?i)
2652                 (setq insert (apply 'widget-create-child-and-convert
2653                                     widget 'insert-button
2654                                     (widget-get widget :insert-button-args))))
2655                ((eq escape ?d)
2656                 (setq delete (apply 'widget-create-child-and-convert
2657                                     widget 'delete-button
2658                                     (widget-get widget :delete-button-args))))
2659                ((eq escape ?v)
2660                 (if conv
2661                     (setq child (widget-create-child-value
2662                                  widget type value))
2663                   (setq child (widget-create-child-value
2664                                widget type (widget-default-get type)))))
2665                (t
2666                 (error "Unknown escape `%c'" escape)))))
2667      (let ((buttons (widget-get widget :buttons)))
2668        (if insert (push insert buttons))
2669        (if delete (push delete buttons))
2670        (widget-put widget :buttons buttons))
2671      (let ((entry-from (point-min-marker))
2672            (entry-to (point-max-marker)))
2673        (set-marker-insertion-type entry-from t)
2674        (set-marker-insertion-type entry-to nil)
2675        (widget-put child :entry-from entry-from)
2676        (widget-put child :entry-to entry-to)))
2677     (if insert (widget-put insert :widget child))
2678     (if delete (widget-put delete :widget child))
2679     child))
2680
2681 ;;; The `group' Widget.
2682
2683 (define-widget 'group 'default
2684   "A widget which groups other widgets inside."
2685   :convert-widget 'widget-types-convert-widget
2686   :copy 'widget-types-copy
2687   :format "%v"
2688   :value-create 'widget-group-value-create
2689   :value-get 'widget-editable-list-value-get
2690   :default-get 'widget-group-default-get
2691   :validate 'widget-children-validate
2692   :match 'widget-group-match
2693   :match-inline 'widget-group-match-inline)
2694
2695 (defun widget-group-value-create (widget)
2696   ;; Create each component.
2697   (let ((args (widget-get widget :args))
2698         (value (widget-get widget :value))
2699         arg answer children)
2700     (while args
2701       (setq arg (car args)
2702             args (cdr args)
2703             answer (widget-match-inline arg value)
2704             value (cdr answer))
2705       (and (eq (preceding-char) ?\n)
2706            (widget-get widget :indent)
2707            (insert-char ?\  (widget-get widget :indent)))
2708       (push (cond ((null answer)
2709                    (widget-create-child widget arg))
2710                   ((widget-get arg :inline)
2711                    (widget-create-child-value widget arg (car answer)))
2712                   (t
2713                    (widget-create-child-value widget arg (car (car answer)))))
2714             children))
2715     (widget-put widget :children (nreverse children))))
2716
2717 (defun widget-group-default-get (widget)
2718   ;; Get the default of the components.
2719   (mapcar 'widget-default-get (widget-get widget :args)))
2720
2721 (defun widget-group-match (widget values)
2722   ;; Match if the components match.
2723   (and (listp values)
2724        (let ((match (widget-group-match-inline widget values)))
2725          (and match (null (cdr match))))))
2726
2727 (defun widget-group-match-inline (widget vals)
2728   ;; Match if the components match.
2729   (let ((args (widget-get widget :args))
2730         argument answer found)
2731     (while args
2732       (setq argument (car args)
2733             args (cdr args)
2734             answer (widget-match-inline argument vals))
2735       (if answer
2736           (setq vals (cdr answer)
2737                 found (append found (car answer)))
2738         (setq vals nil
2739               args nil)))
2740     (if answer
2741         (cons found vals))))
2742
2743 ;;; The `visibility' Widget.
2744
2745 (define-widget 'visibility 'item
2746   "An indicator and manipulator for hidden items."
2747   :format "%[%v%]"
2748   :button-prefix ""
2749   :button-suffix ""
2750   :on "Hide"
2751   :off "Show"
2752   :value-create 'widget-visibility-value-create
2753   :action 'widget-toggle-action
2754   :match (lambda (widget value) t))
2755
2756 (defun widget-visibility-value-create (widget)
2757   ;; Insert text representing the `on' and `off' states.
2758   (let ((on (widget-get widget :on))
2759         (off (widget-get widget :off)))
2760     (if on
2761         (setq on (concat widget-push-button-prefix
2762                          on
2763                          widget-push-button-suffix))
2764       (setq on ""))
2765     (if off
2766         (setq off (concat widget-push-button-prefix
2767                           off
2768                           widget-push-button-suffix))
2769       (setq off ""))
2770     (if (widget-value widget)
2771         (widget-image-insert widget on "down" "down-pushed")
2772       (widget-image-insert widget off "right" "right-pushed"))))
2773
2774 ;;; The `documentation-link' Widget.
2775 ;;
2776 ;; This is a helper widget for `documentation-string'.
2777
2778 (define-widget 'documentation-link 'link
2779   "Link type used in documentation strings."
2780   :tab-order -1
2781   :help-echo "Describe this symbol"
2782   :action 'widget-documentation-link-action)
2783
2784 (defun widget-documentation-link-action (widget &optional event)
2785   "Display documentation for WIDGET's value.  Ignore optional argument EVENT."
2786   (let* ((string (widget-get widget :value))
2787          (symbol (intern string)))
2788     (if (and (fboundp symbol) (boundp symbol))
2789         ;; If there are two doc strings, give the user a way to pick one.
2790         (apropos (concat "\\`" (regexp-quote string) "\\'"))
2791       (if (fboundp symbol)
2792           (describe-function symbol)
2793         (describe-variable symbol)))))
2794
2795 (defcustom widget-documentation-links t
2796   "Add hyperlinks to documentation strings when non-nil."
2797   :type 'boolean
2798   :group 'widget-documentation)
2799
2800 (defcustom widget-documentation-link-regexp "`\\([^\n`' ]+\\)'"
2801   "Regexp for matching potential links in documentation strings.
2802 The first group should be the link itself."
2803   :type 'regexp
2804   :group 'widget-documentation)
2805
2806 (defcustom widget-documentation-link-p 'intern-soft
2807   "Predicate used to test if a string is useful as a link.
2808 The value should be a function.  The function will be called one
2809 argument, a string, and should return non-nil if there should be a
2810 link for that string."
2811   :type 'function
2812   :options '(widget-documentation-link-p)
2813   :group 'widget-documentation)
2814
2815 (defcustom widget-documentation-link-type 'documentation-link
2816   "Widget type used for links in documentation strings."
2817   :type 'symbol
2818   :group 'widget-documentation)
2819
2820 (defun widget-documentation-link-add (widget from to)
2821   (widget-specify-doc widget from to)
2822   (when widget-documentation-links
2823     (let ((regexp widget-documentation-link-regexp)
2824           (buttons (widget-get widget :buttons))
2825           (widget-mouse-face (default-value 'widget-mouse-face))
2826           (widget-button-face widget-documentation-face)
2827           (widget-button-pressed-face widget-documentation-face))
2828       (save-excursion
2829         (goto-char from)
2830         (while (re-search-forward regexp to t)
2831           (let ((name (match-string 1))
2832                 (begin (match-beginning 1))
2833                 (end (match-end 1)))
2834             (when (funcall widget-documentation-link-p name)
2835               (push (widget-convert-button widget-documentation-link-type
2836                                            begin end :value name)
2837                     buttons)))))
2838       (widget-put widget :buttons buttons)))
2839   (let ((indent (widget-get widget :indent)))
2840     (when (and indent (not (zerop indent)))
2841       (save-excursion
2842         (save-restriction
2843           (narrow-to-region from to)
2844           (goto-char (point-min))
2845           (while (search-forward "\n" nil t)
2846             (insert-char ?\  indent)))))))
2847
2848 ;;; The `documentation-string' Widget.
2849
2850 (define-widget 'documentation-string 'item
2851   "A documentation string."
2852   :format "%v"
2853   :action 'widget-documentation-string-action
2854   :value-create 'widget-documentation-string-value-create)
2855
2856 (defun widget-documentation-string-value-create (widget)
2857   ;; Insert documentation string.
2858   (let ((doc (widget-value widget))
2859         (indent (widget-get widget :indent))
2860         (shown (widget-get (widget-get widget :parent) :documentation-shown))
2861         (start (point)))
2862     (if (string-match "\n" doc)
2863         (let ((before (substring doc 0 (match-beginning 0)))
2864               (after (substring doc (match-beginning 0)))
2865               button)
2866           (insert before ?\ )
2867           (widget-documentation-link-add widget start (point))
2868           (setq button
2869                 (widget-create-child-and-convert
2870                  widget 'visibility
2871                  :help-echo "Show or hide rest of the documentation."
2872                  :on "Hide Rest"
2873                  :off "More"
2874                  :always-active t
2875                  :action 'widget-parent-action
2876                  shown))
2877           (when shown
2878             (setq start (point))
2879             (when (and indent (not (zerop indent)))
2880               (insert-char ?\  indent))
2881             (insert after)
2882             (widget-documentation-link-add widget start (point)))
2883           (widget-put widget :buttons (list button)))
2884       (insert doc)
2885       (widget-documentation-link-add widget start (point))))
2886   (insert ?\n))
2887
2888 (defun widget-documentation-string-action (widget &rest ignore)
2889   ;; Toggle documentation.
2890   (let ((parent (widget-get widget :parent)))
2891     (widget-put parent :documentation-shown
2892                 (not (widget-get parent :documentation-shown))))
2893   ;; Redraw.
2894   (widget-value-set widget (widget-value widget)))
2895 \f
2896 ;;; The Sexp Widgets.
2897
2898 (define-widget 'const 'item
2899   "An immutable sexp."
2900   :prompt-value 'widget-const-prompt-value
2901   :format "%t\n%d")
2902
2903 (defun widget-const-prompt-value (widget prompt value unbound)
2904   ;; Return the value of the const.
2905   (widget-value widget))
2906
2907 (define-widget 'function-item 'const
2908   "An immutable function name."
2909   :format "%v\n%h"
2910   :documentation-property (lambda (symbol)
2911                             (condition-case nil
2912                                 (documentation symbol t)
2913                               (error nil))))
2914
2915 (define-widget 'variable-item 'const
2916   "An immutable variable name."
2917   :format "%v\n%h"
2918   :documentation-property 'variable-documentation)
2919
2920 (define-widget 'other 'sexp
2921   "Matches any value, but doesn't let the user edit the value.
2922 This is useful as last item in a `choice' widget.
2923 You should use this widget type with a default value,
2924 as in (other DEFAULT) or (other :tag \"NAME\" DEFAULT).
2925 If the user selects this alternative, that specifies DEFAULT
2926 as the value."
2927   :tag "Other"
2928   :format "%t%n"
2929   :value 'other)
2930
2931 (defvar widget-string-prompt-value-history nil
2932   "History of input to `widget-string-prompt-value'.")
2933
2934 (define-widget 'string 'editable-field
2935   "A string"
2936   :tag "String"
2937   :format "%{%t%}: %v"
2938   :complete-function 'ispell-complete-word
2939   :prompt-history 'widget-string-prompt-value-history)
2940
2941 (define-widget 'regexp 'string
2942   "A regular expression."
2943   :match 'widget-regexp-match
2944   :validate 'widget-regexp-validate
2945   ;; Doesn't work well with terminating newline.
2946   ;; :value-face 'widget-single-line-field-face
2947   :tag "Regexp")
2948
2949 (defun widget-regexp-match (widget value)
2950   ;; Match valid regexps.
2951   (and (stringp value)
2952        (condition-case nil
2953            (prog1 t
2954              (string-match value ""))
2955          (error nil))))
2956
2957 (defun widget-regexp-validate (widget)
2958   "Check that the value of WIDGET is a valid regexp."
2959   (condition-case data
2960       (prog1 nil
2961         (string-match (widget-value widget) ""))
2962     (error (widget-put widget :error (error-message-string data))
2963            widget)))
2964
2965 (define-widget 'file 'string
2966   "A file widget.
2967 It will read a file name from the minibuffer when invoked."
2968   :complete-function 'widget-file-complete
2969   :prompt-value 'widget-file-prompt-value
2970   :format "%{%t%}: %v"
2971   ;; Doesn't work well with terminating newline.
2972   ;; :value-face 'widget-single-line-field-face
2973   :tag "File")
2974
2975 (defun widget-file-complete ()
2976   "Perform completion on file name preceding point."
2977   (interactive)
2978   (let* ((end (point))
2979          (beg (save-excursion
2980                 (skip-chars-backward "^ ")
2981                 (point)))
2982          (pattern (buffer-substring beg end))
2983          (name-part (file-name-nondirectory pattern))
2984          (directory (file-name-directory pattern))
2985          (completion (file-name-completion name-part directory)))
2986     (cond ((eq completion t))
2987           ((null completion)
2988            (message "Can't find completion for \"%s\"" pattern)
2989            (ding))
2990           ((not (string= name-part completion))
2991            (delete-region beg end)
2992            (insert (expand-file-name completion directory)))
2993           (t
2994            (message "Making completion list...")
2995            (with-output-to-temp-buffer "*Completions*"
2996              (display-completion-list
2997               (sort (file-name-all-completions name-part directory)
2998                     'string<)))
2999            (message "Making completion list...%s" "done")))))
3000
3001 (defun widget-file-prompt-value (widget prompt value unbound)
3002   ;; Read file from minibuffer.
3003   (abbreviate-file-name
3004    (if unbound
3005        (read-file-name prompt)
3006      (let ((prompt2 (format "%s (default %s) " prompt value))
3007            (dir (file-name-directory value))
3008            (file (file-name-nondirectory value))
3009            (must-match (widget-get widget :must-match)))
3010        (read-file-name prompt2 dir nil must-match file)))))
3011
3012 ;;;(defun widget-file-action (widget &optional event)
3013 ;;;  ;; Read a file name from the minibuffer.
3014 ;;;  (let* ((value (widget-value widget))
3015 ;;;      (dir (file-name-directory value))
3016 ;;;      (file (file-name-nondirectory value))
3017 ;;;      (menu-tag (widget-apply widget :menu-tag-get))
3018 ;;;      (must-match (widget-get widget :must-match))
3019 ;;;      (answer (read-file-name (concat menu-tag ": (default `" value "') ")
3020 ;;;                              dir nil must-match file)))
3021 ;;;    (widget-value-set widget (abbreviate-file-name answer))
3022 ;;;    (widget-setup)
3023 ;;;    (widget-apply widget :notify widget event)))
3024
3025 ;; Fixme: use file-name-as-directory.
3026 (define-widget 'directory 'file
3027   "A directory widget.
3028 It will read a directory name from the minibuffer when invoked."
3029   :tag "Directory")
3030
3031 (defvar widget-symbol-prompt-value-history nil
3032   "History of input to `widget-symbol-prompt-value'.")
3033
3034 (define-widget 'symbol 'editable-field
3035   "A Lisp symbol."
3036   :value nil
3037   :tag "Symbol"
3038   :format "%{%t%}: %v"
3039   :match (lambda (widget value) (symbolp value))
3040   :complete-function 'lisp-complete-symbol
3041   :prompt-internal 'widget-symbol-prompt-internal
3042   :prompt-match 'symbolp
3043   :prompt-history 'widget-symbol-prompt-value-history
3044   :value-to-internal (lambda (widget value)
3045                        (if (symbolp value)
3046                            (symbol-name value)
3047                          value))
3048   :value-to-external (lambda (widget value)
3049                        (if (stringp value)
3050                            (intern value)
3051                          value)))
3052
3053 (defun widget-symbol-prompt-internal (widget prompt initial history)
3054   ;; Read file from minibuffer.
3055   (let ((answer (completing-read prompt obarray
3056                                  (widget-get widget :prompt-match)
3057                                  nil initial history)))
3058     (if (and (stringp answer)
3059              (not (zerop (length answer))))
3060         answer
3061       (error "No value"))))
3062
3063 (defvar widget-function-prompt-value-history nil
3064   "History of input to `widget-function-prompt-value'.")
3065
3066 (define-widget 'function 'restricted-sexp
3067   "A Lisp function."
3068   :complete-function (lambda ()
3069                        (interactive)
3070                        (lisp-complete-symbol 'fboundp))
3071   :prompt-value 'widget-field-prompt-value
3072   :prompt-internal 'widget-symbol-prompt-internal
3073   :prompt-match 'fboundp
3074   :prompt-history 'widget-function-prompt-value-history
3075   :action 'widget-field-action
3076   :match-alternatives '(functionp)
3077   :validate (lambda (widget)
3078               (unless (functionp (widget-value widget))
3079                 (widget-put widget :error (format "Invalid function: %S"
3080                                                   (widget-value widget)))
3081                 widget))
3082   :value 'ignore
3083   :tag "Function")
3084
3085 (defvar widget-variable-prompt-value-history nil
3086   "History of input to `widget-variable-prompt-value'.")
3087
3088 (define-widget 'variable 'symbol
3089   "A Lisp variable."
3090   :prompt-match 'boundp
3091   :prompt-history 'widget-variable-prompt-value-history
3092   :complete-function (lambda ()
3093                        (interactive)
3094                        (lisp-complete-symbol 'boundp))
3095   :tag "Variable")
3096
3097 (defvar widget-coding-system-prompt-value-history nil
3098   "History of input to `widget-coding-system-prompt-value'.")
3099
3100 (define-widget 'coding-system 'symbol
3101   "A MULE coding-system."
3102   :format "%{%t%}: %v"
3103   :tag "Coding system"
3104   :base-only nil
3105   :prompt-history 'widget-coding-system-prompt-value-history
3106   :prompt-value 'widget-coding-system-prompt-value
3107   :action 'widget-coding-system-action
3108   :complete-function (lambda ()
3109                        (interactive)
3110                        (lisp-complete-symbol 'coding-system-p))
3111   :validate (lambda (widget)
3112               (unless (coding-system-p (widget-value widget))
3113                 (widget-put widget :error (format "Invalid coding system: %S"
3114                                                   (widget-value widget)))
3115                 widget))
3116   :value 'undecided
3117   :prompt-match 'coding-system-p)
3118
3119 (defun widget-coding-system-prompt-value (widget prompt value unbound)
3120   "Read coding-system from minibuffer."
3121   (if (widget-get widget :base-only)
3122       (intern
3123        (completing-read (format "%s (default %s) " prompt value)
3124                         (mapcar #'list (coding-system-list t)) nil nil nil
3125                         coding-system-history))
3126       (read-coding-system (format "%s (default %s) " prompt value) value)))
3127
3128 (defun widget-coding-system-action (widget &optional event)
3129   (let ((answer
3130          (widget-coding-system-prompt-value
3131           widget
3132           (widget-apply widget :menu-tag-get)
3133           (widget-value widget)
3134           t)))
3135     (widget-value-set widget answer)
3136     (widget-apply widget :notify widget event)
3137     (widget-setup)))
3138 \f
3139 (define-widget 'sexp 'editable-field
3140   "An arbitrary Lisp expression."
3141   :tag "Lisp expression"
3142   :format "%{%t%}: %v"
3143   :value nil
3144   :validate 'widget-sexp-validate
3145   :match (lambda (widget value) t)
3146   :value-to-internal 'widget-sexp-value-to-internal
3147   :value-to-external (lambda (widget value) (read value))
3148   :prompt-history 'widget-sexp-prompt-value-history
3149   :prompt-value 'widget-sexp-prompt-value)
3150
3151 (defun widget-sexp-value-to-internal (widget value)
3152   ;; Use pp for printer representation.
3153   (let ((pp (if (symbolp value)
3154                 (prin1-to-string value)
3155               (pp-to-string value))))
3156     (while (string-match "\n\\'" pp)
3157       (setq pp (substring pp 0 -1)))
3158     (if (or (string-match "\n\\'" pp)
3159             (> (length pp) 40))
3160         (concat "\n" pp)
3161       pp)))
3162
3163 (defun widget-sexp-validate (widget)
3164   ;; Valid if we can read the string and there is no junk left after it.
3165   (with-temp-buffer
3166     (insert (widget-apply widget :value-get))
3167     (goto-char (point-min))
3168     (let (err)
3169       (condition-case data
3170           (progn
3171             ;; Avoid a confusing end-of-file error.
3172             (skip-syntax-forward "\\s-")
3173             (if (eobp)
3174                 (setq err "Empty sexp -- use `nil'?")
3175               (unless (widget-apply widget :match (read (current-buffer)))
3176                 (setq err (widget-get widget :type-error))))
3177             ;; Allow whitespace after expression.
3178             (skip-syntax-forward "\\s-")
3179             (if (and (not (eobp))
3180                      (not err))
3181                 (setq err (format "Junk at end of expression: %s"
3182                                   (buffer-substring (point)
3183                                                     (point-max))))))
3184         (end-of-file                    ; Avoid confusing error message.
3185          (setq err "Unbalanced sexp"))
3186         (error (setq err (error-message-string data))))
3187       (if (not err)
3188           nil
3189         (widget-put widget :error err)
3190         widget))))
3191
3192 (defvar widget-sexp-prompt-value-history nil
3193   "History of input to `widget-sexp-prompt-value'.")
3194
3195 (defun widget-sexp-prompt-value (widget prompt value unbound)
3196   ;; Read an arbitrary sexp.
3197   (let ((found (read-string prompt
3198                             (if unbound nil (cons (prin1-to-string value) 0))
3199                             (widget-get widget :prompt-history))))
3200     (let ((answer (read-from-string found)))
3201       (unless (= (cdr answer) (length found))
3202         (error "Junk at end of expression: %s"
3203                (substring found (cdr answer))))
3204       (car answer))))
3205
3206 (define-widget 'restricted-sexp 'sexp
3207   "A Lisp expression restricted to values that match.
3208 To use this type, you must define :match or :match-alternatives."
3209   :type-error "The specified value is not valid"
3210   :match 'widget-restricted-sexp-match
3211   :value-to-internal (lambda (widget value)
3212                        (if (widget-apply widget :match value)
3213                            (prin1-to-string value)
3214                          value)))
3215
3216 (defun widget-restricted-sexp-match (widget value)
3217   (let ((alternatives (widget-get widget :match-alternatives))
3218         matched)
3219     (while (and alternatives (not matched))
3220       (if (cond ((functionp (car alternatives))
3221                  (funcall (car alternatives) value))
3222                 ((and (consp (car alternatives))
3223                       (eq (car (car alternatives)) 'quote))
3224                  (eq value (nth 1 (car alternatives)))))
3225           (setq matched t))
3226       (setq alternatives (cdr alternatives)))
3227     matched))
3228 \f
3229 (define-widget 'integer 'restricted-sexp
3230   "An integer."
3231   :tag "Integer"
3232   :value 0
3233   :type-error "This field should contain an integer"
3234   :match-alternatives '(integerp))
3235
3236 (define-widget 'number 'restricted-sexp
3237   "A number (floating point or integer)."
3238   :tag "Number"
3239   :value 0.0
3240   :type-error "This field should contain a number (floating point or integer)"
3241   :match-alternatives '(numberp))
3242
3243 (define-widget 'float 'restricted-sexp
3244   "A floating point number."
3245   :tag "Floating point number"
3246   :value 0.0
3247   :type-error "This field should contain a floating point number"
3248   :match-alternatives '(floatp))
3249
3250 (define-widget 'character 'editable-field
3251   "A character."
3252   :tag "Character"
3253   :value 0
3254   :size 1
3255   :format "%{%t%}: %v\n"
3256   :valid-regexp "\\`.\\'"
3257   :error "This field should contain a single character"
3258   :value-to-internal (lambda (widget value)
3259                        (if (stringp value)
3260                            value
3261                          (char-to-string value)))
3262   :value-to-external (lambda (widget value)
3263                        (if (stringp value)
3264                            (aref value 0)
3265                          value))
3266   :match (lambda (widget value)
3267            (char-valid-p value)))
3268
3269 (define-widget 'list 'group
3270   "A Lisp list."
3271   :tag "List"
3272   :format "%{%t%}:\n%v")
3273
3274 (define-widget 'vector 'group
3275   "A Lisp vector."
3276   :tag "Vector"
3277   :format "%{%t%}:\n%v"
3278   :match 'widget-vector-match
3279   :value-to-internal (lambda (widget value) (append value nil))
3280   :value-to-external (lambda (widget value) (apply 'vector value)))
3281
3282 (defun widget-vector-match (widget value)
3283   (and (vectorp value)
3284        (widget-group-match widget
3285                            (widget-apply widget :value-to-internal value))))
3286
3287 (define-widget 'cons 'group
3288   "A cons-cell."
3289   :tag "Cons-cell"
3290   :format "%{%t%}:\n%v"
3291   :match 'widget-cons-match
3292   :value-to-internal (lambda (widget value)
3293                        (list (car value) (cdr value)))
3294   :value-to-external (lambda (widget value)
3295                        (apply 'cons value)))
3296
3297 (defun widget-cons-match (widget value)
3298   (and (consp value)
3299        (widget-group-match widget
3300                            (widget-apply widget :value-to-internal value))))
3301 \f
3302 ;;; The `lazy' Widget.
3303 ;;
3304 ;; Recursive datatypes.
3305
3306 (define-widget 'lazy 'default
3307   "Base widget for recursive datastructures.
3308
3309 The `lazy' widget will, when instantiated, contain a single inferior
3310 widget, of the widget type specified by the :type parameter.  The
3311 value of the `lazy' widget is the same as the value of the inferior
3312 widget.  When deriving a new widget from the 'lazy' widget, the :type
3313 parameter is allowed to refer to the widget currently being defined,
3314 thus allowing recursive datastructures to be described.
3315
3316 The :type parameter takes the same arguments as the defcustom
3317 parameter with the same name.
3318
3319 Most composite widgets, i.e. widgets containing other widgets, does
3320 not allow recursion.  That is, when you define a new widget type, none
3321 of the inferior widgets may be of the same type you are currently
3322 defining.
3323
3324 In Lisp, however, it is custom to define datastructures in terms of
3325 themselves.  A list, for example, is defined as either nil, or a cons
3326 cell whose cdr itself is a list.  The obvious way to translate this
3327 into a widget type would be
3328
3329   (define-widget 'my-list 'choice
3330     \"A list of sexps.\"
3331     :tag \"Sexp list\"
3332     :args '((const nil) (cons :value (nil) sexp my-list)))
3333
3334 Here we attempt to define my-list as a choice of either the constant
3335 nil, or a cons-cell containing a sexp and my-lisp.  This will not work
3336 because the `choice' widget does not allow recursion.
3337
3338 Using the `lazy' widget you can overcome this problem, as in this
3339 example:
3340
3341   (define-widget 'sexp-list 'lazy
3342     \"A list of sexps.\"
3343     :tag \"Sexp list\"
3344     :type '(choice (const nil) (cons :value (nil) sexp sexp-list)))"
3345   :format "%{%t%}: %v"
3346   ;; We don't convert :type because we want to allow recursive
3347   ;; datastructures.  This is slow, so we should not create speed
3348   ;; critical widgets by deriving from this.
3349   :convert-widget 'widget-value-convert-widget
3350   :value-create 'widget-type-value-create
3351   :value-get 'widget-child-value-get
3352   :value-inline 'widget-child-value-inline
3353   :default-get 'widget-type-default-get
3354   :match 'widget-type-match
3355   :validate 'widget-child-validate)
3356
3357 \f
3358 ;;; The `plist' Widget.
3359 ;;
3360 ;; Property lists.
3361
3362 (define-widget 'plist 'list
3363   "A property list."
3364   :key-type '(symbol :tag "Key")
3365   :value-type '(sexp :tag "Value")
3366   :convert-widget 'widget-plist-convert-widget
3367   :tag "Plist")
3368
3369 (defvar widget-plist-value-type)        ;Dynamic variable
3370
3371 (defun widget-plist-convert-widget (widget)
3372   ;; Handle `:options'.
3373   (let* ((options (widget-get widget :options))
3374          (widget-plist-value-type (widget-get widget :value-type))
3375          (other `(editable-list :inline t
3376                                 (group :inline t
3377                                        ,(widget-get widget :key-type)
3378                                        ,widget-plist-value-type)))
3379          (args (if options
3380                    (list `(checklist :inline t
3381                                      :greedy t
3382                                      ,@(mapcar 'widget-plist-convert-option
3383                                                options))
3384                          other)
3385                  (list other))))
3386     (widget-put widget :args args)
3387     widget))
3388
3389 (defun widget-plist-convert-option (option)
3390   ;; Convert a single plist option.
3391   (let (key-type value-type)
3392     (if (listp option)
3393         (let ((key (nth 0 option)))
3394           (setq value-type (nth 1 option))
3395           (if (listp key)
3396               (setq key-type key)
3397             (setq key-type `(const ,key))))
3398       (setq key-type `(const ,option)
3399             value-type widget-plist-value-type))
3400     `(group :format "Key: %v" :inline t ,key-type ,value-type)))
3401
3402
3403 ;;; The `alist' Widget.
3404 ;;
3405 ;; Association lists.
3406
3407 (define-widget 'alist 'list
3408   "An association list."
3409   :key-type '(sexp :tag "Key")
3410   :value-type '(sexp :tag "Value")
3411   :convert-widget 'widget-alist-convert-widget
3412   :tag "Alist")
3413
3414 (defvar widget-alist-value-type)        ;Dynamic variable
3415
3416 (defun widget-alist-convert-widget (widget)
3417   ;; Handle `:options'.
3418   (let* ((options (widget-get widget :options))
3419          (widget-alist-value-type (widget-get widget :value-type))
3420          (other `(editable-list :inline t
3421                                 (cons :format "%v"
3422                                       ,(widget-get widget :key-type)
3423                                       ,widget-alist-value-type)))
3424          (args (if options
3425                    (list `(checklist :inline t
3426                                      :greedy t
3427                                      ,@(mapcar 'widget-alist-convert-option
3428                                                options))
3429                          other)
3430                  (list other))))
3431     (widget-put widget :args args)
3432     widget))
3433
3434 (defun widget-alist-convert-option (option)
3435   ;; Convert a single alist option.
3436   (let (key-type value-type)
3437     (if (listp option)
3438         (let ((key (nth 0 option)))
3439           (setq value-type (nth 1 option))
3440           (if (listp key)
3441               (setq key-type key)
3442             (setq key-type `(const ,key))))
3443       (setq key-type `(const ,option)
3444             value-type widget-alist-value-type))
3445     `(cons :format "Key: %v" ,key-type ,value-type)))
3446 \f
3447 (define-widget 'choice 'menu-choice
3448   "A union of several sexp types."
3449   :tag "Choice"
3450   :format "%{%t%}: %[Value Menu%] %v"
3451   :button-prefix 'widget-push-button-prefix
3452   :button-suffix 'widget-push-button-suffix
3453   :prompt-value 'widget-choice-prompt-value)
3454
3455 (defun widget-choice-prompt-value (widget prompt value unbound)
3456   "Make a choice."
3457   (let ((args (widget-get widget :args))
3458         (completion-ignore-case (widget-get widget :case-fold))
3459         current choices old)
3460     ;; Find the first arg that matches VALUE.
3461     (let ((look args))
3462       (while look
3463         (if (widget-apply (car look) :match value)
3464             (setq old (car look)
3465                   look nil)
3466           (setq look (cdr look)))))
3467     ;; Find new choice.
3468     (setq current
3469           (cond ((= (length args) 0)
3470                  nil)
3471                 ((= (length args) 1)
3472                  (nth 0 args))
3473                 ((and (= (length args) 2)
3474                       (memq old args))
3475                  (if (eq old (nth 0 args))
3476                      (nth 1 args)
3477                    (nth 0 args)))
3478                 (t
3479                  (while args
3480                    (setq current (car args)
3481                          args (cdr args))
3482                    (setq choices
3483                          (cons (cons (widget-apply current :menu-tag-get)
3484                                      current)
3485                                choices)))
3486                  (let ((val (completing-read prompt choices nil t)))
3487                    (if (stringp val)
3488                        (let ((try (try-completion val choices)))
3489                          (when (stringp try)
3490                            (setq val try))
3491                          (cdr (assoc val choices)))
3492                      nil)))))
3493     (if current
3494         (widget-prompt-value current prompt nil t)
3495       value)))
3496 \f
3497 (define-widget 'radio 'radio-button-choice
3498   "A union of several sexp types."
3499   :tag "Choice"
3500   :format "%{%t%}:\n%v"
3501   :prompt-value 'widget-choice-prompt-value)
3502
3503 (define-widget 'repeat 'editable-list
3504   "A variable length homogeneous list."
3505   :tag "Repeat"
3506   :format "%{%t%}:\n%v%i\n")
3507
3508 (define-widget 'set 'checklist
3509   "A list of members from a fixed set."
3510   :tag "Set"
3511   :format "%{%t%}:\n%v")
3512
3513 (define-widget 'boolean 'toggle
3514   "To be nil or non-nil, that is the question."
3515   :tag "Boolean"
3516   :prompt-value 'widget-boolean-prompt-value
3517   :button-prefix 'widget-push-button-prefix
3518   :button-suffix 'widget-push-button-suffix
3519   :format "%{%t%}: %[Toggle%]  %v\n"
3520   :on "on (non-nil)"
3521   :off "off (nil)")
3522
3523 (defun widget-boolean-prompt-value (widget prompt value unbound)
3524   ;; Toggle a boolean.
3525   (y-or-n-p prompt))
3526 \f
3527 ;;; The `color' Widget.
3528
3529 ;; Fixme: match
3530 (define-widget 'color 'editable-field
3531   "Choose a color name (with sample)."
3532   :format "%t: %v (%{sample%})\n"
3533   :size 10
3534   :tag "Color"
3535   :value "black"
3536   :complete 'widget-color-complete
3537   :sample-face-get 'widget-color-sample-face-get
3538   :notify 'widget-color-notify
3539   :action 'widget-color-action)
3540
3541 (defun widget-color-complete (widget)
3542   "Complete the color in WIDGET."
3543   (require 'facemenu)                   ; for facemenu-color-alist
3544   (let* ((prefix (buffer-substring-no-properties (widget-field-start widget)
3545                                                  (point)))
3546          (list (or facemenu-color-alist (defined-colors)))
3547          (completion (try-completion prefix list)))
3548     (cond ((eq completion t)
3549            (message "Exact match."))
3550           ((null completion)
3551            (error "Can't find completion for \"%s\"" prefix))
3552           ((not (string-equal prefix completion))
3553            (insert-and-inherit (substring completion (length prefix))))
3554           (t
3555            (message "Making completion list...")
3556            (with-output-to-temp-buffer "*Completions*"
3557              (display-completion-list (all-completions prefix list nil)))
3558            (message "Making completion list...done")))))
3559
3560 (defun widget-color-sample-face-get (widget)
3561   (let* ((value (condition-case nil
3562                     (widget-value widget)
3563                   (error (widget-get widget :value)))))
3564     (if (color-defined-p value)
3565         (list (cons 'foreground-color value))
3566       'default)))
3567
3568 (defun widget-color-action (widget &optional event)
3569   "Prompt for a color."
3570   (let* ((tag (widget-apply widget :menu-tag-get))
3571          (prompt (concat tag ": "))
3572          (value (widget-value widget))
3573          (start (widget-field-start widget))
3574          (answer (facemenu-read-color prompt)))
3575     (unless (zerop (length answer))
3576       (widget-value-set widget answer)
3577       (widget-setup)
3578       (widget-apply widget :notify widget event))))
3579
3580 (defun widget-color-notify (widget child &optional event)
3581   "Update the sample, and notofy the parent."
3582   (overlay-put (widget-get widget :sample-overlay)
3583                'face (widget-apply widget :sample-face-get))
3584   (widget-default-notify widget child event))
3585 \f
3586 ;;; The Help Echo
3587
3588 (defun widget-echo-help (pos)
3589   "Display help-echo text for widget at POS."
3590   (let* ((widget (widget-at pos))
3591          (help-echo (and widget (widget-get widget :help-echo))))
3592     (if (functionp help-echo)
3593         (setq help-echo (funcall help-echo widget)))
3594     (if help-echo (message "%s" (eval help-echo)))))
3595
3596 ;;; The End:
3597
3598 (provide 'wid-edit)
3599
3600 ;;; arch-tag: a076e75e-18a1-4b46-8be5-3f317bcbc707
3601 ;;; wid-edit.el ends here