lisp/font-core.el

   1 ;;; font-core.el --- Core interface to font-lock
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2005  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: languages, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 ;; This variable is used by mode packages that support Font Lock mode by
  29 ;; defining their own keywords to use for `font-lock-keywords'.  (The mode
  30 ;; command should make it buffer-local and set it to provide the set up.)
  31 (defvar font-lock-defaults nil
  32   "Defaults for Font Lock mode specified by the major mode.
  33 Defaults should be of the form:
  34
  35  (KEYWORDS KEYWORDS-ONLY CASE-FOLD SYNTAX-ALIST SYNTAX-BEGIN ...)
  36
  37 KEYWORDS may be a symbol (a variable or function whose value is the keywords to
  38 use for fontification) or a list of symbols.  If KEYWORDS-ONLY is non-nil,
  39 syntactic fontification (strings and comments) is not performed.
  40 If CASE-FOLD is non-nil, the case of the keywords is ignored when fontifying.
  41 If SYNTAX-ALIST is non-nil, it should be a list of cons pairs of the form
  42 \(CHAR-OR-STRING . STRING) used to set the local Font Lock syntax table, for
  43 keyword and syntactic fontification (see `modify-syntax-entry').
  44
  45 If SYNTAX-BEGIN is non-nil, it should be a function with no args used to move
  46 backwards outside any enclosing syntactic block, for syntactic fontification.
  47 Typical values are `beginning-of-line' (i.e., the start of the line is known to
  48 be outside a syntactic block), or `beginning-of-defun' for programming modes or
  49 `backward-paragraph' for textual modes (i.e., the mode-dependent function is
  50 known to move outside a syntactic block).  If nil, the beginning of the buffer
  51 is used as a position outside of a syntactic block, in the worst case.
  52
  53 These item elements are used by Font Lock mode to set the variables
  54 `font-lock-keywords', `font-lock-keywords-only',
  55 `font-lock-keywords-case-fold-search', `font-lock-syntax-table' and
  56 `font-lock-beginning-of-syntax-function', respectively.
  57
  58 Further item elements are alists of the form (VARIABLE . VALUE) and are in no
  59 particular order.  Each VARIABLE is made buffer-local before set to VALUE.
  60
  61 Currently, appropriate variables include `font-lock-mark-block-function'.
  62 If this is non-nil, it should be a function with no args used to mark any
  63 enclosing block of text, for fontification via \\[font-lock-fontify-block].
  64 Typical values are `mark-defun' for programming modes or `mark-paragraph' for
  65 textual modes (i.e., the mode-dependent function is known to put point and mark
  66 around a text block relevant to that mode).
  67
  68 Other variables include that for syntactic keyword fontification,
  69 `font-lock-syntactic-keywords'
  70 and those for buffer-specialized fontification functions,
  71 `font-lock-fontify-buffer-function', `font-lock-unfontify-buffer-function',
  72 `font-lock-fontify-region-function', `font-lock-unfontify-region-function',
  73 `font-lock-inhibit-thing-lock' and `font-lock-maximum-size'.")
  74 (make-variable-buffer-local 'font-lock-defaults)
  75
  76 (defvar font-lock-defaults-alist nil
  77   "Alist of fall-back Font Lock defaults for major modes.
  78
  79 Each item should be a list of the form:
  80
  81  (MAJOR-MODE . FONT-LOCK-DEFAULTS)
  82
  83 where MAJOR-MODE is a symbol and FONT-LOCK-DEFAULTS is a list of default
  84 settings.  See the variable `font-lock-defaults', which takes precedence.")
  85 (make-obsolete-variable 'font-lock-defaults-alist 'font-lock-defaults)
  86
  87 (defvar font-lock-function 'font-lock-default-function
  88   "A function which is called when `font-lock-mode' is toggled.
  89 It will be passed one argument, which is the current value of
  90 `font-lock-mode'.")
  91
  92 (define-minor-mode font-lock-mode
  93   "Toggle Font Lock mode.
  94 With arg, turn Font Lock mode off if and only if arg is a non-positive
  95 number; if arg is nil, toggle Font Lock mode; anything else turns Font
  96 Lock on.
  97 \(Font Lock is also known as \"syntax highlighting\".)
  98
  99 When Font Lock mode is enabled, text is fontified as you type it:
 100
 101  - Comments are displayed in `font-lock-comment-face';
 102  - Strings are displayed in `font-lock-string-face';
 103  - Certain other expressions are displayed in other faces according to the
 104    value of the variable `font-lock-keywords'.
 105
 106 To customize the faces (colors, fonts, etc.) used by Font Lock for
 107 fontifying different parts of buffer text, use \\[customize-face].
 108
 109 You can enable Font Lock mode in any major mode automatically by turning on in
 110 the major mode's hook.  For example, put in your ~/.emacs:
 111
 112  (add-hook 'c-mode-hook 'turn-on-font-lock)
 113
 114 Alternatively, you can use Global Font Lock mode to automagically turn on Font
 115 Lock mode in buffers whose major mode supports it and whose major mode is one
 116 of `font-lock-global-modes'.  For example, put in your ~/.emacs:
 117
 118  (global-font-lock-mode t)
 119
 120 There are a number of support modes that may be used to speed up Font Lock mode
 121 in various ways, specified via the variable `font-lock-support-mode'.  Where
 122 major modes support different levels of fontification, you can use the variable
 123 `font-lock-maximum-decoration' to specify which level you generally prefer.
 124 When you turn Font Lock mode on/off the buffer is fontified/defontified, though
 125 fontification occurs only if the buffer is less than `font-lock-maximum-size'.
 126
 127 For example, to specify that Font Lock mode use use Lazy Lock mode as a support
 128 mode and use maximum levels of fontification, put in your ~/.emacs:
 129
 130  (setq font-lock-support-mode 'lazy-lock-mode)
 131  (setq font-lock-maximum-decoration t)
 132
 133 To add your own highlighting for some major mode, and modify the highlighting
 134 selected automatically via the variable `font-lock-maximum-decoration', you can
 135 use `font-lock-add-keywords'.
 136
 137 To fontify a buffer, without turning on Font Lock mode and regardless of buffer
 138 size, you can use \\[font-lock-fontify-buffer].
 139
 140 To fontify a block (the function or paragraph containing point, or a number of
 141 lines around point), perhaps because modification on the current line caused
 142 syntactic change on other lines, you can use \\[font-lock-fontify-block].
 143
 144 See the variable `font-lock-defaults-alist' for the Font Lock mode default
 145 settings.  You can set your own default settings for some mode, by setting a
 146 buffer local value for `font-lock-defaults', via its mode hook.
 147
 148 The above is the default behavior of `font-lock-mode'; you may specify
 149 your own function which is called when `font-lock-mode' is toggled via
 150 `font-lock-function'. "
 151   nil nil nil
 152   ;; Don't turn on Font Lock mode if we don't have a display (we're running a
 153   ;; batch job) or if the buffer is invisible (the name starts with a space).
 154   (when (or noninteractive (eq (aref (buffer-name) 0) ?\ ))
 155     (setq font-lock-mode nil))
 156   (funcall font-lock-function font-lock-mode)
 157   ;; Arrange to unfontify this buffer if we change major mode later.
 158   (if font-lock-mode
 159       (add-hook 'change-major-mode-hook 'font-lock-change-mode nil t)
 160     (remove-hook 'change-major-mode-hook 'font-lock-change-mode t)))
 161
 162 ;; Get rid of fontification for the old major mode.
 163 ;; We do this when changing major modes.
 164 (defun font-lock-change-mode ()
 165   (font-lock-mode -1))
 166
 167 (defun font-lock-defontify ()
 168   "Clear out all `font-lock-face' properties in current buffer.
 169 A major mode that uses `font-lock-face' properties might want to put
 170 this function onto `change-major-mode-hook'."
 171   (let ((modp (buffer-modified-p))
 172         (inhibit-read-only t))
 173     (save-restriction
 174       (widen)
 175       (remove-list-of-text-properties (point-min) (point-max)
 176                                       '(font-lock-face)))
 177     (restore-buffer-modified-p modp)))
 178
 179 (defun font-lock-default-function (mode)
 180   ;; Turn on Font Lock mode.
 181   (when mode
 182     (set (make-local-variable 'char-property-alias-alist)
 183          (copy-tree char-property-alias-alist))
 184     ;; Add `font-lock-face' as an alias for the `face' property.
 185     (let ((elt (assq 'face char-property-alias-alist)))
 186       (if elt
 187           (unless (memq 'font-lock-face (cdr elt))
 188             (setcdr elt (nconc (cdr elt) (list 'font-lock-face))))
 189         (push (list 'face 'font-lock-face) char-property-alias-alist))))
 190   ;; Turn off Font Lock mode.
 191   (unless mode
 192     ;; Remove `font-lock-face' as an alias for the `face' property.
 193     (set (make-local-variable 'char-property-alias-alist)
 194          (copy-tree char-property-alias-alist))
 195     (let ((elt (assq 'face char-property-alias-alist)))
 196       (when elt
 197         (setcdr elt (remq 'font-lock-face (cdr elt)))
 198         (when (null (cdr elt))
 199           (setq char-property-alias-alist
 200                 (delq elt char-property-alias-alist))))))
 201
 202   ;; Only do hard work if the mode has specified stuff in
 203   ;; `font-lock-defaults'.
 204   (when (or font-lock-defaults
 205             (and (boundp 'font-lock-keywords) font-lock-keywords)
 206             (cdr (assq major-mode font-lock-defaults-alist)))
 207     (font-lock-mode-internal mode)))
 208
 209 (defun turn-on-font-lock ()
 210   "Turn on Font Lock mode (only if the terminal can display it)."
 211   (unless font-lock-mode
 212     (font-lock-mode)))
 213
 214 ;;; Global Font Lock mode.
 215
 216 ;; A few people have hassled in the past for a way to make it easier to turn on
 217 ;; Font Lock mode, without the user needing to know for which modes s/he has to
 218 ;; turn it on, perhaps the same way hilit19.el/hl319.el does.  I've always
 219 ;; balked at that way, as I see it as just re-moulding the same problem in
 220 ;; another form.  That is; some person would still have to keep track of which
 221 ;; modes (which may not even be distributed with Emacs) support Font Lock mode.
 222 ;; The list would always be out of date.  And that person might have to be me.
 223
 224 ;; Implementation.
 225 ;;
 226 ;; In a previous discussion the following hack came to mind.  It is a gross
 227 ;; hack, but it generally works.  We use the convention that major modes start
 228 ;; by calling the function `kill-all-local-variables', which in turn runs
 229 ;; functions on the hook variable `change-major-mode-hook'.  We attach our
 230 ;; function `font-lock-change-major-mode' to that hook.  Of course, when this
 231 ;; hook is run, the major mode is in the process of being changed and we do not
 232 ;; know what the final major mode will be.  So, `font-lock-change-major-mode'
 233 ;; only (a) notes the name of the current buffer, and (b) adds our function
 234 ;; `turn-on-font-lock-if-enabled' to the hook variables `find-file-hook' and
 235 ;; `post-command-hook' (for buffers that are not visiting files).  By the time
 236 ;; the functions on the first of these hooks to be run are run, the new major
 237 ;; mode is assumed to be in place.  This way we get a Font Lock function run
 238 ;; when a major mode is turned on, without knowing major modes or their hooks.
 239 ;;
 240 ;; Naturally this requires that (a) major modes run `kill-all-local-variables',
 241 ;; as they are supposed to do, and (b) the major mode is in place after the
 242 ;; file is visited or the command that ran `kill-all-local-variables' has
 243 ;; finished, whichever the sooner.  Arguably, any major mode that does not
 244 ;; follow the convension (a) is broken, and I can't think of any reason why (b)
 245 ;; would not be met (except `gnudoit' on non-files).  However, it is not clean.
 246 ;;
 247 ;; Probably the cleanest solution is to have each major mode function run some
 248 ;; hook, e.g., `major-mode-hook', but maybe implementing that change is
 249 ;; impractical.  I am personally against making `setq' a macro or be advised,
 250 ;; or have a special function such as `set-major-mode', but maybe someone can
 251 ;; come up with another solution?
 252
 253 ;; User interface.
 254 ;;
 255 ;; Although Global Font Lock mode is a pseudo-mode, I think that the user
 256 ;; interface should conform to the usual Emacs convention for modes, i.e., a
 257 ;; command to toggle the feature (`global-font-lock-mode') with a variable for
 258 ;; finer control of the mode's behaviour (`font-lock-global-modes').
 259 ;;
 260 ;; The feature should not be enabled by loading font-lock.el, since other
 261 ;; mechanisms for turning on Font Lock mode, such as M-x font-lock-mode RET or
 262 ;; (add-hook 'c-mode-hook 'turn-on-font-lock), would cause Font Lock mode to be
 263 ;; turned on everywhere.  That would not be intuitive or informative because
 264 ;; loading a file tells you nothing about the feature or how to control it.  It
 265 ;; would also be contrary to the Principle of Least Surprise.  sm.
 266
 267 (defcustom font-lock-global-modes t
 268   "*Modes for which Font Lock mode is automagically turned on.
 269 Global Font Lock mode is controlled by the command `global-font-lock-mode'.
 270 If nil, means no modes have Font Lock mode automatically turned on.
 271 If t, all modes that support Font Lock mode have it automatically turned on.
 272 If a list, it should be a list of `major-mode' symbol names for which Font Lock
 273 mode should be automatically turned on.  The sense of the list is negated if it
 274 begins with `not'.  For example:
 275  (c-mode c++-mode)
 276 means that Font Lock mode is turned on for buffers in C and C++ modes only."
 277   :type '(choice (const :tag "none" nil)
 278                  (const :tag "all" t)
 279                  (set :menu-tag "mode specific" :tag "modes"
 280                       :value (not)
 281                       (const :tag "Except" not)
 282                       (repeat :inline t (symbol :tag "mode"))))
 283   :group 'font-lock)
 284
 285 (defun turn-on-font-lock-if-enabled ()
 286   (unless (and (eq (car-safe font-lock-global-modes) 'not)
 287                (memq major-mode (cdr font-lock-global-modes)))
 288     (let (inhibit-quit)
 289       (turn-on-font-lock))))
 290
 291 (easy-mmode-define-global-mode
 292  global-font-lock-mode font-lock-mode turn-on-font-lock-if-enabled
 293  :extra-args (dummy))
 294
 295 ;;; End of Global Font Lock mode.
 296
 297 (provide 'font-core)
 298
 299 ;; arch-tag: f8c286e1-02f7-41d9-b89b-1b67780aed71
 300 ;;; font-core.el ends here