lisp/textmodes/tex-mode.el

   1 ;;; tex-mode.el --- TeX, LaTeX, and SliTeX mode commands.
   2
   3 ;; Copyright (C) 1985, 1986, 1989, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: tex
   7
   8 ;; Contributions over the years by William F. Schelter, Dick King,
   9 ;; Stephen Gildea, Michael Prange, and Jacob Gore.
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  26
  27 ;;; Code:
  28
  29 (require 'comint)
  30 (require 'compile)
  31
  32 ;;;###autoload
  33 (defvar tex-shell-file-name nil
  34   "*If non-nil, is file name to use for the subshell in which TeX is run.")
  35
  36 ;;;###autoload
  37 (defvar tex-directory "."
  38   "*Directory in which temporary files are left.
  39 You can make this /tmp if your TEXINPUTS has no relative directories in it
  40 and you don't try to apply \\[tex-region] or \\[tex-buffer] when there are
  41 \\input commands with relative directories.")
  42
  43 ;;;###autoload
  44 (defvar tex-offer-save t
  45   "*If non-nil, ask about saving modified buffers before \\[tex-file] is run.")
  46
  47 ;;;###autoload
  48 (defvar tex-run-command "tex"
  49   "*Command used to run TeX subjob.
  50 If this string contains an asterisk (*), it will be replaced by the
  51 filename; if not, the name of the file, preceded by blank, will be added to
  52 this string.")
  53
  54 ;;;###autoload
  55 (defvar latex-run-command "latex"
  56   "*Command used to run LaTeX subjob.
  57 If this string contains an asterisk (*), it will be replaced by the
  58 filename; if not, the name of the file, preceded by blank, will be added to
  59 this string.")
  60
  61 (defvar standard-latex-block-names
  62       '("abstract"         "array"            "center"       "description"
  63         "displaymath"      "document"         "enumerate"    "eqnarray"
  64         "eqnarray*"        "equation"         "figure"       "figure*"
  65         "flushleft"        "flushright"       "itemize"      "letter"
  66         "list"             "minipage"         "picture"      "quotation"
  67         "quote"            "slide"            "sloppypar"     "tabbing"
  68         "table"            "table*"           "tabular"       "tabular*"
  69         "thebibliography"  "theindex*"        "titlepage"     "trivlist"
  70         "verbatim"         "verbatim*"        "verse")
  71   "Standard LaTeX block names.")
  72
  73 ;;;###autoload
  74 (defvar latex-block-names nil
  75   "*User defined LaTeX block names.
  76 Combined with `standard-latex-block-names' for minibuffer completion.")
  77
  78 ;;;###autoload
  79 (defvar slitex-run-command "slitex"
  80   "*Command used to run SliTeX subjob.
  81 If this string contains an asterisk (*), it will be replaced by the
  82 filename; if not, the name of the file, preceded by blank, will be added to
  83 this string.")
  84
  85 ;;;###autoload
  86 (defvar tex-bibtex-command "bibtex"
  87   "*Command used by `tex-bibtex-file' to gather bibliographic data.
  88 If this string contains an asterisk (*), it will be replaced by the
  89 filename; if not, the name of the file, preceded by blank, will be added to
  90 this string.")
  91
  92 ;;;###autoload
  93 (defvar tex-dvi-print-command "lpr -d"
  94   "*Command used by \\[tex-print] to print a .dvi file.
  95 If this string contains an asterisk (*), it will be replaced by the
  96 filename; if not, the name of the file, preceded by blank, will be added to
  97 this string.")
  98
  99 ;;;###autoload
 100 (defvar tex-alt-dvi-print-command "lpr -d"
 101   "*Command used by \\[tex-print] with a prefix arg to print a .dvi file.
 102 If this string contains an asterisk (*), it will be replaced by the
 103 filename; if not, the name of the file, preceded by blank, will be added to
 104 this string.
 105
 106 If two printers are not enough of a choice, you can define the value
 107 of tex-alt-dvi-print-command to be an expression that asks what you want;
 108 for example,
 109
 110     (setq tex-alt-dvi-print-command
 111          '(format \"lpr -P%s\" (read-string \"Use printer: \")))
 112
 113 would tell \\[tex-print] with a prefix argument to ask you which printer to
 114 use.")
 115
 116 ;;;###autoload
 117 (defvar tex-dvi-view-command nil
 118   "*Command used by \\[tex-view] to display a .dvi file.
 119 If this string contains an asterisk (*), it will be replaced by the
 120 filename; if not, the name of the file, preceded by blank, will be added to
 121 this string.
 122
 123 This can be set conditionally so that the previewer used is suitable for the
 124 window system being used.  For example,
 125
 126     (setq tex-dvi-view-command
 127           (if (eq window-system 'x) \"xdvi\" \"dvi2tty * | cat -s\"))
 128
 129 would tell \\[tex-view] use xdvi under X windows and to use dvi2tty
 130 otherwise.")
 131
 132 ;;;###autoload
 133 (defvar tex-show-queue-command "lpq"
 134   "*Command used by \\[tex-show-print-queue] to show the print queue.
 135 Should show the queue(s) that \\[tex-print] puts jobs on.")
 136
 137 ;;;###autoload
 138 (defvar tex-default-mode 'plain-tex-mode
 139   "*Mode to enter for a new file that might be either TeX or LaTeX.
 140 This variable is used when it can't be determined whether the file
 141 is plain TeX or LaTeX or what because the file contains no commands.
 142 Normally set to either 'plain-tex-mode or 'latex-mode.")
 143
 144 ;;;###autoload
 145 (defvar tex-open-quote "``"
 146   "*String inserted by typing \\[tex-insert-quote] to open a quotation.")
 147
 148 ;;;###autoload
 149 (defvar tex-close-quote "''"
 150   "*String inserted by typing \\[tex-insert-quote] to close a quotation.")
 151
 152 (defvar tex-last-temp-file nil
 153   "Latest temporary file generated by \\[tex-region] and \\[tex-buffer].
 154 Deleted when the \\[tex-region] or \\[tex-buffer] is next run, or when the
 155 tex-shell goes away.")
 156
 157 (defvar tex-command nil
 158   "Command to run TeX.
 159 The name of the file, preceded by a blank, will be added to this string.")
 160
 161 (defvar tex-trailer nil
 162   "String appended after the end of a region sent to TeX by \\[tex-region].")
 163
 164 (defvar tex-start-of-header nil
 165   "String used by \\[tex-region] to delimit the start of the file's header.")
 166
 167 (defvar tex-end-of-header nil
 168   "String used by \\[tex-region] to delimit the end of the file's header.")
 169
 170 (defvar tex-shell-cd-command "cd"
 171   "Command to give to shell running TeX to change directory.
 172 The value of tex-directory will be appended to this, separated by a space.")
 173
 174 (defvar tex-zap-file nil
 175   "Temporary file name used for text being sent as input to TeX.
 176 Should be a simple file name with no extension or directory specification.")
 177
 178 (defvar tex-last-buffer-texed nil
 179   "Buffer which was last TeXed.")
 180
 181 (defvar tex-print-file nil
 182   "File name that \\[tex-print] prints.
 183 Set by \\[tex-region], \\[tex-buffer], and \\[tex-file].")
 184
 185 (defvar tex-mode-syntax-table nil
 186   "Syntax table used while in TeX mode.")
 187
 188 (defun tex-define-common-keys (keymap)
 189   "Define the keys that we want defined both in TeX mode and in the tex-shell."
 190   (define-key keymap "\C-c\C-k" 'tex-kill-job)
 191   (define-key keymap "\C-c\C-l" 'tex-recenter-output-buffer)
 192   (define-key keymap "\C-c\C-q" 'tex-show-print-queue)
 193   (define-key keymap "\C-c\C-p" 'tex-print)
 194   (define-key keymap "\C-c\C-v" 'tex-view)
 195   )
 196
 197 (defvar tex-mode-map nil "Keymap for TeX mode.")
 198
 199 (if tex-mode-map
 200     nil
 201   (setq tex-mode-map (make-sparse-keymap))
 202   (tex-define-common-keys tex-mode-map)
 203   (define-key tex-mode-map "\"" 'tex-insert-quote)
 204   (define-key tex-mode-map "\n" 'tex-terminate-paragraph)
 205   (define-key tex-mode-map "\C-c}" 'up-list)
 206   (define-key tex-mode-map "\C-c{" 'tex-insert-braces)
 207   (define-key tex-mode-map "\C-c\C-r" 'tex-region)
 208   (define-key tex-mode-map "\C-c\C-b" 'tex-buffer)
 209   (define-key tex-mode-map "\C-c\C-f" 'tex-file)
 210   (define-key tex-mode-map "\C-c\C-i" 'tex-bibtex-file)
 211   (define-key tex-mode-map "\C-c\C-o" 'tex-latex-block)
 212   (define-key tex-mode-map "\C-c\C-e" 'tex-close-latex-block))
 213
 214 (defvar tex-shell-map nil
 215   "Keymap for the tex-shell.  A comint-mode-map with a few additions.")
 216
 217 ;(defalias 'TeX-mode 'tex-mode)                 ;in loaddefs.
 218
 219 (defvar compare-windows-whitespace nil) ; Pacify the byte-compiler
 220
 221 ;;; This would be a lot simpler if we just used a regexp search,
 222 ;;; but then it would be too slow.
 223 ;;;###autoload
 224 (defun tex-mode ()
 225   "Major mode for editing files of input for TeX, LaTeX, or SliTeX.
 226 Tries to determine (by looking at the beginning of the file) whether
 227 this file is for plain TeX, LaTeX, or SliTeX and calls plain-tex-mode,
 228 latex-mode, or slitex-mode, respectively.  If it cannot be determined,
 229 such as if there are no commands in the file, the value of tex-default-mode
 230 is used."
 231   (interactive)
 232   (let (mode slash comment)
 233     (save-excursion
 234       (goto-char (point-min))
 235       (while (and (setq slash (search-forward "\\" nil t))
 236                   (setq comment (let ((search-end (point)))
 237                                   (save-excursion
 238                                     (beginning-of-line)
 239                                     (search-forward "%" search-end t))))))
 240       (if (and slash (not comment))
 241           (setq mode (if (looking-at "documentstyle")
 242                          (if (looking-at "documentstyle{slides}")
 243                              'slitex-mode
 244                            'latex-mode)
 245                        'plain-tex-mode))))
 246     (if mode (funcall mode)
 247       (funcall tex-default-mode))))
 248 ;;;###autoload
 249 (defalias 'TeX-mode 'tex-mode)
 250 ;;;###autoload
 251 (defalias 'LaTeX-mode 'latex-mode)
 252
 253 ;;;###autoload
 254 (defun plain-tex-mode ()
 255   "Major mode for editing files of input for plain TeX.
 256 Makes $ and } display the characters they match.
 257 Makes \" insert `` when it seems to be the beginning of a quotation,
 258 and '' when it appears to be the end; it inserts \" only after a \\.
 259
 260 Use \\[tex-region] to run TeX on the current region, plus a \"header\"
 261 copied from the top of the file (containing macro definitions, etc.),
 262 running TeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 263 \\[tex-file] saves the buffer and then processes the file.
 264 \\[tex-print] prints the .dvi file made by any of these.
 265 \\[tex-view] previews the .dvi file made by any of these.
 266 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 267
 268 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 269 mismatched $'s or braces.
 270
 271 Special commands:
 272 \\{tex-mode-map}
 273
 274 Mode variables:
 275 tex-run-command
 276         Command string used by \\[tex-region] or \\[tex-buffer].
 277 tex-directory
 278         Directory in which to create temporary files for TeX jobs
 279         run by \\[tex-region] or \\[tex-buffer].
 280 tex-dvi-print-command
 281         Command string used by \\[tex-print] to print a .dvi file.
 282 tex-alt-dvi-print-command
 283         Alternative command string used by \\[tex-print] (when given a prefix
 284         argument) to print a .dvi file.
 285 tex-dvi-view-command
 286         Command string used by \\[tex-view] to preview a .dvi file.
 287 tex-show-queue-command
 288         Command string used by \\[tex-show-print-queue] to show the print
 289         queue that \\[tex-print] put your job on.
 290
 291 Entering Plain-tex mode calls the value of `text-mode-hook', then the value
 292 of `tex-mode-hook', and then the value of `plain-tex-mode-hook'.  When the
 293 special subshell is initiated, the value of `tex-shell-hook' is called."
 294
 295   (interactive)
 296   (tex-common-initialization)
 297   (setq mode-name "TeX")
 298   (setq major-mode 'plain-tex-mode)
 299   (setq tex-command tex-run-command)
 300   (setq tex-start-of-header "%**start of header")
 301   (setq tex-end-of-header "%**end of header")
 302   (setq tex-trailer "\\bye\n")
 303   (run-hooks 'text-mode-hook 'tex-mode-hook 'plain-tex-mode-hook))
 304 ;;;###autoload
 305 (defalias 'plain-TeX-mode 'plain-tex-mode)
 306
 307 ;;;###autoload
 308 (defun latex-mode ()
 309   "Major mode for editing files of input for LaTeX.
 310 Makes $ and } display the characters they match.
 311 Makes \" insert `` when it seems to be the beginning of a quotation,
 312 and '' when it appears to be the end; it inserts \" only after a \\.
 313
 314 Use \\[tex-region] to run LaTeX on the current region, plus the preamble
 315 copied from the top of the file (containing \\documentstyle, etc.),
 316 running LaTeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 317 \\[tex-file] saves the buffer and then processes the file.
 318 \\[tex-print] prints the .dvi file made by any of these.
 319 \\[tex-view] previews the .dvi file made by any of these.
 320 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 321
 322 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 323 mismatched $'s or braces.
 324
 325 Special commands:
 326 \\{tex-mode-map}
 327
 328 Mode variables:
 329 latex-run-command
 330         Command string used by \\[tex-region] or \\[tex-buffer].
 331 tex-directory
 332         Directory in which to create temporary files for LaTeX jobs
 333         run by \\[tex-region] or \\[tex-buffer].
 334 tex-dvi-print-command
 335         Command string used by \\[tex-print] to print a .dvi file.
 336 tex-alt-dvi-print-command
 337         Alternative command string used by \\[tex-print] (when given a prefix
 338         argument) to print a .dvi file.
 339 tex-dvi-view-command
 340         Command string used by \\[tex-view] to preview a .dvi file.
 341 tex-show-queue-command
 342         Command string used by \\[tex-show-print-queue] to show the print
 343         queue that \\[tex-print] put your job on.
 344
 345 Entering Latex mode calls the value of text-mode-hook, then the value of
 346 tex-mode-hook, and then the value of latex-mode-hook.  When the special
 347 subshell is initiated, the value of tex-shell-hook is called."
 348   (interactive)
 349   (tex-common-initialization)
 350   (setq mode-name "LaTeX")
 351   (setq major-mode 'latex-mode)
 352   (setq tex-command latex-run-command)
 353   (setq tex-start-of-header "\\documentstyle")
 354   (setq tex-end-of-header "\\begin{document}")
 355   (setq tex-trailer "\\end{document}\n")
 356   (run-hooks 'text-mode-hook 'tex-mode-hook 'latex-mode-hook))
 357
 358 (defun slitex-mode ()
 359   "Major mode for editing files of input for SliTeX.
 360 Makes $ and } display the characters they match.
 361 Makes \" insert `` when it seems to be the beginning of a quotation,
 362 and '' when it appears to be the end; it inserts \" only after a \\.
 363
 364 Use \\[tex-region] to run SliTeX on the current region, plus the preamble
 365 copied from the top of the file (containing \\documentstyle, etc.),
 366 running SliTeX under a special subshell.  \\[tex-buffer] does the whole buffer.
 367 \\[tex-file] saves the buffer and then processes the file.
 368 \\[tex-print] prints the .dvi file made by any of these.
 369 \\[tex-view] previews the .dvi file made by any of these.
 370 \\[tex-bibtex-file] runs bibtex on the file of the current buffer.
 371
 372 Use \\[validate-tex-buffer] to check buffer for paragraphs containing
 373 mismatched $'s or braces.
 374
 375 Special commands:
 376 \\{tex-mode-map}
 377
 378 Mode variables:
 379 slitex-run-command
 380         Command string used by \\[tex-region] or \\[tex-buffer].
 381 tex-directory
 382         Directory in which to create temporary files for SliTeX jobs
 383         run by \\[tex-region] or \\[tex-buffer].
 384 tex-dvi-print-command
 385         Command string used by \\[tex-print] to print a .dvi file.
 386 tex-alt-dvi-print-command
 387         Alternative command string used by \\[tex-print] (when given a prefix
 388         argument) to print a .dvi file.
 389 tex-dvi-view-command
 390         Command string used by \\[tex-view] to preview a .dvi file.
 391 tex-show-queue-command
 392         Command string used by \\[tex-show-print-queue] to show the print
 393         queue that \\[tex-print] put your job on.
 394
 395 Entering SliTeX mode calls the value of `text-mode-hook', then the value of
 396 `tex-mode-hook', then the value of `latex-mode-hook', and then the value of
 397 `slitex-mode-hook'.  When the special subshell is initiated, the value of
 398 `tex-shell-hook' is called."
 399   (interactive)
 400   (tex-common-initialization)
 401   (setq mode-name "SliTeX")
 402   (setq major-mode 'slitex-mode)
 403   (setq tex-command slitex-run-command)
 404   (setq tex-start-of-header "\\documentstyle{slides}")
 405   (setq tex-end-of-header "\\begin{document}")
 406   (setq tex-trailer "\\end{document}\n")
 407   (run-hooks
 408    'text-mode-hook 'tex-mode-hook 'latex-mode-hook 'slitex-mode-hook))
 409
 410 (defun tex-common-initialization ()
 411   (kill-all-local-variables)
 412   (use-local-map tex-mode-map)
 413   (setq local-abbrev-table text-mode-abbrev-table)
 414   (if (null tex-mode-syntax-table)
 415       (let ((char 0))
 416         (setq tex-mode-syntax-table (make-syntax-table))
 417         (set-syntax-table tex-mode-syntax-table)
 418         (while (< char ? )
 419           (modify-syntax-entry char ".")
 420           (setq char (1+ char)))
 421         (modify-syntax-entry ?\C-@ "w")
 422         (modify-syntax-entry ?\t " ")
 423         (modify-syntax-entry ?\n ">")
 424         (modify-syntax-entry ?\f ">")
 425         (modify-syntax-entry ?$ "$$")
 426         (modify-syntax-entry ?% "<")
 427         (modify-syntax-entry ?\\ "/")
 428         (modify-syntax-entry ?\" ".")
 429         (modify-syntax-entry ?& ".")
 430         (modify-syntax-entry ?_ ".")
 431         (modify-syntax-entry ?@ "_")
 432         (modify-syntax-entry ?~ " ")
 433         (modify-syntax-entry ?' "w"))
 434     (set-syntax-table tex-mode-syntax-table))
 435   (make-local-variable 'paragraph-start)
 436   (setq paragraph-start "^[ \t]*$\\|^[\f\\\\%]")
 437   (make-local-variable 'paragraph-separate)
 438   (setq paragraph-separate paragraph-start)
 439   (make-local-variable 'comment-start)
 440   (setq comment-start "%")
 441   (make-local-variable 'comment-start-skip)
 442   (setq comment-start-skip "\\(\\(^\\|[^\\]\\)\\(\\\\\\\\\\)*\\)\\(%+ *\\)")
 443   (make-local-variable 'comment-indent-function)
 444   (setq comment-indent-function 'tex-comment-indent)
 445   (make-local-variable 'compare-windows-whitespace)
 446   (setq compare-windows-whitespace 'tex-categorize-whitespace)
 447   (make-local-variable 'tex-command)
 448   (make-local-variable 'tex-start-of-header)
 449   (make-local-variable 'tex-end-of-header)
 450   (make-local-variable 'tex-trailer))
 451
 452 (defun tex-comment-indent ()
 453   (if (looking-at "%%%")
 454       (current-column)
 455     (skip-chars-backward " \t")
 456     (max (if (bolp) 0 (1+ (current-column)))
 457          comment-column)))
 458
 459 (defun tex-categorize-whitespace (backward-limit)
 460   ;; compare-windows-whitespace is set to this.
 461   ;; This is basically a finite-state machine.
 462   ;; Returns a symbol telling how TeX would treat
 463   ;; the whitespace we are looking at: null, space, or par.
 464   (let ((category 'null)
 465         (not-finished t))
 466     (skip-chars-backward " \t\n\f" backward-limit)
 467     (while not-finished
 468       (cond ((looking-at "[ \t]+")
 469              (goto-char (match-end 0))
 470              (if (eql category 'null)
 471                  (setq category 'space)))
 472             ((looking-at "\n")
 473              (cond ((eql category 'newline)
 474                     (setq category 'par)
 475                     (setq not-finished nil))
 476                    (t
 477                     (setq category 'newline) ;a strictly internal state
 478                     (goto-char (match-end 0)))))
 479             ((looking-at "\f+")
 480              (setq category 'par)
 481              (setq not-finished nil))
 482             (t
 483              (setq not-finished nil))))
 484     (skip-chars-forward " \t\n\f")
 485     (if (eql category 'newline)
 486         'space                          ;TeX doesn't distinguish
 487       category)))
 488
 489 (defun tex-insert-quote (arg)
 490   "Insert the appropriate quote marks for TeX.
 491 Inserts the value of tex-open-quote (normally ``) or tex-close-quote
 492 (normally '') depending on the context.  With prefix argument, always
 493 inserts \" characters."
 494   (interactive "*P")
 495   (if arg
 496       (self-insert-command (prefix-numeric-value arg))
 497     (insert
 498      (cond ((or (bobp)
 499                 (save-excursion
 500                   (forward-char -1)
 501                   (looking-at "\\s(\\|\\s \\|\\s>")))
 502             tex-open-quote)
 503            ((= (preceding-char) ?\\)
 504             ?\")
 505            (t
 506             tex-close-quote)))))
 507
 508 (defun validate-tex-buffer ()
 509   "Check current buffer for paragraphs containing mismatched $s.
 510 As each such paragraph is found, a mark is pushed at its beginning,
 511 and the location is displayed for a few seconds."
 512   (interactive)
 513   (let ((opoint (point)))
 514     (goto-char (point-max))
 515     ;; Does not use save-excursion
 516     ;; because we do not want to save the mark.
 517     (unwind-protect
 518         (while (and (not (input-pending-p)) (not (bobp)))
 519           (let ((end (point)))
 520             (search-backward "\n\n" nil 'move)
 521             (or (tex-validate-region (point) end)
 522                 (progn
 523                   (push-mark (point))
 524                   (message "Mismatch found in pararaph starting here")
 525                   (sit-for 4)))))
 526       (goto-char opoint))))
 527
 528 (defun tex-validate-region (start end)
 529   "Check for mismatched braces or $'s in region.
 530 Returns t if no mismatches.  Returns nil and moves point to suspect
 531 area if a mismatch is found."
 532   (interactive "r")
 533   (let ((failure-point nil) (max-possible-sexps (- end start)))
 534     (save-excursion
 535       (condition-case ()
 536           (save-restriction
 537             (narrow-to-region start end)
 538             (goto-char start)
 539             (while (< 0 (setq max-possible-sexps (1- max-possible-sexps)))
 540               (forward-sexp 1)))
 541         (error
 542           (setq failure-point (point)))))
 543     (if failure-point
 544         (progn
 545           (goto-char failure-point)
 546           nil)
 547       t)))
 548
 549 (defun tex-terminate-paragraph (inhibit-validation)
 550   "Insert two newlines, breaking a paragraph for TeX.
 551 Check for mismatched braces/$'s in paragraph being terminated.
 552 A prefix arg inhibits the checking."
 553   (interactive "*P")
 554   (or inhibit-validation
 555       (save-excursion
 556         (tex-validate-region
 557           (save-excursion
 558             (search-backward "\n\n" nil 'move)
 559             (point))
 560           (point)))
 561       (message "Paragraph being closed appears to contain a mismatch"))
 562   (insert "\n\n"))
 563
 564 (defun tex-insert-braces ()
 565   "Make a pair of braces and be poised to type inside of them."
 566   (interactive "*")
 567   (insert ?\{)
 568   (save-excursion
 569     (insert ?})))
 570
 571 ;;; Like tex-insert-braces, but for LaTeX.
 572 (defun tex-latex-block (name)
 573   "Creates a matching pair of lines \\begin{NAME} and \\end{NAME} at point.
 574 Puts point on a blank line between them."
 575   (interactive
 576    (prog2
 577       (barf-if-buffer-read-only)
 578       (list
 579        (completing-read "LaTeX block name: "
 580                         (mapcar 'list
 581                                 (append standard-latex-block-names
 582                                         latex-block-names))))))
 583   (let ((col (current-column)))
 584     (insert (format "\\begin{%s}\n" name))
 585     (indent-to col)
 586     (save-excursion
 587       (insert ?\n)
 588       (indent-to col)
 589       (insert-string (format "\\end{%s}" name))
 590       (if (eobp) (insert ?\n)))))
 591
 592 (defun tex-last-unended-begin ()
 593   "Leave point at the beginning of the last \\begin{...} that is unended."
 594   (while (and (re-search-backward "\\(\\\\begin\\s *{\\)\\|\\(\\\\end\\s *{\\)")
 595               (looking-at "\\\\end{"))
 596     (tex-last-unended-begin)))
 597
 598 (defun tex-close-latex-block ()
 599   "Creates an \\end{...} to match the last unclosed \\begin{...}."
 600   (interactive "*")
 601   (let ((new-line-needed (bolp))
 602         text indentation)
 603     (save-excursion
 604       (condition-case nil
 605           (tex-last-unended-begin)
 606         (error (error "Couldn't find unended \\begin")))
 607       (setq indentation (current-column))
 608       (re-search-forward "\\\\begin\\(\\s *{[^}\n]*}\\)")
 609       (setq text (buffer-substring (match-beginning 1) (match-end 1))))
 610     (indent-to indentation)
 611     (insert "\\end" text)
 612     (if new-line-needed (insert ?\n))))
 613 \f
 614 (defun tex-compilation-parse-errors ()
 615   "Parse the current buffer as error messages.
 616 This makes a list of error descriptors, compilation-error-list.
 617 For each source-file, line-number pair in the buffer,
 618 the source file is read in, and the text location is saved in
 619 compilation-error-list.  The function `next-error', assigned to
 620 \\[next-error], takes the next error off the list and visits its location.
 621
 622 This function works on TeX compilations only.  It is necessary for
 623 that purpose, since TeX does not put file names on the same line as
 624 line numbers for the errors."
 625   (setq compilation-error-list nil)
 626   (message "Parsing error messages...")
 627   (modify-syntax-entry ?\{ "_")
 628   (modify-syntax-entry ?\} "_")
 629   (modify-syntax-entry ?\[ "_")
 630   (modify-syntax-entry ?\] "_")
 631   (let (text-buffer
 632         last-filename last-linenum)
 633     ;; Don't reparse messages already seen at last parse.
 634     (goto-char compilation-parsing-end)
 635     ;; Don't parse the first two lines as error messages.
 636     ;; This matters for grep.
 637     (if (bobp)
 638         (forward-line 2))
 639     (while (re-search-forward "^l\.[0-9]+ " nil t)
 640       (let (linenum filename
 641             error-marker text-marker)
 642         ;; Extract file name and line number from error message.
 643         ;; Line number is 2 away from beginning of line: "l.23"
 644         (beginning-of-line)
 645         (goto-char (+ (point) 2))
 646         (setq linenum (read (current-buffer)))
 647         ;; The file is the one that was opened last and is still open.
 648         ;; We need to find the last open parenthesis.
 649         (insert ?\))
 650         (backward-sexp)
 651         (forward-char)
 652         (setq filename (current-word))
 653         ;; Locate the erring file and line.
 654         (if (and (equal filename last-filename)
 655                  (= linenum last-linenum))
 656             nil
 657           (skip-chars-backward "^(")
 658           (backward-char)
 659           (forward-sexp)
 660           (backward-delete-char 1)
 661           (setq error-marker (point-marker))
 662           ;; text-buffer gets the buffer containing this error's file.
 663           (if (not (equal filename last-filename))
 664               (setq text-buffer
 665                     (and (file-exists-p (setq last-filename filename))
 666                          (find-file-noselect filename))
 667                     last-linenum 0))
 668           (if text-buffer
 669               ;; Go to that buffer and find the erring line.
 670               (save-excursion
 671                 (set-buffer text-buffer)
 672                 (if (zerop last-linenum)
 673                     (progn
 674                       (goto-char 1)
 675                       (setq last-linenum 1)))
 676                 (forward-line (- linenum last-linenum))
 677                 (setq last-linenum linenum)
 678                 (setq text-marker (point-marker))
 679                 (setq compilation-error-list
 680                       (cons (list error-marker text-marker)
 681                             compilation-error-list)))))
 682         (forward-line 1)))
 683     (setq compilation-parsing-end (point-max)))
 684   (message "Parsing error messages...done")
 685   (setq compilation-error-list (nreverse compilation-error-list)))
 686 \f
 687 ;;; Invoking TeX in an inferior shell.
 688
 689 ;;; Why use a shell instead of running TeX directly?  Because if TeX
 690 ;;; gets stuck, the user can switch to the shell window and type at it.
 691
 692 ;;; The utility functions:
 693
 694 (defun tex-start-shell ()
 695   (save-excursion
 696     (set-buffer
 697      (make-comint
 698       "tex-shell"
 699       (or tex-shell-file-name (getenv "ESHELL") (getenv "SHELL") "/bin/sh")
 700       nil "-v"))
 701     (let ((proc (get-process "tex-shell")))
 702       (set-process-sentinel proc 'tex-shell-sentinel)
 703       (process-kill-without-query proc)
 704       (setq tex-shell-map (copy-keymap comint-mode-map))
 705       (tex-define-common-keys tex-shell-map)
 706       (use-local-map tex-shell-map)
 707       (run-hooks 'tex-shell-hook)
 708       (while (zerop (buffer-size))
 709           (sleep-for 1)))))
 710
 711 (defun tex-shell-sentinel (proc msg)
 712   (cond ((null (buffer-name (process-buffer proc)))
 713          ;; buffer killed
 714          (set-process-buffer proc nil)
 715          (tex-delete-last-temp-files))
 716         ((memq (process-status proc) '(signal exit))
 717          (tex-delete-last-temp-files))))
 718
 719 (defun tex-set-buffer-directory (buffer directory)
 720   "Set BUFFER's default directory to be DIRECTORY."
 721   (setq directory (file-name-as-directory (expand-file-name directory)))
 722   (if (not (file-directory-p directory))
 723       (error "%s is not a directory" directory)
 724     (save-excursion
 725       (set-buffer buffer)
 726       (setq default-directory directory))))
 727
 728 (defun tex-send-command (command &optional file background)
 729   "Send COMMAND to tex-shell, substituting optional FILE for *.
 730 Do this in background if optional BACKGROUND is t.  If COMMAND has no *,
 731 FILE will be appended, preceded by a blank, to COMMAND.  If FILE is nil, no
 732 substitution will be made in COMMAND.  COMMAND can be any expression that
 733 evaluates to a command string."
 734   (save-excursion
 735     (let* ((cmd (eval command))
 736            (star (string-match "\\*" cmd))
 737            (front (substring cmd 0 star))
 738            (back (if star (substring cmd (1+ star)) "")))
 739       (comint-proc-query (get-process "tex-shell")
 740                          (concat
 741                           (if file (if star (concat front file back)
 742                                      (concat cmd " " file))
 743                             cmd)
 744                           (if background "&\n" "\n"))))))
 745
 746 (defun tex-delete-last-temp-files ()
 747   "Delete any junk files from last temp file."
 748   (if tex-last-temp-file
 749       (let* ((dir (file-name-directory tex-last-temp-file))
 750              (list (file-name-all-completions
 751                     (file-name-nondirectory tex-last-temp-file) dir)))
 752         (while list
 753           (delete-file (concat dir (car list)))
 754           (setq list (cdr list))))))
 755
 756 (add-hook 'kill-emacs-hook 'tex-delete-last-temp-files)
 757
 758 ;;; The commands:
 759
 760 (defun tex-region (beg end)
 761   "Run TeX on the current region, via a temporary file.
 762 The file's name comes from the variable `tex-zap-file' and the
 763 variable `tex-directory' says where to put it.
 764
 765 If the buffer has a header, the header is given to TeX before the
 766 region itself.  The buffer's header is all lines between the strings
 767 defined by `tex-start-of-header' and `tex-end-of-header' inclusive.
 768 The header must start in the first 100 lines of the buffer.
 769
 770 The value of `tex-trailer' is given to TeX as input after the region.
 771
 772 The value of `tex-command' specifies the command to use to run TeX."
 773   (interactive "r")
 774   (if (tex-shell-running)
 775       (tex-kill-job)
 776     (tex-start-shell))
 777   (or tex-zap-file
 778       (setq tex-zap-file (tex-generate-zap-file-name)))
 779   (let* ((temp-buffer (get-buffer-create " TeX-Output-Buffer"))
 780          ; Temp file will be written and TeX will be run in zap-directory.
 781          ; If the TEXINPUTS file has relative directories or if the region has
 782          ; \input of files, this must be the same directory as the file for
 783          ; TeX to access the correct inputs.  That's why it's safest if
 784          ; tex-directory is ".".
 785          (zap-directory
 786           (file-name-as-directory (expand-file-name tex-directory)))
 787          (tex-out-file (concat zap-directory tex-zap-file)))
 788     (tex-delete-last-temp-files)
 789     ;; Write the new temp file.
 790     (save-excursion
 791       (save-restriction
 792         (widen)
 793         (goto-char (point-min))
 794         (forward-line 100)
 795         (let ((search-end (point))
 796               (hbeg (point-min)) (hend (point-min))
 797               (default-directory zap-directory))
 798           (goto-char (point-min))
 799           ;; Initialize the temp file with either the header or nothing
 800           (if (search-forward tex-start-of-header search-end t)
 801               (progn
 802                 (beginning-of-line)
 803                 (setq hbeg (point))     ;mark beginning of header
 804                 (if (search-forward tex-end-of-header nil t)
 805                     (progn (forward-line 1)
 806                            (setq hend (point))) ;mark end of header
 807                   (setq hbeg (point-min))))) ;no header
 808           (write-region (min hbeg beg) hend
 809                         (concat tex-out-file ".tex") nil nil)
 810           (write-region (max beg hend) end (concat tex-out-file ".tex") t nil))
 811         (let ((local-tex-trailer tex-trailer))
 812           (set-buffer temp-buffer)
 813           (erase-buffer)
 814           ;; make sure trailer isn't hidden by a comment
 815           (insert-string "\n")
 816           (if local-tex-trailer (insert-string local-tex-trailer))
 817           (tex-set-buffer-directory temp-buffer zap-directory)
 818           (write-region (point-min) (point-max)
 819                         (concat tex-out-file ".tex") t nil))))
 820     ;; Record the file name to be deleted afterward.
 821     (setq tex-last-temp-file tex-out-file)
 822     (tex-send-command tex-shell-cd-command zap-directory)
 823     (tex-send-command tex-command tex-out-file)
 824     (setq tex-print-file tex-out-file)
 825     (setq tex-last-buffer-texed (current-buffer))))
 826
 827 (defun tex-buffer ()
 828   "Run TeX on current buffer.  See \\[tex-region] for more information.
 829 Does not save the buffer, so it's useful for trying experimental versions.
 830 See \\[tex-file] for an alternative."
 831   (interactive)
 832   (tex-region (point-min) (point-max)))
 833
 834 (defun tex-file ()
 835   "Prompt to save all buffers and run TeX (or LaTeX) on current buffer's file.
 836 This function is more useful than \\[tex-buffer] when you need the
 837 `.aux' file of LaTeX to have the correct name."
 838   (interactive)
 839   (let ((tex-out-file
 840          (if (buffer-file-name)
 841              (file-name-nondirectory (buffer-file-name))
 842            (error "Buffer does not seem to be associated with any file")))
 843         (file-dir (file-name-directory (buffer-file-name))))
 844     (if tex-offer-save
 845         (save-some-buffers))
 846     (if (tex-shell-running)
 847         (tex-kill-job)
 848       (tex-start-shell))
 849     (tex-send-command tex-shell-cd-command file-dir)
 850     (tex-send-command tex-command tex-out-file))
 851   (setq tex-last-buffer-texed (current-buffer))
 852   (setq tex-print-file (buffer-file-name)))
 853
 854 (defun tex-generate-zap-file-name ()
 855   "Generate a unique name suitable for use as a file name."
 856   ;; Include the shell process number and host name
 857   ;; in case there are multiple shells (for same or different user).
 858   (format "#tz%d%s"
 859           (process-id (get-buffer-process "*tex-shell*"))
 860           (tex-strip-dots (system-name))))
 861
 862 (defun tex-strip-dots (s)
 863   (setq s (copy-sequence s))
 864   (while (string-match "\\." s)
 865     (aset s (match-beginning 0) ?-))
 866   s)
 867
 868 ;; This will perhaps be useful for modifying TEXINPUTS.
 869 ;; Expand each file name, separated by colons, in the string S.
 870 (defun tex-expand-files (s)
 871   (let (elts (start 0))
 872     (while (string-match ":" s start)
 873       (setq elts (cons (substring s start (match-beginning 0)) elts))
 874       (setq start (match-end 0)))
 875     (or (= start 0)
 876         (setq elts (cons (substring s start) elts)))
 877     (mapconcat 'expand-file-name (nreverse elts) ":")))
 878
 879 (defun tex-shell-running ()
 880   (and (get-process "tex-shell")
 881        (eq (process-status (get-process "tex-shell")) 'run)))
 882
 883 (defun tex-kill-job ()
 884   "Kill the currently running TeX job."
 885   (interactive)
 886   (quit-process (get-process "tex-shell") t))
 887
 888 (defun tex-recenter-output-buffer (linenum)
 889   "Redisplay buffer of TeX job output so that most recent output can be seen.
 890 The last line of the buffer is displayed on
 891 line LINE of the window, or centered if LINE is nil."
 892   (interactive "P")
 893   (let ((tex-shell (get-buffer "*tex-shell*"))
 894         (old-buffer (current-buffer)))
 895     (if (null tex-shell)
 896         (message "No TeX output buffer")
 897       (pop-to-buffer tex-shell)
 898       (bury-buffer tex-shell)
 899       (goto-char (point-max))
 900       (recenter (if linenum
 901                     (prefix-numeric-value linenum)
 902                   (/ (window-height) 2)))
 903       (pop-to-buffer old-buffer))))
 904
 905 (defun tex-print (&optional alt)
 906   "Print the .dvi file made by \\[tex-region], \\[tex-buffer] or \\[tex-file].
 907 Runs the shell command defined by `tex-dvi-print-command'.  If prefix argument
 908 is provided, use the alternative command, `tex-alt-dvi-print-command'."
 909   (interactive "P")
 910   (let ((print-file-name-dvi (tex-append tex-print-file ".dvi"))
 911         test-name)
 912     (if (and (not (equal (current-buffer) tex-last-buffer-texed))
 913              (file-newer-than-file-p
 914               (setq test-name (tex-append (buffer-file-name) ".dvi"))
 915               print-file-name-dvi))
 916         (setq print-file-name-dvi test-name))
 917     (if (not (file-exists-p print-file-name-dvi))
 918         (error "No appropriate `.dvi' file could be found")
 919       (tex-send-command
 920         (if alt tex-alt-dvi-print-command tex-dvi-print-command)
 921         print-file-name-dvi t))))
 922
 923 (defun tex-view ()
 924   "Preview the last `.dvi' file made by running TeX under Emacs.
 925 This means, made using \\[tex-region], \\[tex-buffer] or \\[tex-file].
 926 The variable `tex-dvi-view-command' specifies the shell command for preview."
 927   (interactive)
 928   (let ((tex-dvi-print-command tex-dvi-view-command))
 929     (tex-print)))
 930
 931 (defun tex-append (file-name suffix)
 932   "Append to FILENAME the suffix SUFFIX, using same algorithm TeX uses.
 933 Scans for the first (not last) period.
 934 No period is retained immediately before SUFFIX,
 935 so normally SUFFIX starts with one."
 936   (if (stringp file-name)
 937       (let ((file (file-name-nondirectory file-name)))
 938         (concat (file-name-directory file-name)
 939                 (substring file 0
 940                            (string-match "\\." file))
 941                 suffix))
 942     " "))
 943
 944 (defun tex-show-print-queue ()
 945   "Show the print queue that \\[tex-print] put your job on.
 946 Runs the shell command defined by `tex-show-queue-command'."
 947   (interactive)
 948   (if (tex-shell-running)
 949       (tex-kill-job)
 950     (tex-start-shell))
 951   (tex-send-command tex-show-queue-command))
 952
 953 (defun tex-bibtex-file ()
 954   "Run BibTeX on the current buffer's file."
 955   (interactive)
 956   (if (tex-shell-running)
 957       (tex-kill-job)
 958     (tex-start-shell))
 959   (let ((tex-out-file
 960          (tex-append (file-name-nondirectory (buffer-file-name)) ""))
 961         (file-dir (file-name-directory (buffer-file-name))))
 962     (tex-send-command tex-shell-cd-command file-dir)
 963     (tex-send-command tex-bibtex-command tex-out-file)))
 964
 965 (run-hooks 'tex-mode-load-hook)
 966
 967 (provide 'tex-mode)
 968
 969 ;;; tex-mode.el ends here
 970