lisp/org/org-clock.el

   1 ;;; org-clock.el --- The time clocking code for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.31a
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the time clocking code for Org-mode
  30
  31 (require 'org)
  32 (eval-when-compile
  33   (require 'cl)
  34   (require 'calendar))
  35
  36 (declare-function calendar-absolute-from-iso    "cal-iso"    (&optional date))
  37 (defvar org-time-stamp-formats)
  38
  39 (defgroup org-clock nil
  40   "Options concerning clocking working time in Org-mode."
  41   :tag "Org Clock"
  42   :group 'org-progress)
  43
  44 (defcustom org-clock-into-drawer org-log-into-drawer
  45   "Should clocking info be wrapped into a drawer?
  46 When t, clocking info will always be inserted into a :LOGBOOK: drawer.
  47 If necessary, the drawer will be created.
  48 When nil, the drawer will not be created, but used when present.
  49 When an integer and the number of clocking entries in an item
  50 reaches or exceeds this number, a drawer will be created.
  51 When a string, it names the drawer to be used.
  52
  53 The default for this variable is the value of `org-log-into-drawer',
  54 which see."
  55   :group 'org-todo
  56   :group 'org-clock
  57   :type '(choice
  58           (const :tag "Always" t)
  59           (const :tag "Only when drawer exists" nil)
  60           (integer :tag "When at least N clock entries")
  61           (const :tag "Into LOGBOOK drawer" "LOGBOOK")
  62           (string :tag "Into Drawer named...")))
  63
  64 (defcustom org-clock-out-when-done t
  65   "When non-nil, clock will be stopped when the clocked entry is marked DONE.
  66 A nil value means, clock will keep running until stopped explicitly with
  67 `C-c C-x C-o', or until the clock is started in a different item."
  68   :group 'org-clock
  69   :type 'boolean)
  70
  71 (defcustom org-clock-out-remove-zero-time-clocks nil
  72   "Non-nil means, remove the clock line when the resulting time is zero."
  73   :group 'org-clock
  74   :type 'boolean)
  75
  76 (defcustom org-clock-in-switch-to-state nil
  77   "Set task to a special todo state while clocking it.
  78 The value should be the state to which the entry should be
  79 switched. If the value is a function, it must take one
  80 parameter (the current TODO state of the item) and return the
  81 state to switch it to."
  82   :group 'org-clock
  83   :group 'org-todo
  84   :type '(choice
  85           (const :tag "Don't force a state" nil)
  86           (string :tag "State")
  87           (symbol :tag "Function")))
  88
  89 (defcustom org-clock-out-switch-to-state nil
  90   "Set task to a special todo state after clocking out.
  91 The value should be the state to which the entry should be
  92 switched. If the value is a function, it must take one
  93 parameter (the current TODO state of the item) and return the
  94 state to switch it to."
  95   :group 'org-clock
  96   :group 'org-todo
  97   :type '(choice
  98           (const :tag "Don't force a state" nil)
  99           (string :tag "State")
 100           (symbol :tag "Function")))
 101
 102 (defcustom org-clock-history-length 5
 103   "Number of clock tasks to remember in history."
 104   :group 'org-clock
 105   :type 'integer)
 106
 107 (defcustom org-clock-goto-may-find-recent-task t
 108   "Non-nil means, `org-clock-goto' can go to recent task if no active clock."
 109   :group 'org-clock
 110   :type 'boolean)
 111
 112 (defcustom org-clock-heading-function nil
 113   "When non-nil, should be a function to create `org-clock-heading'.
 114 This is the string shown in the mode line when a clock is running.
 115 The function is called with point at the beginning of the headline."
 116   :group 'org-clock
 117   :type 'function)
 118
 119 (defcustom org-clock-string-limit 0
 120   "Maximum length of clock strings in the modeline. 0 means no limit."
 121   :group 'org-clock
 122   :type 'integer)
 123
 124 (defcustom org-clock-in-resume nil
 125   "If non-nil, resume clock when clocking into task with open clock.
 126 When clocking into a task with a clock entry which has not been closed,
 127 the clock can be resumed from that point."
 128   :group 'org-clock
 129   :type 'boolean)
 130
 131 (defcustom org-clock-persist nil
 132   "When non-nil, save the running clock when emacs is closed.
 133 The clock is resumed when emacs restarts.
 134 When this is t, both the running clock, and the entire clock
 135 history are saved.  When this is the symbol `clock', only the
 136 running clock is saved.
 137
 138 When Emacs restarts with saved clock information, the file containing the
 139 running clock as well as all files mentioned in the clock history will
 140 be visited.
 141 All this depends on running `org-clock-persistence-insinuate' in .emacs"
 142   :group 'org-clock
 143   :type '(choice
 144           (const :tag "Just the running clock" clock)
 145           (const :tag "Clock and history" t)
 146           (const :tag "No persistence" nil)))
 147
 148 (defcustom org-clock-persist-file (convert-standard-filename
 149                                    "~/.emacs.d/org-clock-save.el")
 150   "File to save clock data to."
 151   :group 'org-clock
 152   :type 'string)
 153
 154 (defcustom org-clock-persist-query-save nil
 155   "When non-nil, ask before saving the current clock on exit."
 156   :group 'org-clock
 157   :type 'boolean)
 158
 159 (defcustom org-clock-persist-query-resume t
 160   "When non-nil, ask before resuming any stored clock during load."
 161   :group 'org-clock
 162   :type 'boolean)
 163
 164 (defcustom org-clock-sound nil
 165   "Sound that will used for notifications.
 166 Possible values:
 167
 168 nil        no sound played.
 169 t          standard Emacs beep
 170 file name  play this sound file.  If not possible, fall back to beep"
 171   :group 'org-clock
 172   :type '(choice
 173           (const :tag "No sound" nil)
 174           (const :tag "Standard beep" t)
 175           (file :tag "Play sound file")))
 176
 177 (defcustom org-clock-modeline-total 'auto
 178   "Default setting for the time included for the modeline clock.
 179 This can be overruled locally using the CLOCK_MODELINE_TOTAL property.
 180 Allowed values are:
 181
 182 current  Only the time in the current instance of the clock
 183 today    All time clocked inot this task today
 184 repeat   All time clocked into this task since last repeat
 185 all      All time ever recorded for this task
 186 auto     Automtically, either `all', or `repeat' for repeating tasks"
 187   :group 'org-clock
 188   :type '(choice
 189           (const :tag "Current clock" current)
 190           (const :tag "Today's task time" today)
 191           (const :tag "Since last repeat" repeat)
 192           (const :tag "All task time" all)
 193           (const :tag "Automatically, `all' or since `repeat'" auto)))
 194
 195 (defcustom org-show-notification-handler nil
 196   "Function or program to send notification with.
 197 The function or program will be called with the notification
 198 string as argument."
 199   :group 'org-clock
 200   :type '(choice
 201           (string :tag "Program")
 202           (function :tag "Function")))
 203
 204 (defcustom org-clock-clocktable-default-properties '(:maxlevel 2 :scope file)
 205   "Default properties for new clocktables."
 206   :group 'org-clock
 207   :type 'plist)
 208
 209
 210 (defvar org-clock-in-prepare-hook nil
 211   "Hook run when preparing the clock.
 212 This hook is run before anything happens to the task that
 213 you want to clock in.  For example, you can use this hook
 214 to add an effort property.")
 215 (defvar org-clock-in-hook nil
 216   "Hook run when starting the clock.")
 217 (defvar org-clock-out-hook nil
 218   "Hook run when stopping the current clock.")
 219
 220 (defvar org-clock-cancel-hook nil
 221   "Hook run when cancelling the current clock.")
 222 (defvar org-clock-goto-hook nil
 223   "Hook run when selecting the currently clocked-in entry.")
 224
 225 ;;; The clock for measuring work time.
 226
 227 (defvar org-mode-line-string "")
 228 (put 'org-mode-line-string 'risky-local-variable t)
 229
 230 (defvar org-clock-mode-line-timer nil)
 231 (defvar org-clock-heading "")
 232 (defvar org-clock-heading-for-remember "")
 233 (defvar org-clock-start-time "")
 234
 235 (defvar org-clock-effort ""
 236   "Effort estimate of the currently clocking task")
 237
 238 (defvar org-clock-total-time nil
 239   "Holds total time, spent previously on currently clocked item.
 240 This does not include the time in the currently running clock.")
 241
 242 (defvar org-clock-history nil
 243   "List of marker pointing to recent clocked tasks.")
 244
 245 (defvar org-clock-default-task (make-marker)
 246   "Marker pointing to the default task that should clock time.
 247 The clock can be made to switch to this task after clocking out
 248 of a different task.")
 249
 250 (defvar org-clock-interrupted-task (make-marker)
 251   "Marker pointing to the task that has been interrupted by the current clock.")
 252
 253 (defvar org-clock-mode-line-map (make-sparse-keymap))
 254 (define-key org-clock-mode-line-map [mode-line mouse-2] 'org-clock-goto)
 255 (define-key org-clock-mode-line-map [mode-line mouse-1] 'org-clock-menu)
 256
 257 (defun org-clock-menu ()
 258   (interactive)
 259   (popup-menu
 260    '("Clock"
 261      ["Clock out" org-clock-out t]
 262      ["Change effort estimate" org-clock-modify-effort-estimate t]
 263      ["Go to clock entry" org-clock-goto t]
 264      ["Switch task" (lambda () (interactive) (org-clock-in '(4))) :active t :keys "C-u C-c C-x C-i"])))
 265
 266 (defun org-clock-history-push (&optional pos buffer)
 267   "Push a marker to the clock history."
 268   (setq org-clock-history-length (max 1 (min 35 org-clock-history-length)))
 269   (let ((m (move-marker (make-marker) (or pos (point)) buffer)) n l)
 270     (while (setq n (member m org-clock-history))
 271       (move-marker (car n) nil))
 272     (setq org-clock-history
 273           (delq nil
 274                 (mapcar (lambda (x) (if (marker-buffer x) x nil))
 275                         org-clock-history)))
 276     (when (>= (setq l (length org-clock-history)) org-clock-history-length)
 277       (setq org-clock-history
 278             (nreverse
 279              (nthcdr (- l org-clock-history-length -1)
 280                      (nreverse org-clock-history)))))
 281     (push m org-clock-history)))
 282
 283 (defun org-clock-save-markers-for-cut-and-paste (beg end)
 284   "Save relative positions of markers in region."
 285   (org-check-and-save-marker org-clock-marker beg end)
 286   (org-check-and-save-marker org-clock-hd-marker beg end)
 287   (org-check-and-save-marker org-clock-default-task beg end)
 288   (org-check-and-save-marker org-clock-interrupted-task beg end)
 289   (mapc (lambda (m) (org-check-and-save-marker m beg end))
 290         org-clock-history))
 291
 292 (defun org-clock-select-task (&optional prompt)
 293   "Select a task that recently was associated with clocking."
 294   (interactive)
 295   (let (sel-list rpl (i 0) s)
 296     (save-window-excursion
 297       (org-switch-to-buffer-other-window
 298        (get-buffer-create "*Clock Task Select*"))
 299       (erase-buffer)
 300       (when (marker-buffer org-clock-default-task)
 301         (insert (org-add-props "Default Task\n" nil 'face 'bold))
 302         (setq s (org-clock-insert-selection-line ?d org-clock-default-task))
 303         (push s sel-list))
 304       (when (marker-buffer org-clock-interrupted-task)
 305         (insert (org-add-props "The task interrupted by starting the last one\n" nil 'face 'bold))
 306         (setq s (org-clock-insert-selection-line ?i org-clock-interrupted-task))
 307         (push s sel-list))
 308       (when (marker-buffer org-clock-marker)
 309         (insert (org-add-props "Current Clocking Task\n" nil 'face 'bold))
 310         (setq s (org-clock-insert-selection-line ?c org-clock-marker))
 311         (push s sel-list))
 312       (insert (org-add-props "Recent Tasks\n" nil 'face 'bold))
 313       (mapc
 314        (lambda (m)
 315          (when (marker-buffer m)
 316            (setq i (1+ i)
 317                  s (org-clock-insert-selection-line
 318                     (if (< i 10)
 319                         (+ i ?0)
 320                       (+ i (- ?A 10))) m))
 321            (push s sel-list)))
 322        org-clock-history)
 323       (org-fit-window-to-buffer)
 324       (message (or prompt "Select task for clocking:"))
 325       (setq rpl (read-char-exclusive))
 326       (cond
 327        ((eq rpl ?q) nil)
 328        ((eq rpl ?x) nil)
 329        ((assoc rpl sel-list) (cdr (assoc rpl sel-list)))
 330        (t (error "Invalid task choice %c" rpl))))))
 331
 332 (defun org-clock-insert-selection-line (i marker)
 333   "Insert a line for the clock selection menu.
 334 And return a cons cell with the selection character integer and the marker
 335 pointing to it."
 336   (when (marker-buffer marker)
 337     (let (file cat task heading prefix)
 338       (with-current-buffer (org-base-buffer (marker-buffer marker))
 339         (save-excursion
 340           (save-restriction
 341             (widen)
 342             (goto-char marker)
 343             (setq file (buffer-file-name (marker-buffer marker))
 344                   cat (or (org-get-category)
 345                           (progn (org-refresh-category-properties)
 346                                  (org-get-category)))
 347                   heading (org-get-heading 'notags)
 348                   prefix (save-excursion
 349                            (org-back-to-heading t)
 350                            (looking-at "\\*+ ")
 351                            (match-string 0))
 352                   task (substring
 353                         (org-fontify-like-in-org-mode
 354                          (concat prefix heading)
 355                          org-odd-levels-only)
 356                         (length prefix))))))
 357       (when (and cat task)
 358         (insert (format "[%c] %-15s %s\n" i cat task))
 359         (cons i marker)))))
 360
 361 (defun org-clock-get-clock-string ()
 362   "Form a clock-string, that will be show in the mode line.
 363 If an effort estimate was defined for current item, use
 364 01:30/01:50 format (clocked/estimated).
 365 If not, show simply the clocked time like 01:50."
 366   (let* ((clocked-time (org-clock-get-clocked-time))
 367          (h (floor clocked-time 60))
 368          (m (- clocked-time (* 60 h))))
 369     (if (and org-clock-effort)
 370         (let* ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 371                (effort-h (floor effort-in-minutes 60))
 372                (effort-m (- effort-in-minutes (* effort-h 60))))
 373           (format (concat "-[" org-time-clocksum-format "/" org-time-clocksum-format " (%s)]")
 374                   h m effort-h effort-m  org-clock-heading))
 375       (format (concat "-[" org-time-clocksum-format " (%s)]")
 376               h m org-clock-heading))))
 377
 378 (defun org-clock-update-mode-line ()
 379   (setq org-mode-line-string
 380         (org-propertize
 381          (let ((clock-string (org-clock-get-clock-string))
 382                (help-text "Org-mode clock is running.\nmouse-1 shows a menu\nmouse-2 will jump to task"))
 383            (if (and (> org-clock-string-limit 0)
 384                     (> (length clock-string) org-clock-string-limit))
 385                (org-propertize (substring clock-string 0 org-clock-string-limit)
 386                                'help-echo (concat help-text ": " org-clock-heading))
 387              (org-propertize clock-string 'help-echo help-text)))
 388          'local-map org-clock-mode-line-map
 389          'mouse-face (if (featurep 'xemacs) 'highlight 'mode-line-highlight)
 390          'face 'org-mode-line-clock))
 391   (if org-clock-effort (org-clock-notify-once-if-expired))
 392   (force-mode-line-update))
 393
 394 (defun org-clock-get-clocked-time ()
 395   "Get the clocked time for the current item in minutes.
 396 The time returned includes the time spent on this task in
 397 previous clocking intervals."
 398   (let ((currently-clocked-time
 399          (floor (- (org-float-time)
 400                    (org-float-time org-clock-start-time)) 60)))
 401     (+ currently-clocked-time (or org-clock-total-time 0))))
 402
 403 (defun org-clock-modify-effort-estimate (&optional value)
 404  "Add to or set the effort estimate of the item currently being clocked.
 405 VALUE can be a number of minutes, or a string with forat hh:mm or mm.
 406 WHen the strig starts with a + or a - sign, the current value of the effort
 407 property will be changed by that amount.
 408 This will update the \"Effort\" property of currently clocked item, and
 409 the mode line."
 410  (interactive)
 411  (when (org-clock-is-active)
 412    (let ((current org-clock-effort) sign)
 413      (unless value
 414        ;; Prompt user for a value or a change
 415        (setq value
 416              (read-string
 417               (format "Set effort (hh:mm or mm%s): "
 418                       (if current
 419                           (format ", prefix + to add to %s" org-clock-effort)
 420                         "")))))
 421      (when (stringp value)
 422        ;; A string.  See if it is a delta
 423        (setq sign (string-to-char value))
 424        (if (member sign '(?- ?+))
 425            (setq current (org-hh:mm-string-to-minutes (substring current 1)))
 426          (setq current 0))
 427        (setq value (org-hh:mm-string-to-minutes value))
 428        (if (equal ?- sign)
 429            (setq value (- current value))
 430          (if (equal ?+ sign) (setq value (+ current value)))))
 431      (setq value (max 0 value)
 432            org-clock-effort (org-minutes-to-hh:mm-string value))
 433      (org-entry-put org-clock-marker "Effort" org-clock-effort)
 434      (org-clock-update-mode-line)
 435      (message "Effort is now %s" org-clock-effort))))
 436
 437 (defvar org-clock-notification-was-shown nil
 438   "Shows if we have shown notification already.")
 439
 440 (defun org-clock-notify-once-if-expired ()
 441   "Show notification if we spent more time than we estimated before.
 442 Notification is shown only once."
 443   (when (marker-buffer org-clock-marker)
 444     (let ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 445           (clocked-time (org-clock-get-clocked-time)))
 446       (if (>= clocked-time effort-in-minutes)
 447           (unless org-clock-notification-was-shown
 448             (setq org-clock-notification-was-shown t)
 449             (org-notify
 450              (format "Task '%s' should be finished by now. (%s)"
 451                      org-clock-heading org-clock-effort) t))
 452         (setq org-clock-notification-was-shown nil)))))
 453
 454 (defun org-notify (notification &optional play-sound)
 455   "Send a NOTIFICATION and maybe PLAY-SOUND."
 456   (org-show-notification notification)
 457   (if play-sound (org-clock-play-sound)))
 458
 459 (defun org-show-notification (notification)
 460   "Show notification.
 461 Use `org-show-notification-handler' if defined,
 462 use libnotify if available, or fall back on a message."
 463   (cond ((functionp org-show-notification-handler)
 464          (funcall org-show-notification-handler notification))
 465         ((stringp org-show-notification-handler)
 466          (start-process "emacs-timer-notification" nil
 467                         org-show-notification-handler notification))
 468         ((org-program-exists "notify-send")
 469          (start-process "emacs-timer-notification" nil
 470                         "notify-send" notification))
 471         ;; Maybe the handler will send a message, so only use message as
 472         ;; a fall back option
 473         (t (message notification))))
 474
 475 (defun org-clock-play-sound ()
 476   "Play sound as configured by `org-clock-sound'.
 477 Use alsa's aplay tool if available."
 478   (cond
 479    ((not org-clock-sound))
 480    ((eq org-clock-sound t) (beep t) (beep t))
 481    ((stringp org-clock-sound)
 482     (if (file-exists-p org-clock-sound)
 483         (if (org-program-exists "aplay")
 484             (start-process "org-clock-play-notification" nil
 485                            "aplay" org-clock-sound)
 486           (condition-case nil
 487               (play-sound-file org-clock-sound)
 488             (error (beep t) (beep t))))))))
 489
 490 (defun org-program-exists (program-name)
 491   "Checks whenever we can locate program and launch it."
 492   (if (eq system-type 'gnu/linux)
 493       (= 0 (call-process "which" nil nil nil program-name))))
 494
 495 (defvar org-clock-mode-line-entry nil
 496   "Information for the modeline about the running clock.")
 497
 498 (defun org-clock-in (&optional select)
 499   "Start the clock on the current item.
 500 If necessary, clock-out of the currently active clock.
 501 With prefix arg SELECT, offer a list of recently clocked tasks to
 502 clock into.  When SELECT is `C-u C-u', clock into the current task and mark
 503 is as the default task, a special task that will always be offered in
 504 the clocking selection, associated with the letter `d'."
 505   (interactive "P")
 506   (setq org-clock-notification-was-shown nil)
 507   (catch 'abort
 508     (let ((interrupting (marker-buffer org-clock-marker))
 509           ts selected-task target-pos (msg-extra ""))
 510       (when (equal select '(4))
 511         (setq selected-task (org-clock-select-task "Clock-in on task: "))
 512         (if selected-task
 513             (setq selected-task (copy-marker selected-task))
 514           (error "Abort")))
 515       (when interrupting
 516         ;; We are interrupting the clocking of a different task.
 517         ;; Save a marker to this task, so that we can go back.
 518         (move-marker org-clock-interrupted-task
 519                      (marker-position org-clock-marker)
 520                      (marker-buffer org-clock-marker))
 521         (org-clock-out t))
 522
 523       (when (equal select '(16))
 524         ;; Mark as default clocking task
 525         (org-clock-mark-default-task))
 526
 527       (setq target-pos (point))  ;; we want to clock in at this location
 528       (run-hooks 'org-clock-in-prepare-hook)
 529       (save-excursion
 530         (when (and selected-task (marker-buffer selected-task))
 531           ;; There is a selected task, move to the correct buffer
 532           ;; and set the new target position.
 533           (set-buffer (org-base-buffer (marker-buffer selected-task)))
 534           (setq target-pos (marker-position selected-task))
 535           (move-marker selected-task nil))
 536         (save-excursion
 537           (save-restriction
 538             (widen)
 539             (goto-char target-pos)
 540             (org-back-to-heading t)
 541             (or interrupting (move-marker org-clock-interrupted-task nil))
 542             (org-clock-history-push)
 543             (cond ((functionp org-clock-in-switch-to-state)
 544                    (looking-at org-complex-heading-regexp)
 545                    (let ((newstate (funcall org-clock-in-switch-to-state
 546                                             (match-string 2))))
 547                      (if newstate (org-todo newstate))))
 548                   ((and org-clock-in-switch-to-state
 549                         (not (looking-at (concat outline-regexp "[ \t]*"
 550                                                  org-clock-in-switch-to-state
 551                                                  "\\>"))))
 552                    (org-todo org-clock-in-switch-to-state)))
 553             (setq org-clock-heading-for-remember
 554                   (and (looking-at org-complex-heading-regexp)
 555                        (match-end 4)
 556                        (org-trim (buffer-substring (match-end 1)
 557                                                    (match-end 4)))))
 558             (setq org-clock-heading
 559                   (cond ((and org-clock-heading-function
 560                               (functionp org-clock-heading-function))
 561                          (funcall org-clock-heading-function))
 562                         ((looking-at org-complex-heading-regexp)
 563                          (match-string 4))
 564                         (t "???")))
 565             (setq org-clock-heading (org-propertize org-clock-heading
 566                                                     'face nil))
 567             (org-clock-find-position org-clock-in-resume)
 568             (cond
 569              ((and org-clock-in-resume
 570                    (looking-at
 571                     (concat "^[ \t]* " org-clock-string
 572                             " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 573                             " +\\sw+\.? +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")))
 574               (message "Matched %s" (match-string 1))
 575               (setq ts (concat "[" (match-string 1) "]"))
 576               (goto-char (match-end 1))
 577               (setq org-clock-start-time
 578                     (apply 'encode-time
 579                            (org-parse-time-string (match-string 1))))
 580               (setq org-clock-effort (org-get-effort))
 581               (setq org-clock-total-time (org-clock-sum-current-item
 582                                           (org-clock-get-sum-start))))
 583              ((eq org-clock-in-resume 'auto-restart)
 584               ;; called from org-clock-load during startup,
 585               ;; do not interrupt, but warn!
 586               (message "Cannot restart clock because task does not contain unfinished clock")
 587               (ding)
 588               (sit-for 2)
 589               (throw 'abort nil))
 590              (t
 591               (insert-before-markers "\n")
 592               (backward-char 1)
 593               (org-indent-line-function)
 594               (when (and (save-excursion
 595                            (end-of-line 0)
 596                            (org-in-item-p)))
 597                 (beginning-of-line 1)
 598                 (org-indent-line-to (- (org-get-indentation) 2)))
 599               (insert org-clock-string " ")
 600               (setq org-clock-effort (org-get-effort))
 601               (setq org-clock-total-time (org-clock-sum-current-item
 602                                           (org-clock-get-sum-start)))
 603               (setq org-clock-start-time (current-time))
 604               (setq ts (org-insert-time-stamp org-clock-start-time
 605                                               'with-hm 'inactive))))
 606             (move-marker org-clock-marker (point) (buffer-base-buffer))
 607             (move-marker org-clock-hd-marker
 608                          (save-excursion (org-back-to-heading t) (point))
 609                          (buffer-base-buffer))
 610             (or global-mode-string (setq global-mode-string '("")))
 611             (or (memq 'org-mode-line-string global-mode-string)
 612                 (setq global-mode-string
 613                       (append global-mode-string '(org-mode-line-string))))
 614             (org-clock-update-mode-line)
 615             (setq org-clock-mode-line-timer
 616                   (run-with-timer 60 60 'org-clock-update-mode-line))
 617             (message "Clock starts at %s - %s" ts msg-extra)
 618             (run-hooks 'org-clock-in-hook)))))))
 619
 620 (defun org-clock-mark-default-task ()
 621   "Mark current task as default task."
 622   (interactive)
 623   (save-excursion
 624     (org-back-to-heading t)
 625     (move-marker org-clock-default-task (point))))
 626
 627 (defvar msg-extra)
 628 (defun org-clock-get-sum-start ()
 629   "Return the time from which clock times should be counted.
 630 This is for the currently running clock as it is displayed
 631 in the mode line.  This function looks at the properties
 632 LAST_REPEAT and in particular CLOCK_MODELINE_TOTAL and the
 633 corresponding variable `org-clock-modeline-total' and then
 634 decides which time to use."
 635   (let ((cmt (or (org-entry-get nil "CLOCK_MODELINE_TOTAL")
 636                  (symbol-name org-clock-modeline-total)))
 637         (lr (org-entry-get nil "LAST_REPEAT")))
 638     (cond
 639      ((equal cmt "current")
 640       (setq msg-extra "showing time in current clock instance")
 641       (current-time))
 642      ((equal cmt "today")
 643       (setq msg-extra "showing today's task time.")
 644       (let* ((dt (decode-time (current-time))))
 645         (setq dt (append (list 0 0 0) (nthcdr 3 dt)))
 646         (if org-extend-today-until
 647             (setf (nth 2 dt) org-extend-today-until))
 648         (apply 'encode-time dt)))
 649      ((or (equal cmt "all")
 650           (and (or (not cmt) (equal cmt "auto"))
 651                (not lr)))
 652       (setq msg-extra "showing entire task time.")
 653       nil)
 654      ((or (equal cmt "repeat")
 655           (and (or (not cmt) (equal cmt "auto"))
 656                lr))
 657       (setq msg-extra "showing task time since last repeat.")
 658       (if (not lr)
 659           nil
 660         (org-time-string-to-time lr)))
 661      (t nil))))
 662
 663 (defun org-clock-find-position (find-unclosed)
 664   "Find the location where the next clock line should be inserted.
 665 When FIND-UNCLOSED is non-nil, first check if there is an unclosed clock
 666 line and position cursor in that line."
 667   (org-back-to-heading t)
 668   (catch 'exit
 669     (let ((beg (save-excursion
 670                  (beginning-of-line 2)
 671                  (or (bolp) (newline))
 672                  (point)))
 673           (end (progn (outline-next-heading) (point)))
 674           (re (concat "^[ \t]*" org-clock-string))
 675           (cnt 0)
 676           (drawer (if (stringp org-clock-into-drawer)
 677                       org-clock-into-drawer "LOGBOOK"))
 678           first last ind-last)
 679       (goto-char beg)
 680       (when (and find-unclosed
 681                  (re-search-forward
 682                   (concat "^[ \t]* " org-clock-string
 683                           " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 684                           " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")
 685                   end t))
 686         (beginning-of-line 1)
 687         (throw 'exit t))
 688       (when (eobp) (newline) (setq end (max (point) end)))
 689       (when (re-search-forward (concat "^[ \t]*:" drawer ":") end t)
 690         ;; we seem to have a CLOCK drawer, so go there.
 691         (beginning-of-line 2)
 692         (or org-log-states-order-reversed
 693             (and (re-search-forward org-property-end-re nil t)
 694                  (goto-char (match-beginning 0))))
 695         (throw 'exit t))
 696       ;; Lets count the CLOCK lines
 697       (goto-char beg)
 698       (while (re-search-forward re end t)
 699         (setq first (or first (match-beginning 0))
 700               last (match-beginning 0)
 701               cnt (1+ cnt)))
 702       (when (and (integerp org-clock-into-drawer)
 703                  last
 704                  (>= (1+ cnt) org-clock-into-drawer))
 705         ;; Wrap current entries into a new drawer
 706         (goto-char last)
 707         (setq ind-last (org-get-indentation))
 708         (beginning-of-line 2)
 709         (if (and (>= (org-get-indentation) ind-last)
 710                  (org-at-item-p))
 711             (org-end-of-item))
 712         (insert ":END:\n")
 713         (beginning-of-line 0)
 714         (org-indent-line-to ind-last)
 715         (goto-char first)
 716         (insert ":" drawer ":\n")
 717         (beginning-of-line 0)
 718         (org-indent-line-function)
 719         (org-flag-drawer t)
 720         (beginning-of-line 2)
 721         (or org-log-states-order-reversed
 722             (and (re-search-forward org-property-end-re nil t)
 723                  (goto-char (match-beginning 0))))
 724         (throw 'exit nil))
 725
 726       (goto-char beg)
 727       (while (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 728                   (not (equal (match-string 1) org-clock-string)))
 729         ;; Planning info, skip to after it
 730         (beginning-of-line 2)
 731         (or (bolp) (newline)))
 732       (when (or (eq org-clock-into-drawer t)
 733                 (stringp org-clock-into-drawer)
 734                 (and (integerp org-clock-into-drawer)
 735                      (< org-clock-into-drawer 2)))
 736         (insert ":" drawer ":\n:END:\n")
 737         (beginning-of-line -1)
 738         (org-indent-line-function)
 739         (org-flag-drawer t)
 740         (beginning-of-line 2)
 741         (org-indent-line-function)
 742         (beginning-of-line)
 743         (or org-log-states-order-reversed
 744             (and (re-search-forward org-property-end-re nil t)
 745                  (goto-char (match-beginning 0))))))))
 746
 747 (defun org-clock-out (&optional fail-quietly)
 748   "Stop the currently running clock.
 749 If there is no running clock, throw an error, unless FAIL-QUIETLY is set."
 750   (interactive)
 751   (catch 'exit
 752     (if (not (marker-buffer org-clock-marker))
 753         (if fail-quietly (throw 'exit t) (error "No active clock")))
 754     (let (ts te s h m remove)
 755       (with-current-buffer (marker-buffer org-clock-marker)
 756         (save-restriction
 757           (widen)
 758           (goto-char org-clock-marker)
 759           (beginning-of-line 1)
 760           (if (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 761                    (equal (match-string 1) org-clock-string))
 762               (setq ts (match-string 2))
 763             (if fail-quietly (throw 'exit nil) (error "Clock start time is gone")))
 764           (goto-char (match-end 0))
 765           (delete-region (point) (point-at-eol))
 766           (insert "--")
 767           (setq te (org-insert-time-stamp (current-time) 'with-hm 'inactive))
 768           (setq s (- (org-float-time (apply 'encode-time (org-parse-time-string te)))
 769                      (org-float-time (apply 'encode-time (org-parse-time-string ts))))
 770                 h (floor (/ s 3600))
 771                 s (- s (* 3600 h))
 772                 m (floor (/ s 60))
 773                 s (- s (* 60 s)))
 774           (insert " => " (format "%2d:%02d" h m))
 775           (when (setq remove (and org-clock-out-remove-zero-time-clocks
 776                                   (= (+ h m) 0)))
 777             (beginning-of-line 1)
 778             (delete-region (point) (point-at-eol))
 779             (and (looking-at "\n") (> (point-max) (1+ (point)))
 780                  (delete-char 1)))
 781           (move-marker org-clock-marker nil)
 782           (move-marker org-clock-hd-marker nil)
 783           (when org-log-note-clock-out
 784             (org-add-log-setup 'clock-out nil nil nil nil
 785                                (concat "# Task: " (org-get-heading t) "\n\n")))
 786           (when org-clock-mode-line-timer
 787             (cancel-timer org-clock-mode-line-timer)
 788             (setq org-clock-mode-line-timer nil))
 789           (setq global-mode-string
 790                 (delq 'org-mode-line-string global-mode-string))
 791           (when org-clock-out-switch-to-state
 792             (save-excursion
 793               (org-back-to-heading t)
 794               (let ((org-inhibit-logging t))
 795                 (cond
 796                  ((functionp org-clock-out-switch-to-state)
 797                   (looking-at org-complex-heading-regexp)
 798                   (let ((newstate (funcall org-clock-out-switch-to-state
 799                                            (match-string 2))))
 800                     (if newstate (org-todo newstate))))
 801                  ((and org-clock-out-switch-to-state
 802                        (not (looking-at (concat outline-regexp "[ \t]*"
 803                                                 org-clock-out-switch-to-state
 804                                                 "\\>"))))
 805                   (org-todo org-clock-out-switch-to-state))))))
 806           (force-mode-line-update)
 807           (message (concat "Clock stopped at %s after HH:MM = " org-time-clocksum-format "%s") te h m
 808                    (if remove " => LINE REMOVED" ""))
 809           (run-hooks 'org-clock-out-hook))))))
 810
 811 (defun org-clock-cancel ()
 812   "Cancel the running clock be removing the start timestamp."
 813   (interactive)
 814   (if (not (marker-buffer org-clock-marker))
 815       (error "No active clock"))
 816   (with-current-buffer (marker-buffer org-clock-marker)
 817     (goto-char org-clock-marker)
 818     (delete-region (1- (point-at-bol)) (point-at-eol)))
 819   (move-marker 'org-clock-marker nil)
 820   (move-marker 'org-clock-hd-marker nil)
 821   (setq global-mode-string
 822         (delq 'org-mode-line-string global-mode-string))
 823   (force-mode-line-update)
 824   (message "Clock canceled")
 825   (run-hooks 'org-clock-cancel-hook))
 826
 827 (defun org-clock-goto (&optional select)
 828   "Go to the currently clocked-in entry, or to the most recently clocked one.
 829 With prefix arg SELECT, offer recently clocked tasks for selection."
 830   (interactive "@P")
 831   (let* ((recent nil)
 832          (m (cond
 833              (select
 834               (or (org-clock-select-task "Select task to go to: ")
 835                   (error "No task selected")))
 836              ((marker-buffer org-clock-marker) org-clock-marker)
 837              ((and org-clock-goto-may-find-recent-task
 838                    (car org-clock-history)
 839                    (marker-buffer (car org-clock-history)))
 840               (setq recent t)
 841               (car org-clock-history))
 842              (t (error "No active or recent clock task")))))
 843     (switch-to-buffer (marker-buffer m))
 844     (if (or (< m (point-min)) (> m (point-max))) (widen))
 845     (goto-char m)
 846     (org-show-entry)
 847     (org-back-to-heading t)
 848     (org-cycle-hide-drawers 'children)
 849     (recenter)
 850     (if recent
 851         (message "No running clock, this is the most recently clocked task"))
 852     (run-hooks 'org-clock-goto-hook)))
 853
 854 (defvar org-clock-file-total-minutes nil
 855   "Holds the file total time in minutes, after a call to `org-clock-sum'.")
 856 (make-variable-buffer-local 'org-clock-file-total-minutes)
 857
 858 (defun org-clock-sum (&optional tstart tend)
 859   "Sum the times for each subtree.
 860 Puts the resulting times in minutes as a text property on each headline.
 861 TSTART and TEND can mark a time range to be considered."
 862   (interactive)
 863   (let* ((bmp (buffer-modified-p))
 864          (re (concat "^\\(\\*+\\)[ \t]\\|^[ \t]*"
 865                      org-clock-string
 866                      "[ \t]*\\(?:\\(\\[.*?\\]\\)-+\\(\\[.*?\\]\\)\\|=>[ \t]+\\([0-9]+\\):\\([0-9]+\\)\\)"))
 867          (lmax 30)
 868          (ltimes (make-vector lmax 0))
 869          (t1 0)
 870          (level 0)
 871          ts te dt
 872          time)
 873     (if (stringp tstart) (setq tstart (org-time-string-to-seconds tstart)))
 874     (if (stringp tend) (setq tend (org-time-string-to-seconds tend)))
 875     (if (consp tstart) (setq tstart (org-float-time tstart)))
 876     (if (consp tend) (setq tend (org-float-time tend)))
 877     (remove-text-properties (point-min) (point-max) '(:org-clock-minutes t))
 878     (save-excursion
 879       (goto-char (point-max))
 880       (while (re-search-backward re nil t)
 881         (cond
 882          ((match-end 2)
 883           ;; Two time stamps
 884           (setq ts (match-string 2)
 885                 te (match-string 3)
 886                 ts (org-float-time
 887                     (apply 'encode-time (org-parse-time-string ts)))
 888                 te (org-float-time
 889                     (apply 'encode-time (org-parse-time-string te)))
 890                 ts (if tstart (max ts tstart) ts)
 891                 te (if tend (min te tend) te)
 892                 dt (- te ts)
 893                 t1 (if (> dt 0) (+ t1 (floor (/ dt 60))) t1)))
 894          ((match-end 4)
 895           ;; A naked time
 896           (setq t1 (+ t1 (string-to-number (match-string 5))
 897                       (* 60 (string-to-number (match-string 4))))))
 898          (t ;; A headline
 899           (setq level (- (match-end 1) (match-beginning 1)))
 900           (when (or (> t1 0) (> (aref ltimes level) 0))
 901             (loop for l from 0 to level do
 902                   (aset ltimes l (+ (aref ltimes l) t1)))
 903             (setq t1 0 time (aref ltimes level))
 904             (loop for l from level to (1- lmax) do
 905                   (aset ltimes l 0))
 906             (goto-char (match-beginning 0))
 907             (put-text-property (point) (point-at-eol) :org-clock-minutes time)))))
 908       (setq org-clock-file-total-minutes (aref ltimes 0)))
 909     (set-buffer-modified-p bmp)))
 910
 911 (defun org-clock-sum-current-item (&optional tstart)
 912   "Returns time, clocked on current item in total"
 913   (save-excursion
 914     (save-restriction
 915       (org-narrow-to-subtree)
 916       (org-clock-sum tstart)
 917       org-clock-file-total-minutes)))
 918
 919 (defun org-clock-display (&optional total-only)
 920   "Show subtree times in the entire buffer.
 921 If TOTAL-ONLY is non-nil, only show the total time for the entire file
 922 in the echo area."
 923   (interactive)
 924   (org-clock-remove-overlays)
 925   (let (time h m p)
 926     (org-clock-sum)
 927     (unless total-only
 928       (save-excursion
 929         (goto-char (point-min))
 930         (while (or (and (equal (setq p (point)) (point-min))
 931                         (get-text-property p :org-clock-minutes))
 932                    (setq p (next-single-property-change
 933                             (point) :org-clock-minutes)))
 934           (goto-char p)
 935           (when (setq time (get-text-property p :org-clock-minutes))
 936             (org-clock-put-overlay time (funcall outline-level))))
 937         (setq h (/ org-clock-file-total-minutes 60)
 938               m (- org-clock-file-total-minutes (* 60 h)))
 939         ;; Arrange to remove the overlays upon next change.
 940         (when org-remove-highlights-with-change
 941           (org-add-hook 'before-change-functions 'org-clock-remove-overlays
 942                         nil 'local))))
 943     (message (concat "Total file time: " org-time-clocksum-format " (%d hours and %d minutes)") h m h m)))
 944
 945 (defvar org-clock-overlays nil)
 946 (make-variable-buffer-local 'org-clock-overlays)
 947
 948 (defun org-clock-put-overlay (time &optional level)
 949   "Put an overlays on the current line, displaying TIME.
 950 If LEVEL is given, prefix time with a corresponding number of stars.
 951 This creates a new overlay and stores it in `org-clock-overlays', so that it
 952 will be easy to remove."
 953   (let* ((c 60) (h (floor (/ time 60))) (m (- time (* 60 h)))
 954          (l (if level (org-get-valid-level level 0) 0))
 955          (fmt (concat "%s " org-time-clocksum-format "%s"))
 956          (off 0)
 957          ov tx)
 958     (org-move-to-column c)
 959     (unless (eolp) (skip-chars-backward "^ \t"))
 960     (skip-chars-backward " \t")
 961     (setq ov (org-make-overlay (1- (point)) (point-at-eol))
 962           tx (concat (buffer-substring (1- (point)) (point))
 963                      (make-string (+ off (max 0 (- c (current-column)))) ?.)
 964                      (org-add-props (format fmt
 965                                             (make-string l ?*) h m
 966                                             (make-string (- 16 l) ?\ ))
 967                          (list 'face 'org-clock-overlay))
 968                      ""))
 969     (if (not (featurep 'xemacs))
 970         (org-overlay-put ov 'display tx)
 971       (org-overlay-put ov 'invisible t)
 972       (org-overlay-put ov 'end-glyph (make-glyph tx)))
 973     (push ov org-clock-overlays)))
 974
 975 (defun org-clock-remove-overlays (&optional beg end noremove)
 976   "Remove the occur highlights from the buffer.
 977 BEG and END are ignored.  If NOREMOVE is nil, remove this function
 978 from the `before-change-functions' in the current buffer."
 979   (interactive)
 980   (unless org-inhibit-highlight-removal
 981     (mapc 'org-delete-overlay org-clock-overlays)
 982     (setq org-clock-overlays nil)
 983     (unless noremove
 984       (remove-hook 'before-change-functions
 985                    'org-clock-remove-overlays 'local))))
 986
 987 (defvar state) ;; dynamically scoped into this function
 988 (defun org-clock-out-if-current ()
 989   "Clock out if the current entry contains the running clock.
 990 This is used to stop the clock after a TODO entry is marked DONE,
 991 and is only done if the variable `org-clock-out-when-done' is not nil."
 992   (when (and org-clock-out-when-done
 993              (member state org-done-keywords)
 994              (equal (or (buffer-base-buffer (marker-buffer org-clock-marker))
 995                         (marker-buffer org-clock-marker))
 996                     (or (buffer-base-buffer (current-buffer))
 997                         (current-buffer)))
 998              (< (point) org-clock-marker)
 999              (> (save-excursion (outline-next-heading) (point))
1000                 org-clock-marker))
1001     ;; Clock out, but don't accept a logging message for this.
1002     (let ((org-log-note-clock-out nil))
1003       (org-clock-out))))
1004
1005 (add-hook 'org-after-todo-state-change-hook
1006           'org-clock-out-if-current)
1007
1008 ;;;###autoload
1009 (defun org-get-clocktable (&rest props)
1010   "Get a formatted clocktable with parameters according to PROPS.
1011 The table is created in a temporary buffer, fully formatted and
1012 fontified, and then returned."
1013   ;; Set the defaults
1014   (setq props (plist-put props :name "clocktable"))
1015   (unless (plist-member props :maxlevel)
1016     (setq props (plist-put props :maxlevel 2)))
1017   (unless (plist-member props :scope)
1018     (setq props (plist-put props :scope 'agenda)))
1019   (with-temp-buffer
1020     (org-mode)
1021     (org-create-dblock props)
1022     (org-update-dblock)
1023     (font-lock-fontify-buffer)
1024     (forward-line 2)
1025     (buffer-substring (point) (progn
1026                                 (re-search-forward "^#\\+END" nil t)
1027                                 (point-at-bol)))))
1028
1029 (defun org-clock-report (&optional arg)
1030   "Create a table containing a report about clocked time.
1031 If the cursor is inside an existing clocktable block, then the table
1032 will be updated.  If not, a new clocktable will be inserted.
1033 When called with a prefix argument, move to the first clock table in the
1034 buffer and update it."
1035   (interactive "P")
1036   (org-clock-remove-overlays)
1037   (when arg
1038     (org-find-dblock "clocktable")
1039     (org-show-entry))
1040   (if (org-in-clocktable-p)
1041       (goto-char (org-in-clocktable-p))
1042     (org-create-dblock (append (list :name "clocktable")
1043                                org-clock-clocktable-default-properties)))
1044   (org-update-dblock))
1045
1046 (defun org-in-clocktable-p ()
1047   "Check if the cursor is in a clocktable."
1048   (let ((pos (point)) start)
1049     (save-excursion
1050       (end-of-line 1)
1051       (and (re-search-backward "^#\\+BEGIN:[ \t]+clocktable" nil t)
1052            (setq start (match-beginning 0))
1053            (re-search-forward "^#\\+END:.*" nil t)
1054            (>= (match-end 0) pos)
1055            start))))
1056
1057 (defun org-clock-special-range (key &optional time as-strings)
1058   "Return two times bordering a special time range.
1059 Key is a symbol specifying the range and can be one of `today', `yesterday',
1060 `thisweek', `lastweek', `thismonth', `lastmonth', `thisyear', `lastyear'.
1061 A week starts Monday 0:00 and ends Sunday 24:00.
1062 The range is determined relative to TIME.  TIME defaults to the current time.
1063 The return value is a cons cell with two internal times like the ones
1064 returned by `current time' or `encode-time'. if AS-STRINGS is non-nil,
1065 the returned times will be formatted strings."
1066   (if (integerp key) (setq key (intern (number-to-string key))))
1067   (let* ((tm (decode-time (or time (current-time))))
1068          (s 0) (m (nth 1 tm)) (h (nth 2 tm))
1069          (d (nth 3 tm)) (month (nth 4 tm)) (y (nth 5 tm))
1070          (dow (nth 6 tm))
1071          (skey (symbol-name key))
1072          (shift 0)
1073          s1 m1 h1 d1 month1 y1 diff ts te fm txt w date)
1074     (cond
1075      ((string-match "^[0-9]+$" skey)
1076       (setq y (string-to-number skey) m 1 d 1 key 'year))
1077      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1078       (setq y (string-to-number (match-string 1 skey))
1079             month (string-to-number (match-string 2 skey))
1080             d 1 key 'month))
1081      ((string-match "^\\([0-9]+\\)-[wW]\\([0-9]\\{1,2\\}\\)$" skey)
1082       (require 'cal-iso)
1083       (setq y (string-to-number (match-string 1 skey))
1084             w (string-to-number (match-string 2 skey)))
1085       (setq date (calendar-gregorian-from-absolute
1086                   (calendar-absolute-from-iso (list w 1 y))))
1087       (setq d (nth 1 date) month (car date) y (nth 2 date)
1088             dow 1
1089             key 'week))
1090      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1091       (setq y (string-to-number (match-string 1 skey))
1092             month (string-to-number (match-string 2 skey))
1093             d (string-to-number (match-string 3 skey))
1094             key 'day))
1095      ((string-match "\\([-+][0-9]+\\)$" skey)
1096       (setq shift (string-to-number (match-string 1 skey))
1097             key (intern (substring skey 0 (match-beginning 1))))))
1098     (when (= shift 0)
1099       (cond ((eq key 'yesterday) (setq key 'today shift -1))
1100             ((eq key 'lastweek)  (setq key 'week  shift -1))
1101             ((eq key 'lastmonth) (setq key 'month shift -1))
1102             ((eq key 'lastyear)  (setq key 'year  shift -1))))
1103     (cond
1104      ((memq key '(day today))
1105       (setq d (+ d shift) h 0 m 0 h1 24 m1 0))
1106      ((memq key '(week thisweek))
1107       (setq diff (+ (* -7 shift) (if (= dow 0) 6 (1- dow)))
1108             m 0 h 0 d (- d diff) d1 (+ 7 d)))
1109      ((memq key '(month thismonth))
1110       (setq d 1 h 0 m 0 d1 1 month (+ month shift) month1 (1+ month) h1 0 m1 0))
1111      ((memq key '(year thisyear))
1112       (setq m 0 h 0 d 1 month 1 y (+ y shift) y1 (1+ y)))
1113      (t (error "No such time block %s" key)))
1114     (setq ts (encode-time s m h d month y)
1115           te (encode-time (or s1 s) (or m1 m) (or h1 h)
1116                           (or d1 d) (or month1 month) (or y1 y)))
1117     (setq fm (cdr org-time-stamp-formats))
1118     (cond
1119      ((memq key '(day today))
1120       (setq txt (format-time-string "%A, %B %d, %Y" ts)))
1121      ((memq key '(week thisweek))
1122       (setq txt (format-time-string "week %G-W%V" ts)))
1123      ((memq key '(month thismonth))
1124       (setq txt (format-time-string "%B %Y" ts)))
1125      ((memq key '(year thisyear))
1126       (setq txt (format-time-string "the year %Y" ts))))
1127     (if as-strings
1128         (list (format-time-string fm ts) (format-time-string fm te) txt)
1129       (list ts te txt))))
1130
1131 (defun org-clocktable-shift (dir n)
1132   "Try to shift the :block date of the clocktable at point.
1133 Point must be in the #+BEGIN: line of a clocktable, or this function
1134 will throw an error.
1135 DIR is a direction, a symbol `left', `right', `up', or `down'.
1136 Both `left' and `down' shift the block toward the past, `up' and `right'
1137 push it toward the future.
1138 N is the number of shift steps to take.  The size of the step depends on
1139 the currently selected interval size."
1140   (setq n (prefix-numeric-value n))
1141   (and (memq dir '(left down)) (setq n (- n)))
1142   (save-excursion
1143     (goto-char (point-at-bol))
1144     (if (not (looking-at "#\\+BEGIN: clocktable\\>.*?:block[ \t]+\\(\\S-+\\)"))
1145         (error "Line needs a :block definition before this command works")
1146       (let* ((b (match-beginning 1)) (e (match-end 1))
1147              (s (match-string 1))
1148              block shift ins y mw d date wp m)
1149         (cond
1150          ((equal s "yesterday") (setq s "today-1"))
1151          ((equal s "lastweek") (setq s "thisweek-1"))
1152          ((equal s "lastmonth") (setq s "thismonth-1"))
1153          ((equal s "lastyear") (setq s "thisyear-1")))
1154         (cond
1155          ((string-match "^\\(today\\|thisweek\\|thismonth\\|thisyear\\)\\([-+][0-9]+\\)?$" s)
1156           (setq block (match-string 1 s)
1157                 shift (if (match-end 2)
1158                           (string-to-number (match-string 2 s))
1159                         0))
1160           (setq shift (+ shift n))
1161           (setq ins (if (= shift 0) block (format "%s%+d" block shift))))
1162          ((string-match "\\([0-9]+\\)\\(-\\([wW]?\\)\\([0-9]\\{1,2\\}\\)\\(-\\([0-9]\\{1,2\\}\\)\\)?\\)?" s)
1163           ;;               1        1  2   3       3  4                4  5   6                6  5   2
1164           (setq y (string-to-number (match-string 1 s))
1165                 wp (and (match-end 3) (match-string 3 s))
1166                 mw (and (match-end 4) (string-to-number (match-string 4 s)))
1167                 d (and (match-end 6) (string-to-number (match-string 6 s))))
1168           (cond
1169            (d (setq ins (format-time-string
1170                          "%Y-%m-%d"
1171                          (encode-time 0 0 0 (+ d n) m y))))
1172            ((and wp mw (> (length wp) 0))
1173             (require 'cal-iso)
1174             (setq date (calendar-gregorian-from-absolute (calendar-absolute-from-iso (list (+ mw n) 1 y))))
1175             (setq ins (format-time-string
1176                        "%G-W%V"
1177                        (encode-time 0 0 0 (nth 1 date) (car date) (nth 2 date)))))
1178            (mw
1179             (setq ins (format-time-string
1180                        "%Y-%m"
1181                        (encode-time 0 0 0 1 (+ mw n) y))))
1182            (y
1183             (setq ins (number-to-string (+ y n))))))
1184          (t (error "Cannot shift clocktable block")))
1185         (when ins
1186           (goto-char b)
1187           (insert ins)
1188           (delete-region (point) (+ (point) (- e b)))
1189           (beginning-of-line 1)
1190           (org-update-dblock)
1191           t)))))
1192
1193 (defun org-dblock-write:clocktable (params)
1194   "Write the standard clocktable."
1195   (catch 'exit
1196     (let* ((hlchars '((1 . "*") (2 . "/")))
1197            (ins (make-marker))
1198            (total-time nil)
1199            (scope (plist-get params :scope))
1200            (tostring (plist-get  params :tostring))
1201            (multifile (plist-get  params :multifile))
1202            (header (plist-get  params :header))
1203            (maxlevel (or (plist-get params :maxlevel) 3))
1204            (step (plist-get params :step))
1205            (emph (plist-get params :emphasize))
1206            (timestamp (plist-get params :timestamp))
1207            (ts (plist-get params :tstart))
1208            (te (plist-get params :tend))
1209            (block (plist-get params :block))
1210            (link (plist-get params :link))
1211            ipos time p level hlc hdl tsp props content recalc formula pcol
1212            cc beg end pos tbl tbl1 range-text rm-file-column scope-is-list st)
1213       (setq org-clock-file-total-minutes nil)
1214       (when step
1215         (unless (or block (and ts te))
1216           (error "Clocktable `:step' can only be used with `:block' or `:tstart,:end'"))
1217         (org-clocktable-steps params)
1218         (throw 'exit nil))
1219       (when block
1220         (setq cc (org-clock-special-range block nil t)
1221               ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1222       (when (integerp ts) (setq ts (calendar-gregorian-from-absolute ts)))
1223       (when (integerp te) (setq te (calendar-gregorian-from-absolute te)))
1224       (when (and ts (listp ts))
1225         (setq ts (format "%4d-%02d-%02d" (nth 2 ts) (car ts) (nth 1 ts))))
1226       (when (and te (listp te))
1227         (setq te (format "%4d-%02d-%02d" (nth 2 te) (car te) (nth 1 te))))
1228       ;; Now the times are strings we can parse.
1229       (if ts (setq ts (org-float-time
1230                        (apply 'encode-time (org-parse-time-string ts)))))
1231       (if te (setq te (org-float-time
1232                        (apply 'encode-time (org-parse-time-string te)))))
1233       (move-marker ins (point))
1234       (setq ipos (point))
1235
1236       ;; Get the right scope
1237       (setq pos (point))
1238       (cond
1239        ((and scope (listp scope) (symbolp (car scope)))
1240         (setq scope (eval scope)))
1241        ((eq scope 'agenda)
1242         (setq scope (org-agenda-files t)))
1243        ((eq scope 'agenda-with-archives)
1244         (setq scope (org-agenda-files t))
1245         (setq scope (org-add-archive-files scope)))
1246        ((eq scope 'file-with-archives)
1247         (setq scope (org-add-archive-files (list (buffer-file-name)))
1248               rm-file-column t)))
1249       (setq scope-is-list (and scope (listp scope)))
1250       (save-restriction
1251         (cond
1252          ((not scope))
1253          ((eq scope 'file) (widen))
1254          ((eq scope 'subtree) (org-narrow-to-subtree))
1255          ((eq scope 'tree)
1256           (while (org-up-heading-safe))
1257           (org-narrow-to-subtree))
1258          ((and (symbolp scope) (string-match "^tree\\([0-9]+\\)$"
1259                                              (symbol-name scope)))
1260           (setq level (string-to-number (match-string 1 (symbol-name scope))))
1261           (catch 'exit
1262             (while (org-up-heading-safe)
1263               (looking-at outline-regexp)
1264               (if (<= (org-reduced-level (funcall outline-level)) level)
1265                   (throw 'exit nil))))
1266           (org-narrow-to-subtree))
1267          (scope-is-list
1268           (let* ((files scope)
1269                  (scope 'agenda)
1270                  (p1 (copy-sequence params))
1271                  file)
1272             (setq p1 (plist-put p1 :tostring t))
1273             (setq p1 (plist-put p1 :multifile t))
1274             (setq p1 (plist-put p1 :scope 'file))
1275             (org-prepare-agenda-buffers files)
1276             (while (setq file (pop files))
1277               (with-current-buffer (find-buffer-visiting file)
1278                 (setq tbl1 (org-dblock-write:clocktable p1))
1279                 (when tbl1
1280                   (push (org-clocktable-add-file
1281                          file
1282                          (concat "| |*File time*|*"
1283                                  (org-minutes-to-hh:mm-string
1284                                   org-clock-file-total-minutes)
1285                                  "*|\n"
1286                                  tbl1)) tbl)
1287                   (setq total-time (+ (or total-time 0)
1288                                       org-clock-file-total-minutes))))))))
1289         (goto-char pos)
1290
1291         (unless scope-is-list
1292           (org-clock-sum ts te)
1293           (goto-char (point-min))
1294           (setq st t)
1295           (while (or (and (bobp) (prog1 st (setq st nil))
1296                           (get-text-property (point) :org-clock-minutes)
1297                           (setq p (point-min)))
1298                      (setq p (next-single-property-change (point) :org-clock-minutes)))
1299             (goto-char p)
1300             (when (setq time (get-text-property p :org-clock-minutes))
1301               (save-excursion
1302                 (beginning-of-line 1)
1303                 (when (and (looking-at (org-re "\\(\\*+\\)[ \t]+\\(.*?\\)\\([ \t]+:[[:alnum:]_@:]+:\\)?[ \t]*$"))
1304                            (setq level (org-reduced-level
1305                                         (- (match-end 1) (match-beginning 1))))
1306                            (<= level maxlevel))
1307                   (setq hlc (if emph (or (cdr (assoc level hlchars)) "") "")
1308                         hdl (if (not link)
1309                                 (match-string 2)
1310                               (org-make-link-string
1311                                (format "file:%s::%s"
1312                                        (buffer-file-name)
1313                                        (save-match-data
1314                                          (org-make-org-heading-search-string
1315                                           (match-string 2))))
1316                                (match-string 2)))
1317                         tsp (when timestamp
1318                               (setq props (org-entry-properties (point)))
1319                               (or (cdr (assoc "SCHEDULED" props))
1320                                   (cdr (assoc "TIMESTAMP" props))
1321                                   (cdr (assoc "DEADLINE" props))
1322                                   (cdr (assoc "TIMESTAMP_IA" props)))))
1323                   (if (and (not multifile) (= level 1)) (push "|-" tbl))
1324                   (push (concat
1325                          "| " (int-to-string level) "|"
1326                          (if timestamp (concat tsp "|") "")
1327                          hlc hdl hlc " |"
1328                          (make-string (1- level) ?|)
1329                          hlc (org-minutes-to-hh:mm-string time) hlc
1330                          " |") tbl))))))
1331         (setq tbl (nreverse tbl))
1332         (if tostring
1333             (if tbl (mapconcat 'identity tbl "\n") nil)
1334           (goto-char ins)
1335           (insert-before-markers
1336            (or header
1337                (concat
1338                 "Clock summary at ["
1339                 (substring
1340                  (format-time-string (cdr org-time-stamp-formats))
1341                  1 -1)
1342                 "]"
1343                 (if block (concat ", for " range-text ".") "")
1344                 "\n\n"))
1345            (if scope-is-list "|File" "")
1346            "|L|" (if timestamp "Timestamp|" "") "Headline|Time|\n")
1347           (setq total-time (or total-time org-clock-file-total-minutes))
1348           (insert-before-markers
1349            "|-\n|"
1350            (if scope-is-list "|" "")
1351            (if timestamp "|Timestamp|" "|")
1352            "*Total time*| *"
1353            (org-minutes-to-hh:mm-string (or total-time 0))
1354            "*|\n|-\n")
1355           (setq tbl (delq nil tbl))
1356           (if (and (stringp (car tbl)) (> (length (car tbl)) 1)
1357                    (equal (substring (car tbl) 0 2) "|-"))
1358               (pop tbl))
1359           (insert-before-markers (mapconcat
1360                                   'identity (delq nil tbl)
1361                                   (if scope-is-list "\n|-\n" "\n")))
1362           (backward-delete-char 1)
1363           (if (setq formula (plist-get params :formula))
1364               (cond
1365                ((eq formula '%)
1366                 (setq pcol (+ (if scope-is-list 1 0) maxlevel 3))
1367                 (insert
1368                  (format
1369                   "\n#+TBLFM: $%d='(org-clock-time%% @%d$%d $%d..$%d);%%.1f"
1370                   pcol
1371                   2
1372                   (+ 3 (if scope-is-list 1 0))
1373                   (+ (if scope-is-list 1 0) 3)
1374                   (1- pcol)))
1375                 (setq recalc t))
1376                ((stringp formula)
1377                 (insert "\n#+TBLFM: " formula)
1378                 (setq recalc t))
1379                (t (error "invalid formula in clocktable")))
1380             ;; Should we rescue an old formula?
1381             (when (stringp (setq content (plist-get params :content)))
1382               (when (string-match "^\\([ \t]*#\\+TBLFM:.*\\)" content)
1383                 (setq recalc t)
1384                 (insert "\n" (match-string 1 (plist-get params :content)))
1385                 (beginning-of-line 0))))
1386           (goto-char ipos)
1387           (skip-chars-forward "^|")
1388           (org-table-align)
1389           (when recalc
1390             (if (eq formula '%)
1391                 (save-excursion (org-table-goto-column pcol nil 'force)
1392                                 (insert "%")))
1393             (org-table-recalculate 'all))
1394           (when rm-file-column
1395             (forward-char 1)
1396             (org-table-delete-column)))))))
1397
1398 (defun org-clocktable-steps (params)
1399   (let* ((p1 (copy-sequence params))
1400          (ts (plist-get p1 :tstart))
1401          (te (plist-get p1 :tend))
1402          (step0 (plist-get p1 :step))
1403          (step (cdr (assoc step0 '((day . 86400) (week . 604800)))))
1404          (block (plist-get p1 :block))
1405          cc range-text)
1406     (when block
1407       (setq cc (org-clock-special-range block nil t)
1408             ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1409     (if ts (setq ts (org-float-time
1410                      (apply 'encode-time (org-parse-time-string ts)))))
1411     (if te (setq te (org-float-time
1412                      (apply 'encode-time (org-parse-time-string te)))))
1413     (setq p1 (plist-put p1 :header ""))
1414     (setq p1 (plist-put p1 :step nil))
1415     (setq p1 (plist-put p1 :block nil))
1416     (while (< ts te)
1417       (or (bolp) (insert "\n"))
1418       (setq p1 (plist-put p1 :tstart (format-time-string
1419                                       (org-time-stamp-format nil t)
1420                                       (seconds-to-time ts))))
1421       (setq p1 (plist-put p1 :tend (format-time-string
1422                                     (org-time-stamp-format nil t)
1423                                     (seconds-to-time (setq ts (+ ts step))))))
1424       (insert "\n" (if (eq step0 'day) "Daily report: " "Weekly report starting on: ")
1425               (plist-get p1 :tstart) "\n")
1426       (org-dblock-write:clocktable p1)
1427       (re-search-forward "#\\+END:")
1428       (end-of-line 0))))
1429
1430 (defun org-clocktable-add-file (file table)
1431   (if table
1432       (let ((lines (org-split-string table "\n"))
1433             (ff (file-name-nondirectory file)))
1434         (mapconcat 'identity
1435                    (mapcar (lambda (x)
1436                              (if (string-match org-table-dataline-regexp x)
1437                                  (concat "|" ff x)
1438                                x))
1439                            lines)
1440                    "\n"))))
1441
1442 (defun org-clock-time% (total &rest strings)
1443   "Compute a time fraction in percent.
1444 TOTAL s a time string like 10:21 specifying the total times.
1445 STRINGS is a list of strings that should be checked for a time.
1446 The first string that does have a time will be used.
1447 This function is made for clock tables."
1448   (let ((re "\\([0-9]+\\):\\([0-9]+\\)")
1449         tot s)
1450     (save-match-data
1451       (catch 'exit
1452         (if (not (string-match re total))
1453             (throw 'exit 0.)
1454           (setq tot (+ (string-to-number (match-string 2 total))
1455                        (* 60 (string-to-number (match-string 1 total)))))
1456           (if (= tot 0.) (throw 'exit 0.)))
1457         (while (setq s (pop strings))
1458           (if (string-match "\\([0-9]+\\):\\([0-9]+\\)" s)
1459               (throw 'exit
1460                      (/ (* 100.0 (+ (string-to-number (match-string 2 s))
1461                                     (* 60 (string-to-number (match-string 1 s)))))
1462                         tot))))
1463         0))))
1464
1465 (defun org-clock-save ()
1466   "Persist various clock-related data to disk.
1467 The details of what will be saved are regulated by the variable
1468 `org-clock-persist'."
1469   (when org-clock-persist
1470     (let (b)
1471       (with-current-buffer (find-file (expand-file-name org-clock-persist-file))
1472         (progn
1473           (delete-region (point-min) (point-max))
1474           ;;Store clock
1475           (insert (format ";; org-persist.el - %s at %s\n"
1476                           system-name (format-time-string
1477                                        (cdr org-time-stamp-formats))))
1478           (if (and (setq b (marker-buffer org-clock-marker))
1479                    (setq b (or (buffer-base-buffer b) b))
1480                    (buffer-live-p b)
1481                    (buffer-file-name b)
1482                    (or (not org-clock-persist-query-save)
1483                        (y-or-n-p (concat "Save current clock ("
1484                                          (substring-no-properties org-clock-heading)
1485                                          ") "))))
1486               (insert "(setq resume-clock '(\""
1487                       (buffer-file-name (marker-buffer org-clock-marker))
1488                       "\" . " (int-to-string (marker-position org-clock-marker))
1489                       "))\n"))
1490           ;; Store clocked task history. Tasks are stored reversed to make
1491           ;; reading simpler
1492           (when (and org-clock-history (eq org-clock-persist t))
1493             (insert
1494              "(setq stored-clock-history '("
1495              (mapconcat
1496               (lambda (m)
1497                 (when (and (setq b (marker-buffer m))
1498                            (setq b (or (buffer-base-buffer b) b))
1499                            (buffer-live-p b)
1500                            (buffer-file-name b))
1501                   (concat "(\"" (buffer-file-name b)
1502                           "\" . " (int-to-string (marker-position m))
1503                           ")")))
1504               (reverse org-clock-history) " ") "))\n"))
1505           (save-buffer)
1506           (kill-buffer (current-buffer)))))))
1507
1508 (defvar org-clock-loaded nil
1509   "Was the clock file loaded?")
1510
1511 (defun org-clock-load ()
1512   "Load clock-related data from disk, maybe resuming a stored clock."
1513   (when (and org-clock-persist (not org-clock-loaded))
1514     (let ((filename (expand-file-name org-clock-persist-file))
1515           (org-clock-in-resume 'auto-restart)
1516           resume-clock stored-clock-history)
1517       (if (not (file-readable-p filename))
1518           (message "Not restoring clock data; %s not found"
1519                    org-clock-persist-file)
1520         (message "%s" "Restoring clock data")
1521         (setq org-clock-loaded t)
1522         (load-file filename)
1523         ;; load history
1524         (when stored-clock-history
1525           (save-window-excursion
1526             (mapc (lambda (task)
1527                     (if (file-exists-p (car task))
1528                         (org-clock-history-push (cdr task)
1529                                                 (find-file (car task)))))
1530                   stored-clock-history)))
1531         ;; resume clock
1532         (when (and resume-clock org-clock-persist
1533                    (file-exists-p (car resume-clock))
1534                    (or (not org-clock-persist-query-resume)
1535                        (y-or-n-p
1536                         (concat
1537                          "Resume clock ("
1538                          (with-current-buffer (find-file (car resume-clock))
1539                            (save-excursion
1540                              (goto-char (cdr resume-clock))
1541                              (org-back-to-heading t)
1542                              (and (looking-at org-complex-heading-regexp)
1543                                   (match-string 4))))
1544                          ") "))))
1545           (when (file-exists-p (car resume-clock))
1546             (with-current-buffer (find-file (car resume-clock))
1547               (goto-char (cdr resume-clock))
1548               (org-clock-in)
1549               (if (org-invisible-p)
1550                   (org-show-context)))))))))
1551
1552 ;;;###autoload
1553 (defun org-clock-persistence-insinuate ()
1554   "Set up hooks for clock persistence"
1555   (add-hook 'org-mode-hook 'org-clock-load)
1556   (add-hook 'kill-emacs-hook 'org-clock-save))
1557
1558 ;; Suggested bindings
1559 (org-defkey org-mode-map "\C-c\C-x\C-e" 'org-clock-modify-effort-estimate)
1560
1561 (provide 'org-clock)
1562
1563 ;; arch-tag: 7b42c5d4-9b36-48be-97c0-66a869daed4c
1564
1565 ;;; org-clock.el ends here