test/src/eval-tests.el

   1 ;;; eval-tests.el --- unit tests for src/eval.c      -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2016-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Philipp Stephani <phst@google.com>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; Unit tests for src/eval.c.
  25
  26 ;;; Code:
  27
  28 (require 'ert)
  29
  30 (ert-deftest eval-tests--bug24673 ()
  31   "Check that Bug#24673 has been fixed."
  32   ;; This should not crash.
  33   (should-error (funcall '(closure)) :type 'invalid-function))
  34
  35 (defvar byte-compile-debug)
  36
  37 (ert-deftest eval-tests--bugs-24912-and-24913 ()
  38   "Check that Emacs doesn't accept weird argument lists.
  39 Bug#24912 and Bug#24913."
  40   (dolist (args '((&optional) (&rest) (&optional &rest) (&rest &optional)
  41                   (&optional &rest a) (&optional a &rest)
  42                   (&rest a &optional) (&rest &optional a)
  43                   (&optional &optional) (&optional &optional a)
  44                   (&optional a &optional b)
  45                   (&rest &rest) (&rest &rest a)
  46                   (&rest a &rest b)))
  47     (should-error (eval `(funcall (lambda ,args)) t) :type 'invalid-function)
  48     (should-error (byte-compile-check-lambda-list args))
  49     (let ((byte-compile-debug t))
  50       (should-error (eval `(byte-compile (lambda ,args)) t)))))
  51
  52
  53 (dolist (form '(let let*))
  54   (dolist (arg '(1 "a" [a]))
  55     (eval
  56      `(ert-deftest ,(intern (format "eval-tests--%s--%s" form (type-of arg))) ()
  57         ,(format "Check that the first argument of `%s' cannot be a %s"
  58                  form (type-of arg))
  59         (should-error (,form ,arg) :type 'wrong-type-argument))
  60      t)))
  61
  62 (ert-deftest eval-tests--if-dot-string ()
  63   "Check that Emacs rejects (if . \"string\")."
  64   (should-error (eval '(if . "abc")) :type 'wrong-type-argument)
  65   (let ((if-tail (list '(setcdr if-tail "abc") t)))
  66     (should-error (eval (cons 'if if-tail))))
  67   (let ((if-tail (list '(progn (setcdr if-tail "abc") nil) t)))
  68     (should-error (eval (cons 'if if-tail)))))
  69
  70 (ert-deftest eval-tests--let-with-circular-defs ()
  71   "Check that Emacs reports an error for (let VARS ...) when VARS is circular."
  72   (let ((vars (list 'v)))
  73     (setcdr vars vars)
  74     (dolist (let-sym '(let let*))
  75       (should-error (eval (list let-sym vars))))))
  76
  77 (ert-deftest eval-tests--mutating-cond ()
  78   "Check that Emacs doesn't crash on a cond clause that mutates during eval."
  79   (let ((clauses (list '((progn (setcdr clauses "ouch") nil)))))
  80     (should-error (eval (cons 'cond clauses)))))
  81
  82 (defun eval-tests--exceed-specbind-limit ()
  83   (defvar eval-tests--var1)
  84   (defvar eval-tests--var2)
  85   ;; Bind two variables, to make extra sure we hit the
  86   ;; `max-specpdl-size' limit before the `max-lisp-eval-depth' limit.
  87   (let ((eval-tests--var1 1)
  88         (eval-tests--var2 2))
  89     ;; Recurse until we hit the limit.
  90     (eval-tests--exceed-specbind-limit)))
  91
  92 (ert-deftest eval-exceed-specbind-with-signal-hook ()
  93   "Test for Bug#30481.
  94 Check that Emacs doesn't crash when exceeding specbind limit with
  95 `signal-hook-function' bound.  NOTE: Without the fix for
  96 Bug#30481, this test can appear to pass, but cause a
  97 crash/abort/malloc assert failure on the next test."
  98   (let ((max-specpdl-size (/ max-lisp-eval-depth 2))
  99         (signal-hook-function #'ignore))
 100     (should-error (eval-tests--exceed-specbind-limit))))
 101
 102 ;;; eval-tests.el ends here