lisp/progmodes/elisp-mode.el

   1 ;;; elisp-mode.el --- Emacs Lisp mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1999-2014 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Keywords: lisp, languages
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The major mode for editing Emacs Lisp code.
  27 ;; This mode is documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (require 'lisp-mode)
  32
  33 (defvar emacs-lisp-mode-abbrev-table nil)
  34 (define-abbrev-table 'emacs-lisp-mode-abbrev-table ()
  35   "Abbrev table for Emacs Lisp mode.
  36 It has `lisp-mode-abbrev-table' as its parent."
  37   :parents (list lisp-mode-abbrev-table))
  38
  39 (defvar emacs-lisp-mode-syntax-table
  40   (let ((table (make-syntax-table lisp--mode-syntax-table)))
  41     (modify-syntax-entry ?\[ "(]  " table)
  42     (modify-syntax-entry ?\] ")[  " table)
  43     table)
  44   "Syntax table used in `emacs-lisp-mode'.")
  45
  46 (defvar emacs-lisp-mode-map
  47   (let ((map (make-sparse-keymap "Emacs-Lisp"))
  48         (menu-map (make-sparse-keymap "Emacs-Lisp"))
  49         (lint-map (make-sparse-keymap))
  50         (prof-map (make-sparse-keymap))
  51         (tracing-map (make-sparse-keymap)))
  52     (set-keymap-parent map lisp-mode-shared-map)
  53     (define-key map "\e\t" 'completion-at-point)
  54     (define-key map "\e\C-x" 'eval-defun)
  55     (define-key map "\e\C-q" 'indent-pp-sexp)
  56     (bindings--define-key map [menu-bar emacs-lisp]
  57       (cons "Emacs-Lisp" menu-map))
  58     (bindings--define-key menu-map [eldoc]
  59       '(menu-item "Auto-Display Documentation Strings" eldoc-mode
  60                   :button (:toggle . (bound-and-true-p eldoc-mode))
  61                   :help "Display the documentation string for the item under cursor"))
  62     (bindings--define-key menu-map [checkdoc]
  63       '(menu-item "Check Documentation Strings" checkdoc
  64                   :help "Check documentation strings for style requirements"))
  65     (bindings--define-key menu-map [re-builder]
  66       '(menu-item "Construct Regexp" re-builder
  67                   :help "Construct a regexp interactively"))
  68     (bindings--define-key menu-map [tracing] (cons "Tracing" tracing-map))
  69     (bindings--define-key tracing-map [tr-a]
  70       '(menu-item "Untrace All" untrace-all
  71                   :help "Untrace all currently traced functions"))
  72     (bindings--define-key tracing-map [tr-uf]
  73       '(menu-item "Untrace Function..." untrace-function
  74                   :help "Untrace function, and possibly activate all remaining advice"))
  75     (bindings--define-key tracing-map [tr-sep] menu-bar-separator)
  76     (bindings--define-key tracing-map [tr-q]
  77       '(menu-item "Trace Function Quietly..." trace-function-background
  78                   :help "Trace the function with trace output going quietly to a buffer"))
  79     (bindings--define-key tracing-map [tr-f]
  80       '(menu-item "Trace Function..." trace-function
  81                   :help "Trace the function given as an argument"))
  82     (bindings--define-key menu-map [profiling] (cons "Profiling" prof-map))
  83     (bindings--define-key prof-map [prof-restall]
  84       '(menu-item "Remove Instrumentation for All Functions" elp-restore-all
  85                   :help "Restore the original definitions of all functions being profiled"))
  86     (bindings--define-key prof-map [prof-restfunc]
  87       '(menu-item "Remove Instrumentation for Function..." elp-restore-function
  88                   :help "Restore an instrumented function to its original definition"))
  89
  90     (bindings--define-key prof-map [sep-rem] menu-bar-separator)
  91     (bindings--define-key prof-map [prof-resall]
  92       '(menu-item "Reset Counters for All Functions" elp-reset-all
  93                   :help "Reset the profiling information for all functions being profiled"))
  94     (bindings--define-key prof-map [prof-resfunc]
  95       '(menu-item "Reset Counters for Function..." elp-reset-function
  96                   :help "Reset the profiling information for a function"))
  97     (bindings--define-key prof-map [prof-res]
  98       '(menu-item "Show Profiling Results" elp-results
  99                   :help "Display current profiling results"))
 100     (bindings--define-key prof-map [prof-pack]
 101       '(menu-item "Instrument Package..." elp-instrument-package
 102                   :help "Instrument for profiling all function that start with a prefix"))
 103     (bindings--define-key prof-map [prof-func]
 104       '(menu-item "Instrument Function..." elp-instrument-function
 105                   :help "Instrument a function for profiling"))
 106     ;; Maybe this should be in a separate submenu from the ELP stuff?
 107     (bindings--define-key prof-map [sep-natprof] menu-bar-separator)
 108     (bindings--define-key prof-map [prof-natprof-stop]
 109       '(menu-item "Stop Native Profiler" profiler-stop
 110                   :help "Stop recording profiling information"
 111                   :enable (and (featurep 'profiler)
 112                                (profiler-running-p))))
 113     (bindings--define-key prof-map [prof-natprof-report]
 114       '(menu-item "Show Profiler Report" profiler-report
 115                   :help "Show the current profiler report"
 116                   :enable (and (featurep 'profiler)
 117                                (profiler-running-p))))
 118     (bindings--define-key prof-map [prof-natprof-start]
 119       '(menu-item "Start Native Profiler..." profiler-start
 120                   :help "Start recording profiling information"))
 121
 122     (bindings--define-key menu-map [lint] (cons "Linting" lint-map))
 123     (bindings--define-key lint-map [lint-di]
 124       '(menu-item "Lint Directory..." elint-directory
 125                   :help "Lint a directory"))
 126     (bindings--define-key lint-map [lint-f]
 127       '(menu-item "Lint File..." elint-file
 128                   :help "Lint a file"))
 129     (bindings--define-key lint-map [lint-b]
 130       '(menu-item "Lint Buffer" elint-current-buffer
 131                   :help "Lint the current buffer"))
 132     (bindings--define-key lint-map [lint-d]
 133       '(menu-item "Lint Defun" elint-defun
 134                   :help "Lint the function at point"))
 135     (bindings--define-key menu-map [edebug-defun]
 136       '(menu-item "Instrument Function for Debugging" edebug-defun
 137                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 138                   :keys "C-u C-M-x"))
 139     (bindings--define-key menu-map [separator-byte] menu-bar-separator)
 140     (bindings--define-key menu-map [disas]
 141       '(menu-item "Disassemble Byte Compiled Object..." disassemble
 142                   :help "Print disassembled code for OBJECT in a buffer"))
 143     (bindings--define-key menu-map [byte-recompile]
 144       '(menu-item "Byte-recompile Directory..." byte-recompile-directory
 145                   :help "Recompile every `.el' file in DIRECTORY that needs recompilation"))
 146     (bindings--define-key menu-map [emacs-byte-compile-and-load]
 147       '(menu-item "Byte-compile and Load" emacs-lisp-byte-compile-and-load
 148                   :help "Byte-compile the current file (if it has changed), then load compiled code"))
 149     (bindings--define-key menu-map [byte-compile]
 150       '(menu-item "Byte-compile This File" emacs-lisp-byte-compile
 151                   :help "Byte compile the file containing the current buffer"))
 152     (bindings--define-key menu-map [separator-eval] menu-bar-separator)
 153     (bindings--define-key menu-map [ielm]
 154       '(menu-item "Interactive Expression Evaluation" ielm
 155                   :help "Interactively evaluate Emacs Lisp expressions"))
 156     (bindings--define-key menu-map [eval-buffer]
 157       '(menu-item "Evaluate Buffer" eval-buffer
 158                   :help "Execute the current buffer as Lisp code"))
 159     (bindings--define-key menu-map [eval-region]
 160       '(menu-item "Evaluate Region" eval-region
 161                   :help "Execute the region as Lisp code"
 162                   :enable mark-active))
 163     (bindings--define-key menu-map [eval-sexp]
 164       '(menu-item "Evaluate Last S-expression" eval-last-sexp
 165                   :help "Evaluate sexp before point; print value in echo area"))
 166     (bindings--define-key menu-map [separator-format] menu-bar-separator)
 167     (bindings--define-key menu-map [comment-region]
 168       '(menu-item "Comment Out Region" comment-region
 169                   :help "Comment or uncomment each line in the region"
 170                   :enable mark-active))
 171     (bindings--define-key menu-map [indent-region]
 172       '(menu-item "Indent Region" indent-region
 173                   :help "Indent each nonblank line in the region"
 174                   :enable mark-active))
 175     (bindings--define-key menu-map [indent-line]
 176       '(menu-item "Indent Line" lisp-indent-line))
 177     map)
 178   "Keymap for Emacs Lisp mode.
 179 All commands in `lisp-mode-shared-map' are inherited by this map.")
 180
 181 (defun emacs-lisp-byte-compile ()
 182   "Byte compile the file containing the current buffer."
 183   (interactive)
 184   (if buffer-file-name
 185       (byte-compile-file buffer-file-name)
 186     (error "The buffer must be saved in a file first")))
 187
 188 (defun emacs-lisp-byte-compile-and-load ()
 189   "Byte-compile the current file (if it has changed), then load compiled code."
 190   (interactive)
 191   (or buffer-file-name
 192       (error "The buffer must be saved in a file first"))
 193   (require 'bytecomp)
 194   ;; Recompile if file or buffer has changed since last compilation.
 195   (if (and (buffer-modified-p)
 196            (y-or-n-p (format "Save buffer %s first? " (buffer-name))))
 197       (save-buffer))
 198   (byte-recompile-file buffer-file-name nil 0 t))
 199
 200 (defun emacs-lisp-macroexpand ()
 201   "Macroexpand the form after point.
 202 Comments in the form will be lost."
 203   (interactive)
 204   (let* ((start (point))
 205          (exp (read (current-buffer)))
 206          ;; Compute it before, since it may signal errors.
 207          (new (macroexpand-1 exp)))
 208     (if (equal exp new)
 209         (message "Not a macro call, nothing to expand")
 210       (delete-region start (point))
 211       (pp new (current-buffer))
 212       (if (bolp) (delete-char -1))
 213       (indent-region start (point)))))
 214
 215 (defcustom emacs-lisp-mode-hook nil
 216   "Hook run when entering Emacs Lisp mode."
 217   :options '(eldoc-mode imenu-add-menubar-index checkdoc-minor-mode)
 218   :type 'hook
 219   :group 'lisp)
 220
 221 ;;;###autoload
 222 (define-derived-mode emacs-lisp-mode prog-mode "Emacs-Lisp"
 223   "Major mode for editing Lisp code to run in Emacs.
 224 Commands:
 225 Delete converts tabs to spaces as it moves back.
 226 Blank lines separate paragraphs.  Semicolons start comments.
 227
 228 \\{emacs-lisp-mode-map}"
 229   :group 'lisp
 230   (defvar xref-find-function)
 231   (defvar xref-identifier-completion-table-function)
 232   (lisp-mode-variables nil nil 'elisp)
 233   (setq imenu-case-fold-search nil)
 234   (setq-local eldoc-documentation-function
 235               #'elisp-eldoc-documentation-function)
 236   (setq-local xref-find-function #'elisp-xref-find)
 237   (setq-local xref-identifier-completion-table-function
 238               #'elisp--xref-identifier-completion-table)
 239   (add-hook 'completion-at-point-functions
 240             #'elisp-completion-at-point nil 'local))
 241
 242 ;;; Completion at point for Elisp
 243
 244 (defun elisp--local-variables-1 (vars sexp)
 245   "Return the vars locally bound around the witness, or nil if not found."
 246   (let (res)
 247     (while
 248         (unless
 249             (setq res
 250                   (pcase sexp
 251                     (`(,(or `let `let*) ,bindings)
 252                      (let ((vars vars))
 253                        (when (eq 'let* (car sexp))
 254                          (dolist (binding (cdr (reverse bindings)))
 255                            (push (or (car-safe binding) binding) vars)))
 256                        (elisp--local-variables-1
 257                         vars (car (cdr-safe (car (last bindings)))))))
 258                     (`(,(or `let `let*) ,bindings . ,body)
 259                      (let ((vars vars))
 260                        (dolist (binding bindings)
 261                          (push (or (car-safe binding) binding) vars))
 262                        (elisp--local-variables-1 vars (car (last body)))))
 263                     (`(lambda ,_args)
 264                      ;; FIXME: Look for the witness inside `args'.
 265                      (setq sexp nil))
 266                     (`(lambda ,args . ,body)
 267                      (elisp--local-variables-1
 268                       (append (remq '&optional (remq '&rest args)) vars)
 269                       (car (last body))))
 270                     (`(condition-case ,_ ,e) (elisp--local-variables-1 vars e))
 271                     (`(condition-case ,v ,_ . ,catches)
 272                      (elisp--local-variables-1
 273                       (cons v vars) (cdr (car (last catches)))))
 274                     (`(quote . ,_)
 275                      ;; FIXME: Look for the witness inside sexp.
 276                      (setq sexp nil))
 277                     ;; FIXME: Handle `cond'.
 278                     (`(,_ . ,_)
 279                      (elisp--local-variables-1 vars (car (last sexp))))
 280                     (`elisp--witness--lisp (or vars '(nil)))
 281                     (_ nil)))
 282           ;; We didn't find the witness in the last element so we try to
 283           ;; backtrack to the last-but-one.
 284           (setq sexp (ignore-errors (butlast sexp)))))
 285     res))
 286
 287 (defun elisp--local-variables ()
 288   "Return a list of locally let-bound variables at point."
 289   (save-excursion
 290     (skip-syntax-backward "w_")
 291     (let* ((ppss (syntax-ppss))
 292            (txt (buffer-substring-no-properties (or (car (nth 9 ppss)) (point))
 293                                                 (or (nth 8 ppss) (point))))
 294            (closer ()))
 295       (dolist (p (nth 9 ppss))
 296         (push (cdr (syntax-after p)) closer))
 297       (setq closer (apply #'string closer))
 298       (let* ((sexp (condition-case nil
 299                        (car (read-from-string
 300                              (concat txt "elisp--witness--lisp" closer)))
 301                      ((invalid-read-syntax end-of-file) nil)))
 302              (macroexpand-advice (lambda (expander form &rest args)
 303                                    (condition-case nil
 304                                        (apply expander form args)
 305                                      (error form))))
 306              (sexp
 307               (unwind-protect
 308                   (progn
 309                     (advice-add 'macroexpand :around macroexpand-advice)
 310                     (macroexpand-all sexp))
 311                 (advice-remove 'macroexpand macroexpand-advice)))
 312              (vars (elisp--local-variables-1 nil sexp)))
 313         (delq nil
 314               (mapcar (lambda (var)
 315                         (and (symbolp var)
 316                              (not (string-match (symbol-name var) "\\`[&_]"))
 317                              ;; Eliminate uninterned vars.
 318                              (intern-soft var)
 319                              var))
 320                       vars))))))
 321
 322 (defvar elisp--local-variables-completion-table
 323   ;; Use `defvar' rather than `defconst' since defconst would purecopy this
 324   ;; value, which would doubly fail: it would fail because purecopy can't
 325   ;; handle the recursive bytecode object, and it would fail because it would
 326   ;; move `lastpos' and `lastvars' to pure space where they'd be immutable!
 327   (let ((lastpos nil) (lastvars nil))
 328     (letrec ((hookfun (lambda ()
 329                         (setq lastpos nil)
 330                         (remove-hook 'post-command-hook hookfun))))
 331       (completion-table-dynamic
 332        (lambda (_string)
 333          (save-excursion
 334            (skip-syntax-backward "_w")
 335            (let ((newpos (cons (point) (current-buffer))))
 336              (unless (equal lastpos newpos)
 337                (add-hook 'post-command-hook hookfun)
 338                (setq lastpos newpos)
 339                (setq lastvars
 340                      (mapcar #'symbol-name (elisp--local-variables))))))
 341          lastvars)))))
 342
 343 (defun elisp--expect-function-p (pos)
 344   "Return non-nil if the symbol at point is expected to be a function."
 345   (or
 346    (and (eq (char-before pos) ?')
 347         (eq (char-before (1- pos)) ?#))
 348    (save-excursion
 349      (let ((parent (nth 1 (syntax-ppss pos))))
 350        (when parent
 351          (goto-char parent)
 352          (and
 353           (looking-at (concat "(\\(cl-\\)?"
 354                               (regexp-opt '("declare-function"
 355                                             "function" "defadvice"
 356                                             "callf" "callf2"
 357                                             "defsetf"))
 358                               "[ \t\r\n]+"))
 359           (eq (match-end 0) pos)))))))
 360
 361 (defun elisp--form-quoted-p (pos)
 362   "Return non-nil if the form at POS is not evaluated.
 363 It can be quoted, or be inside a quoted form."
 364   ;; FIXME: Do some macro expansion maybe.
 365   (save-excursion
 366     (let ((state (syntax-ppss pos)))
 367       (or (nth 8 state)   ; Code inside strings usually isn't evaluated.
 368           ;; FIXME: The 9th element is undocumented.
 369           (let ((nesting (cons (point) (reverse (nth 9 state))))
 370                 res)
 371             (while (and nesting (not res))
 372               (goto-char (pop nesting))
 373               (cond
 374                ((or (eq (char-after) ?\[)
 375                     (progn
 376                       (skip-chars-backward " ")
 377                       (memq (char-before) '(?' ?`))))
 378                 (setq res t))
 379                ((eq (char-before) ?,)
 380                 (setq nesting nil))))
 381             res)))))
 382
 383 ;; FIXME: Support for Company brings in features which straddle eldoc.
 384 ;; We should consolidate this, so that major modes can provide all that
 385 ;; data all at once:
 386 ;; - a function to extract "the reference at point" (may be more complex
 387 ;;     than a mere string, to distinguish various namespaces).
 388 ;; - a function to jump to such a reference.
 389 ;; - a function to show the signature/interface of such a reference.
 390 ;; - a function to build a help-buffer about that reference.
 391 ;; FIXME: Those functions should also be used by the normal completion code in
 392 ;; the *Completions* buffer.
 393
 394 (defun elisp--company-doc-buffer (str)
 395   (let ((symbol (intern-soft str)))
 396     ;; FIXME: we really don't want to "display-buffer and then undo it".
 397     (save-window-excursion
 398       ;; Make sure we don't display it in another frame, otherwise
 399       ;; save-window-excursion won't be able to undo it.
 400       (let ((display-buffer-overriding-action
 401              '(nil . ((inhibit-switch-frame . t)))))
 402         (ignore-errors
 403           (cond
 404            ((fboundp symbol) (describe-function symbol))
 405            ((boundp symbol) (describe-variable symbol))
 406            ((featurep symbol) (describe-package symbol))
 407            ((facep symbol) (describe-face symbol))
 408            (t (signal 'user-error nil)))
 409           (help-buffer))))))
 410
 411 (defun elisp--company-doc-string (str)
 412   (let* ((symbol (intern-soft str))
 413          (doc (if (fboundp symbol)
 414                   (documentation symbol t)
 415                 (documentation-property symbol 'variable-documentation t))))
 416     (and (stringp doc)
 417          (string-match ".*$" doc)
 418          (match-string 0 doc))))
 419
 420 (declare-function find-library-name "find-func" (library))
 421
 422 (defvar elisp--identifier-types '(defun defvar feature defface))
 423
 424 (defun elisp--identifier-location (type sym)
 425   (pcase (cons type sym)
 426     (`(defun . ,(pred fboundp))
 427      (find-definition-noselect sym nil))
 428     (`(defvar . ,(pred boundp))
 429      (find-definition-noselect sym 'defvar))
 430     (`(defface . ,(pred facep))
 431      (find-definition-noselect sym 'defface))
 432     (`(feature . ,(pred featurep))
 433      (require 'find-func)
 434      (cons (find-file-noselect (find-library-name
 435                                 (symbol-name sym)))
 436            1))))
 437
 438 (defun elisp--company-location (str)
 439   (catch 'res
 440     (let ((sym (intern-soft str)))
 441       (when sym
 442         (dolist (type elisp--identifier-types)
 443           (let ((loc (elisp--identifier-location type sym)))
 444             (and loc (throw 'res loc))))))))
 445
 446 (defvar elisp--identifier-completion-table
 447   (apply-partially #'completion-table-with-predicate
 448                    obarray
 449                    (lambda (sym)
 450                      (or (boundp sym)
 451                          (fboundp sym)
 452                          (featurep sym)
 453                          (symbol-plist sym)))
 454                    'strict))
 455
 456 (defun elisp-completion-at-point ()
 457   "Function used for `completion-at-point-functions' in `emacs-lisp-mode'."
 458   (with-syntax-table emacs-lisp-mode-syntax-table
 459     (let* ((pos (point))
 460            (beg (condition-case nil
 461                     (save-excursion
 462                       (backward-sexp 1)
 463                       (skip-syntax-forward "'")
 464                       (point))
 465                   (scan-error pos)))
 466            (end
 467             (unless (or (eq beg (point-max))
 468                         (member (char-syntax (char-after beg))
 469                                 '(?\s ?\" ?\( ?\))))
 470               (condition-case nil
 471                   (save-excursion
 472                     (goto-char beg)
 473                     (forward-sexp 1)
 474                     (skip-chars-backward "'")
 475                     (when (>= (point) pos)
 476                       (point)))
 477                 (scan-error pos))))
 478            ;; t if in function position.
 479            (funpos (eq (char-before beg) ?\()))
 480       (when (and end (or (not (nth 8 (syntax-ppss)))
 481                          (eq (char-before beg) ?`)))
 482         (let ((table-etc
 483                (if (not funpos)
 484                    ;; FIXME: We could look at the first element of the list and
 485                    ;; use it to provide a more specific completion table in some
 486                    ;; cases.  E.g. filter out keywords that are not understood by
 487                    ;; the macro/function being called.
 488                    (cond
 489                     ((elisp--expect-function-p beg)
 490                      (list nil obarray
 491                            :predicate #'fboundp
 492                            :company-doc-buffer #'elisp--company-doc-buffer
 493                            :company-docsig #'elisp--company-doc-string
 494                            :company-location #'elisp--company-location))
 495                     ((elisp--form-quoted-p beg)
 496                      ;; Don't include all symbols (bug#16646).
 497                      (list nil elisp--identifier-completion-table
 498                            :annotation-function
 499                            (lambda (str) (if (fboundp (intern-soft str)) " <f>"))
 500                            :company-doc-buffer #'elisp--company-doc-buffer
 501                            :company-docsig #'elisp--company-doc-string
 502                            :company-location #'elisp--company-location))
 503                     (t
 504                      (list nil (completion-table-merge
 505                                 elisp--local-variables-completion-table
 506                                 (apply-partially #'completion-table-with-predicate
 507                                                  obarray
 508                                                  #'boundp
 509                                                  'strict))
 510                            :company-doc-buffer #'elisp--company-doc-buffer
 511                            :company-docsig #'elisp--company-doc-string
 512                            :company-location #'elisp--company-location)))
 513                  ;; Looks like a funcall position.  Let's double check.
 514                  (save-excursion
 515                    (goto-char (1- beg))
 516                    (let ((parent
 517                           (condition-case nil
 518                               (progn (up-list -1) (forward-char 1)
 519                                      (let ((c (char-after)))
 520                                        (if (eq c ?\() ?\(
 521                                          (if (memq (char-syntax c) '(?w ?_))
 522                                              (read (current-buffer))))))
 523                             (error nil))))
 524                      (pcase parent
 525                        ;; FIXME: Rather than hardcode special cases here,
 526                        ;; we should use something like a symbol-property.
 527                        (`declare
 528                         (list t (mapcar (lambda (x) (symbol-name (car x)))
 529                                         (delete-dups
 530                                          ;; FIXME: We should include some
 531                                          ;; docstring with each entry.
 532                                          (append
 533                                           macro-declarations-alist
 534                                           defun-declarations-alist)))))
 535                        ((and (or `condition-case `condition-case-unless-debug)
 536                              (guard (save-excursion
 537                                       (ignore-errors
 538                                         (forward-sexp 2)
 539                                         (< (point) beg)))))
 540                         (list t obarray
 541                               :predicate (lambda (sym) (get sym 'error-conditions))))
 542                        ((and ?\(
 543                              (guard (save-excursion
 544                                       (goto-char (1- beg))
 545                                       (up-list -1)
 546                                       (forward-symbol -1)
 547                                       (looking-at "\\_<let\\*?\\_>"))))
 548                         (list t obarray
 549                               :predicate #'boundp
 550                               :company-doc-buffer #'elisp--company-doc-buffer
 551                               :company-docsig #'elisp--company-doc-string
 552                               :company-location #'elisp--company-location))
 553                        (_ (list nil obarray
 554                                 :predicate #'fboundp
 555                                 :company-doc-buffer #'elisp--company-doc-buffer
 556                                 :company-docsig #'elisp--company-doc-string
 557                                 :company-location #'elisp--company-location
 558                                 ))))))))
 559           (nconc (list beg end)
 560                  (if (null (car table-etc))
 561                      (cdr table-etc)
 562                    (cons
 563                     (if (memq (char-syntax (or (char-after end) ?\s))
 564                               '(?\s ?>))
 565                         (cadr table-etc)
 566                       (apply-partially 'completion-table-with-terminator
 567                                        " " (cadr table-etc)))
 568                     (cddr table-etc)))))))))
 569
 570 (define-obsolete-function-alias
 571   'lisp-completion-at-point 'elisp-completion-at-point "25.1")
 572
 573 ;;; Xref backend
 574
 575 (declare-function xref-make-buffer-location "xref" (buffer position))
 576 (declare-function xref-make-bogus-location "xref" (message))
 577 (declare-function xref-make "xref" (description location))
 578
 579 (defun elisp-xref-find (action id)
 580   (pcase action
 581     (`definitions
 582       (let ((sym (intern-soft id)))
 583         (when sym
 584           (elisp--xref-find-definitions sym))))
 585     (`apropos
 586      (elisp--xref-find-apropos id))))
 587
 588 (defun elisp--xref-find-definitions (symbol)
 589   (save-excursion
 590     (let (lst)
 591       (dolist (type elisp--identifier-types)
 592         (let ((loc
 593                (condition-case err
 594                    (let ((buf-pos (elisp--identifier-location type symbol)))
 595                      (when buf-pos
 596                        (xref-make-buffer-location (car buf-pos)
 597                                                   (or (cdr buf-pos) 1))))
 598                  (error
 599                   (xref-make-bogus-location (error-message-string err))))))
 600           (when loc
 601             (push
 602              (xref-make (format "(%s %s)" type symbol)
 603                         loc)
 604              lst))))
 605       lst)))
 606
 607 (defun elisp--xref-find-apropos (regexp)
 608   (apply #'nconc
 609          (let (lst)
 610            (dolist (sym (apropos-internal regexp))
 611             (push (elisp--xref-find-definitions sym) lst))
 612            (nreverse lst))))
 613
 614 (defun elisp--xref-identifier-completion-table ()
 615   elisp--identifier-completion-table)
 616
 617 ;;; Elisp Interaction mode
 618
 619 (defvar lisp-interaction-mode-map
 620   (let ((map (make-sparse-keymap))
 621         (menu-map (make-sparse-keymap "Lisp-Interaction")))
 622     (set-keymap-parent map lisp-mode-shared-map)
 623     (define-key map "\e\C-x" 'eval-defun)
 624     (define-key map "\e\C-q" 'indent-pp-sexp)
 625     (define-key map "\e\t" 'completion-at-point)
 626     (define-key map "\n" 'eval-print-last-sexp)
 627     (bindings--define-key map [menu-bar lisp-interaction]
 628       (cons "Lisp-Interaction" menu-map))
 629     (bindings--define-key menu-map [eval-defun]
 630       '(menu-item "Evaluate Defun" eval-defun
 631                   :help "Evaluate the top-level form containing point, or after point"))
 632     (bindings--define-key menu-map [eval-print-last-sexp]
 633       '(menu-item "Evaluate and Print" eval-print-last-sexp
 634                   :help "Evaluate sexp before point; print value into current buffer"))
 635     (bindings--define-key menu-map [edebug-defun-lisp-interaction]
 636       '(menu-item "Instrument Function for Debugging" edebug-defun
 637                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 638                   :keys "C-u C-M-x"))
 639     (bindings--define-key menu-map [indent-pp-sexp]
 640       '(menu-item "Indent or Pretty-Print" indent-pp-sexp
 641                   :help "Indent each line of the list starting just after point, or prettyprint it"))
 642     (bindings--define-key menu-map [complete-symbol]
 643       '(menu-item "Complete Lisp Symbol" completion-at-point
 644                   :help "Perform completion on Lisp symbol preceding point"))
 645     map)
 646   "Keymap for Lisp Interaction mode.
 647 All commands in `lisp-mode-shared-map' are inherited by this map.")
 648
 649 (define-derived-mode lisp-interaction-mode emacs-lisp-mode "Lisp Interaction"
 650   "Major mode for typing and evaluating Lisp forms.
 651 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 652 before point, and prints its value into the buffer, advancing point.
 653 Note that printing is controlled by `eval-expression-print-length'
 654 and `eval-expression-print-level'.
 655
 656 Commands:
 657 Delete converts tabs to spaces as it moves back.
 658 Paragraphs are separated only by blank lines.
 659 Semicolons start comments.
 660
 661 \\{lisp-interaction-mode-map}"
 662   :abbrev-table nil)
 663
 664 ;;; Emacs Lisp Byte-Code mode
 665
 666 (eval-and-compile
 667   (defconst emacs-list-byte-code-comment-re
 668     (concat "\\(#\\)@\\([0-9]+\\) "
 669             ;; Make sure it's a docstring and not a lazy-loaded byte-code.
 670             "\\(?:[^(]\\|([^\"]\\)")))
 671
 672 (defun elisp--byte-code-comment (end &optional _point)
 673   "Try to syntactically mark the #@NNN ....^_ docstrings in byte-code files."
 674   (let ((ppss (syntax-ppss)))
 675     (when (and (nth 4 ppss)
 676                (eq (char-after (nth 8 ppss)) ?#))
 677       (let* ((n (save-excursion
 678                   (goto-char (nth 8 ppss))
 679                   (when (looking-at emacs-list-byte-code-comment-re)
 680                     (string-to-number (match-string 2)))))
 681              ;; `maxdiff' tries to make sure the loop below terminates.
 682              (maxdiff n))
 683         (when n
 684           (let* ((bchar (match-end 2))
 685                  (b (position-bytes bchar)))
 686             (goto-char (+ b n))
 687             (while (let ((diff (- (position-bytes (point)) b n)))
 688                      (unless (zerop diff)
 689                        (when (> diff maxdiff) (setq diff maxdiff))
 690                        (forward-char (- diff))
 691                        (setq maxdiff (if (> diff 0) diff
 692                                        (max (1- maxdiff) 1)))
 693                        t))))
 694           (if (<= (point) end)
 695               (put-text-property (1- (point)) (point)
 696                                  'syntax-table
 697                                  (string-to-syntax "> b"))
 698             (goto-char end)))))))
 699
 700 (defun elisp-byte-code-syntax-propertize (start end)
 701   (elisp--byte-code-comment end (point))
 702   (funcall
 703    (syntax-propertize-rules
 704     (emacs-list-byte-code-comment-re
 705      (1 (prog1 "< b" (elisp--byte-code-comment end (point))))))
 706    start end))
 707
 708 ;;;###autoload
 709 (add-to-list 'auto-mode-alist '("\\.elc\\'" . elisp-byte-code-mode))
 710 ;;;###autoload
 711 (define-derived-mode elisp-byte-code-mode emacs-lisp-mode
 712   "Elisp-Byte-Code"
 713   "Major mode for *.elc files."
 714   ;; TODO: Add way to disassemble byte-code under point.
 715   (setq-local open-paren-in-column-0-is-defun-start nil)
 716   (setq-local syntax-propertize-function
 717               #'elisp-byte-code-syntax-propertize))
 718
 719
 720 ;;; Globally accessible functionality
 721
 722 (defun eval-print-last-sexp (&optional eval-last-sexp-arg-internal)
 723   "Evaluate sexp before point; print value into current buffer.
 724
 725 Normally, this function truncates long output according to the value
 726 of the variables `eval-expression-print-length' and
 727 `eval-expression-print-level'.  With a prefix argument of zero,
 728 however, there is no such truncation.  Such a prefix argument
 729 also causes integers to be printed in several additional formats
 730 \(octal, hexadecimal, and character).
 731
 732 If `eval-expression-debug-on-error' is non-nil, which is the default,
 733 this command arranges for all errors to enter the debugger."
 734   (interactive "P")
 735   (let ((standard-output (current-buffer)))
 736     (terpri)
 737     (eval-last-sexp (or eval-last-sexp-arg-internal t))
 738     (terpri)))
 739
 740
 741 (defun last-sexp-setup-props (beg end value alt1 alt2)
 742   "Set up text properties for the output of `elisp--eval-last-sexp'.
 743 BEG and END are the start and end of the output in current-buffer.
 744 VALUE is the Lisp value printed, ALT1 and ALT2 are strings for the
 745 alternative printed representations that can be displayed."
 746   (let ((map (make-sparse-keymap)))
 747     (define-key map "\C-m" 'elisp-last-sexp-toggle-display)
 748     (define-key map [down-mouse-2] 'mouse-set-point)
 749     (define-key map [mouse-2] 'elisp-last-sexp-toggle-display)
 750     (add-text-properties
 751      beg end
 752      `(printed-value (,value ,alt1 ,alt2)
 753                      mouse-face highlight
 754                      keymap ,map
 755                      help-echo "RET, mouse-2: toggle abbreviated display"
 756                      rear-nonsticky (mouse-face keymap help-echo
 757                                                 printed-value)))))
 758
 759
 760 (defun elisp-last-sexp-toggle-display (&optional _arg)
 761   "Toggle between abbreviated and unabbreviated printed representations."
 762   (interactive "P")
 763   (save-restriction
 764     (widen)
 765     (let ((value (get-text-property (point) 'printed-value)))
 766       (when value
 767         (let ((beg (or (previous-single-property-change (min (point-max) (1+ (point)))
 768                                                         'printed-value)
 769                        (point)))
 770               (end (or (next-single-char-property-change (point) 'printed-value) (point)))
 771               (standard-output (current-buffer))
 772               (point (point)))
 773           (delete-region beg end)
 774           (insert (nth 1 value))
 775           (or (= beg point)
 776               (setq point (1- (point))))
 777           (last-sexp-setup-props beg (point)
 778                                  (nth 0 value)
 779                                  (nth 2 value)
 780                                  (nth 1 value))
 781           (goto-char (min (point-max) point)))))))
 782
 783 (defun prin1-char (char)                ;FIXME: Move it, e.g. to simple.el.
 784   "Return a string representing CHAR as a character rather than as an integer.
 785 If CHAR is not a character, return nil."
 786   (and (integerp char)
 787        (eventp char)
 788        (let ((c (event-basic-type char))
 789              (mods (event-modifiers char))
 790              string)
 791          ;; Prevent ?A from turning into ?\S-a.
 792          (if (and (memq 'shift mods)
 793                   (zerop (logand char ?\S-\^@))
 794                   (not (let ((case-fold-search nil))
 795                          (char-equal c (upcase c)))))
 796              (setq c (upcase c) mods nil))
 797          ;; What string are we considering using?
 798          (condition-case nil
 799              (setq string
 800                    (concat
 801                     "?"
 802                     (mapconcat
 803                      (lambda (modif)
 804                        (cond ((eq modif 'super) "\\s-")
 805                              (t (string ?\\ (upcase (aref (symbol-name modif) 0)) ?-))))
 806                      mods "")
 807                     (cond
 808                      ((memq c '(?\; ?\( ?\) ?\{ ?\} ?\[ ?\] ?\" ?\' ?\\)) (string ?\\ c))
 809                      ((eq c 127) "\\C-?")
 810                      (t
 811                       (string c)))))
 812            (error nil))
 813          ;; Verify the string reads a CHAR, not to some other character.
 814          ;; If it doesn't, return nil instead.
 815          (and string
 816               (= (car (read-from-string string)) char)
 817               string))))
 818
 819 (defun elisp--preceding-sexp ()
 820   "Return sexp before the point."
 821   (let ((opoint (point))
 822         ignore-quotes
 823         expr)
 824     (save-excursion
 825       (with-syntax-table emacs-lisp-mode-syntax-table
 826         ;; If this sexp appears to be enclosed in `...'
 827         ;; then ignore the surrounding quotes.
 828         (setq ignore-quotes
 829               (or (eq (following-char) ?\')
 830                   (eq (preceding-char) ?\')))
 831         (forward-sexp -1)
 832         ;; If we were after `?\e' (or similar case),
 833         ;; use the whole thing, not just the `e'.
 834         (when (eq (preceding-char) ?\\)
 835           (forward-char -1)
 836           (when (eq (preceding-char) ??)
 837             (forward-char -1)))
 838
 839         ;; Skip over hash table read syntax.
 840         (and (> (point) (1+ (point-min)))
 841              (looking-back "#s" (- (point) 2))
 842              (forward-char -2))
 843
 844         ;; Skip over `#N='s.
 845         (when (eq (preceding-char) ?=)
 846           (let (labeled-p)
 847             (save-excursion
 848               (skip-chars-backward "0-9#=")
 849               (setq labeled-p (looking-at "\\(#[0-9]+=\\)+")))
 850             (when labeled-p
 851               (forward-sexp -1))))
 852
 853         (save-restriction
 854           (if (and ignore-quotes (eq (following-char) ?`))
 855               ;; vladimir@cs.ualberta.ca 30-Jul-1997: Skip ` in `variable' so
 856               ;; that the value is returned, not the name.
 857               (forward-char))
 858           (when (looking-at ",@?") (goto-char (match-end 0)))
 859           (narrow-to-region (point-min) opoint)
 860           (setq expr (read (current-buffer)))
 861           ;; If it's an (interactive ...) form, it's more useful to show how an
 862           ;; interactive call would use it.
 863           ;; FIXME: Is it really the right place for this?
 864           (when (eq (car-safe expr) 'interactive)
 865                (setq expr
 866                   `(call-interactively
 867                     (lambda (&rest args) ,expr args))))
 868           expr)))))
 869 (define-obsolete-function-alias 'preceding-sexp 'elisp--preceding-sexp "25.1")
 870
 871 (defun elisp--eval-last-sexp (eval-last-sexp-arg-internal)
 872   "Evaluate sexp before point; print value in the echo area.
 873 With argument, print output into current buffer.
 874 With a zero prefix arg, print output with no limit on the length
 875 and level of lists, and include additional formats for integers
 876 \(octal, hexadecimal, and character)."
 877   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t)))
 878     ;; Setup the lexical environment if lexical-binding is enabled.
 879     (elisp--eval-last-sexp-print-value
 880      (eval (eval-sexp-add-defvars (elisp--preceding-sexp)) lexical-binding)
 881      eval-last-sexp-arg-internal)))
 882
 883
 884 (defun elisp--eval-last-sexp-print-value (value &optional eval-last-sexp-arg-internal)
 885   (let ((unabbreviated (let ((print-length nil) (print-level nil))
 886                          (prin1-to-string value)))
 887         (print-length (and (not (zerop (prefix-numeric-value
 888                                         eval-last-sexp-arg-internal)))
 889                            eval-expression-print-length))
 890         (print-level (and (not (zerop (prefix-numeric-value
 891                                        eval-last-sexp-arg-internal)))
 892                           eval-expression-print-level))
 893         (beg (point))
 894         end)
 895     (prog1
 896         (prin1 value)
 897       (let ((str (eval-expression-print-format value)))
 898         (if str (princ str)))
 899       (setq end (point))
 900       (when (and (bufferp standard-output)
 901                  (or (not (null print-length))
 902                      (not (null print-level)))
 903                  (not (string= unabbreviated
 904                                (buffer-substring-no-properties beg end))))
 905         (last-sexp-setup-props beg end value
 906                                unabbreviated
 907                                (buffer-substring-no-properties beg end))
 908         ))))
 909
 910
 911 (defvar elisp--eval-last-sexp-fake-value (make-symbol "t"))
 912
 913 (defun eval-sexp-add-defvars (exp &optional pos)
 914   "Prepend EXP with all the `defvar's that precede it in the buffer.
 915 POS specifies the starting position where EXP was found and defaults to point."
 916   (setq exp (macroexpand-all exp))      ;Eager macro-expansion.
 917   (if (not lexical-binding)
 918       exp
 919     (save-excursion
 920       (unless pos (setq pos (point)))
 921       (let ((vars ()))
 922         (goto-char (point-min))
 923         (while (re-search-forward
 924                 "(def\\(?:var\\|const\\|custom\\)[ \t\n]+\\([^; '()\n\t]+\\)"
 925                 pos t)
 926           (let ((var (intern (match-string 1))))
 927             (and (not (special-variable-p var))
 928                  (save-excursion
 929                    (zerop (car (syntax-ppss (match-beginning 0)))))
 930               (push var vars))))
 931         `(progn ,@(mapcar (lambda (v) `(defvar ,v)) vars) ,exp)))))
 932
 933 (defun eval-last-sexp (eval-last-sexp-arg-internal)
 934   "Evaluate sexp before point; print value in the echo area.
 935 Interactively, with prefix argument, print output into current buffer.
 936
 937 Normally, this function truncates long output according to the value
 938 of the variables `eval-expression-print-length' and
 939 `eval-expression-print-level'.  With a prefix argument of zero,
 940 however, there is no such truncation.  Such a prefix argument
 941 also causes integers to be printed in several additional formats
 942 \(octal, hexadecimal, and character).
 943
 944 If `eval-expression-debug-on-error' is non-nil, which is the default,
 945 this command arranges for all errors to enter the debugger."
 946   (interactive "P")
 947   (if (null eval-expression-debug-on-error)
 948       (elisp--eval-last-sexp eval-last-sexp-arg-internal)
 949     (let ((value
 950            (let ((debug-on-error elisp--eval-last-sexp-fake-value))
 951              (cons (elisp--eval-last-sexp eval-last-sexp-arg-internal)
 952                    debug-on-error))))
 953       (unless (eq (cdr value) elisp--eval-last-sexp-fake-value)
 954         (setq debug-on-error (cdr value)))
 955       (car value))))
 956
 957 (defun elisp--eval-defun-1 (form)
 958   "Treat some expressions specially.
 959 Reset the `defvar' and `defcustom' variables to the initial value.
 960 \(For `defcustom', use the :set function if there is one.)
 961 Reinitialize the face according to the `defface' specification."
 962   ;; The code in edebug-defun should be consistent with this, but not
 963   ;; the same, since this gets a macroexpanded form.
 964   (cond ((not (listp form))
 965          form)
 966         ((and (eq (car form) 'defvar)
 967               (cdr-safe (cdr-safe form))
 968               (boundp (cadr form)))
 969          ;; Force variable to be re-set.
 970          `(progn (defvar ,(nth 1 form) nil ,@(nthcdr 3 form))
 971                  (setq-default ,(nth 1 form) ,(nth 2 form))))
 972         ;; `defcustom' is now macroexpanded to
 973         ;; `custom-declare-variable' with a quoted value arg.
 974         ((and (eq (car form) 'custom-declare-variable)
 975               (default-boundp (eval (nth 1 form) lexical-binding)))
 976          ;; Force variable to be bound, using :set function if specified.
 977          (let ((setfunc (memq :set form)))
 978            (when setfunc
 979              (setq setfunc (car-safe (cdr-safe setfunc)))
 980              (or (functionp setfunc) (setq setfunc nil)))
 981            (funcall (or setfunc 'set-default)
 982                     (eval (nth 1 form) lexical-binding)
 983                     ;; The second arg is an expression that evaluates to
 984                     ;; an expression.  The second evaluation is the one
 985                     ;; normally performed not by normal execution but by
 986                     ;; custom-initialize-set (for example), which does not
 987                     ;; use lexical-binding.
 988                     (eval (eval (nth 2 form) lexical-binding))))
 989          form)
 990         ;; `defface' is macroexpanded to `custom-declare-face'.
 991         ((eq (car form) 'custom-declare-face)
 992          ;; Reset the face.
 993          (let ((face-symbol (eval (nth 1 form) lexical-binding)))
 994            (setq face-new-frame-defaults
 995                  (assq-delete-all face-symbol face-new-frame-defaults))
 996            (put face-symbol 'face-defface-spec nil)
 997            (put face-symbol 'face-override-spec nil))
 998          form)
 999         ((eq (car form) 'progn)
1000          (cons 'progn (mapcar #'elisp--eval-defun-1 (cdr form))))
1001         (t form)))
1002
1003 (defun elisp--eval-defun ()
1004   "Evaluate defun that point is in or before.
1005 The value is displayed in the echo area.
1006 If the current defun is actually a call to `defvar',
1007 then reset the variable using the initial value expression
1008 even if the variable already has some other value.
1009 \(Normally `defvar' does not change the variable's value
1010 if it already has a value.\)
1011
1012 Return the result of evaluation."
1013   ;; FIXME: the print-length/level bindings should only be applied while
1014   ;; printing, not while evaluating.
1015   (let ((debug-on-error eval-expression-debug-on-error)
1016         (print-length eval-expression-print-length)
1017         (print-level eval-expression-print-level))
1018     (save-excursion
1019       ;; Arrange for eval-region to "read" the (possibly) altered form.
1020       ;; eval-region handles recording which file defines a function or
1021       ;; variable.
1022       (let ((standard-output t)
1023             beg end form)
1024         ;; Read the form from the buffer, and record where it ends.
1025         (save-excursion
1026           (end-of-defun)
1027           (beginning-of-defun)
1028           (setq beg (point))
1029           (setq form (read (current-buffer)))
1030           (setq end (point)))
1031         ;; Alter the form if necessary.
1032         (let ((form (eval-sexp-add-defvars
1033                      (elisp--eval-defun-1 (macroexpand form)))))
1034           (eval-region beg end standard-output
1035                        (lambda (_ignore)
1036                          ;; Skipping to the end of the specified region
1037                          ;; will make eval-region return.
1038                          (goto-char end)
1039                          form))))))
1040   (let ((str (eval-expression-print-format (car values))))
1041     (if str (princ str)))
1042   ;; The result of evaluation has been put onto VALUES.  So return it.
1043   (car values))
1044
1045 (defun eval-defun (edebug-it)
1046   "Evaluate the top-level form containing point, or after point.
1047
1048 If the current defun is actually a call to `defvar' or `defcustom',
1049 evaluating it this way resets the variable using its initial value
1050 expression (using the defcustom's :set function if there is one), even
1051 if the variable already has some other value.  \(Normally `defvar' and
1052 `defcustom' do not alter the value if there already is one.)  In an
1053 analogous way, evaluating a `defface' overrides any customizations of
1054 the face, so that it becomes defined exactly as the `defface' expression
1055 says.
1056
1057 If `eval-expression-debug-on-error' is non-nil, which is the default,
1058 this command arranges for all errors to enter the debugger.
1059
1060 With a prefix argument, instrument the code for Edebug.
1061
1062 If acting on a `defun' for FUNCTION, and the function was
1063 instrumented, `Edebug: FUNCTION' is printed in the echo area.  If not
1064 instrumented, just FUNCTION is printed.
1065
1066 If not acting on a `defun', the result of evaluation is displayed in
1067 the echo area.  This display is controlled by the variables
1068 `eval-expression-print-length' and `eval-expression-print-level',
1069 which see."
1070   (interactive "P")
1071   (cond (edebug-it
1072          (require 'edebug)
1073          (eval-defun (not edebug-all-defs)))
1074         (t
1075          (if (null eval-expression-debug-on-error)
1076              (elisp--eval-defun)
1077            (let (new-value value)
1078              (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1079                (setq value (elisp--eval-defun))
1080                (setq new-value debug-on-error))
1081              (unless (eq elisp--eval-last-sexp-fake-value new-value)
1082                (setq debug-on-error new-value))
1083              value)))))
1084
1085 ;;; ElDoc Support
1086
1087 (defvar elisp--eldoc-last-data (make-vector 3 nil)
1088   "Bookkeeping; elements are as follows:
1089   0 - contains the last symbol read from the buffer.
1090   1 - contains the string last displayed in the echo area for variables,
1091       or argument string for functions.
1092   2 - 'function if function args, 'variable if variable documentation.")
1093
1094 (defun elisp-eldoc-documentation-function ()
1095   "`eldoc-documentation-function' (which see) for Emacs Lisp."
1096   (let ((current-symbol (elisp--current-symbol))
1097         (current-fnsym  (elisp--fnsym-in-current-sexp)))
1098     (cond ((null current-fnsym)
1099            nil)
1100           ((eq current-symbol (car current-fnsym))
1101            (or (apply #'elisp--get-fnsym-args-string current-fnsym)
1102                (elisp--get-var-docstring current-symbol)))
1103           (t
1104            (or (elisp--get-var-docstring current-symbol)
1105                (apply #'elisp--get-fnsym-args-string current-fnsym))))))
1106
1107 (defun elisp--get-fnsym-args-string (sym &optional index)
1108   "Return a string containing the parameter list of the function SYM.
1109 If SYM is a subr and no arglist is obtainable from the docstring
1110 or elsewhere, return a 1-line docstring."
1111   (let ((argstring
1112          (cond
1113           ((not (and sym (symbolp sym) (fboundp sym))) nil)
1114           ((and (eq sym (aref elisp--eldoc-last-data 0))
1115                 (eq 'function (aref elisp--eldoc-last-data 2)))
1116            (aref elisp--eldoc-last-data 1))
1117           (t
1118            (let* ((advertised (gethash (indirect-function sym)
1119                                        advertised-signature-table t))
1120                   doc
1121                   (args
1122                    (cond
1123                     ((listp advertised) advertised)
1124                     ((setq doc (help-split-fundoc (documentation sym t) sym))
1125                      (car doc))
1126                     (t (help-function-arglist sym)))))
1127              ;; Stringify, and store before highlighting, downcasing, etc.
1128              ;; FIXME should truncate before storing.
1129              (elisp--last-data-store sym (elisp--function-argstring args)
1130                                     'function))))))
1131     ;; Highlight, truncate.
1132     (if argstring
1133         (elisp--highlight-function-argument sym argstring index))))
1134
1135 (defun elisp--highlight-function-argument (sym args index)
1136   "Highlight argument INDEX in ARGS list for function SYM.
1137 In the absence of INDEX, just call `elisp--docstring-format-sym-doc'."
1138   ;; FIXME: This should probably work on the list representation of `args'
1139   ;; rather than its string representation.
1140   ;; FIXME: This function is much too long, we need to split it up!
1141   (let ((start          nil)
1142         (end            0)
1143         (argument-face  'eldoc-highlight-function-argument)
1144         (args-lst (mapcar (lambda (x)
1145                             (replace-regexp-in-string
1146                              "\\`[(]\\|[)]\\'" "" x))
1147                           (split-string args))))
1148     ;; Find the current argument in the argument string.  We need to
1149     ;; handle `&rest' and informal `...' properly.
1150     ;;
1151     ;; FIXME: What to do with optional arguments, like in
1152     ;;        (defun NAME ARGLIST [DOCSTRING] BODY...) case?
1153     ;;        The problem is there is no robust way to determine if
1154     ;;        the current argument is indeed a docstring.
1155
1156     ;; When `&key' is used finding position based on `index'
1157     ;; would be wrong, so find the arg at point and determine
1158     ;; position in ARGS based on this current arg.
1159     (when (string-match "&key" args)
1160       (let* (case-fold-search
1161              key-have-value
1162              (sym-name (symbol-name sym))
1163              (cur-w (current-word))
1164              (args-lst-ak (cdr (member "&key" args-lst)))
1165              (limit (save-excursion
1166                       (when (re-search-backward sym-name nil t)
1167                         (match-end 0))))
1168              (cur-a (if (and cur-w (string-match ":\\([^ ()]*\\)" cur-w))
1169                         (substring cur-w 1)
1170                       (save-excursion
1171                         (let (split)
1172                           (when (re-search-backward ":\\([^()\n]*\\)" limit t)
1173                             (setq split (split-string (match-string 1) " " t))
1174                             (prog1 (car split)
1175                               (when (cdr split)
1176                                 (setq key-have-value t))))))))
1177              ;; If `cur-a' is not one of `args-lst-ak'
1178              ;; assume user is entering an unknown key
1179              ;; referenced in last position in signature.
1180              (other-key-arg (and (stringp cur-a)
1181                                  args-lst-ak
1182                                  (not (member (upcase cur-a) args-lst-ak))
1183                                  (upcase (car (last args-lst-ak))))))
1184         (unless (string= cur-w sym-name)
1185           ;; The last keyword have already a value
1186           ;; i.e :foo a b and cursor is at b.
1187           ;; If signature have also `&rest'
1188           ;; (assume it is after the `&key' section)
1189           ;; go to the arg after `&rest'.
1190           (if (and key-have-value
1191                    (save-excursion
1192                      (not (re-search-forward ":.*" (point-at-eol) t)))
1193                    (string-match "&rest \\([^ ()]*\\)" args))
1194               (setq index nil ; Skip next block based on positional args.
1195                     start (match-beginning 1)
1196                     end   (match-end 1))
1197             ;; If `cur-a' is nil probably cursor is on a positional arg
1198             ;; before `&key', in this case, exit this block and determine
1199             ;; position with `index'.
1200             (when (and cur-a     ; A keyword arg (dot removed) or nil.
1201                        (or (string-match
1202                             (concat "\\_<" (upcase cur-a) "\\_>") args)
1203                            (string-match
1204                             (concat "\\_<" other-key-arg "\\_>") args)))
1205               (setq index nil ; Skip next block based on positional args.
1206                     start (match-beginning 0)
1207                     end   (match-end 0)))))))
1208     ;; Handle now positional arguments.
1209     (while (and index (>= index 1))
1210       (if (string-match "[^ ()]+" args end)
1211           (progn
1212             (setq start (match-beginning 0)
1213                   end   (match-end 0))
1214             (let ((argument (match-string 0 args)))
1215               (cond ((string= argument "&rest")
1216                      ;; All the rest arguments are the same.
1217                      (setq index 1))
1218                     ((string= argument "&optional"))         ; Skip.
1219                     ((string= argument "&allow-other-keys")) ; Skip.
1220                     ;; Back to index 0 in ARG1 ARG2 ARG2 ARG3 etc...
1221                     ;; like in `setq'.
1222                     ((or (and (string-match-p "\\.\\.\\.$" argument)
1223                               (string= argument (car (last args-lst))))
1224                          (and (string-match-p "\\.\\.\\.$"
1225                                               (substring args 1 (1- (length args))))
1226                               (= (length (remove "..." args-lst)) 2)
1227                               (> index 1) (eq (logand index 1) 1)))
1228                      (setq index 0))
1229                     (t
1230                      (setq index (1- index))))))
1231         (setq end           (length args)
1232               start         (1- end)
1233               argument-face 'font-lock-warning-face
1234               index         0)))
1235     (let ((doc args))
1236       (when start
1237         (setq doc (copy-sequence args))
1238         (add-text-properties start end (list 'face argument-face) doc))
1239       (setq doc (elisp--docstring-format-sym-doc
1240                  sym doc (if (functionp sym) 'font-lock-function-name-face
1241                            'font-lock-keyword-face)))
1242       doc)))
1243
1244 ;; Return a string containing a brief (one-line) documentation string for
1245 ;; the variable.
1246 (defun elisp--get-var-docstring (sym)
1247   (cond ((not sym) nil)
1248         ((and (eq sym (aref elisp--eldoc-last-data 0))
1249               (eq 'variable (aref elisp--eldoc-last-data 2)))
1250          (aref elisp--eldoc-last-data 1))
1251         (t
1252          (let ((doc (documentation-property sym 'variable-documentation t)))
1253            (when doc
1254              (let ((doc (elisp--docstring-format-sym-doc
1255                          sym (elisp--docstring-first-line doc)
1256                          'font-lock-variable-name-face)))
1257                (elisp--last-data-store sym doc 'variable)))))))
1258
1259 (defun elisp--last-data-store (symbol doc type)
1260   (aset elisp--eldoc-last-data 0 symbol)
1261   (aset elisp--eldoc-last-data 1 doc)
1262   (aset elisp--eldoc-last-data 2 type)
1263   doc)
1264
1265 ;; Note that any leading `*' in the docstring (which indicates the variable
1266 ;; is a user option) is removed.
1267 (defun elisp--docstring-first-line (doc)
1268   (and (stringp doc)
1269        (substitute-command-keys
1270         (save-match-data
1271           ;; Don't use "^" in the regexp below since it may match
1272           ;; anywhere in the doc-string.
1273           (let ((start (if (string-match "\\`\\*" doc) (match-end 0) 0)))
1274             (cond ((string-match "\n" doc)
1275                    (substring doc start (match-beginning 0)))
1276                   ((zerop start) doc)
1277                   (t (substring doc start))))))))
1278
1279 (defvar eldoc-echo-area-use-multiline-p)
1280
1281 ;; If the entire line cannot fit in the echo area, the symbol name may be
1282 ;; truncated or eliminated entirely from the output to make room for the
1283 ;; description.
1284 (defun elisp--docstring-format-sym-doc (sym doc face)
1285   (save-match-data
1286     (let* ((name (symbol-name sym))
1287            (ea-multi eldoc-echo-area-use-multiline-p)
1288            ;; Subtract 1 from window width since emacs will not write
1289            ;; any chars to the last column, or in later versions, will
1290            ;; cause a wraparound and resize of the echo area.
1291            (ea-width (1- (window-width (minibuffer-window))))
1292            (strip (- (+ (length name) (length ": ") (length doc)) ea-width)))
1293       (cond ((or (<= strip 0)
1294                  (eq ea-multi t)
1295                  (and ea-multi (> (length doc) ea-width)))
1296              (format "%s: %s" (propertize name 'face face) doc))
1297             ((> (length doc) ea-width)
1298              (substring (format "%s" doc) 0 ea-width))
1299             ((>= strip (length name))
1300              (format "%s" doc))
1301             (t
1302              ;; Show the end of the partial symbol name, rather
1303              ;; than the beginning, since the former is more likely
1304              ;; to be unique given package namespace conventions.
1305              (setq name (substring name strip))
1306              (format "%s: %s" (propertize name 'face face) doc))))))
1307
1308 \f
1309 ;; Return a list of current function name and argument index.
1310 (defun elisp--fnsym-in-current-sexp ()
1311   (save-excursion
1312     (let ((argument-index (1- (elisp--beginning-of-sexp))))
1313       ;; If we are at the beginning of function name, this will be -1.
1314       (when (< argument-index 0)
1315         (setq argument-index 0))
1316       ;; Don't do anything if current word is inside a string.
1317       (if (= (or (char-after (1- (point))) 0) ?\")
1318           nil
1319         (list (elisp--current-symbol) argument-index)))))
1320
1321 ;; Move to the beginning of current sexp.  Return the number of nested
1322 ;; sexp the point was over or after.
1323 (defun elisp--beginning-of-sexp ()
1324   (let ((parse-sexp-ignore-comments t)
1325         (num-skipped-sexps 0))
1326     (condition-case _
1327         (progn
1328           ;; First account for the case the point is directly over a
1329           ;; beginning of a nested sexp.
1330           (condition-case _
1331               (let ((p (point)))
1332                 (forward-sexp -1)
1333                 (forward-sexp 1)
1334                 (when (< (point) p)
1335                   (setq num-skipped-sexps 1)))
1336             (error))
1337           (while
1338               (let ((p (point)))
1339                 (forward-sexp -1)
1340                 (when (< (point) p)
1341                   (setq num-skipped-sexps (1+ num-skipped-sexps))))))
1342       (error))
1343     num-skipped-sexps))
1344
1345 ;; returns nil unless current word is an interned symbol.
1346 (defun elisp--current-symbol ()
1347   (let ((c (char-after (point))))
1348     (and c
1349          (memq (char-syntax c) '(?w ?_))
1350          (intern-soft (current-word)))))
1351
1352 (defun elisp--function-argstring (arglist)
1353   "Return ARGLIST as a string enclosed by ().
1354 ARGLIST is either a string, or a list of strings or symbols."
1355   (let ((str (cond ((stringp arglist) arglist)
1356                    ((not (listp arglist)) nil)
1357                    (t (format "%S" (help-make-usage 'toto arglist))))))
1358     (if (and str (string-match "\\`([^ )]+ ?" str))
1359         (replace-match "(" t t str)
1360       str)))
1361
1362 (provide 'elisp-mode)
1363 ;;; elisp-mode.el ends here