lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * working-revision (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       OK
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-revision (file)                          NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-revision (file rev buffer)               OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional revision)          NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (revision)                     OK
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (files)             NEEDED?
  91 ;; - annotate-command (file buf &optional rev)     OK
  92 ;; - annotate-time ()                              OK
  93 ;; - annotate-current-time ()                      NOT NEEDED
  94 ;; - annotate-extract-revision-at-line ()          OK
  95 ;; SNAPSHOT SYSTEM
  96 ;; - create-snapshot (dir name branchp)            OK
  97 ;; - assign-name (file name)                       NOT NEEDED
  98 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
  99 ;; MISCELLANEOUS
 100 ;; - make-version-backups-p (file)                 NOT NEEDED
 101 ;; - repository-hostname (dirname)                 NOT NEEDED
 102 ;; - previous-revision (file rev)                  OK
 103 ;; - next-revision (file rev)                      OK
 104 ;; - check-headers ()                              COULD BE SUPPORTED
 105 ;; - clear-headers ()                              NOT NEEDED
 106 ;; - delete-file (file)                            OK
 107 ;; - rename-file (old new)                         OK
 108 ;; - find-file-hook ()                             NOT NEEDED
 109 ;; - find-file-not-found-hook ()                   NOT NEEDED
 110
 111 (eval-when-compile (require 'cl) (require 'vc))
 112
 113 (defvar git-commits-coding-system 'utf-8
 114   "Default coding system for git commits.")
 115
 116 ;;; BACKEND PROPERTIES
 117
 118 (defun vc-git-revision-granularity ()
 119   'repository)
 120
 121 ;;; STATE-QUERYING FUNCTIONS
 122
 123 ;;;###autoload (defun vc-git-registered (file)
 124 ;;;###autoload   "Return non-nil if FILE is registered with git."
 125 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 126 ;;;###autoload       (progn
 127 ;;;###autoload         (load "vc-git")
 128 ;;;###autoload         (vc-git-registered file))))
 129
 130 (defun vc-git-registered (file)
 131   "Check whether FILE is registered with git."
 132   (when (vc-git-root file)
 133     (with-temp-buffer
 134       (let* ((dir (file-name-directory file))
 135              (name (file-relative-name file dir)))
 136         (and (ignore-errors
 137                (when dir (cd dir))
 138                (vc-git--out-ok "ls-files" "-c" "-z" "--" name))
 139              (let ((str (buffer-string)))
 140                (and (> (length str) (length name))
 141                     (string= (substring str 0 (1+ (length name)))
 142                              (concat name "\0")))))))))
 143
 144 (defun vc-git-state (file)
 145   "Git-specific version of `vc-state'."
 146   ;; FIXME: This can't set 'ignored yet
 147   (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 148   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 149     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0"
 150                                 diff))
 151         'edited
 152       'up-to-date)))
 153
 154 (defun vc-git--ls-files-state (state &rest args)
 155   "Set state to STATE on all files found with git-ls-files ARGS."
 156   (with-temp-buffer
 157     (apply 'vc-git-command (current-buffer) nil nil "ls-files" "-z" args)
 158     (goto-char (point-min))
 159     (let ((start (point)))
 160       (while (search-forward "\0" nil t)
 161         (let ((file (expand-file-name
 162                      (buffer-substring-no-properties start (1- (point))))))
 163           (vc-file-setprop file 'vc-backend (if state 'Git 'none))
 164           (vc-file-setprop file 'vc-state state))
 165         (setq start (point))))))
 166
 167 (defun vc-git-dir-state (dir)
 168   "Git-specific version of `dir-state'."
 169   (vc-git--ls-files-state 'up-to-date "-c")
 170   (vc-git--ls-files-state 'edited "-m")
 171   (vc-git--ls-files-state 'removed "-d")
 172   (vc-git--ls-files-state 'ignored "-o" "-i" "--exclude-standard")
 173   (vc-git--ls-files-state nil "-o" "--exclude-standard"))
 174
 175 (defun vc-git-working-revision (file)
 176   "Git-specific version of `vc-working-revision'."
 177   (let ((str (with-output-to-string
 178                (with-current-buffer standard-output
 179                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 180     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 181         (match-string 2 str)
 182       str)))
 183
 184 (defun vc-git-checkout-model (file)
 185   'implicit)
 186
 187 (defun vc-git-workfile-unchanged-p (file)
 188   (eq 'up-to-date (vc-git-state file)))
 189
 190 (defun vc-git-mode-line-string (file)
 191   "Return string for placement into the modeline for FILE."
 192   (let* ((branch (vc-git-working-revision file))
 193          (def-ml (vc-default-mode-line-string 'Git file))
 194          (help-echo (get-text-property 0 'help-echo def-ml)))
 195     (if (zerop (length branch))
 196         (propertize
 197          (concat def-ml "!")
 198          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 199       (propertize def-ml
 200                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 201
 202 (defun vc-git-dired-state-info (file)
 203   "Git-specific version of `vc-dired-state-info'."
 204   (let ((git-state (vc-state file)))
 205     (if (eq git-state 'edited)
 206         "(modified)"
 207       ;; fall back to the default VC representation
 208       (vc-default-dired-state-info 'Git file))))
 209
 210 ;;; vc-dir-status support (EXPERIMENTAL)
 211 ;;; If vc-directory (which is not half bad under Git, w/ some tweaking)
 212 ;;; is to go away, vc-dir-status must at least support the same operations.
 213 ;;; At the moment, vc-dir-status design is still fluid (a kind way to say
 214 ;;; half-baked, undocumented, and spottily-supported), so the following
 215 ;;; should be considered likewise ripe for sudden unannounced change.
 216 ;;; YHBW, HAND.  --ttn
 217
 218 (defun vc-git-after-dir-status (callback buffer)
 219   (sort-regexp-fields t "^. \\(.+\\)$" "\\1" (point-min) (point-max))
 220   (let ((map '((?H . cached)
 221                (?M . unmerged)
 222                (?R . removed)
 223                (?C . edited)
 224                (?K . removed)           ; ??? "to be killed"
 225                (?? . unregistered)))
 226         status filename result)
 227     (goto-char (point-min))
 228     (while (> (point-max) (point))
 229       (setq status (string-to-char (buffer-substring (point) (1+ (point))))
 230             status (cdr (assq status map))
 231             filename (buffer-substring (+ 2 (point)) (line-end-position)))
 232       ;; TODO: Add dynamic selection of which status(es) to display, and
 233       ;; bubble that up to vc-dir-status.  For now, we consider `cached'
 234       ;; to be uninteresting, to mimic vc-directory (somewhat).
 235       (unless (eq 'cached status)
 236         (push (cons filename status) result))
 237       (forward-line 1))
 238     (funcall callback result buffer)))
 239
 240 (defun vc-git-dir-status (dir update-function status-buffer)
 241   "Return a list of conses (file . state) for DIR."
 242   (with-current-buffer
 243       (get-buffer-create
 244        (expand-file-name " *VC-Git* tmp status" dir))
 245     (erase-buffer)
 246     (vc-git-command (current-buffer) 'async dir "ls-files" "-t"
 247                     "-c"                ; cached
 248                     "-d"                ; deleted
 249                     "-k"                ; killed
 250                     "-m"                ; modified
 251                     "-o"                ; others
 252                     "--directory"
 253                     "--exclude-per-directory=.gitignore")
 254     (vc-exec-after
 255      `(vc-git-after-dir-status (quote ,update-function) ,status-buffer))
 256     (current-buffer)))
 257
 258 ;;; STATE-CHANGING FUNCTIONS
 259
 260 (defun vc-git-create-repo ()
 261   "Create a new Git repository."
 262   (vc-git-command nil 0 nil "init"))
 263
 264 (defun vc-git-register (files &optional rev comment)
 265   "Register FILE into the git version-control system."
 266   (vc-git-command nil 0 files "update-index" "--add" "--"))
 267
 268 (defalias 'vc-git-responsible-p 'vc-git-root)
 269
 270 (defun vc-git-unregister (file)
 271   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 272
 273
 274 (defun vc-git-checkin (files rev comment)
 275   (let ((coding-system-for-write git-commits-coding-system))
 276     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 277
 278 (defun vc-git-find-revision (file rev buffer)
 279   (let ((coding-system-for-read 'binary)
 280         (coding-system-for-write 'binary)
 281         (fullname (substring
 282                    (vc-git--run-command-string
 283                     file "ls-files" "-z" "--full-name" "--")
 284                    0 -1)))
 285     (vc-git-command
 286      buffer 0
 287      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 288
 289 (defun vc-git-checkout (file &optional editable rev)
 290   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 291
 292 (defun vc-git-revert (file &optional contents-done)
 293   "Revert FILE to the version stored in the git repository."
 294   (if contents-done
 295       (vc-git-command nil 0 file "update-index" "--")
 296     (vc-git-command nil 0 file "checkout" "HEAD")))
 297
 298 ;;; HISTORY FUNCTIONS
 299
 300 (defun vc-git-print-log (files &optional buffer)
 301   "Get change log associated with FILES."
 302   (let ((coding-system-for-read git-commits-coding-system)
 303         ;; Support both the old print-log interface that passes a
 304         ;; single file, and the new one that passes a file list.
 305         (flist (if (listp files) files (list files))))
 306     ;; `vc-do-command' creates the buffer, but we need it before running
 307     ;; the command.
 308     (vc-setup-buffer buffer)
 309     ;; If the buffer exists from a previous invocation it might be
 310     ;; read-only.
 311     (let ((inhibit-read-only t))
 312       ;; XXX `log-view-mode' needs to have something to identify where
 313       ;; the log for each individual file starts. It seems that by
 314       ;; default git does not output this info. So loop here and call
 315       ;; "git rev-list" on each file separately to make sure that each
 316       ;; file gets a "File:" header before the corresponding
 317       ;; log. Maybe there is a way to do this with one command...
 318       (dolist (file flist)
 319         (with-current-buffer
 320             buffer
 321           (insert "File: " (file-name-nondirectory file) "\n"))
 322         (vc-git-command buffer 'async (file-relative-name file)
 323                         "rev-list" "--pretty" "HEAD" "--")))))
 324
 325 (defvar log-view-message-re)
 326 (defvar log-view-file-re)
 327 (defvar log-view-font-lock-keywords)
 328
 329 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 330   (require 'add-log) ;; we need the faces add-log
 331   ;; Don't have file markers, so use impossible regexp.
 332   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 333   (set (make-local-variable 'log-view-message-re)
 334        "^commit *\\([0-9a-z]+\\)")
 335   (set (make-local-variable 'log-view-font-lock-keywords)
 336        (append
 337         `((,log-view-message-re  (1 'change-log-acknowledgement))
 338           (,log-view-file-re (1 'change-log-file-face)))
 339         ;; Handle the case:
 340         ;; user: foo@bar
 341         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 342            (1 'change-log-email))
 343           ;; Handle the case:
 344           ;; user: FirstName LastName <foo@bar>
 345           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 346            (1 'change-log-name)
 347            (2 'change-log-email))
 348           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 349            (1 'change-log-name))
 350           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 351            (1 'change-log-name)
 352            (2 'change-log-email))
 353           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 354            (1 'change-log-acknowledgement)
 355            (2 'change-log-acknowledgement))
 356           ("^Date:   \\(.+\\)" (1 'change-log-date))
 357           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 358
 359 (defun vc-git-show-log-entry (revision)
 360   "Move to the log entry for REVISION.
 361 REVISION may have the form BRANCH, BRANCH~N,
 362 or BRANCH^ (where \"^\" can be repeated)."
 363   (goto-char (point-min))
 364   (search-forward "\ncommit" nil t
 365                   (cond ((string-match "~\\([0-9]\\)$" revision)
 366                          (1+ (string-to-number (match-string 1 revision))))
 367                         ((string-match "\\^+$" revision)
 368                          (1+ (length (match-string 0 revision))))
 369                         (t nil)))
 370   (beginning-of-line))
 371
 372 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 373   (let ((buf (or buffer "*vc-diff*")))
 374     (if (and rev1 rev2)
 375         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 376                         rev1 rev2 "--")
 377       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 378                       (or rev1 "HEAD") "--"))))
 379
 380 (defun vc-git-revision-table (files)
 381   ;; What about `files'?!?  --Stef
 382   (let ((table (list "HEAD")))
 383     (with-temp-buffer
 384       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 385       (goto-char (point-min))
 386       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 387         (push (match-string 2) table)))
 388     table))
 389
 390 (defun vc-git-revision-completion-table (files)
 391   (lexical-let ((files files)
 392                 table)
 393     (setq table (lazy-completion-table
 394                  table (lambda () (vc-git-revision-table files))))
 395     table))
 396
 397 (defun vc-git-annotate-command (file buf &optional rev)
 398   ;; FIXME: rev is ignored
 399   (let ((name (file-relative-name file)))
 400     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 401
 402 (defun vc-git-annotate-time ()
 403   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 404        (vc-annotate-convert-time
 405         (apply #'encode-time (mapcar (lambda (match)
 406                                        (string-to-number (match-string match)))
 407                                      '(6 5 4 3 2 1 7))))))
 408
 409 (defun vc-git-annotate-extract-revision-at-line ()
 410   (save-excursion
 411     (move-beginning-of-line 1)
 412     (and (looking-at "[0-9a-f]+")
 413          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 414
 415 ;;; SNAPSHOT SYSTEM
 416
 417 (defun vc-git-create-snapshot (dir name branchp)
 418   (let ((default-directory dir))
 419     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 420          (if branchp
 421              (vc-git-command nil 0 nil "checkout" "-b" name)
 422            (vc-git-command nil 0 nil "tag" name)))))
 423
 424 (defun vc-git-retrieve-snapshot (dir name update)
 425   (let ((default-directory dir))
 426     (vc-git-command nil 0 nil "checkout" name)
 427     ;; FIXME: update buffers if `update' is true
 428     ))
 429
 430
 431 ;;; MISCELLANEOUS
 432
 433 (defun vc-git-previous-revision (file rev)
 434   "Git-specific version of `vc-previous-revision'."
 435   (let ((default-directory (file-name-directory (expand-file-name file)))
 436         (file (file-name-nondirectory file)))
 437     (vc-git-symbolic-commit
 438      (with-temp-buffer
 439        (and
 440         (vc-git--out-ok "rev-list" "-2" rev "--" file)
 441         (goto-char (point-max))
 442         (bolp)
 443         (zerop (forward-line -1))
 444         (not (bobp))
 445         (buffer-substring-no-properties
 446          (point)
 447          (1- (point-max))))))))
 448
 449 (defun vc-git-next-revision (file rev)
 450   "Git-specific version of `vc-next-revision'."
 451   (let* ((default-directory (file-name-directory
 452                              (expand-file-name file)))
 453          (file (file-name-nondirectory file))
 454          (current-rev
 455           (with-temp-buffer
 456             (and
 457              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 458              (goto-char (point-max))
 459              (bolp)
 460              (zerop (forward-line -1))
 461              (bobp)
 462              (buffer-substring-no-properties
 463               (point)
 464               (1- (point-max)))))))
 465     (and current-rev
 466          (vc-git-symbolic-commit
 467           (with-temp-buffer
 468             (and
 469              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 470              (goto-char (point-min))
 471              (search-forward current-rev nil t)
 472              (zerop (forward-line -1))
 473              (buffer-substring-no-properties
 474               (point)
 475               (progn (forward-line 1) (1- (point))))))))))
 476
 477 (defun vc-git-delete-file (file)
 478   (vc-git-command nil 0 file "rm" "-f" "--"))
 479
 480 (defun vc-git-rename-file (old new)
 481   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 482
 483 \f
 484 ;;; Internal commands
 485
 486 (defun vc-git-root (file)
 487   (vc-find-root file ".git"))
 488
 489 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 490   "A wrapper around `vc-do-command' for use in vc-git.el.
 491 The difference to vc-do-command is that this function always invokes `git'."
 492   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 493
 494 (defun vc-git--call (buffer command &rest args)
 495   ;; We don't need to care the arguments.  If there is a file name, it
 496   ;; is always a relative one.  This works also for remote
 497   ;; directories.
 498   (apply 'process-file "git" nil buffer nil command args))
 499
 500 (defun vc-git--out-ok (command &rest args)
 501   (zerop (apply 'vc-git--call '(t nil) command args)))
 502
 503 (defun vc-git--run-command-string (file &rest args)
 504   "Run a git command on FILE and return its output as string."
 505   (let* ((ok t)
 506          (str (with-output-to-string
 507                 (with-current-buffer standard-output
 508                   (unless (apply 'vc-git--out-ok
 509                                  (append args (list (file-relative-name
 510                                                      file))))
 511                     (setq ok nil))))))
 512     (and ok str)))
 513
 514 (defun vc-git-symbolic-commit (commit)
 515   "Translate COMMIT string into symbolic form.
 516 Returns nil if not possible."
 517   (and commit
 518        (with-temp-buffer
 519          (and
 520           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 521           (goto-char (point-min))
 522           (= (forward-line 2) 1)
 523           (bolp)
 524           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 525
 526 (provide 'vc-git)
 527
 528 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 529 ;;; vc-git.el ends here