lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  27 ;; associated support machinery, such as adding hyperlinks, etc.,
  28
  29 ;;; Code:
  30
  31 (require 'button)
  32 (require 'view)
  33 (eval-when-compile (require 'easymenu))
  34
  35 (defvar help-mode-map (make-sparse-keymap)
  36   "Keymap for help mode.")
  37
  38 (set-keymap-parent help-mode-map button-buffer-map)
  39
  40 (define-key help-mode-map [mouse-2] 'help-follow-mouse)
  41 (define-key help-mode-map "\C-c\C-b" 'help-go-back)
  42 (define-key help-mode-map "\C-c\C-f" 'help-go-forward)
  43 (define-key help-mode-map "\C-c\C-c" 'help-follow-symbol)
  44 ;; Documentation only, since we use minor-mode-overriding-map-alist.
  45 (define-key help-mode-map "\r" 'help-follow)
  46
  47 (easy-menu-define help-mode-menu help-mode-map
  48   "Menu for Help Mode."
  49   '("Help-Mode"
  50     ["Show Help for Symbol" help-follow-symbol
  51      :help "Show the docs for the symbol at point"]
  52     ["Previous Topic" help-go-back
  53      :help "Go back to previous topic in this help buffer"]
  54     ["Next Topic" help-go-forward
  55      :help "Go back to next topic in this help buffer"]
  56     ["Move to Previous Button" backward-button
  57      :help "Move to the Next Button in the help buffer"]
  58     ["Move to Next Button" forward-button
  59       :help "Move to the Next Button in the help buffer"]))
  60
  61 (defvar help-xref-stack nil
  62   "A stack of ways by which to return to help buffers after following xrefs.
  63 Used by `help-follow' and `help-xref-go-back'.
  64 An element looks like (POSITION FUNCTION ARGS...).
  65 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  66 (put 'help-xref-stack 'permanent-local t)
  67 (make-variable-buffer-local 'help-xref-stack)
  68
  69 (defvar help-xref-forward-stack nil
  70   "A stack used to navigate help forwards after using the back button.
  71 Used by `help-follow' and `help-xref-go-forward'.
  72 An element looks like (POSITION FUNCTION ARGS...).
  73 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  74 (put 'help-xref-forward-stack 'permanent-local t)
  75 (make-variable-buffer-local 'help-xref-forward-stack)
  76
  77 (defvar help-xref-stack-item nil
  78   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  79 The format is (FUNCTION ARGS...).")
  80 (put 'help-xref-stack-item 'permanent-local t)
  81 (make-variable-buffer-local 'help-xref-stack-item)
  82
  83 (defvar help-xref-stack-forward-item nil
  84   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  85 The format is (FUNCTION ARGS...).")
  86 (put 'help-xref-stack-forward-item 'permanent-local t)
  87 (make-variable-buffer-local 'help-xref-stack-forward-item)
  88
  89 (setq-default help-xref-stack nil help-xref-stack-item nil)
  90 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  91
  92 (defcustom help-mode-hook nil
  93   "Hook run by `help-mode'."
  94   :type 'hook
  95   :group 'help)
  96 \f
  97 ;; Button types used by help
  98
  99 (define-button-type 'help-xref
 100   'follow-link t
 101   'action #'help-button-action)
 102
 103 (defun help-button-action (button)
 104   "Call BUTTON's help function."
 105   (help-do-xref (button-start button)
 106                 (button-get button 'help-function)
 107                 (button-get button 'help-args)))
 108
 109 ;; These 6 calls to define-button-type were generated in a dolist
 110 ;; loop, but that is bad because it means these button types don't
 111 ;; have an easily found definition.
 112
 113 (define-button-type 'help-function
 114   :supertype 'help-xref
 115   'help-function 'describe-function
 116   'help-echo (purecopy "mouse-2, RET: describe this function"))
 117
 118 (define-button-type 'help-variable
 119   :supertype 'help-xref
 120   'help-function 'describe-variable
 121   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 122
 123 (define-button-type 'help-face
 124   :supertype 'help-xref
 125   'help-function 'describe-face
 126   'help-echo (purecopy "mouse-2, RET: describe this face"))
 127
 128 (define-button-type 'help-coding-system
 129   :supertype 'help-xref
 130   'help-function 'describe-coding-system
 131   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 132
 133 (define-button-type 'help-input-method
 134   :supertype 'help-xref
 135   'help-function 'describe-input-method
 136   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 137
 138 (define-button-type 'help-character-set
 139   :supertype 'help-xref
 140   'help-function 'describe-character-set
 141   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 142
 143 ;; make some more ideosyncratic button types
 144
 145 (define-button-type 'help-symbol
 146   :supertype 'help-xref
 147   'help-function #'help-xref-interned
 148   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 149
 150 (define-button-type 'help-back
 151   :supertype 'help-xref
 152   'help-function #'help-xref-go-back
 153   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 154
 155 (define-button-type 'help-forward
 156   :supertype 'help-xref
 157   'help-function #'help-xref-go-forward
 158   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 159
 160 (define-button-type 'help-info-variable
 161   :supertype 'help-xref
 162   ;; the name of the variable is put before the argument to Info
 163   'help-function (lambda (a v) (info v))
 164   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 165
 166 (define-button-type 'help-info
 167   :supertype 'help-xref
 168   'help-function #'info
 169   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 170
 171 (define-button-type 'help-url
 172   :supertype 'help-xref
 173   'help-function #'browse-url
 174   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 175
 176 (define-button-type 'help-customize-variable
 177   :supertype 'help-xref
 178   'help-function (lambda (v)
 179                    (customize-variable v))
 180   'help-echo (purecopy "mouse-2, RET: customize variable"))
 181
 182 (define-button-type 'help-customize-face
 183   :supertype 'help-xref
 184   'help-function (lambda (v)
 185                    (customize-face v))
 186   'help-echo (purecopy "mouse-2, RET: customize face"))
 187
 188 (define-button-type 'help-function-def
 189   :supertype 'help-xref
 190   'help-function (lambda (fun file)
 191                    (require 'find-func)
 192                    (when (eq file 'C-source)
 193                      (setq file
 194                            (help-C-file-name (indirect-function fun) 'fun)))
 195                    ;; Don't use find-function-noselect because it follows
 196                    ;; aliases (which fails for built-in functions).
 197                    (let ((location
 198                           (find-function-search-for-symbol fun nil file)))
 199                      (pop-to-buffer (car location))
 200                      (if (cdr location)
 201                          (goto-char (cdr location))
 202                        (message "Unable to find location in file"))))
 203   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 204
 205 (define-button-type 'help-function-cmacro
 206   :supertype 'help-xref
 207   'help-function (lambda (fun file)
 208                    (setq file (locate-library file t))
 209                    (if (and file (file-readable-p file))
 210                        (progn
 211                          (pop-to-buffer (find-file-noselect file))
 212                          (goto-char (point-min))
 213                          (if (re-search-forward
 214                               (format "^[ \t]*(define-compiler-macro[ \t]+%s"
 215                                       (regexp-quote (symbol-name fun))) nil t)
 216                              (forward-line 0)
 217                            (message "Unable to find location in file")))
 218                      (message "Unable to find file")))
 219   'help-echo (purecopy "mouse-2, RET: find function's compiler macro"))
 220
 221 (define-button-type 'help-variable-def
 222   :supertype 'help-xref
 223   'help-function (lambda (var &optional file)
 224                    (when (eq file 'C-source)
 225                      (setq file (help-C-file-name var 'var)))
 226                    (let ((location (find-variable-noselect var file)))
 227                      (pop-to-buffer (car location))
 228                      (if (cdr location)
 229                        (goto-char (cdr location))
 230                        (message "Unable to find location in file"))))
 231   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 232
 233 (define-button-type 'help-face-def
 234   :supertype 'help-xref
 235   'help-function (lambda (fun file)
 236                    (require 'find-func)
 237                    ;; Don't use find-function-noselect because it follows
 238                    ;; aliases (which fails for built-in functions).
 239                    (let ((location
 240                           (find-function-search-for-symbol fun 'defface file)))
 241                      (pop-to-buffer (car location))
 242                      (if (cdr location)
 243                          (goto-char (cdr location))
 244                        (message "Unable to find location in file"))))
 245   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 246
 247 \f
 248 ;;;###autoload
 249 (defun help-mode ()
 250   "Major mode for viewing help text and navigating references in it.
 251 Entry to this mode runs the normal hook `help-mode-hook'.
 252 Commands:
 253 \\{help-mode-map}"
 254   (interactive)
 255   (kill-all-local-variables)
 256   (use-local-map help-mode-map)
 257   (setq mode-name "Help")
 258   (setq major-mode 'help-mode)
 259
 260   (view-mode)
 261   (set (make-local-variable 'view-no-disable-on-exit) t)
 262   ;; With Emacs 22 `view-exit-action' could delete the selected window
 263   ;; disregarding whether the help buffer was shown in that window at
 264   ;; all.  Since `view-exit-action' is called with the help buffer as
 265   ;; argument it seems more appropriate to have it work on the buffer
 266   ;; only and leave it to `view-mode-exit' to delete any associated
 267   ;; window(s).
 268   (setq view-exit-action
 269         (lambda (buffer)
 270           ;; Use `with-current-buffer' to make sure that `bury-buffer'
 271           ;; also removes BUFFER from the selected window.
 272           (with-current-buffer buffer
 273             (bury-buffer))))
 274
 275   (run-mode-hooks 'help-mode-hook))
 276
 277 ;;;###autoload
 278 (defun help-mode-setup ()
 279   (help-mode)
 280   (setq buffer-read-only nil))
 281
 282 ;;;###autoload
 283 (defun help-mode-finish ()
 284   (if (eq help-window t)
 285       ;; If `help-window' is t, `view-return-to-alist' is handled by
 286       ;; `with-help-window'.  In this case set `help-window' to the
 287       ;; selected window since now is the only moment where we can
 288       ;; unambiguously identify it.
 289       (setq help-window (selected-window))
 290     (let ((entry (assq (selected-window) view-return-to-alist)))
 291       (if entry
 292           ;; When entering Help mode from the Help window,
 293           ;; such as by following a link, preserve the same
 294           ;; meaning for the q command.
 295           ;; (setcdr entry (cons (selected-window) help-return-method))
 296           nil
 297         (setq view-return-to-alist
 298               (cons (cons (selected-window) help-return-method)
 299                     view-return-to-alist)))))
 300
 301   (when (eq major-mode 'help-mode)
 302     ;; View mode's read-only status of existing *Help* buffer is lost
 303     ;; by with-output-to-temp-buffer.
 304     (toggle-read-only 1)
 305     (help-make-xrefs (current-buffer))))
 306 \f
 307 ;; Grokking cross-reference information in doc strings and
 308 ;; hyperlinking it.
 309
 310 ;; This may have some scope for extension and the same or something
 311 ;; similar should be done for widget doc strings, which currently use
 312 ;; another mechanism.
 313
 314 (defvar help-back-label (purecopy "[back]")
 315   "Label to use by `help-make-xrefs' for the go-back reference.")
 316
 317 (defvar help-forward-label (purecopy "[forward]")
 318   "Label to use by `help-make-xrefs' for the go-forward reference.")
 319
 320 (defconst help-xref-symbol-regexp
 321   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 322                     "\\(function\\|command\\)\\|"          ; Link to function
 323                     "\\(face\\)\\|"                        ; Link to face
 324                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 325                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 326                     "[ \t\n]+\\)?"
 327                     ;; Note starting with word-syntax character:
 328                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 329   "Regexp matching doc string references to symbols.
 330
 331 The words preceding the quoted symbol can be used in doc strings to
 332 distinguish references to variables, functions and symbols.")
 333
 334 (defvar help-xref-mule-regexp nil
 335   "Regexp matching doc string references to MULE-related keywords.
 336
 337 It is usually nil, and is temporarily bound to an appropriate regexp
 338 when help commands related to multilingual environment (e.g.,
 339 `describe-coding-system') are invoked.")
 340
 341
 342 (defconst help-xref-info-regexp
 343   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 344   "Regexp matching doc string references to an Info node.")
 345
 346 (defconst help-xref-url-regexp
 347   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
 348   "Regexp matching doc string references to a URL.")
 349
 350 ;;;###autoload
 351 (defun help-setup-xref (item interactive-p)
 352   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 353
 354 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 355 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 356 calling command was invoked interactively.  In this case the stack of
 357 items for help buffer \"back\" buttons is cleared.
 358
 359 This should be called very early, before the output buffer is cleared,
 360 because we want to record the \"previous\" position of point so we can
 361 restore it properly when going back."
 362   (with-current-buffer (help-buffer)
 363     (when help-xref-stack-item
 364       (push (cons (point) help-xref-stack-item) help-xref-stack)
 365       (setq help-xref-forward-stack nil))
 366     (when interactive-p
 367       (let ((tail (nthcdr 10 help-xref-stack)))
 368         ;; Truncate the stack.
 369         (if tail (setcdr tail nil))))
 370     (setq help-xref-stack-item item)))
 371
 372 (defvar help-xref-following nil
 373   "Non-nil when following a help cross-reference.")
 374
 375 ;;;###autoload
 376 (defun help-buffer ()
 377   "Return the name of a buffer for inserting help.
 378 If `help-xref-following' is non-nil, this is the name of the
 379 current buffer.
 380 Otherwise, it is *Help*; if no buffer with that name currently
 381 exists, it is created."
 382   (buffer-name                          ;for with-output-to-temp-buffer
 383    (if help-xref-following
 384        (current-buffer)
 385      (get-buffer-create "*Help*"))))
 386
 387 (defvar help-xref-override-view-map
 388   (let ((map (make-sparse-keymap)))
 389     (set-keymap-parent map view-mode-map)
 390     (define-key map "\r" nil)
 391     map)
 392   "Replacement keymap for `view-mode' in help buffers.")
 393
 394 ;;;###autoload
 395 (defun help-make-xrefs (&optional buffer)
 396   "Parse and hyperlink documentation cross-references in the given BUFFER.
 397
 398 Find cross-reference information in a buffer and activate such cross
 399 references for selection with `help-follow'.  Cross-references have
 400 the canonical form `...'  and the type of reference may be
 401 disambiguated by the preceding word(s) used in
 402 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 403 preceded or followed by the word `face'.  Variables without
 404 variable documentation do not get cross-referenced, unless
 405 preceded by the word `variable' or `option'.
 406
 407 If the variable `help-xref-mule-regexp' is non-nil, find also
 408 cross-reference information related to multilingual environment
 409 \(e.g., coding-systems).  This variable is also used to disambiguate
 410 the type of reference as the same way as `help-xref-symbol-regexp'.
 411
 412 A special reference `back' is made to return back through a stack of
 413 help buffers.  Variable `help-back-label' specifies the text for
 414 that."
 415   (interactive "b")
 416   (with-current-buffer (or buffer (current-buffer))
 417     (goto-char (point-min))
 418     ;; Skip the header-type info, though it might be useful to parse
 419     ;; it at some stage (e.g. "function in `library'").
 420     (forward-paragraph)
 421     (let ((old-modified (buffer-modified-p)))
 422       (let ((stab (syntax-table))
 423             (case-fold-search t)
 424             (inhibit-read-only t))
 425         (set-syntax-table emacs-lisp-mode-syntax-table)
 426         ;; The following should probably be abstracted out.
 427         (unwind-protect
 428             (progn
 429               ;; Info references
 430               (save-excursion
 431                 (while (re-search-forward help-xref-info-regexp nil t)
 432                   (let ((data (match-string 2)))
 433                     (save-match-data
 434                       (unless (string-match "^([^)]+)" data)
 435                         (setq data (concat "(emacs)" data))))
 436                     (help-xref-button 2 'help-info data))))
 437               ;; URLs
 438               (save-excursion
 439                 (while (re-search-forward help-xref-url-regexp nil t)
 440                   (let ((data (match-string 1)))
 441                     (help-xref-button 1 'help-url data))))
 442               ;; Mule related keywords.  Do this before trying
 443               ;; `help-xref-symbol-regexp' because some of Mule
 444               ;; keywords have variable or function definitions.
 445               (if help-xref-mule-regexp
 446                   (save-excursion
 447                     (while (re-search-forward help-xref-mule-regexp nil t)
 448                       (let* ((data (match-string 7))
 449                              (sym (intern-soft data)))
 450                         (cond
 451                          ((match-string 3) ; coding system
 452                           (and sym (coding-system-p sym)
 453                                (help-xref-button 6 'help-coding-system sym)))
 454                          ((match-string 4) ; input method
 455                           (and (assoc data input-method-alist)
 456                                (help-xref-button 7 'help-input-method data)))
 457                          ((or (match-string 5) (match-string 6)) ; charset
 458                           (and sym (charsetp sym)
 459                                (help-xref-button 7 'help-character-set sym)))
 460                          ((assoc data input-method-alist)
 461                           (help-xref-button 7 'help-character-set data))
 462                          ((and sym (coding-system-p sym))
 463                           (help-xref-button 7 'help-coding-system sym))
 464                          ((and sym (charsetp sym))
 465                           (help-xref-button 7 'help-character-set sym)))))))
 466               ;; Quoted symbols
 467               (save-excursion
 468                 (while (re-search-forward help-xref-symbol-regexp nil t)
 469                   (let* ((data (match-string 8))
 470                          (sym (intern-soft data)))
 471                     (if sym
 472                         (cond
 473                          ((match-string 3)  ; `variable' &c
 474                           (and (or (boundp sym) ; `variable' doesn't ensure
 475                                         ; it's actually bound
 476                                    (get sym 'variable-documentation))
 477                                (help-xref-button 8 'help-variable sym)))
 478                          ((match-string 4)   ; `function' &c
 479                           (and (fboundp sym) ; similarly
 480                                (help-xref-button 8 'help-function sym)))
 481                          ((match-string 5) ; `face'
 482                           (and (facep sym)
 483                                (help-xref-button 8 'help-face sym)))
 484                          ((match-string 6)) ; nothing for `symbol'
 485                          ((match-string 7)
 486 ;;;  this used:
 487 ;;;                       #'(lambda (arg)
 488 ;;;                           (let ((location
 489 ;;;                                  (find-function-noselect arg)))
 490 ;;;                             (pop-to-buffer (car location))
 491 ;;;                             (goto-char (cdr location))))
 492                           (help-xref-button 8 'help-function-def sym))
 493                          ((and
 494                            (facep sym)
 495                            (save-match-data (looking-at "[ \t\n]+face\\W")))
 496                           (help-xref-button 8 'help-face sym))
 497                          ((and (or (boundp sym)
 498                                    (get sym 'variable-documentation))
 499                                (fboundp sym))
 500                           ;; We can't intuit whether to use the
 501                           ;; variable or function doc -- supply both.
 502                           (help-xref-button 8 'help-symbol sym))
 503                          ((and
 504                            (or (boundp sym)
 505                                (get sym 'variable-documentation))
 506                            (or
 507                             (documentation-property
 508                              sym 'variable-documentation)
 509                             (condition-case nil
 510                                 (documentation-property
 511                                  (indirect-variable sym)
 512                                  'variable-documentation)
 513                               (cyclic-variable-indirection nil))))
 514                           (help-xref-button 8 'help-variable sym))
 515                          ((fboundp sym)
 516                           (help-xref-button 8 'help-function sym)))))))
 517               ;; An obvious case of a key substitution:
 518               (save-excursion
 519                 (while (re-search-forward
 520                         ;; Assume command name is only word and symbol
 521                         ;; characters to get things like `use M-x foo->bar'.
 522                         ;; Command required to end with word constituent
 523                         ;; to avoid `.' at end of a sentence.
 524                         "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 525                   (let ((sym (intern-soft (match-string 1))))
 526                     (if (fboundp sym)
 527                         (help-xref-button 1 'help-function sym)))))
 528               ;; Look for commands in whole keymap substitutions:
 529               (save-excursion
 530                 ;; Make sure to find the first keymap.
 531                 (goto-char (point-min))
 532                 ;; Find a header and the column at which the command
 533                 ;; name will be found.
 534
 535                 ;; If the keymap substitution isn't the last thing in
 536                 ;; the doc string, and if there is anything on the
 537                 ;; same line after it, this code won't recognize the end of it.
 538                 (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 539                                           nil t)
 540                   (let ((col (- (match-end 1) (match-beginning 1))))
 541                     (while
 542                         (and (not (eobp))
 543                              ;; Stop at a pair of blank lines.
 544                              (not (looking-at "\n\\s-*\n")))
 545                       ;; Skip a single blank line.
 546                       (and (eolp) (forward-line))
 547                       (end-of-line)
 548                       (skip-chars-backward "^ \t\n")
 549                       (if (and (>= (current-column) col)
 550                                (looking-at "\\(\\sw\\|\\s_\\)+$"))
 551                           (let ((sym (intern-soft (match-string 0))))
 552                             (if (fboundp sym)
 553                                 (help-xref-button 0 'help-function sym))))
 554                       (forward-line))))))
 555           (set-syntax-table stab))
 556         ;; Delete extraneous newlines at the end of the docstring
 557         (goto-char (point-max))
 558         (while (and (not (bobp)) (bolp))
 559           (delete-char -1))
 560         (insert "\n")
 561         (when (or help-xref-stack help-xref-forward-stack)
 562           (insert "\n"))
 563         ;; Make a back-reference in this buffer if appropriate.
 564         (when help-xref-stack
 565           (help-insert-xref-button help-back-label 'help-back
 566                                    (current-buffer)))
 567         ;; Make a forward-reference in this buffer if appropriate.
 568         (when help-xref-forward-stack
 569           (when help-xref-stack
 570             (insert "\t"))
 571           (help-insert-xref-button help-forward-label 'help-forward
 572                                    (current-buffer)))
 573         (when (or help-xref-stack help-xref-forward-stack)
 574           (insert "\n")))
 575       ;; View mode steals RET from us.
 576       (set (make-local-variable 'minor-mode-overriding-map-alist)
 577            (list (cons 'view-mode help-xref-override-view-map)))
 578       (set-buffer-modified-p old-modified))))
 579
 580 ;;;###autoload
 581 (defun help-xref-button (match-number type &rest args)
 582   "Make a hyperlink for cross-reference text previously matched.
 583 MATCH-NUMBER is the subexpression of interest in the last matched
 584 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 585 passed to the button's help-function when it is invoked.
 586 See `help-make-xrefs'."
 587   ;; Don't mung properties we've added specially in some instances.
 588   (unless (button-at (match-beginning match-number))
 589     (make-text-button (match-beginning match-number)
 590                       (match-end match-number)
 591                       'type type 'help-args args)))
 592
 593 ;;;###autoload
 594 (defun help-insert-xref-button (string type &rest args)
 595   "Insert STRING and make a hyperlink from cross-reference text on it.
 596 TYPE is the type of button to use.  Any remaining arguments are passed
 597 to the button's help-function when it is invoked.
 598 See `help-make-xrefs'."
 599   (unless (button-at (point))
 600     (insert-text-button string 'type type 'help-args args)))
 601
 602 ;;;###autoload
 603 (defun help-xref-on-pp (from to)
 604   "Add xrefs for symbols in `pp's output between FROM and TO."
 605   (if (> (- to from) 5000) nil
 606     (with-syntax-table emacs-lisp-mode-syntax-table
 607       (save-excursion
 608         (save-restriction
 609           (narrow-to-region from to)
 610           (goto-char (point-min))
 611           (condition-case nil
 612               (while (not (eobp))
 613                 (cond
 614                  ((looking-at "\"") (forward-sexp 1))
 615                  ((looking-at "#<") (search-forward ">" nil 'move))
 616                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 617                   (let* ((sym (intern-soft (match-string 1)))
 618                          (type (cond ((fboundp sym) 'help-function)
 619                                      ((or (memq sym '(t nil))
 620                                           (keywordp sym))
 621                                       nil)
 622                                      ((and sym
 623                                            (or (boundp sym)
 624                                                (get sym
 625                                                     'variable-documentation)))
 626                                       'help-variable))))
 627                     (when type (help-xref-button 1 type sym)))
 628                   (goto-char (match-end 1)))
 629                  (t (forward-char 1))))
 630             (error nil)))))))
 631
 632 \f
 633 ;; Additional functions for (re-)creating types of help buffers.
 634 (defun help-xref-interned (symbol)
 635   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 636 Both variable, function and face documentation are extracted into a single
 637 help buffer."
 638   (with-current-buffer (help-buffer)
 639     ;; Push the previous item on the stack before clobbering the output buffer.
 640     (help-setup-xref nil nil)
 641     (let ((facedoc (when (facep symbol)
 642                      ;; Don't record the current entry in the stack.
 643                      (setq help-xref-stack-item nil)
 644                      (describe-face symbol)))
 645           (fdoc (when (fboundp symbol)
 646                   ;; Don't record the current entry in the stack.
 647                   (setq help-xref-stack-item nil)
 648                   (describe-function symbol)))
 649           (sdoc (when (or (boundp symbol)
 650                           (get symbol 'variable-documentation))
 651                   ;; Don't record the current entry in the stack.
 652                   (setq help-xref-stack-item nil)
 653                   (describe-variable symbol))))
 654       (cond
 655        (sdoc
 656         ;; We now have a help buffer on the variable.
 657         ;; Insert the function and face text before it.
 658         (when (or fdoc facedoc)
 659           (goto-char (point-min))
 660           (let ((inhibit-read-only t))
 661             (when fdoc
 662               (insert fdoc "\n\n")
 663               (when facedoc
 664                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 665                         " is also a " "face." "\n\n")))
 666             (when facedoc
 667               (insert facedoc "\n\n"))
 668             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 669                     " is also a " "variable." "\n\n"))
 670           ;; Don't record the `describe-variable' item in the stack.
 671           (setq help-xref-stack-item nil)
 672           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 673        (fdoc
 674         ;; We now have a help buffer on the function.
 675         ;; Insert face text before it.
 676         (when facedoc
 677           (goto-char (point-max))
 678           (let ((inhibit-read-only t))
 679             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 680                     " is also a " "face." "\n\n" facedoc))
 681           ;; Don't record the `describe-function' item in the stack.
 682           (setq help-xref-stack-item nil)
 683           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 684
 685 \f
 686 ;; Navigation/hyperlinking with xrefs
 687
 688 (defun help-xref-go-back (buffer)
 689   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 690   (let (item position method args)
 691     (with-current-buffer buffer
 692       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 693       (when help-xref-stack
 694         (setq item (pop help-xref-stack)
 695               ;; Clear the current item so that it won't get pushed
 696               ;; by the function we're about to call.  TODO: We could also
 697               ;; push it onto a "forward" stack and add a `forw' button.
 698               help-xref-stack-item nil
 699               position (car item)
 700               method (cadr item)
 701               args (cddr item))))
 702     (apply method args)
 703     (with-current-buffer buffer
 704       (if (get-buffer-window buffer)
 705           (set-window-point (get-buffer-window buffer) position)
 706         (goto-char position)))))
 707
 708 (defun help-xref-go-forward (buffer)
 709   "From BUFFER, go forward to next help buffer."
 710   (let (item position method args)
 711     (with-current-buffer buffer
 712       (push (cons (point) help-xref-stack-item) help-xref-stack)
 713       (when help-xref-forward-stack
 714         (setq item (pop help-xref-forward-stack)
 715               ;; Clear the current item so that it won't get pushed
 716               ;; by the function we're about to call.  TODO: We could also
 717               ;; push it onto a "forward" stack and add a `forw' button.
 718               help-xref-stack-item nil
 719               position (car item)
 720               method (cadr item)
 721               args (cddr item))))
 722     (apply method args)
 723     (with-current-buffer buffer
 724       (if (get-buffer-window buffer)
 725           (set-window-point (get-buffer-window buffer) position)
 726         (goto-char position)))))
 727
 728 (defun help-go-back ()
 729   "Go back to previous topic in this help buffer."
 730   (interactive)
 731   (if help-xref-stack
 732       (help-xref-go-back (current-buffer))
 733     (error "No previous help buffer")))
 734
 735 (defun help-go-forward ()
 736   "Go back to next topic in this help buffer."
 737   (interactive)
 738   (if help-xref-forward-stack
 739       (help-xref-go-forward (current-buffer))
 740     (error "No next help buffer")))
 741
 742 (defun help-do-xref (pos function args)
 743   "Call the help cross-reference function FUNCTION with args ARGS.
 744 Things are set up properly so that the resulting help-buffer has
 745 a proper [back] button."
 746   ;; There is a reference at point.  Follow it.
 747   (let ((help-xref-following t))
 748     (apply function args)))
 749
 750 ;; The doc string is meant to explain what buttons do.
 751 (defun help-follow-mouse ()
 752   "Follow the cross-reference that you click on."
 753   (interactive)
 754   (error "No cross-reference here"))
 755
 756 ;; The doc string is meant to explain what buttons do.
 757 (defun help-follow ()
 758   "Follow cross-reference at point.
 759
 760 For the cross-reference format, see `help-make-xrefs'."
 761   (interactive)
 762   (error "No cross-reference here"))
 763
 764 (defun help-follow-symbol (&optional pos)
 765   "In help buffer, show docs for symbol at POS, defaulting to point.
 766 Show all docs for that symbol as either a variable, function or face."
 767   (interactive "d")
 768   (unless pos
 769     (setq pos (point)))
 770   ;; check if the symbol under point is a function, variable or face
 771   (let ((sym
 772          (intern
 773           (save-excursion
 774             (goto-char pos) (skip-syntax-backward "w_")
 775             (buffer-substring (point)
 776                               (progn (skip-syntax-forward "w_")
 777                                      (point)))))))
 778     (when (or (boundp sym)
 779               (get sym 'variable-documentation)
 780               (fboundp sym) (facep sym))
 781       (help-do-xref pos #'help-xref-interned (list sym)))))
 782
 783 (defun help-insert-string (string)
 784   "Insert STRING to the help buffer and install xref info for it.
 785 This function can be used to restore the old contents of the help buffer
 786 when going back to the previous topic in the xref stack.  It is needed
 787 in case when it is impossible to recompute the old contents of the
 788 help buffer by other means."
 789   (setq help-xref-stack-item (list #'help-insert-string string))
 790   (with-output-to-temp-buffer (help-buffer)
 791     (insert string)))
 792
 793 (provide 'help-mode)
 794
 795 ;; arch-tag: 850954ae-3725-4cb4-8e91-0bf6d52d6b0b
 796 ;;; help-mode.el ends here