lisp/tempo.el

   1 ;;; tempo.el --- Flexible template insertion -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 1994-1995, 2001-2019 Free Software Foundation, Inc.
   4
   5 ;; Author: David Kågedal <davidk@lysator.liu.se>
   6 ;; Created: 16 Feb 1994
   7 ;; Kågedal's last version number: 1.2.4
   8 ;; Keywords: abbrev, extensions, languages, tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file provides a simple way to define powerful templates, or
  28 ;; macros, if you wish. It is mainly intended for, but not limited to,
  29 ;; other programmers to be used for creating shortcuts for editing
  30 ;; certain kind of documents. It was originally written to be used by
  31 ;; a HTML editing mode written by Nelson Minar <nelson@santafe.edu>,
  32 ;; and his html-helper-mode.el is probably the best example of how to
  33 ;; use this program.
  34
  35 ;; A template is defined as a list of items to be inserted in the
  36 ;; current buffer at point. Some of the items can be simple strings,
  37 ;; while other can control formatting or define special points of
  38 ;; interest in the inserted text.
  39
  40 ;; If a template defines a "point of interest" that point is inserted
  41 ;; in a buffer-local list of "points of interest" that the user can
  42 ;; jump between with the commands `tempo-backward-mark' and
  43 ;; `tempo-forward-mark'. If the template definer provides a prompt for
  44 ;; the point, and the variable `tempo-interactive' is non-nil, the
  45 ;; user will be prompted for a string to be inserted in the buffer,
  46 ;; using the minibuffer.
  47
  48 ;; The template can also define one point to be replaced with the
  49 ;; current region if the template command is called with a prefix (or
  50 ;; a non-nil argument).
  51
  52 ;; More flexible templates can be created by including lisp symbols,
  53 ;; which will be evaluated as variables, or lists, which will be
  54 ;; evaluated as lisp expressions.
  55
  56 ;; See the documentation for tempo-define-template for the different
  57 ;; items that can be used to define a tempo template.
  58
  59 ;; One of the more powerful features of tempo templates are automatic
  60 ;; completion. With every template can be assigned a special tag that
  61 ;; should be recognized by `tempo-complete-tag' and expanded to the
  62 ;; complete template. By default the tags are added to a global list
  63 ;; of template tags, and are matched against the last word before
  64 ;; point. But if you assign your tags to a specific list, you can also
  65 ;; specify another method for matching text in the buffer against the
  66 ;; tags. In the HTML mode, for instance, the tags are matched against
  67 ;; the text between the last `<' and point.
  68
  69 ;; When defining a template named `foo', a symbol named
  70 ;; `tempo-template-foo' will be created whose value as a variable will
  71 ;; be the template definition, and its function value will be an
  72 ;; interactive function that inserts the template at the point.
  73
  74 ;; The latest tempo.el distribution can be fetched from
  75 ;; ftp.lysator.liu.se in the directory /pub/emacs
  76
  77 ;; There is also a WWW page at
  78 ;; http://www.lysator.liu.se/~davidk/elisp/ which has some information
  79
  80 ;;; Known bugs:
  81
  82 ;; If the 'o is the first element in a template, strange things can
  83 ;; happen when the template is inserted at the beginning of a
  84 ;; line. This is due to strange behavior in open-line. But it should
  85 ;; be easily avoided.
  86
  87 ;; The 'o tag is also a problem when including the region. This will
  88 ;; be looked into.
  89
  90 ;; Clicking mouse-2 in the completion buffer gives strange results.
  91
  92 ;; There is a bug in some emacs versions that prevents completion from
  93 ;; working. If it doesn't work for you, send me a note indicating your
  94 ;; emacs version and your problems.
  95
  96 ;;; Contributors:
  97
  98 ;; These people have given me important feedback and new ideas for
  99 ;; tempo.el. Thanks.
 100
 101 ;; Nelson Minar <nelson@santafe.edu>
 102 ;; Richard Stallman <rms@gnu.org>
 103 ;; Lars Lindberg <Lars.Lindberg@sypro.cap.se>
 104 ;; Glen Whitney <Glen.Whitney@math.lsa.umich.edu>
 105
 106 ;;; Code:
 107
 108 ;;; User options
 109
 110 (defgroup tempo nil
 111   "Flexible template insertion."
 112   :prefix "tempo-"
 113   :group 'tools)
 114
 115 (defcustom tempo-interactive nil
 116   "Prompt user for strings in templates.
 117 If this variable is non-nil, `tempo-insert' prompts the
 118 user for text to insert in the templates."
 119   :type 'boolean
 120   :group 'tempo)
 121
 122 (defcustom tempo-insert-region nil
 123   "Automatically insert current region when there is a `r' in the template
 124 If this variable is nil, `r' elements will be treated just like `p'
 125 elements, unless the template function is given a prefix (or a non-nil
 126 argument).  If this variable is non-nil, the behavior is reversed.
 127
 128 In Transient Mark mode, this option is unused."
 129   :type 'boolean
 130   :group 'tempo)
 131
 132 (defcustom tempo-show-completion-buffer t
 133   "If non-nil, show a buffer with possible completions, when only
 134 a partial completion can be found."
 135   :type 'boolean
 136   :group 'tempo)
 137
 138 (defcustom tempo-leave-completion-buffer nil
 139   "If nil, a completion buffer generated by \\[tempo-complete-tag]
 140 disappears at the next keypress; otherwise, it remains forever."
 141   :type 'boolean
 142   :group 'tempo)
 143
 144 ;;; Internal variables
 145
 146 (defvar tempo-insert-string-functions nil
 147   "List of functions to run when inserting a string.
 148 Each function is called with a single arg, STRING and should return
 149 another string.  This could be used for making all strings upcase by
 150 setting it to (upcase), for example.")
 151
 152 (defvar tempo-tags nil
 153   "An association list with tags and corresponding templates.")
 154
 155 (defvar-local tempo-local-tags '((tempo-tags . nil))
 156   "A list of locally installed tag completion lists.
 157 It is an association list where the car of every element is a symbol
 158 whose variable value is a template list.  The cdr part, if non-nil,
 159 is a function or a regexp that defines the string to match.  See the
 160 documentation for the function `tempo-complete-tag' for more info.
 161
 162 `tempo-tags' is always in the last position in this list.")
 163
 164 (defvar-local tempo-collection nil
 165   "A collection of all the tags defined for the current buffer.")
 166
 167 (defvar-local tempo-dirty-collection t
 168   "Indicates if the tag collection needs to be rebuilt.")
 169
 170 (defvar-local tempo-marks nil
 171   "A list of marks to jump to with `\\[tempo-forward-mark]' and `\\[tempo-backward-mark]'.")
 172
 173 (defvar-local tempo-match-finder "\\b\\([[:word:]]+\\)\\="
 174   "The regexp or function used to find the string to match against tags.
 175
 176 If `tempo-match-finder' is a string, it should contain a regular
 177 expression with at least one \\( \\) pair.  When searching for tags,
 178 `tempo-complete-tag' calls `re-search-backward' with this string, and
 179 the string between the first \\( and \\) is used for matching against
 180 each string in the tag list. If one is found, the whole text between
 181 the first \\( and the point is replaced with the inserted template.
 182
 183 You will probably want to include \\=\\= at the end of the regexp to
 184 make sure that the string is matched only against text adjacent to the
 185 point.
 186
 187 If `tempo-match-finder' is a symbol, it should be a function that
 188 returns a pair of the form (STRING . POS), where STRING is the string
 189 used for matching and POS is the buffer position after which text
 190 should be replaced with a template.")
 191
 192 (defvar tempo-user-elements nil
 193   "Element handlers for user-defined elements.
 194 A list of symbols which are bound to functions that take one argument.
 195 This function should return something to be sent to `tempo-insert' if
 196 it recognizes the argument, and nil otherwise.")
 197
 198 (defvar-local tempo-named-insertions nil
 199   "Temporary storage for named insertions.")
 200
 201 (defvar-local tempo-region-start (make-marker)
 202   "Region start when inserting around the region.")
 203
 204 (defvar-local tempo-region-stop (make-marker)
 205   "Region stop when inserting around the region.")
 206
 207 ;;; Functions
 208
 209 ;;
 210 ;; tempo-define-template
 211
 212 (defun tempo-define-template (name elements &optional tag documentation taglist)
 213   "Define a template.
 214 This function creates a template variable `tempo-template-NAME' and an
 215 interactive function `tempo-template-NAME' that inserts the template
 216 at the point.  The created function is returned.
 217
 218 NAME is a string that contains the name of the template, ELEMENTS is a
 219 list of elements in the template, TAG is the tag used for completion,
 220 DOCUMENTATION is the documentation string for the insertion command
 221 created, and TAGLIST (a symbol) is the tag list that TAG (if provided)
 222 should be added to.  If TAGLIST is nil and TAG is non-nil, TAG is
 223 added to `tempo-tags'.
 224
 225 The elements in ELEMENTS can be of several types:
 226
 227  - A string: It is sent to the hooks in `tempo-insert-string-functions',
 228    and the result is inserted.
 229  - The symbol `p': This position is saved in `tempo-marks'.
 230  - The symbol `r': If `tempo-insert' is called with ON-REGION non-nil
 231    the current region is placed here.  Otherwise it works like `p'.
 232  - (p PROMPT <NAME> <NOINSERT>): If `tempo-interactive' is non-nil, the
 233    user is prompted in the minibuffer with PROMPT for a string to be
 234    inserted.  If the optional parameter NAME is non-nil, the text is
 235    saved for later insertion with the `s' tag.  If there already is
 236    something saved under NAME that value is used instead and no
 237    prompting is made.  If NOINSERT is provided and non-nil, nothing is
 238    inserted, but text is still saved when a NAME is provided.  For
 239    clarity, the symbol `noinsert' should be used as argument.
 240  - (P PROMPT <NAME> <NOINSERT>): Works just like the previous tag, but
 241    forces `tempo-interactive' to be true.
 242  - (r PROMPT <NAME> <NOINSERT>): Like the previous tag, but if
 243    `tempo-interactive' is nil and `tempo-insert' is called with
 244    ON-REGION non-nil, the current region is placed here.  This usually
 245    happens when you call the template function with a prefix argument.
 246  - (s NAME): Inserts text previously read with the (p ..) construct.
 247    Finds the insertion saved under NAME and inserts it.  Acts like `p'
 248    if tempo-interactive is nil.
 249  - `&': If there is only whitespace between the line start and point,
 250    nothing happens.  Otherwise a newline is inserted.
 251  - `%': If there is only whitespace between point and end of line,
 252    nothing happens.  Otherwise a newline is inserted.
 253  - `n': Inserts a newline.
 254  - `>': The line is indented using `indent-according-to-mode'.  Note
 255    that you often should place this item after the text you want on
 256    the line.
 257  - `r>': Like `r', but it also indents the region.
 258  - (r> PROMPT <NAME> <NOINSERT>): Like (r ...), but is also indents
 259    the region.
 260  - `n>': Inserts a newline and indents line.
 261  - `o': Like `%' but leaves the point before the newline.
 262  - nil: It is ignored.
 263  - Anything else: Each function in `tempo-user-elements' is called
 264    with it as argument until one of them returns non-nil, and the
 265    result is inserted.  If all of them return nil, it is evaluated and
 266    the result is treated as an element to be inserted.  One additional
 267    tag is useful for these cases.  If an expression returns a list (l
 268    foo bar), the elements after `l' will be inserted according to the
 269    usual rules.  This makes it possible to return several elements
 270    from one expression."
 271   (let* ((template-name (intern (concat "tempo-template-"
 272                                        name)))
 273          (command-name template-name))
 274     (set template-name elements)
 275     (fset command-name (list 'lambda (list '&optional 'arg)
 276                              (or documentation
 277                                  (concat "Insert a " name "."))
 278                              (list 'interactive "*P")
 279                              (list 'tempo-insert-template (list 'quote
 280                                                                 template-name)
 281                                    (list 'if 'tempo-insert-region
 282                                          (list 'not 'arg) 'arg))))
 283     (and tag
 284          (tempo-add-tag tag template-name taglist))
 285     command-name))
 286
 287 ;;;
 288 ;;; tempo-insert-template
 289
 290 (defun tempo-insert-template (template on-region)
 291   "Insert a template.
 292 TEMPLATE is the template to be inserted.  If ON-REGION is non-nil the
 293 `r' elements are replaced with the current region.  In Transient Mark
 294 mode, ON-REGION is ignored and assumed true if the region is active."
 295   (unwind-protect
 296       (progn
 297         (if (or (and transient-mark-mode
 298                      mark-active))
 299             (setq on-region t))
 300         (and on-region
 301              (set-marker tempo-region-start (min (mark) (point)))
 302              (set-marker tempo-region-stop (max (mark) (point))))
 303         (if on-region
 304             (goto-char tempo-region-start))
 305         (save-excursion
 306           (tempo-insert-mark (point-marker))
 307           (mapc (function (lambda (elt)
 308                             (tempo-insert elt on-region)))
 309                 (symbol-value template))
 310           (tempo-insert-mark (point-marker)))
 311         (tempo-forward-mark))
 312     (tempo-forget-insertions)
 313     (and transient-mark-mode
 314          (deactivate-mark))))
 315
 316 ;;;
 317 ;;; tempo-insert
 318
 319 (defun tempo-insert (element on-region)
 320   "Insert a template element.
 321 Insert one element from a template. If ON-REGION is non-nil the `r'
 322 elements are replaced with the current region.
 323
 324 See documentation for `tempo-define-template' for the kind of elements
 325 possible."
 326   (cond ((stringp element) (tempo-process-and-insert-string element))
 327         ((and (consp element)
 328               (eq (car element) 'p)) (tempo-insert-prompt-compat
 329                                       (cdr element)))
 330         ((and (consp element)
 331               (eq (car element) 'P)) (let ((tempo-interactive t))
 332                                        (tempo-insert-prompt-compat
 333                                         (cdr element))))
 334 ;;;     ((and (consp element)
 335 ;;;           (eq (car element) 'v)) (tempo-save-named
 336 ;;;                                   (nth 1 element)
 337 ;;;                                   nil
 338 ;;;                                   (nth 2 element)))
 339         ((and (consp element)
 340               (eq (car element) 'r)) (if on-region
 341                                          (goto-char tempo-region-stop)
 342                                        (tempo-insert-prompt-compat
 343                                         (cdr element))))
 344         ((and (consp element)
 345               (eq (car element) 'r>)) (if on-region
 346                                           (progn
 347                                             (goto-char tempo-region-stop)
 348                                             (indent-region (mark) (point) nil))
 349                                         (tempo-insert-prompt-compat
 350                                          (cdr element))))
 351         ((and (consp element)
 352               (eq (car element) 's)) (tempo-insert-named (car (cdr element))))
 353         ((and (consp element)
 354               (eq (car element) 'l)) (mapcar (function
 355                                               (lambda (elt)
 356                                                 (tempo-insert elt on-region)))
 357                                              (cdr element)))
 358         ((eq element 'p) (tempo-insert-mark (point-marker)))
 359         ((eq element 'r) (if on-region
 360                              (goto-char tempo-region-stop)
 361                            (tempo-insert-mark (point-marker))))
 362         ((eq element 'r>) (if on-region
 363                               (progn
 364                                 (goto-char tempo-region-stop)
 365                                 (indent-region (mark) (point) nil))
 366                             (tempo-insert-mark (point-marker))))
 367         ((eq element '>) (indent-according-to-mode))
 368         ((eq element '&) (if (not (or (= (current-column) 0)
 369                                       (save-excursion
 370                                         (re-search-backward
 371                                          "^\\s-*\\=" nil t))))
 372                              (insert "\n")))
 373         ((eq element '%) (if (not (or (eolp)
 374                                       (save-excursion
 375                                         (re-search-forward
 376                                          "\\=\\s-*$" nil t))))
 377                              (insert "\n")))
 378         ((eq element 'n) (insert "\n"))
 379         ((eq element 'n>) (insert "\n") (indent-according-to-mode))
 380         ;; Bug: If the 'o is the first element in a template, strange
 381         ;; things can happen when the template is inserted at the
 382         ;; beginning of a line.
 383         ((eq element 'o) (if (not (or on-region
 384                                       (eolp)
 385                                       (save-excursion
 386                                         (re-search-forward
 387                                          "\\=\\s-*$" nil t))))
 388                              (open-line 1)))
 389         ((null element))
 390         (t (tempo-insert (or (tempo-is-user-element element)
 391                              (eval element))
 392                          on-region))))
 393
 394 ;;;
 395 ;;; tempo-insert-prompt
 396
 397 (defun tempo-insert-prompt-compat (prompt)
 398   "Compatibility hack for `tempo-insert-prompt'.
 399 PROMPT can be either a prompt string, or a list of arguments to
 400 `tempo-insert-prompt', or nil."
 401   (if (consp prompt)                    ; not nil either
 402       (apply 'tempo-insert-prompt prompt)
 403     (tempo-insert-prompt prompt)))
 404
 405 (defun tempo-insert-prompt (prompt &optional save-name no-insert)
 406   "Prompt for a text string and insert it in the current buffer.
 407 If the variable `tempo-interactive' is non-nil the user is prompted
 408 for a string in the minibuffer, which is then inserted in the current
 409 buffer.  If `tempo-interactive' is nil, the current point is placed on
 410 `tempo-mark'.
 411
 412 PROMPT is the prompt string, SAVE-NAME is a name to save the inserted
 413 text under.  If the optional argument NO-INSERT is non-nil, no text is
 414 inserted.  This can be useful when there is a SAVE-NAME.
 415
 416 If there already is a value for SAVE-NAME, it is used and the user is
 417 never prompted."
 418   (let (insertion
 419         (previous (and save-name
 420                        (tempo-lookup-named save-name))))
 421     (cond
 422      ;; Insert  previous value, unless no-insert is non-nil
 423      ((and previous
 424            (not no-insert))
 425       (tempo-insert-named save-name)) ; A double lookup here, but who
 426                                       ; cares
 427      ;; If no-insert is non-nil, don't insert the previous value. Just
 428      ;; keep it
 429      (previous
 430       nil)
 431      ;; No previous value. Prompt or insert mark
 432      (tempo-interactive
 433       (if (not (stringp prompt))
 434           (error "tempo: The prompt (%s) is not a string" prompt))
 435       (setq insertion (read-string prompt))
 436       (or no-insert
 437           (insert insertion))
 438       (if save-name
 439           (tempo-save-named save-name insertion)))
 440      (t
 441       (tempo-insert-mark (point-marker))))))
 442
 443 ;;;
 444 ;;; tempo-is-user-element
 445
 446 (defun tempo-is-user-element (element)
 447   "Tries all the user-defined element handlers in `tempo-user-elements'."
 448   ;; Sigh... I need (some list)
 449   (catch 'found
 450     (mapc (function (lambda (handler)
 451                       (let ((result (funcall handler element)))
 452                         (if result (throw 'found result)))))
 453           tempo-user-elements)
 454     (throw 'found nil)))
 455
 456 ;;;
 457 ;;; tempo-forget-insertions
 458
 459 (defun tempo-forget-insertions ()
 460   "Forget all the saved named insertions."
 461   (setq tempo-named-insertions nil))
 462
 463 ;;;
 464 ;;; tempo-save-named
 465
 466 (defun tempo-save-named (name data)     ; Had an optional prompt for 'v
 467   "Save some data for later insertion
 468 The contents of DATA is saved under the name NAME.
 469
 470 The data can later be retrieved with `tempo-lookup-named'.
 471
 472 This function returns nil, so it can be used in a template without
 473 inserting anything."
 474   (setq tempo-named-insertions
 475         (cons (cons name data)
 476               tempo-named-insertions))
 477   nil)
 478
 479 ;;;
 480 ;;; tempo-lookup-named
 481
 482 (defun tempo-lookup-named (name)
 483   "Lookup some saved data under the name NAME.
 484 Returns the data if NAME was found, and nil otherwise."
 485   (cdr (assq name tempo-named-insertions)))
 486
 487 ;;;
 488 ;;; tempo-insert-named
 489
 490 (defun tempo-insert-named (name)
 491   "Insert the previous insertion saved under a named specified in NAME.
 492 If there is no such name saved, a tempo mark is inserted.
 493
 494 Note that if the data is a string, it will not be run through the string
 495 processor."
 496   (let* ((insertion (tempo-lookup-named name)))
 497     (cond ((null insertion)
 498            (tempo-insert-mark (point-marker)))
 499           ((stringp insertion)
 500            (insert insertion))
 501           (t
 502            (tempo-insert insertion nil)))))
 503
 504
 505 ;;;
 506 ;;; tempo-process-and-insert-string
 507
 508 (defun tempo-process-and-insert-string (string)
 509   "Insert a string from a template.
 510 Run a string through the preprocessors in `tempo-insert-string-functions'
 511 and insert the results."
 512   (cond ((null tempo-insert-string-functions)
 513          nil)
 514         ((symbolp tempo-insert-string-functions)
 515          (setq string
 516                (funcall tempo-insert-string-functions string)))
 517         ((listp tempo-insert-string-functions)
 518          (dolist (fn tempo-insert-string-functions)
 519            (setq string (funcall fn string))))
 520         (t
 521          (error "Bogus value in tempo-insert-string-functions: %s"
 522                 tempo-insert-string-functions)))
 523   (insert string))
 524
 525 ;;;
 526 ;;; tempo-insert-mark
 527
 528 (defun tempo-insert-mark (mark)
 529   "Insert a mark `tempo-marks' while keeping it sorted."
 530   (cond ((null tempo-marks) (setq tempo-marks (list mark)))
 531         ((< mark (car tempo-marks)) (setq tempo-marks (cons mark tempo-marks)))
 532         (t (let ((lp tempo-marks))
 533              (while (and (cdr lp)
 534                          (<= (car (cdr lp)) mark))
 535                (setq lp (cdr lp)))
 536              (if (not (= mark (car lp)))
 537                  (setcdr lp (cons mark (cdr lp))))))))
 538
 539 ;;;
 540 ;;; tempo-forward-mark
 541
 542 (defun tempo-forward-mark ()
 543   "Jump to the next mark in `tempo-forward-mark-list'."
 544   (interactive)
 545   (let ((next-mark (catch 'found
 546                      (mapc
 547                       (function
 548                        (lambda (mark)
 549                          (if (< (point) mark)
 550                              (throw 'found mark))))
 551                       tempo-marks)
 552                      ;; return nil if not found
 553                      nil)))
 554     (if next-mark
 555         (goto-char next-mark))))
 556
 557 ;;;
 558 ;;; tempo-backward-mark
 559
 560 (defun tempo-backward-mark ()
 561   "Jump to the previous mark in `tempo-back-mark-list'."
 562   (interactive)
 563   (let ((prev-mark (catch 'found
 564                      (let (last)
 565                        (mapc
 566                         (function
 567                          (lambda (mark)
 568                            (if (<= (point) mark)
 569                                (throw 'found last))
 570                            (setq last mark)))
 571                         tempo-marks)
 572                        last))))
 573     (if prev-mark
 574         (goto-char prev-mark))))
 575
 576 ;;;
 577 ;;; tempo-add-tag
 578
 579 (defun tempo-add-tag (tag template &optional tag-list)
 580   "Add a template tag.
 581 Add the TAG, that should complete to TEMPLATE to the list in TAG-LIST,
 582 or to `tempo-tags' if TAG-LIST is nil."
 583
 584   (interactive "sTag: \nCTemplate: ")
 585   (if (null tag-list)
 586       (setq tag-list 'tempo-tags))
 587   (if (not (assoc tag (symbol-value tag-list)))
 588       (set tag-list (cons (cons tag template) (symbol-value tag-list))))
 589   (tempo-invalidate-collection))
 590
 591 ;;;
 592 ;;; tempo-use-tag-list
 593
 594 (defun tempo-use-tag-list (tag-list &optional completion-function)
 595   "Install TAG-LIST to be used for template completion in the current buffer.
 596 TAG-LIST is a symbol whose variable value is a tag list created with
 597 `tempo-add-tag'.
 598
 599 COMPLETION-FUNCTION is an obsolete option for specifying an optional
 600 function or string that is used by `\\[tempo-complete-tag]' to find a
 601 string to match the tag against.  It has the same definition as the
 602 variable `tempo-match-finder'.  In this version, supplying a
 603 COMPLETION-FUNCTION just sets `tempo-match-finder' locally."
 604   (setf (alist-get tag-list tempo-local-tags) completion-function)
 605   (if completion-function
 606       (setq tempo-match-finder completion-function))
 607   (tempo-invalidate-collection))
 608
 609 ;;;
 610 ;;; tempo-invalidate-collection
 611
 612 (defun tempo-invalidate-collection ()
 613   "Marks the tag collection as obsolete.
 614 Whenever it is needed again it will be rebuilt."
 615   (setq tempo-dirty-collection t))
 616
 617 ;;;
 618 ;;; tempo-build-collection
 619
 620 (defun tempo-build-collection ()
 621   "Build a collection of all the tags and return it.
 622 If `tempo-dirty-collection' is nil, the old collection is reused."
 623   (prog1
 624       (or (and (not tempo-dirty-collection)
 625                tempo-collection)
 626           (setq tempo-collection
 627                 (apply (function append)
 628                        (mapcar (function (lambda (tag-list)
 629                                         ; If the format for
 630                                         ; tempo-local-tags changes,
 631                                         ; change this
 632                                            (eval (car tag-list))))
 633                                tempo-local-tags))))
 634     (setq tempo-dirty-collection nil)))
 635
 636 ;;;
 637 ;;; tempo-find-match-string
 638
 639 (defun tempo-find-match-string (finder)
 640   "Find a string to be matched against a tag list.
 641 FINDER is a function or a string.  Returns (STRING . POS), or nil
 642 if no reasonable string is found."
 643   (cond ((stringp finder)
 644          (let (successful)
 645            (save-excursion
 646              (or (setq successful (re-search-backward finder nil t))
 647                  0))
 648            (if successful
 649                (cons (buffer-substring (match-beginning 1)
 650                                        (match-end 1)) ; This seems to be a
 651                                         ; bug in emacs
 652                      (match-beginning 1))
 653              nil)))
 654         (t
 655          (funcall finder))))
 656
 657 ;;;
 658 ;;; tempo-complete-tag
 659
 660 (defun tempo-complete-tag (&optional silent)
 661   "Look for a tag and expand it.
 662 All the tags in the tag lists in `tempo-local-tags'
 663 \(this includes `tempo-tags') are searched for a match for the text
 664 before the point.  The way the string to match for is determined can
 665 be altered with the variable `tempo-match-finder'.  If
 666 `tempo-match-finder' returns nil, then the results are the same as
 667 no match at all.
 668
 669 If a single match is found, the corresponding template is expanded in
 670 place of the matching string.
 671
 672 If a partial completion or no match at all is found, and SILENT is
 673 non-nil, the function will give a signal.
 674
 675 If a partial completion is found and `tempo-show-completion-buffer' is
 676 non-nil, a buffer containing possible completions is displayed."
 677
 678   ;; This function may look like a hack, but this is how I want it to
 679   ;; work.
 680   (interactive "*")
 681   (let* ((collection (tempo-build-collection))
 682          (match-info (tempo-find-match-string tempo-match-finder))
 683          (match-string (car match-info))
 684          (match-start (cdr match-info))
 685          (exact (assoc match-string collection))
 686          (compl (or (car exact)
 687                     (and match-info (try-completion match-string collection)))))
 688     (if compl (delete-region match-start (point)))
 689     (cond ((null match-info) (or silent (ding)))
 690           ((null compl) (or silent (ding)))
 691           ((eq compl t) (tempo-insert-template
 692                          (cdr (assoc match-string
 693                                      collection))
 694                          nil))
 695           (t (if (setq exact (assoc compl collection))
 696                  (tempo-insert-template (cdr exact) nil)
 697                (insert compl)
 698                (or silent (ding))
 699                (if tempo-show-completion-buffer
 700                    (tempo-display-completions match-string
 701                                               collection)))))))
 702
 703
 704 ;;;
 705 ;;; tempo-display-completions
 706
 707 (defun tempo-display-completions (string tag-list)
 708   "Show a buffer containing possible completions for STRING."
 709   (if tempo-leave-completion-buffer
 710       (with-output-to-temp-buffer "*Completions*"
 711         (display-completion-list
 712          (completion-hilit-commonality (all-completions string tag-list)
 713                                        (length string))))
 714     (save-window-excursion
 715       (with-output-to-temp-buffer "*Completions*"
 716         (display-completion-list
 717          (completion-hilit-commonality (all-completions string tag-list)
 718                                        (length string))))
 719       (sit-for 32767))))
 720
 721 ;;;
 722 ;;; tempo-expand-if-complete
 723
 724 (defun tempo-expand-if-complete ()
 725   "Expand the tag before point if it is complete.
 726 Returns non-nil if an expansion was made and nil otherwise.
 727
 728 This could as an example be used in a command that is bound to the
 729 space bar, and looks something like this:
 730
 731 \(defun tempo-space ()
 732   (interactive \"*\")
 733   (or (tempo-expand-if-complete)
 734       (insert \" \")))"
 735
 736   (interactive "*")
 737   (let* ((collection (tempo-build-collection))
 738          (match-info (tempo-find-match-string tempo-match-finder))
 739          (match-string (car match-info))
 740          (match-start (cdr match-info))
 741          (exact (assoc match-string collection)))
 742     (if exact
 743         (progn
 744           (delete-region match-start (point))
 745           (tempo-insert-template (cdr exact) nil)
 746           t)
 747       nil)))
 748
 749 (provide 'tempo)
 750
 751 ;;; tempo.el ends here