lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support
   2
   3 ;; Maintainer: FSF
   4 ;; Keywords: internal
   5
   6 ;; Copyright (c) 1993, 1994 Free Software Foundation, Inc.
   7 ;; Based partially on earlier release by Lucid.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;; This is for temporary compatibility with pre-release Emacs 19.
  31 (defalias 'x-selection 'x-get-selection)
  32 (defun x-get-selection (&optional type data-type)
  33   "Return the value of an X Windows selection.
  34 The argument TYPE (default `PRIMARY') says which selection,
  35 and the argument DATA-TYPE (default `STRING') says
  36 how to convert the data.
  37
  38 TYPE may be `SECONDARY' or `CLIPBOARD', in addition to `PRIMARY'.
  39 DATA-TYPE is usually `STRING', but can also be one of the symbols
  40 in `selection-converter-alist', which see."
  41   (x-get-selection-internal (or type 'PRIMARY) (or data-type 'STRING)))
  42
  43 (defun x-get-clipboard ()
  44   "Return text pasted to the clipboard."
  45   (x-get-selection-internal 'CLIPBOARD 'STRING))
  46
  47 (defun x-set-selection (type data)
  48   "Make an X Windows selection of type TYPE and value DATA.
  49 The argument TYPE (default `PRIMARY') says which selection,
  50 and DATA specifies the contents.  DATA may be a string,
  51 a symbol, an integer (or a cons of two integers or list of two integers).
  52
  53 The selection may also be a cons of two markers pointing to the same buffer,
  54 or an overlay.  In these cases, the selection is considered to be the text
  55 between the markers *at whatever time the selection is examined*.
  56 Thus, editing done in the buffer after you specify the selection
  57 can alter the effective value of the selection.
  58
  59 The data may also be a vector of valid non-vector selection values.
  60
  61 Interactively, the text of the region is used as the selection value
  62 if the prefix arg is set."
  63   (interactive (if (not current-prefix-arg)
  64                    (list 'PRIMARY (read-string "Set text for pasting: "))
  65                  (list 'PRIMARY (buffer-substring (region-beginning) (region-end)))))
  66   ;; This is for temporary compatibility with pre-release Emacs 19.
  67   (if (stringp type)
  68       (setq type (intern type)))
  69   (or (x-valid-simple-selection-p data)
  70       (and (vectorp data)
  71            (let ((valid t)
  72                  (i (1- (length data))))
  73              (while (>= i 0)
  74                (or (x-valid-simple-selection-p (aref data i))
  75                    (setq valid nil))
  76                (setq i (1- i)))
  77              valid))
  78       (signal 'error (list "invalid selection" data)))
  79   (or type (setq type 'PRIMARY))
  80   (if data
  81       (x-own-selection-internal type data)
  82     (x-disown-selection-internal type))
  83   data)
  84
  85 (defun x-valid-simple-selection-p (data)
  86   (or (stringp data)
  87       (symbolp data)
  88       (integerp data)
  89       (and (consp data)
  90            (integerp (car data))
  91            (or (integerp (cdr data))
  92                (and (consp (cdr data))
  93                     (integerp (car (cdr data))))))
  94       (overlayp data)
  95       (and (consp data)
  96            (markerp (car data))
  97            (markerp (cdr data))
  98            (marker-buffer (car data))
  99            (marker-buffer (cdr data))
 100            (eq (marker-buffer (car data))
 101                (marker-buffer (cdr data)))
 102            (buffer-name (marker-buffer (car data)))
 103            (buffer-name (marker-buffer (cdr data))))))
 104 \f
 105 ;;; Cut Buffer support
 106
 107 (defun x-get-cut-buffer (&optional which-one)
 108   "Returns the value of one of the 8 X server cut-buffers.
 109 Optional arg WHICH-ONE should be a number from 0 to 7, defaulting to 0.
 110 Cut buffers are considered obsolete; you should use selections instead."
 111   (x-get-cut-buffer-internal
 112    (if which-one
 113        (aref [CUT_BUFFER0 CUT_BUFFER1 CUT_BUFFER2 CUT_BUFFER3
 114               CUT_BUFFER4 CUT_BUFFER5 CUT_BUFFER6 CUT_BUFFER7]
 115              which-one)
 116      'CUT_BUFFER0)))
 117
 118 (defun x-set-cut-buffer (string &optional push)
 119   "Store STRING into the X server's primary cut buffer.
 120 If PUSH is non-nil, also rotate the cut buffers:
 121 this means the previous value of the primary cut buffer moves the second
 122 cut buffer, and the second to the third, and so on (there are 8 buffers.)
 123 Cut buffers are considered obsolete; you should use selections instead."
 124   ;; Check the data type of STRING.
 125   (substring string 0 0)
 126   (if push
 127       (x-rotate-cut-buffers-internal 1))
 128   (x-store-cut-buffer-internal 'CUT_BUFFER0 string))
 129
 130 \f
 131 ;;; Functions to convert the selection into various other selection types.
 132 ;;; Every selection type that Emacs handles is implemented this way, except
 133 ;;; for TIMESTAMP, which is a special case.
 134
 135 (defun xselect-convert-to-string (selection type value)
 136   (let (str coding)
 137     ;; Get the actual string from VALUE.
 138     (cond ((stringp value)
 139            (setq str value))
 140
 141           ((overlayp value)
 142            (save-excursion
 143              (or (buffer-name (overlay-buffer value))
 144                  (error "selection is in a killed buffer"))
 145              (set-buffer (overlay-buffer value))
 146              (setq str (buffer-substring (overlay-start value)
 147                                          (overlay-end value)))))
 148           ((and (consp value)
 149                 (markerp (car value))
 150                 (markerp (cdr value)))
 151            (or (eq (marker-buffer (car value)) (marker-buffer (cdr value)))
 152                (signal 'error
 153                        (list "markers must be in the same buffer"
 154                              (car value) (cdr value))))
 155            (save-excursion
 156              (set-buffer (or (marker-buffer (car value))
 157                              (error "selection is in a killed buffer")))
 158              (setq str (buffer-substring (car value) (cdr value))))))
 159
 160     (when str
 161       ;; If TYPE is nil, this is a local request, thus return STR as
 162       ;; is.  Otherwise, encode STR.
 163       (if (not type)
 164           str
 165         (setq coding (or next-selection-coding-system selection-coding-system))
 166         (if coding
 167             (setq coding (coding-system-base coding))
 168           (setq coding 'raw-text))
 169         ;; Suppress producing escape sequences for compositions.
 170         (remove-text-properties 0 (length str) '(composition nil) str)
 171         (cond
 172          ((eq type 'TEXT)
 173           (if (not (multibyte-string-p str))
 174               ;; Don't have to encode unibyte string.
 175               (setq type 'STRING)
 176             ;; If STR contains only ASCII, Latin-1, and raw bytes,
 177             ;; encode STR by iso-latin-1, and return it as type
 178             ;; `STRING'.  Otherwise, encode STR by CODING.  In that
 179             ;; case, the returing type depends on CODING.
 180             (let ((charsets (find-charset-string str)))
 181               (setq charsets
 182                     (delq 'ascii
 183                           (delq 'latin-iso8859-1
 184                                 (delq 'eight-bit-control
 185                                       (delq 'eight-bit-graphic charsets)))))
 186               (if charsets
 187                   (setq str (encode-coding-string str coding)
 188                         type (if (memq coding '(compound-text
 189                                                 compound-text-with-extensions))
 190                                  'COMPOUND_TEXT
 191                                'STRING))
 192                 (setq type 'STRING
 193                       str (encode-coding-string str 'iso-latin-1))))))
 194
 195          ((eq type 'COMPOUND_TEXT)
 196           (setq str (encode-coding-string str coding)))
 197
 198          ((eq type 'STRING)
 199           (if (memq coding '(compound-text
 200                              compound-text-with-extensions))
 201               (setq str (string-make-unibyte str))
 202             (setq str (encode-coding-string str coding))))
 203
 204          ((eq type 'UTF8_STRING)
 205           (setq str (encode-coding-string str 'utf-8)))
 206
 207          (t
 208           (error "Unknow selection type: %S" type))
 209          ))
 210
 211       (setq next-selection-coding-system nil)
 212       (cons type str))))
 213
 214
 215 (defun xselect-convert-to-length (selection type value)
 216   (let ((value
 217          (cond ((stringp value)
 218                 (length value))
 219                ((overlayp value)
 220                 (abs (- (overlay-end value) (overlay-start value))))
 221                ((and (consp value)
 222                      (markerp (car value))
 223                      (markerp (cdr value)))
 224                 (or (eq (marker-buffer (car value))
 225                         (marker-buffer (cdr value)))
 226                     (signal 'error
 227                             (list "markers must be in the same buffer"
 228                                   (car value) (cdr value))))
 229                 (abs (- (car value) (cdr value)))))))
 230     (if value ; force it to be in 32-bit format.
 231         (cons (ash value -16) (logand value 65535))
 232       nil)))
 233
 234 (defun xselect-convert-to-targets (selection type value)
 235   ;; return a vector of atoms, but remove duplicates first.
 236   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 237          (rest all))
 238     (while rest
 239       (cond ((memq (car rest) (cdr rest))
 240              (setcdr rest (delq (car rest) (cdr rest))))
 241             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 242              (setcdr rest (cdr (cdr rest))))
 243             (t
 244              (setq rest (cdr rest)))))
 245     (apply 'vector all)))
 246
 247 (defun xselect-convert-to-delete (selection type value)
 248   (x-disown-selection-internal selection)
 249   ;; A return value of nil means that we do not know how to do this conversion,
 250   ;; and replies with an "error".  A return value of NULL means that we have
 251   ;; done the conversion (and any side-effects) but have no value to return.
 252   'NULL)
 253
 254 (defun xselect-convert-to-filename (selection type value)
 255   (cond ((overlayp value)
 256          (buffer-file-name (or (overlay-buffer value)
 257                                (error "selection is in a killed buffer"))))
 258         ((and (consp value)
 259               (markerp (car value))
 260               (markerp (cdr value)))
 261          (buffer-file-name (or (marker-buffer (car value))
 262                                (error "selection is in a killed buffer"))))
 263         (t nil)))
 264
 265 (defun xselect-convert-to-charpos (selection type value)
 266   (let (a b tmp)
 267     (cond ((cond ((overlayp value)
 268                   (setq a (overlay-start value)
 269                         b (overlay-end value)))
 270                  ((and (consp value)
 271                        (markerp (car value))
 272                        (markerp (cdr value)))
 273                   (setq a (car value)
 274                         b (cdr value))))
 275            (setq a (1- a) b (1- b)) ; zero-based
 276            (if (< b a) (setq tmp a a b b tmp))
 277            (cons 'SPAN
 278                  (vector (cons (ash a -16) (logand a 65535))
 279                          (cons (ash b -16) (logand b 65535))))))))
 280
 281 (defun xselect-convert-to-lineno (selection type value)
 282   (let (a b buf tmp)
 283     (cond ((cond ((and (consp value)
 284                        (markerp (car value))
 285                        (markerp (cdr value)))
 286                   (setq a (marker-position (car value))
 287                         b (marker-position (cdr value))
 288                         buf (marker-buffer (car value))))
 289                  ((overlayp value)
 290                   (setq buf (overlay-buffer value)
 291                         a (overlay-start value)
 292                         b (overlay-end value)))
 293                  )
 294            (save-excursion
 295              (set-buffer buf)
 296              (setq a (count-lines 1 a)
 297                    b (count-lines 1 b)))
 298            (if (< b a) (setq tmp a a b b tmp))
 299            (cons 'SPAN
 300                  (vector (cons (ash a -16) (logand a 65535))
 301                          (cons (ash b -16) (logand b 65535))))))))
 302
 303 (defun xselect-convert-to-colno (selection type value)
 304   (let (a b buf tmp)
 305     (cond ((cond ((and (consp value)
 306                        (markerp (car value))
 307                        (markerp (cdr value)))
 308                   (setq a (car value)
 309                         b (cdr value)
 310                         buf (marker-buffer a)))
 311                  ((overlayp value)
 312                   (setq buf (overlay-buffer value)
 313                         a (overlay-start value)
 314                         b (overlay-end value)))
 315                  )
 316            (save-excursion
 317              (set-buffer buf)
 318              (goto-char a)
 319              (setq a (current-column))
 320              (goto-char b)
 321              (setq b (current-column)))
 322            (if (< b a) (setq tmp a a b b tmp))
 323            (cons 'SPAN
 324                  (vector (cons (ash a -16) (logand a 65535))
 325                          (cons (ash b -16) (logand b 65535))))))))
 326
 327 (defun xselect-convert-to-os (selection type size)
 328   (symbol-name system-type))
 329
 330 (defun xselect-convert-to-host (selection type size)
 331   (system-name))
 332
 333 (defun xselect-convert-to-user (selection type size)
 334   (user-full-name))
 335
 336 (defun xselect-convert-to-class (selection type size)
 337   "Convert selection to class.
 338 This function returns the string \"Emacs\"."
 339   "Emacs")
 340
 341 ;; We do not try to determine the name Emacs was invoked with,
 342 ;; because it is not clean for a program's behavior to depend on that.
 343 (defun xselect-convert-to-name (selection type size)
 344   "Convert selection to name.
 345 This function returns the string \"emacs\"."
 346   "emacs")
 347
 348 (defun xselect-convert-to-integer (selection type value)
 349   (and (integerp value)
 350        (cons (ash value -16) (logand value 65535))))
 351
 352 (defun xselect-convert-to-atom (selection type value)
 353   (and (symbolp value) value))
 354
 355 (defun xselect-convert-to-identity (selection type value) ; used internally
 356   (vector value))
 357
 358 (setq selection-converter-alist
 359       '((TEXT . xselect-convert-to-string)
 360         (COMPOUND_TEXT . xselect-convert-to-string)
 361         (STRING . xselect-convert-to-string)
 362         (UTF8_STRING . xselect-convert-to-string)
 363         (TARGETS . xselect-convert-to-targets)
 364         (LENGTH . xselect-convert-to-length)
 365         (DELETE . xselect-convert-to-delete)
 366         (FILE_NAME . xselect-convert-to-filename)
 367         (CHARACTER_POSITION . xselect-convert-to-charpos)
 368         (LINE_NUMBER . xselect-convert-to-lineno)
 369         (COLUMN_NUMBER . xselect-convert-to-colno)
 370         (OWNER_OS . xselect-convert-to-os)
 371         (HOST_NAME . xselect-convert-to-host)
 372         (USER . xselect-convert-to-user)
 373         (CLASS . xselect-convert-to-class)
 374         (NAME . xselect-convert-to-name)
 375         (ATOM . xselect-convert-to-atom)
 376         (INTEGER . xselect-convert-to-integer)
 377         (_EMACS_INTERNAL . xselect-convert-to-identity)
 378         ))
 379
 380 (provide 'select)
 381
 382 ;;; select.el ends here