msdos/sed1v2.inp

   1 # -sed1v2.inp-----------------------------------------------------------
   2 # Configuration script for src/Makefile under DJGPP v2.x
   3 # ----------------------------------------------------------------------
   4 #
   5 # Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   6 #   2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   7 #
   8 # This file is part of GNU Emacs.
   9 #
  10 # This file is free software; as a special exception, the author gives
  11 # unlimited permission to copy and/or distribute it, with or without
  12 # modifications, as long as this notice is preserved.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  17 #
  18 # ----------------------------------------------------------------------
  19 s/^#.*//
  20 s/^[ \f\t][ \f\t]*$//
  21 s/^ /   /
  22 s/\.h\.in/.h-in/
  23 /^      LC_ALL=C \$(RUN_TEMACS)/i\
  24         stubedit temacs.exe minstack=1024k
  25 /^      LC_ALL=C.*\$(RUN_TEMACS)/s/LC_ALL=C/set &;/
  26 /-batch -l loadup/a\
  27         stubify emacs\
  28         stubedit emacs.exe minstack=2048k
  29 /^MAKE *=/s/^/# /
  30 /^SHELL *=/s/^/# /
  31 /^srcdir *=/s/@[^@\n]*@/./
  32 /^abs_builddir *=/s|@abs_builddir@|../src|
  33 /^VPATH *=/s/@[^@\n]*@/./
  34 /^CC *=/s/@[^@\n]*@/gcc/
  35 /^CPP *=/s/@[^@\n]*@/gcc -e/
  36 /^CFLAGS *=/s/@[^@\n]*@/-O2 -gcoff/
  37 /^ALL_CFLAGS *=/s/@[^@\n]*@//g
  38 /^CPPFLAGS *=/s/@[^@\n]*@//
  39 /^LDFLAGS *=/s/@[^@\n]*@//
  40 /^LIBS *=/s/@[^@\n]*@//
  41 /^LIBES *=/,/^ *$/ {
  42   s/@[^@\n]*@//g
  43 }
  44 /^LIBOBJS *=/s/@[^@\n]*@/getloadavg.o/
  45 /^GETLOADAVG_LIBS *=/s/@[^@\n]*@//
  46 /^LIBSOUND *=/s/@LIBSOUND@//
  47 /^CFLAGS_SOUND *=/s/@CFLAGS_SOUND@//
  48 /^RSVG_LIBS *=/s/@RSVG_LIBS@//
  49 /^RSVG_CFLAGS *=/s/@RSVG_CFLAGS@//
  50 /^OTHER_FILES *=/s/@OTHER_FILES@//
  51 /^EXEEXT *=/s/@EXEEXT@/.exe/
  52 /^version *=/s/@[^@\n]*@//
  53 /^LN_S *=/s/@[^@\n]*@/ln -s/
  54 /^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
  55 /^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
  56 /^@SET_MAKE@$/s/@SET_MAKE@//
  57 /^.\${libsrc}make-docfile.*>/s!make-docfile!make-docfile -o ../etc/DOC!
  58 /^.\${libsrc}make-doc/s!>.*$!!
  59 /^[\f    ]*$/d
  60 /^temacs:/s/prefix-args//
  61 /^temacs:/s/stamp-oldxmenu//
  62 /^RUN_TEMACS *=/s|`/bin/pwd`|.|
  63 /^      mv \.\/\.gdbinit/d
  64 /^      if test -f/c\
  65         command.com /c if exist .gdbinit rm -f _gdbinit
  66 /^      else mv \.\/\.gdbinit/d
  67 /^      #/d
  68 /^      cd.*make-docfile/s!$!; cd ${dot}${dot}/src!
  69 /^      @: /d
  70 /^      -\{0,1\}ln -/s/ln -f/cp -pf/
  71 /^[     ]touch /s/touch/djecho $@ >/
  72 s/bootstrap-emacs/b-emacs/
  73 s/bootstrap-temacs/b-temacs/
  74 s/bootstrap-doc/b-doc/
  75 /rm -f bootstrap-emacs/s/b-emacs/b-emacs b-emacs.exe/
  76 s/echo.*buildobj.lst/dj&/
  77 / --load loadup bootstrap/i\
  78         stubedit temacs.exe minstack=1024k
  79 / --load loadup bootstrap/a\
  80         stubify emacs
  81 /^      mv -f emacs/a\
  82         stubedit b-emacs.exe minstack=3072k\
  83         djecho bootlisp > bootlisp
  84 /^      -\{0,1\}rm -f/s/\\#/#/
  85 /^      @\{0,1\}cd ..\/lisp; /s|$|\; cd ../src|
  86 /^      echo.* buildobj.h/s|echo |djecho |
  87
  88 # arch-tag: c7e3aacb-4162-460e-99f9-4252bca68d2c