lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl)
  31   (require 'comint)
  32   (require 'gud)
  33   (require 'gdb-ui))
  34
  35 \f
  36 ;;; Customizable settings
  37
  38 (defgroup tooltip nil
  39   "Customization group for the `tooltip' package."
  40   :group 'help
  41   :group 'gud
  42   :group 'mouse
  43   :group 'tools
  44   :version "21.1"
  45   :tag "Tool Tips")
  46
  47 (defvar tooltip-mode)
  48
  49 (defcustom tooltip-delay 0.7
  50   "Seconds to wait before displaying a tooltip the first time."
  51   :tag "Delay"
  52   :type 'number
  53   :group 'tooltip)
  54
  55 (defcustom tooltip-short-delay 0.1
  56   "Seconds to wait between subsequent tooltips on different items."
  57   :tag "Short delay"
  58   :type 'number
  59   :group 'tooltip)
  60
  61 (defcustom tooltip-recent-seconds 1
  62   "Display tooltips if changing tip items within this many seconds.
  63 Do so after `tooltip-short-delay'."
  64   :tag "Recent seconds"
  65   :type 'number
  66   :group 'tooltip)
  67
  68 (defcustom tooltip-hide-delay 10
  69   "Hide tooltips automatically after this many seconds."
  70   :tag "Hide delay"
  71   :type 'number
  72   :group 'tooltip)
  73
  74 (defcustom tooltip-x-offset nil
  75   "X offset, in pixels, for the display of tooltips.
  76 The offset is relative to the position of the mouse.  It must
  77 be chosen so that the tooltip window doesn't contain the mouse
  78 when it pops up.  If the value is nil, the default offset is 5
  79 pixels.
  80
  81 If `tooltip-frame-parameters' includes the `left' parameter,
  82 the value of `tooltip-x-offset' is ignored."
  83   :tag "X offset"
  84   :type '(choice (const :tag "Default" nil)
  85                  (integer :tag "Offset" :value 1))
  86   :group 'tooltip)
  87
  88 (defcustom tooltip-y-offset nil
  89   "Y offset, in pixels, for the display of tooltips.
  90 The offset is relative to the position of the mouse.  It must
  91 be chosen so that the tooltip window doesn't contain the mouse
  92 when it pops up.  If the value is nil, the default offset is -10
  93 pixels.
  94
  95 If `tooltip-frame-parameters' includes the `top' parameter,
  96 the value of `tooltip-y-offset' is ignored."
  97   :tag "Y offset"
  98   :type '(choice (const :tag "Default" nil)
  99                  (integer :tag "Offset" :value 1))
 100   :group 'tooltip)
 101
 102 (defcustom tooltip-frame-parameters
 103   '((name . "tooltip")
 104     (internal-border-width . 5)
 105     (border-width . 1))
 106   "Frame parameters used for tooltips.
 107
 108 If `left' or `top' parameters are included, they specify the absolute
 109 position to pop up the tooltip."
 110   :type 'sexp
 111   :tag "Frame Parameters"
 112   :group 'tooltip)
 113
 114 (defface tooltip
 115   '((((class color))
 116      (:background "lightyellow" :foreground "black"))
 117     (t ()))
 118   "Face for tooltips."
 119   :group 'tooltip)
 120
 121 (defcustom tooltip-gud-tips-p nil
 122   "*Non-nil means show tooltips in GUD sessions."
 123   :type 'boolean
 124   :tag "GUD"
 125   :set #'(lambda (symbol on)
 126            (setq tooltip-gud-tips-p on))
 127   :group 'tooltip)
 128
 129 (defcustom tooltip-gud-modes '(gud-mode c-mode c++-mode)
 130   "List of modes for which to enable GUD tips."
 131   :type 'sexp
 132   :tag "GUD modes"
 133   :group 'tooltip)
 134
 135 (defcustom tooltip-gud-display
 136   '((eq (tooltip-event-buffer tooltip-gud-event)
 137         (marker-buffer overlay-arrow-position)))
 138   "List of forms determining where GUD tooltips are displayed.
 139
 140 Forms in the list are combined with AND.  The default is to display
 141 only tooltips in the buffer containing the overlay arrow."
 142   :type 'sexp
 143   :tag "GUD buffers predicate"
 144   :group 'tooltip)
 145
 146 (defcustom tooltip-use-echo-area nil
 147   "Use the echo area instead of tooltip frames.
 148 This is only relevant GUD display, since otherwise it is equivalent to
 149 turning off Tooltip mode."
 150   :type 'boolean
 151   :tag "Use echo area"
 152   :group 'tooltip)
 153
 154 \f
 155 ;;; Variables that are not customizable.
 156
 157 (defvar tooltip-hook nil
 158   "Functions to call to display tooltips.
 159 Each function is called with one argument EVENT which is a copy of
 160 the last mouse movement event that occurred.")
 161
 162 (defvar tooltip-timeout-id nil
 163   "The id of the timeout started when Emacs becomes idle.")
 164
 165 (defvar tooltip-last-mouse-motion-event nil
 166   "A copy of the last mouse motion event seen.")
 167
 168 (defvar tooltip-hide-time nil
 169   "Time when the last tooltip was hidden.")
 170
 171 \f
 172 ;;; Event accessors
 173
 174 (defun tooltip-event-buffer (event)
 175   "Return the buffer over which event EVENT occurred.
 176 This might return nil if the event did not occur over a buffer."
 177   (let ((window (posn-window (event-end event))))
 178     (and window (window-buffer window))))
 179
 180 \f
 181 ;;; Switching tooltips on/off
 182
 183 ;; We don't set track-mouse globally because this is a big redisplay
 184 ;; problem in buffers having a pre-command-hook or such installed,
 185 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 186 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 187 ;; would be accompanied by a full redisplay.
 188
 189 ;;;###autoload
 190 (defun tooltip-mode (&optional arg)
 191   "Mode for tooltip display.
 192 With ARG, turn tooltip mode on if and only if ARG is positive."
 193   (interactive "P")
 194   (unless (fboundp 'x-show-tip)
 195     (error "Sorry, tooltips are not yet available on this system"))
 196   (let* ((on (if arg
 197                  (> (prefix-numeric-value arg) 0)
 198                (not tooltip-mode)))
 199          (hook-fn (if on 'add-hook 'remove-hook)))
 200     (setq tooltip-mode on)
 201     (funcall hook-fn 'change-major-mode-hook 'tooltip-change-major-mode)
 202     (tooltip-activate-mouse-motions-if-enabled)
 203     (funcall hook-fn 'pre-command-hook 'tooltip-hide)
 204     (funcall hook-fn 'tooltip-hook 'tooltip-gud-tips)
 205     (funcall hook-fn 'tooltip-hook 'tooltip-help-tips)
 206     (setq show-help-function (if on 'tooltip-show-help-function nil))
 207     ;; `ignore' is the default binding for mouse movements.
 208     (define-key global-map [mouse-movement]
 209       (if on 'tooltip-mouse-motion 'ignore))))
 210
 211 \f
 212 ;;; Timeout for tooltip display
 213
 214 (defun tooltip-delay ()
 215   "Return the delay in seconds for the next tooltip."
 216   (let ((delay tooltip-delay)
 217         (now (float-time)))
 218     (when (and tooltip-hide-time
 219                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 220       (setq delay tooltip-short-delay))
 221     delay))
 222
 223 (defun tooltip-cancel-delayed-tip ()
 224   "Disable the tooltip timeout."
 225   (when tooltip-timeout-id
 226     (disable-timeout tooltip-timeout-id)
 227     (setq tooltip-timeout-id nil)))
 228
 229 (defun tooltip-start-delayed-tip ()
 230   "Add a one-shot timeout to call function tooltip-timeout."
 231   (setq tooltip-timeout-id
 232         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 233
 234 (defun tooltip-timeout (object)
 235   "Function called when timer with id tooltip-timeout-id fires."
 236   (run-hook-with-args-until-success 'tooltip-hook
 237                                     tooltip-last-mouse-motion-event))
 238
 239 \f
 240 ;;; Reacting on mouse movements
 241
 242 (defun tooltip-change-major-mode ()
 243   "Function added to `change-major-mode-hook' when tooltip mode is on."
 244   (add-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled))
 245
 246 (defun tooltip-activate-mouse-motions-if-enabled ()
 247   "Reconsider for all buffers whether mouse motion events are desired."
 248   (remove-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled)
 249   (let ((buffers (buffer-list)))
 250     (save-excursion
 251       (while buffers
 252         (set-buffer (car buffers))
 253         (if (and tooltip-mode
 254                  tooltip-gud-tips-p
 255                  (memq major-mode tooltip-gud-modes))
 256             (tooltip-activate-mouse-motions t)
 257           (tooltip-activate-mouse-motions nil))
 258         (setq buffers (cdr buffers))))))
 259
 260 (defvar tooltip-mouse-motions-active nil
 261   "Locally t in a buffer if tooltip processing of mouse motion is enabled.")
 262
 263 (defun tooltip-activate-mouse-motions (activatep)
 264   "Activate/deactivate mouse motion events for the current buffer.
 265 ACTIVATEP non-nil means activate mouse motion events."
 266   (if activatep
 267       (progn
 268         (make-local-variable 'tooltip-mouse-motions-active)
 269         (setq tooltip-mouse-motions-active t)
 270         (make-local-variable 'track-mouse)
 271         (setq track-mouse t))
 272     (when tooltip-mouse-motions-active
 273       (kill-local-variable 'tooltip-mouse-motions-active)
 274       (kill-local-variable 'track-mouse))))
 275
 276 (defun tooltip-mouse-motion (event)
 277   "Command handler for mouse movement events in `global-map'."
 278   (interactive "e")
 279   (tooltip-hide)
 280   (when (car (mouse-pixel-position))
 281     (setq tooltip-last-mouse-motion-event (copy-sequence event))
 282     (tooltip-start-delayed-tip)))
 283
 284 \f
 285 ;;; Displaying tips
 286
 287 (defun tooltip-set-param (alist key value)
 288   "Change the value of KEY in alist ALIST to VALUE.
 289 If there's no association for KEY in ALIST, add one, otherwise
 290 change the existing association.  Value is the resulting alist."
 291   (let ((param (assq key alist)))
 292     (if (consp param)
 293         (setcdr param value)
 294       (push (cons key value) alist))
 295     alist))
 296
 297 (defun tooltip-show (text)
 298   "Show a tooltip window displaying TEXT.
 299
 300 Text larger than `x-max-tooltip-size' (which see) is clipped.
 301
 302 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 303 parameters, they determine the x and y position where the tooltip
 304 is displayed.  Otherwise, the tooltip pops at offsets specified by
 305 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 306 position."
 307   (if tooltip-use-echo-area
 308       (message "%s" text)
 309     (condition-case error
 310         (let ((params (copy-sequence tooltip-frame-parameters))
 311               (fg (face-attribute 'tooltip :foreground))
 312               (bg (face-attribute 'tooltip :background)))
 313           (when (stringp fg)
 314             (setq params (tooltip-set-param params 'foreground-color fg))
 315             (setq params (tooltip-set-param params 'border-color fg)))
 316           (when (stringp bg)
 317             (setq params (tooltip-set-param params 'background-color bg)))
 318           (x-show-tip (propertize text 'face 'tooltip)
 319                       (selected-frame)
 320                       params
 321                       tooltip-hide-delay
 322                       tooltip-x-offset
 323                       tooltip-y-offset))
 324       (error
 325        (message "Error while displaying tooltip: %s" error)
 326        (sit-for 1)
 327        (message "%s" text)))))
 328
 329 (defun tooltip-hide (&optional ignored-arg)
 330   "Hide a tooltip, if one is displayed.
 331 Value is non-nil if tooltip was open."
 332   (tooltip-cancel-delayed-tip)
 333   (when (x-hide-tip)
 334     (setq tooltip-hide-time (float-time))))
 335
 336 \f
 337 ;;; Debugger-related functions
 338
 339 (defun tooltip-identifier-from-point (point)
 340   "Extract the identifier at POINT, if any.
 341 Value is nil if no identifier exists at point.  Identifier extraction
 342 is based on the current syntax table."
 343   (save-excursion
 344     (goto-char point)
 345     (let ((start (progn (skip-syntax-backward "w_") (point))))
 346       (unless (looking-at "[0-9]")
 347         (skip-syntax-forward "w_")
 348         (when (> (point) start)
 349           (buffer-substring start (point)))))))
 350
 351 (defmacro tooltip-region-active-p ()
 352   "Value is non-nil if the region is currently active."
 353   (if (string-match "^GNU" (emacs-version))
 354       `(and transient-mark-mode mark-active)
 355     `(region-active-p)))
 356
 357 (defun tooltip-expr-to-print (event)
 358   "Return an expression that should be printed for EVENT.
 359 If a region is active and the mouse is inside the region, print
 360 the region.  Otherwise, figure out the identifier around the point
 361 where the mouse is."
 362   (save-excursion
 363     (set-buffer (tooltip-event-buffer event))
 364     (let ((point (posn-point (event-end event))))
 365       (if (tooltip-region-active-p)
 366           (when (and (<= (region-beginning) point) (<= point (region-end)))
 367             (buffer-substring (region-beginning) (region-end)))
 368         (tooltip-identifier-from-point point)))))
 369
 370 (defun tooltip-process-prompt-regexp (process)
 371   "Return regexp matching the prompt of PROCESS at the end of a string.
 372 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 373 of PROCESS."
 374   (let ((prompt-regexp (save-excursion
 375                          (set-buffer (process-buffer process))
 376                          comint-prompt-regexp)))
 377     ;; Most start with `^' but the one for `sdb' cannot be easily
 378     ;; stripped.  Code the prompt for `sdb' fixed here.
 379     (if (= (aref prompt-regexp 0) ?^)
 380         (setq prompt-regexp (substring prompt-regexp 1))
 381       (setq prompt-regexp "\\*"))
 382     (concat "\n*" prompt-regexp "$")))
 383
 384 (defun tooltip-strip-prompt (process output)
 385   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 386   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 387     (save-match-data
 388       (when (string-match prompt-regexp output)
 389         (setq output (substring output 0 (match-beginning 0)))))
 390     output))
 391
 392 \f
 393 ;;; Tips for `gud'
 394
 395 (defvar tooltip-gud-original-filter nil
 396   "Process filter to restore after GUD output has been received.")
 397
 398 (defvar tooltip-gud-dereference nil
 399   "Non-nil means print expressions with a `*' in front of them.
 400 For C this would dereference a pointer expression.")
 401
 402 (defvar tooltip-gud-event nil
 403   "The mouse movement event that led to a tooltip display.
 404 This event can be examined by forms in TOOLTIP-GUD-DISPLAY.")
 405
 406 (defun tooltip-gud-toggle-dereference ()
 407   "Toggle whether tooltips should show `* expr' or `expr'."
 408   (interactive)
 409   (setq tooltip-gud-dereference (not tooltip-gud-dereference))
 410   (when (interactive-p)
 411     (message "Dereferencing is now %s."
 412              (if tooltip-gud-dereference "on" "off"))))
 413
 414 ; This will only display data that comes in one chunk.
 415 ; Larger arrays (say 400 elements) are displayed in
 416 ; the tootip incompletely and spill over into the gud buffer.
 417 ; Switching the process-filter creates timing problems and
 418 ; it may be difficult to do better. gdba in gdb-ui.el
 419 ; gets round this problem.
 420 (defun tooltip-gud-process-output (process output)
 421   "Process debugger output and show it in a tooltip window."
 422   (set-process-filter process tooltip-gud-original-filter)
 423   (tooltip-show (tooltip-strip-prompt process output)))
 424
 425 (defun tooltip-gud-print-command (expr)
 426   "Return a suitable command to print the expression EXPR.
 427 If TOOLTIP-GUD-DEREFERENCE is t, also prepend a `*' to EXPR."
 428   (when tooltip-gud-dereference
 429     (setq expr (concat "*" expr)))
 430   (case gud-minor-mode
 431     ((gdb gdba) (concat "server print " expr))
 432     (dbx (concat "print " expr))
 433     (xdb (concat "p " expr))
 434     (sdb (concat expr "/"))
 435     (perldb expr)))
 436
 437 (defun tooltip-gud-tips (event)
 438   "Show tip for identifier or selection under the mouse.
 439 The mouse must either point at an identifier or inside a selected
 440 region for the tip window to be shown.  If tooltip-gud-dereference is t,
 441 add a `*' in front of the printed expression.
 442
 443 This function must return nil if it doesn't handle EVENT."
 444   (let (gud-buffer process)
 445     (when (and (eventp event)
 446                tooltip-gud-tips-p
 447                (boundp 'gud-comint-buffer)
 448                (setq gud-buffer gud-comint-buffer)
 449                (setq process (get-buffer-process gud-buffer))
 450                (posn-point (event-end event))
 451                (progn (setq tooltip-gud-event event)
 452                       (eval (cons 'and tooltip-gud-display))))
 453       (let ((expr (tooltip-expr-to-print event)))
 454         (when expr
 455           (let ((cmd (tooltip-gud-print-command expr)))
 456             (unless (null cmd)         ; CMD can be nil if unknown debugger
 457               (case gud-minor-mode
 458                     (gdba (gdb-enqueue-input
 459                            (list  (concat cmd "\n") 'gdb-tooltip-print)))
 460                     (t
 461                      (setq tooltip-gud-original-filter (process-filter process))
 462                        (set-process-filter process 'tooltip-gud-process-output)
 463                        (gud-basic-call cmd)))
 464                     expr)))))))
 465
 466 (defun gdb-tooltip-print ()
 467   (tooltip-show
 468    (with-current-buffer (gdb-get-buffer 'gdb-partial-output-buffer)
 469      (buffer-string))))
 470
 471 \f
 472 ;;; Tooltip help.
 473
 474 (defvar tooltip-help-message nil
 475   "The last help message received via `tooltip-show-help-function'.")
 476
 477 (defun tooltip-show-help-function (msg)
 478   "Function installed as `show-help-function'.
 479 MSG is either a help string to display, or nil to cancel the display."
 480   (let ((previous-help tooltip-help-message))
 481     (setq tooltip-help-message msg)
 482     (cond ((null msg)
 483            ;; Cancel display.  This also cancels a delayed tip, if
 484            ;; there is one.
 485            (tooltip-hide))
 486           ((equal previous-help msg)
 487            ;; Same help as before (but possibly the mouse has moved).
 488            ;; Keep what we have.
 489            )
 490           (t
 491            ;; A different help.  Remove a previous tooltip, and
 492            ;; display a new one, with some delay.
 493            (tooltip-hide)
 494            (tooltip-start-delayed-tip)))))
 495
 496 (defun tooltip-help-tips (event)
 497   "Hook function to display a help tooltip.
 498 This is installed on the hook `tooltip-hook', which is run when
 499 the timer with ID `tooltip-timeout-id' fires.
 500 Value is non-nil if this function handled the tip."
 501   (when (stringp tooltip-help-message)
 502     (tooltip-show tooltip-help-message)
 503     t))
 504
 505 \f
 506 ;;; Do this after all functions have been defined that are called from
 507 ;;; `tooltip-mode'.  The actual default value of `tooltip-mode' is set
 508 ;;; in startup.el.
 509
 510 ;;;###autoload
 511 (defcustom tooltip-mode nil
 512   "Toggle tooltip-mode.
 513 Setting this variable directly does not take effect;
 514 use either \\[customize] or the function `tooltip-mode'."
 515   :set (lambda (symbol value)
 516          (tooltip-mode (or value 0)))
 517   :initialize 'custom-initialize-default
 518   :type 'boolean
 519   :require 'tooltip
 520   :group 'tooltip)
 521
 522 (provide 'tooltip)
 523
 524 ;;; tooltip.el ends here