lisp/timer.el

   1 ;;; timer.el --- run a function with args at some time in future
   2
   3 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package gives you the capability to run Emacs Lisp commands at
  27 ;; specified times in the future, either as one-shots or periodically.
  28
  29 ;;; Code:
  30
  31 ;; Layout of a timer vector:
  32 ;; [triggered-p high-seconds low-seconds usecs repeat-delay
  33 ;;  function args idle-delay]
  34
  35 (defun timer-create ()
  36   "Create a timer object."
  37   (let ((timer (make-vector 8 nil)))
  38     (aset timer 0 t)
  39     timer))
  40
  41 (defun timerp (object)
  42   "Return t if OBJECT is a timer."
  43   (and (vectorp object) (= (length object) 8)))
  44
  45 (defun timer-set-time (timer time &optional delta)
  46   "Set the trigger time of TIMER to TIME.
  47 TIME must be in the internal format returned by, e.g., `current-time'.
  48 If optional third argument DELTA is a positive number, make the timer
  49 fire repeatedly that many seconds apart."
  50   (or (timerp timer)
  51       (error "Invalid timer"))
  52   (aset timer 1 (car time))
  53   (aset timer 2 (if (consp (cdr time)) (car (cdr time)) (cdr time)))
  54   (aset timer 3 (or (and (consp (cdr time)) (consp (cdr (cdr time)))
  55                          (nth 2 time))
  56                     0))
  57   (aset timer 4 (and (numberp delta) (> delta 0) delta))
  58   timer)
  59
  60 (defun timer-set-idle-time (timer secs &optional repeat)
  61   "Set the trigger idle time of TIMER to SECS.
  62 If optional third argument REPEAT is non-nil, make the timer
  63 fire each time Emacs is idle for that many seconds."
  64   (or (timerp timer)
  65       (error "Invalid timer"))
  66   (aset timer 1 0)
  67   (aset timer 2 0)
  68   (aset timer 3 0)
  69   (timer-inc-time timer secs)
  70   (aset timer 4 repeat)
  71   timer)
  72
  73 (defun timer-next-integral-multiple-of-time (time secs)
  74   "Yield the next value after TIME that is an integral multiple of SECS.
  75 More precisely, the next value, after TIME, that is an integral multiple
  76 of SECS seconds since the epoch.  SECS may be a fraction."
  77   (let ((time-base (ash 1 16)))
  78     (if (fboundp 'atan)
  79         ;; Use floating point, taking care to not lose precision.
  80         (let* ((float-time-base (float time-base))
  81                (million 1000000.0)
  82                (time-usec (+ (* million
  83                                 (+ (* float-time-base (nth 0 time))
  84                                    (nth 1 time)))
  85                              (nth 2 time)))
  86                (secs-usec (* million secs))
  87                (mod-usec (mod time-usec secs-usec))
  88                (next-usec (+ (- time-usec mod-usec) secs-usec))
  89                (time-base-million (* float-time-base million)))
  90           (list (floor next-usec time-base-million)
  91                 (floor (mod next-usec time-base-million) million)
  92                 (floor (mod next-usec million))))
  93       ;; Floating point is not supported.
  94       ;; Use integer arithmetic, avoiding overflow if possible.
  95       (let* ((mod-sec (mod (+ (* (mod time-base secs)
  96                                  (mod (nth 0 time) secs))
  97                               (nth 1 time))
  98                            secs))
  99              (next-1-sec (+ (- (nth 1 time) mod-sec) secs)))
 100         (list (+ (nth 0 time) (floor next-1-sec time-base))
 101               (mod next-1-sec time-base)
 102               0)))))
 103
 104 (defun timer-relative-time (time secs &optional usecs)
 105   "Advance TIME by SECS seconds and optionally USECS microseconds.
 106 SECS may be a fraction."
 107   (let ((high (car time))
 108         (low (if (consp (cdr time)) (nth 1 time) (cdr time)))
 109         (micro (if (numberp (car-safe (cdr-safe (cdr time))))
 110                    (nth 2 time)
 111                  0)))
 112     ;; Add
 113     (if usecs (setq micro (+ micro usecs)))
 114     (if (floatp secs)
 115         (setq micro (+ micro (floor (* 1000000 (- secs (floor secs)))))))
 116     (setq low (+ low (floor secs)))
 117
 118     ;; Normalize
 119     ;; `/' rounds towards zero while `mod' returns a positive number,
 120     ;; so we can't rely on (= a (+ (* 100 (/ a 100)) (mod a 100))).
 121     (setq low (+ low (/ micro 1000000) (if (< micro 0) -1 0)))
 122     (setq micro (mod micro 1000000))
 123     (setq high (+ high (/ low 65536) (if (< low 0) -1 0)))
 124     (setq low (logand low 65535))
 125
 126     (list high low (and (/= micro 0) micro))))
 127
 128 (defun timer-inc-time (timer secs &optional usecs)
 129   "Increment the time set in TIMER by SECS seconds and USECS microseconds.
 130 SECS may be a fraction.  If USECS is omitted, that means it is zero."
 131   (let ((time (timer-relative-time
 132                (list (aref timer 1) (aref timer 2) (aref timer 3))
 133                secs
 134                usecs)))
 135     (aset timer 1 (nth 0 time))
 136     (aset timer 2 (nth 1 time))
 137     (aset timer 3 (or (nth 2 time) 0))))
 138
 139 (defun timer-set-time-with-usecs (timer time usecs &optional delta)
 140   "Set the trigger time of TIMER to TIME plus USECS.
 141 TIME must be in the internal format returned by, e.g., `current-time'.
 142 The microsecond count from TIME is ignored, and USECS is used instead.
 143 If optional fourth argument DELTA is a positive number, make the timer
 144 fire repeatedly that many seconds apart."
 145   (or (timerp timer)
 146       (error "Invalid timer"))
 147   (aset timer 1 (nth 0 time))
 148   (aset timer 2 (nth 1 time))
 149   (aset timer 3 usecs)
 150   (aset timer 4 (and (numberp delta) (> delta 0) delta))
 151   timer)
 152 (make-obsolete 'timer-set-time-with-usecs
 153                "use `timer-set-time' and `timer-inc-time' instead."
 154                "21.4")
 155
 156 (defun timer-set-function (timer function &optional args)
 157   "Make TIMER call FUNCTION with optional ARGS when triggering."
 158   (or (timerp timer)
 159       (error "Invalid timer"))
 160   (aset timer 5 function)
 161   (aset timer 6 args)
 162   timer)
 163 \f
 164 (defun timer-activate (timer)
 165   "Put TIMER on the list of active timers."
 166   (if (and (timerp timer)
 167            (integerp (aref timer 1))
 168            (integerp (aref timer 2))
 169            (integerp (aref timer 3))
 170            (aref timer 5))
 171       (let ((timers timer-list)
 172             last)
 173         ;; Skip all timers to trigger before the new one.
 174         (while (and timers
 175                     (or (> (aref timer 1) (aref (car timers) 1))
 176                         (and (= (aref timer 1) (aref (car timers) 1))
 177                              (> (aref timer 2) (aref (car timers) 2)))
 178                         (and (= (aref timer 1) (aref (car timers) 1))
 179                              (= (aref timer 2) (aref (car timers) 2))
 180                              (> (aref timer 3) (aref (car timers) 3)))))
 181           (setq last timers
 182                 timers (cdr timers)))
 183         ;; Insert new timer after last which possibly means in front of queue.
 184         (if last
 185             (setcdr last (cons timer timers))
 186           (setq timer-list (cons timer timers)))
 187         (aset timer 0 nil)
 188         (aset timer 7 nil)
 189         nil)
 190     (error "Invalid or uninitialized timer")))
 191
 192 (defun timer-activate-when-idle (timer &optional dont-wait)
 193   "Arrange to activate TIMER whenever Emacs is next idle.
 194 If optional argument DONT-WAIT is non-nil, then enable the
 195 timer to activate immediately, or at the right time, if Emacs
 196 is already idle."
 197   (if (and (timerp timer)
 198            (integerp (aref timer 1))
 199            (integerp (aref timer 2))
 200            (integerp (aref timer 3))
 201            (aref timer 5))
 202       (let ((timers timer-idle-list)
 203             last)
 204         ;; Skip all timers to trigger before the new one.
 205         (while (and timers
 206                     (or (> (aref timer 1) (aref (car timers) 1))
 207                         (and (= (aref timer 1) (aref (car timers) 1))
 208                              (> (aref timer 2) (aref (car timers) 2)))
 209                         (and (= (aref timer 1) (aref (car timers) 1))
 210                              (= (aref timer 2) (aref (car timers) 2))
 211                              (> (aref timer 3) (aref (car timers) 3)))))
 212           (setq last timers
 213                 timers (cdr timers)))
 214         ;; Insert new timer after last which possibly means in front of queue.
 215         (if last
 216             (setcdr last (cons timer timers))
 217           (setq timer-idle-list (cons timer timers)))
 218         (aset timer 0 (not dont-wait))
 219         (aset timer 7 t)
 220         nil)
 221     (error "Invalid or uninitialized timer")))
 222
 223 ;;;###autoload
 224 (defalias 'disable-timeout 'cancel-timer)
 225 ;;;###autoload
 226 (defun cancel-timer (timer)
 227   "Remove TIMER from the list of active timers."
 228   (or (timerp timer)
 229       (error "Invalid timer"))
 230   (setq timer-list (delq timer timer-list))
 231   (setq timer-idle-list (delq timer timer-idle-list))
 232   nil)
 233
 234 ;;;###autoload
 235 (defun cancel-function-timers (function)
 236   "Cancel all timers scheduled by `run-at-time' which would run FUNCTION."
 237   (interactive "aCancel timers of function: ")
 238   (let ((tail timer-list))
 239     (while tail
 240       (if (eq (aref (car tail) 5) function)
 241           (setq timer-list (delq (car tail) timer-list)))
 242       (setq tail (cdr tail))))
 243   (let ((tail timer-idle-list))
 244     (while tail
 245       (if (eq (aref (car tail) 5) function)
 246           (setq timer-idle-list (delq (car tail) timer-idle-list)))
 247       (setq tail (cdr tail)))))
 248 \f
 249 ;; Record the last few events, for debugging.
 250 (defvar timer-event-last-2 nil)
 251 (defvar timer-event-last-1 nil)
 252 (defvar timer-event-last nil)
 253
 254 (defvar timer-max-repeats 10
 255   "*Maximum number of times to repeat a timer, if real time jumps.")
 256
 257 (defun timer-until (timer time)
 258   "Calculate number of seconds from when TIMER will run, until TIME.
 259 TIMER is a timer, and stands for the time when its next repeat is scheduled.
 260 TIME is a time-list."
 261   (let ((high (- (car time) (aref timer 1)))
 262         (low (- (nth 1 time) (aref timer 2))))
 263     (+ low (* high 65536))))
 264
 265 (defun timer-event-handler (timer)
 266   "Call the handler for the timer TIMER.
 267 This function is called, by name, directly by the C code."
 268   (setq timer-event-last-2 timer-event-last-1)
 269   (setq timer-event-last-1 timer-event-last)
 270   (setq timer-event-last timer)
 271   (let ((inhibit-quit t))
 272     (if (timerp timer)
 273         (progn
 274           ;; Delete from queue.
 275           (cancel-timer timer)
 276           ;; Re-schedule if requested.
 277           (if (aref timer 4)
 278               (if (aref timer 7)
 279                   (timer-activate-when-idle timer)
 280                 (timer-inc-time timer (aref timer 4) 0)
 281                 ;; If real time has jumped forward,
 282                 ;; perhaps because Emacs was suspended for a long time,
 283                 ;; limit how many times things get repeated.
 284                 (if (and (numberp timer-max-repeats)
 285                          (< 0 (timer-until timer (current-time))))
 286                     (let ((repeats (/ (timer-until timer (current-time))
 287                                       (aref timer 4))))
 288                       (if (> repeats timer-max-repeats)
 289                           (timer-inc-time timer (* (aref timer 4) repeats)))))
 290                 (timer-activate timer)))
 291           ;; Run handler.
 292           ;; We do this after rescheduling so that the handler function
 293           ;; can cancel its own timer successfully with cancel-timer.
 294           (condition-case nil
 295               (apply (aref timer 5) (aref timer 6))
 296             (error nil)))
 297       (error "Bogus timer event"))))
 298
 299 ;; This function is incompatible with the one in levents.el.
 300 (defun timeout-event-p (event)
 301   "Non-nil if EVENT is a timeout event."
 302   (and (listp event) (eq (car event) 'timer-event)))
 303 \f
 304 ;;;###autoload
 305 (defun run-at-time (time repeat function &rest args)
 306   "Perform an action at time TIME.
 307 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 308 TIME should be a string like \"11:23pm\", nil meaning now, a number of seconds
 309 from now, a value from `current-time', or t (with non-nil REPEAT)
 310 meaning the next integral multiple of REPEAT.
 311 REPEAT may be an integer or floating point number.
 312 The action is to call FUNCTION with arguments ARGS.
 313
 314 This function returns a timer object which you can use in `cancel-timer'."
 315   (interactive "sRun at time: \nNRepeat interval: \naFunction: ")
 316
 317   (or (null repeat)
 318       (and (numberp repeat) (< 0 repeat))
 319       (error "Invalid repetition interval"))
 320
 321   ;; Special case: nil means "now" and is useful when repeating.
 322   (if (null time)
 323       (setq time (current-time)))
 324
 325   ;; Special case: t means the next integral multiple of REPEAT.
 326   (if (and (eq time t) repeat)
 327       (setq time (timer-next-integral-multiple-of-time (current-time) repeat)))
 328
 329   ;; Handle numbers as relative times in seconds.
 330   (if (numberp time)
 331       (setq time (timer-relative-time (current-time) time)))
 332
 333   ;; Handle relative times like "2 hours and 35 minutes"
 334   (if (stringp time)
 335       (let ((secs (timer-duration time)))
 336         (if secs
 337             (setq time (timer-relative-time (current-time) secs)))))
 338
 339   ;; Handle "11:23pm" and the like.  Interpret it as meaning today
 340   ;; which admittedly is rather stupid if we have passed that time
 341   ;; already.  (Though only Emacs hackers hack Emacs at that time.)
 342   (if (stringp time)
 343       (progn
 344         (require 'diary-lib)
 345         (let ((hhmm (diary-entry-time time))
 346               (now (decode-time)))
 347           (if (>= hhmm 0)
 348               (setq time
 349                     (encode-time 0 (% hhmm 100) (/ hhmm 100) (nth 3 now)
 350                                  (nth 4 now) (nth 5 now) (nth 8 now)))))))
 351
 352   (or (consp time)
 353       (error "Invalid time format"))
 354
 355   (let ((timer (timer-create)))
 356     (timer-set-time timer time repeat)
 357     (timer-set-function timer function args)
 358     (timer-activate timer)
 359     timer))
 360
 361 ;;;###autoload
 362 (defun run-with-timer (secs repeat function &rest args)
 363   "Perform an action after a delay of SECS seconds.
 364 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 365 SECS and REPEAT may be integers or floating point numbers.
 366 The action is to call FUNCTION with arguments ARGS.
 367
 368 This function returns a timer object which you can use in `cancel-timer'."
 369   (interactive "sRun after delay (seconds): \nNRepeat interval: \naFunction: ")
 370   (apply 'run-at-time secs repeat function args))
 371
 372 ;;;###autoload
 373 (defun add-timeout (secs function object &optional repeat)
 374   "Add a timer to run SECS seconds from now, to call FUNCTION on OBJECT.
 375 If REPEAT is non-nil, repeat the timer every REPEAT seconds.
 376 This function is for compatibility; see also `run-with-timer'."
 377   (run-with-timer secs repeat function object))
 378
 379 ;;;###autoload
 380 (defun run-with-idle-timer (secs repeat function &rest args)
 381   "Perform an action the next time Emacs is idle for SECS seconds.
 382 The action is to call FUNCTION with arguments ARGS.
 383 SECS may be an integer or a floating point number.
 384
 385 If REPEAT is non-nil, do the action each time Emacs has been idle for
 386 exactly SECS seconds (that is, only once for each time Emacs becomes idle).
 387
 388 This function returns a timer object which you can use in `cancel-timer'."
 389   (interactive
 390    (list (read-from-minibuffer "Run after idle (seconds): " nil nil t)
 391          (y-or-n-p "Repeat each time Emacs is idle? ")
 392          (intern (completing-read "Function: " obarray 'fboundp t))))
 393   (let ((timer (timer-create)))
 394     (timer-set-function timer function args)
 395     (timer-set-idle-time timer secs repeat)
 396     (timer-activate-when-idle timer)
 397     timer))
 398 \f
 399 (defun with-timeout-handler (tag)
 400   (throw tag 'timeout))
 401
 402 ;;;###autoload (put 'with-timeout 'lisp-indent-function 1)
 403
 404 ;;;###autoload
 405 (defmacro with-timeout (list &rest body)
 406   "Run BODY, but if it doesn't finish in SECONDS seconds, give up.
 407 If we give up, we run the TIMEOUT-FORMS and return the value of the last one.
 408 The call should look like:
 409  (with-timeout (SECONDS TIMEOUT-FORMS...) BODY...)
 410 The timeout is checked whenever Emacs waits for some kind of external
 411 event \(such as keyboard input, input from subprocesses, or a certain time);
 412 if the program loops without waiting in any way, the timeout will not
 413 be detected."
 414   (let ((seconds (car list))
 415         (timeout-forms (cdr list)))
 416     `(let ((with-timeout-tag (cons nil nil))
 417            with-timeout-value with-timeout-timer)
 418        (if (catch with-timeout-tag
 419              (progn
 420                (setq with-timeout-timer
 421                      (run-with-timer ,seconds nil
 422                                       'with-timeout-handler
 423                                       with-timeout-tag))
 424                (setq with-timeout-value (progn . ,body))
 425                nil))
 426            (progn . ,timeout-forms)
 427          (cancel-timer with-timeout-timer)
 428          with-timeout-value))))
 429
 430 (defun y-or-n-p-with-timeout (prompt seconds default-value)
 431   "Like (y-or-n-p PROMPT), with a timeout.
 432 If the user does not answer after SECONDS seconds, return DEFAULT-VALUE."
 433   (with-timeout (seconds default-value)
 434     (y-or-n-p prompt)))
 435 \f
 436 (defvar timer-duration-words
 437   (list (cons "microsec" 0.000001)
 438         (cons "microsecond" 0.000001)
 439         (cons "millisec" 0.001)
 440         (cons "millisecond" 0.001)
 441         (cons "sec" 1)
 442         (cons "second" 1)
 443         (cons "min" 60)
 444         (cons "minute" 60)
 445         (cons "hour" (* 60 60))
 446         (cons "day" (* 24 60 60))
 447         (cons "week" (* 7 24 60 60))
 448         (cons "fortnight" (* 14 24 60 60))
 449         (cons "month" (* 30 24 60 60))    ; Approximation
 450         (cons "year" (* 365.25 24 60 60)) ; Approximation
 451         )
 452   "Alist mapping temporal words to durations in seconds")
 453
 454 (defun timer-duration (string)
 455   "Return number of seconds specified by STRING, or nil if parsing fails."
 456   (let ((secs 0)
 457         (start 0)
 458         (case-fold-search t))
 459     (while (string-match
 460             "[ \t]*\\([0-9.]+\\)?[ \t]*\\([a-z]+[a-rt-z]\\)s?[ \t]*"
 461             string start)
 462       (let ((count (if (match-beginning 1)
 463                        (string-to-number (match-string 1 string))
 464                      1))
 465             (itemsize (cdr (assoc (match-string 2 string)
 466                                   timer-duration-words))))
 467         (if itemsize
 468             (setq start (match-end 0)
 469                   secs (+ secs (* count itemsize)))
 470           (setq secs nil
 471                 start (length string)))))
 472     (if (= start (length string))
 473         secs
 474       (if (string-match "\\`[0-9.]+\\'" string)
 475           (string-to-number string)))))
 476 \f
 477 (provide 'timer)
 478
 479 ;;; timer.el ends here