lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@diku.dk>
   6 ;; Keywords: archives msdog editing major-mode
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  29 ;; to files whose name end in ".arc"
  30 ;;
  31 ;; This code does not decode any files internally, although it does
  32 ;; understand the directory level of the archives.  For this reason,
  33 ;; you should expect this code to need more fiddling than tar-mode.el
  34 ;; (although it at present has fewer bugs :-)  In particular, I have
  35 ;; not tested this under Ms-Dog myself.
  36 ;; -------------------------------------
  37 ;; INTERACTION: arc-mode.el should play together with
  38 ;;
  39 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  40 ;;                to you) are handled by doing all updates on a local
  41 ;;                copy.  When you make changes to a remote file the
  42 ;;                changes will first take effect when the archive buffer
  43 ;;                is saved.  You will be warned about this.
  44 ;;
  45 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  46 ;;                conversion.
  47 ;;
  48 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  49 ;; such this could be fixed (but wouldn't be useful) by declaring such
  50 ;; archives to be "remote".  For the members this is a general Emacs
  51 ;; problem that 19.29's file formats may fix.
  52 ;; -------------------------------------
  53 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  54 ;; structure for handling just about anything is in place.
  55 ;;
  56 ;;                        Arc     Lzh     Zip     Zoo
  57 ;;                        --------------------------------
  58 ;; View listing           Intern  Intern  Intern  Intern
  59 ;; Extract member         Y       Y       Y       Y
  60 ;; Save changed member    Y       Y       Y       Y
  61 ;; Add new member         N       N       N       N
  62 ;; Delete member          Y       Y       Y       Y
  63 ;; Rename member          Y       Y       N       N
  64 ;; Chmod                  -       Y       Y       -
  65 ;; Chown                  -       Y       -       -
  66 ;; Chgrp                  -       Y       -       -
  67 ;;
  68 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  69 ;; on the first released version of this package.
  70 ;;
  71 ;; This code is partly based on tar-mode.el from Emacs.
  72 ;; -------------------------------------
  73 ;; ARCHIVE STRUCTURES:
  74 ;; (This is mostly for myself.)
  75 ;;
  76 ;; ARC         A series of (header,file).  No interactions among members.
  77 ;;
  78 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  79 ;;             interaction among members.
  80 ;;             Headers come in three flavours called level 0, 1 and 2 headers.
  81 ;;             Level 2 header is free of DOS specific restrictions and most
  82 ;;             prevalently used.  Also level 1 and 2 headers consist of base
  83 ;;             and extension headers.  For more details see
  84 ;;             http://homepage1.nifty.com/dangan/en/Content/Program/Java/jLHA/Notes/Notes.html
  85 ;;             http://www.osirusoft.com/joejared/lzhformat.html
  86 ;;
  87 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  88 ;;             which is a series of (cheader) followed by an end-of-
  89 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  90 ;;             links to c-d.  cheaders link to lheaders which are basically
  91 ;;             cut-down versions of the cheaders.
  92 ;;
  93 ;; ZOO         An archive header followed by a series of (header,file).
  94 ;;             Each member header points to the next.  The archive is
  95 ;;             terminated by a bogus header with a zero next link.
  96 ;; -------------------------------------
  97 ;; HOOKS: `foo' means one of the supported archive types.
  98 ;;
  99 ;; archive-mode-hook
 100 ;; archive-foo-mode-hook
 101 ;; archive-extract-hooks
 102
 103 ;;; Code:
 104
 105 ;; -------------------------------------------------------------------------
 106 ;; Section: Configuration.
 107
 108 (defgroup archive nil
 109   "Simple editing of archives."
 110   :group 'data)
 111
 112 (defgroup archive-arc nil
 113   "ARC-specific options to archive."
 114   :group 'archive)
 115
 116 (defgroup archive-lzh nil
 117   "LZH-specific options to archive."
 118   :group 'archive)
 119
 120 (defgroup archive-zip nil
 121   "ZIP-specific options to archive."
 122   :group 'archive)
 123
 124 (defgroup archive-zoo nil
 125   "ZOO-specific options to archive."
 126   :group 'archive)
 127
 128 (defcustom archive-tmpdir
 129   ;; make-temp-name is safe here because we use this name
 130   ;; to create a directory.
 131   (make-temp-name
 132    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 133                      temporary-file-directory))
 134   "*Directory for temporary files made by arc-mode.el"
 135   :type 'directory
 136   :group 'archive)
 137
 138 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 139   "*Regexp recognizing archive files names that are not local.
 140 A non-local file is one whose file name is not proper outside Emacs.
 141 A local copy of the archive will be used when updating."
 142   :type 'regexp
 143   :group 'archive)
 144
 145 (defcustom archive-extract-hooks nil
 146   "*Hooks to run when an archive member has been extracted."
 147   :type 'hook
 148   :group 'archive)
 149 ;; ------------------------------
 150 ;; Arc archive configuration
 151
 152 ;; We always go via a local file since there seems to be no reliable way
 153 ;; to extract to stdout without junk getting added.
 154 (defcustom archive-arc-extract
 155   '("arc" "x")
 156   "*Program and its options to run in order to extract an arc file member.
 157 Extraction should happen to the current directory.  Archive and member
 158 name will be added."
 159   :type '(list (string :tag "Program")
 160                 (repeat :tag "Options"
 161                         :inline t
 162                         (string :format "%v")))
 163   :group 'archive-arc)
 164
 165 (defcustom archive-arc-expunge
 166   '("arc" "d")
 167   "*Program and its options to run in order to delete arc file members.
 168 Archive and member names will be added."
 169   :type '(list (string :tag "Program")
 170                 (repeat :tag "Options"
 171                         :inline t
 172                         (string :format "%v")))
 173   :group 'archive-arc)
 174
 175 (defcustom archive-arc-write-file-member
 176   '("arc" "u")
 177   "*Program and its options to run in order to update an arc file member.
 178 Archive and member name will be added."
 179   :type '(list (string :tag "Program")
 180                 (repeat :tag "Options"
 181                         :inline t
 182                         (string :format "%v")))
 183   :group 'archive-arc)
 184 ;; ------------------------------
 185 ;; Lzh archive configuration
 186
 187 (defcustom archive-lzh-extract
 188   '("lha" "pq")
 189   "*Program and its options to run in order to extract an lzh file member.
 190 Extraction should happen to standard output.  Archive and member name will
 191 be added."
 192   :type '(list (string :tag "Program")
 193                 (repeat :tag "Options"
 194                         :inline t
 195                         (string :format "%v")))
 196   :group 'archive-lzh)
 197
 198 (defcustom archive-lzh-expunge
 199   '("lha" "d")
 200   "*Program and its options to run in order to delete lzh file members.
 201 Archive and member names will be added."
 202   :type '(list (string :tag "Program")
 203                 (repeat :tag "Options"
 204                         :inline t
 205                         (string :format "%v")))
 206   :group 'archive-lzh)
 207
 208 (defcustom archive-lzh-write-file-member
 209   '("lha" "a")
 210   "*Program and its options to run in order to update an lzh file member.
 211 Archive and member name will be added."
 212   :type '(list (string :tag "Program")
 213                 (repeat :tag "Options"
 214                         :inline t
 215                         (string :format "%v")))
 216   :group 'archive-lzh)
 217 ;; ------------------------------
 218 ;; Zip archive configuration
 219
 220 (defcustom archive-zip-extract
 221   (if (locate-file "unzip" nil 'file-executable-p)
 222       '("unzip" "-qq" "-c")
 223     (if (locate-file "pkunzip" nil 'file-executable-p)
 224         '("pkunzip" "-e" "-o-")
 225       '("unzip" "-qq" "-c")))
 226   "*Program and its options to run in order to extract a zip file member.
 227 Extraction should happen to standard output.  Archive and member name will
 228 be added.  If `archive-zip-use-pkzip' is non-nil then this program is
 229 expected to extract to a file junking the directory part of the name."
 230   :type '(list (string :tag "Program")
 231                 (repeat :tag "Options"
 232                         :inline t
 233                         (string :format "%v")))
 234   :group 'archive-zip)
 235
 236 ;; For several reasons the latter behaviour is not desirable in general.
 237 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 238 ;; existent.  (3) It tends to do funny things with other systems' file
 239 ;; names.
 240
 241 (defcustom archive-zip-expunge
 242   (if (locate-file "zip" nil 'file-executable-p)
 243       '("zip" "-d" "-q")
 244     (if (locate-file "pkzip" nil 'file-executable-p)
 245          '("pkzip" "-d")
 246       '("zip" "-d" "-q")))
 247   "*Program and its options to run in order to delete zip file members.
 248 Archive and member names will be added."
 249   :type '(list (string :tag "Program")
 250                 (repeat :tag "Options"
 251                         :inline t
 252                         (string :format "%v")))
 253   :group 'archive-zip)
 254
 255 (defcustom archive-zip-update
 256   (if (locate-file "zip" nil 'file-executable-p)
 257       '("zip" "-q")
 258     (if (locate-file "pkzip" nil 'file-executable-p)
 259          '("pkzip" "-u" "-P")
 260       '("zip" "-q")))
 261   "*Program and its options to run in order to update a zip file member.
 262 Options should ensure that specified directory will be put into the zip
 263 file.  Archive and member name will be added."
 264   :type '(list (string :tag "Program")
 265                 (repeat :tag "Options"
 266                         :inline t
 267                         (string :format "%v")))
 268   :group 'archive-zip)
 269
 270 (defcustom archive-zip-update-case
 271   (if (locate-file "zip" nil 'file-executable-p)
 272       '("zip" "-q" "-k")
 273     (if (locate-file "pkzip" nil 'file-executable-p)
 274          '("pkzip" "-u" "-P")
 275       '("zip" "-q" "-k")))
 276   "*Program and its options to run in order to update a case fiddled zip member.
 277 Options should ensure that specified directory will be put into the zip file.
 278 Archive and member name will be added."
 279   :type '(list (string :tag "Program")
 280                 (repeat :tag "Options"
 281                         :inline t
 282                         (string :format "%v")))
 283   :group 'archive-zip)
 284
 285 (defcustom archive-zip-case-fiddle t
 286   "*If non-nil then zip file members may be down-cased.
 287 This case fiddling will only happen for members created by a system
 288 that uses caseless file names."
 289   :type 'boolean
 290   :group 'archive-zip)
 291 ;; ------------------------------
 292 ;; Zoo archive configuration
 293
 294 (defcustom archive-zoo-extract
 295   '("zoo" "xpq")
 296   "*Program and its options to run in order to extract a zoo file member.
 297 Extraction should happen to standard output.  Archive and member name will
 298 be added."
 299   :type '(list (string :tag "Program")
 300                 (repeat :tag "Options"
 301                         :inline t
 302                         (string :format "%v")))
 303   :group 'archive-zoo)
 304
 305 (defcustom archive-zoo-expunge
 306   '("zoo" "DqPP")
 307   "*Program and its options to run in order to delete zoo file members.
 308 Archive and member names will be added."
 309   :type '(list (string :tag "Program")
 310                 (repeat :tag "Options"
 311                         :inline t
 312                         (string :format "%v")))
 313   :group 'archive-zoo)
 314
 315 (defcustom archive-zoo-write-file-member
 316   '("zoo" "a")
 317   "*Program and its options to run in order to update a zoo file member.
 318 Archive and member name will be added."
 319   :type '(list (string :tag "Program")
 320                 (repeat :tag "Options"
 321                         :inline t
 322                         (string :format "%v")))
 323   :group 'archive-zoo)
 324 ;; -------------------------------------------------------------------------
 325 ;; Section: Variables
 326
 327 (defvar archive-subtype nil "*Symbol describing archive type.")
 328 (defvar archive-file-list-start nil "*Position of first contents line.")
 329 (defvar archive-file-list-end nil "*Position just after last contents line.")
 330 (defvar archive-proper-file-start nil "*Position of real archive's start.")
 331 (defvar archive-read-only nil "*Non-nil if the archive is read-only on disk.")
 332 (defvar archive-local-name nil "*Name of local copy of remote archive.")
 333 (defvar archive-mode-map nil "*Local keymap for archive mode listings.")
 334 (defvar archive-file-name-indent nil "*Column where file names start.")
 335
 336 (defvar archive-remote nil "*Non-nil if the archive is outside file system.")
 337 (make-variable-buffer-local 'archive-remote)
 338 (put 'archive-remote 'permanent-local t)
 339
 340 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 341 (make-variable-buffer-local 'archive-member-coding-system)
 342
 343 (defvar archive-alternate-display nil
 344   "*Non-nil when alternate information is shown.")
 345 (make-variable-buffer-local 'archive-alternate-display)
 346 (put 'archive-alternate-display 'permanent-local t)
 347
 348 (defvar archive-superior-buffer nil "*In archive members, points to archive.")
 349 (put 'archive-superior-buffer 'permanent-local t)
 350
 351 (defvar archive-subfile-mode nil "*Non-nil in archive member buffers.")
 352 (make-variable-buffer-local 'archive-subfile-mode)
 353 (put 'archive-subfile-mode 'permanent-local t)
 354
 355 (defvar archive-files nil
 356   "Vector of file descriptors.
 357 Each descriptor is a vector of the form
 358  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 359 (make-variable-buffer-local 'archive-files)
 360
 361 (defvar archive-lemacs
 362   (string-match "\\(Lucid\\|Xemacs\\)" emacs-version)
 363   "*Non-nil when running under under Lucid Emacs or Xemacs.")
 364 ;; -------------------------------------------------------------------------
 365 ;; Section: Support functions.
 366
 367 (defsubst archive-name (suffix)
 368   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 369
 370 (defun archive-l-e (str &optional len)
 371   "Convert little endian string/vector to integer.
 372 Alternatively, first argument may be a buffer position in the current buffer
 373 in which case a second argument, length, should be supplied."
 374   (if (stringp str)
 375       (setq len (length str))
 376     (setq str (buffer-substring str (+ str len))))
 377   (let ((result 0)
 378         (i 0))
 379     (while (< i len)
 380       (setq i (1+ i)
 381             result (+ (ash result 8) (aref str (- len i)))))
 382     result))
 383
 384 (defun archive-int-to-mode (mode)
 385   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 386   ;; FIXME: merge with tar-grind-file-mode.
 387   (string
 388     (if (zerop (logand  8192 mode))
 389         (if (zerop (logand 16384 mode)) ?- ?d)
 390       ?c) ; completeness
 391     (if (zerop (logand   256 mode)) ?- ?r)
 392     (if (zerop (logand   128 mode)) ?- ?w)
 393     (if (zerop (logand    64 mode))
 394         (if (zerop (logand  1024 mode)) ?- ?S)
 395       (if (zerop (logand  1024 mode)) ?x ?s))
 396     (if (zerop (logand    32 mode)) ?- ?r)
 397     (if (zerop (logand    16 mode)) ?- ?w)
 398     (if (zerop (logand     8 mode))
 399         (if (zerop (logand  2048 mode)) ?- ?S)
 400       (if (zerop (logand  2048 mode)) ?x ?s))
 401     (if (zerop (logand     4 mode)) ?- ?r)
 402     (if (zerop (logand     2 mode)) ?- ?w)
 403     (if (zerop (logand     1 mode)) ?- ?x)))
 404
 405 (defun archive-calc-mode (oldmode newmode &optional error)
 406   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 407 NEWMODE may be an octal number including a leading zero in which case it
 408 will become the new mode.\n
 409 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 410 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 411 If optional third argument ERROR is non-nil an error will be signaled if
 412 the mode is invalid.  If ERROR is nil then nil will be returned."
 413   (cond ((string-match "^0[0-7]*$" newmode)
 414          (let ((result 0)
 415                (len (length newmode))
 416                (i 1))
 417            (while (< i len)
 418              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 419                    i (1+ i)))
 420            (logior (logand oldmode 65024) result)))
 421         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 422          (let ((who 0)
 423                (result oldmode)
 424                (op (aref newmode (match-beginning 2)))
 425                (bits 0)
 426                (i (match-beginning 3)))
 427            (while (< i (match-end 3))
 428              (let ((rwx (aref newmode i)))
 429                (setq bits (logior bits (cond ((= rwx ?r)  292)
 430                                              ((= rwx ?w)  146)
 431                                              ((= rwx ?x)   73)
 432                                              ((= rwx ?s) 3072)
 433                                              ((= rwx ?t)  512)))
 434                      i (1+ i))))
 435            (while (< who (match-end 1))
 436              (let* ((whoc (aref newmode who))
 437                     (whomask (cond ((= whoc ?a) 4095)
 438                                    ((= whoc ?u) 1472)
 439                                    ((= whoc ?g) 2104)
 440                                    ((= whoc ?o)    7))))
 441                (if (= op ?=)
 442                    (setq result (logand result (lognot whomask))))
 443                (if (= op ?-)
 444                    (setq result (logand result (lognot (logand whomask bits))))
 445                  (setq result (logior result (logand whomask bits)))))
 446              (setq who (1+ who)))
 447            result))
 448         (t
 449          (if error
 450              (error "Invalid mode specification: %s" newmode)))))
 451
 452 (defun archive-dosdate (date)
 453   "Stringify dos packed DATE record."
 454   (let ((year (+ 1980 (logand (ash date -9) 127)))
 455         (month (logand (ash date -5) 15))
 456         (day (logand date 31)))
 457     (if (or (> month 12) (< month 1))
 458         ""
 459       (format "%2d-%s-%d"
 460               day
 461               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 462                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 463               year))))
 464
 465 (defun archive-dostime (time)
 466   "Stringify dos packed TIME record."
 467   (let ((hour (logand (ash time -11) 31))
 468         (minute (logand (ash time -5) 63))
 469         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 470     (format "%02d:%02d:%02d" hour minute second)))
 471
 472 (defun archive-unixdate (low high)
 473   "Stringify unix (LOW HIGH) date."
 474   (let ((str (current-time-string (cons high low))))
 475     (format "%s-%s-%s"
 476             (substring str 8 10)
 477             (substring str 4 7)
 478             (substring str 20 24))))
 479
 480 (defun archive-unixtime (low high)
 481   "Stringify unix (LOW HIGH) time."
 482   (let ((str (current-time-string (cons high low))))
 483     (substring str 11 19)))
 484
 485 (defun archive-get-lineno ()
 486   (if (>= (point) archive-file-list-start)
 487       (count-lines archive-file-list-start
 488                    (save-excursion (beginning-of-line) (point)))
 489     0))
 490
 491 (defun archive-get-descr (&optional noerror)
 492   "Return the descriptor vector for file at point.
 493 Does not signal an error if optional second argument NOERROR is non-nil."
 494   (let ((no (archive-get-lineno)))
 495     (if (and (>= (point) archive-file-list-start)
 496              (< no (length archive-files)))
 497         (let ((item (aref archive-files no)))
 498           (if (vectorp item)
 499               item
 500             (if (not noerror)
 501                 (error "Entry is not a regular member of the archive"))))
 502       (if (not noerror)
 503           (error "Line does not describe a member of the archive")))))
 504 ;; -------------------------------------------------------------------------
 505 ;; Section: the mode definition
 506
 507 ;;;###autoload
 508 (defun archive-mode (&optional force)
 509   "Major mode for viewing an archive file in a dired-like way.
 510 You can move around using the usual cursor motion commands.
 511 Letters no longer insert themselves.
 512 Type `e' to pull a file out of the archive and into its own buffer;
 513 or click mouse-2 on the file's line in the archive mode buffer.
 514
 515 If you edit a sub-file of this archive (as with the `e' command) and
 516 save it, the contents of that buffer will be saved back into the
 517 archive.
 518
 519 \\{archive-mode-map}"
 520   ;; This is not interactive because you shouldn't be turning this
 521   ;; mode on and off.  You can corrupt things that way.
 522   (if (zerop (buffer-size))
 523       ;; At present we cannot create archives from scratch
 524       (funcall default-major-mode)
 525     (if (and (not force) archive-files) nil
 526       (let* ((type (archive-find-type))
 527              (typename (capitalize (symbol-name type))))
 528         (kill-all-local-variables)
 529         (make-local-variable 'archive-subtype)
 530         (setq archive-subtype type)
 531
 532         ;; Buffer contains treated image of file before the file contents
 533         (make-local-variable 'revert-buffer-function)
 534         (setq revert-buffer-function 'archive-mode-revert)
 535         (auto-save-mode 0)
 536
 537         ;; Remote archives are not written by a hook.
 538         (if archive-remote nil
 539           (make-local-variable 'write-contents-hooks)
 540           (add-hook 'write-contents-hooks 'archive-write-file))
 541
 542         (make-local-variable 'require-final-newline)
 543         (setq require-final-newline nil)
 544         (make-local-variable 'local-enable-local-variables)
 545         (setq local-enable-local-variables nil)
 546
 547         ;; Prevent loss of data when saving the file.
 548         (make-local-variable 'file-precious-flag)
 549         (setq file-precious-flag t)
 550
 551         (make-local-variable 'archive-read-only)
 552         ;; Archives which are inside other archives and whose
 553         ;; names are invalid for this OS, can't be written.
 554         (setq archive-read-only
 555               (or (not (file-writable-p (buffer-file-name)))
 556                   (and archive-subfile-mode
 557                        (string-match file-name-invalid-regexp
 558                                      (aref archive-subfile-mode 0)))))
 559
 560         ;; Should we use a local copy when accessing from outside Emacs?
 561         (make-local-variable 'archive-local-name)
 562
 563         ;; An archive can contain another archive whose name is invalid
 564         ;; on local filesystem.  Treat such archives as remote.
 565         (or archive-remote
 566             (setq archive-remote
 567                   (or (string-match archive-remote-regexp (buffer-file-name))
 568                       (string-match file-name-invalid-regexp
 569                                     (buffer-file-name)))))
 570
 571         (setq major-mode 'archive-mode)
 572         (setq mode-name (concat typename "-Archive"))
 573         ;; Run archive-foo-mode-hook and archive-mode-hook
 574         (run-hooks (archive-name "mode-hook") 'archive-mode-hook)
 575         (use-local-map archive-mode-map))
 576
 577       (make-local-variable 'archive-proper-file-start)
 578       (make-local-variable 'archive-file-list-start)
 579       (make-local-variable 'archive-file-list-end)
 580       (make-local-variable 'archive-file-name-indent)
 581       (archive-summarize nil)
 582       (setq buffer-read-only t))))
 583
 584 ;; Archive mode is suitable only for specially formatted data.
 585 (put 'archive-mode 'mode-class 'special)
 586 ;; -------------------------------------------------------------------------
 587 ;; Section: Key maps
 588
 589 (if archive-mode-map nil
 590   (setq archive-mode-map (make-keymap))
 591   (suppress-keymap archive-mode-map)
 592   (define-key archive-mode-map " " 'archive-next-line)
 593   (define-key archive-mode-map "a" 'archive-alternate-display)
 594   ;;(define-key archive-mode-map "c" 'archive-copy)
 595   (define-key archive-mode-map "d" 'archive-flag-deleted)
 596   (define-key archive-mode-map "\C-d" 'archive-flag-deleted)
 597   (define-key archive-mode-map "e" 'archive-extract)
 598   (define-key archive-mode-map "f" 'archive-extract)
 599   (define-key archive-mode-map "\C-m" 'archive-extract)
 600   (define-key archive-mode-map "g" 'revert-buffer)
 601   (define-key archive-mode-map "h" 'describe-mode)
 602   (define-key archive-mode-map "m" 'archive-mark)
 603   (define-key archive-mode-map "n" 'archive-next-line)
 604   (define-key archive-mode-map "\C-n" 'archive-next-line)
 605   (define-key archive-mode-map [down] 'archive-next-line)
 606   (define-key archive-mode-map "o" 'archive-extract-other-window)
 607   (define-key archive-mode-map "p" 'archive-previous-line)
 608   (define-key archive-mode-map "q" 'quit-window)
 609   (define-key archive-mode-map "\C-p" 'archive-previous-line)
 610   (define-key archive-mode-map [up] 'archive-previous-line)
 611   (define-key archive-mode-map "r" 'archive-rename-entry)
 612   (define-key archive-mode-map "u" 'archive-unflag)
 613   (define-key archive-mode-map "\M-\C-?" 'archive-unmark-all-files)
 614   (define-key archive-mode-map "v" 'archive-view)
 615   (define-key archive-mode-map "x" 'archive-expunge)
 616   (define-key archive-mode-map "\177" 'archive-unflag-backwards)
 617   (define-key archive-mode-map "E" 'archive-extract-other-window)
 618   (define-key archive-mode-map "M" 'archive-chmod-entry)
 619   (define-key archive-mode-map "G" 'archive-chgrp-entry)
 620   (define-key archive-mode-map "O" 'archive-chown-entry)
 621
 622   (if archive-lemacs
 623       (progn
 624         ;; Not a nice "solution" but it'll have to do
 625         (define-key archive-mode-map "\C-xu" 'archive-undo)
 626         (define-key archive-mode-map "\C-_" 'archive-undo))
 627     (define-key archive-mode-map [remap advertised-undo] 'archive-undo)
 628     (define-key archive-mode-map [remap undo] 'archive-undo))
 629
 630   (define-key archive-mode-map
 631     (if archive-lemacs 'button2 [mouse-2]) 'archive-mouse-extract)
 632
 633   (if archive-lemacs
 634       ()                                ; out of luck
 635
 636     (define-key archive-mode-map [menu-bar immediate]
 637       (cons "Immediate" (make-sparse-keymap "Immediate")))
 638     (define-key archive-mode-map [menu-bar immediate alternate]
 639       '(menu-item "Alternate Display" archive-alternate-display
 640                   :enable (boundp (archive-name "alternate-display"))
 641                   :help "Toggle alternate file info display"))
 642     (define-key archive-mode-map [menu-bar immediate view]
 643       '(menu-item "View This File" archive-view
 644                   :help "Display file at cursor in View Mode"))
 645     (define-key archive-mode-map [menu-bar immediate display]
 646       '(menu-item "Display in Other Window" archive-display-other-window
 647                   :help "Display file at cursor in another window"))
 648     (define-key archive-mode-map [menu-bar immediate find-file-other-window]
 649       '(menu-item "Find in Other Window" archive-extract-other-window
 650                   :help "Edit file at cursor in another window"))
 651     (define-key archive-mode-map [menu-bar immediate find-file]
 652       '(menu-item "Find This File" archive-extract
 653                   :help "Extract file at cursor and edit it"))
 654
 655     (define-key archive-mode-map [menu-bar mark]
 656       (cons "Mark" (make-sparse-keymap "Mark")))
 657     (define-key archive-mode-map [menu-bar mark unmark-all]
 658       '(menu-item "Unmark All" archive-unmark-all-files
 659                   :help "Unmark all marked files"))
 660     (define-key archive-mode-map [menu-bar mark deletion]
 661       '(menu-item "Flag" archive-flag-deleted
 662                   :help "Flag file at cursor for deletion"))
 663     (define-key archive-mode-map [menu-bar mark unmark]
 664       '(menu-item "Unflag" archive-unflag
 665                   :help "Unmark file at cursor"))
 666     (define-key archive-mode-map [menu-bar mark mark]
 667       '(menu-item "Mark" archive-mark
 668                   :help "Mark file at cursor"))
 669
 670     (define-key archive-mode-map [menu-bar operate]
 671       (cons "Operate" (make-sparse-keymap "Operate")))
 672     (define-key archive-mode-map [menu-bar operate chown]
 673       '(menu-item "Change Owner..." archive-chown-entry
 674                   :enable (fboundp (archive-name "chown-entry"))
 675                   :help "Change owner of marked files"))
 676     (define-key archive-mode-map [menu-bar operate chgrp]
 677       '(menu-item "Change Group..." archive-chgrp-entry
 678                   :enable (fboundp (archive-name "chgrp-entry"))
 679                   :help "Change group ownership of marked files"))
 680     (define-key archive-mode-map [menu-bar operate chmod]
 681       '(menu-item "Change Mode..." archive-chmod-entry
 682                   :enable (fboundp (archive-name "chmod-entry"))
 683                   :help "Change mode (permissions) of marked files"))
 684     (define-key archive-mode-map [menu-bar operate rename]
 685       '(menu-item "Rename to..." archive-rename-entry
 686                   :enable (fboundp (archive-name "rename-entry"))
 687                   :help "Rename marked files"))
 688     ;;(define-key archive-mode-map [menu-bar operate copy]
 689     ;;  '(menu-item "Copy to..." archive-copy))
 690     (define-key archive-mode-map [menu-bar operate expunge]
 691       '(menu-item "Expunge Marked Files" archive-expunge
 692                   :help "Delete all flagged files from archive"))
 693   ))
 694
 695 (let* ((item1 '(archive-subfile-mode " Archive"))
 696        (items (list item1)))
 697   (or (member item1 minor-mode-alist)
 698       (setq minor-mode-alist (append items minor-mode-alist))))
 699 ;; -------------------------------------------------------------------------
 700 (defun archive-find-type ()
 701   (widen)
 702   (goto-char (point-min))
 703   ;; The funny [] here make it unlikely that the .elc file will be treated
 704   ;; as an archive by other software.
 705   (let (case-fold-search)
 706     (cond ((looking-at "[P]K\003\004") 'zip)
 707           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 708           ((looking-at "....................[\334]\247\304\375") 'zoo)
 709           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 710                 (string-match "\\.[aA][rR][cC]$"
 711                               (or buffer-file-name (buffer-name))))
 712            'arc)
 713           (t (error "Buffer format not recognized")))))
 714 ;; -------------------------------------------------------------------------
 715 (defun archive-summarize (&optional shut-up)
 716   "Parse the contents of the archive file in the current buffer.
 717 Place a dired-like listing on the front;
 718 then narrow to it, so that only that listing
 719 is visible (and the real data of the buffer is hidden).
 720 Optional argument SHUT-UP, if non-nil, means don't print messages
 721 when parsing the archive."
 722   (widen)
 723   (set-buffer-multibyte nil)
 724   (let (buffer-read-only)
 725     (or shut-up
 726         (message "Parsing archive file..."))
 727     (buffer-disable-undo (current-buffer))
 728     (setq archive-files (funcall (archive-name "summarize")))
 729     (or shut-up
 730         (message "Parsing archive file...done."))
 731     (setq archive-proper-file-start (point-marker))
 732     (narrow-to-region (point-min) (point))
 733     (set-buffer-modified-p nil)
 734     (buffer-enable-undo))
 735   (goto-char archive-file-list-start)
 736   (archive-next-line 0))
 737
 738 (defun archive-resummarize ()
 739   "Recreate the contents listing of an archive."
 740   (let ((modified (buffer-modified-p))
 741         (no (archive-get-lineno))
 742         buffer-read-only)
 743     (widen)
 744     (delete-region (point-min) archive-proper-file-start)
 745     (archive-summarize t)
 746     (set-buffer-modified-p modified)
 747     (goto-char archive-file-list-start)
 748     (archive-next-line no)))
 749
 750 (defun archive-summarize-files (files)
 751   "Insert a description of a list of files annotated with proper mouse face."
 752   (setq archive-file-list-start (point-marker))
 753   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 754   ;; We don't want to do an insert for each element since that takes too
 755   ;; long when the archive -- which has to be moved in memory -- is large.
 756   (insert
 757    (apply
 758     (function concat)
 759     (mapcar
 760      (function
 761       (lambda (fil)
 762         ;; Using `concat' here copies the text also, so we can add
 763         ;; properties without problems.
 764         (let ((text (concat (aref fil 0) "\n")))
 765           (if archive-lemacs
 766               ()                        ; out of luck
 767             (add-text-properties
 768              (aref fil 1) (aref fil 2)
 769              '(mouse-face highlight
 770                help-echo "mouse-2: extract this file into a buffer")
 771              text))
 772           text)))
 773      files)))
 774   (setq archive-file-list-end (point-marker)))
 775
 776 (defun archive-alternate-display ()
 777   "Toggle alternative display.
 778 To avoid very long lines some archive mode don't show all information.
 779 This function changes the set of information shown for each files."
 780   (interactive)
 781   (setq archive-alternate-display (not archive-alternate-display))
 782   (archive-resummarize))
 783 ;; -------------------------------------------------------------------------
 784 ;; Section: Local archive copy handling
 785
 786 (defun archive-unique-fname (fname dir)
 787   "Make sure a file FNAME can be created uniquely in directory DIR.
 788
 789 If FNAME can be uniquely created in DIR, it is returned unaltered.
 790 If FNAME is something our underlying filesystem can't grok, or if another
 791 file by that name already exists in DIR, a unique new name is generated
 792 using `make-temp-file', and the generated name is returned."
 793   (let ((fullname (expand-file-name fname dir))
 794         (alien (string-match file-name-invalid-regexp fname)))
 795     (if (or alien (file-exists-p fullname))
 796         (make-temp-file
 797          (expand-file-name
 798           (if (if (fboundp 'msdos-long-file-names)
 799                   (not (msdos-long-file-names)))
 800               "am"
 801             "arc-mode.")
 802           dir))
 803       fullname)))
 804
 805 (defun archive-maybe-copy (archive)
 806   (let ((coding-system-for-write 'no-conversion))
 807     (if archive-remote
 808         (let ((start (point-max))
 809               ;; Sometimes ARCHIVE is invalid while its actual name, as
 810               ;; recorded in its parent archive, is not.  For example, an
 811               ;; archive bar.zip inside another archive foo.zip gets a name
 812               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 813               ;; So use the actual name if available.
 814               (archive-name
 815                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 816                    archive)))
 817           (make-directory archive-tmpdir t)
 818           (setq archive-local-name
 819                 (archive-unique-fname archive-name archive-tmpdir))
 820           (save-restriction
 821             (widen)
 822             (write-region start (point-max) archive-local-name nil 'nomessage))
 823           archive-local-name)
 824       (if (buffer-modified-p) (save-buffer))
 825       archive)))
 826
 827 (defun archive-maybe-update (unchanged)
 828   (if archive-remote
 829       (let ((name archive-local-name)
 830             (modified (buffer-modified-p))
 831             (coding-system-for-read 'no-conversion)
 832             (lno (archive-get-lineno))
 833             buffer-read-only)
 834         (if unchanged nil
 835           (setq archive-files nil)
 836           (erase-buffer)
 837           (insert-file-contents name)
 838           (archive-mode t)
 839           (goto-char archive-file-list-start)
 840           (archive-next-line lno))
 841         (archive-delete-local name)
 842         (if (not unchanged)
 843             (message
 844              "Buffer `%s' must be saved for changes to take effect"
 845              (buffer-name (current-buffer))))
 846         (set-buffer-modified-p (or modified (not unchanged))))))
 847
 848 (defun archive-delete-local (name)
 849   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 850   (let ((again t)
 851         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 852     (condition-case nil
 853         (delete-file name)
 854       (error nil))
 855     (while again
 856       (setq name (directory-file-name (file-name-directory name)))
 857       (condition-case nil
 858           (delete-directory name)
 859         (error nil))
 860       (if (string= name top) (setq again nil)))))
 861 ;; -------------------------------------------------------------------------
 862 ;; Section: Member extraction
 863
 864 (defun archive-file-name-handler (op &rest args)
 865   (or (eq op 'file-exists-p)
 866       (let ((file-name-handler-alist nil))
 867         (apply op args))))
 868
 869 (defun archive-set-buffer-as-visiting-file (filename)
 870   "Set the current buffer as if it were visiting FILENAME."
 871   (save-excursion
 872     (goto-char (point-min))
 873     (let ((coding
 874            (or coding-system-for-read
 875                (and set-auto-coding-function
 876                     (save-excursion
 877                       (funcall set-auto-coding-function
 878                                filename (- (point-max) (point-min)))))
 879                ;; dos-w32.el defines find-operation-coding-system for
 880                ;; DOS/Windows systems which preserves the coding-system
 881                ;; of existing files.  We want it to act here as if the
 882                ;; extracted file existed.
 883                (let ((file-name-handler-alist
 884                       '(("" . archive-file-name-handler))))
 885                  (car (find-operation-coding-system 'insert-file-contents
 886                                                     filename t))))))
 887       (if (and (not coding-system-for-read)
 888                (not enable-multibyte-characters))
 889           (setq coding
 890                 (coding-system-change-text-conversion coding 'raw-text)))
 891       (if (and coding
 892                (not (eq coding 'no-conversion)))
 893           (decode-coding-region (point-min) (point-max) coding)
 894         (setq last-coding-system-used coding))
 895       (set-buffer-modified-p nil)
 896       (kill-local-variable 'buffer-file-coding-system)
 897       (after-insert-file-set-buffer-file-coding-system (- (point-max)
 898                                                           (point-min))))))
 899
 900 (defun archive-mouse-extract (event)
 901   "Extract a file whose name you click on."
 902   (interactive "e")
 903   (mouse-set-point event)
 904   (switch-to-buffer
 905    (save-excursion
 906      (archive-extract)
 907      (current-buffer))))
 908
 909 (defun archive-extract (&optional other-window-p)
 910   "In archive mode, extract this entry of the archive into its own buffer."
 911   (interactive)
 912   (let* ((view-p (eq other-window-p 'view))
 913          (descr (archive-get-descr))
 914          (ename (aref descr 0))
 915          (iname (aref descr 1))
 916          (archive-buffer (current-buffer))
 917          (arcdir default-directory)
 918          (archive (buffer-file-name))
 919          (arcname (file-name-nondirectory archive))
 920          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 921          (extractor (archive-name "extract"))
 922          ;; Members with file names which aren't valid for the
 923          ;; underlying filesystem, are treated as read-only.
 924          (read-only-p (or archive-read-only
 925                           view-p
 926                           (string-match file-name-invalid-regexp ename)))
 927          (buffer (get-buffer bufname))
 928          (just-created nil))
 929       (if buffer
 930           nil
 931         (setq archive (archive-maybe-copy archive))
 932         (setq buffer (get-buffer-create bufname))
 933         (setq just-created t)
 934         (save-excursion
 935           (set-buffer buffer)
 936           (setq buffer-file-name
 937                 (expand-file-name (concat arcname ":" iname)))
 938           (setq buffer-file-truename
 939                 (abbreviate-file-name buffer-file-name))
 940           ;; Set the default-directory to the dir of the superior buffer.
 941           (setq default-directory arcdir)
 942           (make-local-variable 'archive-superior-buffer)
 943           (setq archive-superior-buffer archive-buffer)
 944           (make-local-variable 'local-write-file-hooks)
 945           (add-hook 'local-write-file-hooks 'archive-write-file-member)
 946           (setq archive-subfile-mode descr)
 947           (if (and
 948                (null
 949                 (let (;; We may have to encode file name arguement for
 950                       ;; external programs.
 951                       (coding-system-for-write
 952                        (and enable-multibyte-characters
 953                             file-name-coding-system))
 954                       ;; We read an archive member by no-conversion at
 955                       ;; first, then decode appropriately by calling
 956                       ;; archive-set-buffer-as-visiting-file later.
 957                       (coding-system-for-read 'no-conversion))
 958                   (condition-case err
 959                       (if (fboundp extractor)
 960                           (funcall extractor archive ename)
 961                         (archive-*-extract archive ename
 962                                            (symbol-value extractor)))
 963                     (error
 964                      (ding (message "%s" (error-message-string err)))
 965                      nil))))
 966                just-created)
 967               (progn
 968                 (set-buffer-modified-p nil)
 969                 (kill-buffer buffer))
 970             (archive-set-buffer-as-visiting-file ename)
 971             (goto-char (point-min))
 972             (rename-buffer bufname)
 973             (setq buffer-read-only read-only-p)
 974             (setq buffer-undo-list nil)
 975             (set-buffer-modified-p nil)
 976             (setq buffer-saved-size (buffer-size))
 977             (normal-mode)
 978             ;; Just in case an archive occurs inside another archive.
 979             (if (eq major-mode 'archive-mode)
 980                 (progn
 981                   (setq archive-remote t)
 982                   (if read-only-p (setq archive-read-only t))
 983                   ;; We will write out the archive ourselves if it is
 984                   ;; part of another archive.
 985                   (remove-hook 'write-contents-hooks 'archive-write-file t)))
 986             (run-hooks 'archive-extract-hooks)
 987             (if archive-read-only
 988                 (message "Note: altering this archive is not implemented."))))
 989         (archive-maybe-update t))
 990       (or (not (buffer-name buffer))
 991           (progn
 992             (if view-p
 993                 (view-buffer buffer (and just-created 'kill-buffer))
 994               (if (eq other-window-p 'display)
 995                   (display-buffer buffer)
 996                 (if other-window-p
 997                     (switch-to-buffer-other-window buffer)
 998                   (switch-to-buffer buffer))))))))
 999
1000 (defun archive-*-extract (archive name command)
1001   (let* ((default-directory (file-name-as-directory archive-tmpdir))
1002          (tmpfile (expand-file-name (file-name-nondirectory name)
1003                                     default-directory))
1004          exit-status success)
1005     (make-directory (directory-file-name default-directory) t)
1006     (setq exit-status
1007           (apply 'call-process
1008                  (car command)
1009                  nil
1010                  nil
1011                  nil
1012                  (append (cdr command) (list archive name))))
1013     (cond ((and (numberp exit-status) (= exit-status 0))
1014            (if (not (file-exists-p tmpfile))
1015                (ding (message "`%s': no such file or directory" tmpfile))
1016              (insert-file-contents tmpfile)
1017              (setq success t)))
1018           ((numberp exit-status)
1019            (ding
1020             (message "`%s' exited with status %d" (car command) exit-status)))
1021           ((stringp exit-status)
1022            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1023           (t
1024            (ding (message "`%s' failed" (car command)))))
1025     (archive-delete-local tmpfile)
1026     success))
1027
1028 (defun archive-extract-by-stdout (archive name command)
1029   (apply 'call-process
1030          (car command)
1031          nil
1032          t
1033          nil
1034          (append (cdr command) (list archive name))))
1035
1036 (defun archive-extract-other-window ()
1037   "In archive mode, find this member in another window."
1038   (interactive)
1039   (archive-extract t))
1040
1041 (defun archive-display-other-window ()
1042   "In archive mode, display this member in another window."
1043   (interactive)
1044   (archive-extract 'display))
1045
1046 (defun archive-view ()
1047   "In archive mode, view the member on this line."
1048   (interactive)
1049   (archive-extract 'view))
1050
1051 (defun archive-add-new-member (arcbuf name)
1052   "Add current buffer to the archive in ARCBUF naming it NAME."
1053   (interactive
1054    (list (get-buffer
1055           (read-buffer "Buffer containing archive: "
1056                        ;; Find first archive buffer and suggest that
1057                        (let ((bufs (buffer-list)))
1058                          (while (and bufs (not (eq (save-excursion
1059                                                      (set-buffer (car bufs))
1060                                                      major-mode)
1061                                                    'archive-mode)))
1062                            (setq bufs (cdr bufs)))
1063                          (if bufs
1064                              (car bufs)
1065                            (error "There are no archive buffers")))
1066                        t))
1067          (read-string "File name in archive: "
1068                       (if buffer-file-name
1069                           (file-name-nondirectory buffer-file-name)
1070                         ""))))
1071   (save-excursion
1072     (set-buffer arcbuf)
1073     (or (eq major-mode 'archive-mode)
1074         (error "Buffer is not an archive buffer"))
1075     (if archive-read-only
1076         (error "Archive is read-only")))
1077   (if (eq arcbuf (current-buffer))
1078       (error "An archive buffer cannot be added to itself"))
1079   (if (string= name "")
1080       (error "Archive members may not be given empty names"))
1081   (let ((func (save-excursion (set-buffer arcbuf)
1082                               (archive-name "add-new-member")))
1083         (membuf (current-buffer)))
1084     (if (fboundp func)
1085         (save-excursion
1086           (set-buffer arcbuf)
1087           (funcall func buffer-file-name membuf name))
1088       (error "Adding a new member is not supported for this archive type"))))
1089 ;; -------------------------------------------------------------------------
1090 ;; Section: IO stuff
1091
1092 (defun archive-write-file-member ()
1093   (save-excursion
1094     (save-restriction
1095       (message "Updating archive...")
1096       (widen)
1097       (let ((writer  (save-excursion (set-buffer archive-superior-buffer)
1098                                      (archive-name "write-file-member")))
1099             (archive (save-excursion (set-buffer archive-superior-buffer)
1100                                      (archive-maybe-copy (buffer-file-name)))))
1101         (if (fboundp writer)
1102             (funcall writer archive archive-subfile-mode)
1103           (archive-*-write-file-member archive
1104                                        archive-subfile-mode
1105                                        (symbol-value writer)))
1106         (set-buffer-modified-p nil)
1107         (message "Updating archive...done"))
1108       (set-buffer archive-superior-buffer)
1109       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1110   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1111   ;; won't reset the coding-system of this archive member.
1112   (if (local-variable-p 'archive-member-coding-system)
1113       (setq last-coding-system-used archive-member-coding-system))
1114   t)
1115
1116 (defun archive-*-write-file-member (archive descr command)
1117   (let* ((ename (aref descr 0))
1118          (tmpfile (expand-file-name ename archive-tmpdir))
1119          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1120          (default-directory (file-name-as-directory top)))
1121     (unwind-protect
1122         (progn
1123           (make-directory (file-name-directory tmpfile) t)
1124           ;; If the member is itself an archive, write it without
1125           ;; the dired-like listing we created.
1126           (if (eq major-mode 'archive-mode)
1127               (archive-write-file tmpfile)
1128             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1129           ;; basic-save-buffer needs last-coding-system-used to have
1130           ;; the value used to write the file, so save it before any
1131           ;; further processing clobbers it (we restore it in
1132           ;; archive-write-file-member, above).
1133           (setq archive-member-coding-system last-coding-system-used)
1134           (if (aref descr 3)
1135               ;; Set the file modes, but make sure we can read it.
1136               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1137           (if enable-multibyte-characters
1138               (setq ename
1139                     (encode-coding-string ename file-name-coding-system)))
1140           (let ((exitcode (apply 'call-process
1141                                  (car command)
1142                                  nil
1143                                  nil
1144                                  nil
1145                                  (append (cdr command) (list archive ename)))))
1146             (if (equal exitcode 0)
1147                 nil
1148               (error "Updating was unsuccessful (%S)" exitcode))))
1149       (archive-delete-local tmpfile))))
1150
1151 (defun archive-write-file (&optional file)
1152   (save-excursion
1153     (let ((coding-system-for-write 'no-conversion))
1154       (write-region archive-proper-file-start (point-max)
1155                     (or file buffer-file-name) nil t)
1156       (set-buffer-modified-p nil))
1157     t))
1158 ;; -------------------------------------------------------------------------
1159 ;; Section: Marking and unmarking.
1160
1161 (defun archive-flag-deleted (p &optional type)
1162   "In archive mode, mark this member to be deleted from the archive.
1163 With a prefix argument, mark that many files."
1164   (interactive "p")
1165   (or type (setq type ?D))
1166   (beginning-of-line)
1167   (let ((sign (if (>= p 0) +1 -1))
1168         (modified (buffer-modified-p))
1169         buffer-read-only)
1170     (while (not (zerop p))
1171       (if (archive-get-descr t)
1172           (progn
1173             (delete-char 1)
1174             (insert type)))
1175       (forward-line sign)
1176       (setq p (- p sign)))
1177     (set-buffer-modified-p modified))
1178   (archive-next-line 0))
1179
1180 (defun archive-unflag (p)
1181   "In archive mode, un-mark this member if it is marked to be deleted.
1182 With a prefix argument, un-mark that many files forward."
1183   (interactive "p")
1184   (archive-flag-deleted p ? ))
1185
1186 (defun archive-unflag-backwards (p)
1187   "In archive mode, un-mark this member if it is marked to be deleted.
1188 With a prefix argument, un-mark that many members backward."
1189   (interactive "p")
1190   (archive-flag-deleted (- p) ? ))
1191
1192 (defun archive-unmark-all-files ()
1193   "Remove all marks."
1194   (interactive)
1195   (let ((modified (buffer-modified-p))
1196         buffer-read-only)
1197     (save-excursion
1198       (goto-char archive-file-list-start)
1199       (while (< (point) archive-file-list-end)
1200         (or (= (following-char) ? )
1201             (progn (delete-char 1) (insert ? )))
1202         (forward-line 1)))
1203     (set-buffer-modified-p modified)))
1204
1205 (defun archive-mark (p)
1206   "In archive mode, mark this member for group operations.
1207 With a prefix argument, mark that many members.
1208 Use \\[archive-unmark-all-files] to remove all marks."
1209   (interactive "p")
1210   (archive-flag-deleted p ?*))
1211
1212 (defun archive-get-marked (mark &optional default)
1213   (let (files)
1214     (save-excursion
1215       (goto-char archive-file-list-start)
1216       (while (< (point) archive-file-list-end)
1217         (if (= (following-char) mark)
1218             (setq files (cons (archive-get-descr) files)))
1219         (forward-line 1)))
1220     (or (nreverse files)
1221         (and default
1222              (list (archive-get-descr))))))
1223 ;; -------------------------------------------------------------------------
1224 ;; Section: Operate
1225
1226 (defun archive-next-line (p)
1227   (interactive "p")
1228   (forward-line p)
1229   (or (eobp)
1230       (forward-char archive-file-name-indent)))
1231
1232 (defun archive-previous-line (p)
1233   (interactive "p")
1234   (archive-next-line (- p)))
1235
1236 (defun archive-chmod-entry (new-mode)
1237   "Change the protection bits associated with all marked or this member.
1238 The new protection bits can either be specified as an octal number or
1239 as a relative change like \"g+rw\" as for chmod(2)"
1240   (interactive "sNew mode (octal or relative): ")
1241   (if archive-read-only (error "Archive is read-only"))
1242   (let ((func (archive-name "chmod-entry")))
1243     (if (fboundp func)
1244         (progn
1245           (funcall func new-mode (archive-get-marked ?* t))
1246           (archive-resummarize))
1247       (error "Setting mode bits is not supported for this archive type"))))
1248
1249 (defun archive-chown-entry (new-uid)
1250   "Change the owner of all marked or this member."
1251   (interactive "nNew uid: ")
1252   (if archive-read-only (error "Archive is read-only"))
1253   (let ((func (archive-name "chown-entry")))
1254     (if (fboundp func)
1255         (progn
1256           (funcall func new-uid (archive-get-marked ?* t))
1257           (archive-resummarize))
1258       (error "Setting owner is not supported for this archive type"))))
1259
1260 (defun archive-chgrp-entry (new-gid)
1261   "Change the group of all marked or this member."
1262   (interactive "nNew gid: ")
1263   (if archive-read-only (error "Archive is read-only"))
1264   (let ((func (archive-name "chgrp-entry")))
1265     (if (fboundp func)
1266         (progn
1267           (funcall func new-gid (archive-get-marked ?* t))
1268           (archive-resummarize))
1269       (error "Setting group is not supported for this archive type"))))
1270
1271 (defun archive-expunge ()
1272   "Do the flagged deletions."
1273   (interactive)
1274   (let (files)
1275     (save-excursion
1276       (goto-char archive-file-list-start)
1277       (while (< (point) archive-file-list-end)
1278         (if (= (following-char) ?D)
1279             (setq files (cons (aref (archive-get-descr) 0) files)))
1280         (forward-line 1)))
1281     (setq files (nreverse files))
1282     (and files
1283          (or (not archive-read-only)
1284              (error "Archive is read-only"))
1285          (or (yes-or-no-p (format "Really delete %d member%s? "
1286                                   (length files)
1287                                   (if (null (cdr files)) "" "s")))
1288              (error "Operation aborted"))
1289          (let ((archive (archive-maybe-copy (buffer-file-name)))
1290                (expunger (archive-name "expunge")))
1291            (if (fboundp expunger)
1292                (funcall expunger archive files)
1293              (archive-*-expunge archive files (symbol-value expunger)))
1294            (archive-maybe-update nil)
1295            (if archive-remote
1296                (archive-resummarize)
1297              (revert-buffer))))))
1298
1299 (defun archive-*-expunge (archive files command)
1300   (apply 'call-process
1301          (car command)
1302          nil
1303          nil
1304          nil
1305          (append (cdr command) (cons archive files))))
1306
1307 (defun archive-rename-entry (newname)
1308   "Change the name associated with this entry in the tar file."
1309   (interactive "sNew name: ")
1310   (if archive-read-only (error "Archive is read-only"))
1311   (if (string= newname "")
1312       (error "Archive members may not be given empty names"))
1313   (let ((func (archive-name "rename-entry"))
1314         (descr (archive-get-descr)))
1315     (if (fboundp func)
1316         (progn
1317           (funcall func (buffer-file-name)
1318                    (if enable-multibyte-characters
1319                        (encode-coding-string newname file-name-coding-system)
1320                      newname)
1321                    descr)
1322           (archive-resummarize))
1323       (error "Renaming is not supported for this archive type"))))
1324
1325 ;; Revert the buffer and recompute the dired-like listing.
1326 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1327   (let ((no (archive-get-lineno)))
1328     (setq archive-files nil)
1329     (let ((revert-buffer-function nil)
1330           (coding-system-for-read 'no-conversion))
1331       (set-buffer-multibyte nil)
1332       (revert-buffer t t))
1333     (archive-mode)
1334     (goto-char archive-file-list-start)
1335     (archive-next-line no)))
1336
1337 (defun archive-undo ()
1338   "Undo in an archive buffer.
1339 This doesn't recover lost files, it just undoes changes in the buffer itself."
1340   (interactive)
1341   (let (buffer-read-only)
1342     (undo)))
1343 ;; -------------------------------------------------------------------------
1344 ;; Section: Arc Archives
1345
1346 (defun archive-arc-summarize ()
1347   (let ((p 1)
1348         (totalsize 0)
1349         (maxlen 8)
1350         files
1351         visual)
1352     (while (and (< (+ p 29) (point-max))
1353                 (= (char-after p) ?\C-z)
1354                 (> (char-after (1+ p)) 0))
1355       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1356              (fnlen   (or (string-match "\0" namefld) 13))
1357              (efnname (substring namefld 0 fnlen))
1358              (csize   (archive-l-e (+ p 15) 4))
1359              (moddate (archive-l-e (+ p 19) 2))
1360              (modtime (archive-l-e (+ p 21) 2))
1361              (ucsize  (archive-l-e (+ p 25) 4))
1362              (fiddle  (string= efnname (upcase efnname)))
1363              (ifnname (if fiddle (downcase efnname) efnname))
1364              (text    (format "  %8d  %-11s  %-8s  %s"
1365                               ucsize
1366                               (archive-dosdate moddate)
1367                               (archive-dostime modtime)
1368                               ifnname)))
1369         (setq maxlen (max maxlen fnlen)
1370               totalsize (+ totalsize ucsize)
1371               visual (cons (vector text
1372                                    (- (length text) (length ifnname))
1373                                    (length text))
1374                            visual)
1375               files (cons (vector efnname ifnname fiddle nil (1- p))
1376                           files)
1377               p (+ p 29 csize))))
1378     (goto-char (point-min))
1379     (let ((dash (concat "- --------  -----------  --------  "
1380                         (make-string maxlen ?-)
1381                         "\n")))
1382       (insert "M   Length  Date         Time      File\n"
1383               dash)
1384       (archive-summarize-files (nreverse visual))
1385       (insert dash
1386               (format "  %8d                         %d file%s"
1387                       totalsize
1388                       (length files)
1389                       (if (= 1 (length files)) "" "s"))
1390               "\n"))
1391     (apply 'vector (nreverse files))))
1392
1393 (defun archive-arc-rename-entry (archive newname descr)
1394   (if (string-match "[:\\\\/]" newname)
1395       (error "File names in arc files must not contain a directory component"))
1396   (if (> (length newname) 12)
1397       (error "File names in arc files are limited to 12 characters"))
1398   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1399                                          (length newname))))
1400         buffer-read-only)
1401     (save-restriction
1402       (save-excursion
1403         (widen)
1404         (set-buffer-multibyte nil)
1405         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1406         (delete-char 13)
1407         (insert name)))))
1408 ;; -------------------------------------------------------------------------
1409 ;; Section: Lzh Archives
1410
1411 (defun archive-lzh-summarize ()
1412   (let ((p 1)
1413         (totalsize 0)
1414         (maxlen 8)
1415         files
1416         visual)
1417     (while (progn (goto-char p)         ;beginning of a base header.
1418                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1419       (let* ((hsize   (char-after p))   ;size of the base header (level 0 and 1)
1420              (csize   (archive-l-e (+ p 7) 4)) ;size of a compressed file to follow.
1421              (ucsize  (archive-l-e (+ p 11) 4)) ;size of an uncompressed file.
1422              (time1   (archive-l-e (+ p 15) 2)) ;date/time (MSDOS format in level 0, 1 headers
1423              (time2   (archive-l-e (+ p 17) 2)) ;and UNIX format in level 2 header.)
1424              (hdrlvl  (char-after (+ p 20))) ;header level
1425              thsize             ;total header size (base + extensions)
1426              fnlen efnname fiddle ifnname width p2 creator
1427              neh        ;beginning of next extension header (level 1 and 2)
1428              mode modestr uid gid text dir prname
1429              gname uname modtime moddate)
1430         (if (= hdrlvl 3) (error "can't handle lzh level 3 header type"))
1431         (when (or (= hdrlvl 0) (= hdrlvl 1))
1432           (setq fnlen   (char-after (+ p 21))) ;filename length
1433           (setq efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen)))) ;filename from offset 22
1434                         (if file-name-coding-system
1435                             (decode-coding-string str file-name-coding-system)
1436                           (string-as-multibyte str))))
1437           (setq p2      (+ p 22 fnlen))) ;
1438         (if (= hdrlvl 1)
1439             (progn              ;specific to level 1 header
1440               (setq creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1441               (setq neh (+ p2 3)))
1442           (if (= hdrlvl 2)
1443               (progn            ;specific to level 2 header
1444                 (setq creator (char-after (+ p 23)) )
1445                 (setq neh (+ p 24)))))
1446         (if neh         ;if level 1 or 2 we expect extension headers to follow
1447             (let* ((ehsize (archive-l-e neh 2)) ;size of the extension header
1448                    (etype (char-after (+ neh 2)))) ;extension type
1449               (while (not (= ehsize 0))
1450                   (cond
1451                  ((= etype 1)   ;file name
1452                   (let ((i (+ neh 3)))
1453                     (while (< i (+ neh ehsize))
1454                       (setq efnname (concat efnname (char-to-string (char-after i))))
1455                       (setq i (1+ i)))))
1456                  ((= etype 2)   ;directory name
1457                   (let ((i (+ neh 3)))
1458                     (while (< i (+ neh ehsize))
1459                                     (setq dir (concat dir
1460                                                        (if (= (char-after i)
1461                                                               255)
1462                                                            "/"
1463                                                          (char-to-string
1464                                                           (char-after i)))))
1465                                     (setq i (1+ i)))))
1466                  ((= etype 80)          ;Unix file permission
1467                   (setq mode (archive-l-e (+ neh 3) 2)))
1468                  ((= etype 81)          ;UNIX file group/user ID
1469                   (progn (setq uid (archive-l-e (+ neh 3) 2))
1470                          (setq gid (archive-l-e (+ neh 5) 2))))
1471                  ((= etype 82)          ;UNIX file group name
1472                   (let ((i (+ neh 3)))
1473                     (while (< i (+ neh ehsize))
1474                       (setq gname (concat gname (char-to-string (char-after i))))
1475                       (setq i (1+ i)))))
1476                  ((= etype 83)          ;UNIX file user name
1477                   (let ((i (+ neh 3)))
1478                     (while (< i (+ neh ehsize))
1479                       (setq uname (concat uname (char-to-string (char-after i))))
1480                       (setq i (1+ i)))))
1481                    )
1482                 (setq neh (+ neh ehsize))
1483                 (setq ehsize (archive-l-e neh 2))
1484                 (setq etype (char-after (+ neh 2))))
1485               ;;get total header size for level 1 and 2 headers
1486               (setq thsize (- neh p))))
1487         (if (= hdrlvl 0)  ;total header size
1488             (setq thsize hsize))
1489         (setq fiddle  (if efnname (string= efnname (upcase efnname))))
1490         (setq ifnname (if fiddle (downcase efnname) efnname))
1491         (setq prname (if dir (concat dir ifnname) ifnname))
1492         (setq width (if prname (string-width prname) 0))
1493         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1494         (setq moddate (if (= hdrlvl 2)
1495                           (archive-unixdate time1 time2) ;level 2 header in UNIX format
1496                         (archive-dosdate time2))) ;level 0 and 1 header in DOS format
1497         (setq modtime (if (= hdrlvl 2)
1498                           (archive-unixtime time1 time2)
1499                         (archive-dostime time1)))
1500         (setq text    (if archive-alternate-display
1501                           (format "  %8d  %5S  %5S  %s"
1502                                   ucsize
1503                                   (or uid "?")
1504                                   (or gid "?")
1505                                   ifnname)
1506                         (format "  %10s  %8d  %-11s  %-8s  %s"
1507                                 modestr
1508                                 ucsize
1509                                 moddate
1510                                 modtime
1511                                 prname)))
1512         (setq maxlen (max maxlen width)
1513               totalsize (+ totalsize ucsize)
1514               visual (cons (vector text
1515                                    (- (length text) (length prname))
1516                                    (length text))
1517                            visual)
1518               files (cons (vector prname ifnname fiddle mode (1- p))
1519                           files)
1520               p (+ p thsize 2 csize))))
1521     (goto-char (point-min))
1522     (set-buffer-multibyte default-enable-multibyte-characters)
1523     (let ((dash (concat (if archive-alternate-display
1524                             "- --------  -----  -----  "
1525                           "- ----------  --------  -----------  --------  ")
1526                         (make-string maxlen ?-)
1527                         "\n"))
1528           (header (if archive-alternate-display
1529                        "M   Length    Uid    Gid  File\n"
1530                     "M   Filemode    Length  Date         Time      File\n"))
1531           (sumline (if archive-alternate-display
1532                        "  %8d                %d file%s"
1533                      "              %8d                         %d file%s")))
1534       (insert header dash)
1535       (archive-summarize-files (nreverse visual))
1536       (insert dash
1537               (format sumline
1538                       totalsize
1539                       (length files)
1540                       (if (= 1 (length files)) "" "s"))
1541               "\n"))
1542     (apply 'vector (nreverse files))))
1543
1544 (defconst archive-lzh-alternate-display t)
1545
1546 (defun archive-lzh-extract (archive name)
1547   (archive-extract-by-stdout archive name archive-lzh-extract))
1548
1549 (defun archive-lzh-resum (p count)
1550   (let ((sum 0))
1551     (while (> count 0)
1552       (setq count (1- count)
1553             sum (+ sum (char-after p))
1554             p (1+ p)))
1555     (logand sum 255)))
1556
1557 (defun archive-lzh-rename-entry (archive newname descr)
1558   (save-restriction
1559     (save-excursion
1560       (widen)
1561       (set-buffer-multibyte nil)
1562       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1563              (oldhsize (char-after p))
1564              (oldfnlen (char-after (+ p 21)))
1565              (newfnlen (length newname))
1566              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1567              buffer-read-only)
1568         (if (> newhsize 255)
1569             (error "The file name is too long"))
1570         (goto-char (+ p 21))
1571         (delete-char (1+ oldfnlen))
1572         (insert newfnlen newname)
1573         (goto-char p)
1574         (delete-char 2)
1575         (insert newhsize (archive-lzh-resum p newhsize))))))
1576
1577 (defun archive-lzh-ogm (newval files errtxt ofs)
1578   (save-restriction
1579     (save-excursion
1580       (widen)
1581       (set-buffer-multibyte nil)
1582       (while files
1583         (let* ((fil (car files))
1584                (p (+ archive-proper-file-start (aref fil 4)))
1585                (hsize   (char-after p))
1586                (fnlen   (char-after (+ p 21)))
1587                (p2      (+ p 22 fnlen))
1588                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1589                buffer-read-only)
1590           (if (= creator ?U)
1591               (progn
1592                 (or (numberp newval)
1593                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1594                 (goto-char (+ p2 ofs))
1595                 (delete-char 2)
1596                 (insert (logand newval 255) (lsh newval -8))
1597                 (goto-char (1+ p))
1598                 (delete-char 1)
1599                 (insert (archive-lzh-resum (1+ p) hsize)))
1600             (message "Member %s does not have %s field"
1601                      (aref fil 1) errtxt)))
1602         (setq files (cdr files))))))
1603
1604 (defun archive-lzh-chown-entry (newuid files)
1605   (archive-lzh-ogm newuid files "an uid" 10))
1606
1607 (defun archive-lzh-chgrp-entry (newgid files)
1608   (archive-lzh-ogm newgid files "a gid" 12))
1609
1610 (defun archive-lzh-chmod-entry (newmode files)
1611   (archive-lzh-ogm
1612    ;; This should work even though newmode will be dynamically accessed.
1613    (function (lambda (old) (archive-calc-mode old newmode t)))
1614    files "a unix-style mode" 8))
1615 ;; -------------------------------------------------------------------------
1616 ;; Section: Zip Archives
1617
1618 (defun archive-zip-summarize ()
1619   (goto-char (- (point-max) (- 22 18)))
1620   (search-backward-regexp "[P]K\005\006")
1621   (let ((p (+ (point-min) (archive-l-e (+ (point) 16) 4)))
1622         (maxlen 8)
1623         (totalsize 0)
1624         files
1625         visual)
1626     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1627       (let* ((creator (char-after (+ p 5)))
1628              (method  (archive-l-e (+ p 10) 2))
1629              (modtime (archive-l-e (+ p 12) 2))
1630              (moddate (archive-l-e (+ p 14) 2))
1631              (ucsize  (archive-l-e (+ p 24) 4))
1632              (fnlen   (archive-l-e (+ p 28) 2))
1633              (exlen   (archive-l-e (+ p 30) 2))
1634              (fclen   (archive-l-e (+ p 32) 2))
1635              (lheader (archive-l-e (+ p 42) 4))
1636              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1637                         (if file-name-coding-system
1638                             (decode-coding-string str file-name-coding-system)
1639                           (string-as-multibyte str))))
1640              (isdir   (and (= ucsize 0)
1641                            (string= (file-name-nondirectory efnname) "")))
1642              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1643                              (archive-l-e (+ p 40) 2))
1644                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1645                              (logior ?\444
1646                                      (if isdir (logior 16384 ?\111) 0)
1647                                      (if (zerop
1648                                           (logand 1 (char-after (+ p 38))))
1649                                          ?\222 0)))
1650                             (t nil)))
1651              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1652              (fiddle  (and archive-zip-case-fiddle
1653                            (not (not (memq creator '(0 2 4 5 9))))
1654                            (string= (upcase efnname) efnname)))
1655              (ifnname (if fiddle (downcase efnname) efnname))
1656              (width (string-width ifnname))
1657              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1658                               modestr
1659                               ucsize
1660                               (archive-dosdate moddate)
1661                               (archive-dostime modtime)
1662                               ifnname)))
1663         (setq maxlen (max maxlen width)
1664               totalsize (+ totalsize ucsize)
1665               visual (cons (vector text
1666                                    (- (length text) (length ifnname))
1667                                    (length text))
1668                            visual)
1669               files (cons (if isdir
1670                               nil
1671                             (vector efnname ifnname fiddle mode
1672                                     (list (1- p) lheader)))
1673                           files)
1674               p (+ p 46 fnlen exlen fclen))))
1675     (goto-char (point-min))
1676     (let ((dash (concat "- ----------  --------  -----------  --------  "
1677                         (make-string maxlen ?-)
1678                         "\n")))
1679       (insert "M Filemode      Length  Date         Time      File\n"
1680               dash)
1681       (archive-summarize-files (nreverse visual))
1682       (insert dash
1683               (format "              %8d                         %d file%s"
1684                       totalsize
1685                       (length files)
1686                       (if (= 1 (length files)) "" "s"))
1687               "\n"))
1688     (apply 'vector (nreverse files))))
1689
1690 (defun archive-zip-extract (archive name)
1691   (if (equal (car archive-zip-extract) "pkzip")
1692       (archive-*-extract archive name archive-zip-extract)
1693     (archive-extract-by-stdout archive name archive-zip-extract)))
1694
1695 (defun archive-zip-write-file-member (archive descr)
1696   (archive-*-write-file-member
1697    archive
1698    descr
1699    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1700
1701 (defun archive-zip-chmod-entry (newmode files)
1702   (save-restriction
1703     (save-excursion
1704       (widen)
1705       (set-buffer-multibyte nil)
1706       (while files
1707         (let* ((fil (car files))
1708                (p (+ archive-proper-file-start (car (aref fil 4))))
1709                (creator (char-after (+ p 5)))
1710                (oldmode (aref fil 3))
1711                (newval  (archive-calc-mode oldmode newmode t))
1712                buffer-read-only)
1713           (cond ((memq creator '(2 3)) ; Unix + VMS
1714                  (goto-char (+ p 40))
1715                  (delete-char 2)
1716                  (insert (logand newval 255) (lsh newval -8)))
1717                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1718                  (goto-char (+ p 38))
1719                  (insert (logior (logand (char-after (point)) 254)
1720                                  (logand (logxor 1 (lsh newval -7)) 1)))
1721                  (delete-char 1))
1722                 (t (message "Don't know how to change mode for this member"))))
1723         (setq files (cdr files))))))
1724 ;; -------------------------------------------------------------------------
1725 ;; Section: Zoo Archives
1726
1727 (defun archive-zoo-summarize ()
1728   (let ((p (1+ (archive-l-e 25 4)))
1729         (maxlen 8)
1730         (totalsize 0)
1731         files
1732         visual)
1733     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1734                 (> (archive-l-e (+ p 6) 4) 0))
1735       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1736              (moddate (archive-l-e (+ p 14) 2))
1737              (modtime (archive-l-e (+ p 16) 2))
1738              (ucsize  (archive-l-e (+ p 20) 4))
1739              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1740              (dirtype (char-after (+ p 4)))
1741              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1742              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1743              (fnlen   (or (string-match "\0" namefld) 13))
1744              (efnname (let ((str
1745                              (concat
1746                               (if (> ldirlen 0)
1747                                   (concat (buffer-substring
1748                                            (+ p 58 lfnlen)
1749                                            (+ p 58 lfnlen ldirlen -1))
1750                                           "/")
1751                                 "")
1752                               (if (> lfnlen 0)
1753                                   (buffer-substring (+ p 58)
1754                                                     (+ p 58 lfnlen -1))
1755                                 (substring namefld 0 fnlen)))))
1756                         (if file-name-coding-system
1757                             (decode-coding-string str file-name-coding-system)
1758                           (string-as-multibyte str))))
1759              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1760              (ifnname (if fiddle (downcase efnname) efnname))
1761              (width (string-width ifnname))
1762              (text    (format "  %8d  %-11s  %-8s  %s"
1763                               ucsize
1764                               (archive-dosdate moddate)
1765                               (archive-dostime modtime)
1766                               ifnname)))
1767         (setq maxlen (max maxlen width)
1768               totalsize (+ totalsize ucsize)
1769               visual (cons (vector text
1770                                    (- (length text) (length ifnname))
1771                                    (length text))
1772                            visual)
1773               files (cons (vector efnname ifnname fiddle nil (1- p))
1774                           files)
1775               p next)))
1776     (goto-char (point-min))
1777     (let ((dash (concat "- --------  -----------  --------  "
1778                         (make-string maxlen ?-)
1779                         "\n")))
1780       (insert "M   Length  Date         Time      File\n"
1781               dash)
1782       (archive-summarize-files (nreverse visual))
1783       (insert dash
1784               (format "  %8d                         %d file%s"
1785                       totalsize
1786                       (length files)
1787                       (if (= 1 (length files)) "" "s"))
1788               "\n"))
1789     (apply 'vector (nreverse files))))
1790
1791 (defun archive-zoo-extract (archive name)
1792   (archive-extract-by-stdout archive name archive-zoo-extract))
1793 ;; -------------------------------------------------------------------------
1794 ;; This line was a mistake; it is kept now for compatibility.
1795 ;; rms  15 Oct 98
1796 (provide 'archive-mode)
1797
1798 (provide 'arc-mode)
1799
1800 ;;; arc-mode.el ends here