lisp/tmm.el

   1 ;;; tmm.el --- text mode access to menu-bar
   2
   3 ;; Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Ilya Zakharevich <ilya@math.mps.ohio-state.edu>
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; To use this package add
  28
  29 ;; (autoload 'tmm-menubar 'tmm "Text mode substitute for menubar" t)
  30 ;; (global-set-key [f10] 'tmm-menubar)
  31 ;; to your .emacs file. You can also add your own access to different
  32 ;; menus available in Window System Emacs modeling definition after
  33 ;; tmm-menubar.
  34
  35 ;;; Code:
  36
  37 (require 'electric)
  38
  39 (defgroup tmm nil
  40   "Text mode access to menu-bar."
  41   :prefix "tmm-"
  42   :group 'menu)
  43
  44 ;;; The following will be localized, added only to pacify the compiler.
  45 (defvar tmm-short-cuts)
  46 (defvar tmm-old-mb-map nil)
  47 (defvar tmm-old-comp-map)
  48 (defvar tmm-c-prompt)
  49 (defvar tmm-km-list)
  50 (defvar tmm-next-shortcut-digit)
  51 (defvar tmm-table-undef)
  52
  53 ;;;###autoload (define-key global-map "\M-`" 'tmm-menubar)
  54 ;;;###autoload (define-key global-map [f10] 'tmm-menubar)
  55 ;;;###autoload (define-key global-map [menu-bar mouse-1] 'tmm-menubar-mouse)
  56
  57 ;;;###autoload
  58 (defun tmm-menubar (&optional x-position)
  59   "Text-mode emulation of looking and choosing from a menubar.
  60 See the documentation for `tmm-prompt'.
  61 X-POSITION, if non-nil, specifies a horizontal position within the menu bar;
  62 we make that menu bar item (the one at that position) the default choice."
  63   (interactive)
  64   (run-hooks 'menu-bar-update-hook)
  65   ;; Obey menu-bar-final-items; put those items last.
  66   (let ((menu-bar (tmm-get-keybind [menu-bar]))
  67         menu-bar-item)
  68     (let ((list menu-bar-final-items))
  69       (while list
  70         (let ((item (car list)))
  71           ;; ITEM is the name of an item that we want to put last.
  72           ;; Find it in MENU-BAR and move it to the end.
  73           (let ((this-one (assq item menu-bar)))
  74             (setq menu-bar (append (delq this-one menu-bar)
  75                                    (list this-one)))))
  76         (setq list (cdr list))))
  77     (if x-position
  78         (let ((tail menu-bar)
  79               this-one
  80               (column 0))
  81           (while (and tail (< column x-position))
  82             (setq this-one (car tail))
  83             (if (and (consp (car tail))
  84                      (consp (cdr (car tail)))
  85                      (stringp (nth 1 (car tail))))
  86                 (setq column (+ column
  87                                 (length (nth 1 (car tail)))
  88                                 1)))
  89             (setq tail (cdr tail)))
  90           (setq menu-bar-item (car this-one))))
  91     (tmm-prompt menu-bar nil menu-bar-item)))
  92
  93 ;;;###autoload
  94 (defun tmm-menubar-mouse (event)
  95   "Text-mode emulation of looking and choosing from a menubar.
  96 This command is used when you click the mouse in the menubar
  97 on a console which has no window system but does have a mouse.
  98 See the documentation for `tmm-prompt'."
  99   (interactive "e")
 100   (tmm-menubar (car (posn-x-y (event-start event)))))
 101
 102 (defcustom tmm-mid-prompt "==>"
 103   "*String to insert between shortcut and menu item.
 104 If nil, there will be no shortcuts. It should not consist only of spaces,
 105 or else the correct item might not be found in the `*Completions*' buffer."
 106   :type 'string
 107   :group 'tmm)
 108
 109 (defvar tmm-mb-map nil
 110   "A place to store minibuffer map.")
 111
 112 (defcustom tmm-completion-prompt
 113   "Press PageUp Key to reach this buffer from the minibuffer.
 114 Alternatively, you can use Up/Down keys (or your History keys) to change
 115 the item in the minibuffer, and press RET when you are done, or press the
 116 marked letters to pick up your choice.  Type C-g or ESC ESC ESC to cancel.
 117 "
 118   "*Help text to insert on the top of the completion buffer.
 119 To save space, you can set this to nil,
 120 in which case the standard introduction text is deleted too."
 121   :type '(choice string (const nil))
 122   :group 'tmm)
 123
 124 (defcustom tmm-shortcut-style '(downcase upcase)
 125   "*What letters to use as menu shortcuts.
 126 Must be either one of the symbols `downcase' or `upcase',
 127 or else a list of the two in the order you prefer."
 128   :type '(choice (const downcase)
 129                  (const upcase)
 130                  (repeat (choice (const downcase) (const upcase))))
 131   :group 'tmm)
 132
 133 (defcustom tmm-shortcut-words 2
 134   "*How many successive words to try for shortcuts, nil means all.
 135 If you use only one of `downcase' or `upcase' for `tmm-shortcut-style',
 136 specify nil for this variable."
 137   :type '(choice integer (const nil))
 138   :group 'tmm)
 139
 140 ;;;###autoload
 141 (defun tmm-prompt (menu &optional in-popup default-item)
 142   "Text-mode emulation of calling the bindings in keymap.
 143 Creates a text-mode menu of possible choices.  You can access the elements
 144 in the menu in two ways:
 145    *)  via history mechanism from minibuffer;
 146    *)  Or via completion-buffer that is automatically shown.
 147 The last alternative is currently a hack, you cannot use mouse reliably.
 148
 149 MENU is like the MENU argument to `x-popup-menu': either a
 150 keymap or an alist of alists.
 151 DEFAULT-ITEM, if non-nil, specifies an initial default choice.
 152 Its value should be an event that has a binding in MENU."
 153   ;; If the optional argument IN-POPUP is t,
 154   ;; then MENU is an alist of elements of the form (STRING . VALUE).
 155   ;; That is used for recursive calls only.
 156   (let ((gl-str "Menu bar")  ;; The menu bar itself is not a menu keymap
 157                                         ; so it doesn't have a name.
 158         tmm-km-list out history history-len tmm-table-undef tmm-c-prompt
 159         tmm-old-mb-map tmm-old-comp-map tmm-short-cuts
 160         chosen-string choice
 161         (not-menu (not (keymapp menu))))
 162     (run-hooks 'activate-menubar-hook)
 163     ;; Compute tmm-km-list from MENU.
 164     ;; tmm-km-list is an alist of (STRING . MEANING).
 165     ;; It has no other elements.
 166     ;; The order of elements in tmm-km-list is the order of the menu bar.
 167     (mapcar (function (lambda (elt)
 168                         (if (stringp elt)
 169                             (setq gl-str elt)
 170                           (and (listp elt) (tmm-get-keymap elt not-menu)))))
 171             menu)
 172     ;; Choose an element of tmm-km-list; put it in choice.
 173     (if (and not-menu (= 1 (length tmm-km-list)))
 174         ;; If this is the top-level of an x-popup-menu menu,
 175         ;; and there is just one pane, choose that one silently.
 176         ;; This way we only ask the user one question,
 177         ;; for which element of that pane.
 178         (setq choice (cdr (car tmm-km-list)))
 179       (unless tmm-km-list
 180         (error "Empty menu reached"))
 181       (and tmm-km-list
 182            (let ((index-of-default 0))
 183              (if tmm-mid-prompt
 184                  (setq tmm-km-list (tmm-add-shortcuts tmm-km-list))
 185                t)
 186              ;; Find the default item's index within the menu bar.
 187              ;; We use this to decide the initial minibuffer contents
 188              ;; and initial history position.
 189              (if default-item
 190                  (let ((tail menu))
 191                    (while (and tail
 192                                (not (eq (car-safe (car tail)) default-item)))
 193                      ;; Be careful to count only the elements of MENU
 194                      ;; that actually constitute menu bar items.
 195                      (if (and (consp (car tail))
 196                               (or (stringp (car-safe (cdr (car tail))))
 197                                   (eq (car-safe (cdr (car tail))) 'menu-item)))
 198                          (setq index-of-default (1+ index-of-default)))
 199                      (setq tail (cdr tail)))))
 200              (setq history (reverse (mapcar 'car tmm-km-list)))
 201              (setq history-len (length history))
 202              (setq history (append history history history history))
 203              (setq tmm-c-prompt (nth (- history-len 1 index-of-default) history))
 204              (add-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 205              (save-excursion
 206                (unwind-protect
 207                    (setq out
 208                          (completing-read
 209                           (concat gl-str " (up/down to change, PgUp to menu): ")
 210                           tmm-km-list nil t nil
 211                           (cons 'history (- (* 2 history-len) index-of-default))))
 212                  (save-excursion
 213                    (remove-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 214                    (if (get-buffer "*Completions*")
 215                        (progn
 216                          (set-buffer "*Completions*")
 217                          (use-local-map tmm-old-comp-map)
 218                          (bury-buffer (current-buffer)))))
 219                  ))))
 220       (setq choice (cdr (assoc out tmm-km-list)))
 221       (and (null choice)
 222            (> (length out) (length tmm-c-prompt))
 223            (string= (substring out 0 (length tmm-c-prompt)) tmm-c-prompt)
 224            (setq out (substring out (length tmm-c-prompt))
 225                  choice (cdr (assoc out tmm-km-list))))
 226       (and (null choice) out
 227            (setq out (try-completion out tmm-km-list)
 228                  choice (cdr (assoc  out tmm-km-list)))))
 229     ;; CHOICE is now (STRING . MEANING).  Separate the two parts.
 230     (setq chosen-string (car choice))
 231     (setq choice (cdr choice))
 232     (cond (in-popup
 233            ;; We just did the inner level of a -popup menu.
 234            choice)
 235           ;; We just did the outer level.  Do the inner level now.
 236           (not-menu (tmm-prompt choice t))
 237           ;; We just handled a menu keymap and found another keymap.
 238           ((keymapp choice)
 239            (if (symbolp choice)
 240                (setq choice (indirect-function choice)))
 241            (condition-case nil
 242                (require 'mouse)
 243              (error nil))
 244            (condition-case nil
 245                (x-popup-menu nil choice) ; Get the shortcuts
 246              (error nil))
 247            (tmm-prompt choice))
 248           ;; We just handled a menu keymap and found a command.
 249           (choice
 250            (if chosen-string
 251                (progn
 252                  (setq last-command-event chosen-string)
 253                  (call-interactively choice))
 254              choice)))))
 255
 256 (defun tmm-add-shortcuts (list)
 257   "Adds shortcuts to cars of elements of the list.
 258 Takes a list of lists with a string as car, returns list with
 259 shortcuts added to these cars.
 260 Stores a list of all the shortcuts in the free variable `tmm-short-cuts'."
 261   (let ((tmm-next-shortcut-digit ?0))
 262     (mapcar 'tmm-add-one-shortcut (reverse list))))
 263
 264 (defsubst tmm-add-one-shortcut (elt)
 265 ;; uses the free vars tmm-next-shortcut-digit and tmm-short-cuts
 266   (let* ((str (car elt))
 267         (paren (string-match "(" str))
 268         (pos 0) (word 0) char)
 269     (catch 'done                        ; ??? is this slow?
 270       (while (and (or (not tmm-shortcut-words) ; no limit on words
 271                       (< word tmm-shortcut-words)) ; try n words
 272                   (setq pos (string-match "\\w+" str pos)) ; get next word
 273                   (not (and paren (> pos paren)))) ; don't go past "(binding.."
 274         (if (or (= pos 0)
 275                 (/= (aref str (1- pos)) ?.)) ; avoid file extensions
 276             (let ((shortcut-style
 277                    (if (listp tmm-shortcut-style) ; convert to list
 278                        tmm-shortcut-style
 279                      (list tmm-shortcut-style))))
 280               (while shortcut-style     ; try upcase and downcase variants
 281                 (setq char (funcall (car shortcut-style) (aref str pos)))
 282                 (if (not (memq char tmm-short-cuts)) (throw 'done char))
 283                 (setq shortcut-style (cdr shortcut-style)))))
 284         (setq word (1+ word))
 285         (setq pos (match-end 0)))
 286       (while (<= tmm-next-shortcut-digit ?9) ; no letter shortcut, pick a digit
 287         (setq char tmm-next-shortcut-digit)
 288         (setq tmm-next-shortcut-digit (1+ tmm-next-shortcut-digit))
 289         (if (not (memq char tmm-short-cuts)) (throw 'done char)))
 290       (setq char nil))
 291     (if char (setq tmm-short-cuts (cons char tmm-short-cuts)))
 292     (cons (concat (if char (concat (char-to-string char) tmm-mid-prompt)
 293                     ;; keep them lined up in columns
 294                     (make-string (1+ (length tmm-mid-prompt)) ?\ ))
 295                   str)
 296           (cdr elt))))
 297
 298 ;; This returns the old map.
 299 (defun tmm-define-keys (minibuffer)
 300   (let ((map (make-sparse-keymap)))
 301     (suppress-keymap map t)
 302     (mapcar
 303      (function
 304       (lambda (c)
 305         (if (listp tmm-shortcut-style)
 306             (define-key map (char-to-string c) 'tmm-shortcut)
 307           ;; only one kind of letters are shortcuts, so map both upcase and
 308           ;; downcase input to the same
 309           (define-key map (char-to-string (downcase c)) 'tmm-shortcut)
 310           (define-key map (char-to-string (upcase c)) 'tmm-shortcut))))
 311      tmm-short-cuts)
 312     (if minibuffer
 313         (progn
 314           (define-key map [pageup] 'tmm-goto-completions)
 315           (define-key map [prior] 'tmm-goto-completions)
 316           (define-key map "\ev" 'tmm-goto-completions)
 317           (define-key map "\C-n" 'next-history-element)
 318           (define-key map "\C-p" 'previous-history-element)))
 319     (prog1 (current-local-map)
 320       (use-local-map (append map (current-local-map))))))
 321
 322 (defun tmm-completion-delete-prompt ()
 323   (set-buffer standard-output)
 324   (goto-char 1)
 325   (delete-region 1 (search-forward "Possible completions are:\n")))
 326
 327 (defun tmm-add-prompt ()
 328   (remove-hook 'minibuffer-setup-hook 'tmm-add-prompt)
 329   (make-local-hook 'minibuffer-exit-hook)
 330   (add-hook 'minibuffer-exit-hook 'tmm-delete-map nil t)
 331   (let ((win (selected-window)))
 332     (setq tmm-old-mb-map (tmm-define-keys t))
 333     ;; Get window and hide it for electric mode to get correct size
 334     (save-window-excursion
 335       (let ((completions
 336              (mapcar 'car minibuffer-completion-table)))
 337         (or tmm-completion-prompt
 338             (add-hook 'completion-setup-hook
 339                       'tmm-completion-delete-prompt 'append))
 340         (with-output-to-temp-buffer "*Completions*"
 341           (display-completion-list completions))
 342         (remove-hook 'completion-setup-hook 'tmm-completion-delete-prompt))
 343       (if tmm-completion-prompt
 344           (progn
 345             (set-buffer "*Completions*")
 346             (goto-char 1)
 347             (insert tmm-completion-prompt)))
 348       )
 349     (save-selected-window
 350       (other-window 1)                  ; Electric-pop-up-window does
 351                                         ; not work in minibuffer
 352       (Electric-pop-up-window "*Completions*")
 353       (with-current-buffer "*Completions*"
 354         (setq tmm-old-comp-map (tmm-define-keys nil))))
 355
 356     (insert tmm-c-prompt)))
 357
 358 (defun tmm-delete-map ()
 359   (remove-hook 'minibuffer-exit-hook 'tmm-delete-map t)
 360   (if tmm-old-mb-map
 361       (use-local-map tmm-old-mb-map)))
 362
 363 (defun tmm-shortcut ()
 364   "Choose the shortcut that the user typed."
 365   (interactive)
 366   (let ((c last-command-char) s)
 367     (if (symbolp tmm-shortcut-style)
 368         (setq c (funcall tmm-shortcut-style c)))
 369     (if (memq c tmm-short-cuts)
 370         (if (equal (buffer-name) "*Completions*")
 371             (progn
 372               (beginning-of-buffer)
 373               (re-search-forward
 374                (concat "\\(^\\|[ \t]\\)" (char-to-string c) tmm-mid-prompt))
 375               (choose-completion))
 376           ;; In minibuffer
 377           (delete-region (minibuffer-prompt-end) (point-max))
 378           (mapcar (lambda (elt)
 379                     (if (string=
 380                          (substring (car elt) 0
 381                                     (min (1+ (length tmm-mid-prompt))
 382                                          (length (car elt))))
 383                          (concat (char-to-string c) tmm-mid-prompt))
 384                         (setq s (car elt))))
 385                   tmm-km-list)
 386           (insert s)
 387           (exit-minibuffer)))))
 388
 389 (defun tmm-goto-completions ()
 390   (interactive)
 391   (let ((prompt-end (minibuffer-prompt-end)))
 392     (setq tmm-c-prompt (buffer-substring prompt-end (point-max)))
 393     (delete-region prompt-end (point-max)))
 394   (switch-to-buffer-other-window "*Completions*")
 395   (search-forward tmm-c-prompt)
 396   (search-backward tmm-c-prompt))
 397
 398 (defun tmm-get-keymap (elt &optional in-x-menu)
 399   "Prepends (DOCSTRING EVENT BINDING) to free variable `tmm-km-list'.
 400 The values are deduced from the argument ELT, that should be an
 401 element of keymap, an `x-popup-menu' argument, or an element of
 402 `x-popup-menu' argument (when IN-X-MENU is not-nil).
 403 This function adds the element only if it is not already present.
 404 It uses the free variable `tmm-table-undef' to keep undefined keys."
 405   (let (km str cache plist filter (event (car elt)))
 406     (setq elt (cdr elt))
 407     (if (eq elt 'undefined)
 408         (setq tmm-table-undef (cons (cons event nil) tmm-table-undef))
 409       (unless (assoc event tmm-table-undef)
 410         (cond ((if (listp elt)
 411                    (or (keymapp elt) (eq (car elt) 'lambda))
 412                  (fboundp elt))
 413                (setq km elt))
 414               ((if (listp (cdr-safe elt))
 415                    (or (keymapp (cdr-safe elt))
 416                        (eq (car (cdr-safe elt)) 'lambda))
 417                  (fboundp (cdr-safe elt)))
 418                (setq km (cdr elt))
 419                (and (stringp (car elt)) (setq str (car elt))))
 420               ((if (listp (cdr-safe (cdr-safe elt)))
 421                    (or (keymapp (cdr-safe (cdr-safe elt)))
 422                        (eq (car (cdr-safe (cdr-safe elt))) 'lambda))
 423                  (fboundp (cdr-safe (cdr-safe elt))))
 424                (setq km (cdr (cdr elt)))
 425                (and (stringp (car elt)) (setq str (car elt)))
 426                (and str
 427                     (stringp (cdr (car (cdr elt)))) ; keyseq cache
 428                     (setq cache (cdr (car (cdr elt))))
 429                     cache (setq str (concat str cache))))
 430               ((eq (car-safe elt) 'menu-item)
 431                (setq plist (cdr-safe (cdr-safe (cdr-safe elt))))
 432                (setq km (nth 2 elt))
 433                (setq str (nth 1 elt))
 434                (setq filter (plist-get plist :filter))
 435                (if filter
 436                    (setq km (funcall filter km)))
 437                (and str
 438                     (consp (nth 3 elt))
 439                     (stringp (cdr (nth 3 elt))) ; keyseq cache
 440                     (setq cache (cdr (nth 3 elt)))
 441                     cache
 442                     (setq str (concat str cache))))
 443               ((if (listp (cdr-safe (cdr-safe (cdr-safe elt))))
 444                    (or (keymapp (cdr-safe (cdr-safe (cdr-safe elt))))
 445                        (eq (car (cdr-safe (cdr-safe (cdr-safe elt)))) 'lambda))
 446                  (fboundp (cdr-safe (cdr-safe (cdr-safe elt)))))
 447                                          ; New style of easy-menu
 448                (setq km (cdr (cdr (cdr elt))))
 449                (and (stringp (car elt)) (setq str (car elt)))
 450                (and str
 451                     (stringp (cdr (car (cdr (cdr elt))))) ; keyseq cache
 452                     (setq cache (cdr (car (cdr (cdr elt)))))
 453                     cache (setq str (concat str cache))))
 454               ((stringp event)          ; x-popup or x-popup element
 455                (if (or in-x-menu (stringp (car-safe elt)))
 456                    (setq str event event nil km elt)
 457                  (setq str event event nil km (cons 'keymap elt))
 458                  ))))
 459       (and km (stringp km) (setq str km))
 460       ;; Verify that the command is enabled;
 461       ;; if not, don't mention it.
 462       (when (and km (symbolp km) (get km 'menu-enable))
 463         (unless (eval (get km 'menu-enable))
 464           (setq km nil)))
 465       (and km str
 466            (or (assoc str tmm-km-list)
 467                (setq tmm-km-list
 468                      (cons (cons str (cons event km)) tmm-km-list)))
 469            ))))
 470
 471 (defun tmm-get-keybind (keyseq)
 472   "Return the current binding of KEYSEQ, merging prefix definitions.
 473 If KEYSEQ is a prefix key that has local and global bindings,
 474 we merge them into a single keymap which shows the proper order of the menu.
 475 However, for the menu bar itself, the value does not take account
 476 of `menu-bar-final-items'."
 477   (let (allbind bind)
 478     (setq bind (key-binding keyseq))
 479     ;; If KEYSEQ is a prefix key, then BIND is either nil
 480     ;; or a symbol defined as a keymap (which satisfies keymapp).
 481     (if (keymapp bind)
 482         (setq bind nil))
 483     ;; If we have a non-keymap definition, return that.
 484     (or bind
 485         (progn
 486           ;; Otherwise, it is a prefix, so make a list of the subcommands.
 487           ;; Make a list of all the bindings in all the keymaps.
 488           (setq allbind (mapcar 'cdr (minor-mode-key-binding keyseq)))
 489           (setq allbind (cons (local-key-binding keyseq) allbind))
 490           (setq allbind (cons (global-key-binding keyseq) allbind))
 491           ;; Merge all the elements of ALLBIND into one keymap.
 492           (mapcar (lambda (in)
 493                     (if (and (symbolp in) (keymapp in))
 494                         (setq in (symbol-function in)))
 495                     (and in (keymapp in)
 496                          (if (keymapp bind)
 497                              (setq bind (nconc bind (copy-sequence (cdr in))))
 498                            (setq bind (copy-sequence in)))))
 499                   allbind)
 500           ;; Return that keymap.
 501           bind))))
 502
 503 (add-hook 'calendar-load-hook (lambda () (require 'cal-menu)))
 504
 505 (provide 'tmm)
 506
 507 ;;; tmm.el ends here