lisp/ielm.el

   1 ;;; ielm.el --- interaction mode for Emacs Lisp
   2
   3 ;; Copyright (C) 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: David Smith <maa036@lancaster.ac.uk>
   6 ;; Maintainer: FSF
   7 ;; Created: 25 Feb 1994
   8 ;; Keywords: lisp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Provides a nice interface to evaluating Emacs Lisp expressions.
  30 ;; Input is handled by the comint package, and output is passed
  31 ;; through the pretty-printer.
  32
  33 ;; To install: copy this file to a directory in your load-path, and
  34 ;; add the following line to your .emacs file:
  35 ;;
  36 ;;   (autoload 'ielm "ielm" "Start an inferior Emacs Lisp session" t)
  37 ;;
  38 ;; For completion to work, the comint.el from Emacs 19.23 is
  39 ;; required.  If you do not have it, or if you are running Lemacs,
  40 ;; also add the following code to your .emacs:
  41 ;;
  42 ;;    (setq ielm-mode-hook
  43 ;;          '(lambda nil
  44 ;;               (define-key ielm-map "\t"
  45 ;;                  '(lambda nil (interactive) (or (ielm-tab)
  46 ;;                                                 (lisp-complete-symbol))))))
  47
  48 ;; To start: M-x ielm.  Type C-h m in the *ielm* buffer for more info.
  49
  50 ;; The latest version is available by WWW from
  51 ;;      http://mathssun5.lancs.ac.uk:2080/~maa036/elisp/dir.html
  52 ;; or by anonymous FTP from
  53 ;;      /anonymous@wingra.stat.wisc.edu:pub/src/emacs-lisp/ielm.el.gz
  54 ;; or from the author: David M. Smith <maa036@lancaster.ac.uk>
  55
  56 ;;; Code:
  57
  58 (require 'comint)
  59 (require 'pp)
  60
  61 ;;; User variables
  62
  63 (defgroup ielm nil
  64   "Interaction mode for Emacs Lisp."
  65   :group 'lisp)
  66
  67
  68 (defcustom ielm-noisy t
  69   "*If non-nil, IELM will beep on error."
  70   :type 'boolean
  71   :group 'ielm)
  72
  73 (defvar ielm-prompt "ELISP> "
  74   "Prompt used in IELM.")
  75
  76 (defcustom ielm-dynamic-return t
  77   "*Controls whether \\<ielm-map>\\[ielm-return] has intelligent behaviour in IELM.
  78 If non-nil, \\[ielm-return] evaluates input for complete sexps, or inserts a newline
  79 and indents for incomplete sexps.  If nil, always inserts newlines."
  80   :type 'boolean
  81   :group 'ielm)
  82
  83 (defcustom ielm-dynamic-multiline-inputs t
  84   "*Force multiline inputs to start from column zero?
  85 If non-nil, after entering the first line of an incomplete sexp, a newline
  86 will be inserted after the prompt, moving the input to the next line.
  87 This gives more frame width for large indented sexps, and allows functions
  88 such as `edebug-defun' to work with such inputs."
  89   :type 'boolean
  90   :group 'ielm)
  91
  92 (defcustom ielm-mode-hook nil
  93   "*Hooks to be run when IELM (`inferior-emacs-lisp-mode') is started."
  94   :type 'hook
  95   :group 'ielm)
  96
  97 (defvar * nil
  98   "Most recent value evaluated in IELM.")
  99
 100 (defvar ** nil
 101   "Second-most-recent value evaluated in IELM.")
 102
 103 (defvar *** nil
 104   "Third-most-recent value evaluated in IELM.")
 105
 106 ;;; System variables
 107
 108 (defvar ielm-working-buffer nil
 109   "Buffer in which IELM sexps will be evaluated.
 110 This variable is buffer-local.")
 111
 112 (defvar ielm-header
 113   "*** Welcome to IELM ***  Type (describe-mode) for help.\n"
 114   "Message to display when IELM is started.")
 115
 116 (defvar ielm-map nil)
 117 (if ielm-map nil
 118   (if (string-match "Lucid" emacs-version)
 119       ;; Lemacs
 120       (progn
 121         (setq ielm-map (make-sparse-keymap))
 122         (set-keymap-parent ielm-map comint-mode-map))
 123     ;; FSF
 124     (setq ielm-map (cons 'keymap comint-mode-map)))
 125   (define-key ielm-map "\t" 'comint-dynamic-complete)
 126   (define-key ielm-map "\C-m" 'ielm-return)
 127   (define-key ielm-map "\C-j" 'ielm-send-input)
 128   (define-key ielm-map "\e\C-x" 'eval-defun)         ; for consistency with
 129   (define-key ielm-map "\e\t" 'lisp-complete-symbol) ; lisp-interaction-mode
 130   ;; These bindings are from shared-lisp-mode-map -- can you inherit
 131   ;; from more than one keymap??
 132   (define-key ielm-map "\e\C-q" 'indent-sexp)
 133   (define-key ielm-map "\177" 'backward-delete-char-untabify)
 134   ;; Some convenience bindings for setting the working buffer
 135   (define-key ielm-map "\C-c\C-b" 'ielm-change-working-buffer)
 136   (define-key ielm-map "\C-c\C-f" 'ielm-display-working-buffer)
 137   (define-key ielm-map "\C-c\C-v" 'ielm-print-working-buffer))
 138
 139 (defvar ielm-font-lock-keywords
 140   (list
 141    (cons (concat "^" (regexp-quote ielm-prompt)) 'font-lock-keyword-face)
 142    '("\\(^\\*\\*\\*[^*]+\\*\\*\\*\\)\\(.*$\\)"
 143      (1 font-lock-comment-face)
 144      (2 font-lock-constant-face)))
 145   "Additional expressions to highlight in ielm buffers.")
 146
 147 ;;; Completion stuff
 148
 149 (defun ielm-tab nil
 150   "Possibly indent the current line as lisp code."
 151   (interactive)
 152   (if (or (eq (preceding-char) ?\n)
 153           (eq (char-syntax (preceding-char)) ? ))
 154       (progn
 155         (ielm-indent-line)
 156         t)))
 157
 158 (defun ielm-complete-symbol nil
 159   "Complete the lisp symbol before point."
 160   ;; A wrapper for lisp-complete symbol that returns non-nil if
 161   ;; completion has occurred
 162   (let* ((btick (buffer-modified-tick))
 163          (cbuffer (get-buffer "*Completions*"))
 164          (ctick (and cbuffer (buffer-modified-tick cbuffer))))
 165     (lisp-complete-symbol)
 166      ;; completion has occurred if:
 167     (or
 168      ;; the buffer has been modified
 169      (not (= btick (buffer-modified-tick)))
 170      ;; a completions buffer has been modified or created
 171      (if cbuffer
 172          (not (= ctick (buffer-modified-tick cbuffer)))
 173        (get-buffer "*Completions*")))))
 174
 175 (defun ielm-complete-filename nil
 176   "Dynamically complete filename before point, if in a string."
 177   (if (nth 3 (parse-partial-sexp comint-last-input-start (point)))
 178       (comint-dynamic-complete-filename)))
 179
 180 (defun ielm-indent-line nil
 181   "Indent the current line as Lisp code if it is not a prompt line."
 182   (when (save-excursion (comint-bol) (bolp))
 183     (lisp-indent-line)))
 184
 185 ;;; Working buffer manipulation
 186
 187 (defun ielm-print-working-buffer nil
 188   "Print the current IELM working buffer's name in the echo area."
 189   (interactive)
 190   (message "The current working buffer is: %s" (buffer-name ielm-working-buffer)))
 191
 192 (defun ielm-display-working-buffer nil
 193   "Display the current IELM working buffer.
 194 Don't forget that selecting that buffer will change its value of `point'
 195 to its value of `window-point'!"
 196   (interactive)
 197   (display-buffer ielm-working-buffer)
 198   (ielm-print-working-buffer))
 199
 200 (defun ielm-change-working-buffer (buf)
 201   "Change the current IELM working buffer to BUF.
 202 This is the buffer in which all sexps entered at the IELM prompt are
 203 evaluated.  You can achieve the same effect with a call to
 204 `set-buffer' at the IELM prompt."
 205   (interactive "bSet working buffer to: ")
 206   (setq ielm-working-buffer (or (get-buffer buf) (error "No such buffer")))
 207   (ielm-print-working-buffer))
 208
 209 ;;; Other bindings
 210
 211 (defun ielm-return nil
 212   "Newline and indent, or evaluate the sexp before the prompt.
 213 Complete sexps are evaluated; for incomplete sexps inserts a newline
 214 and indents.  If however `ielm-dynamic-return' is nil, this always
 215 simply inserts a newline."
 216   (interactive)
 217   (if ielm-dynamic-return
 218       (let ((state
 219              (save-excursion
 220                (end-of-line)
 221                (parse-partial-sexp (ielm-pm)
 222                                    (point)))))
 223         (if (and (< (car state) 1) (not (nth 3 state)))
 224             (ielm-send-input)
 225           (if (and ielm-dynamic-multiline-inputs
 226                    (save-excursion
 227                      (beginning-of-line)
 228                      (looking-at comint-prompt-regexp)))
 229               (save-excursion
 230                 (goto-char (ielm-pm))
 231                 (newline 1)))
 232           (newline-and-indent)))
 233     (newline)))
 234
 235 (defvar ielm-input)
 236
 237 (defun ielm-input-sender (proc input)
 238   ;; Just sets the variable ielm-input, which is in the scope of
 239   ;; `ielm-send-input's call.
 240   (setq ielm-input input))
 241
 242 (defun ielm-send-input nil
 243   "Evaluate the Emacs Lisp expression after the prompt."
 244   (interactive)
 245   (let ((buf (current-buffer))
 246         ielm-input)                     ; set by ielm-input-sender
 247     (comint-send-input)                 ; update history, markers etc.
 248     (ielm-eval-input ielm-input)))
 249
 250 ;;; Utility functions
 251
 252 (defun ielm-is-whitespace (string)
 253   "Return non-nil if STRING is all whitespace."
 254   (or (string= string "") (string-match "\\`[ \t\n]+\\'" string)))
 255
 256 (defun ielm-format-errors (errlist)
 257   (let ((result ""))
 258     (while errlist
 259       (setq result (concat result (prin1-to-string (car errlist)) ", "))
 260       (setq errlist (cdr errlist)))
 261     (substring result 0 -2)))
 262
 263
 264 (defun ielm-format-error (err)
 265   ;; Return a string form of the error ERR.
 266   (format "%s%s"
 267           (or (get (car err) 'error-message) "Peculiar error")
 268           (if (cdr err)
 269               (format ": %s" (ielm-format-errors (cdr err)))
 270             "")))
 271
 272 ;;; Evaluation
 273
 274 (defun ielm-eval-input (ielm-string)
 275   "Evaluate the Lisp expression IELM-STRING, and pretty-print the result."
 276   ;; This is the function that actually `sends' the input to the
 277   ;; `inferior Lisp process'. All comint-send-input does is works out
 278   ;; what that input is.  What this function does is evaluates that
 279   ;; input and produces `output' which gets inserted into the buffer,
 280   ;; along with a new prompt.  A better way of doing this might have
 281   ;; been to actually send the output to the `cat' process, and write
 282   ;; this as in output filter that converted sexps in the output
 283   ;; stream to their evaluated value.  But that would have involved
 284   ;; more process coordination than I was happy to deal with.
 285   ;;
 286   ;; NOTE: all temporary variables in this function will be in scope
 287   ;; during the eval, and so need to have non-clashing names.
 288   (let (ielm-form                       ; form to evaluate
 289         ielm-pos                        ; End posn of parse in string
 290         ielm-result                     ; Result, or error message
 291         ielm-error-type                 ; string, nil if no error
 292         (ielm-output    "")             ; result to display
 293         (ielm-wbuf ielm-working-buffer) ; current buffer after evaluation
 294         (ielm-pmark (ielm-pm)))
 295     (if (not (ielm-is-whitespace ielm-string))
 296         (progn
 297           (condition-case err
 298               (let (rout)
 299                 (setq rout (read-from-string ielm-string))
 300                 (setq ielm-form (car rout))
 301                 (setq ielm-pos (cdr rout)))
 302             (error (setq ielm-result (ielm-format-error err))
 303                    (setq ielm-error-type "Read error")))
 304           (if ielm-error-type nil
 305             ;; Make sure working buffer has not been killed
 306             (if (not (buffer-name ielm-working-buffer))
 307                 (setq ielm-result "Working buffer has been killed"
 308                       ielm-error-type "IELM Error"
 309                       ielm-wbuf (current-buffer))
 310               (if (ielm-is-whitespace (substring ielm-string ielm-pos))
 311                   ;; need this awful let convolution to work around
 312                   ;; an Emacs bug involving local vbls and let binding
 313                   (let ((*save *)
 314                         (**save **)
 315                         (***save ***))
 316                     (save-excursion
 317                       (set-buffer ielm-working-buffer)
 318                       (condition-case err
 319                           (let ((* *save)
 320                                 (** **save)
 321                                 (*** ***save)
 322                                 (ielm-obuf (current-buffer)))
 323                             (setq ielm-result (eval ielm-form))
 324                             (setq ielm-wbuf (current-buffer))
 325                             ;; The eval may have changed current-buffer;
 326                             ;; need to set it back here to avoid a bug
 327                             ;; in let.  Don't want to use save-excursion
 328                             ;; because we want to allow changes in point.
 329                             (set-buffer ielm-obuf))
 330                         (error (setq ielm-result (ielm-format-error err))
 331                                (setq ielm-error-type "Eval error"))
 332                         (quit (setq ielm-result "Quit during evaluation")
 333                               (setq ielm-error-type "Eval error")))))
 334                 (setq ielm-error-type "IELM error")
 335                 (setq ielm-result "More than one sexp in input"))))
 336
 337           ;; If the eval changed the current buffer, mention it here
 338           (if (eq ielm-wbuf ielm-working-buffer) nil
 339             (message "current buffer is now: %s" ielm-wbuf)
 340             (setq ielm-working-buffer ielm-wbuf))
 341
 342           (goto-char ielm-pmark)
 343           (if (not ielm-error-type)
 344               (condition-case err
 345                   ;; Self-referential objects cause loops in the printer, so
 346                   ;; trap quits here. May as well do errors, too
 347                   (setq ielm-output (concat ielm-output (pp-to-string ielm-result)))
 348                 (error (setq ielm-error-type "IELM Error")
 349                        (setq ielm-result  "Error during pretty-printing (bug in pp)"))
 350                 (quit  (setq ielm-error-type "IELM Error")
 351                        (setq ielm-result "Quit during pretty-printing"))))
 352           (if ielm-error-type
 353               (progn
 354                 (if ielm-noisy (ding))
 355                 (setq ielm-output (concat ielm-output "*** " ielm-error-type " ***  "))
 356                 (setq ielm-output (concat ielm-output ielm-result)))
 357             ;; There was no error, so shift the *** values
 358             (setq *** **)
 359             (setq ** *)
 360             (setq * ielm-result))
 361           (setq ielm-output (concat ielm-output "\n"))))
 362     (setq ielm-output (concat ielm-output ielm-prompt))
 363     (comint-output-filter (ielm-process) ielm-output)))
 364
 365 ;;; Process and marker utilities
 366
 367 (defun ielm-process nil
 368   ;; Return the current buffer's process.
 369   (get-buffer-process (current-buffer)))
 370
 371 (defun ielm-pm nil
 372   ;; Return the process mark of the current buffer.
 373   (process-mark (get-buffer-process (current-buffer))))
 374
 375 (defun ielm-set-pm (pos)
 376   ;; Set the process mark in the current buffer to POS.
 377   (set-marker (process-mark (get-buffer-process (current-buffer))) pos))
 378
 379 ;;; Major mode
 380
 381 (put 'inferior-emacs-lisp-mode 'mode-class 'special)
 382
 383 (defun inferior-emacs-lisp-mode nil
 384   "Major mode for interactively evaluating Emacs Lisp expressions.
 385 Uses the interface provided by `comint-mode' (which see).
 386
 387 * \\<ielm-map>\\[ielm-send-input] evaluates the sexp following the prompt. There must be at most
 388   one top-level sexp per prompt.
 389
 390 * \\[ielm-return] inserts a newline and indents, or evaluates a
 391   complete expression (but see variable `ielm-dynamic-return').
 392   Inputs longer than one line are moved to the line following the
 393   prompt (but see variable `ielm-dynamic-multiline-inputs').
 394
 395 * \\[comint-dynamic-complete] completes Lisp symbols (or filenames, within strings),
 396   or indents the line if there is nothing to complete.
 397
 398 During evaluations, the values of the variables `*', `**', and `***'
 399 are the results of the previous, second previous and third previous
 400 evaluations respectively.
 401
 402 The current working buffer may be changed (with a call to
 403 `set-buffer', or with \\[ielm-change-working-buffer]), and its value
 404 is preserved between successive evaluations.  In this way, expressions
 405 may be evaluated in a different buffer than the *ielm* buffer.
 406 Display the name of the working buffer with \\[ielm-print-working-buffer],
 407 or the buffer itself with \\[ielm-display-working-buffer].
 408
 409 Expressions evaluated by IELM are not subject to `debug-on-quit' or
 410 `debug-on-error'.
 411
 412 The behaviour of IELM may be customised with the following variables:
 413 * To stop beeping on error, set `ielm-noisy' to nil
 414 * If you don't like the prompt, you can change it by setting `ielm-prompt'.
 415 * Set `ielm-dynamic-return' to nil for bindings like `lisp-interaction-mode'
 416 * Entry to this mode runs `comint-mode-hook' and `ielm-mode-hook'
 417  (in that order).
 418
 419 Customised bindings may be defined in `ielm-map', which currently contains:
 420 \\{ielm-map}"
 421   (interactive)
 422   (comint-mode)
 423   (setq comint-prompt-regexp (concat "^" (regexp-quote ielm-prompt)))
 424   (make-local-variable 'paragraph-start)
 425   (setq paragraph-start comint-prompt-regexp)
 426   (setq comint-input-sender 'ielm-input-sender)
 427   (setq comint-process-echoes nil)
 428   (setq comint-dynamic-complete-functions
 429         '(ielm-tab comint-replace-by-expanded-history ielm-complete-filename ielm-complete-symbol))
 430   (setq comint-get-old-input 'ielm-get-old-input)
 431   (make-local-variable 'comint-completion-addsuffix)
 432   (setq comint-completion-addsuffix
 433         (cons (char-to-string directory-sep-char) ""))
 434
 435   (setq major-mode 'inferior-emacs-lisp-mode)
 436   (setq mode-name "IELM")
 437   (use-local-map ielm-map)
 438   (set-syntax-table emacs-lisp-mode-syntax-table)
 439
 440   (make-local-variable 'indent-line-function)
 441   (make-local-variable 'ielm-working-buffer)
 442   (setq ielm-working-buffer (current-buffer))
 443   (setq indent-line-function 'ielm-indent-line)
 444   (make-local-variable 'fill-paragraph-function)
 445   (setq fill-paragraph-function 'lisp-fill-paragraph)
 446
 447   ;; Value holders
 448   (setq * nil)
 449   (make-local-variable '*)
 450   (setq ** nil)
 451   (make-local-variable '**)
 452   (setq *** nil)
 453   (make-local-variable '***)
 454
 455   ;; font-lock support
 456   (make-local-variable 'font-lock-defaults)
 457   (setq font-lock-defaults
 458         '(ielm-font-lock-keywords nil nil ((?: . "w") (?- . "w") (?* . "w"))))
 459
 460   ;; A dummy process to keep comint happy. It will never get any input
 461   (if (comint-check-proc (current-buffer)) nil
 462     (start-process "ielm" (current-buffer) "cat")
 463     (process-kill-without-query (ielm-process))
 464     (goto-char (point-max))
 465     ;; Add a silly header
 466     (insert ielm-header)
 467     (ielm-set-pm (point-max))
 468     (comint-output-filter (ielm-process) ielm-prompt)
 469     (set-marker comint-last-input-start (ielm-pm))
 470     (set-process-filter (get-buffer-process (current-buffer)) 'comint-output-filter))
 471   (run-hooks 'ielm-mode-hook))
 472
 473 (defun ielm-get-old-input nil
 474   ;; Return the previous input surrounding point
 475   (save-excursion
 476     (beginning-of-line)
 477     (if (looking-at comint-prompt-regexp) nil
 478       (re-search-backward comint-prompt-regexp))
 479     (comint-skip-prompt)
 480     (buffer-substring (point) (progn (forward-sexp 1) (point)))))
 481
 482 ;;; User command
 483
 484 ;;;###autoload (add-hook 'same-window-buffer-names "*ielm*")
 485
 486 ;;;###autoload
 487 (defun ielm nil
 488   "Interactively evaluate Emacs Lisp expressions.
 489 Switches to the buffer `*ielm*', or creates it if it does not exist."
 490   (interactive)
 491   (if (comint-check-proc "*ielm*")
 492       nil
 493     (save-excursion
 494       (set-buffer (get-buffer-create "*ielm*"))
 495       (inferior-emacs-lisp-mode)))
 496   (pop-to-buffer "*ielm*"))
 497
 498 (provide 'ielm)
 499
 500 ;;; ielm.el ends here