lisp/hi-lock.el

   1 ;;; hi-lock.el --- Minor mode for interactive automatic highlighting.
   2
   3 ;; Copyright (C) 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: David M. Koppelman, koppel@ee.lsu.edu
   6 ;; Keywords: faces, minor-mode, matching, display
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary
  26 ;;
  27 ;;  With the hi-lock commands text matching interactively entered
  28 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  29 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  30 ;;  using a yellow background face.  New occurrences of `clearly' will
  31 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  32 ;;  will remove the highlighting.  Any existing face can be used for
  33 ;;  highlighting and a set of appropriate faces is provided.  The
  34 ;;  regexps can be written into the current buffer in a form that will
  35 ;;  be recognized the next time the corresponding file is read.
  36 ;;
  37 ;;  Applications:
  38 ;;
  39 ;;    In program source code highlight a variable to quickly see all
  40 ;;    places it is modified or referenced:
  41 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  42 ;;
  43 ;;    In a shell or other buffer that is showing lots of program
  44 ;;    output, highlight the parts of the output you're interested in:
  45 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  46 ;;
  47 ;;    In buffers displaying tables, highlight the lines you're interested in:
  48 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  49 ;;
  50 ;;    When writing text, highlight personal cliches.  This can be
  51 ;;    amusing.
  52 ;;    M-x highlight-regexp as can be seen RET RET
  53 ;;
  54 ;;  Setup
  55 ;;
  56 ;;    Put the following code in your .emacs file.  This turns on
  57 ;;    hi-lock mode and adds an "Automatic Highlighting" entry
  58 ;;    to the edit menu.
  59 ;;
  60 ;;    (hi-lock-mode 1)
  61 ;;
  62 ;;    You might also want to bind the hi-lock commands to more
  63 ;;    finger-friendly sequences:
  64
  65 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  66 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  67 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  68 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  69 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  70
  71 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  72 ;;    additional instructions.
  73
  74 ;; Sample file patterns:
  75
  76 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  77 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  78 ; Hi-lock: end
  79
  80 ;;; Code:
  81
  82 (eval-and-compile
  83   (require 'font-lock))
  84
  85 ;;;###autoload
  86 (defgroup hi-lock-interactive-text-highlighting nil
  87   "Interactively add and remove font-lock patterns for highlighting text."
  88   :group 'faces)
  89
  90 ;;;###autoload
  91 (defcustom hi-lock-mode nil
  92   "Toggle hi-lock, for interactively adding font-lock text-highlighting patterns."
  93   :set (lambda (symbol value)
  94          (hi-lock-mode (or value 0)))
  95   :initialize 'custom-initialize-default
  96   :type 'boolean
  97   :group 'hi-lock-interactive-text-highlighting
  98   :require 'hi-lock)
  99
 100 (defcustom hi-lock-file-patterns-range 10000
 101   "Limit of search in a buffer for hi-lock patterns.
 102 When a file is visited and hi-lock mode is on patterns starting
 103 up to this limit are added to font-lock's patterns.  See documentation
 104 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 105   :type 'integer
 106   :group 'hi-lock-interactive-text-highlighting)
 107
 108 (defcustom hi-lock-exclude-modes
 109   '(rmail-mode mime/viewer-mode gnus-article-mode)
 110   "List of major modes in which hi-lock will not run.
 111 For security reasons since font lock patterns can specify function
 112 calls."
 113   :type 'variable
 114   :group 'hi-lock-interactive-text-highlighting)
 115
 116
 117 (defgroup hi-lock-faces nil
 118   "Faces for hi-lock."
 119   :group 'hi-lock-interactive-text-highlighting)
 120
 121 (defface hi-yellow
 122   '((t (:background "yellow")))
 123   "Default face for hi-lock mode."
 124   :group 'hi-lock-faces)
 125
 126 (defface hi-pink
 127   '((t (:background "pink")))
 128   "Face for hi-lock mode."
 129   :group 'hi-lock-faces)
 130
 131 (defface hi-green
 132   '((t (:background "green")))
 133   "Face for hi-lock mode."
 134   :group 'hi-lock-faces)
 135
 136 (defface hi-blue
 137   '((t (:background "light blue")))
 138   "Face for hi-lock mode."
 139   :group 'hi-lock-faces)
 140
 141 (defface hi-black-b
 142   '((t (:weight bold)))
 143   "Face for hi-lock mode."
 144   :group 'hi-lock-faces)
 145
 146 (defface hi-blue-b
 147   '((t (:weight bold :foreground "blue")))
 148   "Face for hi-lock mode."
 149   :group 'hi-lock-faces)
 150
 151 (defface hi-green-b
 152   '((t (:weight bold :foreground "green")))
 153   "Face for hi-lock mode."
 154   :group 'hi-lock-faces)
 155
 156 (defface hi-red-b
 157   '((t (:weight bold :foreground "red")))
 158   "Face for hi-lock mode."
 159   :group 'hi-lock-faces)
 160
 161 (defface hi-black-hb
 162   '((t (:weight bold :family "helv" :height 200)))
 163   "Face for hi-lock mode."
 164   :group 'hi-lock-faces)
 165
 166 (defvar hi-lock-file-patterns nil
 167   "Patterns found in file for hi-lock.  Should not be changed.")
 168
 169 (defvar hi-lock-interactive-patterns nil
 170   "Patterns provided to hi-lock by user.  Should not be changed.")
 171
 172 (defvar hi-lock-face-history
 173   (list "hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 174         "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 175       "History list of faces for hi-lock interactive functions.")
 176
 177 ;(dolist (f hi-lock-face-history) (unless (facep f) (error "%s not a face" f)))
 178
 179 (defvar hi-lock-regexp-history nil
 180   "History of regexps used for interactive fontification.")
 181
 182 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 183   "Regexp for finding hi-lock patterns at top of file.")
 184
 185 (make-variable-buffer-local 'hi-lock-interactive-patterns)
 186 (put 'hi-lock-interactive-patterns 'permanent-local t)
 187 (make-variable-buffer-local 'hi-lock-regexp-history)
 188 (put 'hi-lock-regexp-history 'permanent-local t)
 189 (make-variable-buffer-local 'hi-lock-file-patterns)
 190 (put 'hi-lock-file-patterns 'permanent-local t)
 191
 192 (defvar hi-lock-menu (make-sparse-keymap "Hi Lock")
 193   "Menu for hi-lock mode.")
 194
 195 (define-key-after hi-lock-menu [highlight-regexp]
 196   '(menu-item "Highlight Regexp..." highlight-regexp
 197               :help "Highlight text matching PATTERN (a regexp)."))
 198
 199 (define-key-after hi-lock-menu [highlight-lines-matching-regexp]
 200   '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 201               :help "Highlight lines containing match of PATTERN (a regexp).."))
 202
 203 (define-key-after hi-lock-menu [unhighlight-regexp]
 204   '(menu-item "Remove Highlighting..." unhighlight-regexp
 205               :help "Remove previously entered highlighting pattern."
 206               :enable hi-lock-interactive-patterns))
 207
 208 (define-key-after hi-lock-menu [hi-lock-write-interactive-patterns]
 209   '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 210               :help "Insert interactively added REGEXPs into buffer at point."
 211               :enable hi-lock-interactive-patterns))
 212
 213 (define-key-after hi-lock-menu [hi-lock-find-patterns]
 214   '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 215               :help "Use patterns (if any) near top of buffer."))
 216
 217 (defvar hi-lock-map (make-sparse-keymap "Hi Lock")
 218   "Key map for hi-lock.")
 219
 220 (define-key hi-lock-map "\C-xwi" 'hi-lock-find-patterns)
 221 (define-key hi-lock-map "\C-xwl" 'highlight-lines-matching-regexp)
 222 (define-key hi-lock-map "\C-xwh" 'highlight-regexp)
 223 (define-key hi-lock-map "\C-xwr" 'unhighlight-regexp)
 224 (define-key hi-lock-map "\C-xwb" 'hi-lock-write-interactive-patterns)
 225
 226 (unless (assq 'hi-lock-mode minor-mode-map-alist)
 227   (setq minor-mode-map-alist (cons (cons 'hi-lock-mode hi-lock-map)
 228                                    minor-mode-map-alist)))
 229
 230 (unless (assq 'hi-lock-mode minor-mode-alist)
 231   (setq minor-mode-alist (cons '(hi-lock-mode " H") minor-mode-alist)))
 232
 233
 234 ;; Visible Functions
 235
 236
 237 ;;;###autoload
 238 (defun hi-lock-mode (&optional arg)
 239   "Toggle minor mode for interactively adding font-lock highlighting patterns.
 240
 241 If ARG positive turn hi-lock on.  Issuing a hi-lock command will also
 242 turn hi-lock on.  When hi-lock turned on an \"Automatic Highlighting\"
 243 submenu is added to the \"Edit\" menu.  The commands in the submenu,
 244 which can be called interactively, are:
 245
 246 \\[highlight-regexp] REGEXP FACE
 247   Highlight matches of pattern REGEXP in current buffer with FACE.
 248
 249 \\[highlight-lines-matching-regexp] REGEXP FACE
 250   Highlight lines containing matches of REGEXP in current buffer with FACE.
 251
 252 \\[unhighlight-regexp] REGEXP
 253   Remove highlighting on matches of REGEXP in current buffer.
 254
 255 \\[hi-lock-write-interactive-patterns]
 256   Write active REGEXPs into buffer as comments (if possible). They will
 257   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 258   is issued.  The inserted regexps are in the form of font lock keywords.
 259   (See `font-lock-keywords') They may be edited and re-loaded with \\[hi-lock-find-patterns],
 260   any valid `font-lock-keywords' form is acceptable.
 261
 262 \\[hi-lock-find-patterns]
 263   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 264
 265 When hi-lock is started and if the mode is not excluded, the
 266 beginning of the buffer is searched for lines of the form:
 267   Hi-lock: FOO
 268 where FOO is a list of patterns. These are added to the font lock keywords
 269 already present.  The patterns must start before position (number
 270 of characters into buffer) `hi-lock-file-patterns-range'.  Patterns
 271 will be read until
 272  Hi-lock: end
 273 is found. A mode is excluded if it's in the list `hi-lock-exclude-modes'."
 274   (interactive)
 275   (let ((hi-lock-mode-prev hi-lock-mode))
 276     (setq hi-lock-mode
 277            (if (null arg) (not hi-lock-mode)
 278              (> (prefix-numeric-value arg) 0)))
 279     ;; Turned on.
 280     (when (and (not hi-lock-mode-prev) hi-lock-mode)
 281       (if (not font-lock-mode) (turn-on-font-lock))
 282       (add-hook 'find-file-hooks 'hi-lock-find-file-hook)
 283       (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook)
 284       (define-key-after menu-bar-edit-menu [hi-lock]
 285         (cons "Automatic Highlighting" hi-lock-menu))
 286       (hi-lock-find-patterns))
 287     ;; Turned off.
 288     (when (and hi-lock-mode-prev (not hi-lock-mode))
 289       (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 290       (font-lock-remove-keywords nil hi-lock-file-patterns)
 291       (setq hi-lock-interactive-patterns nil)
 292       (hi-lock-refontify)
 293       (define-key-after menu-bar-edit-menu [hi-lock] nil)
 294       (remove-hook 'find-file-hooks 'hi-lock-find-file-hook)
 295       (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook))))
 296
 297
 298 ;;;###autoload
 299 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 300 ;;;###autoload
 301 (defun hi-lock-line-face-buffer (regexp &optional face)
 302   "Set face of all lines containing matches of REGEXP to FACE.
 303
 304 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 305 list maintained for regexps, global history maintained for faces.
 306 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 307 (See info node `Minibuffer History')"
 308   (interactive
 309    (list
 310     (hi-lock-regexp-okay
 311      (read-from-minibuffer "Regexp to highlight line: "
 312                            (cons (or (car hi-lock-regexp-history) "") 1 )
 313                            nil nil 'hi-lock-regexp-history))
 314     (hi-lock-read-face-name)))
 315   (unless hi-lock-mode (hi-lock-mode))
 316   (or (facep face) (setq face 'rwl-yellow))
 317   (hi-lock-set-pattern
 318    (list (concat "^.*" regexp ".*$") (list 0 (list 'quote face) t))))
 319
 320 ;;;###autoload
 321 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 322 ;;;###autoload
 323 (defun hi-lock-face-buffer (regexp &optional face)
 324   "Set face of all matches of REGEXP to FACE.
 325
 326 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 327 list maintained for regexps, global history maintained for faces.
 328 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 329 (See info node `Minibuffer History')"
 330   (interactive
 331    (list
 332     (hi-lock-regexp-okay
 333      (read-from-minibuffer "Regexp to highlight: "
 334                            (cons (or (car hi-lock-regexp-history) "") 1 )
 335                            nil nil 'hi-lock-regexp-history))
 336     (hi-lock-read-face-name)))
 337   (or (facep face) (setq face 'rwl-yellow))
 338   (unless hi-lock-mode (hi-lock-mode))
 339   (hi-lock-set-pattern (list regexp (list 0 (list 'quote face) t))))
 340
 341 ;;;###autoload
 342 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 343 ;;;###autoload
 344 (defun hi-lock-unface-buffer (regexp)
 345   "Remove highlighting of matches to REGEXP set by hi-lock.
 346
 347 Interactively, prompt for REGEXP.  Buffer-local history of inserted
 348 regexp's maintained.  Will accept only regexps inserted by hi-lock
 349 interactive functions. \(See `hi-lock-interactive-patterns'.\)
 350 \\<minibuffer-local-must-match-map>Use \\[minibuffer-complete] to complete a partially typed regexp.
 351 \(See info node `Minibuffer History'.\)"
 352   (interactive
 353    (if (vectorp (this-command-keys))
 354        (catch 'snafu
 355          (or
 356           (x-popup-menu
 357            t
 358            (cons
 359             `keymap
 360             (cons "Select Pattern to Unhighlight"
 361                   (mapcar (lambda (pattern)
 362                             (list (car pattern)
 363                                   (format
 364                                    "%s (%s)" (car pattern)
 365                                    (symbol-name
 366                                     (car
 367                                      (cdr (car (cdr (car (cdr pattern))))))))
 368                                   (cons nil nil)
 369                                   (car pattern)))
 370                           hi-lock-interactive-patterns))))
 371           ;; If the user clicks outside the menu, meaning that they
 372           ;; change their mind, x-popup-menu returns nil, and
 373           ;; interactive signals a wrong number of arguments error.
 374           ;; To prevent that, we return an empty string, which will
 375           ;; effectively disable the rest of the function.
 376           (throw 'snafu '(""))))
 377      (let ((history-list (mapcar (lambda (p) (car p))
 378                                  hi-lock-interactive-patterns)))
 379        (unless hi-lock-interactive-patterns
 380          (error "No highlighting to remove"))
 381        (list
 382         (completing-read "Regexp to unhighlight: "
 383                          hi-lock-interactive-patterns t t
 384                          (car (car hi-lock-interactive-patterns))
 385                          (cons 'history-list 1))))))
 386   (let ((keyword (assoc regexp hi-lock-interactive-patterns)))
 387     (when keyword
 388       (font-lock-remove-keywords nil (list keyword))
 389       (setq hi-lock-interactive-patterns
 390             (delq keyword hi-lock-interactive-patterns))
 391       (hi-lock-refontify))))
 392
 393 ;;;###autoload
 394 (defun hi-lock-write-interactive-patterns ()
 395   "Write interactively added patterns, if any, into buffer at point.
 396
 397 Interactively added patterns are those normally specified using
 398 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 399 be found in variable `hi-lock-interactive-patterns'."
 400   (interactive)
 401   (let ((prefix (format "%s %s:" (or comment-start "") "Hi-lock")))
 402     (when (> (+ (point) (length prefix)) hi-lock-file-patterns-range)
 403       (beep)
 404       (message
 405        "Warning, inserted keywords not close enough to top of file."))
 406     (mapcar
 407      (lambda (pattern)
 408        (insert (format "%s (%s) %s\n"
 409                        prefix (prin1-to-string pattern) (or comment-end ""))))
 410      hi-lock-interactive-patterns)))
 411
 412
 413 ;; Implementation Functions
 414
 415 (defun hi-lock-regexp-okay (regexp)
 416   "Return REGEXP if it appears suitable for a font-lock pattern.
 417
 418 Otherwise signal an error.  A pattern that matches the null string is
 419 not suitable."
 420   (if (string-match regexp "")
 421       (error "Regexp cannot match an empty string")
 422     regexp))
 423
 424 (defun hi-lock-read-face-name ()
 425   "Read face name from minibuffer with completion and history."
 426   (intern (completing-read
 427            "Highlight using face: "
 428            obarray 'facep t
 429            (cons (car hi-lock-face-history)
 430                  (let ((prefix
 431                         (try-completion
 432                          (substring (car hi-lock-face-history) 0 1)
 433                          (mapcar (lambda (f) (cons f f))
 434                                  hi-lock-face-history))))
 435                    (if (and (stringp prefix)
 436                             (not (equal prefix (car hi-lock-face-history))))
 437                        (length prefix) 0)))
 438            '(hi-lock-face-history . 0))))
 439
 440 (defun hi-lock-find-file-hook ()
 441   "Add hi-lock patterns, if present."
 442   (hi-lock-find-patterns))
 443
 444 (defun hi-lock-current-line (&optional end)
 445   "Return line number of line at point.
 446 Optional argument END is maximum excursion."
 447   (interactive)
 448   (save-excursion
 449     (beginning-of-line)
 450     (1+ (count-lines 1 (or end (point))))))
 451
 452 (defun hi-lock-set-pattern (pattern)
 453   "Add PATTERN to list of interactively highlighted patterns and refontify."
 454   (hi-lock-set-patterns (list pattern)))
 455
 456 (defun hi-lock-set-patterns (patterns)
 457   "Add PATTERNS to list of interactively highlighted patterns and refontify.."
 458   (dolist (pattern patterns)
 459     (unless (member pattern hi-lock-interactive-patterns)
 460       (font-lock-add-keywords nil (list pattern))
 461       (add-to-list 'hi-lock-interactive-patterns pattern)))
 462   (hi-lock-refontify))
 463
 464 (defun hi-lock-set-file-patterns (patterns)
 465   "Replace file patterns list with PATTERNS and refontify."
 466   (font-lock-remove-keywords nil hi-lock-file-patterns)
 467   (setq hi-lock-file-patterns patterns)
 468   (font-lock-add-keywords nil hi-lock-file-patterns)
 469   (hi-lock-refontify))
 470
 471 (defun hi-lock-refontify ()
 472   "Unfontify then refontify buffer.  Used when hi-lock patterns change."
 473   (interactive)
 474   (font-lock-unfontify-buffer)
 475   (cond
 476    (jit-lock-mode (jit-lock-fontify-buffer))
 477    ;; Need a better way, since this assumes too much about lazy lock.
 478    (lazy-lock-mode
 479     (let ((windows (get-buffer-window-list (current-buffer) 'nomini t)))
 480         (while windows
 481           (lazy-lock-fontify-window (car windows))
 482           (setq windows (cdr windows)))))
 483    (t (font-lock-fontify-buffer))))
 484
 485
 486 (defun hi-lock-find-patterns ()
 487   "Find patterns in current buffer for hi-lock."
 488   (interactive)
 489   (unless (memq major-mode hi-lock-exclude-modes)
 490     (let ((all-patterns nil)
 491           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 492       (save-excursion
 493         (widen)
 494         (goto-char (point-min))
 495         (re-search-forward target-regexp
 496                            (+ (point) hi-lock-file-patterns-range) t)
 497         (beginning-of-line)
 498         (while
 499             (and
 500              (re-search-forward target-regexp (+ (point) 100) t)
 501              (not (looking-at "\\s-*end")))
 502           (let
 503               ((patterns
 504                 (condition-case nil
 505                     (read (current-buffer))
 506                   (error  (message
 507                            (format "Could not read expression at %d"
 508                                    (hi-lock-current-line))) nil))))
 509             (if patterns
 510                 (setq all-patterns (append patterns all-patterns))))))
 511       (if (and (not hi-lock-mode) all-patterns)
 512           (hi-lock-mode 1))
 513       (if hi-lock-mode (hi-lock-set-file-patterns all-patterns))
 514       (if (interactive-p)
 515         (message (format "Hi-lock added %d patterns." (length all-patterns)))))))
 516
 517 (defun hi-lock-font-lock-hook ()
 518   "Add hi lock patterns to font-lock's."
 519   (when hi-lock-mode
 520     (font-lock-add-keywords nil hi-lock-file-patterns)
 521     (font-lock-add-keywords nil hi-lock-interactive-patterns)))
 522
 523 (provide 'hi-lock)
 524
 525 ;;; hi-lock.el ends here
 526
 527