lisp/finder.el

   1 ;;; finder.el --- topic & keyword-based code finder
   2
   3 ;; Copyright (C) 1992, 1997, 1998, 1999 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Created: 16 Jun 1992
   7 ;; Version: 1.0
   8 ;; Keywords: help
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This mode uses the Keywords library header to provide code-finding
  30 ;; services by keyword.
  31 ;;
  32 ;; Things to do:
  33 ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  34 ;; there doesn't seem to be any way to get completing-read to exit on
  35 ;; an EOL with no substring pending, which is what we'd want to end the loop.
  36 ;;    2. Search by string in synopsis line?
  37 ;;    3. Function to check finder-package-info for unknown keywords.
  38
  39 ;;; Code:
  40
  41 (require 'lisp-mnt)
  42 (require 'finder-inf)
  43
  44 ;; Local variable in finder buffer.
  45 (defvar finder-headmark)
  46
  47 ;; These are supposed to correspond to top-level customization groups,
  48 ;; says rms.
  49 (defvar finder-known-keywords
  50   '(
  51     (abbrev     . "abbreviation handling, typing shortcuts, macros")
  52     (bib        . "code related to the `bib' bibliography processor")
  53     (c          . "support for the C language and related languages")
  54     (calendar   . "calendar and time management support")
  55     (comm       . "communications, networking, remote access to files")
  56     (convenience . "convenience features for faster editing")
  57     (data       . "support editing files of data")
  58     (docs       . "support for Emacs documentation")
  59     (emulations . "emulations of other editors")
  60     (extensions . "Emacs Lisp language extensions")
  61     (faces      . "support for multiple fonts")
  62     (frames     . "support for Emacs frames and window systems")
  63     (games      . "games, jokes and amusements")
  64     (hardware   . "support for interfacing with exotic hardware")
  65     (help       . "support for on-line help systems")
  66     (hypermedia . "support for links between text or other media types")
  67     (i18n       . "internationalization and alternate character-set support")
  68     (internal   . "code for Emacs internals, build process, defaults")
  69     (languages  . "specialized modes for editing programming languages")
  70     (lisp       . "Lisp support, including Emacs Lisp")
  71     (local      . "code local to your site")
  72     (maint      . "maintenance aids for the Emacs development group")
  73     (mail       . "modes for electronic-mail handling")
  74     (matching   . "various sorts of searching and matching")
  75     (mouse      . "mouse support")
  76     (multimedia . "images and sound support")
  77     (news       . "support for netnews reading and posting")
  78     (oop        . "support for object-oriented programming")
  79     (outlines   . "support for hierarchical outlining")
  80     (processes  . "process, subshell, compilation, and job control support")
  81     (terminals  . "support for terminal types")
  82     (tex        . "code related to the TeX formatter")
  83     (tools      . "programming tools")
  84     (unix       . "front-ends/assistants for, or emulators of, UNIX features")
  85     (vms        . "support code for vms")
  86     (wp         . "word processing")
  87     ))
  88
  89 (defvar finder-mode-map nil)
  90 (or finder-mode-map
  91     (let ((map (make-sparse-keymap)))
  92       (define-key map " "       'finder-select)
  93       (define-key map "f"       'finder-select)
  94       (define-key map [mouse-2] 'finder-mouse-select)
  95       (define-key map "\C-m"    'finder-select)
  96       (define-key map "?"       'finder-summary)
  97       (define-key map "q"       'finder-exit)
  98       (define-key map "d"       'finder-list-keywords)
  99       (setq finder-mode-map map)))
 100
 101
 102 ;;; Code for regenerating the keyword list.
 103
 104 (defvar finder-package-info nil
 105   "Assoc list mapping file names to description & keyword lists.")
 106
 107 (defun finder-compile-keywords (&rest dirs)
 108   "Regenerate the keywords association list into the file `finder-inf.el'.
 109 Optional arguments DIRS are a list of Emacs Lisp directories to compile from;
 110 no arguments compiles from `load-path'."
 111   (save-excursion
 112     (let ((processed nil))
 113       (find-file "finder-inf.el")
 114       (erase-buffer)
 115       (insert ";;; finder-inf.el --- keyword-to-package mapping\n")
 116       (insert ";; Keywords: help\n")
 117       (insert ";;; Commentary:\n")
 118       (insert ";; Don't edit this file.  It's generated by finder.el\n\n")
 119       (insert ";;; Code:\n")
 120       (insert "\n(setq finder-package-info '(\n")
 121       (mapcar
 122        (lambda (d)
 123          (when (file-exists-p (directory-file-name d))
 124            (message "Directory %s" d)
 125            (mapcar
 126             (lambda (f)
 127               (if (and (or (string-match "^[^=].*\\.el$" f)
 128                            ;; Allow compressed files also.  Fixme:
 129                            ;; generalize this, especially for
 130                            ;; MS-DOG-type filenames.
 131                            (and (string-match "^[^=].*\\.el\\.\\(gz\\|Z\\)$" f)
 132                                 (require 'jka-compr)))
 133                        ;; Ignore lock files.
 134                        (not (string-match "^.#" f))
 135                        (not (member f processed)))
 136                   (let (summary keystart keywords)
 137                     (setq processed (cons f processed))
 138                     (save-excursion
 139                       (set-buffer (get-buffer-create "*finder-scratch*"))
 140                       (buffer-disable-undo (current-buffer))
 141                       (erase-buffer)
 142                       (insert-file-contents
 143                        (concat (file-name-as-directory (or d ".")) f))
 144                       (setq summary (lm-synopsis))
 145                       (setq keywords (lm-keywords)))
 146                     (insert
 147                      (format "    (\"%s\"\n        "
 148                              (if (string-match "\\.\\(gz\\|Z\\)$" f)
 149                                  (file-name-sans-extension f)
 150                                f)))
 151                     (prin1 summary (current-buffer))
 152                     (insert
 153                      "\n        ")
 154                     (setq keystart (point))
 155                     (insert
 156                      (if keywords (format "(%s)" keywords) "nil")
 157                      ")\n")
 158                     (subst-char-in-region keystart (point) ?, ? )
 159                     )))
 160             (directory-files (or d ".")))))
 161        (or dirs load-path))
 162       (insert "))\n\n(provide 'finder-inf)\n\n;;; finder-inf.el ends here\n")
 163       (kill-buffer "*finder-scratch*")
 164       (eval-current-buffer) ;; So we get the new keyword list immediately
 165       (basic-save-buffer))))
 166
 167 (defun finder-compile-keywords-make-dist ()
 168   "Regenerate `finder-inf.el' for the Emacs distribution."
 169   (apply 'finder-compile-keywords command-line-args-left)
 170   (kill-emacs))
 171
 172 ;;; Now the retrieval code
 173
 174 (defun finder-insert-at-column (column &rest strings)
 175   "Insert, at column COLUMN, other args STRINGS."
 176   (if (> (current-column) column) (insert "\n"))
 177   (move-to-column column t)
 178   (apply 'insert strings))
 179
 180 (defun finder-mouse-face-on-line ()
 181   "Put a `mouse-face' property on the previous line."
 182   (save-excursion
 183     (previous-line 1)
 184     (put-text-property (save-excursion (beginning-of-line) (point))
 185                        (progn (end-of-line) (point))
 186                        'mouse-face 'highlight)))
 187
 188 ;;;###autoload
 189 (defun finder-list-keywords ()
 190   "Display descriptions of the keywords in the Finder buffer."
 191   (interactive)
 192   (if (get-buffer "*Finder*")
 193       (pop-to-buffer "*Finder*")
 194     (pop-to-buffer (set-buffer (get-buffer-create "*Finder*")))
 195     (finder-mode)
 196     (setq buffer-read-only nil)
 197     (erase-buffer)
 198     (mapcar
 199      (lambda (assoc)
 200        (let ((keyword (car assoc)))
 201          (insert (symbol-name keyword))
 202          (finder-insert-at-column 14 (concat (cdr assoc) "\n"))
 203          (finder-mouse-face-on-line)))
 204      finder-known-keywords)
 205     (goto-char (point-min))
 206     (setq finder-headmark (point))
 207     (setq buffer-read-only t)
 208     (set-buffer-modified-p nil)
 209     (balance-windows)
 210     (finder-summary)))
 211
 212 (defun finder-list-matches (key)
 213   (pop-to-buffer (set-buffer (get-buffer-create "*Finder Category*")))
 214   (finder-mode)
 215   (setq buffer-read-only nil)
 216   (erase-buffer)
 217   (let ((id (intern key)))
 218     (insert
 219      "The following packages match the keyword `" key "':\n\n")
 220     (setq finder-headmark (point))
 221     (mapcar
 222      (lambda (x)
 223        (if (memq id (car (cdr (cdr x))))
 224            (progn
 225              (insert (car x))
 226              (finder-insert-at-column 16 (concat (nth 1 x) "\n"))
 227              (finder-mouse-face-on-line))))
 228      finder-package-info)
 229     (goto-char (point-min))
 230     (forward-line)
 231     (setq buffer-read-only t)
 232     (set-buffer-modified-p nil)
 233     (shrink-window-if-larger-than-buffer)
 234     (finder-summary)))
 235
 236 (defun finder-find-library (library)
 237   "Search for file LIBRARY on `load-path'.
 238 Try compressed versions if jka-compr is in use."
 239   (or (locate-library library t)
 240       (if (rassq 'jka-compr-handler file-name-handler-alist)
 241         (or (locate-library (concat library ".gz") t)
 242             (locate-library (concat library ".Z") t)
 243             ;; last resort for MS-DOG et al
 244             (locate-library (concat library "z"))))))
 245
 246 ;;;###autoload
 247 (defun finder-commentary (file)
 248   "Display FILE's commentary section.
 249 FILE should be in a form suitable for passing to `locate-library'."
 250   (interactive "sLibrary name: ")
 251   (let* ((str (lm-commentary (or (finder-find-library file)
 252                                  (finder-find-library (concat file ".el"))
 253                                  (error "Can't find library %s" file)))))
 254     (if (null str)
 255         (error "Can't find any Commentary section"))
 256     (pop-to-buffer "*Finder*")
 257     (setq buffer-read-only nil)
 258     (erase-buffer)
 259     (insert str)
 260     (goto-char (point-min))
 261     (delete-blank-lines)
 262     (goto-char (point-max))
 263     (delete-blank-lines)
 264     (goto-char (point-min))
 265     (while (re-search-forward "^;+ ?" nil t)
 266       (replace-match "" nil nil))
 267     (goto-char (point-min))
 268     (setq buffer-read-only t)
 269     (set-buffer-modified-p nil)
 270     (shrink-window-if-larger-than-buffer)
 271     (finder-mode)
 272     (finder-summary)))
 273
 274 (defun finder-current-item ()
 275   (if (and finder-headmark (< (point) finder-headmark))
 276       (error "No keyword or filename on this line")
 277     (save-excursion
 278       (beginning-of-line)
 279       (current-word))))
 280
 281 (defun finder-select ()
 282   "Select item on current line in a finder buffer."
 283   (interactive)
 284   (let ((key (finder-current-item)))
 285       (if (string-match "\\.el$" key)
 286           (finder-commentary key)
 287         (finder-list-matches key))))
 288
 289 (defun finder-mouse-select (event)
 290   "Select item in a finder buffer with the mouse."
 291   (interactive "e")
 292   (save-excursion
 293     (set-buffer (window-buffer (posn-window (event-start event))))
 294     (goto-char (posn-point (event-start event)))
 295     (finder-select)))
 296
 297 ;;;###autoload
 298 (defun finder-by-keyword ()
 299   "Find packages matching a given keyword."
 300   (interactive)
 301   (finder-list-keywords))
 302
 303 (defun finder-mode ()
 304   "Major mode for browsing package documentation.
 305 \\<finder-mode-map>
 306 \\[finder-select]       more help for the item on the current line
 307 \\[finder-exit] exit Finder mode and kill the Finder buffer."
 308   (interactive)
 309   (use-local-map finder-mode-map)
 310   (set-syntax-table emacs-lisp-mode-syntax-table)
 311   (setq mode-name "Finder")
 312   (setq major-mode 'finder-mode)
 313   (make-local-variable 'finder-headmark)
 314   (setq finder-headmark nil))
 315
 316 (defun finder-summary ()
 317   "Summarize basic Finder commands."
 318   (interactive)
 319   (message "%s"
 320    (substitute-command-keys
 321     "\\<finder-mode-map>\\[finder-select] = select, \
 322 \\[finder-mouse-select] = select, \\[finder-list-keywords] = to \
 323 finder directory, \\[finder-exit] = quit, \\[finder-summary] = help")))
 324
 325 (defun finder-exit ()
 326   "Exit Finder mode and kill the buffer."
 327   (interactive)
 328   (or (one-window-p t)
 329       (delete-window))
 330   ;; Can happen in either buffer -- kill each of the two that exists
 331   (and (get-buffer "*Finder*")
 332        (kill-buffer "*Finder*"))
 333   (and (get-buffer "*Finder Category*")
 334        (kill-buffer "*Finder Category*")))
 335
 336 (provide 'finder)
 337
 338 ;;; finder.el ends here