lisp/ebuff-menu.el

   1 ;;; ebuff-menu.el --- electric-buffer-list mode
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Richard Mlynarik <mly@ai.mit.edu>
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Who says one can't have typeout windows in GNU Emacs?   The entry
  28 ;; point, `electric-buffer-list' works like ^r select buffer from the
  29 ;; ITS Emacs lunar or tmacs libraries.
  30
  31 ;;; Code:
  32
  33 (require 'electric)
  34
  35 ;; this depends on the format of list-buffers (from src/buffer.c) and
  36 ;; on stuff in lisp/buff-menu.el
  37
  38 (defvar electric-buffer-menu-mode-map nil)
  39
  40 ;;;###autoload
  41 (defun electric-buffer-list (arg)
  42   "Pops up a buffer describing the set of Emacs buffers.
  43 Vaguely like ITS lunar select buffer; combining typeoutoid buffer
  44 listing with menuoid buffer selection.
  45
  46 If the very next character typed is a space then the buffer list
  47 window disappears.  Otherwise, one may move around in the buffer list
  48 window, marking buffers to be selected, saved or deleted.
  49
  50 To exit and select a new buffer, type a space when the cursor is on
  51 the appropriate line of the buffer-list window.  Other commands are
  52 much like those of buffer-menu-mode.
  53
  54 Calls value of `electric-buffer-menu-mode-hook' on entry if non-nil.
  55
  56 \\{electric-buffer-menu-mode-map}"
  57   (interactive "P")
  58   (let (select buffer)
  59     (save-window-excursion
  60       (save-window-excursion (list-buffers arg))
  61       (setq buffer (window-buffer (Electric-pop-up-window "*Buffer List*")))
  62       (unwind-protect
  63           (progn
  64             (set-buffer buffer)
  65             (Electric-buffer-menu-mode)
  66             (setq select
  67                   (catch 'electric-buffer-menu-select
  68                     (message "<<< Press Return to bury the buffer list >>>")
  69                     (if (eq (setq unread-command-events (list (read-event)))
  70                             ?\ )
  71                         (progn (setq unread-command-events nil)
  72                                (throw 'electric-buffer-menu-select nil)))
  73                     (let ((start-point (point))
  74                           (first (progn (goto-char (point-min))
  75                                         (forward-line 2)
  76                                         (point)))
  77                           (last (progn (goto-char (point-max))
  78                                        (forward-line -1)
  79                                        (point)))
  80                           (goal-column 0))
  81                       ;; Use start-point if it is meaningful.
  82                       (goto-char (if (or (< start-point first)
  83                                          (> start-point last))
  84                                      first
  85                                    start-point))
  86                       (Electric-command-loop 'electric-buffer-menu-select
  87                                              nil
  88                                              t
  89                                              'electric-buffer-menu-looper
  90                                              (cons first last))))))
  91         (set-buffer buffer)
  92         (Buffer-menu-mode)
  93         (bury-buffer buffer)
  94         (message "")))
  95     (if select
  96         (progn (set-buffer buffer)
  97                (let ((opoint (point-marker)))
  98                  (Buffer-menu-execute)
  99                  (goto-char (point-min))
 100                  (if (prog1 (search-forward "\n>" nil t)
 101                        (goto-char opoint) (set-marker opoint nil))
 102                      (Buffer-menu-select)
 103                      (switch-to-buffer (Buffer-menu-buffer t))))))))
 104
 105 (defun electric-buffer-menu-looper (state condition)
 106   (cond ((and condition
 107               (not (memq (car condition) '(buffer-read-only
 108                                            end-of-buffer
 109                                            beginning-of-buffer))))
 110          (signal (car condition) (cdr condition)))
 111         ((< (point) (car state))
 112          (goto-char (point-min))
 113          (forward-line 2))
 114         ((> (point) (cdr state))
 115          (goto-char (point-max))
 116          (forward-line -1)
 117          (if (pos-visible-in-window-p (point-max))
 118              (recenter -1)))))
 119
 120 (put 'Electric-buffer-menu-mode 'mode-class 'special)
 121 (defun Electric-buffer-menu-mode ()
 122   "Major mode for editing a list of buffers.
 123 Each line describes one of the buffers in Emacs.
 124 Letters do not insert themselves; instead, they are commands.
 125 \\<electric-buffer-menu-mode-map>
 126 \\[keyboard-quit] or \\[Electric-buffer-menu-quit] -- exit buffer menu, returning to previous window and buffer
 127   configuration.  If the very first character typed is a space, it
 128   also has this effect.
 129 \\[Electric-buffer-menu-select] -- select buffer of line point is on.
 130   Also show buffers marked with m in other windows,
 131   deletes buffers marked with \"D\", and saves those marked with \"S\".
 132 \\[Buffer-menu-mark] -- mark buffer to be displayed.
 133 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 134 \\[Buffer-menu-save] -- mark that buffer to be saved.
 135 \\[Buffer-menu-delete] or \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted.
 136 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 137 \\[Electric-buffer-menu-mode-view-buffer] -- view buffer, returning when done.
 138 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 139
 140 \\{electric-buffer-menu-mode-map}
 141
 142 Entry to this mode via command electric-buffer-list calls the value of
 143 electric-buffer-menu-mode-hook if it is non-nil."
 144   (kill-all-local-variables)
 145   (use-local-map electric-buffer-menu-mode-map)
 146   (setq mode-name "Electric Buffer Menu")
 147   (setq mode-line-buffer-identification "Electric Buffer List")
 148   (make-local-variable 'Helper-return-blurb)
 149   (setq Helper-return-blurb "return to buffer editing")
 150   (setq truncate-lines t)
 151   (setq buffer-read-only t)
 152   (setq major-mode 'Electric-buffer-menu-mode)
 153   (goto-char (point-min))
 154   (if (search-forward "\n." nil t) (forward-char -1))
 155   (run-hooks 'electric-buffer-menu-mode-hook))
 156
 157 ;; generally the same as Buffer-menu-mode-map
 158 ;;  (except we don't indirect to global-map)
 159 (put 'Electric-buffer-menu-undefined 'suppress-keymap t)
 160 (if electric-buffer-menu-mode-map
 161     nil
 162   (let ((map (make-keymap)))
 163     (fillarray (car (cdr map)) 'Electric-buffer-menu-undefined)
 164     (define-key map "\e" nil)
 165     (define-key map "\C-z" 'suspend-emacs)
 166     (define-key map "v" 'Electric-buffer-menu-mode-view-buffer)
 167     (define-key map (char-to-string help-char) 'Helper-help)
 168     (define-key map "?" 'Helper-describe-bindings)
 169     (define-key map "\C-c" nil)
 170     (define-key map "\C-c\C-c" 'Electric-buffer-menu-quit)
 171     (define-key map "\C-]" 'Electric-buffer-menu-quit)
 172     (define-key map "q" 'Electric-buffer-menu-quit)
 173     (define-key map " " 'Electric-buffer-menu-select)
 174     (define-key map "\C-m" 'Electric-buffer-menu-select)
 175     (define-key map "\C-l" 'recenter)
 176     (define-key map "s" 'Buffer-menu-save)
 177     (define-key map "d" 'Buffer-menu-delete)
 178     (define-key map "k" 'Buffer-menu-delete)
 179     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
 180     ;(define-key map "\C-k" 'Buffer-menu-delete)
 181     (define-key map "\177" 'Buffer-menu-backup-unmark)
 182     (define-key map "~" 'Buffer-menu-not-modified)
 183     (define-key map "u" 'Buffer-menu-unmark)
 184     (let ((i ?0))
 185       (while (<= i ?9)
 186         (define-key map (char-to-string i) 'digit-argument)
 187         (define-key map (concat "\e" (char-to-string i)) 'digit-argument)
 188         (setq i (1+ i))))
 189     (define-key map "-" 'negative-argument)
 190     (define-key map "\e-" 'negative-argument)
 191     (define-key map "m" 'Buffer-menu-mark)
 192     (define-key map "\C-u" 'universal-argument)
 193     (define-key map "\C-p" 'previous-line)
 194     (define-key map "\C-n" 'next-line)
 195     (define-key map "p" 'previous-line)
 196     (define-key map "n" 'next-line)
 197     (define-key map "\C-v" 'scroll-up)
 198     (define-key map "\ev" 'scroll-down)
 199     (define-key map ">" 'scroll-right)
 200     (define-key map "<" 'scroll-left)
 201     (define-key map "\e\C-v" 'scroll-other-window)
 202     (define-key map "\e>" 'end-of-buffer)
 203     (define-key map "\e<" 'beginning-of-buffer)
 204     (define-key map "\e\e" nil)
 205     (define-key map "\e\e\e" 'Electric-buffer-menu-quit)
 206     (define-key map [escape escape escape] 'Electric-buffer-menu-quit)
 207     (define-key map [mouse-2] 'Electric-buffer-menu-mouse-select)
 208     (setq electric-buffer-menu-mode-map map)))
 209
 210 (defun Electric-buffer-menu-exit ()
 211   (interactive)
 212   (setq unread-command-events (listify-key-sequence (this-command-keys)))
 213   ;; for robustness
 214   (condition-case ()
 215       (throw 'electric-buffer-menu-select nil)
 216     (error (Buffer-menu-mode)
 217            (other-buffer))))
 218
 219 (defun Electric-buffer-menu-select ()
 220   "Leave Electric Buffer Menu, selecting buffers and executing changes.
 221 Saves buffers marked \"S\".  Deletes buffers marked \"K\".
 222 Selects buffer at point and displays buffers marked \">\" in other windows."
 223   (interactive)
 224   (throw 'electric-buffer-menu-select (point)))
 225
 226 (defun Electric-buffer-menu-mouse-select (event)
 227   (interactive "e")
 228   (select-window (posn-window (event-end event)))
 229   (set-buffer (window-buffer (selected-window)))
 230   (goto-char (posn-point (event-end event)))
 231   (throw 'electric-buffer-menu-select (point)))
 232
 233 (defun Electric-buffer-menu-quit ()
 234   "Leave Electric Buffer Menu, restoring previous window configuration.
 235 Does not execute select, save, or delete commands."
 236   (interactive)
 237   (throw 'electric-buffer-menu-select nil))
 238
 239 (defun Electric-buffer-menu-undefined ()
 240   (interactive)
 241   (ding)
 242   (message "%s"
 243            (if (and (eq (key-binding "\C-c\C-c") 'Electric-buffer-menu-quit)
 244                     (eq (key-binding " ") 'Electric-buffer-menu-select)
 245                     (eq (key-binding (char-to-string help-char)) 'Helper-help)
 246                     (eq (key-binding "?") 'Helper-describe-bindings))
 247                (substitute-command-keys "Type C-c C-c to exit, Space to select, \\[Helper-help] for help, ? for commands")
 248              (substitute-command-keys "\
 249 Type \\[Electric-buffer-menu-quit] to exit, \
 250 \\[Electric-buffer-menu-select] to select, \
 251 \\[Helper-help] for help, \\[Helper-describe-bindings] for commands.")))
 252   (sit-for 4))
 253
 254 (defun Electric-buffer-menu-mode-view-buffer ()
 255   "View buffer on current line in Electric Buffer Menu.
 256 Returns to Electric Buffer Menu when done."
 257   (interactive)
 258   (let ((bufnam (Buffer-menu-buffer nil)))
 259     (if bufnam
 260         (view-buffer bufnam)
 261       (ding)
 262       (message "Buffer %s does not exist!" bufnam)
 263       (sit-for 4))))
 264
 265 (provide 'ebuff-menu)
 266
 267 ;;; ebuff-menu.el ends here