lisp/dos-fns.el

   1 ;;; dos-fns.el --- MS-Dos specific functions.
   2
   3 ;; Copyright (C) 1991, 1993, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: Morten Welinder <terra@diku.dk>
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Part of this code is taken from (or derived from) demacs.
  28
  29 ;;; Code:
  30
  31 ;; This overrides a trivial definition in files.el.
  32 (defun convert-standard-filename (filename)
  33   "Convert a standard file's name to something suitable for the current OS.
  34 This function's standard definition is trivial; it just returns the argument.
  35 However, on some systems, the function is redefined
  36 with a definition that really does change some file names."
  37   (if (or (not (stringp filename))
  38           ;; This catches the case where FILENAME is "x:" or "x:/" or
  39           ;; "/", thus preventing infinite recursion.
  40           (string-match "\\`\\([a-zA-Z]:\\)?[/\\]?\\'" filename))
  41       filename
  42     (let ((flen (length filename)))
  43       ;; If FILENAME has a trailing slash, remove it and recurse.
  44       (if (memq (aref filename (1- flen)) '(?/ ?\\))
  45           (concat (convert-standard-filename
  46                    (substring filename 0 (1- flen)))
  47                   "/")
  48         (let* (;; ange-ftp gets in the way for names like "/foo:bar".
  49                ;; We need to inhibit all magic file names, because
  50                ;; remote file names should never be passed through
  51                ;; this function, as they are not meant for the local
  52                ;; filesystem!
  53                (file-name-handler-alist nil)
  54                (dir
  55                 ;; If FILENAME is "x:foo", file-name-directory returns
  56                 ;; "x:/bar/baz", substituting the current working
  57                 ;; directory on drive x:.  We want to be left with "x:"
  58                 ;; instead.
  59                 (if (and (< 1 flen)
  60                          (eq (aref filename 1) ?:)
  61                          (null (string-match "[/\\]" filename)))
  62                     (substring filename 0 2)
  63                   (file-name-directory filename)))
  64                (dlen-m-1 (1- (length dir)))
  65                (string (copy-sequence (file-name-nondirectory filename)))
  66                (lastchar (aref string (1- (length string))))
  67                i firstdot)
  68           (cond
  69            ((msdos-long-file-names)
  70             ;; Replace characters that are invalid even on Windows.
  71             (while (setq i (string-match "[?*:<>|\"\000-\037]" string))
  72               (aset string i ?!)))
  73            ((not (member string '("" "." "..")))
  74             ;; Change a leading period to a leading underscore.
  75             (if (= (aref string 0) ?.)
  76                 (aset string 0 ?_))
  77             ;; Get rid of invalid characters.
  78             (while (setq i (string-match
  79                             "[^-a-zA-Z0-9_.%~^$!#&{}@`'()\200-\376]"
  80                             string))
  81               (aset string i ?_))
  82             ;; If we don't have a period,
  83             ;; and we have a dash or underscore that isn't the first char,
  84             ;; change that to a period.
  85             (if (and (not (string-match "\\." string))
  86                      (setq i (string-match "[-_]" string 1)))
  87                 (aset string i ?\.))
  88             ;; If we don't have a period in the first 8 chars, insert one.
  89             (if (> (or (string-match "\\." string) (length string))
  90                    8)
  91                 (setq string
  92                       (concat (substring string 0 8)
  93                               "."
  94                               (substring string 8))))
  95             (setq firstdot (or (string-match "\\." string)
  96                                (1- (length string))))
  97             ;; Truncate to 3 chars after the first period.
  98             (if (> (length string) (+ firstdot 4))
  99                 (setq string (substring string 0 (+ firstdot 4))))
 100             ;; Change all periods except the first one into underscores.
 101             (while (string-match "\\." string (1+ firstdot))
 102               (setq i (string-match "\\." string (1+ firstdot)))
 103               (aset string i ?_))
 104             ;; If the last character of the original filename was `~',
 105             ;; make sure the munged name ends with it also.  This is so
 106             ;; a backup file retains its final `~'.
 107             (if (equal lastchar ?~)
 108                 (aset string (1- (length string)) lastchar))))
 109           (concat (if (and (stringp dir)
 110                            (memq (aref dir dlen-m-1) '(?/ ?\\)))
 111                       (concat (convert-standard-filename
 112                                (substring dir 0 dlen-m-1))
 113                               "/")
 114                     (convert-standard-filename dir))
 115                   string))))))
 116
 117 ;; See dos-vars.el for defcustom.
 118 (defvar msdos-shells)
 119
 120 ;;; Override setting chosen at startup.
 121 (defun set-default-process-coding-system ()
 122   (setq default-process-coding-system
 123         (if default-enable-multibyte-characters
 124             '(undecided-dos . undecided-dos)
 125           '(raw-text-dos . raw-text-dos))))
 126
 127 (add-hook 'before-init-hook 'set-default-process-coding-system)
 128
 129 (defvar register-name-alist
 130   '((ax . 0) (bx . 1) (cx . 2) (dx . 3) (si . 4) (di . 5)
 131     (cflag . 6) (flags . 7)
 132     (al . (0 . 0)) (bl . (1 . 0)) (cl . (2 . 0)) (dl . (3 . 0))
 133     (ah . (0 . 1)) (bh . (1 . 1)) (ch . (2 . 1)) (dh . (3 . 1))))
 134
 135 (defun make-register ()
 136   (make-vector 8 0))
 137
 138 (defun register-value (regs name)
 139   (let ((where (cdr (assoc name register-name-alist))))
 140     (cond ((consp where)
 141            (let ((tem (aref regs (car where))))
 142              (if (zerop (cdr where))
 143                  (% tem 256)
 144                (/ tem 256))))
 145           ((numberp where)
 146            (aref regs where))
 147           (t nil))))
 148
 149 (defun set-register-value (regs name value)
 150   (and (numberp value)
 151        (>= value 0)
 152        (let ((where (cdr (assoc name register-name-alist))))
 153          (cond ((consp where)
 154                 (let ((tem (aref regs (car where)))
 155                       (value (logand value 255)))
 156                   (aset regs
 157                         (car where)
 158                         (if (zerop (cdr where))
 159                             (logior (logand tem 65280) value)
 160                           (logior (logand tem 255) (lsh value 8))))))
 161                ((numberp where)
 162                 (aset regs where (logand value 65535))))))
 163   regs)
 164
 165 (defsubst intdos (regs)
 166   (int86 33 regs))
 167
 168 ;; Backward compatibility for obsolescent functions which
 169 ;; set screen size.
 170
 171 (defun mode25 ()
 172   "Changes the number of screen rows to 25."
 173   (interactive)
 174   (set-frame-size (selected-frame) 80 25))
 175
 176 (defun mode4350 ()
 177   "Changes the number of rows to 43 or 50.
 178 Emacs always tries to set the screen height to 50 rows first.
 179 If this fails, it will try to set it to 43 rows, on the assumption
 180 that your video hardware might not support 50-line mode."
 181   (interactive)
 182   (set-frame-size (selected-frame) 80 50)
 183   (if (eq (frame-height (selected-frame)) 50)
 184       nil  ; the original built-in function returned nil
 185     (set-frame-size (selected-frame) 80 43)))
 186
 187 (provide 'dos-fns)
 188
 189 ; dos-fns.el ends here