lisp/composite.el

   1 ;;; composite.el --- Support character composition.
   2
   3 ;; Copyright (C) 1999 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5
   6 ;; Keywords: mule, multilingual, character composition
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 ;;;###autoload
  28 (defconst reference-point-alist
  29   '((tl . 0) (tc . 1) (tr . 2)
  30     (Bl . 3) (Bc . 4) (Br . 5)
  31     (bl . 6) (bc . 7) (br . 8)
  32     (cl . 9) (cc . 10) (cr . 11)
  33     (top-left . 0) (top-center . 1) (top-right . 2)
  34     (base-left . 3) (base-center . 4) (base-right . 5)
  35     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
  36     (center-left . 9) (center-center . 10) (center-right . 11)
  37     ;; For backward compatibility...
  38     (ml . 3) (mc . 10) (mr . 5)
  39     (mid-left . 3) (mid-center . 10) (mid-right . 5))
  40   "Alist of symbols vs integer codes of glyph reference points.
  41 A glyph reference point symbol is to be used to specify a composition
  42 rule in COMPONENTS argument to such functions as `compose-region' and
  43 `make-composition'.
  44
  45 Meanings of glyph reference point codes are as follows:
  46
  47     0----1----2 <---- ascent    0:tl or top-left
  48     |         |                 1:tc or top-center
  49     |         |                 2:tr or top-right
  50     |         |                 3:Bl or base-left     9:cl or center-left
  51     9   10   11 <---- center    4:Bc or base-center  10:cc or center-center
  52     |         |                 5:Br or base-right   11:cr or center-right
  53   --3----4----5-- <-- baseline  6:bl or bottom-left
  54     |         |                 7:bc or bottom-center
  55     6----7----8 <---- descent   8:br or bottom-right
  56
  57 Glyph reference point symbols are to be used to specify composition
  58 rule of the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where
  59 GLOBAL-REF-POINT is a reference point in the overall glyphs already
  60 composed, and NEW-REF-POINT is a reference point in the new glyph to
  61 be added.
  62
  63 For instance, if GLOBAL-REF-POINT is `br' (bottom-right) and
  64 NEW-REF-POINT is `tl' (top-left), the overall glyph is updated as
  65 follows (the point `*' corresponds to both reference points):
  66
  67     +-------+--+ <--- new ascent
  68     |       |  |
  69     | global|  |
  70     | glyph |  |
  71  -- |       |  |-- <--- baseline \(doesn't change)
  72     +----+--*--+
  73     |    | new |
  74     |    |glyph|
  75     +----+-----+ <--- new descent
  76 ")
  77
  78 ;; Encode composition rule RULE into an integer value.  RULE is a cons
  79 ;; of global and new reference point symbols.
  80 ;; This must be compatible with C macro COMPOSITION_ENCODE_RULE
  81 ;; defined in composite.h.
  82
  83 (defun encode-composition-rule (rule)
  84   (if (and (integerp rule) (< rule 144))
  85       ;; Already encoded.
  86       rule
  87     (or (consp rule)
  88         (error "Invalid composition rule: %S" rule))
  89     (let ((gref (car rule))
  90           (nref (cdr rule)))
  91       (or (integerp gref)
  92           (setq gref (cdr (assq gref reference-point-alist))))
  93       (or (integerp nref)
  94           (setq nref (cdr (assq nref reference-point-alist))))
  95       (or (and (>= gref 0) (< gref 12) (>= nref 0) (< nref 12))
  96           (error "Invalid composition rule: %S" rule))
  97       (+ (* gref 12) nref))))
  98
  99 ;; Decode encoded composition rule RULE-CODE.  The value is a cons of
 100 ;; global and new reference point symbols.
 101 ;; This must be compatible with C macro COMPOSITION_DECODE_RULE
 102 ;; defined in composite.h.
 103
 104 (defun decode-composition-rule (rule-code)
 105   (or (and (natnump rule-code) (< rule-code 144))
 106       (error "Invalid encoded composition rule: %S" rule-code))
 107   (let ((gref (car (rassq (/ rule-code 12) reference-point-alist)))
 108         (nref (car (rassq (% rule-code 12) reference-point-alist))))
 109     (or (and gref (symbolp gref) nref (symbolp nref))
 110         (error "Invalid composition rule code: %S" rule-code))
 111     (cons gref nref)))
 112
 113 ;; Encode composition rules in composition components COMPONENTS.  The
 114 ;; value is a copy of COMPONENTS, where composition rules (cons of
 115 ;; global and new glyph reference point symbols) are replaced with
 116 ;; encoded composition rules.  Optional 2nd argument NOCOPY non-nil
 117 ;; means don't make a copy but modify COMPONENTS directly.
 118
 119 (defun encode-composition-components (components &optional nocopy)
 120   (or nocopy
 121       (setq components (copy-sequence components)))
 122   (if (vectorp components)
 123       (let ((len (length components))
 124             (i 1))
 125         (while (< i len)
 126           (aset components i
 127                 (encode-composition-rule (aref components i)))
 128           (setq i (+ i 2))))
 129     (let ((tail (cdr components)))
 130       (while tail
 131         (setcar tail
 132                 (encode-composition-rule (car tail)))
 133         (setq tail (nthcdr 2 tail)))))
 134   components)
 135
 136 ;; Decode composition rule codes in composition components COMPONENTS.
 137 ;; The value is a copy of COMPONENTS, where composition rule codes are
 138 ;; replaced with composition rules (cons of global and new glyph
 139 ;; reference point symbols).  Optional 2nd argument NOCOPY non-nil
 140 ;; means don't make a copy but modify COMPONENTS directly.
 141 ;; It is assumed that COMPONENTS is a vector and is for rule-base
 142 ;; composition, thus (2N+1)th elements are rule codes.
 143
 144 (defun decode-composition-components (components &optional nocopy)
 145   (or nocopy
 146       (setq components (copy-sequence components)))
 147   (let ((len (length components))
 148         (i 1))
 149     (while (< i len)
 150       (aset components i
 151             (decode-composition-rule (aref components i)))
 152       (setq i (+ i 2))))
 153   components)
 154
 155 ;;;###autoload
 156 (defun compose-region (start end &optional components modification-func)
 157   "Compose characters in the current region.
 158
 159 When called from a program, expects these four arguments.
 160
 161 First two arguments START and END are positions (integers or markers)
 162 specifying the region.
 163
 164 Optional 3rd argument COMPONENTS, if non-nil, is a character or a
 165 sequence (vector, list, or string) of integers.
 166
 167 If it is a character, it is an alternate character to display instead
 168 of the text in the region.
 169
 170 If it is a string, the elements are alternate characters.
 171
 172 If it is a vector or list, it is a sequence of alternate characters and
 173 composition rules, where (2N)th elements are characters and (2N+1)th
 174 elements are composition rules to specify how to compose (2N+2)th
 175 elements with previously composed N glyphs.
 176
 177 A composition rule is a cons of global and new glyph reference point
 178 symbols.  See the documentation of `reference-point-alist' for more
 179 detail.
 180
 181 Optional 4th argument MODIFICATION-FUNC is a function to call to
 182 adjust the composition when it gets invalid because of a change of
 183 text in the composition."
 184   (interactive "r")
 185   (let ((modified-p (buffer-modified-p))
 186         (buffer-read-only nil))
 187     (if (or (vectorp components) (listp components))
 188         (setq components (encode-composition-components components)))
 189     (compose-region-internal start end components modification-func)
 190     (set-buffer-modified-p modified-p)))
 191
 192 ;;;###autoload
 193 (defun decompose-region (start end)
 194   "Decompose text in the current region.
 195
 196 When called from a program, expects two arguments,
 197 positions (integers or markers) specifying the region."
 198   (interactive "r")
 199   (let ((modified-p (buffer-modified-p))
 200         (buffer-read-only nil))
 201     (remove-text-properties start end '(composition nil))
 202     (set-buffer-modified-p modified-p)))
 203
 204 ;;;###autoload
 205 (defun compose-string (string &optional start end components modification-func)
 206   "Compose characters in string STRING.
 207
 208 The return value is STRING where `composition' property is put on all
 209 the characters in it.
 210
 211 Optional 2nd and 3rd arguments START and END specify the range of
 212 STRING to be composed.  They defaults to the beginning and the end of
 213 STRING respectively.
 214
 215 Optional 4th argument COMPONENTS, if non-nil, is a character or a
 216 sequence (vector, list, or string) of integers.  See the function
 217 `compose-region' for more detail.
 218
 219 Optional 5th argument MODIFICATION-FUNC is a function to call to
 220 adjust the composition when it gets invalid because of a change of
 221 text in the composition."
 222   (if (or (vectorp components) (listp components))
 223       (setq components (encode-composition-components components)))
 224   (or start (setq start 0))
 225   (or end (setq end (length string)))
 226   (compose-string-internal string start end components modification-func)
 227   string)
 228
 229 ;;;###autoload
 230 (defun decompose-string (string)
 231   "Return STRING where `composition' property is removed."
 232   (remove-text-properties 0 (length string) '(composition nil) string)
 233   string)
 234
 235 ;;;###autoload
 236 (defun compose-chars (&rest args)
 237   "Return a string from arguments in which all characters are composed.
 238 For relative composition, arguments are characters.
 239 For rule-based composition, Mth \(where M is odd) arguments are
 240 characters, and Nth \(where N is even) arguments are composition rules.
 241 A composition rule is a cons of glyph reference points of the form
 242 \(GLOBAL-REF-POINT . NEW-REF-POINT).  See the documentation of
 243 `reference-point-alist' for more detail."
 244   (let (str components)
 245     (if (consp (car (cdr args)))
 246         ;; Rule-base composition.
 247         (let ((len (length args))
 248               (tail (encode-composition-components args 'nocopy)))
 249
 250           (while tail
 251             (setq str (cons (car tail) str))
 252             (setq tail (nthcdr 2 tail)))
 253           (setq str (concat (nreverse str))
 254                 components args))
 255       ;; Relative composition.
 256       (setq str (concat args)))
 257     (compose-string-internal str 0 (length str) components)))
 258
 259 ;;;###autoload
 260 (defun find-composition (pos &optional limit string detail-p)
 261   "Return information about a composition at or nearest to buffer position POS.
 262
 263 If the character at POS has `composition' property, the value is a list
 264 of FROM, TO, and VALID-P.
 265
 266 FROM and TO specify the range of text that has the same `composition'
 267 property, VALID-P is non-nil if and only if this composition is valid.
 268
 269 If there's no composition at POS, and the optional 2nd argument LIMIT
 270 is non-nil, search for a composition toward LIMIT.
 271
 272 If no composition is found, return nil.
 273
 274 Optional 3rd argument STRING, if non-nil, is a string to look for a
 275 composition in; nil means the current buffer.
 276
 277 If a valid composition is found and the optional 4th argument DETAIL-P
 278 is non-nil, the return value is a list of FROM, TO, COMPONENTS,
 279 RELATIVE-P, MOD-FUNC, and WIDTH.
 280
 281 COMPONENTS is a vector of integers, the meaning depends on RELATIVE-P.
 282
 283 RELATIVE-P is t if the composition method is relative, else nil.
 284
 285 If RELATIVE-P is t, COMPONENTS is a vector of characters to be
 286 composed.  If RELATIVE-P is nil, COMPONENTS is a vector of characters
 287 and composition rules as described in `compose-region'.
 288
 289 MOD-FUNC is a modification function of the composition.
 290
 291 WIDTH is a number of columns the composition occupies on the screen."
 292   (let ((result (find-composition-internal pos limit string detail-p)))
 293     (if (and detail-p result (nth 2 result) (not (nth 3 result)))
 294         ;; This is a valid rule-base composition.
 295         (decode-composition-components (nth 2 result) 'nocopy))
 296     result))
 297
 298 \f
 299 ;; A char-table of functions to call for compositions.
 300 ;;;###autoload
 301 (put 'composition-function-table 'char-table-extra-slots 0)
 302
 303 ;;;###autoload
 304 (defvar composition-function-table
 305   (make-char-table 'composition-function-table)
 306   "Char table of patterns and functions to make a composition.
 307
 308 Each element is nil or an alist of PATTERNs vs FUNCs, where PATTERNs
 309 are regular expressions and FUNCs are functions.  FUNC is responsible
 310 for composing text matching the corresponding PATTERN.  FUNC is called
 311 with three arguments FROM, TO, and PATTERN.  See the function
 312 `compose-chars-after' for more detail.
 313
 314 This table is looked up by the first character of a composition when
 315 the composition gets invalid after a change in a buffer.")
 316
 317 ;;;###autoload
 318 (defun compose-chars-after (pos &optional limit)
 319   "Compose characters in current buffer after position POS.
 320
 321 It looks up the char-table `composition-function-table' (which see) by
 322 a character after POS.  If non-nil value is found, the format of the
 323 value should be an alist of PATTERNs vs FUNCs, where PATTERNs are
 324 regular expressions and FUNCs are functions.  If the text after POS
 325 matches one of PATTERNs, call the corresponding FUNC with three
 326 arguments POS, TO, and PATTERN, where TO is the end position of text
 327 matching PATTERN, and return what FUNC returns.  Otherwise, return
 328 nil.
 329
 330 FUNC is responsible for composing the text properly.  The return value
 331 is:
 332   nil -- if no characters were composed.
 333   CHARS (integer) -- if CHARS characters were composed.
 334
 335 Optional 2nd arg LIMIT, if non-nil, limits the matching of text.
 336
 337 This function is the default value of `compose-chars-after-function'."
 338   (let ((tail (aref composition-function-table (char-after pos)))
 339         pattern func result)
 340     (when tail
 341       (save-match-data
 342         (save-excursion
 343           (while (and tail (not func))
 344             (setq pattern (car (car tail))
 345                   func (cdr (car tail)))
 346             (goto-char pos)
 347             (if (if limit
 348                     (and (re-search-forward pattern limit t)
 349                          (= (match-beginning 0) pos))
 350                   (looking-at pattern))
 351                 (setq result (funcall func pos (match-end 0) pattern nil))
 352               (setq func nil tail (cdr tail)))))))
 353       result))
 354
 355 ;;;###autoload
 356 (defun compose-last-chars (args)
 357   "Compose last characters.
 358 The argument is a parameterized event of the form (compose-last-chars N),
 359 where N is the number of characters before point to compose.
 360 This function is intended to be used from input methods.
 361 The global keymap binds special event `compose-last-chars' to this
 362 function.  Input method may generate an event (compose-last-chars N)
 363 after a sequence character events."
 364   (interactive "e")
 365   (let ((chars (nth 1 args)))
 366     (if (and (numberp chars)
 367              (>= (- (point) (point-min)) chars))
 368         (compose-chars-after (- (point) chars) (point)))))
 369
 370 ;;;###autoload(global-set-key [compose-last-chars] 'compose-last-chars)
 371
 372 \f
 373 ;;; The following codes are only for backward compatibility with Emacs
 374 ;;; 20.4 and the earlier.
 375
 376 ;;;###autoload
 377 (defun decompose-composite-char (char &optional type with-composition-rule)
 378   "Convert CHAR to string.
 379 This is only for backward compatibility with Emacs 20.4 and the earlier.
 380
 381 If optional 2nd arg TYPE is non-nil, it is `string', `list', or
 382 `vector'.  In this case, CHAR is converted string, list of CHAR, or
 383 vector of CHAR respectively."
 384   (cond ((or (null type) (eq type 'string)) (char-to-string char))
 385         ((eq type 'list) (list char))
 386         (t (vector char))))
 387
 388 (make-obsolete 'decompose-composite-char 'char-to-string "21.1")
 389
 390 \f
 391 ;;; composite.el ends here