lisp/timezone.el

   1 ;;; timezone.el --- time zone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1996, 1999 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu Umeda
   6 ;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (defvar timezone-world-timezones
  29   '(("PST" .  -800)
  30     ("PDT" .  -700)
  31     ("MST" .  -700)
  32     ("MDT" .  -600)
  33     ("CST" .  -600)
  34     ("CDT" .  -500)
  35     ("EST" .  -500)
  36     ("EDT" .  -400)
  37     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  38     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  39     ("UT"  .  +000)
  40     ("GMT" .  +000)
  41     ("BST" .  +100)
  42     ("MET" .  +100)
  43     ("EET" .  +200)
  44     ("JST" .  +900)
  45     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  46     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  47     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  48     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  49     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  50     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  51     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  52     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  53   "*Time differentials of timezone from GMT in +-HHMM form.
  54 This list is obsolescent, and is present only for backwards compatibility,
  55 because time zone names are ambiguous in practice.
  56 Use `current-time-zone' instead.")
  57
  58 (defvar timezone-months-assoc
  59   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  60     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  61     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  62     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  63   "Alist of first three letters of a month and its numerical representation.")
  64
  65 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  66   "Convert DATE to an arpanet standard date.
  67 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  68 if nil, GMT is assumed.
  69 Optional 3rd argument TIMEZONE specifies a time zone to be represented in;
  70 if nil, the local time zone is assumed."
  71   (let ((new (timezone-fix-time date local timezone)))
  72     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  73                              (timezone-make-time-string
  74                               (aref new 3) (aref new 4) (aref new 5))
  75                              (aref new 6))
  76     ))
  77
  78 (defun timezone-make-date-sortable (date &optional local timezone)
  79   "Convert DATE to a sortable date string.
  80 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  81 if nil, GMT is assumed.
  82 Optional 3rd argument TIMEZONE specifies a timezone to be represented in;
  83 if nil, the local time zone is assumed."
  84   (let ((new (timezone-fix-time date local timezone)))
  85     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  86                                  (timezone-make-time-string
  87                                   (aref new 3) (aref new 4) (aref new 5)))
  88     ))
  89
  90 \f
  91 ;;
  92 ;; Parsers and Constructors of Date and Time
  93 ;;
  94
  95 (defun timezone-make-arpa-date (year month day time &optional timezone)
  96   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  97 Optional argument TIMEZONE specifies a time zone."
  98   (let ((zone
  99          (if (listp timezone)
 100              (let* ((m (timezone-zone-to-minute timezone))
 101                     (absm (if (< m 0) (- m) m)))
 102                (format "%c%02d%02d"
 103                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 104            timezone)))
 105     (format "%02d %s %04d %s %s"
 106             day
 107             (capitalize (car (rassq month timezone-months-assoc)))
 108             year
 109             time
 110             zone)))
 111
 112 (defun timezone-make-sortable-date (year month day time)
 113   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 114   (format "%4d%02d%02d%s"
 115           year month day time))
 116
 117 (defun timezone-make-time-string (hour minute second)
 118   "Make time string from HOUR, MINUTE, and SECOND."
 119   (format "%02d:%02d:%02d" hour minute second))
 120
 121 (defun timezone-parse-date (date)
 122   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 123 19 is prepended to year if necessary.  Timezone may be nil if nothing.
 124 Understands the following styles:
 125  (1) 14 Apr 89 03:20[:12] [GMT]
 126  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 127  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 128  (4) 6 May 1992 1641-JST (Wednesday)
 129  (5) 22-AUG-1993 10:59:12.82
 130  (6) Thu, 11 Apr 16:17:12 91 [MET]
 131  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]
 132  (8) 1996-06-24 21:13:12 [GMT]
 133  (9) 1996-06-24 21:13-ZONE"
 134  ;; Get rid of any text properties.
 135   (and (stringp date)
 136        (or (text-properties-at 0 date)
 137            (next-property-change 0 date))
 138        (setq date (copy-sequence date))
 139        (set-text-properties 0 (length date) nil date))
 140   (let ((date (or date ""))
 141         (year nil)
 142         (month nil)
 143         (day nil)
 144         (time nil)
 145         (zone nil))                     ;This may be nil.
 146     (cond ((string-match
 147             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 148            ;; Styles: (1) and (2) with timezone and buggy timezone
 149            ;; This is most common in mail and news,
 150            ;; so it is worth trying first.
 151            (setq year 3 month 2 day 1 time 4 zone 5))
 152           ((string-match
 153             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 154            ;; Styles: (1) and (2) without timezone
 155            (setq year 3 month 2 day 1 time 4 zone nil))
 156           ((string-match
 157             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 158            ;; Styles: (6) and (7) without timezone
 159            (setq year 6 month 3 day 2 time 4 zone nil))
 160           ((string-match
 161             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 162            ;; Styles: (6) and (7) with timezone and buggy timezone
 163            (setq year 6 month 3 day 2 time 4 zone 7))
 164           ((string-match
 165             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 166            ;; Styles: (3) without timezone
 167            (setq year 4 month 1 day 2 time 3 zone nil))
 168           ((string-match
 169             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 170            ;; Styles: (3) with timezone
 171            (setq year 5 month 1 day 2 time 3 zone 4))
 172           ((string-match
 173             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 174            ;; Styles: (4) with timezone
 175            (setq year 3 month 2 day 1 time 4 zone 5))
 176           ((string-match
 177             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 178            ;; Styles: (5) with timezone.
 179            (setq year 3 month 2 day 1 time 4 zone 6))
 180           ((string-match
 181             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?" date)
 182            ;; Styles: (5) without timezone.
 183            (setq year 3 month 2 day 1 time 4 zone nil))
 184           ((string-match
 185             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 186            ;; Styles: (8) with timezone.
 187            (setq year 1 month 2 day 3 time 4 zone 5))
 188           ((string-match
 189             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+\\)[ \t]*\\([-+a-zA-Z0-9:]+\\)" date)
 190            ;; Styles: (8) with timezone with a colon in it.
 191            (setq year 1 month 2 day 3 time 4 zone 5))
 192           ((string-match
 193             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)" date)
 194            ;; Styles: (8) without timezone.
 195            (setq year 1 month 2 day 3 time 4 zone nil))
 196           )
 197     (when year
 198       (setq year (match-string year date))
 199       ;; Guess ambiguous years.  Assume years < 69 don't predate the
 200       ;; Unix Epoch, so are 2000+.  Three-digit years are assumed to
 201       ;; be relative to 1900.
 202       (if (< (length year) 4)
 203           (let ((y (string-to-int year)))
 204             (if (< y 69)
 205                 (setq y (+ y 100)))
 206             (setq year (int-to-string (+ 1900 y)))))
 207       (setq month
 208             (if (= (aref date (+ (match-beginning month) 2)) ?-)
 209                 ;; Handle numeric months, spanning exactly two digits.
 210                 (substring date
 211                            (match-beginning month)
 212                            (+ (match-beginning month) 2))
 213               (let* ((string (substring date
 214                                         (match-beginning month)
 215                                         (+ (match-beginning month) 3)))
 216                      (monthnum
 217                       (cdr (assoc (upcase string) timezone-months-assoc))))
 218                 (if monthnum
 219                     (int-to-string monthnum)))))
 220       (setq day (match-string day date))
 221       (setq time (match-string time date)))
 222     (if zone (setq zone (match-string zone date)))
 223     ;; Return a vector.
 224     (if (and year month)
 225         (vector year month day time zone)
 226       (vector "0" "0" "0" "0" nil))))
 227
 228 (defun timezone-parse-time (time)
 229   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 230 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 231   (let ((time (or time ""))
 232         hour minute second)
 233     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 234            ;; HH:MM:SS
 235            (setq hour 1 minute 2 second 3))
 236           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 237            ;; HH:MM
 238            (setq hour 1 minute 2 second nil))
 239           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 240            ;; HHMMSS
 241            (setq hour 1 minute 2 second 3))
 242           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 243            ;; HHMM
 244            (setq hour 1 minute 2 second nil))
 245           )
 246     ;; Return [hour minute second]
 247     (vector
 248      (if hour (match-string hour time) "0")
 249      (if minute (match-string minute time) "0")
 250      (if second (match-string second time) "0"))))
 251
 252 \f
 253 ;; Miscellaneous
 254
 255 (defun timezone-zone-to-minute (timezone)
 256   "Translate TIMEZONE to an integer minute offset from GMT.
 257 TIMEZONE can be a cons cell containing the output of current-time-zone,
 258 or an integer of the form +-HHMM, or a time zone name."
 259   (cond
 260      ((consp timezone)
 261       (/ (car timezone) 60))
 262      (timezone
 263       (progn
 264         (setq timezone
 265               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 266                   ;; +900
 267                   timezone))
 268         (if (stringp timezone)
 269             (setq timezone (string-to-int timezone)))
 270         ;; Taking account of minute in timezone.
 271         ;; HHMM -> MM
 272         (let* ((abszone (abs timezone))
 273                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 274           (if (< timezone 0) (- minutes) minutes))))
 275      (t 0)))
 276
 277 (defun timezone-time-from-absolute (date seconds)
 278   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 279 Return a list suitable as an argument to current-time-zone,
 280 or nil if the date cannot be thus represented.
 281 DATE is the number of days elapsed since the (imaginary)
 282 Gregorian date Sunday, December 31, 1 BC."
 283   (let* ((current-time-origin 719163)
 284             ;; (timezone-absolute-from-gregorian 1 1 1970)
 285          (days (- date current-time-origin))
 286          (seconds-per-day (float 86400))
 287          (seconds (+ seconds (* days seconds-per-day)))
 288          (current-time-arithmetic-base (float 65536))
 289          (hi (floor (/ seconds current-time-arithmetic-base)))
 290          (hibase (* hi current-time-arithmetic-base))
 291          (lo (floor (- seconds hibase))))
 292      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 293           (cons hi lo))))
 294
 295 (defun timezone-time-zone-from-absolute (date seconds)
 296   "Compute the local time zone for DATE at time SECONDS after midnight.
 297 Return a list in the same format as current-time-zone's result,
 298 or nil if the local time zone could not be computed.
 299 DATE is the number of days elapsed since the (imaginary)
 300 Gregorian date Sunday, December 31, 1 BC."
 301    (and (fboundp 'current-time-zone)
 302         (let ((utc-time (timezone-time-from-absolute date seconds)))
 303           (and utc-time
 304                (let ((zone (current-time-zone utc-time)))
 305                  (and (car zone) zone))))))
 306
 307 (defun timezone-fix-time (date local timezone)
 308   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 309 If LOCAL is nil, it is assumed to be GMT.
 310 If TIMEZONE is nil, use the local time zone."
 311   (let* ((date   (timezone-parse-date date))
 312          (year   (string-to-int (aref date 0)))
 313          (year   (cond ((< year 69)
 314                         (+ year 2000))
 315                        ((< year 100)
 316                         (+ year 1900))
 317                        ((< year 1000)   ; possible 3-digit years.
 318                         (+ year 1900))
 319                        (t year)))
 320          (month  (string-to-int (aref date 1)))
 321          (day    (string-to-int (aref date 2)))
 322          (time   (timezone-parse-time (aref date 3)))
 323          (hour   (string-to-int (aref time 0)))
 324          (minute (string-to-int (aref time 1)))
 325          (second (string-to-int (aref time 2)))
 326          (local  (or (aref date 4) local)) ;Use original if defined
 327          (timezone
 328           (or timezone
 329               (timezone-time-zone-from-absolute
 330                (timezone-absolute-from-gregorian month day year)
 331                (+ second (* 60 (+ minute (* 60 hour)))))))
 332          (diff   (- (timezone-zone-to-minute timezone)
 333                     (timezone-zone-to-minute local)))
 334          (minute (+ minute diff))
 335          (hour-fix (floor minute 60)))
 336     (setq hour (+ hour hour-fix))
 337     (setq minute (- minute (* 60 hour-fix)))
 338     ;; HOUR may be larger than 24 or smaller than 0.
 339     (cond ((<= 24 hour)                 ;24 -> 00
 340            (setq hour (- hour 24))
 341            (setq day  (1+ day))
 342            (if (< (timezone-last-day-of-month month year) day)
 343                (progn
 344                  (setq month (1+ month))
 345                  (setq day 1)
 346                  (if (< 12 month)
 347                      (progn
 348                        (setq month 1)
 349                        (setq year (1+ year))
 350                        ))
 351                  )))
 352           ((> 0 hour)
 353            (setq hour (+ hour 24))
 354            (setq day  (1- day))
 355            (if (> 1 day)
 356                (progn
 357                  (setq month (1- month))
 358                  (if (> 1 month)
 359                      (progn
 360                        (setq month 12)
 361                        (setq year (1- year))
 362                        ))
 363                  (setq day (timezone-last-day-of-month month year))
 364                  )))
 365           )
 366     (vector year month day hour minute second timezone)))
 367
 368 ;; Partly copied from Calendar program by Edward M. Reingold.
 369 ;; Thanks a lot.
 370
 371 (defun timezone-last-day-of-month (month year)
 372   "The last day in MONTH during YEAR."
 373   (if (and (= month 2) (timezone-leap-year-p year))
 374       29
 375     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 376
 377 (defun timezone-leap-year-p (year)
 378   "Returns t if YEAR is a Gregorian leap year."
 379   (or (and (zerop  (% year 4))
 380            (not (zerop (% year 100))))
 381       (zerop (% year 400))))
 382
 383 (defun timezone-day-number (month day year)
 384   "Return the day number within the year of the date month/day/year."
 385   (let ((day-of-year (+ day (* 31 (1- month)))))
 386     (if (> month 2)
 387         (progn
 388           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 389           (if (timezone-leap-year-p year)
 390               (setq day-of-year (1+ day-of-year)))))
 391     day-of-year))
 392
 393 (defun timezone-absolute-from-gregorian (month day year)
 394   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 395 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 396   (+ (timezone-day-number month day year);; Days this year
 397      (* 365 (1- year));;        + Days in prior years
 398      (/ (1- year) 4);;          + Julian leap years
 399      (- (/ (1- year) 100));;    - century years
 400      (/ (1- year) 400)));;      + Gregorian leap years
 401
 402 (provide 'timezone)
 403
 404 ;;; timezone.el ends here