lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This code implements GNU Emacs' on-line help system, the one invoked by
  29 ;; `M-x help-for-help'.
  30
  31 ;;; Code:
  32
  33 ;; Get the macro make-help-screen when this is compiled,
  34 ;; or run interpreted, but not when the compiled code is loaded.
  35 (eval-when-compile (require 'help-macro))
  36
  37 ;; This makes `with-output-to-temp-buffer' buffers use `help-mode'.
  38 (add-hook 'temp-buffer-setup-hook 'help-mode-setup)
  39 (add-hook 'temp-buffer-show-hook 'help-mode-finish)
  40
  41 (defvar help-map
  42   (let ((map (make-sparse-keymap)))
  43     (define-key map (char-to-string help-char) 'help-for-help)
  44     (define-key map [help] 'help-for-help)
  45     (define-key map [f1] 'help-for-help)
  46     (define-key map "." 'display-local-help)
  47     (define-key map "?" 'help-for-help)
  48
  49     (define-key map "\C-c" 'describe-copying)
  50     (define-key map "\C-d" 'describe-distribution)
  51     (define-key map "\C-e" 'view-emacs-problems)
  52     (define-key map "\C-f" 'view-emacs-FAQ)
  53     (define-key map "\C-m" 'view-order-manuals)
  54     (define-key map "\C-n" 'view-emacs-news)
  55     (define-key map "\C-p" 'describe-project)
  56     (define-key map "\C-t" 'view-todo)
  57     (define-key map "\C-w" 'describe-no-warranty)
  58
  59     ;; This does not fit the pattern, but it is natural given the C-\ command.
  60     (define-key map "\C-\\" 'describe-input-method)
  61
  62     (define-key map "C" 'describe-coding-system)
  63     (define-key map "F" 'Info-goto-emacs-command-node)
  64     (define-key map "I" 'describe-input-method)
  65     (define-key map "K" 'Info-goto-emacs-key-command-node)
  66     (define-key map "L" 'describe-language-environment)
  67     (define-key map "S" 'info-lookup-symbol)
  68
  69     (define-key map "a" 'apropos-command)
  70     (define-key map "b" 'describe-bindings)
  71     (define-key map "c" 'describe-key-briefly)
  72     (define-key map "d" 'apropos-documentation)
  73     (define-key map "e" 'view-echo-area-messages)
  74     (define-key map "f" 'describe-function)
  75     (define-key map "h" 'view-hello-file)
  76
  77     (define-key map "i" 'info)
  78     (define-key map "4i" 'info-other-window)
  79
  80     (define-key map "k" 'describe-key)
  81     (define-key map "l" 'view-lossage)
  82     (define-key map "m" 'describe-mode)
  83     (define-key map "n" 'view-emacs-news)
  84     (define-key map "p" 'finder-by-keyword)
  85     (define-key map "r" 'info-emacs-manual)
  86     (define-key map "s" 'describe-syntax)
  87     (define-key map "t" 'help-with-tutorial)
  88     (define-key map "w" 'where-is)
  89     (define-key map "v" 'describe-variable)
  90     (define-key map "q" 'help-quit)
  91     map)
  92   "Keymap for characters following the Help key.")
  93
  94 (define-key global-map (char-to-string help-char) 'help-command)
  95 (define-key global-map [help] 'help-command)
  96 (define-key global-map [f1] 'help-command)
  97 (fset 'help-command help-map)
  98
  99 (autoload 'finder-by-keyword "finder"
 100   "Find packages matching a given keyword." t)
 101
 102 ;; insert-button makes the action nil if it is not store somewhere
 103 (defvar help-button-cache nil)
 104
 105 \f
 106 (defun help-quit ()
 107   "Just exit from the Help command's command loop."
 108   (interactive)
 109   nil)
 110
 111 (defvar help-return-method nil
 112   "What to do to \"exit\" the help buffer.
 113 This is a list
 114  (WINDOW . t)              delete the selected window (and possibly its frame,
 115                            see `quit-window' and `View-quit'), go to WINDOW.
 116  (WINDOW . quit-window)    do quit-window, then select WINDOW.
 117  (WINDOW BUF START POINT)  display BUF at START, POINT, then select WINDOW.")
 118
 119 (defun print-help-return-message (&optional function)
 120   "Display or return message saying how to restore windows after help command.
 121 This function assumes that `standard-output' is the help buffer.
 122 It computes a message, and applies the optional argument FUNCTION to it.
 123 If FUNCTION is nil, it applies `message', thus displaying the message.
 124 In addition, this function sets up `help-return-method', which see, that
 125 specifies what to do when the user exits the help buffer."
 126   (and (not (get-buffer-window standard-output))
 127        (let ((first-message
 128               (cond ((or
 129                       pop-up-frames
 130                       (special-display-p (buffer-name standard-output)))
 131                      (setq help-return-method (cons (selected-window) t))
 132                      ;; If the help output buffer is a special display buffer,
 133                      ;; don't say anything about how to get rid of it.
 134                      ;; First of all, the user will do that with the window
 135                      ;; manager, not with Emacs.
 136                      ;; Secondly, the buffer has not been displayed yet,
 137                      ;; so we don't know whether its frame will be selected.
 138                      nil)
 139                     (display-buffer-reuse-frames
 140                      (setq help-return-method (cons (selected-window)
 141                                                     'quit-window))
 142                      nil)
 143                     ((not (one-window-p t))
 144                      (setq help-return-method
 145                            (cons (selected-window) 'quit-window))
 146                      "Type \\[display-buffer] RET to restore the other window.")
 147                     (pop-up-windows
 148                      (setq help-return-method (cons (selected-window) t))
 149                      "Type \\[delete-other-windows] to remove help window.")
 150                     (t
 151                      (setq help-return-method
 152                            (list (selected-window) (window-buffer)
 153                                  (window-start) (window-point)))
 154                      "Type \\[switch-to-buffer] RET to remove help window."))))
 155          (funcall (or function 'message)
 156                   (concat
 157                    (if first-message
 158                        (substitute-command-keys first-message))
 159                    (if first-message "  ")
 160                    ;; If the help buffer will go in a separate frame,
 161                    ;; it's no use mentioning a command to scroll, so don't.
 162                    (if (or pop-up-windows
 163                            (special-display-p (buffer-name standard-output)))
 164                        nil
 165                      (if (same-window-p (buffer-name standard-output))
 166                          ;; Say how to scroll this window.
 167                          (substitute-command-keys
 168                           "\\[scroll-up] to scroll the help.")
 169                        ;; Say how to scroll some other window.
 170                        (substitute-command-keys
 171                         "\\[scroll-other-window] to scroll the help."))))))))
 172
 173 ;; So keyboard macro definitions are documented correctly
 174 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 175
 176 (defalias 'help 'help-for-help-internal)
 177 ;; find-function can find this.
 178 (defalias 'help-for-help 'help-for-help-internal)
 179 ;; It can't find this, but nobody will look.
 180 (make-help-screen help-for-help-internal
 181   "a b c C e f F i I k C-k l L m p r s t v w C-c C-d C-f C-n C-p C-t C-w . or ? :"
 182   "You have typed %THIS-KEY%, the help character.  Type a Help option:
 183 \(Use SPC or DEL to scroll through this text.  Type \\<help-map>\\[help-quit] to exit the Help command.)
 184
 185 a  command-apropos.  Type a list of words or a regexp; it shows a list of
 186         commands whose names match.  See also the  apropos  command.
 187 b  describe-bindings.  Display a table of all key bindings.
 188 c  describe-key-briefly.  Type a key sequence;
 189         it displays the command name run by that key sequence.
 190 C  describe-coding-system.  Type the name of the coding system to describe,
 191         or just RET to describe the ones currently in use.
 192 d  apropos-documentation.  Type a pattern (a list of words or a regexp), and
 193         it shows a list of functions, variables, and other items whose
 194         documentation matches that pattern.  See also the apropos command.
 195 e  view-echo-area-messages.  Go to the buffer that logs echo-area messages.
 196 f  describe-function.  Type a function name and you see its documentation.
 197 F  Info-goto-emacs-command-node.  Type a command name;
 198         it goes to the on-line manual's section that describes the command.
 199 h  Display the HELLO file which illustrates various scripts.
 200 i  info.  The Info documentation reader: read on-line manuals.
 201 I  describe-input-method.  Describe a specific input method (if you type
 202         its name) or the current input method (if you type just RET).
 203 k  describe-key.  Type a key sequence;
 204         it displays the full documentation for that key sequence.
 205 K  Info-goto-emacs-key-command-node.  Type a key sequence;
 206         it goes to the on-line manual's section that describes
 207         the command bound to that key.
 208 l  view-lossage.  Show last 100 characters you typed.
 209 L  describe-language-environment.  This describes either a
 210         specific language environment (if you type its name)
 211         or the current language environment (if you type just RET).
 212 m  describe-mode.  Display documentation of current minor modes,
 213         and the current major mode, including their special commands.
 214 n  view-emacs-news.  Display news of recent Emacs changes.
 215 p  finder-by-keyword. Find packages matching a given topic keyword.
 216 r  info-emacs-manual.  Display the Emacs manual in Info mode.
 217 s  describe-syntax.  Display contents of syntax table, plus explanations.
 218 S  info-lookup-symbol.  Type a symbol; it goes to that symbol in the
 219         on-line manual for the programming language used in this buffer.
 220 t  help-with-tutorial.  Select the Emacs learn-by-doing tutorial.
 221 v  describe-variable.  Type name of a variable;
 222         it displays the variable's documentation and value.
 223 w  where-is.  Type a command name; it displays which keystrokes
 224         invoke that command.
 225 .  display-local-help.  Display any available local help at point
 226         in the echo area.
 227
 228 C-c Display Emacs copying permission (GNU General Public License).
 229 C-d Display Emacs ordering information.
 230 C-e Display info about Emacs problems.
 231 C-f Display the Emacs FAQ.
 232 C-m Display how to order printed Emacs manuals.
 233 C-n Display news of recent Emacs changes.
 234 C-p Display information about the GNU project.
 235 C-t Display the Emacs TODO list.
 236 C-w Display information on absence of warranty for GNU Emacs."
 237   help-map)
 238
 239 \f
 240
 241 (defun function-called-at-point ()
 242   "Return a function around point or else called by the list containing point.
 243 If that doesn't give a function, return nil."
 244   (or (with-syntax-table emacs-lisp-mode-syntax-table
 245         (or (condition-case ()
 246                 (save-excursion
 247                   (or (not (zerop (skip-syntax-backward "_w")))
 248                       (eq (char-syntax (following-char)) ?w)
 249                       (eq (char-syntax (following-char)) ?_)
 250                       (forward-sexp -1))
 251                   (skip-chars-forward "'")
 252                   (let ((obj (read (current-buffer))))
 253                     (and (symbolp obj) (fboundp obj) obj)))
 254               (error nil))
 255             (condition-case ()
 256                 (save-excursion
 257                   (save-restriction
 258                     (narrow-to-region (max (point-min)
 259                                            (- (point) 1000)) (point-max))
 260                     ;; Move up to surrounding paren, then after the open.
 261                     (backward-up-list 1)
 262                     (forward-char 1)
 263                     ;; If there is space here, this is probably something
 264                     ;; other than a real Lisp function call, so ignore it.
 265                     (if (looking-at "[ \t]")
 266                         (error "Probably not a Lisp function call"))
 267                     (let ((obj (read (current-buffer))))
 268                       (and (symbolp obj) (fboundp obj) obj))))
 269               (error nil))))
 270       (let* ((str (find-tag-default))
 271              (sym (if str (intern-soft str))))
 272         (if (and sym (fboundp sym))
 273             sym
 274           (save-match-data
 275             (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 276               (setq sym (intern-soft (match-string 1 str)))
 277               (and (fboundp sym) sym)))))))
 278
 279 \f
 280 ;;; `User' help functions
 281
 282 (defun describe-distribution ()
 283   "Display info on how to obtain the latest version of GNU Emacs."
 284   (interactive)
 285   (view-file (expand-file-name "DISTRIB" data-directory)))
 286
 287 (defun describe-copying ()
 288   "Display info on how you may redistribute copies of GNU Emacs."
 289   (interactive)
 290   (view-file (expand-file-name "COPYING" data-directory))
 291   (goto-char (point-min)))
 292
 293 (defun describe-project ()
 294   "Display info on the GNU project."
 295   (interactive)
 296   (view-file (expand-file-name "THE-GNU-PROJECT" data-directory))
 297   (goto-char (point-min)))
 298
 299 (defun describe-no-warranty ()
 300   "Display info on all the kinds of warranty Emacs does NOT have."
 301   (interactive)
 302   (describe-copying)
 303   (let (case-fold-search)
 304     (search-forward "NO WARRANTY")
 305     (recenter 0)))
 306
 307 (defun describe-prefix-bindings ()
 308   "Describe the bindings of the prefix used to reach this command.
 309 The prefix described consists of all but the last event
 310 of the key sequence that ran this command."
 311   (interactive)
 312   (let ((key (this-command-keys)))
 313     (describe-bindings
 314      (if (stringp key)
 315          (substring key 0 (1- (length key)))
 316        (let ((prefix (make-vector (1- (length key)) nil))
 317              (i 0))
 318          (while (< i (length prefix))
 319            (aset prefix i (aref key i))
 320            (setq i (1+ i)))
 321          prefix)))))
 322 ;; Make C-h after a prefix, when not specifically bound,
 323 ;; run describe-prefix-bindings.
 324 (setq prefix-help-command 'describe-prefix-bindings)
 325
 326 (defun view-emacs-news (&optional version)
 327   "Display info on recent changes to Emacs.
 328 With argument, display info only for the selected version."
 329   (interactive "P")
 330   (unless version
 331     (setq version emacs-major-version))
 332   (when (consp version)
 333     (let* ((all-versions
 334             (let (res)
 335               (mapcar
 336                (lambda (file)
 337                  (with-temp-buffer
 338                    (insert-file-contents
 339                     (expand-file-name file data-directory))
 340                    (while (re-search-forward
 341                            (if (member file '("NEWS.18" "NEWS.1-17"))
 342                                "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 343                              "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t)
 344                      (setq res (cons (match-string-no-properties 1) res)))))
 345                (cons "NEWS"
 346                      (directory-files data-directory nil
 347                                       "^NEWS\\.[0-9][-0-9]*$" nil)))
 348               (sort (delete-dups res) (lambda (a b) (string< b a)))))
 349            (current (car all-versions)))
 350       (setq version (completing-read
 351                      (format "Read NEWS for the version (default %s): " current)
 352                      all-versions nil nil nil nil current))
 353       (if (integerp (string-to-number version))
 354           (setq version (string-to-number version))
 355         (unless (or (member version all-versions)
 356                     (<= (string-to-number version) (string-to-number current)))
 357           (error "No news about version %s" version)))))
 358   (when (integerp version)
 359     (cond ((<= version 12)
 360            (setq version (format "1.%d" version)))
 361           ((<= version 18)
 362            (setq version (format "%d" version)))
 363           ((> version emacs-major-version)
 364            (error "No news about emacs %d (yet)" version))))
 365   (let* ((vn (if (stringp version)
 366                  (string-to-number version)
 367                version))
 368          (file (cond
 369                 ((>= vn emacs-major-version) "NEWS")
 370                 ((< vn 18) "NEWS.1-17")
 371                 (t (format "NEWS.%d" vn))))
 372          res)
 373     (view-file (expand-file-name file data-directory))
 374     (widen)
 375     (goto-char (point-min))
 376     (when (stringp version)
 377       (when (re-search-forward
 378              (concat (if (< vn 19)
 379                          "Changes in Emacs[ \t]*"
 380                        "^\* [^0-9\n]*") version "$")
 381              nil t)
 382         (beginning-of-line)
 383         (narrow-to-region
 384          (point)
 385          (save-excursion
 386            (while (and (setq res
 387                              (re-search-forward
 388                               (if (< vn 19)
 389                                   "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 390                                 "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t))
 391                        (equal (match-string-no-properties 1) version)))
 392            (or res (goto-char (point-max)))
 393            (beginning-of-line)
 394            (point)))))))
 395
 396
 397 (defun view-todo (&optional arg)
 398   "Display the Emacs TODO list."
 399   (interactive "P")
 400   (view-file (expand-file-name "TODO" data-directory)))
 401
 402 (defun view-echo-area-messages ()
 403   "View the log of recent echo-area messages: the `*Messages*' buffer.
 404 The number of messages retained in that buffer
 405 is specified by the variable `message-log-max'."
 406   (interactive)
 407   (switch-to-buffer (get-buffer-create "*Messages*")))
 408
 409 (defun view-order-manuals ()
 410   "Display the Emacs ORDERS file."
 411   (interactive)
 412   (view-file (expand-file-name "ORDERS" data-directory))
 413   (goto-address))
 414
 415 (defun view-emacs-FAQ ()
 416   "Display the Emacs Frequently Asked Questions (FAQ) file."
 417   (interactive)
 418   ;; (find-file-read-only (expand-file-name "FAQ" data-directory))
 419   (info "(efaq)"))
 420
 421 (defun view-emacs-problems ()
 422   "Display info on known problems with Emacs and possible workarounds."
 423   (interactive)
 424   (view-file (expand-file-name "PROBLEMS" data-directory)))
 425
 426 (defun view-lossage ()
 427   "Display last 100 input keystrokes.
 428
 429 To record all your input on a file, use `open-dribble-file'."
 430   (interactive)
 431   (help-setup-xref (list #'view-lossage) (interactive-p))
 432   (with-output-to-temp-buffer (help-buffer)
 433     (princ (mapconcat (lambda (key)
 434                         (if (or (integerp key) (symbolp key) (listp key))
 435                             (single-key-description key)
 436                           (prin1-to-string key nil)))
 437                       (recent-keys)
 438                       " "))
 439     (with-current-buffer standard-output
 440       (goto-char (point-min))
 441       (while (progn (move-to-column 50) (not (eobp)))
 442         (when (search-forward " " nil t)
 443           (delete-char -1))
 444         (insert "\n")))
 445     (print-help-return-message)))
 446
 447 \f
 448 ;; Key bindings
 449
 450 (defun describe-bindings (&optional prefix buffer)
 451   "Show a list of all defined keys, and their definitions.
 452 We put that list in a buffer, and display the buffer.
 453
 454 The optional argument PREFIX, if non-nil, should be a key sequence;
 455 then we display only bindings that start with that prefix.
 456 The optional argument BUFFER specifies which buffer's bindings
 457 to display (default, the current buffer).  BUFFER can be a buffer
 458 or a buffer name."
 459   (interactive)
 460   (or buffer (setq buffer (current-buffer)))
 461   (help-setup-xref (list #'describe-bindings prefix buffer) (interactive-p))
 462   (with-current-buffer buffer
 463     (describe-bindings-internal nil prefix)))
 464
 465 ;; This function used to be in keymap.c.
 466 (defun describe-bindings-internal (&optional menus prefix)
 467   "Show a list of all defined keys, and their definitions.
 468 We put that list in a buffer, and display the buffer.
 469
 470 The optional argument MENUS, if non-nil, says to mention menu bindings.
 471 \(Ordinarily these are omitted from the output.)
 472 The optional argument PREFIX, if non-nil, should be a key sequence;
 473 then we display only bindings that start with that prefix."
 474   (interactive)
 475   (let ((buf (current-buffer)))
 476     (with-output-to-temp-buffer "*Help*"
 477       (with-current-buffer standard-output
 478         (describe-buffer-bindings buf prefix menus)))))
 479
 480 (defun where-is (definition &optional insert)
 481   "Print message listing key sequences that invoke the command DEFINITION.
 482 Argument is a command definition, usually a symbol with a function definition.
 483 If INSERT (the prefix arg) is non-nil, insert the message in the buffer."
 484   (interactive
 485    (let ((fn (function-called-at-point))
 486          (enable-recursive-minibuffers t)
 487          val)
 488      (setq val (completing-read
 489                 (if fn
 490                     (format "Where is command (default %s): " fn)
 491                   "Where is command: ")
 492                 obarray 'commandp t))
 493      (list (if (equal val "") fn (intern val)) current-prefix-arg)))
 494   (let ((func (indirect-function definition))
 495         (defs nil)
 496         (standard-output (if insert (current-buffer) t)))
 497     ;; In DEFS, find all symbols that are aliases for DEFINITION.
 498     (mapatoms (lambda (symbol)
 499                 (and (fboundp symbol)
 500                      (not (eq symbol definition))
 501                      (eq func (condition-case ()
 502                                   (indirect-function symbol)
 503                                 (error symbol)))
 504                      (push symbol defs))))
 505     ;; Look at all the symbols--first DEFINITION,
 506     ;; then its aliases.
 507     (dolist (symbol (cons definition defs))
 508       (let* ((remapped (command-remapping symbol))
 509              (keys (where-is-internal
 510                     symbol overriding-local-map nil nil remapped))
 511              (keys (mapconcat 'key-description keys ", "))
 512              string)
 513         (setq string
 514               (if insert
 515                   (if (> (length keys) 0)
 516                       (if remapped
 517                           (format "%s (%s) (remapped from %s)"
 518                                   keys remapped symbol)
 519                         (format "%s (%s)" keys symbol))
 520                     (format "M-x %s RET" symbol))
 521                 (if (> (length keys) 0)
 522                     (if remapped
 523                         (format "%s is remapped to %s which is on %s"
 524                                 symbol remapped keys)
 525                       (format "%s is on %s" symbol keys))
 526                   ;; If this is the command the user asked about,
 527                   ;; and it is not on any key, say so.
 528                   ;; For other symbols, its aliases, say nothing
 529                   ;; about them unless they are on keys.
 530                   (if (eq symbol definition)
 531                       (format "%s is not on any key" symbol)))))
 532         (when string
 533           (unless (eq symbol definition)
 534             (princ ";\n its alias "))
 535           (princ string)))))
 536   nil)
 537
 538 (defun help-key-description (key untranslated)
 539   (let ((string (key-description key)))
 540     (if (or (not untranslated)
 541             (and (eq (aref untranslated 0) ?\e) (not (eq (aref key 0) ?\e))))
 542         string
 543       (let ((otherstring (key-description untranslated)))
 544         (if (equal string otherstring)
 545             string
 546           (format "%s (translated from %s)" string otherstring))))))
 547
 548 (defun describe-key-briefly (&optional key insert untranslated)
 549   "Print the name of the function KEY invokes.  KEY is a string.
 550 If INSERT (the prefix arg) is non-nil, insert the message in the buffer.
 551 If non-nil, UNTRANSLATED is a vector of the untranslated events.
 552 It can also be a number in which case the untranslated events from
 553 the last key hit are used.
 554
 555 If KEY is a menu item or a tool-bar button that is disabled, this command
 556 temporarily enables it to allow getting help on disabled items and buttons."
 557   (interactive
 558    (let ((enable-disabled-menus-and-buttons t)
 559          (cursor-in-echo-area t)
 560          saved-yank-menu)
 561      (unwind-protect
 562          (let (key)
 563            ;; If yank-menu is empty, populate it temporarily, so that
 564            ;; "Select and Paste" menu can generate a complete event.
 565            (when (null (cdr yank-menu))
 566              (setq saved-yank-menu (copy-sequence yank-menu))
 567              (menu-bar-update-yank-menu "(any string)" nil))
 568            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 569            ;; If KEY is a down-event, read and discard the
 570            ;; corresponding up-event.  Note that there are also
 571            ;; down-events on scroll bars and mode lines: the actual
 572            ;; event then is in the second element of the vector.
 573            (and (vectorp key)
 574                 (or (and (eventp (aref key 0))
 575                          (memq 'down (event-modifiers (aref key 0))))
 576                     (and (> (length key) 1)
 577                          (eventp (aref key 1))
 578                          (memq 'down (event-modifiers (aref key 1)))))
 579                 (read-event))
 580            (list
 581             key
 582             (if current-prefix-arg (prefix-numeric-value current-prefix-arg))
 583             1))
 584        ;; Put yank-menu back as it was, if we changed it.
 585        (when saved-yank-menu
 586          (setq yank-menu (copy-sequence saved-yank-menu))
 587          (fset 'yank-menu (cons 'keymap yank-menu))))))
 588   (if (numberp untranslated)
 589       (setq untranslated (this-single-command-raw-keys)))
 590   (let* ((event (if (and (symbolp (aref key 0))
 591                          (> (length key) 1)
 592                          (consp (aref key 1)))
 593                     (aref key 1)
 594                   (aref key 0)))
 595          (modifiers (event-modifiers event))
 596          (standard-output (if insert (current-buffer) t))
 597          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 598                             (memq 'drag modifiers)) " at that spot" ""))
 599          (defn (key-binding key t))
 600          key-desc)
 601     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 602     (if (and (eq defn nil)
 603              (stringp (aref key (1- (length key))))
 604              (eq (key-binding (substring key 0 -1)) 'yank-menu))
 605         (setq defn 'menu-bar-select-yank))
 606     ;; Don't bother user with strings from (e.g.) the select-paste menu.
 607     (if (stringp (aref key (1- (length key))))
 608         (aset key (1- (length key)) "(any string)"))
 609     (if (and (> (length untranslated) 0)
 610              (stringp (aref untranslated (1- (length untranslated)))))
 611         (aset untranslated (1- (length untranslated)) "(any string)"))
 612     ;; Now describe the key, perhaps as changed.
 613     (setq key-desc (help-key-description key untranslated))
 614     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 615         (princ (format "%s%s is undefined" key-desc mouse-msg))
 616       (princ (format "%s%s runs the command %S" key-desc mouse-msg defn)))))
 617
 618 (defun describe-key (&optional key untranslated up-event)
 619   "Display documentation of the function invoked by KEY.
 620 KEY can be any kind of a key sequence; it can include keyboard events,
 621 mouse events, and/or menu events.  When calling from a program,
 622 pass KEY as a string or a vector.
 623
 624 If non-nil, UNTRANSLATED is a vector of the corresponding untranslated events.
 625 It can also be a number, in which case the untranslated events from
 626 the last key sequence entered are used.
 627 UP-EVENT is the up-event that was discarded by reading KEY, or nil.
 628
 629 If KEY is a menu item or a tool-bar button that is disabled, this command
 630 temporarily enables it to allow getting help on disabled items and buttons."
 631   (interactive
 632    (let ((enable-disabled-menus-and-buttons t)
 633          (cursor-in-echo-area t)
 634          saved-yank-menu)
 635      (unwind-protect
 636          (let (key)
 637            ;; If yank-menu is empty, populate it temporarily, so that
 638            ;; "Select and Paste" menu can generate a complete event.
 639            (when (null (cdr yank-menu))
 640              (setq saved-yank-menu (copy-sequence yank-menu))
 641              (menu-bar-update-yank-menu "(any string)" nil))
 642            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 643            (list
 644             key
 645             (prefix-numeric-value current-prefix-arg)
 646             ;; If KEY is a down-event, read the corresponding up-event
 647             ;; and use it as the third argument.
 648             (and (vectorp key)
 649                  (or (and (eventp (aref key 0))
 650                           (memq 'down (event-modifiers (aref key 0))))
 651                      (and (> (length key) 1)
 652                           (eventp (aref key 1))
 653                           (memq 'down (event-modifiers (aref key 1)))))
 654                  (read-event))))
 655        ;; Put yank-menu back as it was, if we changed it.
 656        (when saved-yank-menu
 657          (setq yank-menu (copy-sequence saved-yank-menu))
 658          (fset 'yank-menu (cons 'keymap yank-menu))))))
 659   (if (numberp untranslated)
 660       (setq untranslated (this-single-command-raw-keys)))
 661   (let* ((event (aref key (if (and (symbolp (aref key 0))
 662                                    (> (length key) 1)
 663                                    (consp (aref key 1)))
 664                               1
 665                             0)))
 666          (modifiers (event-modifiers event))
 667          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 668                             (memq 'drag modifiers)) " at that spot" ""))
 669          (defn (key-binding key t))
 670          defn-up defn-up-tricky ev-type
 671          mouse-1-remapped mouse-1-tricky)
 672
 673     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 674     (when (and (eq defn nil)
 675                (stringp (aref key (1- (length key))))
 676                (eq (key-binding (substring key 0 -1)) 'yank-menu))
 677       (setq defn 'menu-bar-select-yank))
 678     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 679         (message "%s%s is undefined"
 680                  (help-key-description key untranslated) mouse-msg)
 681       (help-setup-xref (list #'describe-function defn) (interactive-p))
 682       ;; Don't bother user with strings from (e.g.) the select-paste menu.
 683       (when (stringp (aref key (1- (length key))))
 684         (aset key (1- (length key)) "(any string)"))
 685       (when (and untranslated
 686                  (stringp (aref untranslated (1- (length untranslated)))))
 687         (aset untranslated (1- (length untranslated))
 688               "(any string)"))
 689       ;; Need to do this before erasing *Help* buffer in case event
 690       ;; is a mouse click in an existing *Help* buffer.
 691       (when up-event
 692         (setq ev-type (event-basic-type up-event))
 693         (let ((sequence (vector up-event)))
 694           (when (and (eq ev-type 'mouse-1)
 695                      mouse-1-click-follows-link
 696                      (not (eq mouse-1-click-follows-link 'double))
 697                      (setq mouse-1-remapped
 698                            (mouse-on-link-p (event-start up-event))))
 699             (setq mouse-1-tricky (and (integerp mouse-1-click-follows-link)
 700                                       (> mouse-1-click-follows-link 0)))
 701             (cond ((stringp mouse-1-remapped)
 702                    (setq sequence mouse-1-remapped))
 703                   ((vectorp mouse-1-remapped)
 704                    (setcar up-event (elt mouse-1-remapped 0)))
 705                   (t (setcar up-event 'mouse-2))))
 706           (setq defn-up (key-binding sequence nil nil (event-start up-event)))
 707           (when mouse-1-tricky
 708             (setq sequence (vector up-event))
 709             (aset sequence 0 'mouse-1)
 710             (setq defn-up-tricky (key-binding sequence nil nil (event-start up-event))))))
 711       (with-output-to-temp-buffer (help-buffer)
 712         (princ (help-key-description key untranslated))
 713         (princ (format "\
 714 %s runs the command %S
 715   which is "
 716                        mouse-msg defn))
 717         (describe-function-1 defn)
 718         (when up-event
 719           (unless (or (null defn-up)
 720                       (integerp defn-up)
 721                       (equal defn-up 'undefined))
 722             (princ (format "
 723
 724 ----------------- up-event %s----------------
 725
 726 <%S>%s%s runs the command %S
 727   which is "
 728                            (if mouse-1-tricky "(short click) " "")
 729                            ev-type mouse-msg
 730                            (if mouse-1-remapped
 731                                " is remapped to <mouse-2>\nwhich" "")
 732                            defn-up))
 733             (describe-function-1 defn-up))
 734           (unless (or (null defn-up-tricky)
 735                       (integerp defn-up-tricky)
 736                       (eq defn-up-tricky 'undefined))
 737             (princ (format "
 738
 739 ----------------- up-event (long click) ----------------
 740
 741 Pressing <%S>%s for longer than %d milli-seconds
 742 runs the command %S
 743   which is "
 744                            ev-type mouse-msg
 745                            mouse-1-click-follows-link
 746                            defn-up-tricky))
 747             (describe-function-1 defn-up-tricky)))
 748         (print-help-return-message)))))
 749 \f
 750 (defun describe-mode (&optional buffer)
 751   "Display documentation of current major mode and minor modes.
 752 A brief summary of the minor modes comes first, followed by the
 753 major mode description.  This is followed by detailed
 754 descriptions of the minor modes, each on a separate page.
 755
 756 For this to work correctly for a minor mode, the mode's indicator
 757 variable \(listed in `minor-mode-alist') must also be a function
 758 whose documentation describes the minor mode."
 759   (interactive)
 760   (unless buffer (setq buffer (current-buffer)))
 761   (help-setup-xref (list #'describe-mode buffer)
 762                    (interactive-p))
 763   ;; For the sake of help-do-xref and help-xref-go-back,
 764   ;; don't switch buffers before calling `help-buffer'.
 765   (with-output-to-temp-buffer (help-buffer)
 766     (with-current-buffer buffer
 767       (let (minor-modes)
 768         ;; Older packages do not register in minor-mode-list but only in
 769         ;; minor-mode-alist.
 770         (dolist (x minor-mode-alist)
 771           (setq x (car x))
 772           (unless (memq x minor-mode-list)
 773             (push x minor-mode-list)))
 774         ;; Find enabled minor mode we will want to mention.
 775         (dolist (mode minor-mode-list)
 776           ;; Document a minor mode if it is listed in minor-mode-alist,
 777           ;; non-nil, and has a function definition.
 778           (let ((fmode (or (get mode :minor-mode-function) mode)))
 779             (and (boundp mode) (symbol-value mode)
 780                  (fboundp fmode)
 781                  (let ((pretty-minor-mode
 782                         (if (string-match "\\(\\(-minor\\)?-mode\\)?\\'"
 783                                           (symbol-name fmode))
 784                             (capitalize
 785                              (substring (symbol-name fmode)
 786                                         0 (match-beginning 0)))
 787                           fmode)))
 788                    (push (list fmode pretty-minor-mode
 789                                (format-mode-line (assq mode minor-mode-alist)))
 790                          minor-modes)))))
 791         (setq minor-modes
 792               (sort minor-modes
 793                     (lambda (a b) (string-lessp (cadr a) (cadr b)))))
 794         (when minor-modes
 795           (princ "Enabled minor modes:\n")
 796           (make-local-variable 'help-button-cache)
 797           (with-current-buffer standard-output
 798             (dolist (mode minor-modes)
 799               (let ((mode-function (nth 0 mode))
 800                     (pretty-minor-mode (nth 1 mode))
 801                     (indicator (nth 2 mode)))
 802                 (add-text-properties 0 (length pretty-minor-mode)
 803                                      '(face bold) pretty-minor-mode)
 804                 (save-excursion
 805                   (goto-char (point-max))
 806                   (princ "\n\f\n")
 807                   (push (point-marker) help-button-cache)
 808                   ;; Document the minor modes fully.
 809                   (insert pretty-minor-mode)
 810                   (princ (format " minor mode (%s):\n"
 811                                  (if (zerop (length indicator))
 812                                      "no indicator"
 813                                    (format "indicator%s"
 814                                            indicator))))
 815                   (princ (documentation mode-function)))
 816                 (insert-button pretty-minor-mode
 817                                'action (car help-button-cache)
 818                                'follow-link t
 819                                'help-echo "mouse-2, RET: show full information")
 820                 (newline)))
 821             (forward-line -1)
 822             (fill-paragraph nil)
 823             (forward-line 1))
 824
 825           (princ "\n(Information about these minor modes follows the major mode info.)\n\n"))
 826         ;; Document the major mode.
 827         (let ((mode mode-name))
 828           (with-current-buffer standard-output
 829             (let ((start (point)))
 830               (insert (format-mode-line mode))
 831               (add-text-properties start (point) '(face bold)))))
 832         (princ " mode:\n")
 833         (princ (documentation major-mode)))
 834       (print-help-return-message))))
 835
 836
 837 (defun describe-minor-mode (minor-mode)
 838   "Display documentation of a minor mode given as MINOR-MODE.
 839 MINOR-MODE can be a minor mode symbol or a minor mode indicator string
 840 appeared on the mode-line."
 841   (interactive (list (completing-read
 842                       "Minor mode: "
 843                               (nconc
 844                                (describe-minor-mode-completion-table-for-symbol)
 845                                (describe-minor-mode-completion-table-for-indicator)
 846                                ))))
 847   (if (symbolp minor-mode)
 848       (setq minor-mode (symbol-name minor-mode)))
 849   (let ((symbols (describe-minor-mode-completion-table-for-symbol))
 850         (indicators (describe-minor-mode-completion-table-for-indicator)))
 851     (cond
 852      ((member minor-mode symbols)
 853       (describe-minor-mode-from-symbol (intern minor-mode)))
 854      ((member minor-mode indicators)
 855       (describe-minor-mode-from-indicator minor-mode))
 856      (t
 857       (error "No such minor mode: %s" minor-mode)))))
 858
 859 ;; symbol
 860 (defun describe-minor-mode-completion-table-for-symbol ()
 861   ;; In order to list up all minor modes, minor-mode-list
 862   ;; is used here instead of minor-mode-alist.
 863   (delq nil (mapcar 'symbol-name minor-mode-list)))
 864 (defun describe-minor-mode-from-symbol (symbol)
 865   "Display documentation of a minor mode given as a symbol, SYMBOL"
 866   (interactive (list (intern (completing-read
 867                               "Minor mode symbol: "
 868                               (describe-minor-mode-completion-table-for-symbol)))))
 869   (if (fboundp symbol)
 870       (describe-function symbol)
 871     (describe-variable symbol)))
 872
 873 ;; indicator
 874 (defun describe-minor-mode-completion-table-for-indicator ()
 875   (delq nil
 876         (mapcar (lambda (x)
 877                   (let ((i (format-mode-line x)))
 878                     ;; remove first space if existed
 879                     (cond
 880                      ((= 0 (length i))
 881                       nil)
 882                      ((eq (aref i 0) ?\ )
 883                       (substring i 1))
 884                      (t
 885                       i))))
 886                 minor-mode-alist)))
 887 (defun describe-minor-mode-from-indicator (indicator)
 888   "Display documentation of a minor mode specified by INDICATOR.
 889 If you call this function interactively, you can give indicator which
 890 is currently activated with completion."
 891   (interactive (list
 892                 (completing-read
 893                  "Minor mode indicator: "
 894                  (describe-minor-mode-completion-table-for-indicator))))
 895   (let ((minor-mode (lookup-minor-mode-from-indicator indicator)))
 896     (if minor-mode
 897         (describe-minor-mode-from-symbol minor-mode)
 898       (error "Cannot find minor mode for `%s'" indicator))))
 899
 900 (defun lookup-minor-mode-from-indicator (indicator)
 901   "Return a minor mode symbol from its indicator on the modeline."
 902   ;; remove first space if existed
 903   (if (and (< 0 (length indicator))
 904            (eq (aref indicator 0) ?\ ))
 905       (setq indicator (substring indicator 1)))
 906   (let ((minor-modes minor-mode-alist)
 907         result)
 908     (while minor-modes
 909       (let* ((minor-mode (car (car minor-modes)))
 910              (anindicator (format-mode-line
 911                            (car (cdr (car minor-modes))))))
 912         ;; remove first space if existed
 913         (if (and (stringp anindicator)
 914                  (> (length anindicator) 0)
 915                  (eq (aref anindicator 0) ?\ ))
 916             (setq anindicator (substring anindicator 1)))
 917         (if (equal indicator anindicator)
 918             (setq result minor-mode
 919                   minor-modes nil)
 920           (setq minor-modes (cdr minor-modes)))))
 921     result))
 922
 923 \f
 924 ;;; Automatic resizing of temporary buffers.
 925
 926 (defcustom temp-buffer-max-height (lambda (buffer) (/ (- (frame-height) 2) 2))
 927   "Maximum height of a window displaying a temporary buffer.
 928 This is effective only when Temp Buffer Resize mode is enabled.
 929 The value is the maximum height (in lines) which `resize-temp-buffer-window'
 930 will give to a window displaying a temporary buffer.
 931 It can also be a function to be called to choose the height for such a buffer.
 932 It gets one argumemt, the buffer, and should return a positive integer."
 933   :type '(choice integer function)
 934   :group 'help
 935   :version "20.4")
 936
 937 (define-minor-mode temp-buffer-resize-mode
 938   "Toggle the mode which makes windows smaller for temporary buffers.
 939 With prefix argument ARG, turn the resizing of windows displaying temporary
 940 buffers on if ARG is positive or off otherwise.
 941 This makes the window the right height for its contents, but never
 942 more than `temp-buffer-max-height' nor less than `window-min-height'.
 943 This applies to `help', `apropos' and `completion' buffers, and some others."
 944   :global t :group 'help
 945   (if temp-buffer-resize-mode
 946       ;; `help-make-xrefs' may add a `back' button and thus increase the
 947       ;; text size, so `resize-temp-buffer-window' must be run *after* it.
 948       (add-hook 'temp-buffer-show-hook 'resize-temp-buffer-window 'append)
 949     (remove-hook 'temp-buffer-show-hook 'resize-temp-buffer-window)))
 950
 951 (defun resize-temp-buffer-window ()
 952   "Resize the current window to fit its contents.
 953 Will not make it higher than `temp-buffer-max-height' nor smaller than
 954 `window-min-height'.  Do nothing if it is the only window on its frame, if it
 955 is not as wide as the frame or if some of the window's contents are scrolled
 956 out of view."
 957   (unless (or (one-window-p 'nomini)
 958               (not (pos-visible-in-window-p (point-min)))
 959               (/=  (frame-width) (window-width)))
 960     (fit-window-to-buffer
 961      (selected-window)
 962      (if (functionp temp-buffer-max-height)
 963          (funcall temp-buffer-max-height (current-buffer))
 964        temp-buffer-max-height))))
 965
 966 \f
 967 (provide 'help)
 968
 969 ;; arch-tag: cf427352-27e9-49b7-9a6f-741ebab02423
 970 ;;; help.el ends here