lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer.
   2
   3 ;; Copyright (C) 1986, 1987 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This package provides the sorting facilities documented in the Emacs
  28 ;;; user's manual.
  29
  30 ;;; Code:
  31
  32 (defvar sort-fold-case nil
  33   "*Non-nil if the buffer sort functions should ignore case.")
  34
  35 ;;;###autoload
  36 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  37   "General text sorting routine to divide buffer into records and sort them.
  38 Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  39
  40 We divide the accessible portion of the buffer into disjoint pieces
  41 called sort records.  A portion of each sort record (perhaps all of
  42 it) is designated as the sort key.  The records are rearranged in the
  43 buffer in order by their sort keys.  The records may or may not be
  44 contiguous.
  45
  46 Usually the records are rearranged in order of ascending sort key.
  47 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  48
  49 The next four arguments are functions to be called to move point
  50 across a sort record.  They will be called many times from within sort-subr.
  51
  52 NEXTRECFUN is called with point at the end of the previous record.
  53 It moves point to the start of the next record.
  54 It should move point to the end of the buffer if there are no more records.
  55 The first record is assumed to start at the position of point when sort-subr
  56 is called.
  57
  58 ENDRECFUN is called with point within the record.
  59 It should move point to the end of the record.
  60
  61 STARTKEYFUN moves from the start of the record to the start of the key.
  62 It may return either a non-nil value to be used as the key, or
  63 else the key is the substring between the values of point after
  64 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  65 starts at the beginning of the record.
  66
  67 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  68 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  69 same as ENDRECFUN."
  70   ;; Heuristically try to avoid messages if sorting a small amt of text.
  71   (let ((messages (> (- (point-max) (point-min)) 50000)))
  72     (save-excursion
  73       (if messages (message "Finding sort keys..."))
  74       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  75                                            startkeyfun endkeyfun))
  76              (old (reverse sort-lists))
  77              (case-fold-search sort-fold-case))
  78         (if (null sort-lists)
  79             ()
  80           (or reverse (setq sort-lists (nreverse sort-lists)))
  81           (if messages (message "Sorting records..."))
  82           (setq sort-lists
  83                 (if (fboundp 'sortcar)
  84                     (sortcar sort-lists
  85                              (cond ((numberp (car (car sort-lists)))
  86                                     ;; This handles both ints and floats.
  87                                     '<)
  88                                    ((consp (car (car sort-lists)))
  89                                     (function
  90                                      (lambda (a b)
  91                                        (> 0 (compare-buffer-substrings
  92                                              nil (car a) (cdr a)
  93                                              nil (car b) (cdr b))))))
  94                                    (t
  95                                     'string<)))
  96                   (sort sort-lists
  97                         (cond ((numberp (car (car sort-lists)))
  98                                (function
  99                                 (lambda (a b)
 100                                   (< (car a) (car b)))))
 101                               ((consp (car (car sort-lists)))
 102                                (function
 103                                 (lambda (a b)
 104                                   (> 0 (compare-buffer-substrings
 105                                         nil (car (car a)) (cdr (car a))
 106                                         nil (car (car b)) (cdr (car b)))))))
 107                               (t
 108                                (function
 109                                 (lambda (a b)
 110                                   (string< (car a) (car b)))))))))
 111           (if reverse (setq sort-lists (nreverse sort-lists)))
 112           (if messages (message "Reordering buffer..."))
 113           (sort-reorder-buffer sort-lists old)))
 114       (if messages (message "Reordering buffer... Done"))))
 115   nil)
 116
 117 ;; Parse buffer into records using the arguments as Lisp expressions;
 118 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 119 ;; where KEY is the sort key (a number or string),
 120 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 121
 122 ;; The records appear in the list lastmost first!
 123
 124 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 125   (let ((sort-lists ())
 126         (start-rec nil)
 127         done key)
 128     ;; Loop over sort records.
 129     ;(goto-char (point-min)) -- it is the caller's responsibility to
 130     ;arrange this if necessary
 131     (while (not (eobp))
 132       (setq start-rec (point))          ;save record start
 133       (setq done nil)
 134       ;; Get key value, or move to start of key.
 135       (setq key (catch 'key
 136                   (or (and startkeyfun (funcall startkeyfun))
 137                       ;; If key was not returned as value,
 138                       ;; move to end of key and get key from the buffer.
 139                       (let ((start (point)))
 140                         (funcall (or endkeyfun
 141                                      (prog1 endrecfun (setq done t))))
 142                         (cons start (point))))))
 143       ;; Move to end of this record (start of next one, or end of buffer).
 144       (cond ((prog1 done (setq done nil)))
 145             (endrecfun (funcall endrecfun))
 146             (nextrecfun (funcall nextrecfun) (setq done t)))
 147       (if key (setq sort-lists (cons
 148                                  ;; consing optimization in case in which key
 149                                  ;; is same as record.
 150                                  (if (and (consp key)
 151                                           (equal (car key) start-rec)
 152                                           (equal (cdr key) (point)))
 153                                      (cons key key)
 154                                    (cons key (cons start-rec (point))))
 155                                  sort-lists)))
 156       (and (not done) nextrecfun (funcall nextrecfun)))
 157     sort-lists))
 158
 159 (defun sort-reorder-buffer (sort-lists old)
 160   (let ((inhibit-quit t)
 161         (last (point-min))
 162         (min (point-min)) (max (point-max)))
 163     ;; Make sure insertions done for reordering
 164     ;; do not go after any markers at the end of the sorted region,
 165     ;; by inserting a space to separate them.
 166     (goto-char (point-max))
 167     (insert-before-markers " ")
 168     (narrow-to-region min (1- (point-max)))
 169     (while sort-lists
 170       (goto-char (point-max))
 171       (insert-buffer-substring (current-buffer)
 172                                last
 173                                (nth 1 (car old)))
 174       (goto-char (point-max))
 175       (insert-buffer-substring (current-buffer)
 176                                (nth 1 (car sort-lists))
 177                                (cdr (cdr (car sort-lists))))
 178       (setq last (cdr (cdr (car old)))
 179             sort-lists (cdr sort-lists)
 180             old (cdr old)))
 181     (goto-char (point-max))
 182     (insert-buffer-substring (current-buffer)
 183                              last
 184                              max)
 185     ;; Delete the original copy of the text.
 186     (delete-region min max)
 187     ;; Get rid of the separator " ".
 188     (goto-char (point-max))
 189     (narrow-to-region min (1+ (point)))
 190     (delete-region (point) (1+ (point)))))
 191
 192 ;;;###autoload
 193 (defun sort-lines (reverse beg end)
 194   "Sort lines in region alphabetically; argument means descending order.
 195 Called from a program, there are three arguments:
 196 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 197   (interactive "P\nr")
 198   (save-excursion
 199     (save-restriction
 200       (narrow-to-region beg end)
 201       (goto-char (point-min))
 202       (sort-subr reverse 'forward-line 'end-of-line))))
 203
 204 ;;;###autoload
 205 (defun sort-paragraphs (reverse beg end)
 206   "Sort paragraphs in region alphabetically; argument means descending order.
 207 Called from a program, there are three arguments:
 208 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 209   (interactive "P\nr")
 210   (save-excursion
 211     (save-restriction
 212       (narrow-to-region beg end)
 213       (goto-char (point-min))
 214       (sort-subr reverse
 215                  (function
 216                   (lambda ()
 217                     (while (and (not (eobp)) (looking-at paragraph-separate))
 218                       (forward-line 1))))
 219                  'forward-paragraph))))
 220
 221 ;;;###autoload
 222 (defun sort-pages (reverse beg end)
 223   "Sort pages in region alphabetically; argument means descending order.
 224 Called from a program, there are three arguments:
 225 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 226   (interactive "P\nr")
 227   (save-excursion
 228     (save-restriction
 229       (narrow-to-region beg end)
 230       (goto-char (point-min))
 231       (sort-subr reverse
 232                  (function (lambda () (skip-chars-forward "\n")))
 233                  'forward-page))))
 234 \f
 235 (defvar sort-fields-syntax-table nil)
 236 (if sort-fields-syntax-table nil
 237   (let ((table (make-syntax-table))
 238         (i 0))
 239     (while (< i 256)
 240       (modify-syntax-entry i "w" table)
 241       (setq i (1+ i)))
 242     (modify-syntax-entry ?\  " " table)
 243     (modify-syntax-entry ?\t " " table)
 244     (modify-syntax-entry ?\n " " table)
 245     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 246     (setq sort-fields-syntax-table table)))
 247
 248 ;;;###autoload
 249 (defun sort-numeric-fields (field beg end)
 250   "Sort lines in region numerically by the ARGth field of each line.
 251 Fields are separated by whitespace and numbered from 1 up.
 252 Specified field must contain a number in each line of the region.
 253 With a negative arg, sorts by the ARGth field counted from the right.
 254 Called from a program, there are three arguments:
 255 FIELD, BEG and END.  BEG and END specify region to sort."
 256   (interactive "p\nr")
 257   (sort-fields-1 field beg end
 258                  (function (lambda ()
 259                              (sort-skip-fields field)
 260                              (string-to-number
 261                               (buffer-substring
 262                                 (point)
 263                                 (save-excursion
 264                                   ;; This is just wrong! Even without floats...
 265                                   ;; (skip-chars-forward "[0-9]")
 266                                   (forward-sexp 1)
 267                                   (point))))))
 268                  nil))
 269
 270 ;;;;;###autoload
 271 ;;(defun sort-float-fields (field beg end)
 272 ;;  "Sort lines in region numerically by the ARGth field of each line.
 273 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 274 ;;must contain a floating point number in each line of the region.  With a
 275 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 276 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 277 ;;region to sort."
 278 ;;  (interactive "p\nr")
 279 ;;  (sort-fields-1 field beg end
 280 ;;               (function (lambda ()
 281 ;;                           (sort-skip-fields field)
 282 ;;                           (string-to-number
 283 ;;                            (buffer-substring
 284 ;;                             (point)
 285 ;;                             (save-excursion
 286 ;;                               (re-search-forward
 287 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 288 ;;                               (point))))))
 289 ;;               nil))
 290
 291 ;;;###autoload
 292 (defun sort-fields (field beg end)
 293   "Sort lines in region lexicographically by the ARGth field of each line.
 294 Fields are separated by whitespace and numbered from 1 up.
 295 With a negative arg, sorts by the ARGth field counted from the right.
 296 Called from a program, there are three arguments:
 297 FIELD, BEG and END.  BEG and END specify region to sort."
 298   (interactive "p\nr")
 299   (sort-fields-1 field beg end
 300                  (function (lambda ()
 301                              (sort-skip-fields field)
 302                              nil))
 303                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 304
 305 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 306   (let ((tbl (syntax-table)))
 307     (if (zerop field) (setq field 1))
 308     (unwind-protect
 309         (save-excursion
 310           (save-restriction
 311             (narrow-to-region beg end)
 312             (goto-char (point-min))
 313             (set-syntax-table sort-fields-syntax-table)
 314             (sort-subr nil
 315                        'forward-line 'end-of-line
 316                        startkeyfun endkeyfun)))
 317       (set-syntax-table tbl))))
 318
 319 ;; Position at the beginning of field N on the current line,
 320 ;; assuming point is initially at the beginning of the line.
 321 (defun sort-skip-fields (n)
 322   (if (> n 0)
 323       ;; Skip across N - 1 fields.
 324       (let ((i (1- n)))
 325         (while (> i 0)
 326           (skip-chars-forward " \t")
 327           (skip-chars-forward "^ \t\n")
 328           (setq i (1- i)))
 329         (skip-chars-forward " \t")
 330         (if (eolp)
 331             (error "Line has too few fields: %s"
 332                    (buffer-substring
 333                     (save-excursion (beginning-of-line) (point))
 334                     (save-excursion (end-of-line) (point))))))
 335     (end-of-line)
 336     ;; Skip back across - N - 1 fields.
 337     (let ((i (1- (- n))))
 338       (while (> i 0)
 339         (skip-chars-backward " \t")
 340         (skip-chars-backward "^ \t\n")
 341         (setq i (1- i)))
 342       (skip-chars-backward " \t"))
 343     (if (bolp)
 344         (error "Line has too few fields: %s"
 345                (buffer-substring
 346                 (save-excursion (beginning-of-line) (point))
 347                 (save-excursion (end-of-line) (point)))))
 348     ;; Position at the front of the field
 349     ;; even if moving backwards.
 350     (skip-chars-backward "^ \t\n")))
 351 \f
 352 ;;;###autoload
 353 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 354   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 355 RECORD-REGEXP specifies the textual units which should be sorted.
 356   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 357 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 358   is to be used for sorting.
 359   If it is \"\\digit\" then the digit'th \"\\(...\\)\" match field from
 360   RECORD-REGEXP is used.
 361   If it is \"\\&\" then the whole record is used.
 362   Otherwise, it is a regular-expression for which to search within the record.
 363 If a match for KEY is not found within a record then that record is ignored.
 364
 365 With a negative prefix arg sorts in reverse order.
 366
 367 For example: to sort lines in the region by the first word on each line
 368  starting with the letter \"f\",
 369  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\=\\<f\\w*\\>\""
 370   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 371   ;; other sort-.*fields functions but then again this was before, since it
 372   ;; didn't use the magnitude of the arg to specify anything.
 373   (interactive "P\nsRegexp specifying records to sort:
 374 sRegexp specifying key within record: \nr")
 375   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 376          (setq key-regexp 0))
 377         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 378          (setq key-regexp (- (aref key-regexp 1) ?0))))
 379   (save-excursion
 380     (save-restriction
 381       (narrow-to-region beg end)
 382       (goto-char (point-min))
 383       (let (sort-regexp-record-end) ;isn't dynamic scoping wonderful?
 384         (re-search-forward record-regexp)
 385         (setq sort-regexp-record-end (point))
 386         (goto-char (match-beginning 0))
 387         (sort-subr reverse
 388                    (function (lambda ()
 389                                (and (re-search-forward record-regexp nil 'move)
 390                                     (setq sort-regexp-record-end (match-end 0))
 391                                     (goto-char (match-beginning 0)))))
 392                    (function (lambda ()
 393                                (goto-char sort-regexp-record-end)))
 394                    (function (lambda ()
 395                                (let ((n 0))
 396                                  (cond ((numberp key-regexp)
 397                                         (setq n key-regexp))
 398                                        ((re-search-forward
 399                                           key-regexp sort-regexp-record-end t)
 400                                         (setq n 0))
 401                                        (t (throw 'key nil)))
 402                                  (condition-case ()
 403                                      (if (fboundp 'buffer-substring-lessp)
 404                                          (cons (match-beginning n)
 405                                                (match-end n))
 406                                          (buffer-substring (match-beginning n)
 407                                                            (match-end n)))
 408                                    ;; if there was no such register
 409                                    (error (throw 'key nil)))))))))))
 410
 411 \f
 412 (defvar sort-columns-subprocess t)
 413
 414 ;;;###autoload
 415 (defun sort-columns (reverse &optional beg end)
 416   "Sort lines in region alphabetically by a certain range of columns.
 417 For the purpose of this command, the region includes
 418 the entire line that point is in and the entire line the mark is in.
 419 The column positions of point and mark bound the range of columns to sort on.
 420 A prefix argument means sort into reverse order.
 421
 422 Note that `sort-columns' rejects text that contains tabs,
 423 because tabs could be split across the specified columns
 424 and it doesn't know how to handle that.  Also, when possible,
 425 it uses the `sort' utility program, which doesn't understand tabs.
 426 Use \\[untabify] to convert tabs to spaces before sorting."
 427   (interactive "P\nr")
 428   (save-excursion
 429     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 430       (goto-char (min beg end))
 431       (setq col-beg1 (current-column))
 432       (beginning-of-line)
 433       (setq beg1 (point))
 434       (goto-char (max beg end))
 435       (setq col-end1 (current-column))
 436       (forward-line)
 437       (setq end1 (point))
 438       (setq col-start (min col-beg1 col-end1))
 439       (setq col-end (max col-beg1 col-end1))
 440       (if (search-backward "\t" beg1 t)
 441           (error "sort-columns does not work with tabs.  Use M-x untabify."))
 442       (if (not (eq system-type 'vax-vms))
 443           ;; Use the sort utility if we can; it is 4 times as fast.
 444           (call-process-region beg1 end1 "sort" t t nil
 445                                (if reverse "-rt\n" "-t\n")
 446                                (concat "+0." col-start)
 447                                (concat "-0." col-end))
 448         ;; On VMS, use Emacs's own facilities.
 449         (save-excursion
 450           (save-restriction
 451             (narrow-to-region beg1 end1)
 452             (goto-char beg1)
 453             (sort-subr reverse 'forward-line 'end-of-line
 454                        (function (lambda () (move-to-column col-start) nil))
 455                        (function (lambda () (move-to-column col-end) nil)))))))))
 456
 457 ;;;###autoload
 458 (defun reverse-region (beg end)
 459   "Reverse the order of lines in a region.
 460 From a program takes two point or marker arguments, BEG and END."
 461   (interactive "r")
 462   (if (> beg end)
 463       (let (mid) (setq mid end end beg beg mid)))
 464   (save-excursion
 465     ;; put beg at the start of a line and end and the end of one --
 466     ;; the largest possible region which fits this criteria
 467     (goto-char beg)
 468     (or (bolp) (forward-line 1))
 469     (setq beg (point))
 470     (goto-char end)
 471     ;; the test for bolp is for those times when end is on an empty line;
 472     ;; it is probably not the case that the line should be included in the
 473     ;; reversal; it isn't difficult to add it afterward.
 474     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 475     (setq end (point-marker))
 476     ;; the real work.  this thing cranks through memory on large regions.
 477     (let (ll (do t))
 478       (while do
 479         (goto-char beg)
 480         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 481                        ll))
 482         (setq do (/= (point) end))
 483         (delete-region beg (if do (1+ (point)) (point))))
 484       (while (cdr ll)
 485         (insert (car ll) "\n")
 486         (setq ll (cdr ll)))
 487       (insert (car ll)))))
 488
 489 (provide 'sort)
 490
 491 ;;; sort.el ends here