lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 96, 97, 98, 99, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file parses the command line and gets Emacs running.  Options on
  29 ;; the command line are handled in precedence order.  The order is the
  30 ;; one in the list below; first described means first handled.  Options
  31 ;; within each category (delimited by a bar) are handled in the order
  32 ;; encountered on the command line.
  33
  34 ;; -------------------------
  35 ;; -version                  Print Emacs version to stderr, then exit
  36 ;; --version                 successfully right away.
  37 ;;                           This option is handled by emacs.c
  38 ;; -------------------------
  39 ;; -help                     Print a short usage description and exit
  40 ;; --help                    successfully right away.
  41 ;;                           This option is handled by emacs.c
  42 ;; -------------------------
  43 ;; -nl                       Do not use shared memory (for systems that
  44 ;; -no-shared-memory         support this) for the dumped Emacs data.
  45 ;;                           This option is handled by emacs.c
  46 ;;
  47 ;; -map                      For VMS.
  48 ;; --map-data                This option is handled by emacs.c
  49 ;; -------------------------
  50 ;; -t FILE                   Use FILE as the name of the terminal.
  51 ;; --terminal FILE           Using this implies "-nw" also.
  52 ;;                           This option is handled by emacs.c
  53 ;; -------------------------
  54 ;; -d DISPNAME               Use DISPNAME as the name of the X
  55 ;; -display DISPNAME         display for the initial frame.
  56 ;; --display DISPNAME        This option is handled by emacs.c
  57 ;; -------------------------
  58 ;; -nw                       Do not use a windows system (but use the
  59 ;; --no-windows              terminal instead.)
  60 ;;                           This option is handled by emacs.c
  61 ;; -------------------------
  62 ;; -batch                    Execute noninteractively (messages go to stdout,
  63 ;; --batch                   variable noninteractive set to t)
  64 ;;                           This option is handled by emacs.c
  65 ;; -------------------------
  66 ;; -q                        Do not load user's init file and do not load
  67 ;; -no-init-file             "default.el".  Regardless of this switch,
  68 ;; --no-init-file            "site-start" is still loaded.
  69 ;; -------------------------
  70 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  71 ;; --no-site-file            way to prevent loading that file.)
  72 ;; -------------------------
  73 ;; -u USER                   Load USER's init file instead of the init
  74 ;; -user USER                file belonging to the user starting Emacs.
  75 ;; --user USER
  76 ;; -------------------------
  77 ;; -debug-init               Don't catch errors in init files; let the
  78 ;; --debug-init              debugger run.
  79 ;; -------------------------
  80 ;; -i ICONTYPE               Set type of icon using when Emacs is
  81 ;; -itype ICONTYPE           iconified under X.
  82 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  83 ;;
  84 ;; -iconic                   Start Emacs iconified.
  85 ;; --iconic                  This option is passed on to term/x-win.el
  86 ;; -------------------------
  87 ;; Various X options for colors/fonts/geometry/title etc.
  88 ;; These options are passed on to term/x-win.el which see.
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;; -visit FILE
  92 ;; --visit FILE
  93 ;; -file FILE
  94 ;; --file FILE
  95 ;;
  96 ;; -L DIRNAME                Add DIRNAME to load-path
  97 ;; -directory DIRNAME
  98 ;; --directory DIRNAME
  99 ;;
 100 ;; -l FILE                   Load and execute the Emacs lisp code
 101 ;; -load FILE                in FILE.
 102 ;; --load FILE
 103 ;;
 104 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 105 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 106 ;; --funcall FUNC            and should not be used.  (It's a typo
 107 ;; -e FUNC                   promoted to a feature.)
 108 ;;
 109 ;; -eval FORM                Execute Emacs lisp form FORM.
 110 ;; --eval FORM
 111 ;; -execute EXPR
 112 ;; --execute EXPR
 113 ;;
 114 ;; -insert FILE              Insert the contents of FILE into buffer.
 115 ;; --insert FILE
 116 ;; -------------------------
 117 ;; -kill                     Kill (exit) Emacs right away.
 118 ;; --kill
 119 ;; -------------------------
 120
 121 ;;; Code:
 122
 123 (setq top-level '(normal-top-level))
 124
 125 (defvar command-line-processed nil
 126   "Non-nil once command line has been processed")
 127
 128 (defgroup initialization nil
 129   "Emacs start-up procedure"
 130   :group 'internal)
 131
 132 (defcustom inhibit-startup-message nil
 133   "*Non-nil inhibits the initial startup message.
 134 This is for use in your personal init file, once you are familiar
 135 with the contents of the startup message."
 136   :type 'boolean
 137   :group 'initialization)
 138
 139 (defcustom inhibit-startup-echo-area-message nil
 140   "*Non-nil inhibits the initial startup echo area message.
 141 Setting this variable takes effect
 142 only if you do it with the customization buffer
 143 or if your `.emacs' file contains a line of this form:
 144  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 145 If your `.emacs' file is byte-compiled, use the following form instead:
 146  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 147 Thus, someone else using a copy of your `.emacs' file will see
 148 the startup message unless he personally acts to inhibit it."
 149   :type '(choice (const :tag "Don't inhibit")
 150                  (string :tag "Enter your user name, to inhibit"))
 151   :group 'initialization)
 152
 153 (defcustom inhibit-default-init nil
 154   "*Non-nil inhibits loading the `default' library."
 155   :type 'boolean
 156   :group 'initialization)
 157
 158 (defvar command-switch-alist nil
 159   "Alist of command-line switches.
 160 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 161 HANDLER-FUNCTION receives switch name as sole arg;
 162 remaining command-line args are in the variable `command-line-args-left'.")
 163
 164 (defvar command-line-args-left nil
 165   "List of command-line args not yet processed.")
 166
 167 (defvar command-line-functions nil    ;; lrs 7/31/89
 168   "List of functions to process unrecognized command-line arguments.
 169 Each function should access the dynamically bound variables
 170 `argi' (the current argument) and `command-line-args-left' (the remaining
 171 arguments).  The function should return non-nil only if it recognizes and
 172 processes `argi'.  If it does so, it may consume successive arguments by
 173 altering `command-line-args-left' to remove them.")
 174
 175 (defvar command-line-default-directory nil
 176   "Default directory to use for command line arguments.
 177 This is normally copied from `default-directory' when Emacs starts.")
 178
 179 ;;; This is here, rather than in x-win.el, so that we can ignore these
 180 ;;; options when we are not using X.
 181 (defconst command-line-x-option-alist
 182   '(("-bw" 1 x-handle-numeric-switch border-width)
 183     ("-d" 1 x-handle-display)
 184     ("-display" 1 x-handle-display)
 185     ("-name" 1 x-handle-name-switch)
 186     ("-title" 1 x-handle-switch title)
 187     ("-T" 1 x-handle-switch title)
 188     ("-r" 0 x-handle-switch reverse t)
 189     ("-rv" 0 x-handle-switch reverse t)
 190     ("-reverse" 0 x-handle-switch reverse t)
 191     ("-reverse-video" 0 x-handle-switch reverse t)
 192     ("-fn" 1 x-handle-switch font)
 193     ("-font" 1 x-handle-switch font)
 194     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 195     ("-g" 1 x-handle-geometry)
 196     ("-lsp" 1 x-handle-numeric-switch line-spacing)
 197     ("-geometry" 1 x-handle-geometry)
 198     ("-fg" 1 x-handle-switch foreground-color)
 199     ("-foreground" 1 x-handle-switch foreground-color)
 200     ("-bg" 1 x-handle-switch background-color)
 201     ("-background" 1 x-handle-switch background-color)
 202     ("-ms" 1 x-handle-switch mouse-color)
 203     ("-itype" 0 x-handle-switch icon-type t)
 204     ("-i" 0 x-handle-switch icon-type t)
 205     ("-iconic" 0 x-handle-iconic)
 206     ("-xrm" 1 x-handle-xrm-switch)
 207     ("-cr" 1 x-handle-switch cursor-color)
 208     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 209     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 210     ("-bd" 1 x-handle-switch)
 211     ("--border-width" 1 x-handle-numeric-switch border-width)
 212     ("--display" 1 x-handle-display)
 213     ("--name" 1 x-handle-name-switch)
 214     ("--title" 1 x-handle-switch title)
 215     ("--reverse-video" 0 x-handle-switch reverse t)
 216     ("--font" 1 x-handle-switch font)
 217     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 218     ("--geometry" 1 x-handle-geometry)
 219     ("--foreground-color" 1 x-handle-switch foreground-color)
 220     ("--background-color" 1 x-handle-switch background-color)
 221     ("--mouse-color" 1 x-handle-switch mouse-color)
 222     ("--icon-type" 0 x-handle-switch icon-type t)
 223     ("--iconic" 0 x-handle-iconic)
 224     ("--xrm" 1 x-handle-xrm-switch)
 225     ("--cursor-color" 1 x-handle-switch cursor-color)
 226     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 227     ("--line-spacing" 1 x-handle-numeric-switch line-spacing)
 228     ("--border-color" 1 x-handle-switch border-width))
 229   "Alist of X Windows options.
 230 Each element has the form
 231   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 232 where NAME is the option name string, NUMARGS is the number of arguments
 233 that the option accepts, HANDLER is a function to call to handle the option.
 234 FRAME-PARAM (optional) is the frame parameter this option specifies,
 235 and VALUE is the value which is given to that frame parameter
 236 \(most options use the argument for this, so VALUE is not present).")
 237
 238 (defvar before-init-hook nil
 239   "Normal hook run after handling urgent options but before loading init files.")
 240
 241 (defvar after-init-hook nil
 242   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 243 There is no `condition-case' around the running of these functions;
 244 therefore, if you set `debug-on-error' non-nil in `.emacs',
 245 an error in one of these functions will invoke the debugger.")
 246
 247 (defvar emacs-startup-hook nil
 248   "Normal hook run after loading init files and handling the command line.")
 249
 250 (defvar term-setup-hook nil
 251   "Normal hook run after loading terminal-specific Lisp code.
 252 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 253 so as to override the definitions made by the terminal-specific file.
 254 Emacs never sets this variable itself.")
 255
 256 (defvar keyboard-type nil
 257   "The brand of keyboard you are using.
 258 This variable is used to define
 259 the proper function and keypad keys for use under X.  It is used in a
 260 fashion analogous to the environment variable TERM.")
 261
 262 (defvar window-setup-hook nil
 263   "Normal hook run to initialize window system display.
 264 Emacs runs this hook after processing the command line arguments and loading
 265 the user's init file.")
 266
 267 (defcustom initial-major-mode 'lisp-interaction-mode
 268   "Major mode command symbol to use for the initial *scratch* buffer."
 269   :type 'function
 270   :group 'initialization)
 271
 272 (defcustom init-file-user nil
 273   "Identity of user whose `.emacs' file is or was read.
 274 The value is nil if `-q' or `--no-init-file' was specified,
 275 meaning do not load any init file.
 276
 277 Otherwise, the value may be the null string, meaning use the init file
 278 for the user that originally logged in, or it may be a
 279 string containing a user's name meaning use that person's init file.
 280
 281 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 282 evaluates to the name of the directory where the `.emacs' file was
 283 looked for.
 284
 285 Setting `init-file-user' does not prevent Emacs from loading
 286 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 287   :type '(choice (const :tag "none" nil) string)
 288   :group 'initialization)
 289
 290 (defcustom site-run-file "site-start"
 291   "File containing site-wide run-time initializations.
 292 This file is loaded at run-time before `~/.emacs'.  It contains inits
 293 that need to be in place for the entire site, but which, due to their
 294 higher incidence of change, don't make sense to load into emacs'
 295 dumped image.  Thus, the run-time load order is: 1. file described in
 296 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 297
 298 Don't use the `site-start.el' file for things some users may not like.
 299 Put them in `default.el' instead, so that users can more easily
 300 override them.  Users can prevent loading `default.el' with the `-q'
 301 option or by setting `inhibit-default-init' in their own init files,
 302 but inhibiting `site-start.el' requires `--no-site-file', which
 303 is less convenient."
 304   :type '(choice (const :tag "none" nil) string)
 305   :group 'initialization)
 306
 307 (defcustom mail-host-address nil
 308   "*Name of this machine, for purposes of naming users."
 309   :type '(choice (const nil) string)
 310   :group 'mail)
 311
 312 (defcustom user-mail-address nil
 313   "*Full mailing address of this user.
 314 This is initialized based on `mail-host-address',
 315 after your init file is read, in case it sets `mail-host-address'."
 316   :type 'string
 317   :group 'mail)
 318
 319 (defcustom auto-save-list-file-prefix
 320   (cond ((eq system-type 'ms-dos)
 321          ;; MS-DOS cannot have initial dot, and allows only 8.3 names
 322          "~/_emacs.d/auto-save.list/_s")
 323         (t
 324          "~/.emacs.d/auto-save-list/.saves-"))
 325   "Prefix for generating `auto-save-list-file-name'.
 326 This is used after reading your `.emacs' file to initialize
 327 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 328 if you have not already set `auto-save-list-file-name' yourself.
 329 Directories in the prefix will be created if necessary.
 330 Set this to nil if you want to prevent `auto-save-list-file-name'
 331 from being initialized."
 332   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 333                  string)
 334   :group 'auto-save)
 335
 336 (defvar init-file-debug nil)
 337
 338 (defvar init-file-had-error nil)
 339
 340 (defvar normal-top-level-add-subdirs-inode-list nil)
 341
 342 (defun normal-top-level-add-subdirs-to-load-path ()
 343   "Add all subdirectories of current directory to `load-path'.
 344 More precisely, this uses only the subdirectories whose names
 345 start with letters or digits; it excludes any subdirectory named `RCS'
 346 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 347   (let (dirs
 348         attrs
 349         (pending (list default-directory)))
 350     ;; This loop does a breadth-first tree walk on DIR's subtree,
 351     ;; putting each subdir into DIRS as its contents are examined.
 352     (while pending
 353       (setq dirs (cons (car pending) dirs))
 354       (setq pending (cdr pending))
 355       (let* ((this-dir (car dirs))
 356              (contents (directory-files this-dir))
 357              (default-directory this-dir)
 358              (canonicalized (and (eq system-type 'windows-nt)
 359                                  (untranslated-canonical-name this-dir))))
 360         ;; The Windows version doesn't report meaningful inode
 361         ;; numbers, so use the canonicalized absolute file name of the
 362         ;; directory instead.
 363         (setq attrs (or canonicalized
 364                         (nthcdr 10 (file-attributes this-dir))))
 365         (unless (member attrs normal-top-level-add-subdirs-inode-list)
 366           (setq normal-top-level-add-subdirs-inode-list
 367                 (cons attrs normal-top-level-add-subdirs-inode-list))
 368           (while contents
 369             ;; The lower-case variants of RCS and CVS are for DOS/Windows.
 370             (unless (member (car contents) '("." ".." "RCS" "CVS" "rcs" "cvs"))
 371               (when (and (string-match "\\`[[:alnum:]]" (car contents))
 372                          ;; Avoid doing a `stat' when it isn't necessary
 373                          ;; because that can cause trouble when an NFS server
 374                          ;; is down.
 375                          (not (string-match "\\.elc?\\'" (car contents)))
 376                          (file-directory-p (car contents)))
 377                 (let ((expanded (expand-file-name (car contents))))
 378                   (unless (file-exists-p (expand-file-name ".nosearch"
 379                                                            expanded))
 380                     (setq pending (nconc pending (list expanded)))))))
 381             (setq contents (cdr contents))))))
 382     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 383
 384 ;; This function is called from a subdirs.el file.
 385 ;; It assumes that default-directory is the directory
 386 ;; in which the subdirs.el file exists,
 387 ;; and it adds to load-path the subdirs of that directory
 388 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 389 (defun normal-top-level-add-to-load-path (dirs)
 390   (let ((tail load-path)
 391         (thisdir (directory-file-name default-directory)))
 392     (while (and tail
 393                 ;;Don't go all the way to the nil terminator.
 394                 (cdr tail)
 395                 (not (equal thisdir (car tail)))
 396                 (not (and (memq system-type '(ms-dos windows-nt))
 397                           (equal (downcase thisdir) (downcase (car tail))))))
 398       (setq tail (cdr tail)))
 399     ;;Splice the new section in.
 400     (when tail
 401       (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail))))))
 402
 403 (defun normal-top-level ()
 404   (if command-line-processed
 405       (message "Back to top level.")
 406     (setq command-line-processed t)
 407     ;; Give *Messages* the same default-directory as *scratch*,
 408     ;; just to keep things predictable.
 409     (let ((dir default-directory))
 410       (save-excursion
 411         (set-buffer (get-buffer "*Messages*"))
 412         (setq default-directory dir)))
 413     ;; For root, preserve owner and group when editing files.
 414     (if (equal (user-uid) 0)
 415         (setq backup-by-copying-when-mismatch t))
 416     ;; Look in each dir in load-path for a subdirs.el file.
 417     ;; If we find one, load it, which will add the appropriate subdirs
 418     ;; of that dir into load-path,
 419     ;; Look for a leim-list.el file too.  Loading it will register
 420     ;; available input methods.
 421     (let ((tail load-path)
 422           new)
 423       (while tail
 424         (setq new (cons (car tail) new))
 425         (condition-case nil
 426             (let ((default-directory (car tail)))
 427               (load (expand-file-name "subdirs.el" (car tail)) t t t)))
 428         (condition-case nil
 429             (let ((default-directory (car tail)))
 430               (load (expand-file-name "leim-list.el" (car tail)) t t t)))
 431         (setq tail (cdr tail))))
 432     (if (not (eq system-type 'vax-vms))
 433         (progn
 434           ;; If the PWD environment variable isn't accurate, delete it.
 435           (let ((pwd (getenv "PWD")))
 436             (and (stringp pwd)
 437                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 438                  ;; describes the directory linked to, not FOO itself.
 439                  (or (equal (file-attributes
 440                              (concat (file-name-as-directory pwd) "."))
 441                             (file-attributes
 442                              (concat (file-name-as-directory default-directory)
 443                                      ".")))
 444                      (setq process-environment
 445                            (delete (concat "PWD=" pwd)
 446                                    process-environment)))))))
 447     (setq default-directory (abbreviate-file-name default-directory))
 448     (let ((menubar-bindings-done nil))
 449       (unwind-protect
 450           (command-line)
 451         ;; Do this again, in case .emacs defined more abbreviations.
 452         (setq default-directory (abbreviate-file-name default-directory))
 453         ;; Specify the file for recording all the auto save files of this session.
 454         ;; This is used by recover-session.
 455         (or auto-save-list-file-name
 456             (and auto-save-list-file-prefix
 457                  (setq auto-save-list-file-name
 458                        ;; Under MS-DOS our PID is almost always reused between
 459                        ;; Emacs invocations.  We need something more unique.
 460                        (cond ((eq system-type 'ms-dos)
 461                               ;; We are going to access the auto-save
 462                               ;; directory, so make sure it exists.
 463                               (make-directory
 464                                (file-name-directory auto-save-list-file-prefix)
 465                                t)
 466                               (concat
 467                                (make-temp-name
 468                                 (expand-file-name
 469                                  auto-save-list-file-prefix))
 470                                "~"))
 471                              (t
 472                               (expand-file-name
 473                                (format "%s%d-%s~"
 474                                        auto-save-list-file-prefix
 475                                        (emacs-pid)
 476                                        (system-name))))))))
 477         (run-hooks 'emacs-startup-hook)
 478         (and term-setup-hook
 479              (run-hooks 'term-setup-hook))
 480
 481         ;; Don't do this if we failed to create the initial frame,
 482         ;; for instance due to a dense colormap.
 483         (when frame-initial-frame
 484           ;; Modify the initial frame based on what .emacs puts into
 485           ;; ...-frame-alist.
 486           (if (fboundp 'frame-notice-user-settings)
 487               (frame-notice-user-settings))
 488           (if (fboundp 'frame-set-background-mode)
 489               ;; Set the faces for the initial background mode even if
 490               ;; frame-notice-user-settings didn't (such as on a tty).
 491               ;; frame-set-background-mode is idempotent, so it won't
 492               ;; cause any harm if it's already been done.
 493               (let ((frame-background-mode frame-background-mode)
 494                     (frame (selected-frame))
 495                     term)
 496                 (when (and (null window-system)
 497                            ;; Don't override a possibly customized value.
 498                            (null frame-background-mode)
 499                            ;; Don't override user specifications.
 500                            (null (frame-parameter frame 'reverse))
 501                            (let ((bg (frame-parameter frame 'background-color)))
 502                              (or (null bg)
 503                                  (member bg '(unspecified "unspecified-bg")))))
 504                   (setq term (getenv "TERM"))
 505                   (if (string-match "^\\(xterm\\|rxvt\\|dtterm\\|eterm\\)"
 506                                     term)
 507                       (setq frame-background-mode 'light)))
 508                 (frame-set-background-mode (selected-frame)))))
 509
 510         ;; Now we know the user's default font, so add it to the menu.
 511         (if (fboundp 'font-menu-add-default)
 512             (font-menu-add-default))
 513         (and window-setup-hook
 514              (run-hooks 'window-setup-hook))
 515         (or menubar-bindings-done
 516             (if (display-popup-menus-p)
 517                 (precompute-menubar-bindings)))))))
 518
 519 ;; Precompute the keyboard equivalents in the menu bar items.
 520 (defun precompute-menubar-bindings ()
 521   (let ((submap (lookup-key global-map [menu-bar])))
 522     (while submap
 523       (and (consp (car submap))
 524            (symbolp (car (car submap)))
 525            (stringp (car-safe (cdr (car submap))))
 526            (keymapp (cdr (cdr (car submap))))
 527            (progn
 528              (x-popup-menu nil (cdr (cdr (car submap))))
 529              (if purify-flag
 530                  (garbage-collect))))
 531       (setq submap (cdr submap))))
 532     (setq define-key-rebound-commands t))
 533
 534 ;; Command-line options supported by tty's:
 535 (defconst tty-long-option-alist
 536   '(("--name" .         "-name")
 537     ("--title" .        "-T")
 538     ("--reverse-video" . "-reverse")
 539     ("--foreground-color" . "-fg")
 540     ("--background-color" . "-bg")))
 541
 542 (defconst tool-bar-images-pixel-height 24
 543   "Height in pixels of images in the tool bar.")
 544
 545 (defvar tool-bar-originally-present nil
 546   "Non-nil if tool-bars are present before user and site init files are read.")
 547
 548 ;; Handle the X-like command line parameters "-fg", "-bg", "-name", etc.
 549 (defun tty-handle-args (args)
 550   (let ((rest nil))
 551     (message "%s" args)
 552     (while (and args
 553                 (not (equal (car args) "--")))
 554       (let* ((this (car args))
 555              (orig-this this)
 556              completion argval)
 557         (setq args (cdr args))
 558         ;; Check for long options with attached arguments
 559         ;; and separate out the attached option argument into argval.
 560         (if (string-match "^--[^=]*=" this)
 561             (setq argval (substring this (match-end 0))
 562                   this (substring this 0 (1- (match-end 0)))))
 563         (when (string-match "^--" this)
 564           (setq completion (try-completion this tty-long-option-alist))
 565           (if (eq completion t)
 566               ;; Exact match for long option.
 567               (setq this (cdr (assoc this tty-long-option-alist)))
 568             (if (stringp completion)
 569                 (let ((elt (assoc completion tty-long-option-alist)))
 570                   ;; Check for abbreviated long option.
 571                   (or elt
 572                       (error "Option `%s' is ambiguous" this))
 573                   (setq this (cdr elt)))
 574               ;; Check for a short option.
 575               (setq argval nil this orig-this))))
 576         (cond ((or (string= this "-fg") (string= this "-foreground"))
 577                (or argval (setq argval (car args) args (cdr args)))
 578                (setq default-frame-alist
 579                      (cons (cons 'foreground-color argval)
 580                            default-frame-alist)))
 581               ((or (string= this "-bg") (string= this "-background"))
 582                (or argval (setq argval (car args) args (cdr args)))
 583                (setq default-frame-alist
 584                      (cons (cons 'background-color argval)
 585                            default-frame-alist)))
 586               ((or (string= this "-T") (string= this "-name"))
 587                (or argval (setq argval (car args) args (cdr args)))
 588                (setq default-frame-alist
 589                      (cons
 590                       (cons 'title
 591                             (if (stringp argval)
 592                                 argval
 593                               (let ((case-fold-search t)
 594                                     i)
 595                                 (setq argval (invocation-name))
 596
 597                                 ;; Change any . or * characters in name to
 598                                 ;; hyphens, so as to emulate behavior on X.
 599                                 (while
 600                                     (setq i (string-match "[.*]" argval))
 601                                   (aset argval i ?-))
 602                                 argval)))
 603                       default-frame-alist)))
 604               ((or (string= this "-r")
 605                    (string= this "-rv")
 606                    (string= this "-reverse"))
 607                (setq default-frame-alist
 608                      (cons '(reverse . t)
 609                            default-frame-alist)))
 610               (t (setq rest (cons this rest))))))
 611       (nreverse rest)))
 612
 613 (defun command-line ()
 614   (setq command-line-default-directory default-directory)
 615
 616   ;; Choose a reasonable location for temporary files.
 617   (setq temporary-file-directory
 618         (file-name-as-directory
 619          (cond ((memq system-type '(ms-dos windows-nt))
 620                 (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 621                ((memq system-type '(vax-vms axp-vms))
 622                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 623                (t
 624                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp")))))
 625   (setq small-temporary-file-directory
 626         (if (eq system-type 'ms-dos)
 627             (getenv "TMPDIR")))
 628
 629   ;; See if we should import version-control from the environment variable.
 630   (let ((vc (getenv "VERSION_CONTROL")))
 631     (cond ((eq vc nil))                 ;don't do anything if not set
 632           ((or (string= vc "t")
 633                (string= vc "numbered"))
 634            (setq version-control t))
 635           ((or (string= vc "nil")
 636                (string= vc "existing"))
 637            (setq version-control nil))
 638           ((or (string= vc "never")
 639                (string= vc "simple"))
 640            (setq version-control 'never))))
 641
 642   ;;! This has been commented out; I currently find the behavior when
 643   ;;! split-window-keep-point is nil disturbing, but if I can get used
 644   ;;! to it, then it would be better to eliminate the option.
 645   ;;! ;; Choose a good default value for split-window-keep-point.
 646   ;;! (setq split-window-keep-point (> baud-rate 2400))
 647
 648   ;; Set the default strings to display in mode line for
 649   ;; end-of-line formats that aren't native to this platform.
 650   (cond
 651    ((memq system-type '(ms-dos windows-nt emx))
 652     (setq eol-mnemonic-unix "(Unix)")
 653     (setq eol-mnemonic-mac  "(Mac)"))
 654    ;; Mac-specific settings should come here, once there's a
 655    ;; system-type symbol specific to MacOS.
 656    (t   ; this is for Unix/GNU/Linux systems
 657     (setq eol-mnemonic-dos  "(DOS)")
 658     (setq eol-mnemonic-mac  "(Mac)")))
 659
 660   ;; Read window system's init file if using a window system.
 661   (condition-case error
 662       (if (and window-system (not noninteractive))
 663           (load (concat term-file-prefix
 664                         (symbol-name window-system)
 665                         "-win")
 666                 ;; Every window system should have a startup file;
 667                 ;; barf if we can't find it.
 668                 nil t))
 669     ;; If we can't read it, print the error message and exit.
 670     (error
 671      (princ
 672       (if (eq (car error) 'error)
 673           (apply 'concat (cdr error))
 674         (if (memq 'file-error (get (car error) 'error-conditions))
 675             (format "%s: %s"
 676                      (nth 1 error)
 677                      (mapconcat (lambda (obj) (prin1-to-string obj t))
 678                                 (cdr (cdr error)) ", "))
 679           (format "%s: %s"
 680                    (get (car error) 'error-message)
 681                    (mapconcat (lambda (obj) (prin1-to-string obj t))
 682                               (cdr error) ", "))))
 683       'external-debugging-output)
 684      (terpri 'external-debugging-output)
 685      (setq window-system nil)
 686      (kill-emacs)))
 687
 688   ;; Windowed displays do this inside their *-win.el.
 689   (when (and (not (display-graphic-p))
 690              (not noninteractive))
 691     (setq command-line-args (tty-handle-args command-line-args)))
 692
 693   (set-locale-environment nil)
 694
 695   (let ((done nil)
 696         (args (cdr command-line-args)))
 697
 698     ;; Figure out which user's init file to load,
 699     ;; either from the environment or from the options.
 700     (setq init-file-user (if noninteractive nil (user-login-name)))
 701     ;; If user has not done su, use current $HOME to find .emacs.
 702     (and init-file-user (string= init-file-user (user-real-login-name))
 703          (setq init-file-user ""))
 704
 705     ;; Process the command-line args, and delete the arguments
 706     ;; processed.  This is consistent with the way main in emacs.c
 707     ;; does things.
 708     (while (and (not done) args)
 709       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 710                         ("--debug-init") ("--iconic") ("--icon-type")))
 711             (argi (car args))
 712             (argval nil))
 713         ;; Handle --OPTION=VALUE format.
 714         (if (and (string-match "\\`--" argi)
 715                  (string-match "=" argi))
 716             (setq argval (substring argi (match-end 0))
 717                   argi (substring argi 0 (match-beginning 0))))
 718         (or (equal argi "--")
 719             (let ((completion (try-completion argi longopts)))
 720               (if (eq completion t)
 721                   (setq argi (substring argi 1))
 722                 (if (stringp completion)
 723                     (let ((elt (assoc completion longopts)))
 724                       (or elt
 725                           (error "Option `%s' is ambiguous" argi))
 726                       (setq argi (substring (car elt) 1)))
 727                   (setq argval nil)))))
 728         (cond
 729          ((or (string-equal argi "-q")
 730               (string-equal argi "-no-init-file"))
 731           (setq init-file-user nil
 732                 args (cdr args)))
 733          ((or (string-equal argi "-u")
 734               (string-equal argi "-user"))
 735           (or argval
 736               (setq args (cdr args)
 737                     argval (car args)))
 738           (setq init-file-user argval
 739                 argval nil
 740                 args (cdr args)))
 741          ((string-equal argi "-no-site-file")
 742           (setq site-run-file nil
 743                 args (cdr args)))
 744          ((string-equal argi "-debug-init")
 745           (setq init-file-debug t
 746                 args (cdr args)))
 747          ((string-equal argi "-iconic")
 748           (setq initial-frame-alist
 749                 (cons '(visibility . icon) initial-frame-alist))
 750           (setq args (cdr args)))
 751          ((or (string-equal argi "-icon-type")
 752               (string-equal argi "-i")
 753               (string-equal argi "-itype"))
 754           (setq default-frame-alist
 755                 (cons '(icon-type . t) default-frame-alist))
 756           (setq args (cdr args)))
 757          (t (setq done t)))
 758         ;; Was argval set but not used?
 759         (and argval
 760              (error "Option `%s' doesn't allow an argument" argi))))
 761
 762     ;; Re-attach the program name to the front of the arg list.
 763     (and command-line-args (setcdr command-line-args args)))
 764
 765   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 766   (when (fboundp 'frame-initialize)
 767     (frame-initialize))
 768
 769   ;; If frame was created with a menu bar, set menu-bar-mode on.
 770   (if (and (not noninteractive)
 771            (or (not (memq window-system '(x w32)))
 772                (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0)))
 773       (menu-bar-mode t))
 774
 775   ;; If frame was created with a tool bar, switch tool-bar-mode on.
 776   (when (and (not noninteractive)
 777              (display-graphic-p)
 778              (> (frame-parameter nil 'tool-bar-lines) 0))
 779     (tool-bar-mode 1))
 780
 781   ;; Can't do this init in defcustom because window-system isn't set.
 782   (when (and (not noninteractive)
 783              (not (eq system-type 'ms-dos))
 784              (memq window-system '(x w32)))
 785     (setq-default blink-cursor t)
 786     (blink-cursor-mode 1))
 787
 788   (unless noninteractive
 789     ;; DOS/Windows systems have a PC-type keyboard which has both
 790     ;; <delete> and <backspace> keys.
 791     (when (or (memq system-type '(ms-dos windows-nt))
 792               (and (memq window-system '(x))
 793                    (fboundp 'x-backspace-delete-keys-p)
 794                    (x-backspace-delete-keys-p)))
 795       (setq-default normal-erase-is-backspace t)
 796       (normal-erase-is-backspace-mode 1)))
 797
 798   (when (and (not noninteractive)
 799              (display-graphic-p)
 800              (fboundp 'x-show-tip))
 801     (setq-default tooltip-mode t)
 802     (tooltip-mode 1))
 803
 804   ;; Register default TTY colors for the case the terminal hasn't a
 805   ;; terminal init file.
 806   (or (memq window-system '(x w32))
 807       (not (tty-display-color-p))
 808       (let* ((colors (cond ((eq window-system 'pc)
 809                             msdos-color-values)
 810                            ((eq system-type 'windows-nt)
 811                             w32-tty-standard-colors)
 812                            (t tty-standard-colors)))
 813              (color (car colors)))
 814         (while colors
 815           (tty-color-define (car color) (cadr color) (cddr color))
 816           (setq colors (cdr colors) color (car colors)))
 817         ;; Modifying color mappings means realized faces don't
 818         ;; use the right colors, so clear them.
 819         (clear-face-cache)))
 820
 821   ;; Record whether the tool-bar is present before the user and site
 822   ;; init files are processed.  frame-notice-user-settings uses this
 823   ;; to determine if the tool-bar has been disabled by the init files,
 824   ;; and the frame needs to be resized.
 825   (when (fboundp 'frame-notice-user-settings)
 826     (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 827                               (assq 'tool-bar-lines default-frame-alist))))
 828       (setq tool-bar-originally-present
 829             (not (or (null tool-bar-lines)
 830                      (null (cdr tool-bar-lines))
 831                      (eq 0 (cdr tool-bar-lines)))))))
 832
 833   (let ((old-scalable-fonts-allowed scalable-fonts-allowed)
 834         (old-font-list-limit font-list-limit)
 835         (old-face-ignored-fonts face-ignored-fonts))
 836
 837     (run-hooks 'before-init-hook)
 838
 839     ;; Run the site-start library if it exists.  The point of this file is
 840     ;; that it is run before .emacs.  There is no point in doing this after
 841     ;; .emacs; that is useless.
 842     (if site-run-file
 843         (load site-run-file t t))
 844
 845     ;; Sites should not disable this.  Only individuals should disable
 846     ;; the startup message.
 847     (setq inhibit-startup-message nil)
 848
 849     ;; Load that user's init file, or the default one, or none.
 850     (let (debug-on-error-from-init-file
 851           debug-on-error-should-be-set
 852           (debug-on-error-initial
 853            (if (eq init-file-debug t) 'startup init-file-debug))
 854           (orig-enable-multibyte default-enable-multibyte-characters))
 855       (let ((debug-on-error debug-on-error-initial)
 856             ;; This function actually reads the init files.
 857             (inner
 858              (function
 859               (lambda ()
 860                 (if init-file-user
 861                     (let ((user-init-file-1
 862                            (cond
 863                             ((eq system-type 'ms-dos)
 864                              (concat "~" init-file-user "/_emacs"))
 865                             ((eq system-type 'windows-nt)
 866                              (if (directory-files "~" nil "^\\.emacs\\(\\.elc?\\)?$")
 867                                  "~/.emacs"
 868                                "~/_emacs"))
 869                             ((eq system-type 'vax-vms)
 870                              "sys$login:.emacs")
 871                             (t
 872                              (concat "~" init-file-user "/.emacs")))))
 873                       ;; This tells `load' to store the file name found
 874                       ;; into user-init-file.
 875                       (setq user-init-file t)
 876                       (load user-init-file-1 t t)
 877
 878                       ;; If we did not find the user's init file,
 879                       ;; set user-init-file conclusively to nil;
 880                       ;; don't let it be set from default.el.
 881                       (if (eq user-init-file t)
 882                           (setq user-init-file nil))
 883
 884                       ;; If we loaded a compiled file, set
 885                       ;; `user-init-file' to the source version if that
 886                       ;; exists.
 887                       (when (and user-init-file
 888                                  (equal (file-name-extension user-init-file)
 889                                         "elc"))
 890                         (let* ((source (file-name-sans-extension user-init-file))
 891                                (alt (concat source ".el")))
 892                           (setq source (cond ((file-exists-p alt) alt)
 893                                              ((file-exists-p source) source)
 894                                              (t nil)))
 895                           (when source
 896                             (when (file-newer-than-file-p source user-init-file)
 897                               (message "Warning: %s is newer than %s"
 898                                        source user-init-file)
 899                               (sit-for 1))
 900                             (setq user-init-file source))))
 901
 902                       (or inhibit-default-init
 903                           (let ((inhibit-startup-message nil))
 904                             ;; Users are supposed to be told their rights.
 905                             ;; (Plus how to get help and how to undo.)
 906                             ;; Don't you dare turn this off for anyone
 907                             ;; except yourself.
 908                             (load "default" t t)))))))))
 909         (if init-file-debug
 910             ;; Do this without a condition-case if the user wants to debug.
 911             (funcall inner)
 912           (condition-case error
 913               (progn
 914                 (funcall inner)
 915                 (setq init-file-had-error nil))
 916             (error
 917              (let ((message-log-max nil))
 918                (save-excursion
 919                  (set-buffer (get-buffer-create "*Messages*"))
 920                  (insert "\n\n"
 921                          (format "An error has occurred while loading `%s':\n\n"
 922                                  user-init-file)
 923                          (format "%s%s%s"
 924                                  (get (car error) 'error-message)
 925                                  (if (cdr error) ": " "")
 926                                  (mapconcat 'prin1-to-string (cdr error) ", "))
 927                          "\n\n"
 928                          "To ensure normal operation, you should investigate the cause\n"
 929                          "of the error in your initialization file and remove it.  Start\n"
 930                          "Emacs with the `--debug-init' option to view a complete error\n"
 931                          "backtrace\n"))
 932                (message "Error in init file: %s%s%s"
 933                         (get (car error) 'error-message)
 934                         (if (cdr error) ": " "")
 935                         (mapconcat 'prin1-to-string (cdr error) ", "))
 936                (pop-to-buffer "*Messages*")
 937                (setq init-file-had-error t)))))
 938         ;; If we can tell that the init file altered debug-on-error,
 939         ;; arrange to preserve the value that it set up.
 940         (or (eq debug-on-error debug-on-error-initial)
 941             (setq debug-on-error-should-be-set t
 942                   debug-on-error-from-init-file debug-on-error)))
 943       (if debug-on-error-should-be-set
 944           (setq debug-on-error debug-on-error-from-init-file))
 945       (unless (or default-enable-multibyte-characters
 946                   (eq orig-enable-multibyte default-enable-multibyte-characters))
 947         ;; Init file changed to unibyte.  Reset existing multibyte
 948         ;; buffers (probably *scratch*, *Messages*, *Minibuff-0*).
 949         ;; Arguably this should only be done if they're free of
 950         ;; multibyte characters.
 951         (mapcar (lambda (buffer)
 952                   (with-current-buffer buffer
 953                     (if enable-multibyte-characters
 954                         (set-buffer-multibyte nil))))
 955                 (buffer-list))
 956         ;; Also re-set the language environment in case it was
 957         ;; originally done before unibyte was set and is sensitive to
 958         ;; unibyte (display table, terminal coding system &c).
 959         (set-language-environment current-language-environment)))
 960
 961     ;; Do this here in case the init file sets mail-host-address.
 962     (or user-mail-address
 963         (setq user-mail-address (concat (user-login-name) "@"
 964                                         (or mail-host-address
 965                                             (system-name)))))
 966
 967     ;; If parameter have been changed in the init file which influence
 968     ;; face realization, clear the face cache so that new faces will
 969     ;; be realized.
 970     (unless (and (eq scalable-fonts-allowed old-scalable-fonts-allowed)
 971                  (eq font-list-limit old-font-list-limit)
 972                  (eq face-ignored-fonts old-face-ignored-fonts))
 973       (clear-face-cache)))
 974
 975   (run-hooks 'after-init-hook)
 976
 977   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 978   (if (get-buffer "*scratch*")
 979       (save-excursion
 980         (set-buffer "*scratch*")
 981         (if (eq major-mode 'fundamental-mode)
 982             (funcall initial-major-mode))))
 983
 984   ;; Load library for our terminal type.
 985   ;; User init file can set term-file-prefix to nil to prevent this.
 986   (and term-file-prefix (not noninteractive) (not window-system)
 987        (let ((term (getenv "TERM"))
 988              hyphend)
 989          (while (and term
 990                      (not (load (concat term-file-prefix term) t t)))
 991            ;; Strip off last hyphen and what follows, then try again
 992            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 993                (setq term (substring term 0 hyphend))
 994              (setq term nil)))))
 995
 996   ;; Process the remaining args.
 997   (command-line-1 (cdr command-line-args))
 998
 999   ;; If -batch, terminate after processing the command options.
1000   (if noninteractive (kill-emacs t)))
1001
1002 (defcustom initial-scratch-message (purecopy "\
1003 ;; This buffer is for notes you don't want to save, and for Lisp evaluation.
1004 ;; If you want to create a file, visit that file with C-x C-f,
1005 ;; then enter the text in that file's own buffer.
1006
1007 ")
1008   "Initial message displayed in *scratch* buffer at startup.
1009 If this is nil, no message will be displayed."
1010   :type 'string)
1011
1012 \f
1013 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1014 ;;; Fancy splash screen
1015 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1016
1017 (defvar fancy-splash-text
1018   '((:face variable-pitch
1019            "You can do basic editing with the menu bar and scroll bar \
1020 using the mouse.\n\n"
1021            :face (variable-pitch :weight bold)
1022            "Important Help menu items:\n"
1023            :face variable-pitch "\
1024 Emacs Tutorial\tLearn-by-doing tutorial for using Emacs efficiently
1025 Emacs FAQ\tFrequently asked questions and answers
1026 \(Non)Warranty\tGNU Emacs comes with "
1027            :face (variable-pitch :slant oblique)
1028            "ABSOLUTELY NO WARRANTY\n"
1029            :face variable-pitch
1030            "\
1031 Copying Conditions\tConditions for redistributing and changing Emacs
1032 Ordering Manuals\tHow to order Emacs manuals from the Free Software Foundation\n")
1033   (:face variable-pitch
1034            "You can do basic editing with the menu bar and scroll bar \
1035 using the mouse.\n\n"
1036            :face (variable-pitch :weight bold)
1037            "Useful File menu items:\n"
1038            :face variable-pitch "\
1039 Exit Emacs\t(Or type Control-x followed by Control-c)
1040 Recover Session\tRecover files you were editing before a crash
1041
1042
1043
1044 "
1045            ))
1046   "A list of texts to show in the middle part of splash screens.
1047 Each element in the list should be a list of strings or pairs
1048 `:face FACE', like `fancy-splash-insert' accepts them.")
1049
1050
1051 (defgroup fancy-splash-screen ()
1052   "Fancy splash screen when Emacs starts."
1053   :version "21.1"
1054   :group 'initialization)
1055
1056
1057 (defcustom fancy-splash-delay 10
1058   "*Delay in seconds between splash screens."
1059   :group 'fancy-splash-screen
1060   :type 'integer)
1061
1062
1063 (defcustom fancy-splash-max-time 60
1064   "*Show splash screens for at most this number of seconds.
1065 Values less than 60 seconds are ignored."
1066   :group 'fancy-splash-screen
1067   :type 'integer)
1068
1069
1070 (defcustom fancy-splash-image nil
1071   "*The image to show in the splash screens, or nil for defaults."
1072   :group 'fancy-splash-screen
1073   :type '(choice (const :tag "Default" nil)
1074                  (file :tag "File")))
1075
1076
1077 ;; These are temporary storage areas for the splash screen display.
1078
1079 (defvar fancy-current-text nil)
1080 (defvar fancy-splash-help-echo nil)
1081 (defvar fancy-splash-stop-time nil)
1082
1083
1084 (defun fancy-splash-insert (&rest args)
1085   "Insert text into the current buffer, with faces.
1086 Arguments from ARGS should be either strings or pairs `:face FACE',
1087 where FACE is a valid face specification, as it can be used with
1088 `put-text-properties'."
1089   (let ((current-face nil))
1090     (while args
1091       (if (eq (car args) :face)
1092           (setq args (cdr args) current-face (car args))
1093         (insert (propertize (car args)
1094                             'face current-face
1095                             'help-echo fancy-splash-help-echo)))
1096       (setq args (cdr args)))))
1097
1098
1099 (defun fancy-splash-head ()
1100   "Insert the head part of the splash screen into the current buffer."
1101   (let* ((image-file (cond ((stringp fancy-splash-image)
1102                             fancy-splash-image)
1103                            ((and (display-color-p)
1104                                  (image-type-available-p 'xpm))
1105                             (if (and (fboundp 'x-display-planes)
1106                                      (= (funcall 'x-display-planes) 8))
1107                                 "splash8.xpm"
1108                               "splash.xpm"))
1109                            (t "splash.pbm")))
1110          (img (create-image image-file))
1111          (image-width (and img (car (image-size img))))
1112          (window-width (window-width (selected-window))))
1113     (when img
1114       (when (> window-width image-width)
1115         ;; Center the image in the window.
1116         (let ((pos (/ (- window-width image-width) 2)))
1117           (insert (propertize " " 'display `(space :align-to ,pos))))
1118
1119         ;; Insert the image with a help-echo and a keymap.
1120         (let ((map (make-sparse-keymap))
1121               (help-echo "mouse-2: browse http://www.gnu.org/"))
1122           (define-key map [mouse-2]
1123             (lambda ()
1124               (interactive)
1125               (browse-url "http://www.gnu.org/")
1126               (throw 'exit nil)))
1127           (define-key map [down-mouse-2] 'ignore)
1128           (define-key map [up-mouse-2] 'ignore)
1129           (insert-image img (propertize "xxx" 'help-echo help-echo
1130                                         'keymap map)))
1131         (insert "\n"))))
1132   (if (eq system-type 'gnu/linux)
1133       (fancy-splash-insert
1134        :face '(variable-pitch :foreground "red")
1135        "GNU Emacs is one component of a Linux-based GNU system.")
1136     (fancy-splash-insert
1137      :face '(variable-pitch :foreground "red")
1138      "GNU Emacs is one component of the GNU operating system."))
1139   (insert "\n"))
1140
1141
1142 (defun fancy-splash-tail ()
1143   "Insert the tail part of the splash screen into the current buffer."
1144   (let ((fg (if (eq (frame-parameter nil 'background-mode) 'dark)
1145                 "cyan" "darkblue")))
1146     (fancy-splash-insert :face `(variable-pitch :foreground ,fg)
1147                          "\nThis is "
1148                          (emacs-version)
1149                          "\n"
1150                          :face '(variable-pitch :height 0.5)
1151                          "Copyright (C) 2001 Free Software Foundation, Inc.")))
1152
1153
1154 (defun fancy-splash-screens-1 (buffer)
1155   "Timer function displaying a splash screen."
1156   (when (> (float-time) fancy-splash-stop-time)
1157     (throw 'stop-splashing nil))
1158   (unless fancy-current-text
1159     (setq fancy-current-text fancy-splash-text))
1160   (let ((text (car fancy-current-text)))
1161     (set-buffer buffer)
1162     (erase-buffer)
1163     (fancy-splash-head)
1164     (apply #'fancy-splash-insert text)
1165     (fancy-splash-tail)
1166     (unless (current-message)
1167       (message fancy-splash-help-echo))
1168     (set-buffer-modified-p nil)
1169     (goto-char (point-min))
1170     (force-mode-line-update)
1171     (setq fancy-current-text (cdr fancy-current-text))))
1172
1173
1174 (defun fancy-splash-default-action ()
1175   "Default action for events in the splash screen buffer."
1176   (interactive)
1177   (push last-command-event unread-command-events)
1178   (throw 'exit nil))
1179
1180
1181 (defun fancy-splash-screens ()
1182   "Display fancy splash screens when Emacs starts."
1183   (setq fancy-splash-help-echo (startup-echo-area-message))
1184   (switch-to-buffer "GNU Emacs")
1185   (setq tab-width 20)
1186   (let ((old-hourglass display-hourglass)
1187         (splash-buffer (current-buffer))
1188         timer)
1189     (catch 'stop-splashing
1190       (unwind-protect
1191           (let ((map (make-sparse-keymap)))
1192             (use-local-map map)
1193             (define-key map [t] 'fancy-splash-default-action)
1194             (define-key map [mouse-movement] 'ignore)
1195             (define-key map [mode-line t] 'ignore)
1196             (setq cursor-type nil
1197                   display-hourglass nil
1198                   buffer-undo-list t
1199                   mode-line-format (propertize "---- %b %-"
1200                                                'face '(:weight bold))
1201                   fancy-splash-stop-time (+ (float-time)
1202                                             (max 60 fancy-splash-max-time))
1203                   timer (run-with-timer 0 fancy-splash-delay
1204                                         #'fancy-splash-screens-1
1205                                         splash-buffer))
1206             (recursive-edit))
1207           (cancel-timer timer)
1208           (setq display-hourglass old-hourglass)
1209           (kill-buffer splash-buffer)))))
1210
1211
1212 (defun use-fancy-splash-screens-p ()
1213   "Return t if fancy splash screens should be used."
1214   (when (or (and (display-color-p)
1215                  (image-type-available-p 'xpm))
1216             (image-type-available-p 'pbm))
1217     (let* ((img (create-image (or fancy-splash-image
1218                                   (if (and (display-color-p)
1219                                            (image-type-available-p 'xpm))
1220                                       "splash.xpm" "splash.pbm"))))
1221            (image-height (and img (cdr (image-size img))))
1222            (window-height (1- (window-height (selected-window)))))
1223       (> window-height (+ image-height 15)))))
1224
1225
1226 (defun startup-echo-area-message ()
1227   (if (eq (key-binding "\C-h\C-p") 'describe-project)
1228       "For information about the GNU Project and its goals, type C-h C-p."
1229     (substitute-command-keys
1230      "For information about the GNU Project and its goals, type \
1231 \\[describe-project].")))
1232
1233
1234 (defun display-startup-echo-area-message ()
1235   (let ((resize-mini-windows t))
1236     (message (startup-echo-area-message))))
1237
1238
1239 (defun command-line-1 (command-line-args-left)
1240   (or noninteractive (input-pending-p) init-file-had-error
1241         (and inhibit-startup-echo-area-message
1242              user-init-file
1243              (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
1244                       (equal inhibit-startup-echo-area-message
1245                              (if (string= init-file-user "")
1246                                  (user-login-name)
1247                                init-file-user)))
1248                  ;; Wasn't set with custom; see if .emacs has a setq.
1249                  (let ((buffer (get-buffer-create " *temp*")))
1250                    (prog1
1251                        (condition-case nil
1252                            (save-excursion
1253                              (set-buffer buffer)
1254                              (insert-file-contents user-init-file)
1255                              (re-search-forward
1256                               (concat
1257                                "([ \t\n]*setq[ \t\n]+"
1258                                "inhibit-startup-echo-area-message[ \t\n]+"
1259                                (regexp-quote
1260                                 (prin1-to-string
1261                                  (if (string= init-file-user "")
1262                                      (user-login-name)
1263                                    init-file-user)))
1264                                "[ \t\n]*)")
1265                               nil t))
1266                          (error nil))
1267                      (kill-buffer buffer)))))
1268         (display-startup-echo-area-message))
1269   (if (null command-line-args-left)
1270       (cond ((and (not inhibit-startup-message) (not noninteractive)
1271                   ;; Don't clobber a non-scratch buffer if init file
1272                   ;; has selected it.
1273                   (string= (buffer-name) "*scratch*"))
1274              ;; If there are no switches to process, we might as well
1275              ;; run this hook now, and there may be some need to do it
1276              ;; before doing any output.
1277              (and term-setup-hook
1278                   (run-hooks 'term-setup-hook))
1279              ;; Don't let the hook be run twice.
1280              (setq term-setup-hook nil)
1281
1282              ;; It's important to notice the user settings before we
1283              ;; display the startup message; otherwise, the settings
1284              ;; won't take effect until the user gives the first
1285              ;; keystroke, and that's distracting.
1286              (when (fboundp 'frame-notice-user-settings)
1287                (frame-notice-user-settings))
1288
1289              (when window-setup-hook
1290                (run-hooks 'window-setup-hook)
1291                (setq window-setup-hook nil))
1292
1293              (when (display-popup-menus-p)
1294                (precompute-menubar-bindings))
1295              (setq menubar-bindings-done t)
1296
1297              ;; Do this now to avoid an annoying delay if the user
1298              ;; clicks the menu bar during the sit-for.
1299              (when (= (buffer-size) 0)
1300                (let ((buffer-undo-list t)
1301                      (wait-for-input t))
1302                  (unwind-protect
1303                      (when (not (input-pending-p))
1304                        (goto-char (point-max))
1305                        ;; The convention for this piece of code is that
1306                        ;; each piece of output starts with one or two newlines
1307                        ;; and does not end with any newlines.
1308                        (insert "Welcome to GNU Emacs")
1309                        (if (eq system-type 'gnu/linux)
1310                            (insert ", one component of a Linux-based GNU system."))
1311                        (insert "\n")
1312
1313                        (if (assq 'display (frame-parameters))
1314
1315                            (if (use-fancy-splash-screens-p)
1316                                (progn
1317                                  (setq wait-for-input nil)
1318                                  (fancy-splash-screens))
1319                              (progn
1320                                (insert "\
1321 You can do basic editing with the menu bar and scroll bar using the mouse.
1322
1323 Useful File menu items:
1324 Exit Emacs              (or type Control-x followed by Control-c)
1325 Recover Session         recover files you were editing before a crash
1326
1327 Important Help menu items:
1328 Emacs Tutorial          Learn-by-doing tutorial for using Emacs efficiently.
1329 Emacs FAQ               Frequently asked questions and answers
1330 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
1331 Copying Conditions      Conditions for redistributing and changing Emacs.
1332 Getting New Versions    How to obtain the latest version of Emacs.
1333 Ordering Manuals        How to order manuals from the FSF.
1334 ")
1335                                (insert "\n\n" (emacs-version)
1336                                        "
1337 Copyright (C) 2001 Free Software Foundation, Inc.")))
1338
1339                          ;; If keys have their default meanings,
1340                          ;; use precomputed string to save lots of time.
1341                          (if (and (eq (key-binding "\C-h") 'help-command)
1342                                   (eq (key-binding "\C-xu") 'advertised-undo)
1343                                   (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
1344                                   (eq (key-binding "\C-ht") 'help-with-tutorial)
1345                                   (eq (key-binding "\C-hi") 'info)
1346                                   (eq (key-binding "\C-h\C-n") 'view-emacs-news))
1347                              (insert "
1348 Get help           C-h  (Hold down CTRL and press h)
1349 Undo changes       C-x u       Exit Emacs               C-x C-c
1350 Get a tutorial     C-h t       Use Info to read docs    C-h i
1351 Ordering manuals   C-h RET")
1352                            (insert (substitute-command-keys
1353                                     (format "\n
1354 Get help           %s
1355 Undo changes       \\[advertised-undo]
1356 Exit Emacs         \\[save-buffers-kill-emacs]
1357 Get a tutorial     \\[help-with-tutorial]
1358 Use Info to read docs   \\[info]
1359 Ordering manuals   \\[view-order-manuals]"
1360                                             (let ((where (where-is-internal
1361                                                           'help-command nil t)))
1362                                               (if where
1363                                                   (key-description where)
1364                                                 "M-x help"))))))
1365                          ;; Say how to use the menu bar
1366                          ;; if that is not with the mouse.
1367                          (if (and (eq (key-binding "\M-`") 'tmm-menubar)
1368                                   (eq (key-binding [f10]) 'tmm-menubar))
1369                              (insert "
1370 Activate menubar   F10  or  ESC `  or   M-`")
1371                            (insert (substitute-command-keys "
1372 Activate menubar     \\[tmm-menubar]")))
1373
1374                          (if (display-mouse-p)
1375                              (insert "
1376 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
1377                          ;; Many users seem to have problems with these.
1378                          (insert "
1379 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
1380 If you have no Meta key, you may instead type ESC followed by the character.)")
1381                          (and auto-save-list-file-prefix
1382                               ;; Don't signal an error if the
1383                               ;; directory for auto-save-list files
1384                               ;; does not yet exist.
1385                               (file-directory-p (file-name-directory
1386                                                  auto-save-list-file-prefix))
1387                               (directory-files
1388                                (file-name-directory auto-save-list-file-prefix)
1389                                nil
1390                                (concat "\\`"
1391                                        (regexp-quote (file-name-nondirectory
1392                                                       auto-save-list-file-prefix)))
1393                                t)
1394                               (insert "\n\nIf an Emacs session crashed recently, "
1395                                       "type M-x recover-session RET\nto recover"
1396                                       " the files you were editing."))
1397
1398                          (insert "\n\n" (emacs-version)
1399                                  "
1400 Copyright (C) 2001 Free Software Foundation, Inc.")
1401                          (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
1402                                   (eq (key-binding "\C-h\C-d") 'describe-distribution)
1403                                   (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
1404                              (insert
1405                               "\n
1406 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
1407 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1408 of Emacs and modify it; type C-h C-c to see the conditions.
1409 Type C-h C-d for information on getting the latest version.")
1410                            (insert (substitute-command-keys
1411                                     "\n
1412 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
1413 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1414 of Emacs and modify it; type \\[describe-copying] to see the conditions.
1415 Type \\[describe-distribution] for information on getting the latest version."))))
1416                        (goto-char (point-min))
1417
1418                        (set-buffer-modified-p nil)
1419                        (when wait-for-input
1420                          (sit-for 120)))
1421
1422                    (with-current-buffer (get-buffer "*scratch*")
1423                      (erase-buffer)
1424                      (when initial-scratch-message
1425                        (insert initial-scratch-message))
1426                      (set-buffer-modified-p nil)))))))
1427
1428     ;; Delay 2 seconds after the init file error message
1429     ;; was displayed, so user can read it.
1430     (if init-file-had-error
1431         (sit-for 2))
1432     (let ((dir command-line-default-directory)
1433           (file-count 0)
1434           first-file-buffer
1435           tem
1436           just-files;; t if this follows the magic -- option.
1437           ;; This includes our standard options' long versions
1438           ;; and long versions of what's on command-switch-alist.
1439           (longopts
1440            (append '(("--funcall") ("--load") ("--insert") ("--kill")
1441                      ("--directory") ("--eval") ("--execute")
1442                      ("--find-file") ("--visit") ("--file"))
1443                    (mapcar (lambda (elt)
1444                              (list (concat "-" (car elt))))
1445                            command-switch-alist)))
1446           (line 0)
1447           (column 0))
1448
1449       ;; Add the long X options to longopts.
1450       (setq tem command-line-x-option-alist)
1451       (while tem
1452         (if (string-match "^--" (car (car tem)))
1453             (setq longopts (cons (list (car (car tem))) longopts)))
1454         (setq tem (cdr tem)))
1455
1456       ;; Loop, processing options.
1457       (while (and command-line-args-left)
1458         (let* ((argi (car command-line-args-left))
1459                (orig-argi argi)
1460                argval completion
1461                ;; List of directories specified in -L/--directory,
1462                ;; in reverse of the order specified.
1463                extra-load-path
1464                (initial-load-path load-path))
1465           (setq command-line-args-left (cdr command-line-args-left))
1466
1467           ;; Do preliminary decoding of the option.
1468           (if just-files
1469               ;; After --, don't look for options; treat all args as files.
1470               (setq argi "")
1471             ;; Convert long options to ordinary options
1472             ;; and separate out an attached option argument into argval.
1473             (if (string-match "^--[^=]*=" argi)
1474                 (setq argval (substring argi (match-end 0))
1475                       argi (substring argi 0 (1- (match-end 0)))))
1476             (if (equal argi "--")
1477                 (setq completion nil)
1478               (setq completion (try-completion argi longopts)))
1479             (if (eq completion t)
1480                 (setq argi (substring argi 1))
1481               (if (stringp completion)
1482                   (let ((elt (assoc completion longopts)))
1483                     (or elt
1484                         (error "Option `%s' is ambiguous" argi))
1485                     (setq argi (substring (car elt) 1)))
1486                 (setq argval nil argi orig-argi))))
1487
1488           ;; Execute the option.
1489           (cond ((setq tem (assoc argi command-switch-alist))
1490                  (if argval
1491                      (let ((command-line-args-left
1492                             (cons argval command-line-args-left)))
1493                        (funcall (cdr tem) argi))
1494                    (funcall (cdr tem) argi)))
1495
1496                 ((or (string-equal argi "-f") ;what the manual claims
1497                      (string-equal argi "-funcall")
1498                      (string-equal argi "-e")) ; what the source used to say
1499                  (if argval
1500                      (setq tem (intern argval))
1501                    (setq tem (intern (car command-line-args-left)))
1502                    (setq command-line-args-left (cdr command-line-args-left)))
1503                  (if (arrayp (symbol-function tem))
1504                      (command-execute tem)
1505                    (funcall tem)))
1506
1507                 ((or (string-equal argi "-eval")
1508                      (string-equal argi "-execute"))
1509                  (if argval
1510                      (setq tem argval)
1511                    (setq tem (car command-line-args-left))
1512                    (setq command-line-args-left (cdr command-line-args-left)))
1513                  (eval (read tem)))
1514                 ;; Set the default directory as specified in -L.
1515
1516                 ((or (string-equal argi "-L")
1517                      (string-equal argi "-directory"))
1518                  (if argval
1519                      (setq tem argval)
1520                    (setq tem (car command-line-args-left)
1521                          command-line-args-left (cdr command-line-args-left)))
1522                  (setq tem (command-line-normalize-file-name tem))
1523                  (setq extra-load-path
1524                        (cons (expand-file-name tem) extra-load-path))
1525                  (setq load-path (append (nreverse extra-load-path)
1526                                          initial-load-path)))
1527
1528                 ((or (string-equal argi "-l")
1529                      (string-equal argi "-load"))
1530                  (if argval
1531                      (setq tem argval)
1532                    (setq tem (car command-line-args-left)
1533                          command-line-args-left (cdr command-line-args-left)))
1534                  (let ((file (command-line-normalize-file-name tem)))
1535                    ;; Take file from default dir if it exists there;
1536                    ;; otherwise let `load' search for it.
1537                    (if (file-exists-p (expand-file-name file))
1538                        (setq file (expand-file-name file)))
1539                    (load file nil t)))
1540
1541                 ((string-equal argi "-insert")
1542                  (if argval
1543                      (setq tem argval)
1544                    (setq tem (car command-line-args-left)
1545                          command-line-args-left (cdr command-line-args-left)))
1546                  (or (stringp tem)
1547                      (error "File name omitted from `-insert' option"))
1548                  (insert-file-contents (command-line-normalize-file-name tem)))
1549
1550                 ((string-equal argi "-kill")
1551                  (kill-emacs t))
1552
1553                 ((string-match "^\\+[0-9]+\\'" argi)
1554                  (setq line (string-to-int argi)))
1555
1556                 ((string-match "^\\+\\([0-9]+\\):\\([0-9]+\\)\\'" argi)
1557                  (setq line (string-to-int (match-string 1 argi))
1558                        column (string-to-int (match-string 2 argi))))
1559
1560                 ((setq tem (assoc argi command-line-x-option-alist))
1561                  ;; Ignore X-windows options and their args if not using X.
1562                  (setq command-line-args-left
1563                        (nthcdr (nth 1 tem) command-line-args-left)))
1564
1565                 ((or (string-equal argi "-find-file")
1566                      (string-equal argi "-file")
1567                      (string-equal argi "-visit"))
1568                  ;; An explicit option to specify visiting a file.
1569                  (if argval
1570                      (setq tem argval)
1571                    (setq tem (car command-line-args-left)
1572                          command-line-args-left (cdr command-line-args-left)))
1573                  (unless (stringp tem)
1574                    (error "File name omitted from `%s' option" argi))
1575                  (setq file-count (1+ file-count))
1576                  (let ((file (expand-file-name
1577                               (command-line-normalize-file-name tem) dir)))
1578                    (if (= file-count 1)
1579                        (setq first-file-buffer (find-file file))
1580                      (find-file-other-window file)))
1581                  (or (zerop line)
1582                      (goto-line line))
1583                  (setq line 0)
1584                  (unless (< column 1)
1585                    (move-to-column (1- column)))
1586                  (setq column 0))
1587
1588                 ((equal argi "--")
1589                  (setq just-files t))
1590                 (t
1591                  ;; We have almost exhausted our options. See if the
1592                  ;; user has made any other command-line options available
1593                  (let ((hooks command-line-functions);; lrs 7/31/89
1594                        (did-hook nil))
1595                    (while (and hooks
1596                                (not (setq did-hook (funcall (car hooks)))))
1597                      (setq hooks (cdr hooks)))
1598                    (if (not did-hook)
1599                        ;; Ok, presume that the argument is a file name
1600                        (progn
1601                          (if (string-match "\\`-" argi)
1602                              (error "Unknown option `%s'" argi))
1603                          (setq file-count (1+ file-count))
1604                          (let ((file
1605                                 (expand-file-name
1606                                  (command-line-normalize-file-name orig-argi)
1607                                  dir)))
1608                            (if (= file-count 1)
1609                                (setq first-file-buffer (find-file file))
1610                              (find-file-other-window file)))
1611                          (or (zerop line)
1612                              (goto-line line))
1613                          (setq line 0)
1614                          (unless (< column 1)
1615                            (move-to-column (1- column)))
1616                          (setq column 0))))))))
1617       ;; If 3 or more files visited, and not all visible,
1618       ;; show user what they all are.  But leave the last one current.
1619       (and (> file-count 2)
1620            (not noninteractive)
1621            (or (get-buffer-window first-file-buffer)
1622                (list-buffers))))))
1623
1624
1625 (defun command-line-normalize-file-name (file)
1626   "Collapse multiple slashes to one, to handle non-Emacs file names."
1627   (save-match-data
1628     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1629     ;; That is significant on some systems.
1630     ;; However, /// at the beginning is supposed to mean just /, not //.
1631     (if (string-match "^///+" file)
1632         (setq file (replace-match "/" t t file)))
1633     (while (string-match "//+" file 1)
1634       (setq file (replace-match "/" t t file)))
1635     file))
1636
1637 ;;; startup.el ends here