lisp/tool-bar.el

   1 ;;; tool-bar.el --- setting up the tool bar
   2
   3 ;; Copyright (C) 2000-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;; Keywords: mouse frames
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Provides `tool-bar-mode' to control display of the tool-bar and
  27 ;; bindings for the global tool bar with convenience functions
  28 ;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
  29
  30 ;; The normal global binding for [tool-bar] (below) uses the value of
  31 ;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
  32 ;; may either bind items under the [tool-bar] prefix key of the local
  33 ;; map to add to the global bar or may set `tool-bar-map'
  34 ;; buffer-locally to override it.  (Some items are removed from the
  35 ;; global bar in modes which have `special' as their `mode-class'
  36 ;; property.)
  37
  38 ;; Todo: Somehow make tool bars easily customizable by the naive?
  39
  40 ;;; Code:
  41
  42 ;; The autoload cookie doesn't work when preloading.
  43 ;; Deleting it means invoking this command won't work
  44 ;; when you are on a tty.  I hope that won't cause too much trouble -- rms.
  45 (define-minor-mode tool-bar-mode
  46   "Toggle use of the tool bar.
  47 With numeric ARG, display the tool bar if and only if ARG is positive.
  48
  49 See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
  50 conveniently adding tool bar items."
  51   :init-value t
  52   :global t
  53   ;; It's defined in C/cus-start, this stops the d-m-m macro defining it again.
  54   :variable tool-bar-mode
  55   (let ((val (if tool-bar-mode 1 0)))
  56     (dolist (frame (frame-list))
  57       (set-frame-parameter frame 'tool-bar-lines val))
  58     ;; If the user has given `default-frame-alist' a `tool-bar-lines'
  59     ;; parameter, replace it.
  60     (if (assq 'tool-bar-lines default-frame-alist)
  61         (setq default-frame-alist
  62               (cons (cons 'tool-bar-lines val)
  63                     (assq-delete-all 'tool-bar-lines
  64                                      default-frame-alist)))))
  65   (and tool-bar-mode
  66        (= 1 (length (default-value 'tool-bar-map))) ; not yet setup
  67        (tool-bar-setup)))
  68
  69 ;;;###autoload
  70 ;; Used in the Show/Hide menu, to have the toggle reflect the current frame.
  71 (defun toggle-tool-bar-mode-from-frame (&optional arg)
  72   "Toggle tool bar on or off, based on the status of the current frame.
  73 See `tool-bar-mode' for more information."
  74   (interactive (list (or current-prefix-arg 'toggle)))
  75   (if (eq arg 'toggle)
  76       (tool-bar-mode (if (> (frame-parameter nil 'tool-bar-lines) 0) 0 1))
  77     (tool-bar-mode arg)))
  78
  79 (defvar tool-bar-map (make-sparse-keymap)
  80   "Keymap for the tool bar.
  81 Define this locally to override the global tool bar.")
  82
  83 (global-set-key [tool-bar]
  84                 `(menu-item ,(purecopy "tool bar") ignore
  85                             :filter tool-bar-make-keymap))
  86
  87 (declare-function image-mask-p "image.c" (spec &optional frame))
  88
  89 (defconst tool-bar-keymap-cache (make-hash-table :weakness t :test 'equal))
  90
  91 (defun tool-bar-make-keymap (&optional _ignore)
  92   "Generate an actual keymap from `tool-bar-map'.
  93 Its main job is to figure out which images to use based on the display's
  94 color capability and based on the available image libraries."
  95   (let ((key (cons (frame-terminal) tool-bar-map)))
  96     (or (gethash key tool-bar-keymap-cache)
  97         (puthash key (tool-bar-make-keymap-1) tool-bar-keymap-cache))))
  98
  99 (defun tool-bar-make-keymap-1 ()
 100   "Generate an actual keymap from `tool-bar-map', without caching."
 101   (mapcar (lambda (bind)
 102             (let (image-exp plist)
 103               (when (and (eq (car-safe (cdr-safe bind)) 'menu-item)
 104                          ;; For the format of menu-items, see node
 105                          ;; `Extended Menu Items' in the Elisp manual.
 106                          (setq plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 107                                              bind))
 108                          (setq image-exp (plist-get plist :image))
 109                          (consp image-exp)
 110                          (not (eq (car image-exp) 'image))
 111                          (fboundp (car image-exp)))
 112                 (if (not (display-images-p))
 113                     (setq bind nil)
 114                   (let ((image (eval image-exp)))
 115                     (unless (and image (image-mask-p image))
 116                       (setq image (append image '(:mask heuristic))))
 117                     (setq bind (copy-sequence bind)
 118                           plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 119                                         bind))
 120                     (plist-put plist :image image))))
 121               bind))
 122           tool-bar-map))
 123
 124 ;;;###autoload
 125 (defun tool-bar-add-item (icon def key &rest props)
 126   "Add an item to the tool bar.
 127 ICON names the image, DEF is the key definition and KEY is a symbol
 128 for the fake function key in the menu keymap.  Remaining arguments
 129 PROPS are additional items to add to the menu item specification.  See
 130 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 131
 132 ICON is the base name of a file containing the image to use.  The
 133 function will first try to use low-color/ICON.xpm if `display-color-cells'
 134 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 135 ICON.xbm, using `find-image'.
 136
 137 Use this function only to make bindings in the global value of `tool-bar-map'.
 138 To define items in any other map, use `tool-bar-local-item'."
 139   (apply 'tool-bar-local-item icon def key tool-bar-map props))
 140
 141 (defun tool-bar--image-expression (icon)
 142   "Return an expression that evaluates to an image spec for ICON."
 143   (let* ((fg (face-attribute 'tool-bar :foreground))
 144          (bg (face-attribute 'tool-bar :background))
 145          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 146                         (if (eq bg 'unspecified) nil (list :background bg))))
 147          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 148          (xpm-lo-spec (list :type 'xpm :file
 149                             (concat "low-color/" icon ".xpm")))
 150          (pbm-spec (append (list :type 'pbm :file
 151                                  (concat icon ".pbm")) colors))
 152          (xbm-spec (append (list :type 'xbm :file
 153                                  (concat icon ".xbm")) colors)))
 154     `(find-image (cond ((not (display-color-p))
 155                         ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))
 156                        ((< (display-color-cells) 256)
 157                         ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec))
 158                        (t
 159                         ',(list xpm-spec pbm-spec xbm-spec))))))
 160
 161 ;;;###autoload
 162 (defun tool-bar-local-item (icon def key map &rest props)
 163   "Add an item to the tool bar in map MAP.
 164 ICON names the image, DEF is the key definition and KEY is a symbol
 165 for the fake function key in the menu keymap.  Remaining arguments
 166 PROPS are additional items to add to the menu item specification.  See
 167 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 168
 169 ICON is the base name of a file containing the image to use.  The
 170 function will first try to use low-color/ICON.xpm if `display-color-cells'
 171 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 172 ICON.xbm, using `find-image'."
 173   (let* ((image-exp (tool-bar--image-expression icon)))
 174     (define-key-after map (vector key)
 175       `(menu-item ,(symbol-name key) ,def :image ,image-exp ,@props))))
 176
 177 ;;;###autoload
 178 (defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
 179   "Define tool bar binding for COMMAND in keymap MAP using the given ICON.
 180 This makes a binding for COMMAND in `tool-bar-map', copying its
 181 binding from the menu bar in MAP (which defaults to `global-map'), but
 182 modifies the binding by adding an image specification for ICON.  It
 183 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 184 properties to add to the binding.
 185
 186 MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
 187
 188 Use this function only to make bindings in the global value of `tool-bar-map'.
 189 To define items in any other map, use `tool-bar-local-item-from-menu'."
 190   (apply 'tool-bar-local-item-from-menu command icon
 191          (default-value 'tool-bar-map) map props))
 192
 193 ;;;###autoload
 194 (defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
 195   "Define local tool bar binding for COMMAND using the given ICON.
 196 This makes a binding for COMMAND in IN-MAP, copying its binding from
 197 the menu bar in FROM-MAP (which defaults to `global-map'), but
 198 modifies the binding by adding an image specification for ICON.  It
 199 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 200 properties to add to the binding.
 201
 202 FROM-MAP must contain appropriate binding for `[menu-bar]' which
 203 holds a keymap."
 204   (unless from-map
 205     (setq from-map global-map))
 206   (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
 207          (keys (where-is-internal command menu-bar-map))
 208          (image-exp (tool-bar--image-expression icon))
 209          submap key)
 210     ;; We'll pick up the last valid entry in the list of keys if
 211     ;; there's more than one.
 212     ;; FIXME: Aren't they *all* "valid"??  --Stef
 213     (dolist (k keys)
 214       ;; We're looking for a binding of the command in a submap of
 215       ;; the menu bar map, so the key sequence must be two or more
 216       ;; long.
 217       (if (and (vectorp k)
 218                (> (length k) 1))
 219           (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
 220                 ;; Last element in the bound key sequence:
 221                 (kk (aref k (1- (length k)))))
 222             (if (and (keymapp m)
 223                      (symbolp kk))
 224                 (setq submap m
 225                       key kk)))))
 226     (when (and (symbolp submap) (boundp submap))
 227       (setq submap (eval submap)))
 228     (let ((defn (assq key (cdr submap))))
 229       (if (eq (cadr defn) 'menu-item)
 230           (define-key-after in-map (vector key)
 231             (append (cdr defn) (list :image image-exp) props))
 232         (setq defn (cdr defn))
 233         (define-key-after in-map (vector key)
 234           (let ((rest (cdr defn)))
 235             ;; If the rest of the definition starts
 236             ;; with a list of menu cache info, get rid of that.
 237             (if (and (consp rest) (consp (car rest)))
 238                 (setq rest (cdr rest)))
 239             (append `(menu-item ,(car defn) ,rest)
 240                     (list :image image-exp) props)))))))
 241
 242 ;;; Set up some global items.  Additions/deletions up for grabs.
 243
 244 (defun tool-bar-setup ()
 245   (setq tool-bar-separator-image-expression
 246         (tool-bar--image-expression "separator"))
 247   (tool-bar-add-item-from-menu 'find-file "new" nil :label "New File"
 248                                :vert-only t)
 249   (tool-bar-add-item-from-menu 'menu-find-file-existing "open" nil
 250                                :label "Open" :vert-only t)
 251   (tool-bar-add-item-from-menu 'dired "diropen" nil :vert-only t)
 252   (tool-bar-add-item-from-menu 'kill-this-buffer "close" nil :vert-only t)
 253   (tool-bar-add-item-from-menu 'save-buffer "save" nil
 254                                :label "Save")
 255   (define-key-after (default-value 'tool-bar-map) [separator-1] menu-bar-separator)
 256   (tool-bar-add-item-from-menu 'undo "undo" nil)
 257   (define-key-after (default-value 'tool-bar-map) [separator-2] menu-bar-separator)
 258   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
 259                                "cut" nil :vert-only t)
 260   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
 261                                "copy" nil :vert-only t)
 262   (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
 263                                "paste" nil :vert-only t)
 264   (define-key-after (default-value 'tool-bar-map) [separator-3] menu-bar-separator)
 265   (tool-bar-add-item-from-menu 'isearch-forward "search"
 266                                nil :label "Search" :vert-only t)
 267   ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
 268
 269   ;; There's no icon appropriate for News and we need a command rather
 270   ;; than a lambda for Read Mail.
 271   ;;(tool-bar-add-item-from-menu 'compose-mail "mail/compose")
 272
 273   ;; Help button on a tool bar is rather non-standard...
 274   ;; (let ((tool-bar-map (default-value 'tool-bar-map)))
 275   ;;   (tool-bar-add-item "help" (lambda ()
 276   ;;                            (interactive)
 277   ;;                            (popup-menu menu-bar-help-menu))
 278   ;;                   'help
 279   ;;                   :help "Pop up the Help menu"))
 280 )
 281
 282 (if (featurep 'move-toolbar)
 283     (defcustom tool-bar-position 'top
 284       "Specify on which side the tool bar shall be.
 285 Possible values are `top' (tool bar on top), `bottom' (tool bar at bottom),
 286 `left' (tool bar on left) and `right' (tool bar on right).
 287 Customize `tool-bar-mode' if you want to show or hide the tool bar."
 288       :type '(choice (const top)
 289                      (const bottom)
 290                      (const left)
 291                      (const right))
 292       :group 'frames
 293       :initialize 'custom-initialize-default
 294       :set (lambda (sym val)
 295              (set-default sym val)
 296              (modify-all-frames-parameters
 297               (list (cons 'tool-bar-position val))))))
 298
 299
 300 (provide 'tool-bar)
 301
 302 ;;; tool-bar.el ends here