lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  27 ;; associated support machinery, such as adding hyperlinks, etc.,
  28
  29 ;;; Code:
  30
  31 (require 'button)
  32 (require 'view)
  33 (eval-when-compile (require 'easymenu))
  34
  35 (defvar help-mode-map (make-sparse-keymap)
  36   "Keymap for help mode.")
  37
  38 (set-keymap-parent help-mode-map button-buffer-map)
  39
  40 (define-key help-mode-map [mouse-2] 'help-follow-mouse)
  41 (define-key help-mode-map "\C-c\C-b" 'help-go-back)
  42 (define-key help-mode-map "\C-c\C-f" 'help-go-forward)
  43 (define-key help-mode-map "\C-c\C-c" 'help-follow-symbol)
  44 ;; Documentation only, since we use minor-mode-overriding-map-alist.
  45 (define-key help-mode-map "\r" 'help-follow)
  46
  47 (easy-menu-define help-mode-menu help-mode-map
  48   "Menu for Help Mode."
  49   '("Help-Mode"
  50     ["Show Help for Symbol" help-follow-symbol
  51      :help "Show the docs for the symbol at point"]
  52     ["Previous Topic" help-go-back
  53      :help "Go back to previous topic in this help buffer"]
  54     ["Next Topic" help-go-forward
  55      :help "Go back to next topic in this help buffer"]
  56     ["Move to Previous Button" backward-button
  57      :help "Move to the Next Button in the help buffer"]
  58     ["Move to Next Button" forward-button
  59       :help "Move to the Next Button in the help buffer"]))
  60
  61 (defvar help-xref-stack nil
  62   "A stack of ways by which to return to help buffers after following xrefs.
  63 Used by `help-follow' and `help-xref-go-back'.
  64 An element looks like (POSITION FUNCTION ARGS...).
  65 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  66 (put 'help-xref-stack 'permanent-local t)
  67 (make-variable-buffer-local 'help-xref-stack)
  68
  69 (defvar help-xref-forward-stack nil
  70   "The stack of used to navigate help forwards  after using the back button.
  71 Used by `help-follow' and `help-xref-go-forward'.
  72 An element looks like (POSITION FUNCTION ARGS...).
  73 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  74 (put 'help-xref-forward-stack 'permanent-local t)
  75 (make-variable-buffer-local 'help-xref-forward-stack)
  76
  77 (defvar help-xref-stack-item nil
  78   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  79 The format is (FUNCTION ARGS...).")
  80 (put 'help-xref-stack-item 'permanent-local t)
  81 (make-variable-buffer-local 'help-xref-stack-item)
  82
  83 (defvar help-xref-stack-forward-item nil
  84   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  85 The format is (FUNCTION ARGS...).")
  86 (put 'help-xref-stack-forward-item 'permanent-local t)
  87 (make-variable-buffer-local 'help-xref-stack-forward-item)
  88
  89 (setq-default help-xref-stack nil help-xref-stack-item nil)
  90 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  91
  92 (defcustom help-mode-hook nil
  93   "Hook run by `help-mode'."
  94   :type 'hook
  95   :group 'help)
  96 \f
  97 ;; Button types used by help
  98
  99 (define-button-type 'help-xref
 100   'follow-link t
 101   'action #'help-button-action)
 102
 103 (defun help-button-action (button)
 104   "Call BUTTON's help function."
 105   (help-do-xref (button-start button)
 106                 (button-get button 'help-function)
 107                 (button-get button 'help-args)))
 108
 109 ;; These 6 calls to define-button-type were generated in a dolist
 110 ;; loop, but that is bad because it means these button types don't
 111 ;; have an easily found definition.
 112
 113 (define-button-type 'help-function
 114   :supertype 'help-xref
 115   'help-function 'describe-function
 116   'help-echo (purecopy "mouse-2, RET: describe this function"))
 117
 118 (define-button-type 'help-variable
 119   :supertype 'help-xref
 120   'help-function 'describe-variable
 121   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 122
 123 (define-button-type 'help-face
 124   :supertype 'help-xref
 125   'help-function 'describe-face
 126   'help-echo (purecopy "mouse-2, RET: describe this face"))
 127
 128 (define-button-type 'help-coding-system
 129   :supertype 'help-xref
 130   'help-function 'describe-coding-system
 131   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 132
 133 (define-button-type 'help-input-method
 134   :supertype 'help-xref
 135   'help-function 'describe-input-method
 136   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 137
 138 (define-button-type 'help-character-set
 139   :supertype 'help-xref
 140   'help-function 'describe-character-set
 141   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 142
 143 ;; make some more ideosyncratic button types
 144
 145 (define-button-type 'help-symbol
 146   :supertype 'help-xref
 147   'help-function #'help-xref-interned
 148   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 149
 150 (define-button-type 'help-back
 151   :supertype 'help-xref
 152   'help-function #'help-xref-go-back
 153   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 154
 155 (define-button-type 'help-forward
 156   :supertype 'help-xref
 157   'help-function #'help-xref-go-forward
 158   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 159
 160 (define-button-type 'help-info-variable
 161   :supertype 'help-xref
 162   ;; the name of the variable is put before the argument to Info
 163   'help-function (lambda (a v) (info v))
 164   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 165
 166 (define-button-type 'help-info
 167   :supertype 'help-xref
 168   'help-function #'info
 169   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 170
 171 (define-button-type 'help-url
 172   :supertype 'help-xref
 173   'help-function #'browse-url
 174   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 175
 176 (define-button-type 'help-customize-variable
 177   :supertype 'help-xref
 178   'help-function (lambda (v)
 179                    (customize-variable v))
 180   'help-echo (purecopy "mouse-2, RET: customize variable"))
 181
 182 (define-button-type 'help-customize-face
 183   :supertype 'help-xref
 184   'help-function (lambda (v)
 185                    (customize-face v))
 186   'help-echo (purecopy "mouse-2, RET: customize face"))
 187
 188 (define-button-type 'help-function-def
 189   :supertype 'help-xref
 190   'help-function (lambda (fun file)
 191                    (require 'find-func)
 192                    (when (eq file 'C-source)
 193                      (setq file
 194                            (help-C-file-name (indirect-function fun) 'fun)))
 195                    ;; Don't use find-function-noselect because it follows
 196                    ;; aliases (which fails for built-in functions).
 197                    (let ((location
 198                           (find-function-search-for-symbol fun nil file)))
 199                      (pop-to-buffer (car location))
 200                      (if (cdr location)
 201                          (goto-char (cdr location))
 202                        (message "Unable to find location in file"))))
 203   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 204
 205 (define-button-type 'help-variable-def
 206   :supertype 'help-xref
 207   'help-function (lambda (var &optional file)
 208                    (when (eq file 'C-source)
 209                      (setq file (help-C-file-name var 'var)))
 210                    (let ((location (find-variable-noselect var file)))
 211                      (pop-to-buffer (car location))
 212                      (if (cdr location)
 213                        (goto-char (cdr location))
 214                        (message "Unable to find location in file"))))
 215   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 216
 217 (define-button-type 'help-face-def
 218   :supertype 'help-xref
 219   'help-function (lambda (fun file)
 220                    (require 'find-func)
 221                    ;; Don't use find-function-noselect because it follows
 222                    ;; aliases (which fails for built-in functions).
 223                    (let ((location
 224                           (find-function-search-for-symbol fun 'defface file)))
 225                      (pop-to-buffer (car location))
 226                      (if (cdr location)
 227                          (goto-char (cdr location))
 228                        (message "Unable to find location in file"))))
 229   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 230
 231 \f
 232 ;;;###autoload
 233 (defun help-mode ()
 234   "Major mode for viewing help text and navigating references in it.
 235 Entry to this mode runs the normal hook `help-mode-hook'.
 236 Commands:
 237 \\{help-mode-map}"
 238   (interactive)
 239   (kill-all-local-variables)
 240   (use-local-map help-mode-map)
 241   (setq mode-name "Help")
 242   (setq major-mode 'help-mode)
 243
 244   (view-mode)
 245   (set (make-local-variable 'view-no-disable-on-exit) t)
 246   ;; With Emacs 22 `view-exit-action' could delete the selected window
 247   ;; disregarding whether the help buffer was shown in that window at
 248   ;; all.  Since `view-exit-action' is called with the help buffer as
 249   ;; argument it seems more appropriate to have it work on the buffer
 250   ;; only and leave it to `view-mode-exit' to delete any associated
 251   ;; window(s).
 252   (setq view-exit-action
 253         (lambda (buffer)
 254           ;; Use `with-current-buffer' to make sure that `bury-buffer'
 255           ;; also removes BUFFER from the selected window.
 256           (with-current-buffer buffer
 257             (bury-buffer))))
 258
 259   (run-mode-hooks 'help-mode-hook))
 260
 261 ;;;###autoload
 262 (defun help-mode-setup ()
 263   (help-mode)
 264   (setq buffer-read-only nil))
 265
 266 ;;;###autoload
 267 (defun help-mode-finish ()
 268   (if (eq help-window t)
 269       ;; If `help-window' is t, `view-return-to-alist' is handled by
 270       ;; `with-help-window'.  In this case set `help-window' to the
 271       ;; selected window since now is the only moment where we can
 272       ;; unambiguously identify it.
 273       (setq help-window (selected-window))
 274     (let ((entry (assq (selected-window) view-return-to-alist)))
 275       (if entry
 276           ;; When entering Help mode from the Help window,
 277           ;; such as by following a link, preserve the same
 278           ;; meaning for the q command.
 279           ;; (setcdr entry (cons (selected-window) help-return-method))
 280           nil
 281         (setq view-return-to-alist
 282               (cons (cons (selected-window) help-return-method)
 283                     view-return-to-alist)))))
 284
 285   (when (eq major-mode 'help-mode)
 286     ;; View mode's read-only status of existing *Help* buffer is lost
 287     ;; by with-output-to-temp-buffer.
 288     (toggle-read-only 1)
 289     (help-make-xrefs (current-buffer))))
 290 \f
 291 ;; Grokking cross-reference information in doc strings and
 292 ;; hyperlinking it.
 293
 294 ;; This may have some scope for extension and the same or something
 295 ;; similar should be done for widget doc strings, which currently use
 296 ;; another mechanism.
 297
 298 (defvar help-back-label (purecopy "[back]")
 299   "Label to use by `help-make-xrefs' for the go-back reference.")
 300
 301 (defvar help-forward-label (purecopy "[forward]")
 302   "Label to use by `help-make-xrefs' for the go-forward reference.")
 303
 304 (defconst help-xref-symbol-regexp
 305   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 306                     "\\(function\\|command\\)\\|"          ; Link to function
 307                     "\\(face\\)\\|"                        ; Link to face
 308                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 309                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 310                     "[ \t\n]+\\)?"
 311                     ;; Note starting with word-syntax character:
 312                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 313   "Regexp matching doc string references to symbols.
 314
 315 The words preceding the quoted symbol can be used in doc strings to
 316 distinguish references to variables, functions and symbols.")
 317
 318 (defvar help-xref-mule-regexp nil
 319   "Regexp matching doc string references to MULE-related keywords.
 320
 321 It is usually nil, and is temporarily bound to an appropriate regexp
 322 when help commands related to multilingual environment (e.g.,
 323 `describe-coding-system') are invoked.")
 324
 325
 326 (defconst help-xref-info-regexp
 327   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 328   "Regexp matching doc string references to an Info node.")
 329
 330 (defconst help-xref-url-regexp
 331   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
 332   "Regexp matching doc string references to a URL.")
 333
 334 ;;;###autoload
 335 (defun help-setup-xref (item interactive-p)
 336   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 337
 338 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 339 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 340 calling command was invoked interactively.  In this case the stack of
 341 items for help buffer \"back\" buttons is cleared.
 342
 343 This should be called very early, before the output buffer is cleared,
 344 because we want to record the \"previous\" position of point so we can
 345 restore it properly when going back."
 346   (with-current-buffer (help-buffer)
 347     (when help-xref-stack-item
 348       (push (cons (point) help-xref-stack-item) help-xref-stack)
 349       (setq help-xref-forward-stack nil))
 350     (when interactive-p
 351       (let ((tail (nthcdr 10 help-xref-stack)))
 352         ;; Truncate the stack.
 353         (if tail (setcdr tail nil))))
 354     (setq help-xref-stack-item item)))
 355
 356 (defvar help-xref-following nil
 357   "Non-nil when following a help cross-reference.")
 358
 359 ;;;###autoload
 360 (defun help-buffer ()
 361   (buffer-name                          ;for with-output-to-temp-buffer
 362    (if help-xref-following
 363        (current-buffer)
 364      (get-buffer-create "*Help*"))))
 365
 366 (defvar help-xref-override-view-map
 367   (let ((map (make-sparse-keymap)))
 368     (set-keymap-parent map view-mode-map)
 369     (define-key map "\r" nil)
 370     map)
 371   "Replacement keymap for `view-mode' in help buffers.")
 372
 373 ;;;###autoload
 374 (defun help-make-xrefs (&optional buffer)
 375   "Parse and hyperlink documentation cross-references in the given BUFFER.
 376
 377 Find cross-reference information in a buffer and activate such cross
 378 references for selection with `help-follow'.  Cross-references have
 379 the canonical form `...'  and the type of reference may be
 380 disambiguated by the preceding word(s) used in
 381 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 382 preceded or followed by the word `face'.  Variables without
 383 variable documentation do not get cross-referenced, unless
 384 preceded by the word `variable' or `option'.
 385
 386 If the variable `help-xref-mule-regexp' is non-nil, find also
 387 cross-reference information related to multilingual environment
 388 \(e.g., coding-systems).  This variable is also used to disambiguate
 389 the type of reference as the same way as `help-xref-symbol-regexp'.
 390
 391 A special reference `back' is made to return back through a stack of
 392 help buffers.  Variable `help-back-label' specifies the text for
 393 that."
 394   (interactive "b")
 395   (save-excursion
 396     (set-buffer (or buffer (current-buffer)))
 397     (goto-char (point-min))
 398     ;; Skip the header-type info, though it might be useful to parse
 399     ;; it at some stage (e.g. "function in `library'").
 400     (forward-paragraph)
 401     (let ((old-modified (buffer-modified-p)))
 402       (let ((stab (syntax-table))
 403             (case-fold-search t)
 404             (inhibit-read-only t))
 405         (set-syntax-table emacs-lisp-mode-syntax-table)
 406         ;; The following should probably be abstracted out.
 407         (unwind-protect
 408             (progn
 409               ;; Info references
 410               (save-excursion
 411                 (while (re-search-forward help-xref-info-regexp nil t)
 412                   (let ((data (match-string 2)))
 413                     (save-match-data
 414                       (unless (string-match "^([^)]+)" data)
 415                         (setq data (concat "(emacs)" data))))
 416                     (help-xref-button 2 'help-info data))))
 417               ;; URLs
 418               (save-excursion
 419                 (while (re-search-forward help-xref-url-regexp nil t)
 420                   (let ((data (match-string 1)))
 421                     (help-xref-button 1 'help-url data))))
 422               ;; Mule related keywords.  Do this before trying
 423               ;; `help-xref-symbol-regexp' because some of Mule
 424               ;; keywords have variable or function definitions.
 425               (if help-xref-mule-regexp
 426                   (save-excursion
 427                     (while (re-search-forward help-xref-mule-regexp nil t)
 428                       (let* ((data (match-string 7))
 429                              (sym (intern-soft data)))
 430                         (cond
 431                          ((match-string 3) ; coding system
 432                           (and sym (coding-system-p sym)
 433                                (help-xref-button 6 'help-coding-system sym)))
 434                          ((match-string 4) ; input method
 435                           (and (assoc data input-method-alist)
 436                                (help-xref-button 7 'help-input-method data)))
 437                          ((or (match-string 5) (match-string 6)) ; charset
 438                           (and sym (charsetp sym)
 439                                (help-xref-button 7 'help-character-set sym)))
 440                          ((assoc data input-method-alist)
 441                           (help-xref-button 7 'help-character-set data))
 442                          ((and sym (coding-system-p sym))
 443                           (help-xref-button 7 'help-coding-system sym))
 444                          ((and sym (charsetp sym))
 445                           (help-xref-button 7 'help-character-set sym)))))))
 446               ;; Quoted symbols
 447               (save-excursion
 448                 (while (re-search-forward help-xref-symbol-regexp nil t)
 449                   (let* ((data (match-string 8))
 450                          (sym (intern-soft data)))
 451                     (if sym
 452                         (cond
 453                          ((match-string 3)  ; `variable' &c
 454                           (and (or (boundp sym) ; `variable' doesn't ensure
 455                                         ; it's actually bound
 456                                    (get sym 'variable-documentation))
 457                                (help-xref-button 8 'help-variable sym)))
 458                          ((match-string 4)   ; `function' &c
 459                           (and (fboundp sym) ; similarly
 460                                (help-xref-button 8 'help-function sym)))
 461                          ((match-string 5) ; `face'
 462                           (and (facep sym)
 463                                (help-xref-button 8 'help-face sym)))
 464                          ((match-string 6)) ; nothing for `symbol'
 465                          ((match-string 7)
 466 ;;;  this used:
 467 ;;;                       #'(lambda (arg)
 468 ;;;                           (let ((location
 469 ;;;                                  (find-function-noselect arg)))
 470 ;;;                             (pop-to-buffer (car location))
 471 ;;;                             (goto-char (cdr location))))
 472                           (help-xref-button 8 'help-function-def sym))
 473                          ((and
 474                            (facep sym)
 475                            (save-match-data (looking-at "[ \t\n]+face\\W")))
 476                           (help-xref-button 8 'help-face sym))
 477                          ((and (or (boundp sym)
 478                                    (get sym 'variable-documentation))
 479                                (fboundp sym))
 480                           ;; We can't intuit whether to use the
 481                           ;; variable or function doc -- supply both.
 482                           (help-xref-button 8 'help-symbol sym))
 483                          ((and
 484                            (or (boundp sym)
 485                                (get sym 'variable-documentation))
 486                            (or
 487                             (documentation-property
 488                              sym 'variable-documentation)
 489                             (condition-case nil
 490                                 (documentation-property
 491                                  (indirect-variable sym)
 492                                  'variable-documentation)
 493                               (cyclic-variable-indirection nil))))
 494                           (help-xref-button 8 'help-variable sym))
 495                          ((fboundp sym)
 496                           (help-xref-button 8 'help-function sym)))))))
 497               ;; An obvious case of a key substitution:
 498               (save-excursion
 499                 (while (re-search-forward
 500                         ;; Assume command name is only word and symbol
 501                         ;; characters to get things like `use M-x foo->bar'.
 502                         ;; Command required to end with word constituent
 503                         ;; to avoid `.' at end of a sentence.
 504                         "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 505                   (let ((sym (intern-soft (match-string 1))))
 506                     (if (fboundp sym)
 507                         (help-xref-button 1 'help-function sym)))))
 508               ;; Look for commands in whole keymap substitutions:
 509               (save-excursion
 510                 ;; Make sure to find the first keymap.
 511                 (goto-char (point-min))
 512                 ;; Find a header and the column at which the command
 513                 ;; name will be found.
 514
 515                 ;; If the keymap substitution isn't the last thing in
 516                 ;; the doc string, and if there is anything on the
 517                 ;; same line after it, this code won't recognize the end of it.
 518                 (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 519                                           nil t)
 520                   (let ((col (- (match-end 1) (match-beginning 1))))
 521                     (while
 522                         (and (not (eobp))
 523                              ;; Stop at a pair of blank lines.
 524                              (not (looking-at "\n\\s-*\n")))
 525                       ;; Skip a single blank line.
 526                       (and (eolp) (forward-line))
 527                       (end-of-line)
 528                       (skip-chars-backward "^ \t\n")
 529                       (if (and (>= (current-column) col)
 530                                (looking-at "\\(\\sw\\|\\s_\\)+$"))
 531                           (let ((sym (intern-soft (match-string 0))))
 532                             (if (fboundp sym)
 533                                 (help-xref-button 0 'help-function sym))))
 534                       (forward-line))))))
 535           (set-syntax-table stab))
 536         ;; Delete extraneous newlines at the end of the docstring
 537         (goto-char (point-max))
 538         (while (and (not (bobp)) (bolp))
 539           (delete-char -1))
 540         (insert "\n")
 541         (when (or help-xref-stack help-xref-forward-stack)
 542           (insert "\n"))
 543         ;; Make a back-reference in this buffer if appropriate.
 544         (when help-xref-stack
 545           (help-insert-xref-button help-back-label 'help-back
 546                                    (current-buffer)))
 547         ;; Make a forward-reference in this buffer if appropriate.
 548         (when help-xref-forward-stack
 549           (when help-xref-stack
 550             (insert "\t"))
 551           (help-insert-xref-button help-forward-label 'help-forward
 552                                    (current-buffer)))
 553         (when (or help-xref-stack help-xref-forward-stack)
 554           (insert "\n")))
 555       ;; View mode steals RET from us.
 556       (set (make-local-variable 'minor-mode-overriding-map-alist)
 557            (list (cons 'view-mode help-xref-override-view-map)))
 558       (set-buffer-modified-p old-modified))))
 559
 560 ;;;###autoload
 561 (defun help-xref-button (match-number type &rest args)
 562   "Make a hyperlink for cross-reference text previously matched.
 563 MATCH-NUMBER is the subexpression of interest in the last matched
 564 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 565 passed to the button's help-function when it is invoked.
 566 See `help-make-xrefs'."
 567   ;; Don't mung properties we've added specially in some instances.
 568   (unless (button-at (match-beginning match-number))
 569     (make-text-button (match-beginning match-number)
 570                       (match-end match-number)
 571                       'type type 'help-args args)))
 572
 573 ;;;###autoload
 574 (defun help-insert-xref-button (string type &rest args)
 575   "Insert STRING and make a hyperlink from cross-reference text on it.
 576 TYPE is the type of button to use.  Any remaining arguments are passed
 577 to the button's help-function when it is invoked.
 578 See `help-make-xrefs'."
 579   (unless (button-at (point))
 580     (insert-text-button string 'type type 'help-args args)))
 581
 582 ;;;###autoload
 583 (defun help-xref-on-pp (from to)
 584   "Add xrefs for symbols in `pp's output between FROM and TO."
 585   (if (> (- to from) 5000) nil
 586     (with-syntax-table emacs-lisp-mode-syntax-table
 587       (save-excursion
 588         (save-restriction
 589           (narrow-to-region from to)
 590           (goto-char (point-min))
 591           (condition-case nil
 592               (while (not (eobp))
 593                 (cond
 594                  ((looking-at "\"") (forward-sexp 1))
 595                  ((looking-at "#<") (search-forward ">" nil 'move))
 596                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 597                   (let* ((sym (intern-soft (match-string 1)))
 598                          (type (cond ((fboundp sym) 'help-function)
 599                                      ((or (memq sym '(t nil))
 600                                           (keywordp sym))
 601                                       nil)
 602                                      ((and sym
 603                                            (or (boundp sym)
 604                                                (get sym
 605                                                     'variable-documentation)))
 606                                       'help-variable))))
 607                     (when type (help-xref-button 1 type sym)))
 608                   (goto-char (match-end 1)))
 609                  (t (forward-char 1))))
 610             (error nil)))))))
 611
 612 \f
 613 ;; Additional functions for (re-)creating types of help buffers.
 614 (defun help-xref-interned (symbol)
 615   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 616 Both variable, function and face documentation are extracted into a single
 617 help buffer."
 618   (with-current-buffer (help-buffer)
 619     ;; Push the previous item on the stack before clobbering the output buffer.
 620     (help-setup-xref nil nil)
 621     (let ((facedoc (when (facep symbol)
 622                      ;; Don't record the current entry in the stack.
 623                      (setq help-xref-stack-item nil)
 624                      (describe-face symbol)))
 625           (fdoc (when (fboundp symbol)
 626                   ;; Don't record the current entry in the stack.
 627                   (setq help-xref-stack-item nil)
 628                   (describe-function symbol)))
 629           (sdoc (when (or (boundp symbol)
 630                           (get symbol 'variable-documentation))
 631                   ;; Don't record the current entry in the stack.
 632                   (setq help-xref-stack-item nil)
 633                   (describe-variable symbol))))
 634       (cond
 635        (sdoc
 636         ;; We now have a help buffer on the variable.
 637         ;; Insert the function and face text before it.
 638         (when (or fdoc facedoc)
 639           (goto-char (point-min))
 640           (let ((inhibit-read-only t))
 641             (when fdoc
 642               (insert fdoc "\n\n")
 643               (when facedoc
 644                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 645                         " is also a " "face." "\n\n")))
 646             (when facedoc
 647               (insert facedoc "\n\n"))
 648             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 649                     " is also a " "variable." "\n\n"))
 650           ;; Don't record the `describe-variable' item in the stack.
 651           (setq help-xref-stack-item nil)
 652           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 653        (fdoc
 654         ;; We now have a help buffer on the function.
 655         ;; Insert face text before it.
 656         (when facedoc
 657           (goto-char (point-max))
 658           (let ((inhibit-read-only t))
 659             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 660                     " is also a " "face." "\n\n" facedoc))
 661           ;; Don't record the `describe-function' item in the stack.
 662           (setq help-xref-stack-item nil)
 663           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 664
 665 \f
 666 ;; Navigation/hyperlinking with xrefs
 667
 668 (defun help-xref-go-back (buffer)
 669   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 670   (let (item position method args)
 671     (with-current-buffer buffer
 672       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 673       (when help-xref-stack
 674         (setq item (pop help-xref-stack)
 675               ;; Clear the current item so that it won't get pushed
 676               ;; by the function we're about to call.  TODO: We could also
 677               ;; push it onto a "forward" stack and add a `forw' button.
 678               help-xref-stack-item nil
 679               position (car item)
 680               method (cadr item)
 681               args (cddr item))))
 682     (apply method args)
 683     (with-current-buffer buffer
 684       (if (get-buffer-window buffer)
 685           (set-window-point (get-buffer-window buffer) position)
 686         (goto-char position)))))
 687
 688 (defun help-xref-go-forward (buffer)
 689   "From BUFFER, go forward to next help buffer."
 690   (let (item position method args)
 691     (with-current-buffer buffer
 692       (push (cons (point) help-xref-stack-item) help-xref-stack)
 693       (when help-xref-forward-stack
 694         (setq item (pop help-xref-forward-stack)
 695               ;; Clear the current item so that it won't get pushed
 696               ;; by the function we're about to call.  TODO: We could also
 697               ;; push it onto a "forward" stack and add a `forw' button.
 698               help-xref-stack-item nil
 699               position (car item)
 700               method (cadr item)
 701               args (cddr item))))
 702     (apply method args)
 703     (with-current-buffer buffer
 704       (if (get-buffer-window buffer)
 705           (set-window-point (get-buffer-window buffer) position)
 706         (goto-char position)))))
 707
 708 (defun help-go-back ()
 709   "Go back to previous topic in this help buffer."
 710   (interactive)
 711   (if help-xref-stack
 712       (help-xref-go-back (current-buffer))
 713     (error "No previous help buffer")))
 714
 715 (defun help-go-forward ()
 716   "Go back to next topic in this help buffer."
 717   (interactive)
 718   (if help-xref-forward-stack
 719       (help-xref-go-forward (current-buffer))
 720     (error "No next help buffer")))
 721
 722 (defun help-do-xref (pos function args)
 723   "Call the help cross-reference function FUNCTION with args ARGS.
 724 Things are set up properly so that the resulting help-buffer has
 725 a proper [back] button."
 726   ;; There is a reference at point.  Follow it.
 727   (let ((help-xref-following t))
 728     (apply function args)))
 729
 730 ;; The doc string is meant to explain what buttons do.
 731 (defun help-follow-mouse ()
 732   "Follow the cross-reference that you click on."
 733   (interactive)
 734   (error "No cross-reference here"))
 735
 736 ;; The doc string is meant to explain what buttons do.
 737 (defun help-follow ()
 738   "Follow cross-reference at point.
 739
 740 For the cross-reference format, see `help-make-xrefs'."
 741   (interactive)
 742   (error "No cross-reference here"))
 743
 744 (defun help-follow-symbol (&optional pos)
 745   "In help buffer, show docs for symbol at POS, defaulting to point.
 746 Show all docs for that symbol as either a variable, function or face."
 747   (interactive "d")
 748   (unless pos
 749     (setq pos (point)))
 750   ;; check if the symbol under point is a function, variable or face
 751   (let ((sym
 752          (intern
 753           (save-excursion
 754             (goto-char pos) (skip-syntax-backward "w_")
 755             (buffer-substring (point)
 756                               (progn (skip-syntax-forward "w_")
 757                                      (point)))))))
 758     (when (or (boundp sym)
 759               (get sym 'variable-documentation)
 760               (fboundp sym) (facep sym))
 761       (help-do-xref pos #'help-xref-interned (list sym)))))
 762
 763 (defun help-insert-string (string)
 764   "Insert STRING to the help buffer and install xref info for it.
 765 This function can be used to restore the old contents of the help buffer
 766 when going back to the previous topic in the xref stack.  It is needed
 767 in case when it is impossible to recompute the old contents of the
 768 help buffer by other means."
 769   (setq help-xref-stack-item (list #'help-insert-string string))
 770   (with-output-to-temp-buffer (help-buffer)
 771     (insert string)))
 772
 773 (provide 'help-mode)
 774
 775 ;; arch-tag: 850954ae-3725-4cb4-8e91-0bf6d52d6b0b
 776 ;;; help-mode.el ends here